| 1 | MODULE sbcmod |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE sbcmod *** |
|---|
| 4 | !! Surface module : provide to the ocean its surface boundary condition |
|---|
| 5 | !!====================================================================== |
|---|
| 6 | !! History : 3.0 ! 2006-07 (G. Madec) Original code |
|---|
| 7 | !! 3.1 ! 2008-08 (S. Masson, A. Caubel, E. Maisonnave, G. Madec) coupled interface |
|---|
| 8 | !! 3.3 ! 2010-04 (M. Leclair, G. Madec) Forcing averaged over 2 time steps |
|---|
| 9 | !! 3.3 ! 2010-10 (S. Masson) add diurnal cycle |
|---|
| 10 | !! 3.3 ! 2010-09 (D. Storkey) add ice boundary conditions (BDY) |
|---|
| 11 | !! - ! 2010-11 (G. Madec) ice-ocean stress always computed at each ocean time-step |
|---|
| 12 | !! - ! 2010-10 (J. Chanut, C. Bricaud, G. Madec) add the surface pressure forcing |
|---|
| 13 | !! 3.4 ! 2011-11 (C. Harris) CICE added as an option |
|---|
| 14 | !! 3.5 ! 2012-11 (A. Coward, G. Madec) Rethink of heat, mass and salt surface fluxes |
|---|
| 15 | !! 3.6 ! 2014-11 (P. Mathiot, C. Harris) add ice shelves melting |
|---|
| 16 | !!---------------------------------------------------------------------- |
|---|
| 17 | |
|---|
| 18 | !!---------------------------------------------------------------------- |
|---|
| 19 | !! sbc_init : read namsbc namelist |
|---|
| 20 | !! sbc : surface ocean momentum, heat and freshwater boundary conditions |
|---|
| 21 | !!---------------------------------------------------------------------- |
|---|
| 22 | USE oce ! ocean dynamics and tracers |
|---|
| 23 | USE dom_oce ! ocean space and time domain |
|---|
| 24 | USE phycst ! physical constants |
|---|
| 25 | USE sbc_oce ! Surface boundary condition: ocean fields |
|---|
| 26 | USE trc_oce ! shared ocean-passive tracers variables |
|---|
| 27 | USE sbc_ice ! Surface boundary condition: ice fields |
|---|
| 28 | USE sbcdcy ! surface boundary condition: diurnal cycle |
|---|
| 29 | USE sbcssm ! surface boundary condition: sea-surface mean variables |
|---|
| 30 | USE sbcapr ! surface boundary condition: atmospheric pressure |
|---|
| 31 | USE sbcana ! surface boundary condition: analytical formulation |
|---|
| 32 | USE sbcflx ! surface boundary condition: flux formulation |
|---|
| 33 | USE sbcblk_clio ! surface boundary condition: bulk formulation : CLIO |
|---|
| 34 | USE sbcblk_core ! surface boundary condition: bulk formulation : CORE |
|---|
| 35 | USE sbcblk_mfs ! surface boundary condition: bulk formulation : MFS |
|---|
| 36 | USE sbcice_if ! surface boundary condition: ice-if sea-ice model |
|---|
| 37 | USE sbcice_lim ! surface boundary condition: LIM 3.0 sea-ice model |
|---|
| 38 | USE sbcice_lim_2 ! surface boundary condition: LIM 2.0 sea-ice model |
|---|
| 39 | USE sbcice_cice ! surface boundary condition: CICE sea-ice model |
|---|
| 40 | USE sbccpl ! surface boundary condition: coupled florulation |
|---|
| 41 | USE cpl_oasis3 ! OASIS routines for coupling |
|---|
| 42 | USE sbcssr ! surface boundary condition: sea surface restoring |
|---|
| 43 | USE sbcrnf ! surface boundary condition: runoffs |
|---|
| 44 | USE sbcisf ! surface boundary condition: ice shelf |
|---|
| 45 | USE sbcfwb ! surface boundary condition: freshwater budget |
|---|
| 46 | USE closea ! closed sea |
|---|
| 47 | USE icbstp ! Icebergs! |
|---|
| 48 | |
|---|
| 49 | USE prtctl ! Print control (prt_ctl routine) |
|---|
| 50 | USE iom ! IOM library |
|---|
| 51 | USE in_out_manager ! I/O manager |
|---|
| 52 | USE lib_mpp ! MPP library |
|---|
| 53 | USE timing ! Timing |
|---|
| 54 | USE sbcwave ! Wave module |
|---|
| 55 | USE bdy_par ! Require lk_bdy |
|---|
| 56 | USE iom_def, ONLY : lxios_read |
|---|
| 57 | USE iom_def, ONLY : lwxios |
|---|
| 58 | |
|---|
| 59 | IMPLICIT NONE |
|---|
| 60 | PRIVATE |
|---|
| 61 | |
|---|
| 62 | PUBLIC sbc ! routine called by step.F90 |
|---|
| 63 | PUBLIC sbc_init ! routine called by opa.F90 |
|---|
| 64 | PRIVATE sbc_namelist |
|---|
| 65 | |
|---|
| 66 | INTEGER :: nsbc ! type of surface boundary condition (deduced from namsbc informations) |
|---|
| 67 | |
|---|
| 68 | !! * Substitutions |
|---|
| 69 | # include "domzgr_substitute.h90" |
|---|
| 70 | !!---------------------------------------------------------------------- |
|---|
| 71 | !! NEMO/OPA 4.0 , NEMO-consortium (2011) |
|---|
| 72 | !! $Id$ |
|---|
| 73 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
|---|
| 74 | !!---------------------------------------------------------------------- |
|---|
| 75 | CONTAINS |
|---|
| 76 | |
|---|
| 77 | SUBROUTINE sbc_init |
|---|
| 78 | !!--------------------------------------------------------------------- |
|---|
| 79 | !! *** ROUTINE sbc_init *** |
|---|
| 80 | !! |
|---|
| 81 | !! ** Purpose : Initialisation of the ocean surface boundary computation |
|---|
| 82 | !! |
|---|
| 83 | !! ** Method : Read the namsbc namelist and set derived parameters |
|---|
| 84 | !! Call init routines for all other SBC modules that have one |
|---|
| 85 | !! |
|---|
| 86 | !! ** Action : - read namsbc parameters |
|---|
| 87 | !! - nsbc: type of sbc |
|---|
| 88 | !!---------------------------------------------------------------------- |
|---|
| 89 | INTEGER :: icpt ! local integer |
|---|
| 90 | !! |
|---|
| 91 | NAMELIST/namsbc/ nn_fsbc , ln_ana , ln_flx, ln_blk_clio, ln_blk_core, ln_mixcpl, & |
|---|
| 92 | & ln_blk_mfs, ln_apr_dyn, nn_ice, nn_ice_embd, ln_dm2dc , ln_rnf , & |
|---|
| 93 | & ln_ssr , nn_isf , nn_fwb, ln_cdgw , ln_wave , ln_sdw , & |
|---|
| 94 | & nn_lsm , nn_limflx , nn_components, ln_cpl |
|---|
| 95 | INTEGER :: ios |
|---|
| 96 | INTEGER :: ierr, ierr0, ierr1, ierr2, ierr3, jpm |
|---|
| 97 | LOGICAL :: ll_purecpl |
|---|
| 98 | !!---------------------------------------------------------------------- |
|---|
| 99 | |
|---|
| 100 | IF(lwp) THEN |
|---|
| 101 | WRITE(numout,*) |
|---|
| 102 | WRITE(numout,*) 'sbc_init : surface boundary condition setting' |
|---|
| 103 | WRITE(numout,*) '~~~~~~~~ ' |
|---|
| 104 | ENDIF |
|---|
| 105 | IF(lwm) THEN |
|---|
| 106 | REWIND( numnam_ref ) ! Namelist namsbc in reference namelist : Surface boundary |
|---|
| 107 | READ ( numnam_ref, namsbc, IOSTAT = ios, ERR = 901) |
|---|
| 108 | 901 CONTINUE |
|---|
| 109 | ENDIF |
|---|
| 110 | call mpp_bcast(ios) |
|---|
| 111 | IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc in reference namelist', lwp ) |
|---|
| 112 | IF(lwm) THEN |
|---|
| 113 | REWIND( numnam_cfg ) ! Namelist namsbc in configuration namelist : Parameters of the run |
|---|
| 114 | READ ( numnam_cfg, namsbc, IOSTAT = ios, ERR = 902 ) |
|---|
| 115 | 902 CONTINUE |
|---|
| 116 | ENDIF |
|---|
| 117 | call mpp_bcast(ios) |
|---|
| 118 | IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc in configuration namelist', lwp ) |
|---|
| 119 | |
|---|
| 120 | IF(lwm) WRITE ( numond, namsbc ) |
|---|
| 121 | |
|---|
| 122 | CALL sbc_namelist() |
|---|
| 123 | ! ! overwrite namelist parameter using CPP key information |
|---|
| 124 | IF( Agrif_Root() ) THEN ! AGRIF zoom |
|---|
| 125 | IF( lk_lim2 ) nn_ice = 2 |
|---|
| 126 | IF( lk_lim3 ) nn_ice = 3 |
|---|
| 127 | IF( lk_cice ) nn_ice = 4 |
|---|
| 128 | ENDIF |
|---|
| 129 | IF( cp_cfg == 'gyre' ) THEN ! GYRE configuration |
|---|
| 130 | ln_ana = .TRUE. |
|---|
| 131 | nn_ice = 0 |
|---|
| 132 | ENDIF |
|---|
| 133 | |
|---|
| 134 | IF(lwp) THEN ! Control print |
|---|
| 135 | WRITE(numout,*) ' Namelist namsbc (partly overwritten with CPP key setting)' |
|---|
| 136 | WRITE(numout,*) ' frequency update of sbc (and ice) nn_fsbc = ', nn_fsbc |
|---|
| 137 | WRITE(numout,*) ' Type of sbc : ' |
|---|
| 138 | WRITE(numout,*) ' analytical formulation ln_ana = ', ln_ana |
|---|
| 139 | WRITE(numout,*) ' flux formulation ln_flx = ', ln_flx |
|---|
| 140 | WRITE(numout,*) ' CLIO bulk formulation ln_blk_clio = ', ln_blk_clio |
|---|
| 141 | WRITE(numout,*) ' CORE bulk formulation ln_blk_core = ', ln_blk_core |
|---|
| 142 | WRITE(numout,*) ' MFS bulk formulation ln_blk_mfs = ', ln_blk_mfs |
|---|
| 143 | WRITE(numout,*) ' ocean-atmosphere coupled formulation ln_cpl = ', ln_cpl |
|---|
| 144 | WRITE(numout,*) ' forced-coupled mixed formulation ln_mixcpl = ', ln_mixcpl |
|---|
| 145 | WRITE(numout,*) ' OASIS coupling (with atm or sas) lk_oasis = ', lk_oasis |
|---|
| 146 | WRITE(numout,*) ' components of your executable nn_components = ', nn_components |
|---|
| 147 | WRITE(numout,*) ' Multicategory heat flux formulation (LIM3) nn_limflx = ', nn_limflx |
|---|
| 148 | WRITE(numout,*) ' Misc. options of sbc : ' |
|---|
| 149 | WRITE(numout,*) ' Patm gradient added in ocean & ice Eqs. ln_apr_dyn = ', ln_apr_dyn |
|---|
| 150 | WRITE(numout,*) ' ice management in the sbc (=0/1/2/3) nn_ice = ', nn_ice |
|---|
| 151 | WRITE(numout,*) ' ice-ocean embedded/levitating (=0/1/2) nn_ice_embd = ', nn_ice_embd |
|---|
| 152 | WRITE(numout,*) ' daily mean to diurnal cycle qsr ln_dm2dc = ', ln_dm2dc |
|---|
| 153 | WRITE(numout,*) ' runoff / runoff mouths ln_rnf = ', ln_rnf |
|---|
| 154 | WRITE(numout,*) ' iceshelf formulation nn_isf = ', nn_isf |
|---|
| 155 | WRITE(numout,*) ' Sea Surface Restoring on SST and/or SSS ln_ssr = ', ln_ssr |
|---|
| 156 | WRITE(numout,*) ' FreshWater Budget control (=0/1/2) nn_fwb = ', nn_fwb |
|---|
| 157 | WRITE(numout,*) ' closed sea (=0/1) (set in namdom) nn_closea = ', nn_closea |
|---|
| 158 | WRITE(numout,*) ' n. of iterations if land-sea-mask applied nn_lsm = ', nn_lsm |
|---|
| 159 | ENDIF |
|---|
| 160 | |
|---|
| 161 | ! LIM3 Multi-category heat flux formulation |
|---|
| 162 | SELECT CASE ( nn_limflx) |
|---|
| 163 | CASE ( -1 ) |
|---|
| 164 | IF(lwp) WRITE(numout,*) ' Use of per-category fluxes (nn_limflx = -1) ' |
|---|
| 165 | CASE ( 0 ) |
|---|
| 166 | IF(lwp) WRITE(numout,*) ' Average per-category fluxes (nn_limflx = 0) ' |
|---|
| 167 | CASE ( 1 ) |
|---|
| 168 | IF(lwp) WRITE(numout,*) ' Average then redistribute per-category fluxes (nn_limflx = 1) ' |
|---|
| 169 | CASE ( 2 ) |
|---|
| 170 | IF(lwp) WRITE(numout,*) ' Redistribute a single flux over categories (nn_limflx = 2) ' |
|---|
| 171 | END SELECT |
|---|
| 172 | ! |
|---|
| 173 | IF ( nn_components /= jp_iam_nemo .AND. .NOT. lk_oasis ) & |
|---|
| 174 | & CALL ctl_stop( 'STOP', 'sbc_init : OPA-SAS coupled via OASIS, but key_oasis3 disabled' ) |
|---|
| 175 | IF ( nn_components == jp_iam_opa .AND. ln_cpl ) & |
|---|
| 176 | & CALL ctl_stop( 'STOP', 'sbc_init : OPA-SAS coupled via OASIS, but ln_cpl = T in OPA' ) |
|---|
| 177 | IF ( nn_components == jp_iam_opa .AND. ln_mixcpl ) & |
|---|
| 178 | & CALL ctl_stop( 'STOP', 'sbc_init : OPA-SAS coupled via OASIS, but ln_mixcpl = T in OPA' ) |
|---|
| 179 | IF ( ln_cpl .AND. .NOT. lk_oasis ) & |
|---|
| 180 | & CALL ctl_stop( 'STOP', 'sbc_init : OASIS-coupled atmosphere model, but key_oasis3 disabled' ) |
|---|
| 181 | IF( ln_mixcpl .AND. .NOT. lk_oasis ) & |
|---|
| 182 | & CALL ctl_stop( 'the forced-coupled mixed mode (ln_mixcpl) requires the cpp key key_oasis3' ) |
|---|
| 183 | IF( ln_mixcpl .AND. .NOT. ln_cpl ) & |
|---|
| 184 | & CALL ctl_stop( 'the forced-coupled mixed mode (ln_mixcpl) requires ln_cpl = T' ) |
|---|
| 185 | IF( ln_mixcpl .AND. nn_components /= jp_iam_nemo ) & |
|---|
| 186 | & CALL ctl_stop( 'the forced-coupled mixed mode (ln_mixcpl) is not yet working with sas-opa coupling via oasis' ) |
|---|
| 187 | |
|---|
| 188 | ! ! allocate sbc arrays |
|---|
| 189 | IF( sbc_oce_alloc() /= 0 ) CALL ctl_stop( 'STOP', 'sbc_init : unable to allocate sbc_oce arrays' ) |
|---|
| 190 | |
|---|
| 191 | ! ! Checks: |
|---|
| 192 | IF( nn_isf .EQ. 0 ) THEN ! variable initialisation if no ice shelf |
|---|
| 193 | IF( sbc_isf_alloc() /= 0 ) CALL ctl_stop( 'STOP', 'sbc_init : unable to allocate sbc_isf arrays' ) |
|---|
| 194 | fwfisf (:,:) = 0.0_wp ; fwfisf_b (:,:) = 0.0_wp |
|---|
| 195 | risf_tsc(:,:,:) = 0.0_wp ; risf_tsc_b(:,:,:) = 0.0_wp |
|---|
| 196 | rdivisf = 0.0_wp |
|---|
| 197 | END IF |
|---|
| 198 | IF( nn_ice == 0 .AND. nn_components /= jp_iam_opa ) fr_i(:,:) = 0.e0 ! no ice in the domain, ice fraction is always zero |
|---|
| 199 | |
|---|
| 200 | sfx(:,:) = 0.0_wp ! the salt flux due to freezing/melting will be computed (i.e. will be non-zero) |
|---|
| 201 | ! only if sea-ice is present |
|---|
| 202 | |
|---|
| 203 | fmmflx(:,:) = 0.0_wp ! freezing-melting array initialisation |
|---|
| 204 | |
|---|
| 205 | taum(:,:) = 0.0_wp ! Initialise taum for use in gls in case of reduced restart |
|---|
| 206 | |
|---|
| 207 | ! ! restartability |
|---|
| 208 | IF( ( nn_ice == 2 .OR. nn_ice ==3 ) .AND. .NOT.( ln_blk_clio .OR. ln_blk_core .OR. ln_cpl ) ) & |
|---|
| 209 | & CALL ctl_stop( 'LIM sea-ice model requires a bulk formulation or coupled configuration' ) |
|---|
| 210 | IF( nn_ice == 4 .AND. .NOT.( ln_blk_core .OR. ln_cpl ) ) & |
|---|
| 211 | & CALL ctl_stop( 'CICE sea-ice model requires ln_blk_core or ln_cpl' ) |
|---|
| 212 | IF( nn_ice == 4 .AND. lk_agrif ) & |
|---|
| 213 | & CALL ctl_stop( 'CICE sea-ice model not currently available with AGRIF' ) |
|---|
| 214 | IF( ( nn_ice == 3 .OR. nn_ice == 4 ) .AND. nn_ice_embd == 0 ) & |
|---|
| 215 | & CALL ctl_stop( 'LIM3 and CICE sea-ice models require nn_ice_embd = 1 or 2' ) |
|---|
| 216 | IF( ( nn_ice /= 3 ) .AND. ( nn_limflx >= 0 ) ) & |
|---|
| 217 | & WRITE(numout,*) 'The nn_limflx>=0 option has no effect if sea ice model is not LIM3' |
|---|
| 218 | IF( ( nn_ice == 3 ) .AND. ( ln_cpl ) .AND. ( ( nn_limflx == -1 ) .OR. ( nn_limflx == 1 ) ) ) & |
|---|
| 219 | & CALL ctl_stop( 'The chosen nn_limflx for LIM3 in coupled mode must be 0 or 2' ) |
|---|
| 220 | IF( ( nn_ice == 3 ) .AND. ( .NOT. ln_cpl ) .AND. ( nn_limflx == 2 ) ) & |
|---|
| 221 | & CALL ctl_stop( 'The chosen nn_limflx for LIM3 in forced mode cannot be 2' ) |
|---|
| 222 | |
|---|
| 223 | IF( ln_dm2dc ) nday_qsr = -1 ! initialisation flag |
|---|
| 224 | |
|---|
| 225 | IF( ln_dm2dc .AND. .NOT.( ln_flx .OR. ln_blk_core ) .AND. nn_components /= jp_iam_opa ) & |
|---|
| 226 | & CALL ctl_stop( 'diurnal cycle into qsr field from daily values requires a flux or core-bulk formulation' ) |
|---|
| 227 | |
|---|
| 228 | IF ( ln_wave ) THEN |
|---|
| 229 | !Activated wave module but neither drag nor stokes drift activated |
|---|
| 230 | IF ( .NOT.(ln_cdgw .OR. ln_sdw) ) THEN |
|---|
| 231 | CALL ctl_warn( 'Ask for wave coupling but nor drag coefficient (ln_cdgw=F) neither stokes drift activated (ln_sdw=F)' ) |
|---|
| 232 | !drag coefficient read from wave model definable only with mfs bulk formulae and core |
|---|
| 233 | ELSEIF (ln_cdgw .AND. .NOT.(ln_blk_mfs .OR. ln_blk_core) ) THEN |
|---|
| 234 | CALL ctl_stop( 'drag coefficient read from wave model definable only with mfs bulk formulae and core') |
|---|
| 235 | ENDIF |
|---|
| 236 | ELSE |
|---|
| 237 | IF ( ln_cdgw .OR. ln_sdw ) & |
|---|
| 238 | & CALL ctl_stop('Not Activated Wave Module (ln_wave=F) but & |
|---|
| 239 | & asked coupling with drag coefficient (ln_cdgw =T) or Stokes drift (ln_sdw=T) ') |
|---|
| 240 | ENDIF |
|---|
| 241 | ! ! Choice of the Surface Boudary Condition (set nsbc) |
|---|
| 242 | ll_purecpl = ln_cpl .AND. .NOT. ln_mixcpl |
|---|
| 243 | ! |
|---|
| 244 | icpt = 0 |
|---|
| 245 | IF( ln_ana ) THEN ; nsbc = jp_ana ; icpt = icpt + 1 ; ENDIF ! analytical formulation |
|---|
| 246 | IF( ln_flx ) THEN ; nsbc = jp_flx ; icpt = icpt + 1 ; ENDIF ! flux formulation |
|---|
| 247 | IF( ln_blk_clio ) THEN ; nsbc = jp_clio ; icpt = icpt + 1 ; ENDIF ! CLIO bulk formulation |
|---|
| 248 | IF( ln_blk_core ) THEN ; nsbc = jp_core ; icpt = icpt + 1 ; ENDIF ! CORE bulk formulation |
|---|
| 249 | IF( ln_blk_mfs ) THEN ; nsbc = jp_mfs ; icpt = icpt + 1 ; ENDIF ! MFS bulk formulation |
|---|
| 250 | IF( ll_purecpl ) THEN ; nsbc = jp_purecpl ; icpt = icpt + 1 ; ENDIF ! Pure Coupled formulation |
|---|
| 251 | IF( cp_cfg == 'gyre') THEN ; nsbc = jp_gyre ; ENDIF ! GYRE analytical formulation |
|---|
| 252 | IF( nn_components == jp_iam_opa ) & |
|---|
| 253 | & THEN ; nsbc = jp_none ; icpt = icpt + 1 ; ENDIF ! opa coupling via SAS module |
|---|
| 254 | IF( lk_esopa ) nsbc = jp_esopa ! esopa test, ALL formulations |
|---|
| 255 | ! |
|---|
| 256 | IF( icpt /= 1 .AND. .NOT.lk_esopa ) THEN |
|---|
| 257 | WRITE(numout,*) |
|---|
| 258 | WRITE(numout,*) ' E R R O R in setting the sbc, one and only one namelist/CPP key option ' |
|---|
| 259 | WRITE(numout,*) ' must be choosen. You choose ', icpt, ' option(s)' |
|---|
| 260 | WRITE(numout,*) ' We stop' |
|---|
| 261 | nstop = nstop + 1 |
|---|
| 262 | ENDIF |
|---|
| 263 | IF(lwp) THEN |
|---|
| 264 | WRITE(numout,*) |
|---|
| 265 | IF( nsbc == jp_esopa ) WRITE(numout,*) ' ESOPA test All surface boundary conditions' |
|---|
| 266 | IF( nsbc == jp_gyre ) WRITE(numout,*) ' GYRE analytical formulation' |
|---|
| 267 | IF( nsbc == jp_ana ) WRITE(numout,*) ' analytical formulation' |
|---|
| 268 | IF( nsbc == jp_flx ) WRITE(numout,*) ' flux formulation' |
|---|
| 269 | IF( nsbc == jp_clio ) WRITE(numout,*) ' CLIO bulk formulation' |
|---|
| 270 | IF( nsbc == jp_core ) WRITE(numout,*) ' CORE bulk formulation' |
|---|
| 271 | IF( nsbc == jp_purecpl ) WRITE(numout,*) ' pure coupled formulation' |
|---|
| 272 | IF( nsbc == jp_mfs ) WRITE(numout,*) ' MFS Bulk formulation' |
|---|
| 273 | IF( nsbc == jp_none ) WRITE(numout,*) ' OPA coupled to SAS via oasis' |
|---|
| 274 | IF( ln_mixcpl ) WRITE(numout,*) ' + forced-coupled mixed formulation' |
|---|
| 275 | IF( nn_components/= jp_iam_nemo ) & |
|---|
| 276 | & WRITE(numout,*) ' + OASIS coupled SAS' |
|---|
| 277 | ENDIF |
|---|
| 278 | ! |
|---|
| 279 | IF( lk_oasis ) CALL sbc_cpl_init (nn_ice) ! OASIS initialisation. must be done before: (1) first time step |
|---|
| 280 | ! ! (2) the use of nn_fsbc |
|---|
| 281 | |
|---|
| 282 | ! nn_fsbc initialization if OPA-SAS coupling via OASIS |
|---|
| 283 | ! sas model time step has to be declared in OASIS (mandatory) -> nn_fsbc has to be modified accordingly |
|---|
| 284 | IF ( nn_components /= jp_iam_nemo ) THEN |
|---|
| 285 | |
|---|
| 286 | IF ( nn_components == jp_iam_opa ) nn_fsbc = cpl_freq('O_SFLX') / NINT(rdt) |
|---|
| 287 | IF ( nn_components == jp_iam_sas ) nn_fsbc = cpl_freq('I_SFLX') / NINT(rdt) |
|---|
| 288 | ! |
|---|
| 289 | IF(lwp)THEN |
|---|
| 290 | WRITE(numout,*) |
|---|
| 291 | WRITE(numout,*)" OPA-SAS coupled via OASIS : nn_fsbc re-defined from OASIS namcouple ", nn_fsbc |
|---|
| 292 | WRITE(numout,*) |
|---|
| 293 | ENDIF |
|---|
| 294 | ENDIF |
|---|
| 295 | |
|---|
| 296 | IF( MOD( nitend - nit000 + 1, nn_fsbc) /= 0 .OR. & |
|---|
| 297 | MOD( nstock , nn_fsbc) /= 0 ) THEN |
|---|
| 298 | WRITE(ctmp1,*) 'experiment length (', nitend - nit000 + 1, ') or nstock (', nstock, & |
|---|
| 299 | & ' is NOT a multiple of nn_fsbc (', nn_fsbc, ')' |
|---|
| 300 | CALL ctl_stop( ctmp1, 'Impossible to properly do model restart' ) |
|---|
| 301 | ENDIF |
|---|
| 302 | ! |
|---|
| 303 | IF( MOD( rday, REAL(nn_fsbc, wp) * rdt ) /= 0 ) & |
|---|
| 304 | & CALL ctl_warn( 'nn_fsbc is NOT a multiple of the number of time steps in a day' ) |
|---|
| 305 | ! |
|---|
| 306 | IF( ln_dm2dc .AND. ( ( NINT(rday) / ( nn_fsbc * NINT(rdt) ) ) < 8 ) ) & |
|---|
| 307 | & CALL ctl_warn( 'diurnal cycle for qsr: the sampling of the diurnal cycle is too small...' ) |
|---|
| 308 | |
|---|
| 309 | CALL sbc_ssm_init ! Sea-surface mean fields initialisation |
|---|
| 310 | ! |
|---|
| 311 | IF( ln_ssr ) CALL sbc_ssr_init ! Sea-Surface Restoring initialisation |
|---|
| 312 | ! |
|---|
| 313 | CALL sbc_rnf_init ! Runof initialisation |
|---|
| 314 | ! |
|---|
| 315 | IF( nn_ice == 3 ) CALL sbc_lim_init ! LIM3 initialisation |
|---|
| 316 | |
|---|
| 317 | IF( nn_ice == 4 ) CALL cice_sbc_init( nsbc ) ! CICE initialisation |
|---|
| 318 | |
|---|
| 319 | END SUBROUTINE sbc_init |
|---|
| 320 | |
|---|
| 321 | |
|---|
| 322 | SUBROUTINE sbc( kt ) |
|---|
| 323 | !!--------------------------------------------------------------------- |
|---|
| 324 | !! *** ROUTINE sbc *** |
|---|
| 325 | !! |
|---|
| 326 | !! ** Purpose : provide at each time-step the ocean surface boundary |
|---|
| 327 | !! condition (momentum, heat and freshwater fluxes) |
|---|
| 328 | !! |
|---|
| 329 | !! ** Method : blah blah to be written ????????? |
|---|
| 330 | !! CAUTION : never mask the surface stress field (tke sbc) |
|---|
| 331 | !! |
|---|
| 332 | !! ** Action : - set the ocean surface boundary condition at before and now |
|---|
| 333 | !! time step, i.e. |
|---|
| 334 | !! utau_b, vtau_b, qns_b, qsr_b, emp_n, sfx_b, qrp_b, erp_b |
|---|
| 335 | !! utau , vtau , qns , qsr , emp , sfx , qrp , erp |
|---|
| 336 | !! - updte the ice fraction : fr_i |
|---|
| 337 | !!---------------------------------------------------------------------- |
|---|
| 338 | INTEGER, INTENT(in) :: kt ! ocean time step |
|---|
| 339 | !!--------------------------------------------------------------------- |
|---|
| 340 | ! |
|---|
| 341 | IF( nn_timing == 1 ) CALL timing_start('sbc') |
|---|
| 342 | ! |
|---|
| 343 | ! ! ---------------------------------------- ! |
|---|
| 344 | IF( kt /= nit000 ) THEN ! Swap of forcing fields ! |
|---|
| 345 | ! ! ---------------------------------------- ! |
|---|
| 346 | utau_b(:,:) = utau(:,:) ! Swap the ocean forcing fields |
|---|
| 347 | vtau_b(:,:) = vtau(:,:) ! (except at nit000 where before fields |
|---|
| 348 | qns_b (:,:) = qns (:,:) ! are set at the end of the routine) |
|---|
| 349 | ! The 3D heat content due to qsr forcing is treated in traqsr |
|---|
| 350 | ! qsr_b (:,:) = qsr (:,:) |
|---|
| 351 | emp_b(:,:) = emp(:,:) |
|---|
| 352 | sfx_b(:,:) = sfx(:,:) |
|---|
| 353 | ENDIF |
|---|
| 354 | ! ! ---------------------------------------- ! |
|---|
| 355 | ! ! forcing field computation ! |
|---|
| 356 | ! ! ---------------------------------------- ! |
|---|
| 357 | ! |
|---|
| 358 | IF ( .NOT. lk_bdy ) then |
|---|
| 359 | IF( ln_apr_dyn ) CALL sbc_apr( kt ) ! atmospheric pressure provided at kt+0.5*nn_fsbc |
|---|
| 360 | ENDIF |
|---|
| 361 | ! (caution called before sbc_ssm) |
|---|
| 362 | ! |
|---|
| 363 | IF( nn_components /= jp_iam_sas ) CALL sbc_ssm( kt ) ! ocean sea surface variables (sst_m, sss_m, ssu_m, ssv_m) |
|---|
| 364 | ! ! averaged over nf_sbc time-step |
|---|
| 365 | |
|---|
| 366 | IF (ln_wave) CALL sbc_wave( kt ) |
|---|
| 367 | !== sbc formulation ==! |
|---|
| 368 | |
|---|
| 369 | SELECT CASE( nsbc ) ! Compute ocean surface boundary condition |
|---|
| 370 | ! ! (i.e. utau,vtau, qns, qsr, emp, sfx) |
|---|
| 371 | CASE( jp_gyre ) ; CALL sbc_gyre ( kt ) ! analytical formulation : GYRE configuration |
|---|
| 372 | CASE( jp_ana ) ; CALL sbc_ana ( kt ) ! analytical formulation : uniform sbc |
|---|
| 373 | CASE( jp_flx ) ; CALL sbc_flx ( kt ) ! flux formulation |
|---|
| 374 | CASE( jp_clio ) ; CALL sbc_blk_clio( kt ) ! bulk formulation : CLIO for the ocean |
|---|
| 375 | CASE( jp_core ) |
|---|
| 376 | IF( nn_components == jp_iam_sas ) & |
|---|
| 377 | & CALL sbc_cpl_rcv ( kt, nn_fsbc, nn_ice ) ! OPA-SAS coupling: SAS receiving fields from OPA |
|---|
| 378 | CALL sbc_blk_core( kt ) ! bulk formulation : CORE for the ocean |
|---|
| 379 | ! from oce: sea surface variables (sst_m, sss_m, ssu_m, ssv_m) |
|---|
| 380 | CASE( jp_purecpl ) ; CALL sbc_cpl_rcv ( kt, nn_fsbc, nn_ice ) ! pure coupled formulation |
|---|
| 381 | ! |
|---|
| 382 | CASE( jp_mfs ) ; CALL sbc_blk_mfs ( kt ) ! bulk formulation : MFS for the ocean |
|---|
| 383 | CASE( jp_none ) |
|---|
| 384 | IF( nn_components == jp_iam_opa ) & |
|---|
| 385 | CALL sbc_cpl_rcv ( kt, nn_fsbc, nn_ice ) ! OPA-SAS coupling: OPA receiving fields from SAS |
|---|
| 386 | CASE( jp_esopa ) |
|---|
| 387 | CALL sbc_ana ( kt ) ! ESOPA, test ALL the formulations |
|---|
| 388 | CALL sbc_gyre ( kt ) ! |
|---|
| 389 | CALL sbc_flx ( kt ) ! |
|---|
| 390 | CALL sbc_blk_clio( kt ) ! |
|---|
| 391 | CALL sbc_blk_core( kt ) ! |
|---|
| 392 | CALL sbc_cpl_rcv ( kt, nn_fsbc, nn_ice ) ! |
|---|
| 393 | END SELECT |
|---|
| 394 | |
|---|
| 395 | IF( ln_mixcpl ) CALL sbc_cpl_rcv ( kt, nn_fsbc, nn_ice ) ! forced-coupled mixed formulation after forcing |
|---|
| 396 | |
|---|
| 397 | |
|---|
| 398 | ! !== Misc. Options ==! |
|---|
| 399 | |
|---|
| 400 | SELECT CASE( nn_ice ) ! Update heat and freshwater fluxes over sea-ice areas |
|---|
| 401 | CASE( 1 ) ; CALL sbc_ice_if ( kt ) ! Ice-cover climatology ("Ice-if" model) |
|---|
| 402 | CASE( 2 ) ; CALL sbc_ice_lim_2( kt, nsbc ) ! LIM-2 ice model |
|---|
| 403 | CASE( 3 ) ; CALL sbc_ice_lim ( kt, nsbc ) ! LIM-3 ice model |
|---|
| 404 | CASE( 4 ) ; CALL sbc_ice_cice ( kt, nsbc ) ! CICE ice model |
|---|
| 405 | END SELECT |
|---|
| 406 | |
|---|
| 407 | IF( ln_icebergs ) CALL icb_stp( kt ) ! compute icebergs |
|---|
| 408 | |
|---|
| 409 | IF( nn_isf /= 0 ) CALL sbc_isf( kt ) ! compute iceshelves |
|---|
| 410 | |
|---|
| 411 | IF( ln_rnf ) CALL sbc_rnf( kt ) ! add runoffs to fresh water fluxes |
|---|
| 412 | |
|---|
| 413 | IF( ln_ssr ) CALL sbc_ssr( kt ) ! add SST/SSS damping term |
|---|
| 414 | |
|---|
| 415 | IF( nn_fwb /= 0 ) CALL sbc_fwb( kt, nn_fwb, nn_fsbc ) ! control the freshwater budget |
|---|
| 416 | |
|---|
| 417 | IF( nn_closea == 1 ) CALL sbc_clo( kt ) ! treatment of closed sea in the model domain |
|---|
| 418 | ! ! (update freshwater fluxes) |
|---|
| 419 | !RBbug do not understand why see ticket 667 |
|---|
| 420 | !clem: it looks like it is necessary for the north fold (in certain circumstances). Don't know why. |
|---|
| 421 | CALL lbc_lnk( emp, 'T', 1. ) |
|---|
| 422 | ! |
|---|
| 423 | IF( kt == nit000 ) THEN ! set the forcing field at nit000 - 1 ! |
|---|
| 424 | ! ! ---------------------------------------- ! |
|---|
| 425 | IF( ln_rstart .AND. & !* Restart: read in restart file |
|---|
| 426 | & iom_varid( numror, 'utau_b', ldstop = .FALSE. ) > 0 ) THEN |
|---|
| 427 | IF(lwp) WRITE(numout,*) ' nit000-1 surface forcing fields red in the restart file' |
|---|
| 428 | CALL iom_get( numror, jpdom_autoglo, 'utau_b', utau_b, lrxios = lxios_read ) ! before i-stress (U-point) |
|---|
| 429 | CALL iom_get( numror, jpdom_autoglo, 'vtau_b', vtau_b, lrxios = lxios_read ) ! before j-stress (V-point) |
|---|
| 430 | CALL iom_get( numror, jpdom_autoglo, 'qns_b' , qns_b, lrxios = lxios_read ) ! before non solar heat flux (T-point) |
|---|
| 431 | ! The 3D heat content due to qsr forcing is treated in traqsr |
|---|
| 432 | ! CALL iom_get( numror, jpdom_autoglo, 'qsr_b' , qsr_b, lrxios = lxios_read ) ! before solar heat flux (T-point) |
|---|
| 433 | CALL iom_get( numror, jpdom_autoglo, 'emp_b', emp_b, lrxios = lxios_read ) ! before freshwater flux (T-point) |
|---|
| 434 | ! To ensure restart capability with 3.3x/3.4 restart files !! to be removed in v3.6 |
|---|
| 435 | IF( iom_varid( numror, 'sfx_b', ldstop = .FALSE. ) > 0 ) THEN |
|---|
| 436 | CALL iom_get( numror, jpdom_autoglo, 'sfx_b', sfx_b, lrxios = lxios_read ) ! before salt flux (T-point) |
|---|
| 437 | ELSE |
|---|
| 438 | sfx_b (:,:) = sfx(:,:) |
|---|
| 439 | ENDIF |
|---|
| 440 | ELSE !* no restart: set from nit000 values |
|---|
| 441 | IF(lwp) WRITE(numout,*) ' nit000-1 surface forcing fields set to nit000' |
|---|
| 442 | utau_b(:,:) = utau(:,:) |
|---|
| 443 | vtau_b(:,:) = vtau(:,:) |
|---|
| 444 | qns_b (:,:) = qns (:,:) |
|---|
| 445 | emp_b (:,:) = emp(:,:) |
|---|
| 446 | sfx_b (:,:) = sfx(:,:) |
|---|
| 447 | ENDIF |
|---|
| 448 | ENDIF |
|---|
| 449 | ! ! ---------------------------------------- ! |
|---|
| 450 | IF( lrst_oce ) THEN ! Write in the ocean restart file ! |
|---|
| 451 | ! ! ---------------------------------------- ! |
|---|
| 452 | IF(lwp) WRITE(numout,*) |
|---|
| 453 | IF(lwp) WRITE(numout,*) 'sbc : ocean surface forcing fields written in ocean restart file ', & |
|---|
| 454 | & 'at it= ', kt,' date= ', ndastp |
|---|
| 455 | IF(lwp) WRITE(numout,*) '~~~~' |
|---|
| 456 | IF( lwxios ) CALL iom_swap( wxios_context ) |
|---|
| 457 | CALL iom_rstput( kt, nitrst, numrow, 'utau_b' , utau, lxios = lwxios ) |
|---|
| 458 | CALL iom_rstput( kt, nitrst, numrow, 'vtau_b' , vtau, lxios = lwxios ) |
|---|
| 459 | CALL iom_rstput( kt, nitrst, numrow, 'qns_b' , qns, lxios = lwxios ) |
|---|
| 460 | ! The 3D heat content due to qsr forcing is treated in traqsr |
|---|
| 461 | ! CALL iom_rstput( kt, nitrst, numrow, 'qsr_b' , qsr ) |
|---|
| 462 | CALL iom_rstput( kt, nitrst, numrow, 'emp_b' , emp, lxios = lwxios ) |
|---|
| 463 | CALL iom_rstput( kt, nitrst, numrow, 'sfx_b' , sfx, lxios = lwxios ) |
|---|
| 464 | IF( lwxios ) CALL iom_swap( cxios_context ) |
|---|
| 465 | ENDIF |
|---|
| 466 | |
|---|
| 467 | ! ! ---------------------------------------- ! |
|---|
| 468 | ! ! Outputs and control print ! |
|---|
| 469 | ! ! ---------------------------------------- ! |
|---|
| 470 | IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN |
|---|
| 471 | CALL iom_put( "empmr" , emp - rnf ) ! upward water flux |
|---|
| 472 | CALL iom_put( "empbmr" , emp_b - rnf ) ! before upward water flux ( needed to recalculate the time evolution of ssh in offline ) |
|---|
| 473 | CALL iom_put( "saltflx", sfx ) ! downward salt flux |
|---|
| 474 | ! (includes virtual salt flux beneath ice |
|---|
| 475 | ! in linear free surface case) |
|---|
| 476 | CALL iom_put( "fmmflx", fmmflx ) ! Freezing-melting water flux |
|---|
| 477 | CALL iom_put( "qt" , qns + qsr ) ! total heat flux |
|---|
| 478 | CALL iom_put( "qns" , qns ) ! solar heat flux |
|---|
| 479 | CALL iom_put( "qsr" , qsr ) ! solar heat flux |
|---|
| 480 | IF( nn_ice > 0 .OR. nn_components == jp_iam_opa ) CALL iom_put( "ice_cover", fr_i ) ! ice fraction |
|---|
| 481 | CALL iom_put( "taum" , taum ) ! wind stress module |
|---|
| 482 | CALL iom_put( "wspd" , wndm ) ! wind speed module over free ocean or leads in presence of sea-ice |
|---|
| 483 | ENDIF |
|---|
| 484 | ! |
|---|
| 485 | CALL iom_put( "utau", utau ) ! i-wind stress (stress can be updated at |
|---|
| 486 | CALL iom_put( "vtau", vtau ) ! j-wind stress each time step in sea-ice) |
|---|
| 487 | ! |
|---|
| 488 | IF(ln_ctl) THEN ! print mean trends (used for debugging) |
|---|
| 489 | CALL prt_ctl(tab2d_1=fr_i , clinfo1=' fr_i - : ', mask1=tmask, ovlap=1 ) |
|---|
| 490 | CALL prt_ctl(tab2d_1=(emp-rnf + fwfisf), clinfo1=' emp-rnf - : ', mask1=tmask, ovlap=1 ) |
|---|
| 491 | CALL prt_ctl(tab2d_1=(sfx-rnf + fwfisf), clinfo1=' sfx-rnf - : ', mask1=tmask, ovlap=1 ) |
|---|
| 492 | CALL prt_ctl(tab2d_1=qns , clinfo1=' qns - : ', mask1=tmask, ovlap=1 ) |
|---|
| 493 | CALL prt_ctl(tab2d_1=qsr , clinfo1=' qsr - : ', mask1=tmask, ovlap=1 ) |
|---|
| 494 | CALL prt_ctl(tab3d_1=tmask , clinfo1=' tmask - : ', mask1=tmask, ovlap=1, kdim=jpk ) |
|---|
| 495 | CALL prt_ctl(tab3d_1=tsn(:,:,:,jp_tem), clinfo1=' sst - : ', mask1=tmask, ovlap=1, kdim=1 ) |
|---|
| 496 | CALL prt_ctl(tab3d_1=tsn(:,:,:,jp_sal), clinfo1=' sss - : ', mask1=tmask, ovlap=1, kdim=1 ) |
|---|
| 497 | CALL prt_ctl(tab2d_1=utau , clinfo1=' utau - : ', mask1=umask, & |
|---|
| 498 | & tab2d_2=vtau , clinfo2=' vtau - : ', mask2=vmask, ovlap=1 ) |
|---|
| 499 | ENDIF |
|---|
| 500 | |
|---|
| 501 | IF( kt == nitend ) CALL sbc_final ! Close down surface module if necessary |
|---|
| 502 | ! |
|---|
| 503 | IF( nn_timing == 1 ) CALL timing_stop('sbc') |
|---|
| 504 | ! |
|---|
| 505 | END SUBROUTINE sbc |
|---|
| 506 | |
|---|
| 507 | |
|---|
| 508 | SUBROUTINE sbc_final |
|---|
| 509 | !!--------------------------------------------------------------------- |
|---|
| 510 | !! *** ROUTINE sbc_final *** |
|---|
| 511 | !! |
|---|
| 512 | !! ** Purpose : Finalize CICE (if used) |
|---|
| 513 | !!--------------------------------------------------------------------- |
|---|
| 514 | ! |
|---|
| 515 | IF( nn_ice == 4 ) CALL cice_sbc_final |
|---|
| 516 | ! |
|---|
| 517 | END SUBROUTINE sbc_final |
|---|
| 518 | |
|---|
| 519 | SUBROUTINE sbc_namelist() |
|---|
| 520 | !!--------------------------------------------------------------------- |
|---|
| 521 | !! *** ROUTINE sbc_namelist *** |
|---|
| 522 | !! |
|---|
| 523 | !! ** Purpose : Broadcast namelist variables read by procesor lwm |
|---|
| 524 | !! |
|---|
| 525 | !! ** Method : use lib_mpp |
|---|
| 526 | !!---------------------------------------------------------------------- |
|---|
| 527 | #if defined key_mpp_mpi |
|---|
| 528 | CALL mpp_bcast(nn_fsbc) |
|---|
| 529 | CALL mpp_bcast(ln_ana) |
|---|
| 530 | CALL mpp_bcast(ln_flx) |
|---|
| 531 | CALL mpp_bcast(ln_blk_clio) |
|---|
| 532 | CALL mpp_bcast(ln_blk_core) |
|---|
| 533 | CALL mpp_bcast(ln_mixcpl) |
|---|
| 534 | CALL mpp_bcast(ln_blk_mfs) |
|---|
| 535 | CALL mpp_bcast(ln_apr_dyn) |
|---|
| 536 | CALL mpp_bcast(nn_ice) |
|---|
| 537 | CALL mpp_bcast(nn_ice_embd) |
|---|
| 538 | CALL mpp_bcast(ln_dm2dc) |
|---|
| 539 | CALL mpp_bcast(ln_rnf) |
|---|
| 540 | CALL mpp_bcast(ln_ssr) |
|---|
| 541 | CALL mpp_bcast(nn_isf) |
|---|
| 542 | CALL mpp_bcast(nn_fwb) |
|---|
| 543 | CALL mpp_bcast(ln_cdgw) |
|---|
| 544 | CALL mpp_bcast(ln_wave) |
|---|
| 545 | CALL mpp_bcast(ln_sdw) |
|---|
| 546 | CALL mpp_bcast(nn_lsm) |
|---|
| 547 | CALL mpp_bcast(nn_limflx) |
|---|
| 548 | CALL mpp_bcast(nn_components) |
|---|
| 549 | CALL mpp_bcast(ln_cpl) |
|---|
| 550 | #endif |
|---|
| 551 | END SUBROUTINE sbc_namelist |
|---|
| 552 | |
|---|
| 553 | !!====================================================================== |
|---|
| 554 | END MODULE sbcmod |
|---|
