1 | MODULE limistate |
---|
2 | !!====================================================================== |
---|
3 | !! *** MODULE limistate *** |
---|
4 | !! Initialisation of diagnostics ice variables |
---|
5 | !!====================================================================== |
---|
6 | #if defined key_ice_lim |
---|
7 | !!---------------------------------------------------------------------- |
---|
8 | !! 'key_ice_lim' : LIM sea-ice model |
---|
9 | !!---------------------------------------------------------------------- |
---|
10 | !! lim_istate : Initialisation of diagnostics ice variables |
---|
11 | !! lim_istate_init : initialization of ice state and namelist read |
---|
12 | !!---------------------------------------------------------------------- |
---|
13 | !! * Modules used |
---|
14 | USE phycst |
---|
15 | USE ocfzpt |
---|
16 | USE oce ! dynamics and tracers variables |
---|
17 | USE dom_oce |
---|
18 | USE par_ice ! ice parameters |
---|
19 | USE ice_oce ! ice variables |
---|
20 | USE in_out_manager |
---|
21 | USE dom_ice |
---|
22 | USE ice |
---|
23 | USE lbclnk |
---|
24 | |
---|
25 | IMPLICIT NONE |
---|
26 | PRIVATE |
---|
27 | |
---|
28 | !! * Accessibility |
---|
29 | PUBLIC lim_istate ! routine called by lim_init.F90 |
---|
30 | |
---|
31 | !! * Module variables |
---|
32 | REAL(wp) :: & !!! ** init namelist (namiceini) ** |
---|
33 | ttest = 2.0 , & ! threshold water temperature for initial sea ice |
---|
34 | hninn = 0.5 , & ! initial snow thickness in the north |
---|
35 | hginn = 3.0 , & ! initial ice thickness in the north |
---|
36 | alinn = 0.05 , & ! initial leads area in the north |
---|
37 | hnins = 0.1 , & ! initial snow thickness in the south |
---|
38 | hgins = 1.0 , & ! initial ice thickness in the south |
---|
39 | alins = 0.1 ! initial leads area in the south |
---|
40 | |
---|
41 | REAL(wp) :: & ! constant values |
---|
42 | zzero = 0.e0 , & |
---|
43 | zone = 1.e0 |
---|
44 | !!---------------------------------------------------------------------- |
---|
45 | !! LIM 2.0 , UCL-LODYC-IPSL (2003) |
---|
46 | !!---------------------------------------------------------------------- |
---|
47 | |
---|
48 | CONTAINS |
---|
49 | |
---|
50 | SUBROUTINE lim_istate |
---|
51 | !!------------------------------------------------------------------- |
---|
52 | !! *** ROUTINE lim_istate *** |
---|
53 | !! |
---|
54 | !! ** Purpose : defined the sea-ice initial state |
---|
55 | !! |
---|
56 | !! ** Method : restart from a state defined in a binary file |
---|
57 | !! or from arbitrary sea-ice conditions |
---|
58 | !! |
---|
59 | !! History : |
---|
60 | !! 2.0 ! 01-04 (C. Ethe, G. Madec) Original code |
---|
61 | !!-------------------------------------------------------------------- |
---|
62 | !! * Local variables |
---|
63 | INTEGER :: ji, jj, jk ! dummy loop indices |
---|
64 | REAL(wp) :: zidto, & ! temporary scalar |
---|
65 | zs0, ztf, zbin |
---|
66 | REAL(wp), DIMENSION(jpi,jpj) :: & |
---|
67 | ztn |
---|
68 | !-------------------------------------------------------------------- |
---|
69 | |
---|
70 | |
---|
71 | CALL lim_istate_init ! reading the initials parameters of the ice |
---|
72 | |
---|
73 | !-- Initialisation of sst,sss,u,v do i=1,jpi |
---|
74 | u_io(:,:) = 0.e0 ! ice velocity in x direction |
---|
75 | v_io(:,:) = 0.e0 ! ice velocity in y direction |
---|
76 | |
---|
77 | ! Initialisation at tn or -2 if ice |
---|
78 | DO jj = 1, jpj |
---|
79 | DO ji = 1, jpi |
---|
80 | zbin = MAX( 0., SIGN( 1., fzptn(ji,jj) - tn(ji,jj,1) ) ) |
---|
81 | ztn(ji,jj) = ( (1.-zbin) * tn(ji,jj,1) - 2. * zbin + rt0 ) * tmask(ji,jj,1) |
---|
82 | END DO |
---|
83 | END DO |
---|
84 | |
---|
85 | |
---|
86 | u_io (:,:) = 0.e0 |
---|
87 | v_io (:,:) = 0.e0 |
---|
88 | sst_io(:,:) = ( nfice - 1 ) * ( tn(:,:,1) + rt0 ) ! use the ocean initial values |
---|
89 | sss_io(:,:) = ( nfice - 1 ) * sn(:,:,1) ! tricky trick *(nfice-1) ! |
---|
90 | |
---|
91 | ! reference salinity 34psu |
---|
92 | zs0 = 34.e0 |
---|
93 | ztf = ABS ( rt0 - 0.0575 * zs0 & |
---|
94 | & + 1.710523e-03 * zs0 * SQRT( zs0 ) & |
---|
95 | & - 2.154996e-04 * zs0 *zs0 ) |
---|
96 | |
---|
97 | ! tfu: Melting point of sea water |
---|
98 | tfu(:,:) = ztf |
---|
99 | |
---|
100 | DO jj = 1, jpj |
---|
101 | DO ji = 1, jpi |
---|
102 | !--- Criterion for presence (zidto=1) or absence (zidto=0) of ice |
---|
103 | zidto = tms(ji,jj) * ( 1.0 - MAX(zzero, SIGN( zone, ztn(ji,jj) - tfu(ji,jj) - ttest) ) ) |
---|
104 | |
---|
105 | IF( fcor(ji,jj) >= 0.e0 ) THEN !-- Northern hemisphere. |
---|
106 | hicif(ji,jj) = zidto * hginn |
---|
107 | frld(ji,jj) = zidto * alinn + ( 1.0 - zidto ) * 1.0 |
---|
108 | hsnif(ji,jj) = zidto * hninn |
---|
109 | ELSE !--- Southern hemisphere. |
---|
110 | hicif(ji,jj) = zidto * hgins |
---|
111 | frld(ji,jj) = zidto * alins + ( 1.0 - zidto ) * 1.0 |
---|
112 | hsnif(ji,jj) = zidto * hnins |
---|
113 | ENDIF |
---|
114 | END DO |
---|
115 | END DO |
---|
116 | |
---|
117 | sist (:,:) = tfu(:,:) |
---|
118 | tbif (:,:,1) = tfu(:,:) |
---|
119 | tbif (:,:,2) = tfu(:,:) |
---|
120 | tbif (:,:,3) = tfu(:,:) |
---|
121 | fsbbq (:,:) = 0.e0 |
---|
122 | qstoif(:,:) = 0.e0 |
---|
123 | u_ice (:,:) = 0.e0 |
---|
124 | v_ice (:,:) = 0.e0 |
---|
125 | # if defined key_coupled |
---|
126 | albege(:,:) = 0.8 * tms(:,:) |
---|
127 | # endif |
---|
128 | |
---|
129 | !--- Moments for advection. |
---|
130 | |
---|
131 | sxice (:,:) = 0.e0 ; sxsn (:,:) = 0.e0 ; sxa (:,:) = 0.e0 |
---|
132 | syice (:,:) = 0.e0 ; sysn (:,:) = 0.e0 ; sya (:,:) = 0.e0 |
---|
133 | sxxice(:,:) = 0.e0 ; sxxsn(:,:) = 0.e0 ; sxxa (:,:) = 0.e0 |
---|
134 | syyice(:,:) = 0.e0 ; syysn(:,:) = 0.e0 ; syya (:,:) = 0.e0 |
---|
135 | sxyice(:,:) = 0.e0 ; sxysn(:,:) = 0.e0 ; sxya (:,:) = 0.e0 |
---|
136 | |
---|
137 | sxc0 (:,:) = 0.e0 ; sxc1 (:,:) = 0.e0 ; sxc2 (:,:) = 0.e0 |
---|
138 | syc0 (:,:) = 0.e0 ; syc1 (:,:) = 0.e0 ; syc2 (:,:) = 0.e0 |
---|
139 | sxxc0 (:,:) = 0.e0 ; sxxc1(:,:) = 0.e0 ; sxxc2(:,:) = 0.e0 |
---|
140 | syyc0 (:,:) = 0.e0 ; syyc1(:,:) = 0.e0 ; syyc2(:,:) = 0.e0 |
---|
141 | sxyc0 (:,:) = 0.e0 ; sxyc1(:,:) = 0.e0 ; sxyc2(:,:) = 0.e0 |
---|
142 | |
---|
143 | sxst (:,:) = 0.e0 |
---|
144 | syst (:,:) = 0.e0 |
---|
145 | sxxst (:,:) = 0.e0 |
---|
146 | syyst (:,:) = 0.e0 |
---|
147 | sxyst (:,:) = 0.e0 |
---|
148 | |
---|
149 | !-- lateral boundary conditions |
---|
150 | CALL lbc_lnk( hicif, 'T', 1. ) |
---|
151 | CALL lbc_lnk( frld , 'T', 1. ) |
---|
152 | !i bug frld = 1 over land |
---|
153 | frld(:,:) = tms(:,:) * frld(:,:) + ( 1. - tms(:,:) ) ! put 1 over land |
---|
154 | !i |
---|
155 | CALL lbc_lnk( hsnif, 'T', 1. ) |
---|
156 | CALL lbc_lnk( sist , 'T', 1. ) |
---|
157 | DO jk = 1, jplayersp1 |
---|
158 | CALL lbc_lnk(tbif(:,:,jk), 'T', 1. ) |
---|
159 | END DO |
---|
160 | CALL lbc_lnk( fsbbq , 'T', 1. ) |
---|
161 | CALL lbc_lnk( qstoif , 'T', 1. ) |
---|
162 | CALL lbc_lnk( sss_io , 'T', 1. ) |
---|
163 | |
---|
164 | END SUBROUTINE lim_istate |
---|
165 | |
---|
166 | |
---|
167 | SUBROUTINE lim_istate_init |
---|
168 | !!------------------------------------------------------------------- |
---|
169 | !! *** ROUTINE lim_istate_init *** |
---|
170 | !! |
---|
171 | !! ** Purpose : Definition of initial state of the ice |
---|
172 | !! |
---|
173 | !! ** Method : Read the namiceini namelist and check the parameter |
---|
174 | !! values called at the first timestep (nit000) |
---|
175 | !! |
---|
176 | !! ** input : Namelist namiceini |
---|
177 | !! |
---|
178 | !! history |
---|
179 | !! 8.5 ! 03-08 (C. Ethe) original code |
---|
180 | !!------------------------------------------------------------------- |
---|
181 | NAMELIST/namiceini/ ttest, hninn, hginn, alinn, hnins, hgins, alins |
---|
182 | !!------------------------------------------------------------------- |
---|
183 | |
---|
184 | ! Read Namelist namiceini |
---|
185 | |
---|
186 | REWIND ( numnam_ice ) |
---|
187 | READ ( numnam_ice , namiceini ) |
---|
188 | IF(lwp) THEN |
---|
189 | WRITE(numout,*) |
---|
190 | WRITE(numout,*) 'lim_istate_init : ice parameters inititialisation ' |
---|
191 | WRITE(numout,*) '~~~~~~~~~~~~~~~' |
---|
192 | WRITE(numout,*) ' threshold water temp. for initial sea-ice ttest = ', ttest |
---|
193 | WRITE(numout,*) ' initial snow thickness in the north hninn = ', hninn |
---|
194 | WRITE(numout,*) ' initial ice thickness in the north hginn = ', hginn |
---|
195 | WRITE(numout,*) ' initial leads area in the north alinn = ', alinn |
---|
196 | WRITE(numout,*) ' initial snow thickness in the south hnins = ', hnins |
---|
197 | WRITE(numout,*) ' initial ice thickness in the south hgins = ', hgins |
---|
198 | WRITE(numout,*) ' initial leads area in the south alins = ', alins |
---|
199 | ENDIF |
---|
200 | |
---|
201 | END SUBROUTINE lim_istate_init |
---|
202 | |
---|
203 | #else |
---|
204 | !!---------------------------------------------------------------------- |
---|
205 | !! Default option : Empty module NO LIM sea-ice model |
---|
206 | !!---------------------------------------------------------------------- |
---|
207 | CONTAINS |
---|
208 | SUBROUTINE lim_istate ! Empty routine |
---|
209 | END SUBROUTINE lim_istate |
---|
210 | #endif |
---|
211 | |
---|
212 | !!====================================================================== |
---|
213 | END MODULE limistate |
---|