1 | MODULE mppini |
---|
2 | !!============================================================================== |
---|
3 | !! *** MODULE mppini *** |
---|
4 | !! Ocean initialization : distributed memory computing initialization |
---|
5 | !!============================================================================== |
---|
6 | |
---|
7 | !!---------------------------------------------------------------------- |
---|
8 | !! mpp_init : Lay out the global domain over processors |
---|
9 | !! mpp_init2 : Lay out the global domain over processors |
---|
10 | !! with land processor elimination |
---|
11 | !! mpp_init_ioispl: IOIPSL initialization in mpp |
---|
12 | !!---------------------------------------------------------------------- |
---|
13 | !! * Modules used |
---|
14 | USE dom_oce ! ocean space and time domain |
---|
15 | USE in_out_manager ! I/O Manager |
---|
16 | USE lib_mpp ! distribued memory computing library |
---|
17 | USE ioipsl |
---|
18 | |
---|
19 | IMPLICIT NONE |
---|
20 | PRIVATE |
---|
21 | |
---|
22 | PUBLIC mpp_init ! called by opa.F90 |
---|
23 | PUBLIC mpp_init2 ! called by opa.F90 |
---|
24 | |
---|
25 | !! * Substitutions |
---|
26 | # include "domzgr_substitute.h90" |
---|
27 | !!---------------------------------------------------------------------- |
---|
28 | !! NEMO/OPA 3.3 , NEMO Consortium (2010) |
---|
29 | !! $Id$ |
---|
30 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
---|
31 | !!---------------------------------------------------------------------- |
---|
32 | CONTAINS |
---|
33 | |
---|
34 | #if ! defined key_mpp_mpi |
---|
35 | !!---------------------------------------------------------------------- |
---|
36 | !! Default option : shared memory computing |
---|
37 | !!---------------------------------------------------------------------- |
---|
38 | |
---|
39 | SUBROUTINE mpp_init |
---|
40 | !!---------------------------------------------------------------------- |
---|
41 | !! *** ROUTINE mpp_init *** |
---|
42 | !! |
---|
43 | !! ** Purpose : Lay out the global domain over processors. |
---|
44 | !! |
---|
45 | !! ** Method : Shared memory computing, set the local processor |
---|
46 | !! variables to the value of the global domain |
---|
47 | !! |
---|
48 | !! History : |
---|
49 | !! 9.0 ! 04-01 (G. Madec, J.M. Molines) F90 : free form, north fold jpni >1 |
---|
50 | !!---------------------------------------------------------------------- |
---|
51 | |
---|
52 | ! No mpp computation |
---|
53 | nimpp = 1 |
---|
54 | njmpp = 1 |
---|
55 | nlci = jpi |
---|
56 | nlcj = jpj |
---|
57 | nldi = 1 |
---|
58 | nldj = 1 |
---|
59 | nlei = jpi |
---|
60 | nlej = jpj |
---|
61 | nperio = jperio |
---|
62 | nbondi = 2 |
---|
63 | nbondj = 2 |
---|
64 | nidom = FLIO_DOM_NONE |
---|
65 | npolj = jperio |
---|
66 | |
---|
67 | IF(lwp) THEN |
---|
68 | WRITE(numout,*) |
---|
69 | WRITE(numout,*) 'mpp_init(2) : NO massively parallel processing' |
---|
70 | WRITE(numout,*) '~~~~~~~~~~~: ' |
---|
71 | WRITE(numout,*) ' nperio = ', nperio |
---|
72 | WRITE(numout,*) ' npolj = ', npolj |
---|
73 | WRITE(numout,*) ' nimpp = ', nimpp |
---|
74 | WRITE(numout,*) ' njmpp = ', njmpp |
---|
75 | ENDIF |
---|
76 | |
---|
77 | IF( jpni /= 1 .OR. jpnj /= 1 .OR. jpnij /= 1 ) & |
---|
78 | CALL ctl_stop( 'equality jpni = jpnj = jpnij = 1 is not satisfied', & |
---|
79 | & 'the domain is lay out for distributed memory computing! ' ) |
---|
80 | |
---|
81 | END SUBROUTINE mpp_init |
---|
82 | |
---|
83 | |
---|
84 | SUBROUTINE mpp_init2 |
---|
85 | CALL mpp_init ! same routine as mpp_init |
---|
86 | END SUBROUTINE mpp_init2 |
---|
87 | |
---|
88 | #else |
---|
89 | !!---------------------------------------------------------------------- |
---|
90 | !! 'key_mpp_mpi' OR MPI massively parallel processing |
---|
91 | !!---------------------------------------------------------------------- |
---|
92 | |
---|
93 | SUBROUTINE mpp_init |
---|
94 | !!---------------------------------------------------------------------- |
---|
95 | !! *** ROUTINE mpp_init *** |
---|
96 | !! |
---|
97 | !! ** Purpose : Lay out the global domain over processors. |
---|
98 | !! |
---|
99 | !! ** Method : Global domain is distributed in smaller local domains. |
---|
100 | !! Periodic condition is a function of the local domain position |
---|
101 | !! (global boundary or neighbouring domain) and of the global |
---|
102 | !! periodic |
---|
103 | !! Type : jperio global periodic condition |
---|
104 | !! nperio local periodic condition |
---|
105 | !! |
---|
106 | !! ** Action : - set domain parameters |
---|
107 | !! nimpp : longitudinal index |
---|
108 | !! njmpp : latitudinal index |
---|
109 | !! nperio : lateral condition type |
---|
110 | !! narea : number for local area |
---|
111 | !! nlci : first dimension |
---|
112 | !! nlcj : second dimension |
---|
113 | !! nbondi : mark for "east-west local boundary" |
---|
114 | !! nbondj : mark for "north-south local boundary" |
---|
115 | !! nproc : number for local processor |
---|
116 | !! noea : number for local neighboring processor |
---|
117 | !! nowe : number for local neighboring processor |
---|
118 | !! noso : number for local neighboring processor |
---|
119 | !! nono : number for local neighboring processor |
---|
120 | !! |
---|
121 | !! History : |
---|
122 | !! ! 94-11 (M. Guyon) Original code |
---|
123 | !! ! 95-04 (J. Escobar, M. Imbard) |
---|
124 | !! ! 98-02 (M. Guyon) FETI method |
---|
125 | !! ! 98-05 (M. Imbard, J. Escobar, L. Colombet ) SHMEM and MPI versions |
---|
126 | !! 8.5 ! 02-08 (G. Madec) F90 : free form |
---|
127 | !! 3.4 ! 11-11 (C. Harris) decomposition changes for running with CICE |
---|
128 | !!---------------------------------------------------------------------- |
---|
129 | INTEGER :: ji, jj, jn ! dummy loop indices |
---|
130 | INTEGER :: ii, ij, ifreq, il1, il2 ! local integers |
---|
131 | INTEGER :: iresti, irestj, ijm1, imil, inum ! - - |
---|
132 | REAL(wp) :: zidom, zjdom ! local scalars |
---|
133 | INTEGER, DIMENSION(jpni,jpnj) :: iimppt, ijmppt, ilcit, ilcjt ! local workspace |
---|
134 | !!---------------------------------------------------------------------- |
---|
135 | |
---|
136 | IF(lwp) WRITE(numout,*) |
---|
137 | IF(lwp) WRITE(numout,*) 'mpp_init : Message Passing MPI' |
---|
138 | IF(lwp) WRITE(numout,*) '~~~~~~~~' |
---|
139 | |
---|
140 | |
---|
141 | ! 1. Dimension arrays for subdomains |
---|
142 | ! ----------------------------------- |
---|
143 | ! Computation of local domain sizes ilcit() ilcjt() |
---|
144 | ! These dimensions depend on global sizes jpni,jpnj and jpiglo,jpjglo |
---|
145 | ! The subdomains are squares leeser than or equal to the global |
---|
146 | ! dimensions divided by the number of processors minus the overlap |
---|
147 | ! array (cf. par_oce.F90). |
---|
148 | |
---|
149 | nreci = 2 * jpreci |
---|
150 | nrecj = 2 * jprecj |
---|
151 | iresti = MOD( jpiglo - nreci , jpni ) |
---|
152 | irestj = MOD( jpjglo - nrecj , jpnj ) |
---|
153 | |
---|
154 | IF( iresti == 0 ) iresti = jpni |
---|
155 | |
---|
156 | #if defined key_nemocice_decomp |
---|
157 | ! In order to match CICE the size of domains in NEMO has to be changed |
---|
158 | ! The last line of blocks (west) will have fewer points |
---|
159 | |
---|
160 | DO jj = 1, jpnj |
---|
161 | DO ji=1, jpni-1 |
---|
162 | ilcit(ji,jj) = jpi |
---|
163 | END DO |
---|
164 | ilcit(jpni,jj) = jpiglo - (jpni - 1) * (jpi - nreci) |
---|
165 | END DO |
---|
166 | |
---|
167 | #else |
---|
168 | |
---|
169 | DO jj = 1, jpnj |
---|
170 | DO ji = 1, iresti |
---|
171 | ilcit(ji,jj) = jpi |
---|
172 | END DO |
---|
173 | DO ji = iresti+1, jpni |
---|
174 | ilcit(ji,jj) = jpi -1 |
---|
175 | END DO |
---|
176 | END DO |
---|
177 | |
---|
178 | #endif |
---|
179 | nfilcit(:,:) = ilcit(:,:) |
---|
180 | IF( irestj == 0 ) irestj = jpnj |
---|
181 | |
---|
182 | #if defined key_nemocice_decomp |
---|
183 | ! Same change to domains in North-South direction as in East-West. |
---|
184 | DO ji=1,jpni |
---|
185 | DO jj=1,jpnj-1 |
---|
186 | ilcjt(ji,jj) = jpj |
---|
187 | END DO |
---|
188 | ilcjt(ji,jpnj) = jpjglo - (jpnj - 1) * (jpj - nrecj) |
---|
189 | END DO |
---|
190 | |
---|
191 | #else |
---|
192 | |
---|
193 | DO ji = 1, jpni |
---|
194 | DO jj = 1, irestj |
---|
195 | ilcjt(ji,jj) = jpj |
---|
196 | END DO |
---|
197 | DO jj = irestj+1, jpnj |
---|
198 | ilcjt(ji,jj) = jpj -1 |
---|
199 | END DO |
---|
200 | END DO |
---|
201 | |
---|
202 | #endif |
---|
203 | IF(lwp) THEN |
---|
204 | WRITE(numout,*) |
---|
205 | WRITE(numout,*) ' defines mpp subdomains' |
---|
206 | WRITE(numout,*) ' ----------------------' |
---|
207 | WRITE(numout,*) ' iresti=',iresti,' irestj=',irestj |
---|
208 | WRITE(numout,*) ' jpni =',jpni ,' jpnj =',jpnj |
---|
209 | ifreq = 4 |
---|
210 | il1 = 1 |
---|
211 | DO jn = 1, (jpni-1)/ifreq+1 |
---|
212 | il2 = MIN( jpni, il1+ifreq-1 ) |
---|
213 | WRITE(numout,*) |
---|
214 | WRITE(numout,9200) ('***',ji = il1,il2-1) |
---|
215 | DO jj = jpnj, 1, -1 |
---|
216 | WRITE(numout,9203) (' ',ji = il1,il2-1) |
---|
217 | WRITE(numout,9202) jj, ( ilcit(ji,jj),ilcjt(ji,jj),ji = il1,il2 ) |
---|
218 | WRITE(numout,9203) (' ',ji = il1,il2-1) |
---|
219 | WRITE(numout,9200) ('***',ji = il1,il2-1) |
---|
220 | END DO |
---|
221 | WRITE(numout,9201) (ji,ji = il1,il2) |
---|
222 | il1 = il1+ifreq |
---|
223 | END DO |
---|
224 | 9200 FORMAT(' ***',20('*************',a3)) |
---|
225 | 9203 FORMAT(' * ',20(' * ',a3)) |
---|
226 | 9201 FORMAT(' ',20(' ',i3,' ')) |
---|
227 | 9202 FORMAT(' ',i3,' * ',20(i3,' x',i3,' * ')) |
---|
228 | ENDIF |
---|
229 | |
---|
230 | zidom = nreci |
---|
231 | DO ji = 1, jpni |
---|
232 | zidom = zidom + ilcit(ji,1) - nreci |
---|
233 | END DO |
---|
234 | IF(lwp) WRITE(numout,*) |
---|
235 | IF(lwp) WRITE(numout,*)' sum ilcit(i,1) = ', zidom, ' jpiglo = ', jpiglo |
---|
236 | |
---|
237 | zjdom = nrecj |
---|
238 | DO jj = 1, jpnj |
---|
239 | zjdom = zjdom + ilcjt(1,jj) - nrecj |
---|
240 | END DO |
---|
241 | IF(lwp) WRITE(numout,*)' sum ilcit(1,j) = ', zjdom, ' jpjglo = ', jpjglo |
---|
242 | IF(lwp) WRITE(numout,*) |
---|
243 | |
---|
244 | |
---|
245 | ! 2. Index arrays for subdomains |
---|
246 | ! ------------------------------- |
---|
247 | |
---|
248 | iimppt(:,:) = 1 |
---|
249 | ijmppt(:,:) = 1 |
---|
250 | |
---|
251 | IF( jpni > 1 ) THEN |
---|
252 | DO jj = 1, jpnj |
---|
253 | DO ji = 2, jpni |
---|
254 | iimppt(ji,jj) = iimppt(ji-1,jj) + ilcit(ji-1,jj) - nreci |
---|
255 | END DO |
---|
256 | END DO |
---|
257 | ENDIF |
---|
258 | nfiimpp(:,:)=iimppt(:,:) |
---|
259 | |
---|
260 | IF( jpnj > 1 ) THEN |
---|
261 | DO jj = 2, jpnj |
---|
262 | DO ji = 1, jpni |
---|
263 | ijmppt(ji,jj) = ijmppt(ji,jj-1)+ilcjt(ji,jj-1)-nrecj |
---|
264 | END DO |
---|
265 | END DO |
---|
266 | ENDIF |
---|
267 | |
---|
268 | ! 3. Subdomain description |
---|
269 | ! ------------------------ |
---|
270 | |
---|
271 | DO jn = 1, jpnij |
---|
272 | ii = 1 + MOD( jn-1, jpni ) |
---|
273 | ij = 1 + (jn-1) / jpni |
---|
274 | nfipproc(ii,ij) = jn - 1 |
---|
275 | nimppt(jn) = iimppt(ii,ij) |
---|
276 | njmppt(jn) = ijmppt(ii,ij) |
---|
277 | nlcit (jn) = ilcit (ii,ij) |
---|
278 | nlci = nlcit (jn) |
---|
279 | nlcjt (jn) = ilcjt (ii,ij) |
---|
280 | nlcj = nlcjt (jn) |
---|
281 | nbondj = -1 ! general case |
---|
282 | IF( jn > jpni ) nbondj = 0 ! first row of processor |
---|
283 | IF( jn > (jpnj-1)*jpni ) nbondj = 1 ! last row of processor |
---|
284 | IF( jpnj == 1 ) nbondj = 2 ! one processor only in j-direction |
---|
285 | ibonjt(jn) = nbondj |
---|
286 | |
---|
287 | nbondi = 0 ! |
---|
288 | IF( MOD( jn, jpni ) == 1 ) nbondi = -1 ! |
---|
289 | IF( MOD( jn, jpni ) == 0 ) nbondi = 1 ! |
---|
290 | IF( jpni == 1 ) nbondi = 2 ! one processor only in i-direction |
---|
291 | ibonit(jn) = nbondi |
---|
292 | |
---|
293 | nldi = 1 + jpreci |
---|
294 | nlei = nlci - jpreci |
---|
295 | IF( nbondi == -1 .OR. nbondi == 2 ) nldi = 1 |
---|
296 | IF( nbondi == 1 .OR. nbondi == 2 ) nlei = nlci |
---|
297 | nldj = 1 + jprecj |
---|
298 | nlej = nlcj - jprecj |
---|
299 | IF( nbondj == -1 .OR. nbondj == 2 ) nldj = 1 |
---|
300 | IF( nbondj == 1 .OR. nbondj == 2 ) nlej = nlcj |
---|
301 | nldit(jn) = nldi |
---|
302 | nleit(jn) = nlei |
---|
303 | nldjt(jn) = nldj |
---|
304 | nlejt(jn) = nlej |
---|
305 | END DO |
---|
306 | |
---|
307 | |
---|
308 | ! 4. From global to local |
---|
309 | ! ----------------------- |
---|
310 | |
---|
311 | nperio = 0 |
---|
312 | IF( jperio == 2 .AND. nbondj == -1 ) nperio = 2 |
---|
313 | |
---|
314 | |
---|
315 | ! 5. Subdomain neighbours |
---|
316 | ! ---------------------- |
---|
317 | |
---|
318 | nproc = narea - 1 |
---|
319 | noso = nproc - jpni |
---|
320 | nowe = nproc - 1 |
---|
321 | noea = nproc + 1 |
---|
322 | nono = nproc + jpni |
---|
323 | ! great neighbours |
---|
324 | npnw = nono - 1 |
---|
325 | npne = nono + 1 |
---|
326 | npsw = noso - 1 |
---|
327 | npse = noso + 1 |
---|
328 | nbsw = 1 |
---|
329 | nbnw = 1 |
---|
330 | IF( MOD( nproc, jpni ) == 0 ) THEN |
---|
331 | nbsw = 0 |
---|
332 | nbnw = 0 |
---|
333 | ENDIF |
---|
334 | nbse = 1 |
---|
335 | nbne = 1 |
---|
336 | IF( MOD( nproc, jpni ) == jpni-1 ) THEN |
---|
337 | nbse = 0 |
---|
338 | nbne = 0 |
---|
339 | ENDIF |
---|
340 | IF(nproc < jpni) THEN |
---|
341 | nbsw = 0 |
---|
342 | nbse = 0 |
---|
343 | ENDIF |
---|
344 | IF( nproc >= (jpnj-1)*jpni ) THEN |
---|
345 | nbnw = 0 |
---|
346 | nbne = 0 |
---|
347 | ENDIF |
---|
348 | nlcj = nlcjt(narea) |
---|
349 | nlci = nlcit(narea) |
---|
350 | nldi = nldit(narea) |
---|
351 | nlei = nleit(narea) |
---|
352 | nldj = nldjt(narea) |
---|
353 | nlej = nlejt(narea) |
---|
354 | nbondi = ibonit(narea) |
---|
355 | nbondj = ibonjt(narea) |
---|
356 | nimpp = nimppt(narea) |
---|
357 | njmpp = njmppt(narea) |
---|
358 | |
---|
359 | ! Save processor layout in layout.dat file |
---|
360 | IF (lwp) THEN |
---|
361 | CALL ctl_opn( inum, 'layout.dat', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, numout, .FALSE., narea ) |
---|
362 | WRITE(inum,'(a)') ' jpnij jpi jpj jpk jpiglo jpjglo' |
---|
363 | WRITE(inum,'(6i8)') jpnij,jpi,jpj,jpk,jpiglo,jpjglo |
---|
364 | WRITE(inum,'(a)') 'NAREA nlci nlcj nldi nldj nlei nlej nimpp njmpp' |
---|
365 | |
---|
366 | DO jn = 1, jpnij |
---|
367 | WRITE(inum,'(9i5)') jn, nlcit(jn), nlcjt(jn), & |
---|
368 | nldit(jn), nldjt(jn), & |
---|
369 | nleit(jn), nlejt(jn), & |
---|
370 | nimppt(jn), njmppt(jn) |
---|
371 | END DO |
---|
372 | CLOSE(inum) |
---|
373 | END IF |
---|
374 | |
---|
375 | |
---|
376 | ! w a r n i n g narea (zone) /= nproc (processors)! |
---|
377 | |
---|
378 | IF( jperio == 1 .OR. jperio == 4 .OR. jperio == 6 ) THEN |
---|
379 | IF( jpni == 1 )THEN |
---|
380 | nbondi = 2 |
---|
381 | nperio = 1 |
---|
382 | ELSE |
---|
383 | nbondi = 0 |
---|
384 | ENDIF |
---|
385 | IF( MOD( narea, jpni ) == 0 ) THEN |
---|
386 | noea = nproc-(jpni-1) |
---|
387 | npne = npne-jpni |
---|
388 | npse = npse-jpni |
---|
389 | ENDIF |
---|
390 | IF( MOD( narea, jpni ) == 1 ) THEN |
---|
391 | nowe = nproc+(jpni-1) |
---|
392 | npnw = npnw+jpni |
---|
393 | npsw = npsw+jpni |
---|
394 | ENDIF |
---|
395 | nbsw = 1 |
---|
396 | nbnw = 1 |
---|
397 | nbse = 1 |
---|
398 | nbne = 1 |
---|
399 | IF( nproc < jpni ) THEN |
---|
400 | nbsw = 0 |
---|
401 | nbse = 0 |
---|
402 | ENDIF |
---|
403 | IF( nproc >= (jpnj-1)*jpni ) THEN |
---|
404 | nbnw = 0 |
---|
405 | nbne = 0 |
---|
406 | ENDIF |
---|
407 | ENDIF |
---|
408 | npolj = 0 |
---|
409 | IF( jperio == 3 .OR. jperio == 4 ) THEN |
---|
410 | ijm1 = jpni*(jpnj-1) |
---|
411 | imil = ijm1+(jpni+1)/2 |
---|
412 | IF( narea > ijm1 ) npolj = 3 |
---|
413 | IF( MOD(jpni,2) == 1 .AND. narea == imil ) npolj = 4 |
---|
414 | IF( npolj == 3 ) nono = jpni*jpnj-narea+ijm1 |
---|
415 | ENDIF |
---|
416 | IF( jperio == 5 .OR. jperio == 6 ) THEN |
---|
417 | ijm1 = jpni*(jpnj-1) |
---|
418 | imil = ijm1+(jpni+1)/2 |
---|
419 | IF( narea > ijm1) npolj = 5 |
---|
420 | IF( MOD(jpni,2) == 1 .AND. narea == imil ) npolj = 6 |
---|
421 | IF( npolj == 5 ) nono = jpni*jpnj-narea+ijm1 |
---|
422 | ENDIF |
---|
423 | |
---|
424 | ! Periodicity : no corner if nbondi = 2 and nperio != 1 |
---|
425 | |
---|
426 | IF(lwp) THEN |
---|
427 | WRITE(numout,*) ' nproc = ', nproc |
---|
428 | WRITE(numout,*) ' nowe = ', nowe , ' noea = ', noea |
---|
429 | WRITE(numout,*) ' nono = ', nono , ' noso = ', noso |
---|
430 | WRITE(numout,*) ' nbondi = ', nbondi |
---|
431 | WRITE(numout,*) ' nbondj = ', nbondj |
---|
432 | WRITE(numout,*) ' npolj = ', npolj |
---|
433 | WRITE(numout,*) ' nperio = ', nperio |
---|
434 | WRITE(numout,*) ' nlci = ', nlci |
---|
435 | WRITE(numout,*) ' nlcj = ', nlcj |
---|
436 | WRITE(numout,*) ' nimpp = ', nimpp |
---|
437 | WRITE(numout,*) ' njmpp = ', njmpp |
---|
438 | WRITE(numout,*) ' nbse = ', nbse , ' npse = ', npse |
---|
439 | WRITE(numout,*) ' nbsw = ', nbsw , ' npsw = ', npsw |
---|
440 | WRITE(numout,*) ' nbne = ', nbne , ' npne = ', npne |
---|
441 | WRITE(numout,*) ' nbnw = ', nbnw , ' npnw = ', npnw |
---|
442 | ENDIF |
---|
443 | |
---|
444 | IF( nperio == 1 .AND. jpni /= 1 ) CALL ctl_stop( ' mpp_init: error on cyclicity' ) |
---|
445 | |
---|
446 | ! Prepare mpp north fold |
---|
447 | |
---|
448 | IF (jperio >= 3 .AND. jperio <= 6 .AND. jpni > 1 ) THEN |
---|
449 | CALL mpp_ini_north |
---|
450 | END IF |
---|
451 | |
---|
452 | ! Prepare NetCDF output file (if necessary) |
---|
453 | CALL mpp_init_ioipsl |
---|
454 | |
---|
455 | END SUBROUTINE mpp_init |
---|
456 | |
---|
457 | # include "mppini_2.h90" |
---|
458 | |
---|
459 | # if defined key_dimgout |
---|
460 | !!---------------------------------------------------------------------- |
---|
461 | !! 'key_dimgout' NO use of NetCDF files |
---|
462 | !!---------------------------------------------------------------------- |
---|
463 | SUBROUTINE mpp_init_ioipsl ! Dummy routine |
---|
464 | END SUBROUTINE mpp_init_ioipsl |
---|
465 | # else |
---|
466 | SUBROUTINE mpp_init_ioipsl |
---|
467 | !!---------------------------------------------------------------------- |
---|
468 | !! *** ROUTINE mpp_init_ioipsl *** |
---|
469 | !! |
---|
470 | !! ** Purpose : |
---|
471 | !! |
---|
472 | !! ** Method : |
---|
473 | !! |
---|
474 | !! History : |
---|
475 | !! 9.0 ! 04-03 (G. Madec ) MPP-IOIPSL |
---|
476 | !! " " ! 08-12 (A. Coward) addition in case of jpni*jpnj < jpnij |
---|
477 | !!---------------------------------------------------------------------- |
---|
478 | INTEGER, DIMENSION(2) :: iglo, iloc, iabsf, iabsl, ihals, ihale, idid |
---|
479 | !!---------------------------------------------------------------------- |
---|
480 | |
---|
481 | ! The domain is split only horizontally along i- or/and j- direction |
---|
482 | ! So we need at the most only 1D arrays with 2 elements. |
---|
483 | ! Set idompar values equivalent to the jpdom_local_noextra definition |
---|
484 | ! used in IOM. This works even if jpnij .ne. jpni*jpnj. |
---|
485 | iglo(1) = jpiglo |
---|
486 | iglo(2) = jpjglo |
---|
487 | iloc(1) = nlci |
---|
488 | iloc(2) = nlcj |
---|
489 | iabsf(1) = nimppt(narea) |
---|
490 | iabsf(2) = njmppt(narea) |
---|
491 | iabsl(:) = iabsf(:) + iloc(:) - 1 |
---|
492 | ihals(1) = nldi - 1 |
---|
493 | ihals(2) = nldj - 1 |
---|
494 | ihale(1) = nlci - nlei |
---|
495 | ihale(2) = nlcj - nlej |
---|
496 | idid(1) = 1 |
---|
497 | idid(2) = 2 |
---|
498 | |
---|
499 | IF(lwp) THEN |
---|
500 | WRITE(numout,*) |
---|
501 | WRITE(numout,*) 'mpp_init_ioipsl : iloc = ', iloc (1), iloc (2) |
---|
502 | WRITE(numout,*) '~~~~~~~~~~~~~~~ iabsf = ', iabsf(1), iabsf(2) |
---|
503 | WRITE(numout,*) ' ihals = ', ihals(1), ihals(2) |
---|
504 | WRITE(numout,*) ' ihale = ', ihale(1), ihale(2) |
---|
505 | ENDIF |
---|
506 | ! |
---|
507 | CALL flio_dom_set ( jpnij, nproc, idid, iglo, iloc, iabsf, iabsl, ihals, ihale, 'BOX', nidom) |
---|
508 | ! |
---|
509 | END SUBROUTINE mpp_init_ioipsl |
---|
510 | |
---|
511 | # endif |
---|
512 | #endif |
---|
513 | |
---|
514 | !!====================================================================== |
---|
515 | END MODULE mppini |
---|