New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zmort.F90 in trunk/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z – NEMO

source: trunk/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z/p4zmort.F90 @ 7698

Last change on this file since 7698 was 7698, checked in by mocavero, 7 years ago

update trunk with OpenMP parallelization
  • Property svn:keywords set to Id
File size: 11.9 KB
Line 
1MODULE p4zmort
2   !!======================================================================
3   !!                         ***  MODULE p4zmort  ***
4   !! TOP :   PISCES Compute the mortality terms for phytoplankton
5   !!======================================================================
6   !! History :   1.0  !  2002     (O. Aumont)  Original code
7   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8   !!----------------------------------------------------------------------
9   !!   p4z_mort       :   Compute the mortality terms for phytoplankton
10   !!   p4z_mort_init  :   Initialize the mortality params for phytoplankton
11   !!----------------------------------------------------------------------
12   USE oce_trc         !  shared variables between ocean and passive tracers
13   USE trc             !  passive tracers common variables
14   USE sms_pisces      !  PISCES Source Minus Sink variables
15   USE p4zprod         !  Primary productivity
16   USE p4zlim          !  Phytoplankton limitation terms
17   USE prtctl_trc      !  print control for debugging
18
19   IMPLICIT NONE
20   PRIVATE
21
22   PUBLIC   p4z_mort   
23   PUBLIC   p4z_mort_init   
24
25   !! * Shared module variables
26   REAL(wp), PUBLIC :: wchl    !:
27   REAL(wp), PUBLIC :: wchld   !:
28   REAL(wp), PUBLIC :: wchldm  !:
29   REAL(wp), PUBLIC :: mprat   !:
30   REAL(wp), PUBLIC :: mprat2  !:
31
32   !!----------------------------------------------------------------------
33   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
34   !! $Id$
35   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
36   !!----------------------------------------------------------------------
37
38CONTAINS
39
40   SUBROUTINE p4z_mort( kt )
41      !!---------------------------------------------------------------------
42      !!                     ***  ROUTINE p4z_mort  ***
43      !!
44      !! ** Purpose :   Calls the different subroutine to initialize and compute
45      !!                the different phytoplankton mortality terms
46      !!
47      !! ** Method  : - ???
48      !!---------------------------------------------------------------------
49      INTEGER, INTENT(in) ::   kt ! ocean time step
50      !!---------------------------------------------------------------------
51
52      CALL p4z_nano            ! nanophytoplankton
53
54      CALL p4z_diat            ! diatoms
55
56   END SUBROUTINE p4z_mort
57
58
59   SUBROUTINE p4z_nano
60      !!---------------------------------------------------------------------
61      !!                     ***  ROUTINE p4z_nano  ***
62      !!
63      !! ** Purpose :   Compute the mortality terms for nanophytoplankton
64      !!
65      !! ** Method  : - ???
66      !!---------------------------------------------------------------------
67      INTEGER  :: ji, jj, jk
68      REAL(wp) :: zsizerat, zcompaph
69      REAL(wp) :: zfactfe, zfactch, zprcaca, zfracal
70      REAL(wp) :: ztortp , zrespp , zmortp 
71      CHARACTER (len=25) :: charout
72      !!---------------------------------------------------------------------
73      !
74      IF( nn_timing == 1 )  CALL timing_start('p4z_nano')
75      !
76!$OMP PARALLEL
77!$OMP DO schedule(static) private(jk,jj,ji)
78      DO jk = 1, jpk
79         DO jj = 1, jpj
80            DO ji = 1, jpi
81               prodcal(ji,jj,jk) = 0.  !: calcite production variable set to zero
82            END DO
83         END DO
84      END DO
85!$OMP DO schedule(static) private(jk,jj,ji,zcompaph,zsizerat,zrespp,ztortp,zmortp,zfactfe,zfactch,zprcaca,zfracal)
86      DO jk = 1, jpkm1
87         DO jj = 1, jpj
88            DO ji = 1, jpi
89               zcompaph = MAX( ( trb(ji,jj,jk,jpphy) - 1e-8 ), 0.e0 )
90               !     When highly limited by macronutrients, very small cells
91               !     dominate the community. As a consequence, aggregation
92               !     due to turbulence is negligible. Mortality is also set
93               !     to 0
94               zsizerat = MIN(1., MAX( 0., (quotan(ji,jj,jk) - 0.2) / 0.3) ) * trb(ji,jj,jk,jpphy)
95               !     Squared mortality of Phyto similar to a sedimentation term during
96               !     blooms (Doney et al. 1996)
97               zrespp = wchl * 1.e6 * xstep * xdiss(ji,jj,jk) * zcompaph * zsizerat 
98
99               !     Phytoplankton mortality. This mortality loss is slightly
100               !     increased when nutrients are limiting phytoplankton growth
101               !     as observed for instance in case of iron limitation.
102               ztortp = mprat * xstep * zcompaph / ( xkmort + trb(ji,jj,jk,jpphy) ) * zsizerat
103
104               zmortp = zrespp + ztortp
105
106               !   Update the arrays TRA which contains the biological sources and sinks
107
108               zfactfe = trb(ji,jj,jk,jpnfe)/(trb(ji,jj,jk,jpphy)+rtrn)
109               zfactch = trb(ji,jj,jk,jpnch)/(trb(ji,jj,jk,jpphy)+rtrn)
110               tra(ji,jj,jk,jpphy) = tra(ji,jj,jk,jpphy) - zmortp
111               tra(ji,jj,jk,jpnch) = tra(ji,jj,jk,jpnch) - zmortp * zfactch
112               tra(ji,jj,jk,jpnfe) = tra(ji,jj,jk,jpnfe) - zmortp * zfactfe
113               zprcaca = xfracal(ji,jj,jk) * zmortp
114               !
115               prodcal(ji,jj,jk) = prodcal(ji,jj,jk) + zprcaca  ! prodcal=prodcal(nanophy)+prodcal(microzoo)+prodcal(mesozoo)
116               !
117               zfracal = 0.5 * xfracal(ji,jj,jk)
118               tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) - zprcaca
119               tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) - 2. * zprcaca
120               tra(ji,jj,jk,jpcal) = tra(ji,jj,jk,jpcal) + zprcaca
121               tra(ji,jj,jk,jpgoc) = tra(ji,jj,jk,jpgoc) + zfracal * zmortp
122               tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) + ( 1. - zfracal ) * zmortp
123               prodpoc(ji,jj,jk) = prodpoc(ji,jj,jk) + ( 1. - zfracal ) * zmortp
124               prodgoc(ji,jj,jk) = prodgoc(ji,jj,jk) + zfracal * zmortp
125               tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) + ( 1. - zfracal ) * zmortp * zfactfe
126               tra(ji,jj,jk,jpbfe) = tra(ji,jj,jk,jpbfe) + zfracal * zmortp * zfactfe
127            END DO
128         END DO
129      END DO
130!$OMP END PARALLEL
131      !
132       IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
133         WRITE(charout, FMT="('nano')")
134         CALL prt_ctl_trc_info(charout)
135         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
136       ENDIF
137      !
138      IF( nn_timing == 1 )  CALL timing_stop('p4z_nano')
139      !
140   END SUBROUTINE p4z_nano
141
142   SUBROUTINE p4z_diat
143      !!---------------------------------------------------------------------
144      !!                     ***  ROUTINE p4z_diat  ***
145      !!
146      !! ** Purpose :   Compute the mortality terms for diatoms
147      !!
148      !! ** Method  : - ???
149      !!---------------------------------------------------------------------
150      INTEGER  ::  ji, jj, jk
151      REAL(wp) ::  zfactfe,zfactsi,zfactch, zcompadi
152      REAL(wp) ::  zrespp2, ztortp2, zmortp2
153      REAL(wp) ::  zlim2, zlim1
154      CHARACTER (len=25) :: charout
155      !!---------------------------------------------------------------------
156      !
157      IF( nn_timing == 1 )  CALL timing_start('p4z_diat')
158      !
159
160      !    Aggregation term for diatoms is increased in case of nutrient
161      !    stress as observed in reality. The stressed cells become more
162      !    sticky and coagulate to sink quickly out of the euphotic zone
163      !     ------------------------------------------------------------
164
165!$OMP PARALLEL DO schedule(static) private(jk,jj,ji,zcompadi,zlim2,zlim1,zrespp2,ztortp2,zmortp2,zfactfe,zfactch,zfactsi)
166      DO jk = 1, jpkm1
167         DO jj = 1, jpj
168            DO ji = 1, jpi
169
170               zcompadi = MAX( ( trb(ji,jj,jk,jpdia) - 1e-9), 0. )
171
172               !    Aggregation term for diatoms is increased in case of nutrient
173               !    stress as observed in reality. The stressed cells become more
174               !    sticky and coagulate to sink quickly out of the euphotic zone
175               !     ------------------------------------------------------------
176               !  Phytoplankton respiration
177               !     ------------------------
178               zlim2   = xlimdia(ji,jj,jk) * xlimdia(ji,jj,jk)
179               zlim1   = 0.25 * ( 1. - zlim2 ) / ( 0.25 + zlim2 ) 
180               zrespp2 = 1.e6 * xstep * (  wchld + wchldm * zlim1 ) * xdiss(ji,jj,jk) * zcompadi * trb(ji,jj,jk,jpdia)
181
182               !     Phytoplankton mortality.
183               !     ------------------------
184               ztortp2 = mprat2 * xstep * trb(ji,jj,jk,jpdia)  / ( xkmort + trb(ji,jj,jk,jpdia) ) * zcompadi 
185
186               zmortp2 = zrespp2 + ztortp2
187
188               !   Update the arrays tra which contains the biological sources and sinks
189               !   ---------------------------------------------------------------------
190               zfactch = trb(ji,jj,jk,jpdch) / ( trb(ji,jj,jk,jpdia) + rtrn )
191               zfactfe = trb(ji,jj,jk,jpdfe) / ( trb(ji,jj,jk,jpdia) + rtrn )
192               zfactsi = trb(ji,jj,jk,jpdsi) / ( trb(ji,jj,jk,jpdia) + rtrn )
193               tra(ji,jj,jk,jpdia) = tra(ji,jj,jk,jpdia) - zmortp2 
194               tra(ji,jj,jk,jpdch) = tra(ji,jj,jk,jpdch) - zmortp2 * zfactch
195               tra(ji,jj,jk,jpdfe) = tra(ji,jj,jk,jpdfe) - zmortp2 * zfactfe
196               tra(ji,jj,jk,jpdsi) = tra(ji,jj,jk,jpdsi) - zmortp2 * zfactsi
197               tra(ji,jj,jk,jpgsi) = tra(ji,jj,jk,jpgsi) + zmortp2 * zfactsi
198               tra(ji,jj,jk,jpgoc) = tra(ji,jj,jk,jpgoc) + zrespp2 + 0.5 * ztortp2
199               tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) + 0.5 * ztortp2
200               prodpoc(ji,jj,jk) = prodpoc(ji,jj,jk) + 0.5 * ztortp2
201               prodgoc(ji,jj,jk) = prodgoc(ji,jj,jk) + zrespp2 + 0.5 * ztortp2
202               tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) + 0.5 * ztortp2 * zfactfe
203               tra(ji,jj,jk,jpbfe) = tra(ji,jj,jk,jpbfe) + ( zrespp2 + 0.5 * ztortp2 ) * zfactfe
204            END DO
205         END DO
206      END DO
207      !
208      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
209         WRITE(charout, FMT="('diat')")
210         CALL prt_ctl_trc_info(charout)
211         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
212      ENDIF
213      !
214      IF( nn_timing == 1 )  CALL timing_stop('p4z_diat')
215      !
216   END SUBROUTINE p4z_diat
217
218   SUBROUTINE p4z_mort_init
219
220      !!----------------------------------------------------------------------
221      !!                  ***  ROUTINE p4z_mort_init  ***
222      !!
223      !! ** Purpose :   Initialization of phytoplankton parameters
224      !!
225      !! ** Method  :   Read the nampismort namelist and check the parameters
226      !!      called at the first timestep
227      !!
228      !! ** input   :   Namelist nampismort
229      !!
230      !!----------------------------------------------------------------------
231
232      NAMELIST/namp4zmort/ wchl, wchld, wchldm, mprat, mprat2
233      INTEGER :: ios                 ! Local integer output status for namelist read
234
235      REWIND( numnatp_ref )              ! Namelist nampismort in reference namelist : Pisces phytoplankton
236      READ  ( numnatp_ref, namp4zmort, IOSTAT = ios, ERR = 901)
237901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namp4zmort in reference namelist', lwp )
238
239      REWIND( numnatp_cfg )              ! Namelist nampismort in configuration namelist : Pisces phytoplankton
240      READ  ( numnatp_cfg, namp4zmort, IOSTAT = ios, ERR = 902 )
241902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namp4zmort in configuration namelist', lwp )
242      IF(lwm) WRITE ( numonp, namp4zmort )
243
244      IF(lwp) THEN                         ! control print
245         WRITE(numout,*) ' '
246         WRITE(numout,*) ' Namelist parameters for phytoplankton mortality, namp4zmort'
247         WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
248         WRITE(numout,*) '    quadratic mortality of phytoplankton      wchl      =', wchl
249         WRITE(numout,*) '    maximum quadratic mortality of diatoms    wchld     =', wchld
250         WRITE(numout,*) '    maximum quadratic mortality of diatoms    wchldm    =', wchldm
251         WRITE(numout,*) '    phytoplankton mortality rate              mprat     =', mprat
252         WRITE(numout,*) '    Diatoms mortality rate                    mprat2    =', mprat2
253      ENDIF
254
255   END SUBROUTINE p4z_mort_init
256
257   !!======================================================================
258END MODULE p4zmort
Note: See TracBrowser for help on using the repository browser.