1 | MODULE limdyn |
---|
2 | !!====================================================================== |
---|
3 | !! *** MODULE limdyn *** |
---|
4 | !! Sea-Ice dynamics : |
---|
5 | !!====================================================================== |
---|
6 | #if defined key_lim3 |
---|
7 | !!---------------------------------------------------------------------- |
---|
8 | !! 'key_lim3' : LIM3 sea-ice model |
---|
9 | !!---------------------------------------------------------------------- |
---|
10 | !! lim_dyn : computes ice velocities |
---|
11 | !! lim_dyn_init : initialization and namelist read |
---|
12 | !!---------------------------------------------------------------------- |
---|
13 | !! * Modules used |
---|
14 | USE phycst |
---|
15 | USE in_out_manager ! I/O manager |
---|
16 | USE dom_ice |
---|
17 | USE dom_oce ! ocean space and time domain |
---|
18 | USE ice |
---|
19 | USE par_ice |
---|
20 | USE sbc_oce ! Surface boundary condition: ocean fields |
---|
21 | USE sbc_ice ! Surface boundary condition: ice fields |
---|
22 | USE ice_oce |
---|
23 | USE iceini |
---|
24 | USE limistate |
---|
25 | USE limrhg ! ice rheology |
---|
26 | USE lbclnk |
---|
27 | USE lib_mpp |
---|
28 | USE prtctl ! Print control |
---|
29 | |
---|
30 | IMPLICIT NONE |
---|
31 | PRIVATE |
---|
32 | |
---|
33 | !! * Accessibility |
---|
34 | PUBLIC lim_dyn ! routine called by ice_step |
---|
35 | |
---|
36 | !! * Substitutions |
---|
37 | # include "vectopt_loop_substitute.h90" |
---|
38 | |
---|
39 | !! * Module variables |
---|
40 | REAL(wp) :: rone = 1.e0 ! constant value |
---|
41 | |
---|
42 | !!---------------------------------------------------------------------- |
---|
43 | !! LIM 3.0, UCL-ASTR-LOCEAN-IPSL (2008) |
---|
44 | !! $ Id: $ |
---|
45 | !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt) |
---|
46 | !!---------------------------------------------------------------------- |
---|
47 | |
---|
48 | CONTAINS |
---|
49 | |
---|
50 | SUBROUTINE lim_dyn( kt ) |
---|
51 | !!------------------------------------------------------------------- |
---|
52 | !! *** ROUTINE lim_dyn *** |
---|
53 | !! |
---|
54 | !! ** Purpose : compute ice velocity and ocean-ice stress |
---|
55 | !! |
---|
56 | !! ** Method : |
---|
57 | !! |
---|
58 | !! ** Action : - Initialisation |
---|
59 | !! - Call of the dynamic routine for each hemisphere |
---|
60 | !! - computation of the stress at the ocean surface |
---|
61 | !! - treatment of the case if no ice dynamic |
---|
62 | !! History : |
---|
63 | !! 1.0 ! 01-04 (LIM) Original code |
---|
64 | !! 2.0 ! 02-08 (C. Ethe, G. Madec) F90, mpp |
---|
65 | !! 3.0 ! 2007-03 (M.A. Morales Maqueda, S. Bouillon, M. Vancoppenolle) |
---|
66 | !! LIM3, EVP, C-grid |
---|
67 | !!------------------------------------------------------------------------------------ |
---|
68 | INTEGER, INTENT(in) :: kt ! number of iteration |
---|
69 | !! * Local variables |
---|
70 | INTEGER :: ji, jj, jl, ja ! dummy loop indices |
---|
71 | INTEGER :: i_j1, i_jpj ! Starting/ending j-indices for rheology |
---|
72 | REAL(wp) :: zcoef ! temporary scalar |
---|
73 | REAL(wp), DIMENSION(jpj) :: zind ! i-averaged indicator of sea-ice |
---|
74 | REAL(wp), DIMENSION(jpj) :: zmsk ! i-averaged of tmask |
---|
75 | REAL(wp), DIMENSION(jpi,jpj) :: zu_io, zv_io ! ice-ocean velocity |
---|
76 | !!--------------------------------------------------------------------- |
---|
77 | |
---|
78 | IF( kt == nit000 .AND. lwp ) THEN |
---|
79 | WRITE(numout,*) ' lim_dyn : Ice dynamics ' |
---|
80 | WRITE(numout,*) ' ~~~~~~~ ' |
---|
81 | ENDIF |
---|
82 | |
---|
83 | IF( numit == nstart ) CALL lim_dyn_init ! Initialization (first time-step only) |
---|
84 | |
---|
85 | IF ( ln_limdyn ) THEN |
---|
86 | |
---|
87 | old_u_ice(:,:) = u_ice(:,:) * tmu(:,:) |
---|
88 | old_v_ice(:,:) = v_ice(:,:) * tmv(:,:) |
---|
89 | |
---|
90 | ! Rheology (ice dynamics) |
---|
91 | ! ======== |
---|
92 | |
---|
93 | ! Define the j-limits where ice rheology is computed |
---|
94 | ! --------------------------------------------------- |
---|
95 | |
---|
96 | IF( lk_mpp .OR. nbit_cmp == 1 ) THEN ! mpp: compute over the whole domain |
---|
97 | i_j1 = 1 |
---|
98 | i_jpj = jpj |
---|
99 | IF(ln_ctl) CALL prt_ctl_info( 'lim_dyn : i_j1 = ', ivar1=i_j1, clinfo2=' ij_jpj = ', ivar2=i_jpj ) |
---|
100 | CALL lim_rhg( i_j1, i_jpj ) |
---|
101 | ELSE ! optimization of the computational area |
---|
102 | |
---|
103 | DO jj = 1, jpj |
---|
104 | zind(jj) = SUM( 1.0 - at_i (:,jj ) ) ! = FLOAT(jpj) if ocean everywhere on a j-line |
---|
105 | zmsk(jj) = SUM( tmask(:,jj,1) ) ! = 0 if land everywhere on a j-line |
---|
106 | END DO |
---|
107 | |
---|
108 | IF( l_jeq ) THEN ! local domain include both hemisphere |
---|
109 | ! ! Rheology is computed in each hemisphere |
---|
110 | ! ! only over the ice cover latitude strip |
---|
111 | ! Northern hemisphere |
---|
112 | i_j1 = njeq |
---|
113 | i_jpj = jpj |
---|
114 | DO WHILE ( i_j1 <= jpj .AND. zind(i_j1) == FLOAT(jpi) .AND. zmsk(i_j1) /=0 ) |
---|
115 | i_j1 = i_j1 + 1 |
---|
116 | END DO |
---|
117 | i_j1 = MAX( 1, i_j1-2 ) |
---|
118 | IF(ln_ctl) CALL prt_ctl_info( 'lim_dyn : NH i_j1 = ', ivar1=i_j1, clinfo2=' ij_jpj = ', ivar2=i_jpj ) |
---|
119 | CALL lim_rhg( i_j1, i_jpj ) |
---|
120 | |
---|
121 | ! Southern hemisphere |
---|
122 | i_j1 = 1 |
---|
123 | i_jpj = njeq |
---|
124 | DO WHILE ( i_jpj >= 1 .AND. zind(i_jpj) == FLOAT(jpi) .AND. zmsk(i_jpj) /=0 ) |
---|
125 | i_jpj = i_jpj - 1 |
---|
126 | END DO |
---|
127 | i_jpj = MIN( jpj, i_jpj+1 ) |
---|
128 | IF(ln_ctl) CALL prt_ctl_info( 'lim_dyn : SH i_j1 = ', ivar1=i_j1, clinfo2=' ij_jpj = ', ivar2=i_jpj ) |
---|
129 | |
---|
130 | CALL lim_rhg( i_j1, i_jpj ) |
---|
131 | |
---|
132 | ELSE ! local domain extends over one hemisphere only |
---|
133 | ! ! Rheology is computed only over the ice cover |
---|
134 | ! ! latitude strip |
---|
135 | i_j1 = 1 |
---|
136 | DO WHILE ( i_j1 <= jpj .AND. zind(i_j1) == FLOAT(jpi) .AND. zmsk(i_j1) /=0 ) |
---|
137 | i_j1 = i_j1 + 1 |
---|
138 | END DO |
---|
139 | i_j1 = MAX( 1, i_j1-2 ) |
---|
140 | |
---|
141 | i_jpj = jpj |
---|
142 | DO WHILE ( i_jpj >= 1 .AND. zind(i_jpj) == FLOAT(jpi) .AND. zmsk(i_jpj) /=0 ) |
---|
143 | i_jpj = i_jpj - 1 |
---|
144 | END DO |
---|
145 | i_jpj = MIN( jpj, i_jpj+1) |
---|
146 | |
---|
147 | IF(ln_ctl) CALL prt_ctl_info( 'lim_dyn : one hemisphere: i_j1 = ', ivar1=i_j1, clinfo2=' ij_jpj = ', ivar2=i_jpj ) |
---|
148 | |
---|
149 | CALL lim_rhg( i_j1, i_jpj ) |
---|
150 | |
---|
151 | ENDIF |
---|
152 | |
---|
153 | ENDIF |
---|
154 | |
---|
155 | ! computation of friction velocity |
---|
156 | ! -------------------------------- |
---|
157 | ! ice-ocean velocity at U & V-points (u_ice vi_ice at U- & V-points ; ssu_m, ssv_m at U- & V-points) |
---|
158 | zu_io(:,:) = u_ice(:,:) - ssu_m(:,:) |
---|
159 | zv_io(:,:) = v_ice(:,:) - ssv_m(:,:) |
---|
160 | ! frictional velocity at T-point |
---|
161 | DO jj = 2, jpjm1 |
---|
162 | DO ji = fs_2, fs_jpim1 ! vector opt. |
---|
163 | ust2s(ji,jj) = 0.5 * cw & |
---|
164 | & * ( zu_io(ji,jj) * zu_io(ji,jj) + zu_io(ji-1,jj) * zu_io(ji-1,jj) & |
---|
165 | & + zv_io(ji,jj) * zv_io(ji,jj) + zv_io(ji,jj-1) * zv_io(ji,jj-1) ) * tms(ji,jj) |
---|
166 | END DO |
---|
167 | END DO |
---|
168 | ! |
---|
169 | ELSE ! no ice dynamics : transmit directly the atmospheric stress to the ocean |
---|
170 | ! |
---|
171 | zcoef = SQRT( 0.5 ) / rau0 |
---|
172 | DO jj = 2, jpjm1 |
---|
173 | DO ji = fs_2, fs_jpim1 ! vector opt. |
---|
174 | ust2s(ji,jj) = zcoef * tms(ji,jj) * SQRT( utau(ji,jj) * utau(ji,jj) + utau(ji-1,jj) * utau(ji-1,jj) & |
---|
175 | & + vtau(ji,jj) * vtau(ji,jj) + vtau(ji,jj-1) * vtau(ji,jj-1) ) |
---|
176 | END DO |
---|
177 | END DO |
---|
178 | ! |
---|
179 | ENDIF |
---|
180 | |
---|
181 | CALL lbc_lnk( ust2s, 'T', 1. ) ! T-point |
---|
182 | |
---|
183 | IF(ln_ctl) THEN ! Control print |
---|
184 | CALL prt_ctl_info(' ') |
---|
185 | CALL prt_ctl_info(' - Cell values : ') |
---|
186 | CALL prt_ctl_info(' ~~~~~~~~~~~~~ ') |
---|
187 | CALL prt_ctl(tab2d_1=ust2s , clinfo1=' lim_dyn : ust2s :') |
---|
188 | CALL prt_ctl(tab2d_1=divu_i , clinfo1=' lim_dyn : divu_i :') |
---|
189 | CALL prt_ctl(tab2d_1=delta_i , clinfo1=' lim_dyn : delta_i :') |
---|
190 | CALL prt_ctl(tab2d_1=strength , clinfo1=' lim_dyn : strength :') |
---|
191 | CALL prt_ctl(tab2d_1=area , clinfo1=' lim_dyn : cell area :') |
---|
192 | CALL prt_ctl(tab2d_1=at_i , clinfo1=' lim_dyn : at_i :') |
---|
193 | CALL prt_ctl(tab2d_1=vt_i , clinfo1=' lim_dyn : vt_i :') |
---|
194 | CALL prt_ctl(tab2d_1=vt_s , clinfo1=' lim_dyn : vt_s :') |
---|
195 | CALL prt_ctl(tab2d_1=stress1_i , clinfo1=' lim_dyn : stress1_i :') |
---|
196 | CALL prt_ctl(tab2d_1=stress2_i , clinfo1=' lim_dyn : stress2_i :') |
---|
197 | CALL prt_ctl(tab2d_1=stress12_i, clinfo1=' lim_dyn : stress12_i:') |
---|
198 | DO jl = 1, jpl |
---|
199 | CALL prt_ctl_info(' ') |
---|
200 | CALL prt_ctl_info(' - Category : ', ivar1=jl) |
---|
201 | CALL prt_ctl_info(' ~~~~~~~~~~') |
---|
202 | CALL prt_ctl(tab2d_1=a_i (:,:,jl) , clinfo1= ' lim_dyn : a_i : ') |
---|
203 | CALL prt_ctl(tab2d_1=ht_i (:,:,jl) , clinfo1= ' lim_dyn : ht_i : ') |
---|
204 | CALL prt_ctl(tab2d_1=ht_s (:,:,jl) , clinfo1= ' lim_dyn : ht_s : ') |
---|
205 | CALL prt_ctl(tab2d_1=v_i (:,:,jl) , clinfo1= ' lim_dyn : v_i : ') |
---|
206 | CALL prt_ctl(tab2d_1=v_s (:,:,jl) , clinfo1= ' lim_dyn : v_s : ') |
---|
207 | CALL prt_ctl(tab2d_1=e_s (:,:,1,jl) , clinfo1= ' lim_dyn : e_s : ') |
---|
208 | CALL prt_ctl(tab2d_1=t_su (:,:,jl) , clinfo1= ' lim_dyn : t_su : ') |
---|
209 | CALL prt_ctl(tab2d_1=t_s (:,:,1,jl) , clinfo1= ' lim_dyn : t_snow : ') |
---|
210 | CALL prt_ctl(tab2d_1=sm_i (:,:,jl) , clinfo1= ' lim_dyn : sm_i : ') |
---|
211 | CALL prt_ctl(tab2d_1=smv_i (:,:,jl) , clinfo1= ' lim_dyn : smv_i : ') |
---|
212 | DO ja = 1, nlay_i |
---|
213 | CALL prt_ctl_info(' ') |
---|
214 | CALL prt_ctl_info(' - Layer : ', ivar1=ja) |
---|
215 | CALL prt_ctl_info(' ~~~~~~~') |
---|
216 | CALL prt_ctl(tab2d_1=t_i(:,:,ja,jl) , clinfo1= ' lim_dyn : t_i : ') |
---|
217 | CALL prt_ctl(tab2d_1=e_i(:,:,ja,jl) , clinfo1= ' lim_dyn : e_i : ') |
---|
218 | END DO |
---|
219 | END DO |
---|
220 | ENDIF |
---|
221 | |
---|
222 | END SUBROUTINE lim_dyn |
---|
223 | |
---|
224 | SUBROUTINE lim_dyn_init |
---|
225 | !!------------------------------------------------------------------- |
---|
226 | !! *** ROUTINE lim_dyn_init *** |
---|
227 | !! |
---|
228 | !! ** Purpose : Physical constants and parameters linked to the ice |
---|
229 | !! dynamics |
---|
230 | !! |
---|
231 | !! ** Method : Read the namicedyn namelist and check the ice-dynamic |
---|
232 | !! parameter values called at the first timestep (nit000) |
---|
233 | !! |
---|
234 | !! ** input : Namelist namicedyn |
---|
235 | !! |
---|
236 | !! history : |
---|
237 | !! 8.5 ! 03-08 (C. Ethe) original code |
---|
238 | !! 9.0 ! 07-03 (MA Morales Maqueda, S. Bouillon, M. Vancoppenolle) |
---|
239 | !! EVP-Cgrid-LIM3 |
---|
240 | !!------------------------------------------------------------------- |
---|
241 | NAMELIST/namicedyn/ epsd, alpha, & |
---|
242 | & dm, nbiter, nbitdr, om, resl, cw, angvg, pstar, & |
---|
243 | & c_rhg, etamn, creepl, ecc, ahi0, & |
---|
244 | & nevp, telast, alphaevp |
---|
245 | !!------------------------------------------------------------------- |
---|
246 | |
---|
247 | ! Define the initial parameters |
---|
248 | ! ------------------------- |
---|
249 | |
---|
250 | ! Read Namelist namicedyn |
---|
251 | REWIND ( numnam_ice ) |
---|
252 | READ ( numnam_ice , namicedyn ) |
---|
253 | IF(lwp) THEN |
---|
254 | WRITE(numout,*) |
---|
255 | WRITE(numout,*) 'lim_dyn_init : ice parameters for ice dynamics ' |
---|
256 | WRITE(numout,*) '~~~~~~~~~~~~' |
---|
257 | WRITE(numout,*) ' tolerance parameter epsd = ', epsd |
---|
258 | WRITE(numout,*) ' coefficient for semi-implicit coriolis alpha = ', alpha |
---|
259 | WRITE(numout,*) ' diffusion constant for dynamics dm = ', dm |
---|
260 | WRITE(numout,*) ' number of sub-time steps for relaxation nbiter = ', nbiter |
---|
261 | WRITE(numout,*) ' maximum number of iterations for relaxation nbitdr = ', nbitdr |
---|
262 | WRITE(numout,*) ' relaxation constant om = ', om |
---|
263 | WRITE(numout,*) ' maximum value for the residual of relaxation resl = ', resl |
---|
264 | WRITE(numout,*) ' drag coefficient for oceanic stress cw = ', cw |
---|
265 | WRITE(numout,*) ' turning angle for oceanic stress angvg = ', angvg |
---|
266 | WRITE(numout,*) ' first bulk-rheology parameter pstar = ', pstar |
---|
267 | WRITE(numout,*) ' second bulk-rhelogy parameter c_rhg = ', c_rhg |
---|
268 | WRITE(numout,*) ' minimun value for viscosity etamn = ', etamn |
---|
269 | WRITE(numout,*) ' creep limit creepl = ', creepl |
---|
270 | WRITE(numout,*) ' eccentricity of the elliptical yield curve ecc = ', ecc |
---|
271 | WRITE(numout,*) ' horizontal diffusivity coeff. for sea-ice ahi0 = ', ahi0 |
---|
272 | WRITE(numout,*) ' number of iterations for subcycling nevp = ', nevp |
---|
273 | WRITE(numout,*) ' timescale for elastic waves telast = ', telast |
---|
274 | WRITE(numout,*) ' coefficient for the solution of int. stresses alphaevp = ', alphaevp |
---|
275 | |
---|
276 | ENDIF |
---|
277 | |
---|
278 | usecc2 = 1.0 / ( ecc * ecc ) |
---|
279 | rhoco = rau0 * cw |
---|
280 | angvg = angvg * rad |
---|
281 | sangvg = SIN( angvg ) |
---|
282 | cangvg = COS( angvg ) |
---|
283 | pstarh = pstar / 2.0 |
---|
284 | |
---|
285 | ! Diffusion coefficients. |
---|
286 | ahiu(:,:) = ahi0 * umask(:,:,1) |
---|
287 | ahiv(:,:) = ahi0 * vmask(:,:,1) |
---|
288 | |
---|
289 | END SUBROUTINE lim_dyn_init |
---|
290 | |
---|
291 | #else |
---|
292 | !!---------------------------------------------------------------------- |
---|
293 | !! Default option Empty module NO LIM sea-ice model |
---|
294 | !!---------------------------------------------------------------------- |
---|
295 | CONTAINS |
---|
296 | SUBROUTINE lim_dyn ! Empty routine |
---|
297 | END SUBROUTINE lim_dyn |
---|
298 | #endif |
---|
299 | |
---|
300 | !!====================================================================== |
---|
301 | END MODULE limdyn |
---|