| 1 | MODULE trcdmp |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE trcdmp *** |
|---|
| 4 | !! Ocean physics: internal restoring trend on passive tracers |
|---|
| 5 | !!====================================================================== |
|---|
| 6 | !! History : OPA ! 1991-03 (O. Marti, G. Madec) Original code |
|---|
| 7 | !! ! 1996-01 (G. Madec) statement function for e3 |
|---|
| 8 | !! ! 1997-05 (H. Loukos) adapted for passive tracers |
|---|
| 9 | !! NEMO 9.0 ! 2004-03 (C. Ethe) free form + modules |
|---|
| 10 | !! 3.2 ! 2007-02 (C. Deltel) Diagnose ML trends for passive tracers |
|---|
| 11 | !! 3.3 ! 2010-06 (C. Ethe, G. Madec) merge TRA-TRC |
|---|
| 12 | !!---------------------------------------------------------------------- |
|---|
| 13 | #if defined key_top |
|---|
| 14 | !!---------------------------------------------------------------------- |
|---|
| 15 | !! trc_dmp : update the tracer trend with the internal damping |
|---|
| 16 | !! trc_dmp_init : initialization, namlist read, parameters control |
|---|
| 17 | !!---------------------------------------------------------------------- |
|---|
| 18 | USE oce_trc ! ocean dynamics and tracers variables |
|---|
| 19 | USE trc ! ocean passive tracers variables |
|---|
| 20 | USE trcdta |
|---|
| 21 | USE tradmp |
|---|
| 22 | USE prtctl_trc ! Print control for debbuging |
|---|
| 23 | USE trdtra |
|---|
| 24 | USE trd_oce |
|---|
| 25 | USE iom |
|---|
| 26 | |
|---|
| 27 | IMPLICIT NONE |
|---|
| 28 | PRIVATE |
|---|
| 29 | |
|---|
| 30 | PUBLIC trc_dmp |
|---|
| 31 | PUBLIC trc_dmp_clo |
|---|
| 32 | PUBLIC trc_dmp_alloc |
|---|
| 33 | PUBLIC trc_dmp_ini |
|---|
| 34 | |
|---|
| 35 | INTEGER , PUBLIC :: nn_zdmp_tr ! = 0/1/2 flag for damping in the mixed layer |
|---|
| 36 | CHARACTER(LEN=200) , PUBLIC :: cn_resto_tr !File containing restoration coefficient |
|---|
| 37 | |
|---|
| 38 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: restotr ! restoring coeff. on tracers (s-1) |
|---|
| 39 | |
|---|
| 40 | INTEGER, PARAMETER :: npncts = 8 ! number of closed sea |
|---|
| 41 | INTEGER, DIMENSION(npncts) :: nctsi1, nctsj1 ! south-west closed sea limits (i,j) |
|---|
| 42 | INTEGER, DIMENSION(npncts) :: nctsi2, nctsj2 ! north-east closed sea limits (i,j) |
|---|
| 43 | |
|---|
| 44 | !! * Substitutions |
|---|
| 45 | # include "vectopt_loop_substitute.h90" |
|---|
| 46 | !!---------------------------------------------------------------------- |
|---|
| 47 | !! NEMO/TOP 3.3 , NEMO Consortium (2010) |
|---|
| 48 | !! $Id$ |
|---|
| 49 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
|---|
| 50 | !!---------------------------------------------------------------------- |
|---|
| 51 | CONTAINS |
|---|
| 52 | |
|---|
| 53 | INTEGER FUNCTION trc_dmp_alloc() |
|---|
| 54 | !!---------------------------------------------------------------------- |
|---|
| 55 | !! *** ROUTINE trc_dmp_alloc *** |
|---|
| 56 | !!---------------------------------------------------------------------- |
|---|
| 57 | ALLOCATE( restotr(jpi,jpj,jpk) , STAT=trc_dmp_alloc ) |
|---|
| 58 | ! |
|---|
| 59 | IF( trc_dmp_alloc /= 0 ) CALL ctl_warn('trc_dmp_alloc: failed to allocate array') |
|---|
| 60 | ! |
|---|
| 61 | END FUNCTION trc_dmp_alloc |
|---|
| 62 | |
|---|
| 63 | |
|---|
| 64 | SUBROUTINE trc_dmp( kt ) |
|---|
| 65 | !!---------------------------------------------------------------------- |
|---|
| 66 | !! *** ROUTINE trc_dmp *** |
|---|
| 67 | !! |
|---|
| 68 | !! ** Purpose : Compute the passive tracer trend due to a newtonian damping |
|---|
| 69 | !! of the tracer field towards given data field and add it to the |
|---|
| 70 | !! general tracer trends. |
|---|
| 71 | !! |
|---|
| 72 | !! ** Method : Newtonian damping towards trdta computed |
|---|
| 73 | !! and add to the general tracer trends: |
|---|
| 74 | !! trn = tra + restotr * (trdta - trb) |
|---|
| 75 | !! The trend is computed either throughout the water column |
|---|
| 76 | !! (nlmdmptr=0) or in area of weak vertical mixing (nlmdmptr=1) or |
|---|
| 77 | !! below the well mixed layer (nlmdmptr=2) |
|---|
| 78 | !! |
|---|
| 79 | !! ** Action : - update the tracer trends tra with the newtonian |
|---|
| 80 | !! damping trends. |
|---|
| 81 | !! - save the trends ('key_trdmxl_trc') |
|---|
| 82 | !!---------------------------------------------------------------------- |
|---|
| 83 | INTEGER, INTENT(in) :: kt ! ocean time-step index |
|---|
| 84 | ! |
|---|
| 85 | INTEGER :: ji, jj, jk, jn, jl ! dummy loop indices |
|---|
| 86 | CHARACTER (len=22) :: charout |
|---|
| 87 | REAL(wp), POINTER, DIMENSION(:,:,:) :: ztrtrd |
|---|
| 88 | REAL(wp), POINTER, DIMENSION(:,:,:) :: ztrcdta ! 3D workspace |
|---|
| 89 | !!---------------------------------------------------------------------- |
|---|
| 90 | ! |
|---|
| 91 | IF( nn_timing == 1 ) CALL timing_start('trc_dmp') |
|---|
| 92 | ! |
|---|
| 93 | IF( l_trdtrc ) CALL wrk_alloc( jpi, jpj, jpk, ztrtrd ) ! temporary save of trends |
|---|
| 94 | ! |
|---|
| 95 | IF( nb_trcdta > 0 ) THEN ! Initialisation of tracer from a file that may also be used for damping |
|---|
| 96 | ! |
|---|
| 97 | CALL wrk_alloc( jpi, jpj, jpk, ztrcdta ) ! Memory allocation |
|---|
| 98 | ! ! =========== |
|---|
| 99 | DO jn = 1, jptra ! tracer loop |
|---|
| 100 | ! ! =========== |
|---|
| 101 | IF( l_trdtrc ) ztrtrd(:,:,:) = tra(:,:,:,jn) ! save trends |
|---|
| 102 | CALL trc_dta( kt, ztrcdta ) ! read tracer data at nit000 |
|---|
| 103 | ! |
|---|
| 104 | IF( ln_trc_ini(jn) ) THEN ! update passive tracers arrays with input data read from file |
|---|
| 105 | ! |
|---|
| 106 | jl = n_trc_index(jn) |
|---|
| 107 | ! |
|---|
| 108 | SELECT CASE ( nn_zdmp_tr ) |
|---|
| 109 | ! |
|---|
| 110 | CASE( 0 ) !== newtonian damping throughout the water column ==! |
|---|
| 111 | DO jk = 1, jpkm1 |
|---|
| 112 | DO jj = 2, jpjm1 |
|---|
| 113 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 114 | tra(ji,jj,jk,jn) = tra(ji,jj,jk,jn) + restotr(ji,jj,jk) * ( ztrcdta(ji,jj,jk) * rf_trfac(jl) - trb(ji,jj,jk,jn) ) |
|---|
| 115 | END DO |
|---|
| 116 | END DO |
|---|
| 117 | END DO |
|---|
| 118 | ! |
|---|
| 119 | CASE ( 1 ) !== no damping in the turbocline (avt > 5 cm2/s) ==! |
|---|
| 120 | DO jk = 1, jpkm1 |
|---|
| 121 | DO jj = 2, jpjm1 |
|---|
| 122 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 123 | IF( avt(ji,jj,jk) <= 5.e-4_wp ) THEN |
|---|
| 124 | tra(ji,jj,jk,jn) = tra(ji,jj,jk,jn) + restotr(ji,jj,jk) * ( ztrcdta(ji,jj,jk) * rf_trfac(jl) - trb(ji,jj,jk,jn) ) |
|---|
| 125 | ENDIF |
|---|
| 126 | END DO |
|---|
| 127 | END DO |
|---|
| 128 | END DO |
|---|
| 129 | ! |
|---|
| 130 | CASE ( 2 ) !== no damping in the mixed layer ==! |
|---|
| 131 | DO jk = 1, jpkm1 |
|---|
| 132 | DO jj = 2, jpjm1 |
|---|
| 133 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 134 | IF( gdept_n(ji,jj,jk) >= hmlp (ji,jj) ) THEN |
|---|
| 135 | tra(ji,jj,jk,jn) = tra(ji,jj,jk,jn) + restotr(ji,jj,jk) * ( ztrcdta(ji,jj,jk) * rf_trfac(jl) - trb(ji,jj,jk,jn) ) |
|---|
| 136 | END IF |
|---|
| 137 | END DO |
|---|
| 138 | END DO |
|---|
| 139 | END DO |
|---|
| 140 | ! |
|---|
| 141 | END SELECT |
|---|
| 142 | ! |
|---|
| 143 | ENDIF |
|---|
| 144 | ! |
|---|
| 145 | IF( l_trdtrc ) THEN |
|---|
| 146 | ztrtrd(:,:,:) = tra(:,:,:,jn) - ztrtrd(:,:,:) |
|---|
| 147 | CALL trd_tra( kt, 'TRC', jn, jptra_dmp, ztrtrd ) |
|---|
| 148 | END IF |
|---|
| 149 | ! ! =========== |
|---|
| 150 | END DO ! tracer loop |
|---|
| 151 | ! ! =========== |
|---|
| 152 | CALL wrk_dealloc( jpi, jpj, jpk, ztrcdta ) |
|---|
| 153 | ENDIF |
|---|
| 154 | ! |
|---|
| 155 | IF( l_trdtrc ) CALL wrk_dealloc( jpi, jpj, jpk, ztrtrd ) |
|---|
| 156 | ! ! print mean trends (used for debugging) |
|---|
| 157 | IF( ln_ctl ) THEN |
|---|
| 158 | WRITE(charout, FMT="('dmp ')") |
|---|
| 159 | CALL prt_ctl_trc_info(charout) |
|---|
| 160 | CALL prt_ctl_trc( tab4d=tra, mask=tmask, clinfo=ctrcnm, clinfo2='trd' ) |
|---|
| 161 | ENDIF |
|---|
| 162 | ! |
|---|
| 163 | IF( nn_timing == 1 ) CALL timing_stop('trc_dmp') |
|---|
| 164 | ! |
|---|
| 165 | END SUBROUTINE trc_dmp |
|---|
| 166 | |
|---|
| 167 | |
|---|
| 168 | SUBROUTINE trc_dmp_ini |
|---|
| 169 | !!---------------------------------------------------------------------- |
|---|
| 170 | !! *** ROUTINE trc_dmp_ini *** |
|---|
| 171 | !! |
|---|
| 172 | !! ** Purpose : Initialization for the newtonian damping |
|---|
| 173 | !! |
|---|
| 174 | !! ** Method : read the nammbf namelist and check the parameters |
|---|
| 175 | !! called by trc_dmp at the first timestep (nittrc000) |
|---|
| 176 | !!---------------------------------------------------------------------- |
|---|
| 177 | INTEGER :: ios, imask ! local integers |
|---|
| 178 | !! |
|---|
| 179 | NAMELIST/namtrc_dmp/ nn_zdmp_tr , cn_resto_tr |
|---|
| 180 | !!---------------------------------------------------------------------- |
|---|
| 181 | ! |
|---|
| 182 | IF( nn_timing == 1 ) CALL timing_start('trc_dmp_init') |
|---|
| 183 | ! |
|---|
| 184 | REWIND( numnat_ref ) ! Namelist namtrc_dmp in reference namelist : Passive tracers newtonian damping |
|---|
| 185 | READ ( numnat_ref, namtrc_dmp, IOSTAT = ios, ERR = 909) |
|---|
| 186 | 909 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namtrc_dmp in reference namelist', lwp ) |
|---|
| 187 | |
|---|
| 188 | REWIND( numnat_cfg ) ! Namelist namtrc_dmp in configuration namelist : Passive tracers newtonian damping |
|---|
| 189 | READ ( numnat_cfg, namtrc_dmp, IOSTAT = ios, ERR = 910) |
|---|
| 190 | 910 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namtrc_dmp in configuration namelist', lwp ) |
|---|
| 191 | IF(lwm) WRITE ( numont, namtrc_dmp ) |
|---|
| 192 | |
|---|
| 193 | IF(lwp) THEN ! Namelist print |
|---|
| 194 | WRITE(numout,*) |
|---|
| 195 | WRITE(numout,*) 'trc_dmp : Passive tracers newtonian damping' |
|---|
| 196 | WRITE(numout,*) '~~~~~~~' |
|---|
| 197 | WRITE(numout,*) ' Namelist namtrc_dmp : set damping parameter' |
|---|
| 198 | WRITE(numout,*) ' mixed layer damping option nn_zdmp_tr = ', nn_zdmp_tr, '(zoom: forced to 0)' |
|---|
| 199 | WRITE(numout,*) ' Restoration coeff file cn_resto_tr = ', cn_resto_tr |
|---|
| 200 | ENDIF |
|---|
| 201 | ! |
|---|
| 202 | IF( lzoom .AND. .NOT.lk_c1d ) nn_zdmp_tr = 0 ! restoring to climatology at closed north or south boundaries |
|---|
| 203 | SELECT CASE ( nn_zdmp_tr ) |
|---|
| 204 | CASE ( 0 ) ; IF(lwp) WRITE(numout,*) ' tracer damping throughout the water column' |
|---|
| 205 | CASE ( 1 ) ; IF(lwp) WRITE(numout,*) ' no tracer damping in the turbocline (avt > 5 cm2/s)' |
|---|
| 206 | CASE ( 2 ) ; IF(lwp) WRITE(numout,*) ' no tracer damping in the mixed layer' |
|---|
| 207 | CASE DEFAULT |
|---|
| 208 | WRITE(ctmp1,*) 'bad flag value for nn_zdmp_tr = ', nn_zdmp_tr |
|---|
| 209 | CALL ctl_stop(ctmp1) |
|---|
| 210 | END SELECT |
|---|
| 211 | |
|---|
| 212 | IF( .NOT.lk_c1d ) THEN |
|---|
| 213 | IF( .NOT. ln_tradmp ) & |
|---|
| 214 | & CALL ctl_stop( 'passive trace damping need ln_tradmp to compute damping coef.' ) |
|---|
| 215 | ! |
|---|
| 216 | ! ! Read damping coefficients from file |
|---|
| 217 | !Read in mask from file |
|---|
| 218 | CALL iom_open ( cn_resto_tr, imask) |
|---|
| 219 | CALL iom_get ( imask, jpdom_autoglo, 'resto', restotr) |
|---|
| 220 | CALL iom_close( imask ) |
|---|
| 221 | ! |
|---|
| 222 | ENDIF |
|---|
| 223 | IF( nn_timing == 1 ) CALL timing_stop('trc_dmp_init') |
|---|
| 224 | ! |
|---|
| 225 | END SUBROUTINE trc_dmp_ini |
|---|
| 226 | |
|---|
| 227 | |
|---|
| 228 | SUBROUTINE trc_dmp_clo( kt ) |
|---|
| 229 | !!--------------------------------------------------------------------- |
|---|
| 230 | !! *** ROUTINE trc_dmp_clo *** |
|---|
| 231 | !! |
|---|
| 232 | !! ** Purpose : Closed sea domain initialization |
|---|
| 233 | !! |
|---|
| 234 | !! ** Method : if a closed sea is located only in a model grid point |
|---|
| 235 | !! we restore to initial data |
|---|
| 236 | !! |
|---|
| 237 | !! ** Action : nctsi1(), nctsj1() : south-west closed sea limits (i,j) |
|---|
| 238 | !! nctsi2(), nctsj2() : north-east Closed sea limits (i,j) |
|---|
| 239 | !!---------------------------------------------------------------------- |
|---|
| 240 | INTEGER, INTENT( in ) :: kt ! ocean time-step index |
|---|
| 241 | ! |
|---|
| 242 | INTEGER :: ji , jj, jk, jn, jl, jc ! dummy loop indicesa |
|---|
| 243 | INTEGER :: isrow ! local index |
|---|
| 244 | REAL(wp), POINTER, DIMENSION(:,:,:,:) :: ztrcdta ! 3D workspace |
|---|
| 245 | |
|---|
| 246 | !!---------------------------------------------------------------------- |
|---|
| 247 | |
|---|
| 248 | IF( kt == nit000 ) THEN |
|---|
| 249 | ! initial values |
|---|
| 250 | nctsi1(:) = 1 ; nctsi2(:) = 1 |
|---|
| 251 | nctsj1(:) = 1 ; nctsj2(:) = 1 |
|---|
| 252 | |
|---|
| 253 | ! set the closed seas (in data domain indices) |
|---|
| 254 | ! ------------------- |
|---|
| 255 | |
|---|
| 256 | IF( cp_cfg == "orca" ) THEN |
|---|
| 257 | ! |
|---|
| 258 | SELECT CASE ( jp_cfg ) |
|---|
| 259 | ! ! ======================= |
|---|
| 260 | CASE ( 1 ) ! eORCA_R1 configuration |
|---|
| 261 | ! ! ======================= |
|---|
| 262 | isrow = 332 - jpjglo |
|---|
| 263 | ! |
|---|
| 264 | ! Caspian Sea |
|---|
| 265 | nctsi1(1) = 333 ; nctsj1(1) = 243 - isrow |
|---|
| 266 | nctsi2(1) = 342 ; nctsj2(1) = 274 - isrow |
|---|
| 267 | ! ! Lake Superior |
|---|
| 268 | nctsi1(2) = 198 ; nctsj1(2) = 258 - isrow |
|---|
| 269 | nctsi2(2) = 204 ; nctsj2(2) = 262 - isrow |
|---|
| 270 | ! ! Lake Michigan |
|---|
| 271 | nctsi1(3) = 201 ; nctsj1(3) = 250 - isrow |
|---|
| 272 | nctsi2(3) = 203 ; nctsj2(3) = 256 - isrow |
|---|
| 273 | ! ! Lake Huron |
|---|
| 274 | nctsi1(4) = 204 ; nctsj1(4) = 252 - isrow |
|---|
| 275 | nctsi2(4) = 209 ; nctsj2(4) = 256 - isrow |
|---|
| 276 | ! ! Lake Erie |
|---|
| 277 | nctsi1(5) = 206 ; nctsj1(5) = 249 - isrow |
|---|
| 278 | nctsi2(5) = 209 ; nctsj2(5) = 251 - isrow |
|---|
| 279 | ! ! Lake Ontario |
|---|
| 280 | nctsi1(6) = 210 ; nctsj1(6) = 252 - isrow |
|---|
| 281 | nctsi2(6) = 212 ; nctsj2(6) = 252 - isrow |
|---|
| 282 | ! ! Victoria Lake |
|---|
| 283 | nctsi1(7) = 321 ; nctsj1(7) = 180 - isrow |
|---|
| 284 | nctsi2(7) = 322 ; nctsj2(7) = 189 - isrow |
|---|
| 285 | ! ! Baltic Sea |
|---|
| 286 | nctsi1(8) = 297 ; nctsj1(8) = 270 - isrow |
|---|
| 287 | nctsi2(8) = 308 ; nctsj2(8) = 293 - isrow |
|---|
| 288 | |
|---|
| 289 | ! ! ======================= |
|---|
| 290 | CASE ( 2 ) ! ORCA_R2 configuration |
|---|
| 291 | ! ! ======================= |
|---|
| 292 | ! ! Caspian Sea |
|---|
| 293 | nctsi1(1) = 11 ; nctsj1(1) = 103 |
|---|
| 294 | nctsi2(1) = 17 ; nctsj2(1) = 112 |
|---|
| 295 | ! ! Great North American Lakes |
|---|
| 296 | nctsi1(2) = 97 ; nctsj1(2) = 107 |
|---|
| 297 | nctsi2(2) = 103 ; nctsj2(2) = 111 |
|---|
| 298 | ! ! Black Sea 1 : west part of the Black Sea |
|---|
| 299 | nctsi1(3) = 174 ; nctsj1(3) = 107 |
|---|
| 300 | nctsi2(3) = 181 ; nctsj2(3) = 112 |
|---|
| 301 | ! ! Black Sea 2 : est part of the Black Sea |
|---|
| 302 | nctsi1(4) = 2 ; nctsj1(4) = 107 |
|---|
| 303 | nctsi2(4) = 6 ; nctsj2(4) = 112 |
|---|
| 304 | ! ! Baltic Sea |
|---|
| 305 | nctsi1(5) = 145 ; nctsj1(5) = 116 |
|---|
| 306 | nctsi2(5) = 150 ; nctsj2(5) = 126 |
|---|
| 307 | ! ! ======================= |
|---|
| 308 | CASE ( 4 ) ! ORCA_R4 configuration |
|---|
| 309 | ! ! ======================= |
|---|
| 310 | ! ! Caspian Sea |
|---|
| 311 | nctsi1(1) = 4 ; nctsj1(1) = 53 |
|---|
| 312 | nctsi2(1) = 4 ; nctsj2(1) = 56 |
|---|
| 313 | ! ! Great North American Lakes |
|---|
| 314 | nctsi1(2) = 49 ; nctsj1(2) = 55 |
|---|
| 315 | nctsi2(2) = 51 ; nctsj2(2) = 56 |
|---|
| 316 | ! ! Black Sea |
|---|
| 317 | nctsi1(3) = 88 ; nctsj1(3) = 55 |
|---|
| 318 | nctsi2(3) = 91 ; nctsj2(3) = 56 |
|---|
| 319 | ! ! Baltic Sea |
|---|
| 320 | nctsi1(4) = 75 ; nctsj1(4) = 59 |
|---|
| 321 | nctsi2(4) = 76 ; nctsj2(4) = 61 |
|---|
| 322 | ! ! ======================= |
|---|
| 323 | CASE ( 025 ) ! ORCA_R025 configuration |
|---|
| 324 | ! ! ======================= |
|---|
| 325 | ! Caspian + Aral sea |
|---|
| 326 | nctsi1(1) = 1330 ; nctsj1(1) = 645 |
|---|
| 327 | nctsi2(1) = 1400 ; nctsj2(1) = 795 |
|---|
| 328 | ! ! Azov Sea |
|---|
| 329 | nctsi1(2) = 1284 ; nctsj1(2) = 722 |
|---|
| 330 | nctsi2(2) = 1304 ; nctsj2(2) = 747 |
|---|
| 331 | ! |
|---|
| 332 | END SELECT |
|---|
| 333 | ! |
|---|
| 334 | ENDIF |
|---|
| 335 | ! |
|---|
| 336 | |
|---|
| 337 | ! convert the position in local domain indices |
|---|
| 338 | ! -------------------------------------------- |
|---|
| 339 | DO jc = 1, npncts |
|---|
| 340 | nctsi1(jc) = mi0( nctsi1(jc) ) |
|---|
| 341 | nctsj1(jc) = mj0( nctsj1(jc) ) |
|---|
| 342 | |
|---|
| 343 | nctsi2(jc) = mi1( nctsi2(jc) ) |
|---|
| 344 | nctsj2(jc) = mj1( nctsj2(jc) ) |
|---|
| 345 | END DO |
|---|
| 346 | ! |
|---|
| 347 | ENDIF |
|---|
| 348 | |
|---|
| 349 | ! Restore close seas values to initial data |
|---|
| 350 | IF( ln_trcdta .AND. nb_trcdta > 0 ) THEN ! Initialisation of tracer from a file that may also be used for damping |
|---|
| 351 | ! |
|---|
| 352 | IF(lwp) WRITE(numout,*) |
|---|
| 353 | IF(lwp) WRITE(numout,*) ' trc_dmp_clo : Restoring of nutrients on close seas at time-step kt = ', kt |
|---|
| 354 | IF(lwp) WRITE(numout,*) |
|---|
| 355 | ! |
|---|
| 356 | CALL wrk_alloc( jpi, jpj, jpk, nb_trcdta, ztrcdta ) ! Memory allocation |
|---|
| 357 | CALL trc_dta( kt, ztrcdta ) ! read tracer data at nit000 |
|---|
| 358 | ! |
|---|
| 359 | DO jn = 1, jptra |
|---|
| 360 | IF( ln_trc_ini(jn) ) THEN ! update passive tracers arrays with input data read from file |
|---|
| 361 | jl = n_trc_index(jn) |
|---|
| 362 | IF(lwp) WRITE(numout,*) |
|---|
| 363 | DO jc = 1, npncts |
|---|
| 364 | DO jk = 1, jpkm1 |
|---|
| 365 | DO jj = nctsj1(jc), nctsj2(jc) |
|---|
| 366 | DO ji = nctsi1(jc), nctsi2(jc) |
|---|
| 367 | trn(ji,jj,jk,jn) = ztrcdta(ji,jj,jk,jl) * rf_trfac(jl) |
|---|
| 368 | trb(ji,jj,jk,jn) = trn(ji,jj,jk,jn) |
|---|
| 369 | ENDDO |
|---|
| 370 | ENDDO |
|---|
| 371 | ENDDO |
|---|
| 372 | ENDDO |
|---|
| 373 | ENDIF |
|---|
| 374 | ENDDO |
|---|
| 375 | CALL wrk_dealloc( jpi, jpj, jpk, nb_trcdta, ztrcdta ) ! Memory allocation |
|---|
| 376 | ! |
|---|
| 377 | ENDIF |
|---|
| 378 | ! |
|---|
| 379 | END SUBROUTINE trc_dmp_clo |
|---|
| 380 | |
|---|
| 381 | |
|---|
| 382 | #else |
|---|
| 383 | !!---------------------------------------------------------------------- |
|---|
| 384 | !! Dummy module : No passive tracer |
|---|
| 385 | !!---------------------------------------------------------------------- |
|---|
| 386 | CONTAINS |
|---|
| 387 | SUBROUTINE trc_dmp( kt ) ! Empty routine |
|---|
| 388 | INTEGER, INTENT(in) :: kt |
|---|
| 389 | WRITE(*,*) 'trc_dmp: You should not have seen this print! error?', kt |
|---|
| 390 | END SUBROUTINE trc_dmp |
|---|
| 391 | #endif |
|---|
| 392 | |
|---|
| 393 | !!====================================================================== |
|---|
| 394 | END MODULE trcdmp |
|---|
