New URL for NEMO forge! http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.

sbcice_lim.F90 in trunk/NEMOGCM/NEMO/OPA_SRC/SBC – NEMO

Context Navigation

source: trunk/NEMOGCM/NEMO/OPA_SRC/SBC/sbcice_lim.F90 @ 6403

Last change on this file since 6403 was 6403, checked in by cetlod, 8 years ago
trunk:new developments already included in 3.6 stable, see points 1, 2 and 4 of ticket #1678
Property svn:keywords set to `Id`
File size: 32.1 KB

Line
1	MODULE sbcice_lim
2	!!======================================================================
3	!! * MODULE sbcice_lim *
4	!! Surface module : update the ocean surface boundary condition over ice
5	!! & covered area using LIM sea-ice model
6	!! Sea-Ice model : LIM-3 Sea ice model time-stepping
7	!!=====================================================================
8	!! History : 2.0 ! 2006-12 (M. Vancoppenolle) Original code
9	!! 3.0 ! 2008-02 (C. Talandier) Surface module from icestp.F90
10	!! - ! 2008-04 (G. Madec) sltyle and lim_ctl routine
11	!! 3.3 ! 2010-11 (G. Madec) ice-ocean stress always computed at each ocean time-step
12	!! 3.4 ! 2011-01 (A Porter) dynamical allocation
13	!! - ! 2012-10 (C. Rousset) add lim_diahsb
14	!! 3.6 ! 2014-07 (M. Vancoppenolle, G. Madec, O. Marti) revise coupled interface
15	!!----------------------------------------------------------------------
16	#if defined key_lim3
17	!!----------------------------------------------------------------------
18	!! 'key_lim3' : LIM 3.0 sea-ice model
19	!!----------------------------------------------------------------------
20	!! sbc_ice_lim : sea-ice model time-stepping and update ocean sbc over ice-covered area
21	!!----------------------------------------------------------------------
22	USE oce ! ocean dynamics and tracers
23	USE dom_oce ! ocean space and time domain
24	USE ice ! LIM-3: ice variables
25	USE thd_ice ! LIM-3: thermodynamical variables
26	USE dom_ice ! LIM-3: ice domain
27	!
28	USE sbc_oce ! Surface boundary condition: ocean fields
29	USE sbc_ice ! Surface boundary condition: ice fields
30	USE sbcblk_core ! Surface boundary condition: CORE bulk
31	USE sbcblk_clio ! Surface boundary condition: CLIO bulk
32	USE sbccpl ! Surface boundary condition: coupled interface
33	USE albedo ! ocean & ice albedo
34	!
35	USE phycst ! Define parameters for the routines
36	USE eosbn2 ! equation of state
37	USE limdyn ! Ice dynamics
38	USE limtrp ! Ice transport
39	USE limhdf ! Ice horizontal diffusion
40	USE limthd ! Ice thermodynamics
41	USE limitd_me ! Mechanics on ice thickness distribution
42	USE limsbc ! sea surface boundary condition
43	USE limdiahsb ! Ice budget diagnostics
44	USE limwri ! Ice outputs
45	USE limrst ! Ice restarts
46	USE limupdate1 ! update of global variables
47	USE limupdate2 ! update of global variables
48	USE limvar ! Ice variables switch
49	USE limctl !
50	USE limmsh ! LIM mesh
51	USE limistate ! LIM initial state
52	USE limthd_sal ! LIM ice thermodynamics: salinity
53	!
54	USE c1d ! 1D vertical configuration
55	USE in_out_manager ! I/O manager
56	USE iom ! I/O manager library
57	USE prtctl ! Print control
58	USE lib_fortran !
59	USE lbclnk ! lateral boundary condition - MPP link
60	USE lib_mpp ! MPP library
61	USE wrk_nemo ! work arrays
62	USE timing ! Timing
63
64	#if defined key_bdy
65	USE bdyice_lim ! unstructured open boundary data (bdy_ice_lim routine)
66	#endif
67
68	IMPLICIT NONE
69	PRIVATE
70
71	PUBLIC sbc_ice_lim ! routine called by sbcmod.F90
72	PUBLIC sbc_lim_init ! routine called by sbcmod.F90
73
74	!! * Substitutions
75	# include "vectopt_loop_substitute.h90"
76	!!----------------------------------------------------------------------
77	!! NEMO/OPA 4.0 , UCL NEMO Consortium (2011)
78	!! $Id$
79	!! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
80	!!----------------------------------------------------------------------
81	CONTAINS
82
83	SUBROUTINE sbc_ice_lim( kt, kblk )
84	!!---------------------------------------------------------------------
85	!! * ROUTINE sbc_ice_lim *
86	!!
87	!! ** Purpose : update the ocean surface boundary condition via the
88	!! Louvain la Neuve Sea Ice Model time stepping
89	!!
90	!! ** Method : ice model time stepping
91	!! - call the ice dynamics routine
92	!! - call the ice advection/diffusion routine
93	!! - call the ice thermodynamics routine
94	!! - call the routine that computes mass and
95	!! heat fluxes at the ice/ocean interface
96	!! - save the outputs
97	!! - save the outputs for restart when necessary
98	!!
99	!! ** Action : - time evolution of the LIM sea-ice model
100	!! - update all sbc variables below sea-ice:
101	!! utau, vtau, taum, wndm, qns , qsr, emp , sfx
102	!!---------------------------------------------------------------------
103	INTEGER, INTENT(in) :: kt ! ocean time step
104	INTEGER, INTENT(in) :: kblk ! type of bulk (=3 CLIO, =4 CORE, =5 COUPLED)
105	!!
106	INTEGER :: jl ! dummy loop index
107	REAL(wp), POINTER, DIMENSION(:,:,:) :: zalb_os, zalb_cs ! ice albedo under overcast/clear sky
108	REAL(wp), POINTER, DIMENSION(:,:,:) :: zalb_ice ! mean ice albedo (for coupled)
109	REAL(wp), POINTER, DIMENSION(:,: ) :: zutau_ice, zvtau_ice
110	!!----------------------------------------------------------------------
111
112	IF( nn_timing == 1 ) CALL timing_start('sbc_ice_lim')
113
114	!-----------------------!
115	! --- Ice time step --- !
116	!-----------------------!
117	IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN
118
119	! mean surface ocean current at ice velocity point (C-grid dynamics : U- & V-points as the ocean)
120	u_oce(:,:) = ssu_m(:,:) * umask(:,:,1)
121	v_oce(:,:) = ssv_m(:,:) * vmask(:,:,1)
122
123	! masked sea surface freezing temperature [Kelvin] (set to rt0 over land)
124	CALL eos_fzp( sss_m(:,:) , t_bo(:,:) )
125	t_bo(:,:) = ( t_bo(:,:) + rt0 ) * tmask(:,:,1) + rt0 * ( 1._wp - tmask(:,:,1) )
126
127	! Mask sea ice surface temperature (set to rt0 over land)
128	DO jl = 1, jpl
129	t_su(:,:,jl) = t_su(:,:,jl) * tmask(:,:,1) + rt0 * ( 1._wp - tmask(:,:,1) )
130	END DO
131	!
132	!------------------------------------------------!
133	! --- Dynamical coupling with the atmosphere --- !
134	!------------------------------------------------!
135	! It provides the following fields:
136	! utau_ice, vtau_ice : surface ice stress (U- & V-points) [N/m2]
137	!-----------------------------------------------------------------
138	SELECT CASE( kblk )
139	CASE( jp_clio ) ; CALL blk_ice_clio_tau ! CLIO bulk formulation
140	CASE( jp_core ) ; CALL blk_ice_core_tau ! CORE bulk formulation
141	CASE( jp_purecpl ) ; CALL sbc_cpl_ice_tau( utau_ice , vtau_ice ) ! Coupled formulation
142	END SELECT
143
144	IF( ln_mixcpl) THEN ! Case of a mixed Bulk/Coupled formulation
145	CALL wrk_alloc( jpi,jpj , zutau_ice, zvtau_ice)
146	CALL sbc_cpl_ice_tau( zutau_ice , zvtau_ice )
147	utau_ice(:,:) = utau_ice(:,:) * xcplmask(:,:,0) + zutau_ice(:,:) * ( 1. - xcplmask(:,:,0) )
148	vtau_ice(:,:) = vtau_ice(:,:) * xcplmask(:,:,0) + zvtau_ice(:,:) * ( 1. - xcplmask(:,:,0) )
149	CALL wrk_dealloc( jpi,jpj , zutau_ice, zvtau_ice)
150	ENDIF
151
152	!-------------------------------------------------------!
153	! --- ice dynamics and transport (except in 1D case) ---!
154	!-------------------------------------------------------!
155	numit = numit + nn_fsbc ! Ice model time step
156	!
157	CALL sbc_lim_bef ! Store previous ice values
158	CALL sbc_lim_diag0 ! set diag of mass, heat and salt fluxes to 0
159	CALL lim_rst_opn( kt ) ! Open Ice restart file
160	!
161	IF( .NOT. lk_c1d ) THEN
162	!
163	CALL lim_dyn( kt ) ! Ice dynamics ( rheology/dynamics )
164	!
165	CALL lim_trp( kt ) ! Ice transport ( Advection/diffusion )
166	!
167	IF( nn_monocat /= 2 ) CALL lim_itd_me ! Mechanical redistribution ! (ridging/rafting)
168	!
169	#if defined key_bdy
170	CALL bdy_ice_lim( kt ) ! bdy ice thermo
171	IF( ln_icectl ) CALL lim_prt( kt, iiceprt, jiceprt, 1, ' - ice thermo bdy - ' )
172	#endif
173	!
174	CALL lim_update1( kt ) ! Corrections
175	!
176	ENDIF
177
178	! previous lead fraction and ice volume for flux calculations
179	CALL sbc_lim_bef
180	CALL lim_var_glo2eqv ! ht_i and ht_s for ice albedo calculation
181	CALL lim_var_agg(1) ! at_i for coupling (via pfrld)
182	pfrld(:,:) = 1._wp - at_i(:,:)
183	phicif(:,:) = vt_i(:,:)
184
185	!------------------------------------------------------!
186	! --- Thermodynamical coupling with the atmosphere --- !
187	!------------------------------------------------------!
188	! It provides the following fields:
189	! qsr_ice , qns_ice : solar & non solar heat flux over ice (T-point) [W/m2]
190	! qla_ice : latent heat flux over ice (T-point) [W/m2]
191	! dqns_ice, dqla_ice : non solar & latent heat sensistivity (T-point) [W/m2]
192	! tprecip , sprecip : total & solid precipitation (T-point) [Kg/m2/s]
193	! fr1_i0 , fr2_i0 : 1sr & 2nd fraction of qsr penetration in ice [%]
194	!----------------------------------------------------------------------------------------
195	CALL wrk_alloc( jpi,jpj,jpl, zalb_os, zalb_cs, zalb_ice )
196	CALL albedo_ice( t_su, ht_i, ht_s, zalb_cs, zalb_os ) ! cloud-sky and overcast-sky ice albedos
197
198	SELECT CASE( kblk )
199	CASE( jp_clio ) ! CLIO bulk formulation
200	! In CLIO the cloud fraction is read in the climatology and the all-sky albedo
201	! (zalb_ice) is computed within the bulk routine
202	CALL blk_ice_clio_flx( t_su, zalb_cs, zalb_os, zalb_ice )
203	IF( ln_mixcpl ) CALL sbc_cpl_ice_flx( p_frld=pfrld, palbi=zalb_ice, psst=sst_m, pist=t_su )
204	IF( nn_limflx /= 2 ) CALL ice_lim_flx( t_su, zalb_ice, qns_ice, qsr_ice, dqns_ice, evap_ice, devap_ice, nn_limflx )
205	CASE( jp_core ) ! CORE bulk formulation
206	! albedo depends on cloud fraction because of non-linear spectral effects
207	zalb_ice(:,:,:) = ( 1. - cldf_ice ) * zalb_cs(:,:,:) + cldf_ice * zalb_os(:,:,:)
208	CALL blk_ice_core_flx( t_su, zalb_ice )
209	IF( ln_mixcpl ) CALL sbc_cpl_ice_flx( p_frld=pfrld, palbi=zalb_ice, psst=sst_m, pist=t_su )
210	IF( nn_limflx /= 2 ) CALL ice_lim_flx( t_su, zalb_ice, qns_ice, qsr_ice, dqns_ice, evap_ice, devap_ice, nn_limflx )
211	CASE ( jp_purecpl )
212	! albedo depends on cloud fraction because of non-linear spectral effects
213	zalb_ice(:,:,:) = ( 1. - cldf_ice ) * zalb_cs(:,:,:) + cldf_ice * zalb_os(:,:,:)
214	CALL sbc_cpl_ice_flx( p_frld=pfrld, palbi=zalb_ice, psst=sst_m, pist=t_su )
215	! clem: evap_ice is forced to 0 in coupled mode for now
216	! but it needs to be changed (along with modif in limthd_dh) once heat flux from evap will be avail. from atm. models
217	evap_ice (:,:,:) = 0._wp ; devap_ice (:,:,:) = 0._wp
218	IF( nn_limflx == 2 ) CALL ice_lim_flx( t_su, zalb_ice, qns_ice, qsr_ice, dqns_ice, evap_ice, devap_ice, nn_limflx )
219	END SELECT
220	CALL wrk_dealloc( jpi,jpj,jpl, zalb_os, zalb_cs, zalb_ice )
221
222	!----------------------------!
223	! --- ice thermodynamics --- !
224	!----------------------------!
225	CALL lim_thd( kt ) ! Ice thermodynamics
226	!
227	CALL lim_update2( kt ) ! Corrections
228	!
229	CALL lim_sbc_flx( kt ) ! Update surface ocean mass, heat and salt fluxes
230	!
231	IF(ln_limdiaout) CALL lim_diahsb ! Diagnostics and outputs
232	!
233	CALL lim_wri( 1 ) ! Ice outputs
234	!
235	IF( kt == nit000 .AND. ln_rstart ) &
236	& CALL iom_close( numrir ) ! close input ice restart file
237	!
238	IF( lrst_ice ) CALL lim_rst_write( kt ) ! Ice restart file
239	!
240	IF( ln_icectl ) CALL lim_ctl( kt ) ! alerts in case of model crash
241	!
242	ENDIF ! End sea-ice time step only
243
244	!-------------------------!
245	! --- Ocean time step --- !
246	!-------------------------!
247	! Update surface ocean stresses (only in ice-dynamic case) otherwise the atm.-ocean stresses are used everywhere
248	IF( ln_limdyn ) CALL lim_sbc_tau( kt, ub(:,:,1), vb(:,:,1) ) ! using before instantaneous surf. currents
249	!!gm remark, the ocean-ice stress is not saved in ice diag call above ..... find a solution!!!
250	!
251	IF( nn_timing == 1 ) CALL timing_stop('sbc_ice_lim')
252	!
253	END SUBROUTINE sbc_ice_lim
254
255
256	SUBROUTINE sbc_lim_init
257	!!----------------------------------------------------------------------
258	!! * ROUTINE sbc_lim_init *
259	!!
260	!! ** purpose : Allocate all the dynamic arrays of the LIM-3 modules
261	!!----------------------------------------------------------------------
262	INTEGER :: ji, jj, ierr
263	!!----------------------------------------------------------------------
264	IF(lwp) WRITE(numout,*)
265	IF(lwp) WRITE(numout,*) 'sbc_ice_lim : update ocean surface boudary condition'
266	IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ via Louvain la Neuve Ice Model (LIM-3) time stepping'
267	!
268	! ! Open the reference and configuration namelist files and namelist output file
269	CALL ctl_opn( numnam_ice_ref, 'namelist_ice_ref', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, numout, lwp )
270	CALL ctl_opn( numnam_ice_cfg, 'namelist_ice_cfg', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, numout, lwp )
271	IF(lwm) CALL ctl_opn( numoni, 'output.namelist.ice', 'UNKNOWN', 'FORMATTED', 'SEQUENTIAL', -1, numout, lwp, 1 )
272	!
273	CALL ice_run ! set some ice run parameters
274	!
275	! ! Allocate the ice arrays
276	ierr = ice_alloc () ! ice variables
277	ierr = ierr + dom_ice_alloc () ! domain
278	ierr = ierr + sbc_ice_alloc () ! surface forcing
279	ierr = ierr + thd_ice_alloc () ! thermodynamics
280	ierr = ierr + lim_itd_me_alloc () ! ice thickness distribution - mechanics
281	!
282	IF( lk_mpp ) CALL mpp_sum( ierr )
283	IF( ierr /= 0 ) CALL ctl_stop('STOP', 'sbc_lim_init : unable to allocate ice arrays')
284	!
285	! ! adequation jpk versus ice/snow layers/categories
286	IF( jpl > jpk .OR. (nlay_i+1) > jpk .OR. nlay_s > jpk ) &
287	& CALL ctl_stop( 'STOP', &
288	& 'sbc_lim_init: the 3rd dimension of workspace arrays is too small.', &
289	& 'use more ocean levels or less ice/snow layers/categories.' )
290	!
291	CALL lim_itd_init ! ice thickness distribution initialization
292	!
293	CALL lim_hdf_init ! set ice horizontal diffusion computation parameters
294	!
295	CALL lim_thd_init ! set ice thermodynics parameters
296	!
297	CALL lim_thd_sal_init ! set ice salinity parameters
298	!
299	CALL lim_msh ! ice mesh initialization
300	!
301	CALL lim_itd_me_init ! ice thickness distribution initialization for mecanical deformation
302	! ! Initial sea-ice state
303	IF( .NOT. ln_rstart ) THEN ! start from rest: sea-ice deduced from sst
304	numit = 0
305	numit = nit000 - 1
306	CALL lim_istate
307	ELSE ! start from a restart file
308	CALL lim_rst_read
309	numit = nit000 - 1
310	ENDIF
311	CALL lim_var_agg(1)
312	CALL lim_var_glo2eqv
313	!
314	CALL lim_sbc_init ! ice surface boundary condition
315	!
316	fr_i(:,:) = at_i(:,:) ! initialisation of sea-ice fraction
317	tn_ice(:,:,:) = t_su(:,:,:) ! initialisation of surface temp for coupled simu
318	!
319	DO jj = 1, jpj
320	DO ji = 1, jpi
321	IF( gphit(ji,jj) > 0._wp ) THEN ; rn_amax_2d(ji,jj) = rn_amax_n ! NH
322	ELSE ; rn_amax_2d(ji,jj) = rn_amax_s ! SH
323	ENDIF
324	ENDDO
325	ENDDO
326	!
327	nstart = numit + nn_fsbc
328	nitrun = nitend - nit000 + 1
329	nlast = numit + nitrun
330	!
331	IF( nstock == 0 ) nstock = nlast + 1
332	!
333	END SUBROUTINE sbc_lim_init
334
335
336	SUBROUTINE ice_run
337	!!-------------------------------------------------------------------
338	!! * ROUTINE ice_run *
339	!!
340	!! ** Purpose : Definition some run parameter for ice model
341	!!
342	!! ** Method : Read the namicerun namelist and check the parameter
343	!! values called at the first timestep (nit000)
344	!!
345	!! ** input : Namelist namicerun
346	!!-------------------------------------------------------------------
347	INTEGER :: ios ! Local integer output status for namelist read
348	NAMELIST/namicerun/ jpl, nlay_i, nlay_s, cn_icerst_in, cn_icerst_indir, cn_icerst_out, cn_icerst_outdir, &
349	& ln_limdyn, rn_amax_n, rn_amax_s, ln_limdiahsb, ln_limdiaout, ln_icectl, iiceprt, jiceprt
350	!!-------------------------------------------------------------------
351	!
352	REWIND( numnam_ice_ref ) ! Namelist namicerun in reference namelist : Parameters for ice
353	READ ( numnam_ice_ref, namicerun, IOSTAT = ios, ERR = 901)
354	901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namicerun in reference namelist', lwp )
355	!
356	REWIND( numnam_ice_cfg ) ! Namelist namicerun in configuration namelist : Parameters for ice
357	READ ( numnam_ice_cfg, namicerun, IOSTAT = ios, ERR = 902 )
358	902 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namicerun in configuration namelist', lwp )
359	IF(lwm) WRITE( numoni, namicerun )
360	!
361	IF(lwp) THEN ! control print
362	WRITE(numout,*)
363	WRITE(numout,*) 'ice_run : ice share parameters for dynamics/advection/thermo of sea-ice'
364	WRITE(numout,*) ' ~~~~~~'
365	WRITE(numout,*) ' number of ice categories = ', jpl
366	WRITE(numout,*) ' number of ice layers = ', nlay_i
367	WRITE(numout,*) ' number of snow layers = ', nlay_s
368	WRITE(numout,*) ' switch for ice dynamics (1) or not (0) ln_limdyn = ', ln_limdyn
369	WRITE(numout,*) ' maximum ice concentration for NH = ', rn_amax_n
370	WRITE(numout,*) ' maximum ice concentration for SH = ', rn_amax_s
371	WRITE(numout,*) ' Diagnose heat/salt budget or not ln_limdiahsb = ', ln_limdiahsb
372	WRITE(numout,*) ' Output heat/salt budget or not ln_limdiaout = ', ln_limdiaout
373	WRITE(numout,*) ' control prints in ocean.out for (i,j)=(iiceprt,jiceprt) = ', ln_icectl
374	WRITE(numout,*) ' i-index for control prints (ln_icectl=true) = ', iiceprt
375	WRITE(numout,*) ' j-index for control prints (ln_icectl=true) = ', jiceprt
376	ENDIF
377	!
378	! sea-ice timestep and inverse
379	rdt_ice = nn_fsbc * rdt
380	r1_rdtice = 1._wp / rdt_ice
381
382	! inverse of nlay_i and nlay_s
383	r1_nlay_i = 1._wp / REAL( nlay_i, wp )
384	r1_nlay_s = 1._wp / REAL( nlay_s, wp )
385	!
386	#if defined key_bdy
387	IF( lwp .AND. ln_limdiahsb ) CALL ctl_warn('online conservation check activated but it does not work with BDY')
388	#endif
389	!
390	END SUBROUTINE ice_run
391
392
393	SUBROUTINE lim_itd_init
394	!!------------------------------------------------------------------
395	!! * ROUTINE lim_itd_init *
396	!!
397	!! ** Purpose : Initializes the ice thickness distribution
398	!! ** Method : ...
399	!! ** input : Namelist namiceitd
400	!!-------------------------------------------------------------------
401	INTEGER :: ios ! Local integer output status for namelist read
402	NAMELIST/namiceitd/ nn_catbnd, rn_himean
403	!
404	INTEGER :: jl ! dummy loop index
405	REAL(wp) :: zc1, zc2, zc3, zx1 ! local scalars
406	REAL(wp) :: zhmax, znum, zden, zalpha !
407	!!------------------------------------------------------------------
408	!
409	REWIND( numnam_ice_ref ) ! Namelist namiceitd in reference namelist : Parameters for ice
410	READ ( numnam_ice_ref, namiceitd, IOSTAT = ios, ERR = 903)
411	903 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namiceitd in reference namelist', lwp )
412	!
413	REWIND( numnam_ice_cfg ) ! Namelist namiceitd in configuration namelist : Parameters for ice
414	READ ( numnam_ice_cfg, namiceitd, IOSTAT = ios, ERR = 904 )
415	904 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namiceitd in configuration namelist', lwp )
416	IF(lwm) WRITE( numoni, namiceitd )
417	!
418	IF(lwp) THEN ! control print
419	WRITE(numout,*)
420	WRITE(numout,*) 'ice_itd : ice cat distribution'
421	WRITE(numout,*) ' ~~~~~~'
422	WRITE(numout,*) ' shape of ice categories distribution nn_catbnd = ', nn_catbnd
423	WRITE(numout,*) ' mean ice thickness in the domain (used if nn_catbnd=2) rn_himean = ', rn_himean
424	ENDIF
425	!
426	!----------------------------------
427	!- Thickness categories boundaries
428	!----------------------------------
429	IF(lwp) WRITE(numout,*)
430	IF(lwp) WRITE(numout,*) 'lim_itd_init : Initialization of ice cat distribution '
431	IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~'
432	!
433	hi_max(:) = 0._wp
434	!
435	SELECT CASE ( nn_catbnd ) ! type of ice categories distribution
436	!
437	CASE (1) !== tanh function (CICE) ==!
438	zc1 = 3._wp / REAL( jpl, wp )
439	zc2 = 10._wp * zc1
440	zc3 = 3._wp
441	DO jl = 1, jpl
442	zx1 = REAL( jl-1, wp ) / REAL( jpl, wp )
443	hi_max(jl) = hi_max(jl-1) + zc1 + zc2 * (1._wp + TANH( zc3 * (zx1 - 1._wp ) ) )
444	END DO
445	!
446	CASE (2) !== h^(-alpha) function ==!
447	zalpha = 0.05_wp
448	zhmax = 3._wp * rn_himean
449	DO jl = 1, jpl
450	znum = jpl * ( zhmax+1 )**zalpha
451	zden = REAL( jpl-jl , wp ) * ( zhmax + 1._wp )**zalpha + REAL( jl , wp )
452	hi_max(jl) = ( znum / zden )**(1./zalpha) - 1
453	END DO
454	!
455	END SELECT
456	!
457	DO jl = 1, jpl ! mean thickness by category
458	hi_mean(jl) = ( hi_max(jl) + hi_max(jl-1) ) * 0.5_wp
459	END DO
460	!
461	hi_max(jpl) = 99._wp ! set to a big value to ensure that all ice is thinner than hi_max(jpl)
462	!
463	IF(lwp) WRITE(numout,*) ' Thickness category boundaries '
464	IF(lwp) WRITE(numout,*) ' hi_max ', hi_max(0:jpl)
465	!
466	END SUBROUTINE lim_itd_init
467
468
469	SUBROUTINE ice_lim_flx( ptn_ice , palb_ice, pqns_ice , &
470	& pqsr_ice, pdqn_ice, pevap_ice, pdevap_ice, k_limflx )
471	!!---------------------------------------------------------------------
472	!! * ROUTINE ice_lim_flx *
473	!!
474	!! ** Purpose : update the ice surface boundary condition by averaging and / or
475	!! redistributing fluxes on ice categories
476	!!
477	!! ** Method : average then redistribute
478	!!
479	!! ** Action :
480	!!---------------------------------------------------------------------
481	INTEGER , INTENT(in ) :: k_limflx ! =-1 do nothing; =0 average ;
482	! ! =1 average and redistribute ; =2 redistribute
483	REAL(wp), DIMENSION(:,:,:), INTENT(in ) :: ptn_ice ! ice surface temperature
484	REAL(wp), DIMENSION(:,:,:), INTENT(in ) :: palb_ice ! ice albedo
485	REAL(wp), DIMENSION(:,:,:), INTENT(inout) :: pqns_ice ! non solar flux
486	REAL(wp), DIMENSION(:,:,:), INTENT(inout) :: pqsr_ice ! net solar flux
487	REAL(wp), DIMENSION(:,:,:), INTENT(inout) :: pdqn_ice ! non solar flux sensitivity
488	REAL(wp), DIMENSION(:,:,:), INTENT(inout) :: pevap_ice ! sublimation
489	REAL(wp), DIMENSION(:,:,:), INTENT(inout) :: pdevap_ice ! sublimation sensitivity
490	!
491	INTEGER :: jl ! dummy loop index
492	!
493	REAL(wp), POINTER, DIMENSION(:,:) :: zalb_m ! Mean albedo over all categories
494	REAL(wp), POINTER, DIMENSION(:,:) :: ztem_m ! Mean temperature over all categories
495	!
496	REAL(wp), POINTER, DIMENSION(:,:) :: z_qsr_m ! Mean solar heat flux over all categories
497	REAL(wp), POINTER, DIMENSION(:,:) :: z_qns_m ! Mean non solar heat flux over all categories
498	REAL(wp), POINTER, DIMENSION(:,:) :: z_evap_m ! Mean sublimation over all categories
499	REAL(wp), POINTER, DIMENSION(:,:) :: z_dqn_m ! Mean d(qns)/dT over all categories
500	REAL(wp), POINTER, DIMENSION(:,:) :: z_devap_m ! Mean d(evap)/dT over all categories
501	!!----------------------------------------------------------------------
502	!
503	IF( nn_timing == 1 ) CALL timing_start('ice_lim_flx')
504	!
505	SELECT CASE( k_limflx ) !== averaged on all ice categories ==!
506	CASE( 0 , 1 )
507	CALL wrk_alloc( jpi,jpj, z_qsr_m, z_qns_m, z_evap_m, z_dqn_m, z_devap_m)
508	!
509	z_qns_m (:,:) = fice_ice_ave ( pqns_ice (:,:,:) )
510	z_qsr_m (:,:) = fice_ice_ave ( pqsr_ice (:,:,:) )
511	z_dqn_m (:,:) = fice_ice_ave ( pdqn_ice (:,:,:) )
512	z_evap_m (:,:) = fice_ice_ave ( pevap_ice (:,:,:) )
513	z_devap_m(:,:) = fice_ice_ave ( pdevap_ice (:,:,:) )
514	DO jl = 1, jpl
515	pdqn_ice (:,:,jl) = z_dqn_m(:,:)
516	pdevap_ice(:,:,jl) = z_devap_m(:,:)
517	END DO
518	!
519	DO jl = 1, jpl
520	pqns_ice (:,:,jl) = z_qns_m(:,:)
521	pqsr_ice (:,:,jl) = z_qsr_m(:,:)
522	pevap_ice(:,:,jl) = z_evap_m(:,:)
523	END DO
524	!
525	CALL wrk_dealloc( jpi,jpj, z_qsr_m, z_qns_m, z_evap_m, z_dqn_m, z_devap_m)
526	END SELECT
527	!
528	SELECT CASE( k_limflx ) !== redistribution on all ice categories ==!
529	CASE( 1 , 2 )
530	CALL wrk_alloc( jpi,jpj, zalb_m, ztem_m )
531	!
532	zalb_m(:,:) = fice_ice_ave ( palb_ice (:,:,:) )
533	ztem_m(:,:) = fice_ice_ave ( ptn_ice (:,:,:) )
534	DO jl = 1, jpl
535	pqns_ice (:,:,jl) = pqns_ice (:,:,jl) + pdqn_ice (:,:,jl) * ( ptn_ice(:,:,jl) - ztem_m(:,:) )
536	pevap_ice(:,:,jl) = pevap_ice(:,:,jl) + pdevap_ice(:,:,jl) * ( ptn_ice(:,:,jl) - ztem_m(:,:) )
537	pqsr_ice (:,:,jl) = pqsr_ice (:,:,jl) * ( 1._wp - palb_ice(:,:,jl) ) / ( 1._wp - zalb_m(:,:) )
538	END DO
539	!
540	CALL wrk_dealloc( jpi,jpj, zalb_m, ztem_m )
541	END SELECT
542	!
543	IF( nn_timing == 1 ) CALL timing_stop('ice_lim_flx')
544	!
545	END SUBROUTINE ice_lim_flx
546
547
548	SUBROUTINE sbc_lim_bef
549	!!----------------------------------------------------------------------
550	!! * ROUTINE sbc_lim_bef *
551	!!
552	!! ** purpose : store ice variables at "before" time step
553	!!----------------------------------------------------------------------
554	a_i_b (:,:,:) = a_i (:,:,:) ! ice area
555	e_i_b (:,:,:,:) = e_i (:,:,:,:) ! ice thermal energy
556	v_i_b (:,:,:) = v_i (:,:,:) ! ice volume
557	v_s_b (:,:,:) = v_s (:,:,:) ! snow volume
558	e_s_b (:,:,:,:) = e_s (:,:,:,:) ! snow thermal energy
559	smv_i_b(:,:,:) = smv_i(:,:,:) ! salt content
560	oa_i_b (:,:,:) = oa_i (:,:,:) ! areal age content
561	u_ice_b(:,:) = u_ice(:,:)
562	v_ice_b(:,:) = v_ice(:,:)
563	!
564	END SUBROUTINE sbc_lim_bef
565
566
567	SUBROUTINE sbc_lim_diag0
568	!!----------------------------------------------------------------------
569	!! * ROUTINE sbc_lim_diag0 *
570	!!
571	!! ** purpose : set ice-ocean and ice-atm. fluxes to zeros at the beggining
572	!! of the time step
573	!!----------------------------------------------------------------------
574	sfx (:,:) = 0._wp ;
575	sfx_bri(:,:) = 0._wp ;
576	sfx_sni(:,:) = 0._wp ; sfx_opw(:,:) = 0._wp
577	sfx_bog(:,:) = 0._wp ; sfx_dyn(:,:) = 0._wp
578	sfx_bom(:,:) = 0._wp ; sfx_sum(:,:) = 0._wp
579	sfx_res(:,:) = 0._wp
580	!
581	wfx_snw(:,:) = 0._wp ; wfx_ice(:,:) = 0._wp
582	wfx_sni(:,:) = 0._wp ; wfx_opw(:,:) = 0._wp
583	wfx_bog(:,:) = 0._wp ; wfx_dyn(:,:) = 0._wp
584	wfx_bom(:,:) = 0._wp ; wfx_sum(:,:) = 0._wp
585	wfx_res(:,:) = 0._wp ; wfx_sub(:,:) = 0._wp
586	wfx_spr(:,:) = 0._wp ;
587	!
588	hfx_thd(:,:) = 0._wp ;
589	hfx_snw(:,:) = 0._wp ; hfx_opw(:,:) = 0._wp
590	hfx_bog(:,:) = 0._wp ; hfx_dyn(:,:) = 0._wp
591	hfx_bom(:,:) = 0._wp ; hfx_sum(:,:) = 0._wp
592	hfx_res(:,:) = 0._wp ; hfx_sub(:,:) = 0._wp
593	hfx_spr(:,:) = 0._wp ; hfx_dif(:,:) = 0._wp
594	hfx_err(:,:) = 0._wp ; hfx_err_rem(:,:) = 0._wp
595	hfx_err_dif(:,:) = 0._wp ;
596	!
597	afx_tot(:,:) = 0._wp ;
598	afx_dyn(:,:) = 0._wp ; afx_thd(:,:) = 0._wp
599	!
600	diag_heat(:,:) = 0._wp ; diag_smvi(:,:) = 0._wp ;
601	diag_vice(:,:) = 0._wp ; diag_vsnw(:,:) = 0._wp ;
602	!
603	END SUBROUTINE sbc_lim_diag0
604
605
606	FUNCTION fice_cell_ave ( ptab )
607	!!--------------------------------------------------------------------------
608	!! * Compute average over categories, for grid cell (ice covered and free ocean)
609	!!--------------------------------------------------------------------------
610	REAL (wp), DIMENSION (jpi,jpj) :: fice_cell_ave
611	REAL (wp), DIMENSION (jpi,jpj,jpl), INTENT (in) :: ptab
612	INTEGER :: jl ! Dummy loop index
613
614	fice_cell_ave (:,:) = 0.0_wp
615	DO jl = 1, jpl
616	fice_cell_ave (:,:) = fice_cell_ave (:,:) + a_i (:,:,jl) * ptab (:,:,jl)
617	END DO
618
619	END FUNCTION fice_cell_ave
620
621
622	FUNCTION fice_ice_ave ( ptab )
623	!!--------------------------------------------------------------------------
624	!! * Compute average over categories, for ice covered part of grid cell
625	!!--------------------------------------------------------------------------
626	REAL (kind=wp), DIMENSION (jpi,jpj) :: fice_ice_ave
627	REAL (kind=wp), DIMENSION (jpi,jpj,jpl), INTENT(in) :: ptab
628
629	fice_ice_ave (:,:) = 0.0_wp
630	WHERE ( at_i (:,:) > 0.0_wp ) fice_ice_ave (:,:) = fice_cell_ave ( ptab (:,:,:)) / at_i (:,:)
631
632	END FUNCTION fice_ice_ave
633
634	#else
635	!!----------------------------------------------------------------------
636	!! Default option Dummy module NO LIM 3.0 sea-ice model
637	!!----------------------------------------------------------------------
638	CONTAINS
639	SUBROUTINE sbc_ice_lim ( kt, kblk ) ! Dummy routine
640	WRITE(,) 'sbc_ice_lim: You should not have seen this print! error?', kt, kblk
641	END SUBROUTINE sbc_ice_lim
642	SUBROUTINE sbc_lim_init ! Dummy routine
643	END SUBROUTINE sbc_lim_init
644	#endif
645
646	!!======================================================================
647	END MODULE sbcice_lim

Note: See TracBrowser for help on using the repository browser.

Download in other formats: