New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traadv.F90 in branches/UKMO/test_moci_test_suite_namelist_read/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: branches/UKMO/test_moci_test_suite_namelist_read/NEMOGCM/NEMO/OPA_SRC/TRA/traadv.F90 @ 9383

Last change on this file since 9383 was 9383, checked in by andmirek, 6 years ago

#2050 fixes and changes
File size: 16.0 KB
Line 
1MODULE traadv
2   !!==============================================================================
3   !!                       ***  MODULE  traadv  ***
4   !! Ocean active tracers:  advection trend
5   !!==============================================================================
6   !! History :  2.0  !  2005-11  (G. Madec)  Original code
7   !!            3.3  !  2010-09  (C. Ethe, G. Madec)  merge TRC-TRA + switch from velocity to transport
8   !!            4.0  !  2011-06  (G. Madec)  Addition of Mixed Layer Eddy parameterisation
9   !!----------------------------------------------------------------------
10
11   !!----------------------------------------------------------------------
12   !!   tra_adv      : compute ocean tracer advection trend
13   !!   tra_adv_ctl  : control the different options of advection scheme
14   !!----------------------------------------------------------------------
15   USE oce             ! ocean dynamics and active tracers
16   USE dom_oce         ! ocean space and time domain
17   USE domvvl          ! variable vertical scale factors
18   USE traadv_cen2     ! 2nd order centered scheme (tra_adv_cen2   routine)
19   USE traadv_tvd      ! TVD      scheme           (tra_adv_tvd    routine)
20   USE traadv_muscl    ! MUSCL    scheme           (tra_adv_muscl  routine)
21   USE traadv_muscl2   ! MUSCL2   scheme           (tra_adv_muscl2 routine)
22   USE traadv_ubs      ! UBS      scheme           (tra_adv_ubs    routine)
23   USE traadv_qck      ! QUICKEST scheme           (tra_adv_qck    routine)
24   USE traadv_eiv      ! eddy induced velocity     (tra_adv_eiv    routine)
25   USE traadv_mle      ! ML eddy induced velocity  (tra_adv_mle    routine)
26   USE cla             ! cross land advection      (cla_traadv     routine)
27   USE ldftra_oce      ! lateral diffusion coefficient on tracers
28   USE trd_oce         ! trends: ocean variables
29   USE trdtra          ! trends manager: tracers
30   !
31   USE in_out_manager  ! I/O manager
32   USE iom             ! I/O module
33   USE prtctl          ! Print control
34   USE lib_mpp         ! MPP library
35   USE wrk_nemo        ! Memory Allocation
36   USE timing          ! Timing
37   USE sbc_oce
38   USE diaptr          ! Poleward heat transport
39
40
41   IMPLICIT NONE
42   PRIVATE
43
44   PUBLIC   tra_adv        ! routine called by step module
45   PUBLIC   tra_adv_init   ! routine called by opa module
46   PRIVATE  adv_namelist
47
48   !                              !!* Namelist namtra_adv *
49!make ln_traadv_cen2 public. It's needed when XIOS is used to write restart file
50   LOGICAL, PUBLIC ::   ln_traadv_cen2     ! 2nd order centered scheme flag
51   LOGICAL ::   ln_traadv_tvd      ! TVD scheme flag
52   LOGICAL ::   ln_traadv_tvd_zts  ! TVD scheme flag with vertical sub time-stepping
53   LOGICAL ::   ln_traadv_muscl    ! MUSCL scheme flag
54   LOGICAL ::   ln_traadv_muscl2   ! MUSCL2 scheme flag
55   LOGICAL ::   ln_traadv_ubs      ! UBS scheme flag
56   LOGICAL ::   ln_traadv_qck      ! QUICKEST scheme flag
57   LOGICAL ::   ln_traadv_msc_ups  ! use upstream scheme within muscl
58
59
60   INTEGER ::   nadv   ! choice of the type of advection scheme
61
62   !! * Substitutions
63#  include "domzgr_substitute.h90"
64#  include "vectopt_loop_substitute.h90"
65   !!----------------------------------------------------------------------
66   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
67   !! $Id$
68   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
69   !!----------------------------------------------------------------------
70CONTAINS
71
72   SUBROUTINE tra_adv( kt )
73      !!----------------------------------------------------------------------
74      !!                  ***  ROUTINE tra_adv  ***
75      !!
76      !! ** Purpose :   compute the ocean tracer advection trend.
77      !!
78      !! ** Method  : - Update (ua,va) with the advection term following nadv
79      !!----------------------------------------------------------------------
80      !
81      INTEGER, INTENT( in ) ::   kt   ! ocean time-step index
82      !
83      INTEGER ::   jk   ! dummy loop index
84      REAL(wp), POINTER, DIMENSION(:,:,:) :: zun, zvn, zwn
85      REAL(wp), POINTER, DIMENSION(:,:,:) ::   ztrdt, ztrds   ! 3D workspace
86      !!----------------------------------------------------------------------
87      !
88      IF( nn_timing == 1 )  CALL timing_start('tra_adv')
89      !
90      CALL wrk_alloc( jpi, jpj, jpk, zun, zvn, zwn )
91      !                                          ! set time step
92      IF( neuler == 0 .AND. kt == nit000 ) THEN     ! at nit000
93         r2dtra(:) =  rdttra(:)                          ! = rdtra (restarting with Euler time stepping)
94      ELSEIF( kt <= nit000 + 1) THEN                ! at nit000 or nit000+1
95         r2dtra(:) = 2._wp * rdttra(:)                   ! = 2 rdttra (leapfrog)
96      ENDIF
97      !
98      IF( nn_cla == 1 .AND. cp_cfg == 'orca' .AND. jp_cfg == 2 )   CALL cla_traadv( kt )       !==  Cross Land Advection  ==! (hor. advection)
99      !
100      !                                               !==  effective transport  ==!
101      DO jk = 1, jpkm1
102         zun(:,:,jk) = e2u(:,:) * fse3u(:,:,jk) * un(:,:,jk)                  ! eulerian transport only
103         zvn(:,:,jk) = e1v(:,:) * fse3v(:,:,jk) * vn(:,:,jk)
104         zwn(:,:,jk) = e1t(:,:) * e2t(:,:)      * wn(:,:,jk)
105      END DO
106      !
107      IF( ln_vvl_ztilde .OR. ln_vvl_layer ) THEN
108         zun(:,:,:) = zun(:,:,:) + un_td(:,:,:)
109         zvn(:,:,:) = zvn(:,:,:) + vn_td(:,:,:)
110      ENDIF
111      !
112      zun(:,:,jpk) = 0._wp                                                     ! no transport trough the bottom
113      zvn(:,:,jpk) = 0._wp                                                     ! no transport trough the bottom
114      zwn(:,:,jpk) = 0._wp                                                     ! no transport trough the bottom
115      !
116      IF( lk_traldf_eiv .AND. .NOT. ln_traldf_grif )   &
117         &              CALL tra_adv_eiv( kt, nit000, zun, zvn, zwn, 'TRA' )    ! add the eiv transport (if necessary)
118      !
119      IF( ln_mle    )   CALL tra_adv_mle( kt, nit000, zun, zvn, zwn, 'TRA' )    ! add the mle transport (if necessary)
120      !
121      CALL iom_put( "uocetr_eff", zun )                                         ! output effective transport     
122      CALL iom_put( "vocetr_eff", zvn )
123      CALL iom_put( "wocetr_eff", zwn )
124      !
125      IF( ln_diaptr )   CALL dia_ptr( zvn )                                     ! diagnose the effective MSF
126      !
127      IF( l_trdtra )   THEN                    !* Save ta and sa trends
128         CALL wrk_alloc( jpi, jpj, jpk, ztrdt, ztrds )
129         ztrdt(:,:,:) = tsa(:,:,:,jp_tem)
130         ztrds(:,:,:) = tsa(:,:,:,jp_sal)
131      ENDIF
132      !
133      SELECT CASE ( nadv )                            !==  compute advection trend and add it to general trend  ==!
134      CASE ( 1 )   ;    CALL tra_adv_cen2   ( kt, nit000, 'TRA',         zun, zvn, zwn, tsb, tsn, tsa, jpts )   !  2nd order centered
135      CASE ( 2 )   ;    CALL tra_adv_tvd    ( kt, nit000, 'TRA', r2dtra, zun, zvn, zwn, tsb, tsn, tsa, jpts )   !  TVD
136      CASE ( 3 )   ;    CALL tra_adv_muscl  ( kt, nit000, 'TRA', r2dtra, zun, zvn, zwn, tsb,      tsa, jpts, ln_traadv_msc_ups )   !  MUSCL
137      CASE ( 4 )   ;    CALL tra_adv_muscl2 ( kt, nit000, 'TRA', r2dtra, zun, zvn, zwn, tsb, tsn, tsa, jpts )   !  MUSCL2
138      CASE ( 5 )   ;    CALL tra_adv_ubs    ( kt, nit000, 'TRA', r2dtra, zun, zvn, zwn, tsb, tsn, tsa, jpts )   !  UBS
139      CASE ( 6 )   ;    CALL tra_adv_qck    ( kt, nit000, 'TRA', r2dtra, zun, zvn, zwn, tsb, tsn, tsa, jpts )   !  QUICKEST
140      CASE ( 7 )   ;    CALL tra_adv_tvd_zts( kt, nit000, 'TRA', r2dtra, zun, zvn, zwn, tsb, tsn, tsa, jpts )   !  TVD ZTS
141      !
142      CASE (-1 )                                      !==  esopa: test all possibility with control print  ==!
143         CALL tra_adv_cen2  ( kt, nit000, 'TRA',         zun, zvn, zwn, tsb, tsn, tsa, jpts )         
144         CALL prt_ctl( tab3d_1=tsa(:,:,:,jp_tem), clinfo1=' adv0 - Ta: ', mask1=tmask,               &
145            &          tab3d_2=tsa(:,:,:,jp_sal), clinfo2=       ' Sa: ', mask2=tmask, clinfo3='tra' )
146         CALL tra_adv_tvd   ( kt, nit000, 'TRA', r2dtra, zun, zvn, zwn, tsb, tsn, tsa, jpts )         
147         CALL prt_ctl( tab3d_1=tsa(:,:,:,jp_tem), clinfo1=' adv1 - Ta: ', mask1=tmask,               &
148            &          tab3d_2=tsa(:,:,:,jp_sal), clinfo2=       ' Sa: ', mask2=tmask, clinfo3='tra' )
149         CALL tra_adv_muscl ( kt, nit000, 'TRA', r2dtra, zun, zvn, zwn, tsb,      tsa, jpts, ln_traadv_msc_ups )         
150         CALL prt_ctl( tab3d_1=tsa(:,:,:,jp_tem), clinfo1=' adv3 - Ta: ', mask1=tmask,               &
151            &          tab3d_2=tsa(:,:,:,jp_sal), clinfo2=       ' Sa: ', mask2=tmask, clinfo3='tra' )
152         CALL tra_adv_muscl2( kt, nit000, 'TRA', r2dtra, zun, zvn, zwn, tsb, tsn, tsa, jpts )         
153         CALL prt_ctl( tab3d_1=tsa(:,:,:,jp_tem), clinfo1=' adv4 - Ta: ', mask1=tmask,               &
154            &          tab3d_2=tsa(:,:,:,jp_sal), clinfo2=       ' Sa: ', mask2=tmask, clinfo3='tra' )
155         CALL tra_adv_ubs   ( kt, nit000, 'TRA', r2dtra, zun, zvn, zwn, tsb, tsn, tsa, jpts )         
156         CALL prt_ctl( tab3d_1=tsa(:,:,:,jp_tem), clinfo1=' adv5 - Ta: ', mask1=tmask,               &
157            &          tab3d_2=tsa(:,:,:,jp_sal), clinfo2=       ' Sa: ', mask2=tmask, clinfo3='tra' )
158         CALL tra_adv_qck   ( kt, nit000, 'TRA', r2dtra, zun, zvn, zwn, tsb, tsn, tsa, jpts )         
159         CALL prt_ctl( tab3d_1=tsa(:,:,:,jp_tem), clinfo1=' adv6 - Ta: ', mask1=tmask,               &
160            &          tab3d_2=tsa(:,:,:,jp_sal), clinfo2=       ' Sa: ', mask2=tmask, clinfo3='tra' )
161      END SELECT
162      !
163      IF( l_trdtra )   THEN                      ! save the advective trends for further diagnostics
164         DO jk = 1, jpkm1
165            ztrdt(:,:,jk) = tsa(:,:,jk,jp_tem) - ztrdt(:,:,jk)
166            ztrds(:,:,jk) = tsa(:,:,jk,jp_sal) - ztrds(:,:,jk)
167         END DO
168         CALL trd_tra( kt, 'TRA', jp_tem, jptra_totad, ztrdt )
169         CALL trd_tra( kt, 'TRA', jp_sal, jptra_totad, ztrds )
170         CALL wrk_dealloc( jpi, jpj, jpk, ztrdt, ztrds )
171      ENDIF
172      !                                              ! print mean trends (used for debugging)
173      IF(ln_ctl)   CALL prt_ctl( tab3d_1=tsa(:,:,:,jp_tem), clinfo1=' adv  - Ta: ', mask1=tmask,               &
174         &                       tab3d_2=tsa(:,:,:,jp_sal), clinfo2=       ' Sa: ', mask2=tmask, clinfo3='tra' )
175      !
176      IF( nn_timing == 1 )  CALL timing_stop( 'tra_adv' )
177      !
178      CALL wrk_dealloc( jpi, jpj, jpk, zun, zvn, zwn )
179      !                                         
180   END SUBROUTINE tra_adv
181
182
183   SUBROUTINE tra_adv_init
184      !!---------------------------------------------------------------------
185      !!                  ***  ROUTINE tra_adv_init  ***
186      !!               
187      !! ** Purpose :   Control the consistency between namelist options for
188      !!              tracer advection schemes and set nadv
189      !!----------------------------------------------------------------------
190      INTEGER ::   ioptio
191      INTEGER ::   ios                 ! Local integer output status for namelist read
192      !!
193      NAMELIST/namtra_adv/ ln_traadv_cen2 , ln_traadv_tvd,     &
194         &                 ln_traadv_muscl, ln_traadv_muscl2,  &
195         &                 ln_traadv_ubs  , ln_traadv_qck,     &
196         &                 ln_traadv_msc_ups, ln_traadv_tvd_zts
197      !!----------------------------------------------------------------------
198      IF(lwm) THEN
199         REWIND( numnam_ref )              ! Namelist namtra_adv in reference namelist : Tracer advection scheme
200         READ  ( numnam_ref, namtra_adv, IOSTAT = ios, ERR = 901)
201901      CONTINUE
202      ENDIF
203      call mpp_bcast(ios)
204      IF( ios /= 0 ) CALL ctl_nam ( ios , 'namtra_adv in reference namelist', lwp )
205      IF(lwm) THEN
206         REWIND( numnam_cfg )              ! Namelist namtra_adv in configuration namelist : Tracer advection scheme
207         READ  ( numnam_cfg, namtra_adv, IOSTAT = ios, ERR = 902 )
208902      CONTINUE
209      ENDIF
210      call mpp_bcast(ios)
211      IF( ios /= 0 ) CALL ctl_nam ( ios , 'namtra_adv in configuration namelist', lwp )
212      IF(lwm) WRITE ( numond, namtra_adv )
213
214      call adv_namelist()
215
216      IF(lwp) THEN                    ! Namelist print
217         WRITE(numout,*)
218         WRITE(numout,*) 'tra_adv_init : choice/control of the tracer advection scheme'
219         WRITE(numout,*) '~~~~~~~~~~~'
220         WRITE(numout,*) '   Namelist namtra_adv : chose a advection scheme for tracers'
221         WRITE(numout,*) '      2nd order advection scheme     ln_traadv_cen2    = ', ln_traadv_cen2
222         WRITE(numout,*) '      TVD advection scheme           ln_traadv_tvd     = ', ln_traadv_tvd
223         WRITE(numout,*) '      MUSCL  advection scheme        ln_traadv_muscl   = ', ln_traadv_muscl
224         WRITE(numout,*) '      MUSCL2 advection scheme        ln_traadv_muscl2  = ', ln_traadv_muscl2
225         WRITE(numout,*) '      UBS    advection scheme        ln_traadv_ubs     = ', ln_traadv_ubs
226         WRITE(numout,*) '      QUICKEST advection scheme      ln_traadv_qck     = ', ln_traadv_qck
227         WRITE(numout,*) '      upstream scheme within muscl   ln_traadv_msc_ups = ', ln_traadv_msc_ups
228         WRITE(numout,*) '      TVD advection scheme with zts  ln_traadv_tvd_zts = ', ln_traadv_tvd_zts
229      ENDIF
230
231      ioptio = 0                      ! Parameter control
232      IF( ln_traadv_cen2   )   ioptio = ioptio + 1
233      IF( ln_traadv_tvd    )   ioptio = ioptio + 1
234      IF( ln_traadv_muscl  )   ioptio = ioptio + 1
235      IF( ln_traadv_muscl2 )   ioptio = ioptio + 1
236      IF( ln_traadv_ubs    )   ioptio = ioptio + 1
237      IF( ln_traadv_qck    )   ioptio = ioptio + 1
238      IF( ln_traadv_tvd_zts)   ioptio = ioptio + 1
239      IF( lk_esopa         )   ioptio =          1
240
241      IF( ( ln_traadv_muscl .OR. ln_traadv_muscl2 .OR. ln_traadv_ubs .OR. ln_traadv_qck .OR. ln_traadv_tvd_zts )   &
242         .AND. ln_isfcav )   CALL ctl_stop( 'Only traadv_cen2 and traadv_tvd is compatible with ice shelf cavity')
243
244      IF( ioptio /= 1 )   CALL ctl_stop( 'Choose ONE advection scheme in namelist namtra_adv' )
245
246      !                              ! Set nadv
247      IF( ln_traadv_cen2   )   nadv =  1
248      IF( ln_traadv_tvd    )   nadv =  2
249      IF( ln_traadv_muscl  )   nadv =  3
250      IF( ln_traadv_muscl2 )   nadv =  4
251      IF( ln_traadv_ubs    )   nadv =  5
252      IF( ln_traadv_qck    )   nadv =  6
253      IF( ln_traadv_tvd_zts)   nadv =  7
254      IF( lk_esopa         )   nadv = -1
255
256      IF(lwp) THEN                   ! Print the choice
257         WRITE(numout,*)
258         IF( nadv ==  1 )   WRITE(numout,*) '         2nd order scheme is used'
259         IF( nadv ==  2 )   WRITE(numout,*) '         TVD       scheme is used'
260         IF( nadv ==  3 )   WRITE(numout,*) '         MUSCL     scheme is used'
261         IF( nadv ==  4 )   WRITE(numout,*) '         MUSCL2    scheme is used'
262         IF( nadv ==  5 )   WRITE(numout,*) '         UBS       scheme is used'
263         IF( nadv ==  6 )   WRITE(numout,*) '         QUICKEST  scheme is used'
264         IF( nadv ==  7 )   WRITE(numout,*) '         TVD ZTS   scheme is used'
265         IF( nadv == -1 )   WRITE(numout,*) '         esopa test: use all advection scheme'
266      ENDIF
267      !
268      CALL tra_adv_mle_init          ! initialisation of the Mixed Layer Eddy parametrisation (MLE)
269      lr_traadv_cen2 = ln_traadv_cen2
270      !
271   END SUBROUTINE tra_adv_init
272
273   SUBROUTINE adv_namelist()
274     !!---------------------------------------------------------------------
275     !!                   ***  ROUTINE adv_namelist  ***
276     !!                     
277     !! ** Purpose :   Broadcast namelist variables read by procesor lwm
278     !!
279     !! ** Method  :   use lib_mpp
280     !!----------------------------------------------------------------------
281#if defined key_mpp_mpi
282      CALL mpp_bcast(ln_traadv_cen2)
283      CALL mpp_bcast(ln_traadv_tvd)
284      CALL mpp_bcast(ln_traadv_muscl)
285      CALL mpp_bcast(ln_traadv_muscl2)
286      CALL mpp_bcast(ln_traadv_ubs)
287      CALL mpp_bcast(ln_traadv_qck)
288      CALL mpp_bcast(ln_traadv_msc_ups)
289      CALL mpp_bcast(ln_traadv_tvd_zts)
290#endif
291   END SUBROUTINE adv_namelist
292
293  !!======================================================================
294END MODULE traadv
Note: See TracBrowser for help on using the repository browser.