New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
dynadv_cen2.F90 in NEMO/branches/2021/dev_r14318_RK3_stage1/src/OCE/DYN – NEMO

source: NEMO/branches/2021/dev_r14318_RK3_stage1/src/OCE/DYN/dynadv_cen2.F90 @ 15574

Last change on this file since 15574 was 15574, checked in by techene, 3 years ago

#2605 #2715 trunk merged into dev_r14318_RK3_stage1
  • Property svn:keywords set to Id
File size: 9.5 KB
Line 
1MODULE dynadv_cen2
2   !!======================================================================
3   !!                       ***  MODULE  dynadv  ***
4   !! Ocean dynamics: Update the momentum trend with the flux form advection
5   !!                 using a 2nd order centred scheme
6   !!======================================================================
7   !! History :  2.0  ! 2006-08  (G. Madec, S. Theetten)  Original code
8   !!            3.2  ! 2009-07  (R. Benshila)  Suppression of rigid-lid option
9   !!----------------------------------------------------------------------
10
11   !!----------------------------------------------------------------------
12   !!   dyn_adv_cen2  : flux form momentum advection (ln_dynadv_cen2=T) using a 2nd order centred scheme 
13   !!----------------------------------------------------------------------
14   USE oce            ! ocean dynamics and tracers
15   USE dom_oce        ! ocean space and time domain
16   USE trd_oce        ! trends: ocean variables
17   USE trddyn         ! trend manager: dynamics
18   !
19   USE in_out_manager ! I/O manager
20   USE lib_mpp        ! MPP library
21   USE prtctl         ! Print control
22
23   IMPLICIT NONE
24   PRIVATE
25
26   PUBLIC   dyn_adv_cen2   ! routine called by step.F90
27
28   !! * Substitutions
29#  include "do_loop_substitute.h90"
30#  include "domzgr_substitute.h90"
31   !!----------------------------------------------------------------------
32   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
33   !! $Id$
34   !! Software governed by the CeCILL license (see ./LICENSE)
35   !!----------------------------------------------------------------------
36CONTAINS
37
38   SUBROUTINE dyn_adv_cen2( kt, Kmm, puu, pvv, Krhs, pau, pav, paw, no_zad )
39      !!----------------------------------------------------------------------
40      !!                  ***  ROUTINE dyn_adv_cen2  ***
41      !!
42      !! ** Purpose :   Compute the momentum advection trend in flux form
43      !!              and the general trend of the momentum equation.
44      !!
45      !! ** Method  :   Trend evaluated with a 2nd order centered scheme
46      !!              using fields at Kmm time-level.
47      !!                In RK3 time stepping case, the optional arguments (pau,pav,paw)
48      !!              are present. They are used as advective velocity while
49      !!              the advected velocity remains (puu,pvv).
50      !!
51      !! ** Action  :   (puu,pvv)(:,:,:,Krhs)   updated with the advective trend
52      !!----------------------------------------------------------------------
53      INTEGER                                     , INTENT(in   ) ::   kt , Kmm, Krhs   ! ocean time-step and level indices
54      INTEGER                   , OPTIONAL        , INTENT(in   ) ::   no_zad                ! no vertical advection computation
55      REAL(wp), DIMENSION(jpi,jpj,jpk,jpt), TARGET, INTENT(inout) ::   puu, pvv         ! ocean velocities and RHS of momentum equation
56      REAL(wp), DIMENSION(:,:,:), OPTIONAL, TARGET, INTENT(in   ) ::   pau, pav, paw    ! advective velocity
57      !
58      INTEGER  ::   ji, jj, jk   ! dummy loop indices
59      REAL(wp) ::   zzu, zzv     ! local scalars
60      REAL(wp), DIMENSION(A2D(nn_hls),jpk) ::   zfu_t, zfu_f, zfu_uw, zfu
61      REAL(wp), DIMENSION(A2D(nn_hls),jpk) ::   zfv_t, zfv_f, zfv_vw, zfv, zfw
62      REAL(wp), DIMENSION(:,:,:) , POINTER ::   zpt_u, zpt_v, zpt_w
63      !!----------------------------------------------------------------------
64      !
65      IF( .NOT. l_istiled .OR. ntile == 1 )  THEN                       ! Do only on the first tile
66         IF( kt == nit000 .AND. lwp ) THEN
67            WRITE(numout,*)
68            WRITE(numout,*) 'dyn_adv_cen2 : 2nd order flux form momentum advection'
69            WRITE(numout,*) '~~~~~~~~~~~~'
70         ENDIF
71      ENDIF
72      !
73      IF( l_trddyn ) THEN           ! trends: store the input trends
74         zfu_uw(:,:,:) = puu(:,:,:,Krhs)
75         zfv_vw(:,:,:) = pvv(:,:,:,Krhs)
76      ENDIF
77      !
78      IF( PRESENT( pau ) ) THEN     ! RK3: advective velocity (pau,pav,paw) /= advected velocity (puu,pvv,ww)
79         zpt_u => pau(:,:,:)
80         zpt_v => pav(:,:,:)
81         zpt_w => paw(:,:,:)
82      ELSE                          ! MLF: advective velocity = (puu,pvv,ww)
83         zpt_u => puu(:,:,:,Kmm)
84         zpt_v => pvv(:,:,:,Kmm)
85         zpt_w => ww (:,:,:    )
86      ENDIF
87      !
88      !                             !==  Horizontal advection  ==!
89      !
90      DO jk = 1, jpkm1                    ! horizontal transport
91         DO_2D( 1, 1, 1, 1 )
92            zfu(ji,jj,jk) = 0.25_wp * e2u(ji,jj) * e3u(ji,jj,jk,Kmm) * zpt_u(ji,jj,jk)
93            zfv(ji,jj,jk) = 0.25_wp * e1v(ji,jj) * e3v(ji,jj,jk,Kmm) * zpt_v(ji,jj,jk)
94         END_2D
95         DO_2D( 1, 0, 1, 0 )              ! horizontal momentum fluxes (at T- and F-point)
96            zfu_t(ji+1,jj  ,jk) = ( zfu(ji,jj,jk) + zfu(ji+1,jj,jk) ) * ( puu(ji,jj,jk,Kmm) + puu(ji+1,jj  ,jk,Kmm) )
97            zfv_f(ji  ,jj  ,jk) = ( zfv(ji,jj,jk) + zfv(ji+1,jj,jk) ) * ( puu(ji,jj,jk,Kmm) + puu(ji  ,jj+1,jk,Kmm) )
98            zfu_f(ji  ,jj  ,jk) = ( zfu(ji,jj,jk) + zfu(ji,jj+1,jk) ) * ( pvv(ji,jj,jk,Kmm) + pvv(ji+1,jj  ,jk,Kmm) )
99            zfv_t(ji  ,jj+1,jk) = ( zfv(ji,jj,jk) + zfv(ji,jj+1,jk) ) * ( pvv(ji,jj,jk,Kmm) + pvv(ji  ,jj+1,jk,Kmm) )
100         END_2D
101         DO_2D( 0, 0, 0, 0 )              ! divergence of horizontal momentum fluxes
102            puu(ji,jj,jk,Krhs) = puu(ji,jj,jk,Krhs) - (  zfu_t(ji+1,jj,jk) - zfu_t(ji,jj  ,jk)    &
103               &                                       + zfv_f(ji  ,jj,jk) - zfv_f(ji,jj-1,jk)  ) * r1_e1e2u(ji,jj)   &
104               &                                    / e3u(ji,jj,jk,Kmm)
105            pvv(ji,jj,jk,Krhs) = pvv(ji,jj,jk,Krhs) - (  zfu_f(ji,jj  ,jk) - zfu_f(ji-1,jj,jk)    &
106               &                                       + zfv_t(ji,jj+1,jk) - zfv_t(ji  ,jj,jk)  ) * r1_e1e2v(ji,jj)   &
107               &                                    / e3v(ji,jj,jk,Kmm)
108         END_2D
109      END DO
110      !
111      IF( l_trddyn ) THEN           ! trends: send trend to trddyn for diagnostic
112         zfu_uw(:,:,:) = puu(:,:,:,Krhs) - zfu_uw(:,:,:)
113         zfv_vw(:,:,:) = pvv(:,:,:,Krhs) - zfv_vw(:,:,:)
114         CALL trd_dyn( zfu_uw, zfv_vw, jpdyn_keg, kt, Kmm )
115         zfu_t(:,:,:) = puu(:,:,:,Krhs)
116         zfv_t(:,:,:) = pvv(:,:,:,Krhs)
117      ENDIF
118      !
119      IF( PRESENT( no_zad ) ) THEN  !==  No vertical advection  ==!   (except if linear free surface)
120         !                               ==
121         IF( ln_linssh ) THEN                ! linear free surface: advection through the surface z=0
122            DO_2D( 0, 0, 0, 0 )
123               zzu = 0.5_wp * ( e1e2t(ji,jj) * zpt_w(ji,jj,1) + e1e2t(ji+1,jj) * zpt_w(ji+1,jj,1) ) * puu(ji,jj,1,Kmm)
124               zzv = 0.5_wp * ( e1e2t(ji,jj) * zpt_w(ji,jj,1) + e1e2t(ji,jj+1) * zpt_w(ji,jj+1,1) ) * pvv(ji,jj,1,Kmm)
125               puu(ji,jj,1,Krhs) = puu(ji,jj,1,Krhs) - zzu * r1_e1e2u(ji,jj)   &
126                  &                                        / e3u(ji,jj,1,Kmm)
127               pvv(ji,jj,1,Krhs) = pvv(ji,jj,1,Krhs) - zzv * r1_e1e2v(ji,jj)   &
128                  &                                        / e3v(ji,jj,1,Kmm)
129            END_2D
130         ENDIF
131         !
132      ELSE                          !==  Vertical advection  ==!
133         !
134         DO_2D( 0, 0, 0, 0 )                 ! surface/bottom advective fluxes set to zero
135            zfu_uw(ji,jj,jpk) = 0._wp   ;   zfv_vw(ji,jj,jpk) = 0._wp
136            zfu_uw(ji,jj, 1 ) = 0._wp   ;   zfv_vw(ji,jj, 1 ) = 0._wp
137         END_2D
138         IF( ln_linssh ) THEN                ! linear free surface: advection through the surface z=0
139            DO_2D( 0, 0, 0, 0 )
140               zfu_uw(ji,jj,1) = 0.5_wp * ( e1e2t(ji,jj) * zpt_w(ji,jj,1) + e1e2t(ji+1,jj) * zpt_w(ji+1,jj,1) ) * puu(ji,jj,1,Kmm)
141               zfv_vw(ji,jj,1) = 0.5_wp * ( e1e2t(ji,jj) * zpt_w(ji,jj,1) + e1e2t(ji,jj+1) * zpt_w(ji,jj+1,1) ) * pvv(ji,jj,1,Kmm)
142            END_2D
143         ENDIF
144         DO jk = 2, jpkm1                    ! interior advective fluxes
145            DO_2D( 0, 1, 0, 1 )                  ! 1/4 * Vertical transport
146               zfw(ji,jj,jk) = 0.25_wp * e1e2t(ji,jj) * zpt_w(ji,jj,jk)
147            END_2D
148            DO_2D( 0, 0, 0, 0 )
149               zfu_uw(ji,jj,jk) = ( zfw(ji,jj,jk) + zfw(ji+1,jj  ,jk) ) * ( puu(ji,jj,jk,Kmm) + puu(ji,jj,jk-1,Kmm) )
150               zfv_vw(ji,jj,jk) = ( zfw(ji,jj,jk) + zfw(ji  ,jj+1,jk) ) * ( pvv(ji,jj,jk,Kmm) + pvv(ji,jj,jk-1,Kmm) )
151            END_2D
152         END DO
153         DO_3D( 0, 0, 0, 0, 1, jpkm1 )       ! divergence of vertical momentum flux divergence
154            puu(ji,jj,jk,Krhs) = puu(ji,jj,jk,Krhs) - ( zfu_uw(ji,jj,jk) - zfu_uw(ji,jj,jk+1) ) * r1_e1e2u(ji,jj)   &
155               &                                      / e3u(ji,jj,jk,Kmm)
156            pvv(ji,jj,jk,Krhs) = pvv(ji,jj,jk,Krhs) - ( zfv_vw(ji,jj,jk) - zfv_vw(ji,jj,jk+1) ) * r1_e1e2v(ji,jj)   &
157               &                                      / e3v(ji,jj,jk,Kmm)
158         END_3D
159         !
160         IF( l_trddyn ) THEN                 ! trends: send trend to trddyn for diagnostic
161            zfu_t(:,:,:) = puu(:,:,:,Krhs) - zfu_t(:,:,:)
162            zfv_t(:,:,:) = pvv(:,:,:,Krhs) - zfv_t(:,:,:)
163            CALL trd_dyn( zfu_t, zfv_t, jpdyn_zad, kt, Kmm )
164         ENDIF
165         !                                   ! Control print
166         IF(sn_cfctl%l_prtctl)   CALL prt_ctl( tab3d_1=puu(:,:,:,Krhs), clinfo1=' cen2 adv - Ua: ', mask1=umask,   &
167            &                                  tab3d_2=pvv(:,:,:,Krhs), clinfo2=           ' Va: ', mask2=vmask, clinfo3='dyn' )
168         !
169      ENDIF
170      !
171   END SUBROUTINE dyn_adv_cen2
172
173   !!==============================================================================
174END MODULE dynadv_cen2
Note: See TracBrowser for help on using the repository browser.