New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
dynadv_cen2.F90 in NEMO/branches/2021/dev_r14318_RK3_stage1/src/OCE/DYN – NEMO

source: NEMO/branches/2021/dev_r14318_RK3_stage1/src/OCE/DYN/dynadv_cen2.F90 @ 14419

Last change on this file since 14419 was 14419, checked in by techene, 3 years ago

#2506 comments and loop optimisation from gm
  • Property svn:keywords set to Id
File size: 9.3 KB
RevLine 
[643]1MODULE dynadv_cen2
2   !!======================================================================
3   !!                       ***  MODULE  dynadv  ***
4   !! Ocean dynamics: Update the momentum trend with the flux form advection
5   !!                 using a 2nd order centred scheme
6   !!======================================================================
[1566]7   !! History :  2.0  ! 2006-08  (G. Madec, S. Theetten)  Original code
8   !!            3.2  ! 2009-07  (R. Benshila)  Suppression of rigid-lid option
[643]9   !!----------------------------------------------------------------------
10
11   !!----------------------------------------------------------------------
[6140]12   !!   dyn_adv_cen2  : flux form momentum advection (ln_dynadv_cen2=T) using a 2nd order centred scheme 
[643]13   !!----------------------------------------------------------------------
14   USE oce            ! ocean dynamics and tracers
15   USE dom_oce        ! ocean space and time domain
[4990]16   USE trd_oce        ! trends: ocean variables
17   USE trddyn         ! trend manager: dynamics
18   !
[643]19   USE in_out_manager ! I/O manager
[2715]20   USE lib_mpp        ! MPP library
[1129]21   USE prtctl         ! Print control
[643]22
23   IMPLICIT NONE
24   PRIVATE
25
[1566]26   PUBLIC   dyn_adv_cen2   ! routine called by step.F90
[643]27
28   !! * Substitutions
[12377]29#  include "do_loop_substitute.h90"
[13237]30#  include "domzgr_substitute.h90"
[643]31   !!----------------------------------------------------------------------
[9598]32   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
[1152]33   !! $Id$
[10068]34   !! Software governed by the CeCILL license (see ./LICENSE)
[643]35   !!----------------------------------------------------------------------
36CONTAINS
37
[14419]38   SUBROUTINE dyn_adv_cen2( kt, Kmm, puu, pvv, Krhs, pau, pav, paw, no_zad )
[643]39      !!----------------------------------------------------------------------
40      !!                  ***  ROUTINE dyn_adv_cen2  ***
41      !!
[14419]42      !! ** Purpose :   Compute the momentum advection trend in flux form
[1566]43      !!              and the general trend of the momentum equation.
[643]44      !!
[14419]45      !! ** Method  :   Trend evaluated with a 2nd order centered scheme
46      !!              using fields at Kmm time-level.
47      !!                In RK3 time stepping case, the optional arguments (pau,pav,paw)
48      !!              are present. They are used as advective velocity while
49      !!              the advected velocity remains (puu,pvv).
[643]50      !!
[14419]51      !! ** Action  :   (puu,pvv)(:,:,:,Krhs)   updated with the advective trend
[643]52      !!----------------------------------------------------------------------
[14419]53      INTEGER                                     , INTENT(in   ) ::   kt , Kmm, Krhs   ! ocean time-step and level indices
54      INTEGER                   , OPTIONAL        , INTENT(in   ) ::   no_zad                ! no vertical advection computation
55      REAL(wp), DIMENSION(jpi,jpj,jpk,jpt), TARGET, INTENT(inout) ::   puu, pvv         ! ocean velocities and RHS of momentum equation
56      REAL(wp), DIMENSION(:,:,:), OPTIONAL, TARGET, INTENT(in   ) ::   pau, pav, paw    ! advective velocity
[2715]57      !
[1566]58      INTEGER  ::   ji, jj, jk   ! dummy loop indices
[14419]59      REAL(wp) ::   zzu, zzv     ! local scalars
[14381]60      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zfu_t, zfu_f, zfu_uw, zfu
61      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zfv_t, zfv_f, zfv_vw, zfv, zfw
[14419]62      REAL(wp), DIMENSION(:,:,:), POINTER ::   zpt_u, zpt_v, zpt_w
[643]63      !!----------------------------------------------------------------------
[3294]64      !
[2715]65      IF( kt == nit000 .AND. lwp ) THEN
66         WRITE(numout,*)
67         WRITE(numout,*) 'dyn_adv_cen2 : 2nd order flux form momentum advection'
68         WRITE(numout,*) '~~~~~~~~~~~~'
[643]69      ENDIF
[3294]70      !
[6140]71      IF( l_trddyn ) THEN           ! trends: store the input trends
[12377]72         zfu_uw(:,:,:) = puu(:,:,:,Krhs)
73         zfv_vw(:,:,:) = pvv(:,:,:,Krhs)
[1129]74      ENDIF
[6140]75      !
[14381]76      IF( PRESENT( pau ) ) THEN     ! RK3: advective velocity (pau,pav,paw) /= advected velocity (puu,pvv,ww)
[14419]77         zpt_u => pau(:,:,:)
78         zpt_v => pav(:,:,:)
79         zpt_w => paw(:,:,:)
[14381]80      ELSE                          ! MLF: advective velocity = (puu,pvv,ww)
[14419]81         zpt_u => puu(:,:,:,Kmm)
82         zpt_v => pvv(:,:,:,Kmm)
83         zpt_w => ww (:,:,:    )
[14381]84      ENDIF
85      !
[6140]86      !                             !==  Horizontal advection  ==!
87      !
88      DO jk = 1, jpkm1                    ! horizontal transport
[14419]89         zfu(:,:,jk) = 0.25_wp * e2u(:,:) * e3u(:,:,jk,Kmm) * zpt_u(:,:,jk)
90         zfv(:,:,jk) = 0.25_wp * e1v(:,:) * e3v(:,:,jk,Kmm) * zpt_v(:,:,jk)
[13497]91         DO_2D( 1, 0, 1, 0 )              ! horizontal momentum fluxes (at T- and F-point)
[12377]92            zfu_t(ji+1,jj  ,jk) = ( zfu(ji,jj,jk) + zfu(ji+1,jj,jk) ) * ( puu(ji,jj,jk,Kmm) + puu(ji+1,jj  ,jk,Kmm) )
93            zfv_f(ji  ,jj  ,jk) = ( zfv(ji,jj,jk) + zfv(ji+1,jj,jk) ) * ( puu(ji,jj,jk,Kmm) + puu(ji  ,jj+1,jk,Kmm) )
94            zfu_f(ji  ,jj  ,jk) = ( zfu(ji,jj,jk) + zfu(ji,jj+1,jk) ) * ( pvv(ji,jj,jk,Kmm) + pvv(ji+1,jj  ,jk,Kmm) )
95            zfv_t(ji  ,jj+1,jk) = ( zfv(ji,jj,jk) + zfv(ji,jj+1,jk) ) * ( pvv(ji,jj,jk,Kmm) + pvv(ji  ,jj+1,jk,Kmm) )
96         END_2D
[13497]97         DO_2D( 0, 0, 0, 0 )              ! divergence of horizontal momentum fluxes
[12377]98            puu(ji,jj,jk,Krhs) = puu(ji,jj,jk,Krhs) - (  zfu_t(ji+1,jj,jk) - zfu_t(ji,jj  ,jk)    &
[13237]99               &                           + zfv_f(ji  ,jj,jk) - zfv_f(ji,jj-1,jk)  ) * r1_e1e2u(ji,jj)   &
100               &                           / e3u(ji,jj,jk,Kmm)
[12377]101            pvv(ji,jj,jk,Krhs) = pvv(ji,jj,jk,Krhs) - (  zfu_f(ji,jj  ,jk) - zfu_f(ji-1,jj,jk)    &
[13237]102               &                           + zfv_t(ji,jj+1,jk) - zfv_t(ji  ,jj,jk)  ) * r1_e1e2v(ji,jj)   &
103               &                           / e3v(ji,jj,jk,Kmm)
[12377]104         END_2D
[1566]105      END DO
106      !
[6140]107      IF( l_trddyn ) THEN           ! trends: send trend to trddyn for diagnostic
[12377]108         zfu_uw(:,:,:) = puu(:,:,:,Krhs) - zfu_uw(:,:,:)
109         zfv_vw(:,:,:) = pvv(:,:,:,Krhs) - zfv_vw(:,:,:)
110         CALL trd_dyn( zfu_uw, zfv_vw, jpdyn_keg, kt, Kmm )
111         zfu_t(:,:,:) = puu(:,:,:,Krhs)
112         zfv_t(:,:,:) = pvv(:,:,:,Krhs)
[1129]113      ENDIF
[1566]114      !
[14419]115      IF( PRESENT( no_zad ) ) THEN  !==  No vertical advection  ==!   (except if linear free surface)
116         !                               ==
117         IF( ln_linssh ) THEN                ! linear free surface: advection through the surface z=0
118            DO_2D( 0, 0, 0, 0 )
119               zzu = 0.5_wp * ( e1e2t(ji,jj) * zpt_w(ji,jj,1) + e1e2t(ji+1,jj) * zpt_w(ji+1,jj,1) ) * puu(ji,jj,1,Kmm)
120               zzv = 0.5_wp * ( e1e2t(ji,jj) * zpt_w(ji,jj,1) + e1e2t(ji,jj+1) * zpt_w(ji,jj+1,1) ) * pvv(ji,jj,1,Kmm)
121               puu(ji,jj,1,Krhs) = puu(ji,jj,1,Krhs) - zzu * r1_e1e2u(ji,jj)   &
122                  &                                        / e3u(ji,jj,1,Kmm)
123               pvv(ji,jj,1,Krhs) = pvv(ji,jj,1,Krhs) - zzv * r1_e1e2v(ji,jj)   &
124                  &                                        / e3v(ji,jj,1,Kmm)
125            END_2D
126         ENDIF
127         !
128      ELSE                          !==  Vertical advection  ==!
129         !
130         DO_2D( 0, 0, 0, 0 )                 ! surface/bottom advective fluxes set to zero
131            zfu_uw(ji,jj,jpk) = 0._wp   ;   zfv_vw(ji,jj,jpk) = 0._wp
132            zfu_uw(ji,jj, 1 ) = 0._wp   ;   zfv_vw(ji,jj, 1 ) = 0._wp
[12377]133         END_2D
[14419]134         IF( ln_linssh ) THEN                ! linear free surface: advection through the surface z=0
135            DO_2D( 0, 0, 0, 0 )
136               zfu_uw(ji,jj,1) = 0.5_wp * ( e1e2t(ji,jj) * zpt_w(ji,jj,1) + e1e2t(ji+1,jj) * zpt_w(ji+1,jj,1) ) * puu(ji,jj,1,Kmm)
137               zfv_vw(ji,jj,1) = 0.5_wp * ( e1e2t(ji,jj) * zpt_w(ji,jj,1) + e1e2t(ji,jj+1) * zpt_w(ji,jj+1,1) ) * pvv(ji,jj,1,Kmm)
138            END_2D
139         ENDIF
140         DO jk = 2, jpkm1                    ! interior advective fluxes
141            DO_2D( 0, 1, 0, 1 )                  ! 1/4 * Vertical transport
142               zfw(ji,jj,jk) = 0.25_wp * e1e2t(ji,jj) * zpt_w(ji,jj,jk)
143            END_2D
144            DO_2D( 0, 0, 0, 0 )
145               zfu_uw(ji,jj,jk) = ( zfw(ji,jj,jk) + zfw(ji+1,jj  ,jk) ) * ( puu(ji,jj,jk,Kmm) + puu(ji,jj,jk-1,Kmm) )
146               zfv_vw(ji,jj,jk) = ( zfw(ji,jj,jk) + zfw(ji  ,jj+1,jk) ) * ( pvv(ji,jj,jk,Kmm) + pvv(ji,jj,jk-1,Kmm) )
147            END_2D
148         END DO
149         DO_3D( 0, 0, 0, 0, 1, jpkm1 )       ! divergence of vertical momentum flux divergence
150            puu(ji,jj,jk,Krhs) = puu(ji,jj,jk,Krhs) - ( zfu_uw(ji,jj,jk) - zfu_uw(ji,jj,jk+1) ) * r1_e1e2u(ji,jj)   &
151               &                                      / e3u(ji,jj,jk,Kmm)
152            pvv(ji,jj,jk,Krhs) = pvv(ji,jj,jk,Krhs) - ( zfv_vw(ji,jj,jk) - zfv_vw(ji,jj,jk+1) ) * r1_e1e2v(ji,jj)   &
153               &                                      / e3v(ji,jj,jk,Kmm)
154         END_3D
155         !
156         IF( l_trddyn ) THEN                 ! trends: send trend to trddyn for diagnostic
157            zfu_t(:,:,:) = puu(:,:,:,Krhs) - zfu_t(:,:,:)
158            zfv_t(:,:,:) = pvv(:,:,:,Krhs) - zfv_t(:,:,:)
159            CALL trd_dyn( zfu_t, zfv_t, jpdyn_zad, kt, Kmm )
160         ENDIF
161         !                                   ! Control print
162         IF(sn_cfctl%l_prtctl)   CALL prt_ctl( tab3d_1=puu(:,:,:,Krhs), clinfo1=' cen2 adv - Ua: ', mask1=umask,   &
163            &                                  tab3d_2=pvv(:,:,:,Krhs), clinfo2=           ' Va: ', mask2=vmask, clinfo3='dyn' )
164         !
[6140]165      ENDIF
[1566]166      !
[643]167   END SUBROUTINE dyn_adv_cen2
168
169   !!==============================================================================
170END MODULE dynadv_cen2
Note: See TracBrowser for help on using the repository browser.