New URL for NEMO forge! http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.

dynhpg.F90 in branches/UKMO/dev_r5518_pcbias_ipc/NEMOGCM/NEMO/OPA_SRC/DYN – NEMO

Context Navigation

source: branches/UKMO/dev_r5518_pcbias_ipc/NEMOGCM/NEMO/OPA_SRC/DYN/dynhpg.F90 @ 7658

Last change on this file since 7658 was 7658, checked in by isabella, 7 years ago
write statement put outside case statement
File size: 71.1 KB

Line
1	MODULE dynhpg
2	!!======================================================================
3	!! * MODULE dynhpg *
4	!! Ocean dynamics: hydrostatic pressure gradient trend
5	!!======================================================================
6	!! History : OPA ! 1987-09 (P. Andrich, M.-A. Foujols) hpg_zco: Original code
7	!! 5.0 ! 1991-11 (G. Madec)
8	!! 7.0 ! 1996-01 (G. Madec) hpg_sco: Original code for s-coordinates
9	!! 8.0 ! 1997-05 (G. Madec) split dynber into dynkeg and dynhpg
10	!! 8.5 ! 2002-07 (G. Madec) F90: Free form and module
11	!! 8.5 ! 2002-08 (A. Bozec) hpg_zps: Original code
12	!! NEMO 1.0 ! 2005-10 (A. Beckmann, B.W. An) various s-coordinate options
13	!! ! Original code for hpg_ctl, hpg_hel hpg_wdj, hpg_djc, hpg_rot
14	!! - ! 2005-11 (G. Madec) style & small optimisation
15	!! 3.3 ! 2010-10 (C. Ethe, G. Madec) reorganisation of initialisation phase
16	!! 3.4 ! 2011-11 (H. Liu) hpg_prj: Original code for s-coordinates
17	!! ! (A. Coward) suppression of hel, wdj and rot options
18	!! 3.6 ! 2014-11 (P. Mathiot) hpg_isf: original code for ice shelf cavity
19	!!----------------------------------------------------------------------
20
21	!!----------------------------------------------------------------------
22	!! dyn_hpg : update the momentum trend with the now horizontal
23	!! gradient of the hydrostatic pressure
24	!! dyn_hpg_init : initialisation and control of options
25	!! hpg_zco : z-coordinate scheme
26	!! hpg_zps : z-coordinate plus partial steps (interpolation)
27	!! hpg_sco : s-coordinate (standard jacobian formulation)
28	!! hpg_isf : s-coordinate (sco formulation) adapted to ice shelf
29	!! hpg_djc : s-coordinate (Density Jacobian with Cubic polynomial)
30	!! hpg_prj : s-coordinate (Pressure Jacobian with Cubic polynomial)
31	!!----------------------------------------------------------------------
32	USE oce ! ocean dynamics and tracers
33	USE sbc_oce ! surface variable (only for the flag with ice shelf)
34	USE dom_oce ! ocean space and time domain
35	USE phycst ! physical constants
36	USE trd_oce ! trends: ocean variables
37	USE trddyn ! trend manager: dynamics
38	!
39	USE in_out_manager ! I/O manager
40	USE prtctl ! Print control
41	USE lbclnk ! lateral boundary condition
42	USE lib_mpp ! MPP library
43	USE eosbn2 ! compute density
44	USE wrk_nemo ! Memory Allocation
45	USE timing ! Timing
46	USE biaspar ! bias correction variables
47
48	IMPLICIT NONE
49	PRIVATE
50
51	PUBLIC dyn_hpg ! routine called by step module
52	PUBLIC dyn_hpg_init ! routine called by opa module
53
54	! !!* Namelist namdyn_hpg : hydrostatic pressure gradient
55	LOGICAL , PUBLIC :: ln_hpg_zco !: z-coordinate - full steps
56	LOGICAL , PUBLIC :: ln_hpg_zps !: z-coordinate - partial steps (interpolation)
57	LOGICAL , PUBLIC :: ln_hpg_sco !: s-coordinate (standard jacobian formulation)
58	LOGICAL , PUBLIC :: ln_hpg_djc !: s-coordinate (Density Jacobian with Cubic polynomial)
59	LOGICAL , PUBLIC :: ln_hpg_prj !: s-coordinate (Pressure Jacobian scheme)
60	LOGICAL , PUBLIC :: ln_hpg_isf !: s-coordinate similar to sco modify for isf
61	LOGICAL , PUBLIC :: ln_dynhpg_imp !: semi-implicite hpg flag
62
63	INTEGER , PUBLIC :: nhpg = 0 ! = 0 to 7, type of pressure gradient scheme used ! (deduced from ln_hpg_... flags) (PUBLIC for TAM)
64
65	!! * Substitutions
66	# include "domzgr_substitute.h90"
67	# include "vectopt_loop_substitute.h90"
68	!!----------------------------------------------------------------------
69	!! NEMO/OPA 3.3 , NEMO Consortium (2010)
70	!! $Id$
71	!! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
72	!!----------------------------------------------------------------------
73	CONTAINS
74
75	SUBROUTINE dyn_hpg( kt )
76	!!---------------------------------------------------------------------
77	!! * ROUTINE dyn_hpg *
78	!!
79	!! ** Method : Call the hydrostatic pressure gradient routine
80	!! using the scheme defined in the namelist
81	!!
82	!! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
83	!! - send trends to trd_dyn for futher diagnostics (l_trddyn=T)
84	!!----------------------------------------------------------------------
85	INTEGER, INTENT(in) :: kt ! ocean time-step index
86	REAL(wp), POINTER, DIMENSION(:,:,:) :: ztrdu, ztrdv
87	REAL(wp), DIMENSION(jpi,jpj,jpk) :: z_rhd_st ! tmp density storage for pressure corr
88	REAL(wp), DIMENSION(jpi,jpj) :: z_gru_st ! tmp ua trends storage for pressure corr
89	REAL(wp), DIMENSION(jpi,jpj) :: z_grv_st ! tmp va trends storage for pressure corr
90	!!----------------------------------------------------------------------
91	!
92	IF( nn_timing == 1 ) CALL timing_start('dyn_hpg')
93	!
94	IF( l_trddyn ) THEN ! Temporary saving of ua and va trends (l_trddyn)
95	CALL wrk_alloc( jpi,jpj,jpk, ztrdu, ztrdv )
96	ztrdu(:,:,:) = ua(:,:,:)
97	ztrdv(:,:,:) = va(:,:,:)
98	ENDIF
99	!
100	IF ( ln_bias .AND. ln_bias_pc_app ) THEN
101	IF(lwp) THEN
102	WRITE(numout,*) " ! store orig density, use pressure corrected density using gru_pc and grv_pc"
103	ENDIF
104	z_rhd_st(:,:,:) = rhd(:,:,:) ! store orig density
105	rhd(:,:,:) = rhd_pc(:,:,:) ! use pressure corrected density
106	z_gru_st(:,:) = gru(:,:)
107	gru(:,:) = gru_pc(:,:)
108	z_grv_st(:,:) = grv(:,:)
109	grv(:,:) = grv_pc(:,:)
110	ENDIF
111
112	IF(lwp) WRITE(numout,*) " computing pressure gradient with nhpg = ",nhpg
113	SELECT CASE ( nhpg ) ! Hydrostatic pressure gradient computation
114	CASE ( 0 ) ; CALL hpg_zco ( kt ) ! z-coordinate
115	CASE ( 1 ) ; CALL hpg_zps ( kt ) ! z-coordinate plus partial steps (interpolation)
116	CASE ( 2 ) ; CALL hpg_sco ( kt ) ! s-coordinate (standard jacobian formulation)
117	CASE ( 3 ) ; CALL hpg_djc ( kt ) ! s-coordinate (Density Jacobian with Cubic polynomial)
118	CASE ( 4 ) ; CALL hpg_prj ( kt ) ! s-coordinate (Pressure Jacobian scheme)
119	CASE ( 5 ) ; CALL hpg_isf ( kt ) ! s-coordinate similar to sco modify for ice shelf
120	END SELECT
121	!
122	IF( l_trddyn ) THEN ! save the hydrostatic pressure gradient trends for momentum trend diagnostics
123	ztrdu(:,:,:) = ua(:,:,:) - ztrdu(:,:,:)
124	ztrdv(:,:,:) = va(:,:,:) - ztrdv(:,:,:)
125	CALL trd_dyn( ztrdu, ztrdv, jpdyn_hpg, kt )
126	CALL wrk_dealloc( jpi,jpj,jpk, ztrdu, ztrdv )
127	ENDIF
128	!
129	IF(ln_ctl) CALL prt_ctl( tab3d_1=ua, clinfo1=' hpg - Ua: ', mask1=umask, &
130	& tab3d_2=va, clinfo2= ' Va: ', mask2=vmask, clinfo3='dyn' )
131	!
132	IF ( ln_bias .AND. ln_bias_pc_app ) THEN
133	IF(lwp) THEN
134	WRITE(numout,*) " ! restore original density"
135	ENDIF
136	rhd(:,:,:) = z_rhd_st(:,:,:) ! restore original density
137	gru(:,:) = z_gru_st(:,:)
138	grv(:,:) = z_grv_st(:,:)
139	ENDIF
140	!
141	IF( nn_timing == 1 ) CALL timing_stop('dyn_hpg')
142	!
143	END SUBROUTINE dyn_hpg
144
145
146	SUBROUTINE dyn_hpg_init
147	!!----------------------------------------------------------------------
148	!! * ROUTINE dyn_hpg_init *
149	!!
150	!! ** Purpose : initializations for the hydrostatic pressure gradient
151	!! computation and consistency control
152	!!
153	!! ** Action : Read the namelist namdyn_hpg and check the consistency
154	!! with the type of vertical coordinate used (zco, zps, sco)
155	!!----------------------------------------------------------------------
156	INTEGER :: ioptio = 0 ! temporary integer
157	INTEGER :: ios ! Local integer output status for namelist read
158	!!
159	NAMELIST/namdyn_hpg/ ln_hpg_zco, ln_hpg_zps, ln_hpg_sco, &
160	& ln_hpg_djc, ln_hpg_prj, ln_hpg_isf, ln_dynhpg_imp
161	!!----------------------------------------------------------------------
162	!
163	REWIND( numnam_ref ) ! Namelist namdyn_hpg in reference namelist : Hydrostatic pressure gradient
164	READ ( numnam_ref, namdyn_hpg, IOSTAT = ios, ERR = 901)
165	901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namdyn_hpg in reference namelist', lwp )
166
167	REWIND( numnam_cfg ) ! Namelist namdyn_hpg in configuration namelist : Hydrostatic pressure gradient
168	READ ( numnam_cfg, namdyn_hpg, IOSTAT = ios, ERR = 902 )
169	902 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namdyn_hpg in configuration namelist', lwp )
170	IF(lwm) WRITE ( numond, namdyn_hpg )
171	!
172	IF(lwp) THEN ! Control print
173	WRITE(numout,*)
174	WRITE(numout,*) 'dyn_hpg_init : hydrostatic pressure gradient initialisation'
175	WRITE(numout,*) '~~~~~~~~~~~~'
176	WRITE(numout,*) ' Namelist namdyn_hpg : choice of hpg scheme'
177	WRITE(numout,*) ' z-coord. - full steps ln_hpg_zco = ', ln_hpg_zco
178	WRITE(numout,*) ' z-coord. - partial steps (interpolation) ln_hpg_zps = ', ln_hpg_zps
179	WRITE(numout,*) ' s-coord. (standard jacobian formulation) ln_hpg_sco = ', ln_hpg_sco
180	WRITE(numout,*) ' s-coord. (standard jacobian formulation) for isf ln_hpg_isf = ', ln_hpg_isf
181	WRITE(numout,*) ' s-coord. (Density Jacobian: Cubic polynomial) ln_hpg_djc = ', ln_hpg_djc
182	WRITE(numout,*) ' s-coord. (Pressure Jacobian: Cubic polynomial) ln_hpg_prj = ', ln_hpg_prj
183	WRITE(numout,*) ' time stepping: centered (F) or semi-implicit (T) ln_dynhpg_imp = ', ln_dynhpg_imp
184	ENDIF
185	!
186	IF( ln_hpg_djc ) &
187	& CALL ctl_stop('dyn_hpg_init : Density Jacobian: Cubic polynominal method &
188	& currently disabled (bugs under investigation). Please select &
189	& either ln_hpg_sco or ln_hpg_prj instead')
190	!
191	IF( lk_vvl .AND. .NOT. (ln_hpg_sco.OR.ln_hpg_prj.OR.ln_hpg_isf) ) &
192	& CALL ctl_stop('dyn_hpg_init : variable volume key_vvl requires:&
193	& the standard jacobian formulation hpg_sco or &
194	& the pressure jacobian formulation hpg_prj')
195
196	IF( ln_hpg_isf .AND. .NOT. ln_isfcav ) &
197	& CALL ctl_stop( ' hpg_isf not available if ln_isfcav = false ' )
198	IF( .NOT. ln_hpg_isf .AND. ln_isfcav ) &
199	& CALL ctl_stop( 'Only hpg_isf has been corrected to work with ice shelf cavity.' )
200	!
201	! ! Set nhpg from ln_hpg_... flags
202	IF( ln_hpg_zco ) nhpg = 0
203	IF( ln_hpg_zps ) nhpg = 1
204	IF( ln_hpg_sco ) nhpg = 2
205	IF( ln_hpg_djc ) nhpg = 3
206	IF( ln_hpg_prj ) nhpg = 4
207	IF( ln_hpg_isf ) nhpg = 5
208	!
209	! ! Consistency check
210	ioptio = 0
211	IF( ln_hpg_zco ) ioptio = ioptio + 1
212	IF( ln_hpg_zps ) ioptio = ioptio + 1
213	IF( ln_hpg_sco ) ioptio = ioptio + 1
214	IF( ln_hpg_djc ) ioptio = ioptio + 1
215	IF( ln_hpg_prj ) ioptio = ioptio + 1
216	IF( ln_hpg_isf ) ioptio = ioptio + 1
217	IF( ioptio /= 1 ) CALL ctl_stop( 'NO or several hydrostatic pressure gradient options used' )
218	!
219	! initialisation of ice load
220	riceload(:,:)=0.0
221	!
222	END SUBROUTINE dyn_hpg_init
223
224
225	SUBROUTINE hpg_zco( kt )
226	!!---------------------------------------------------------------------
227	!! * ROUTINE hpg_zco *
228	!!
229	!! ** Method : z-coordinate case, levels are horizontal surfaces.
230	!! The now hydrostatic pressure gradient at a given level, jk,
231	!! is computed by taking the vertical integral of the in-situ
232	!! density gradient along the model level from the suface to that
233	!! level: zhpi = grav .....
234	!! zhpj = grav .....
235	!! add it to the general momentum trend (ua,va).
236	!! ua = ua - 1/e1u * zhpi
237	!! va = va - 1/e2v * zhpj
238	!!
239	!! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
240	!!----------------------------------------------------------------------
241	INTEGER, INTENT(in) :: kt ! ocean time-step index
242	!!
243	INTEGER :: ji, jj, jk ! dummy loop indices
244	REAL(wp) :: zcoef0, zcoef1 ! temporary scalars
245	REAL(wp), POINTER, DIMENSION(:,:,:) :: zhpi, zhpj
246	!!----------------------------------------------------------------------
247	!
248	CALL wrk_alloc( jpi,jpj,jpk, zhpi, zhpj )
249	!
250	IF( kt == nit000 ) THEN
251	IF(lwp) WRITE(numout,*)
252	IF(lwp) WRITE(numout,*) 'dyn:hpg_zco : hydrostatic pressure gradient trend'
253	IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ z-coordinate case '
254	ENDIF
255
256	zcoef0 = - grav * 0.5_wp ! Local constant initialization
257
258	! Surface value
259	DO jj = 2, jpjm1
260	DO ji = fs_2, fs_jpim1 ! vector opt.
261	zcoef1 = zcoef0 * fse3w(ji,jj,1)
262	! hydrostatic pressure gradient
263	zhpi(ji,jj,1) = zcoef1 * ( rhd(ji+1,jj,1) - rhd(ji,jj,1) ) / e1u(ji,jj)
264	zhpj(ji,jj,1) = zcoef1 * ( rhd(ji,jj+1,1) - rhd(ji,jj,1) ) / e2v(ji,jj)
265	! add to the general momentum trend
266	ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
267	va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
268	END DO
269	END DO
270
271	!
272	! interior value (2=<jk=<jpkm1)
273	DO jk = 2, jpkm1
274	DO jj = 2, jpjm1
275	DO ji = fs_2, fs_jpim1 ! vector opt.
276	zcoef1 = zcoef0 * fse3w(ji,jj,jk)
277	! hydrostatic pressure gradient
278	zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) &
279	& + zcoef1 * ( ( rhd(ji+1,jj,jk)+rhd(ji+1,jj,jk-1) ) &
280	& - ( rhd(ji ,jj,jk)+rhd(ji ,jj,jk-1) ) ) / e1u(ji,jj)
281
282	zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) &
283	& + zcoef1 * ( ( rhd(ji,jj+1,jk)+rhd(ji,jj+1,jk-1) ) &
284	& - ( rhd(ji,jj, jk)+rhd(ji,jj ,jk-1) ) ) / e2v(ji,jj)
285	! add to the general momentum trend
286	ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
287	va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
288	END DO
289	END DO
290	END DO
291	!
292	CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zhpj )
293	!
294	END SUBROUTINE hpg_zco
295
296
297	SUBROUTINE hpg_zps( kt )
298	!!---------------------------------------------------------------------
299	!! * ROUTINE hpg_zps *
300	!!
301	!! ** Method : z-coordinate plus partial steps case. blahblah...
302	!!
303	!! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
304	!!----------------------------------------------------------------------
305	INTEGER, INTENT(in) :: kt ! ocean time-step index
306	!!
307	INTEGER :: ji, jj, jk ! dummy loop indices
308	INTEGER :: iku, ikv ! temporary integers
309	REAL(wp) :: zcoef0, zcoef1, zcoef2, zcoef3 ! temporary scalars
310	REAL(wp), POINTER, DIMENSION(:,:,:) :: zhpi, zhpj
311	!!----------------------------------------------------------------------
312	!
313	CALL wrk_alloc( jpi,jpj,jpk, zhpi, zhpj )
314	!
315	IF( kt == nit000 ) THEN
316	IF(lwp) WRITE(numout,*)
317	IF(lwp) WRITE(numout,*) 'dyn:hpg_zps : hydrostatic pressure gradient trend'
318	IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ z-coordinate with partial steps - vector optimization'
319	ENDIF
320
321
322	! Local constant initialization
323	zcoef0 = - grav * 0.5_wp
324
325	! Surface value (also valid in partial step case)
326	DO jj = 2, jpjm1
327	DO ji = fs_2, fs_jpim1 ! vector opt.
328	zcoef1 = zcoef0 * fse3w(ji,jj,1)
329	! hydrostatic pressure gradient
330	zhpi(ji,jj,1) = zcoef1 * ( rhd(ji+1,jj ,1) - rhd(ji,jj,1) ) / e1u(ji,jj)
331	zhpj(ji,jj,1) = zcoef1 * ( rhd(ji ,jj+1,1) - rhd(ji,jj,1) ) / e2v(ji,jj)
332	! add to the general momentum trend
333	ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
334	va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
335	END DO
336	END DO
337
338
339	! interior value (2=<jk=<jpkm1)
340	DO jk = 2, jpkm1
341	DO jj = 2, jpjm1
342	DO ji = fs_2, fs_jpim1 ! vector opt.
343	zcoef1 = zcoef0 * fse3w(ji,jj,jk)
344	! hydrostatic pressure gradient
345	zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) &
346	& + zcoef1 * ( ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) ) &
347	& - ( rhd(ji ,jj,jk) + rhd(ji ,jj,jk-1) ) ) / e1u(ji,jj)
348
349	zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) &
350	& + zcoef1 * ( ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) ) &
351	& - ( rhd(ji,jj, jk) + rhd(ji,jj ,jk-1) ) ) / e2v(ji,jj)
352	! add to the general momentum trend
353	ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
354	va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
355	END DO
356	END DO
357	END DO
358
359
360	! partial steps correction at the last level (use gru & grv computed in zpshde.F90)
361	DO jj = 2, jpjm1
362	DO ji = 2, jpim1
363	iku = mbku(ji,jj)
364	ikv = mbkv(ji,jj)
365	zcoef2 = zcoef0 * MIN( fse3w(ji,jj,iku), fse3w(ji+1,jj ,iku) )
366	zcoef3 = zcoef0 * MIN( fse3w(ji,jj,ikv), fse3w(ji ,jj+1,ikv) )
367	IF( iku > 1 ) THEN ! on i-direction (level 2 or more)
368	ua (ji,jj,iku) = ua(ji,jj,iku) - zhpi(ji,jj,iku) ! subtract old value
369	zhpi(ji,jj,iku) = zhpi(ji,jj,iku-1) & ! compute the new one
370	& + zcoef2 * ( rhd(ji+1,jj,iku-1) - rhd(ji,jj,iku-1) + gru(ji,jj) ) / e1u(ji,jj)
371	ua (ji,jj,iku) = ua(ji,jj,iku) + zhpi(ji,jj,iku) ! add the new one to the general momentum trend
372	ENDIF
373	IF( ikv > 1 ) THEN ! on j-direction (level 2 or more)
374	va (ji,jj,ikv) = va(ji,jj,ikv) - zhpj(ji,jj,ikv) ! subtract old value
375	zhpj(ji,jj,ikv) = zhpj(ji,jj,ikv-1) & ! compute the new one
376	& + zcoef3 * ( rhd(ji,jj+1,ikv-1) - rhd(ji,jj,ikv-1) + grv(ji,jj) ) / e2v(ji,jj)
377	va (ji,jj,ikv) = va(ji,jj,ikv) + zhpj(ji,jj,ikv) ! add the new one to the general momentum trend
378	ENDIF
379	END DO
380	END DO
381	!
382	CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zhpj )
383	!
384	END SUBROUTINE hpg_zps
385
386	SUBROUTINE hpg_sco( kt )
387	!!---------------------------------------------------------------------
388	!! * ROUTINE hpg_sco *
389	!!
390	!! ** Method : s-coordinate case. Jacobian scheme.
391	!! The now hydrostatic pressure gradient at a given level, jk,
392	!! is computed by taking the vertical integral of the in-situ
393	!! density gradient along the model level from the suface to that
394	!! level. s-coordinates (ln_sco): a corrective term is added
395	!! to the horizontal pressure gradient :
396	!! zhpi = grav ..... + 1/e1u mi(rhd) di[ grav dep3w ]
397	!! zhpj = grav ..... + 1/e2v mj(rhd) dj[ grav dep3w ]
398	!! add it to the general momentum trend (ua,va).
399	!! ua = ua - 1/e1u * zhpi
400	!! va = va - 1/e2v * zhpj
401	!!
402	!! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
403	!!----------------------------------------------------------------------
404	INTEGER, INTENT(in) :: kt ! ocean time-step index
405	!!
406	INTEGER :: ji, jj, jk ! dummy loop indices
407	REAL(wp) :: zcoef0, zuap, zvap, znad ! temporary scalars
408	REAL(wp), POINTER, DIMENSION(:,:,:) :: zhpi, zhpj
409	!!----------------------------------------------------------------------
410	!
411	CALL wrk_alloc( jpi,jpj,jpk, zhpi, zhpj )
412	!
413	IF( kt == nit000 ) THEN
414	IF(lwp) WRITE(numout,*)
415	IF(lwp) WRITE(numout,*) 'dyn:hpg_sco : hydrostatic pressure gradient trend'
416	IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ s-coordinate case, OPA original scheme used'
417	ENDIF
418
419	! Local constant initialization
420	zcoef0 = - grav * 0.5_wp
421	! To use density and not density anomaly
422	IF ( lk_vvl ) THEN ; znad = 1._wp ! Variable volume
423	ELSE ; znad = 0._wp ! Fixed volume
424	ENDIF
425
426	! Surface value
427	DO jj = 2, jpjm1
428	DO ji = fs_2, fs_jpim1 ! vector opt.
429	! hydrostatic pressure gradient along s-surfaces
430	zhpi(ji,jj,1) = zcoef0 / e1u(ji,jj) * ( fse3w(ji+1,jj ,1) * ( znad + rhd(ji+1,jj ,1) ) &
431	& - fse3w(ji ,jj ,1) * ( znad + rhd(ji ,jj ,1) ) )
432	zhpj(ji,jj,1) = zcoef0 / e2v(ji,jj) * ( fse3w(ji ,jj+1,1) * ( znad + rhd(ji ,jj+1,1) ) &
433	& - fse3w(ji ,jj ,1) * ( znad + rhd(ji ,jj ,1) ) )
434	! s-coordinate pressure gradient correction
435	zuap = -zcoef0 * ( rhd (ji+1,jj,1) + rhd (ji,jj,1) + 2._wp * znad ) &
436	& * ( fsde3w(ji+1,jj,1) - fsde3w(ji,jj,1) ) / e1u(ji,jj)
437	zvap = -zcoef0 * ( rhd (ji,jj+1,1) + rhd (ji,jj,1) + 2._wp * znad ) &
438	& * ( fsde3w(ji,jj+1,1) - fsde3w(ji,jj,1) ) / e2v(ji,jj)
439	! add to the general momentum trend
440	ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1) + zuap
441	va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1) + zvap
442	END DO
443	END DO
444
445	! interior value (2=<jk=<jpkm1)
446	DO jk = 2, jpkm1
447	DO jj = 2, jpjm1
448	DO ji = fs_2, fs_jpim1 ! vector opt.
449	! hydrostatic pressure gradient along s-surfaces
450	zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) + zcoef0 / e1u(ji,jj) &
451	& * ( fse3w(ji+1,jj,jk) * ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) + 2*znad ) &
452	& - fse3w(ji ,jj,jk) * ( rhd(ji ,jj,jk) + rhd(ji ,jj,jk-1) + 2*znad ) )
453	zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) + zcoef0 / e2v(ji,jj) &
454	& * ( fse3w(ji,jj+1,jk) * ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) + 2*znad ) &
455	& - fse3w(ji,jj ,jk) * ( rhd(ji,jj, jk) + rhd(ji,jj ,jk-1) + 2*znad ) )
456	! s-coordinate pressure gradient correction
457	zuap = -zcoef0 * ( rhd (ji+1,jj ,jk) + rhd (ji,jj,jk) + 2._wp * znad ) &
458	& * ( fsde3w(ji+1,jj ,jk) - fsde3w(ji,jj,jk) ) / e1u(ji,jj)
459	zvap = -zcoef0 * ( rhd (ji ,jj+1,jk) + rhd (ji,jj,jk) + 2._wp * znad ) &
460	& * ( fsde3w(ji ,jj+1,jk) - fsde3w(ji,jj,jk) ) / e2v(ji,jj)
461	! add to the general momentum trend
462	ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk) + zuap
463	va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk) + zvap
464	END DO
465	END DO
466	END DO
467	!
468	CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zhpj )
469	!
470	END SUBROUTINE hpg_sco
471
472	SUBROUTINE hpg_isf( kt )
473	!!---------------------------------------------------------------------
474	!! * ROUTINE hpg_sco *
475	!!
476	!! ** Method : s-coordinate case. Jacobian scheme.
477	!! The now hydrostatic pressure gradient at a given level, jk,
478	!! is computed by taking the vertical integral of the in-situ
479	!! density gradient along the model level from the suface to that
480	!! level. s-coordinates (ln_sco): a corrective term is added
481	!! to the horizontal pressure gradient :
482	!! zhpi = grav ..... + 1/e1u mi(rhd) di[ grav dep3w ]
483	!! zhpj = grav ..... + 1/e2v mj(rhd) dj[ grav dep3w ]
484	!! add it to the general momentum trend (ua,va).
485	!! ua = ua - 1/e1u * zhpi
486	!! va = va - 1/e2v * zhpj
487	!! iceload is added and partial cell case are added to the top and bottom
488	!!
489	!! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
490	!!----------------------------------------------------------------------
491	INTEGER, INTENT(in) :: kt ! ocean time-step index
492	!!
493	INTEGER :: ji, jj, jk, iku, ikv, ikt, iktp1i, iktp1j ! dummy loop indices
494	REAL(wp) :: zcoef0, zuap, zvap, znad, ze3wu, ze3wv, zuapint, zvapint, zhpjint, zhpiint, zdzwt, zdzwtjp1, zdzwtip1 ! temporary scalars
495	REAL(wp), POINTER, DIMENSION(:,:,:) :: zhpi, zhpj, zrhd
496	REAL(wp), POINTER, DIMENSION(:,:,:) :: ztstop
497	REAL(wp), POINTER, DIMENSION(:,:) :: ze3w, zp, zrhdtop_isf, zrhdtop_oce, ziceload, zdept, zpshpi, zpshpj
498	!!----------------------------------------------------------------------
499	!
500	CALL wrk_alloc( jpi,jpj, 2, ztstop)
501	CALL wrk_alloc( jpi,jpj,jpk, zhpi, zhpj, zrhd)
502	CALL wrk_alloc( jpi,jpj, ze3w, zp, zrhdtop_isf, zrhdtop_oce, ziceload, zdept, zpshpi, zpshpj)
503	!
504	IF( kt == nit000 ) THEN
505	IF(lwp) WRITE(numout,*)
506	IF(lwp) WRITE(numout,*) 'dyn:hpg_isf : hydrostatic pressure gradient trend for ice shelf'
507	IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ s-coordinate case, OPA original scheme used'
508	ENDIF
509
510	! Local constant initialization
511	zcoef0 = - grav * 0.5_wp
512	! To use density and not density anomaly
513	! IF ( lk_vvl ) THEN ; znad = 1._wp ! Variable volume
514	! ELSE ; znad = 0._wp ! Fixed volume
515	! ENDIF
516	znad=1._wp
517	! iniitialised to 0. zhpi zhpi
518	zhpi(:,:,:)=0._wp ; zhpj(:,:,:)=0._wp
519
520	!==================================================================================
521	!=====Compute iceload and contribution of the half first wet layer =================
522	!===================================================================================
523
524	! assume water displaced by the ice shelf is at T=-1.9 and S=34.4 (rude)
525	ztstop(:,:,1)=-1.9_wp ; ztstop(:,:,2)=34.4_wp
526
527	! compute density of the water displaced by the ice shelf
528	zrhd = rhd ! save rhd
529	DO jk = 1, jpk
530	zdept(:,:)=gdept_1d(jk)
531	CALL eos(ztstop(:,:,:),zdept(:,:),rhd(:,:,jk))
532	END DO
533	WHERE ( tmask(:,:,:) == 1._wp)
534	rhd(:,:,:) = zrhd(:,:,:) ! replace wet cell by the saved rhd
535	END WHERE
536
537	! compute rhd at the ice/oce interface (ice shelf side)
538	CALL eos(ztstop,risfdep,zrhdtop_isf)
539
540	! compute rhd at the ice/oce interface (ocean side)
541	DO ji=1,jpi
542	DO jj=1,jpj
543	ikt=mikt(ji,jj)
544	ztstop(ji,jj,1)=tsn(ji,jj,ikt,1)
545	ztstop(ji,jj,2)=tsn(ji,jj,ikt,2)
546	END DO
547	END DO
548	CALL eos(ztstop,risfdep,zrhdtop_oce)
549	!
550	! Surface value + ice shelf gradient
551	! compute pressure due to ice shelf load (used to compute hpgi/j for all the level from 1 to miku/v)
552	ziceload = 0._wp
553	DO jj = 1, jpj
554	DO ji = 1, jpi ! vector opt.
555	ikt=mikt(ji,jj)
556	ziceload(ji,jj) = ziceload(ji,jj) + (znad + rhd(ji,jj,1) ) * fse3w(ji,jj,1) * (1._wp - tmask(ji,jj,1))
557	DO jk=2,ikt-1
558	ziceload(ji,jj) = ziceload(ji,jj) + (2._wp * znad + rhd(ji,jj,jk-1) + rhd(ji,jj,jk)) * fse3w(ji,jj,jk) &
559	& * (1._wp - tmask(ji,jj,jk))
560	END DO
561	IF (ikt .GE. 2) ziceload(ji,jj) = ziceload(ji,jj) + (2._wp * znad + zrhdtop_isf(ji,jj) + rhd(ji,jj,ikt-1)) &
562	& * ( risfdep(ji,jj) - gdept_1d(ikt-1) )
563	END DO
564	END DO
565	riceload(:,:) = 0.0_wp ; riceload(:,:)=ziceload(:,:) ! need to be saved for diaar5
566	! compute zp from z=0 to first T wet point (correction due to zps not yet applied)
567	DO jj = 2, jpjm1
568	DO ji = fs_2, fs_jpim1 ! vector opt.
569	ikt=mikt(ji,jj) ; iktp1i=mikt(ji+1,jj); iktp1j=mikt(ji,jj+1)
570	! hydrostatic pressure gradient along s-surfaces and ice shelf pressure
571	! we assume ISF is in isostatic equilibrium
572	zhpi(ji,jj,1) = zcoef0 / e1u(ji,jj) * ( 0.5_wp * fse3w(ji+1,jj ,iktp1i) &
573	& * ( 2._wp * znad + rhd(ji+1,jj ,iktp1i) + zrhdtop_oce(ji+1,jj ) ) &
574	& - 0.5_wp * fse3w(ji ,jj ,ikt ) &
575	& * ( 2._wp * znad + rhd(ji ,jj ,ikt ) + zrhdtop_oce(ji ,jj ) ) &
576	& + ( ziceload(ji+1,jj) - ziceload(ji,jj)) )
577	zhpj(ji,jj,1) = zcoef0 / e2v(ji,jj) * ( 0.5_wp * fse3w(ji ,jj+1,iktp1j) &
578	& * ( 2._wp * znad + rhd(ji ,jj+1,iktp1j) + zrhdtop_oce(ji ,jj+1) ) &
579	& - 0.5_wp * fse3w(ji ,jj ,ikt ) &
580	& * ( 2._wp * znad + rhd(ji ,jj ,ikt ) + zrhdtop_oce(ji ,jj ) ) &
581	& + ( ziceload(ji,jj+1) - ziceload(ji,jj) ) )
582	! s-coordinate pressure gradient correction (=0 if z coordinate)
583	zuap = -zcoef0 * ( rhd (ji+1,jj,1) + rhd (ji,jj,1) + 2._wp * znad ) &
584	& * ( fsde3w(ji+1,jj,1) - fsde3w(ji,jj,1) ) / e1u(ji,jj)
585	zvap = -zcoef0 * ( rhd (ji,jj+1,1) + rhd (ji,jj,1) + 2._wp * znad ) &
586	& * ( fsde3w(ji,jj+1,1) - fsde3w(ji,jj,1) ) / e2v(ji,jj)
587	! add to the general momentum trend
588	ua(ji,jj,1) = ua(ji,jj,1) + (zhpi(ji,jj,1) + zuap) * umask(ji,jj,1)
589	va(ji,jj,1) = va(ji,jj,1) + (zhpj(ji,jj,1) + zvap) * vmask(ji,jj,1)
590	END DO
591	END DO
592	!==================================================================================
593	!===== Compute partial cell contribution for the top cell =========================
594	!==================================================================================
595	DO jj = 2, jpjm1
596	DO ji = fs_2, fs_jpim1 ! vector opt.
597	iku = miku(ji,jj) ;
598	zpshpi(ji,jj)=0.0_wp ; zpshpj(ji,jj)=0.0_wp
599	ze3wu = (gdepw_0(ji+1,jj,iku+1) - gdept_0(ji+1,jj,iku)) - (gdepw_0(ji,jj,iku+1) - gdept_0(ji,jj,iku))
600	! u direction
601	IF ( iku .GT. 1 ) THEN
602	! case iku
603	zhpi(ji,jj,iku) = zcoef0 / e1u(ji,jj) * ze3wu &
604	& * ( rhd (ji+1,jj,iku) + rhd (ji,jj,iku) &
605	& + SIGN(1._wp,ze3wu) * grui(ji,jj) + 2._wp * znad )
606	! corrective term ( = 0 if z coordinate )
607	zuap = -zcoef0 * ( arui(ji,jj) + 2._wp * znad ) * gzui(ji,jj) / e1u(ji,jj)
608	! zhpi will be added in interior loop
609	ua(ji,jj,iku) = ua(ji,jj,iku) + zuap
610	! in case of 2 cell water column, need to save the pressure gradient to compute the bottom pressure
611	IF (mbku(ji,jj) == iku + 1) zpshpi(ji,jj) = zhpi(ji,jj,iku)
612
613	! case iku + 1 (remove the zphi term added in the interior loop and compute the one corrected for zps)
614	zhpiint = zcoef0 / e1u(ji,jj) &
615	& * ( fse3w(ji+1,jj ,iku+1) * ( (rhd(ji+1,jj,iku+1) + znad) &
616	& + (rhd(ji+1,jj,iku ) + znad) ) * tmask(ji+1,jj,iku) &
617	& - fse3w(ji ,jj ,iku+1) * ( (rhd(ji ,jj,iku+1) + znad) &
618	& + (rhd(ji ,jj,iku ) + znad) ) * tmask(ji ,jj,iku) )
619	zhpi(ji,jj,iku+1) = zcoef0 / e1u(ji,jj) * ge3rui(ji,jj) - zhpiint
620	END IF
621
622	! v direction
623	ikv = mikv(ji,jj)
624	ze3wv = (gdepw_0(ji,jj+1,ikv+1) - gdept_0(ji,jj+1,ikv)) - (gdepw_0(ji,jj,ikv+1) - gdept_0(ji,jj,ikv))
625	IF ( ikv .GT. 1 ) THEN
626	! case ikv
627	zhpj(ji,jj,ikv) = zcoef0 / e2v(ji,jj) * ze3wv &
628	& * ( rhd(ji,jj+1,ikv) + rhd (ji,jj,ikv) &
629	& + SIGN(1._wp,ze3wv) * grvi(ji,jj) + 2._wp * znad )
630	! corrective term ( = 0 if z coordinate )
631	zvap = -zcoef0 * ( arvi(ji,jj) + 2._wp * znad ) * gzvi(ji,jj) / e2v(ji,jj)
632	! zhpi will be added in interior loop
633	va(ji,jj,ikv) = va(ji,jj,ikv) + zvap
634	! in case of 2 cell water column, need to save the pressure gradient to compute the bottom pressure
635	IF (mbkv(ji,jj) == ikv + 1) zpshpj(ji,jj) = zhpj(ji,jj,ikv)
636
637	! case ikv + 1 (remove the zphj term added in the interior loop and compute the one corrected for zps)
638	zhpjint = zcoef0 / e2v(ji,jj) &
639	& * ( fse3w(ji ,jj+1,ikv+1) * ( (rhd(ji,jj+1,ikv+1) + znad) &
640	& + (rhd(ji,jj+1,ikv ) + znad) ) * tmask(ji,jj+1,ikv) &
641	& - fse3w(ji ,jj ,ikv+1) * ( (rhd(ji,jj ,ikv+1) + znad) &
642	& + (rhd(ji,jj ,ikv ) + znad) ) * tmask(ji,jj ,ikv) )
643	zhpj(ji,jj,ikv+1) = zcoef0 / e2v(ji,jj) * ge3rvi(ji,jj) - zhpjint
644	END IF
645	END DO
646	END DO
647
648	!==================================================================================
649	!===== Compute interior value =====================================================
650	!==================================================================================
651
652	DO jj = 2, jpjm1
653	DO ji = fs_2, fs_jpim1 ! vector opt.
654	iku=miku(ji,jj); ikv=mikv(ji,jj)
655	DO jk = 2, jpkm1
656	! hydrostatic pressure gradient along s-surfaces
657	! zhpi is masked for the first wet cell (contribution already done in the upper bloc)
658	zhpi(ji,jj,jk) = zhpi(ji,jj,jk) + zhpi(ji,jj,jk-1) &
659	& + zcoef0 / e1u(ji,jj) &
660	& * ( fse3w(ji+1,jj ,jk) * ( (rhd(ji+1,jj,jk ) + znad) &
661	& + (rhd(ji+1,jj,jk-1) + znad) ) * tmask(ji+1,jj,jk-1) &
662	& - fse3w(ji ,jj ,jk) * ( (rhd(ji ,jj,jk ) + znad) &
663	& + (rhd(ji ,jj,jk-1) + znad) ) * tmask(ji ,jj,jk-1) )
664	! s-coordinate pressure gradient correction
665	! corrective term, we mask this term for the first wet level beneath the ice shelf (contribution done in the upper bloc)
666	zuap = - zcoef0 * ( rhd (ji+1,jj ,jk) + rhd (ji,jj,jk) + 2._wp * znad ) &
667	& * ( fsde3w(ji+1,jj ,jk) - fsde3w(ji,jj,jk) ) / e1u(ji,jj) * umask(ji,jj,jk-1)
668	ua(ji,jj,jk) = ua(ji,jj,jk) + ( zhpi(ji,jj,jk) + zuap) * umask(ji,jj,jk)
669
670	! hydrostatic pressure gradient along s-surfaces
671	! zhpi is masked for the first wet cell (contribution already done in the upper bloc)
672	zhpj(ji,jj,jk) = zhpj(ji,jj,jk) + zhpj(ji,jj,jk-1) &
673	& + zcoef0 / e2v(ji,jj) &
674	& * ( fse3w(ji ,jj+1,jk) * ( (rhd(ji,jj+1,jk ) + znad) &
675	& + (rhd(ji,jj+1,jk-1) + znad) ) * tmask(ji,jj+1,jk-1) &
676	& - fse3w(ji ,jj ,jk) * ( (rhd(ji,jj ,jk ) + znad) &
677	& + (rhd(ji,jj ,jk-1) + znad) ) * tmask(ji,jj ,jk-1) )
678	! s-coordinate pressure gradient correction
679	! corrective term, we mask this term for the first wet level beneath the ice shelf (contribution done in the upper bloc)
680	zvap = - zcoef0 * ( rhd (ji ,jj+1,jk) + rhd (ji,jj,jk) + 2._wp * znad ) &
681	& * ( fsde3w(ji ,jj+1,jk) - fsde3w(ji,jj,jk) ) / e2v(ji,jj) * vmask(ji,jj,jk-1)
682	! add to the general momentum trend
683	va(ji,jj,jk) = va(ji,jj,jk) + ( zhpj(ji,jj,jk) + zvap ) * vmask(ji,jj,jk)
684	END DO
685	END DO
686	END DO
687
688	!==================================================================================
689	!===== Compute bottom cell contribution (partial cell) ============================
690	!==================================================================================
691
692	DO jj = 2, jpjm1
693	DO ji = 2, jpim1
694	iku = mbku(ji,jj)
695	ikv = mbkv(ji,jj)
696
697	IF (iku .GT. 1) THEN
698	! remove old value (interior case)
699	zuap = -zcoef0 * ( rhd (ji+1,jj ,iku) + rhd (ji,jj,iku) + 2._wp * znad ) &
700	& * ( fsde3w(ji+1,jj ,iku) - fsde3w(ji,jj,iku) ) / e1u(ji,jj)
701	ua(ji,jj,iku) = ua(ji,jj,iku) - zhpi(ji,jj,iku) - zuap
702	! put new value
703	! -zpshpi to avoid double contribution of the partial step in the top layer
704	zuap = -zcoef0 * ( aru(ji,jj) + 2._wp * znad ) * gzu(ji,jj) / e1u(ji,jj)
705	zhpi(ji,jj,iku) = zhpi(ji,jj,iku-1) + zcoef0 / e1u(ji,jj) * ge3ru(ji,jj) - zpshpi(ji,jj)
706	ua(ji,jj,iku) = ua(ji,jj,iku) + zhpi(ji,jj,iku) + zuap
707	END IF
708	! v direction
709	IF (ikv .GT. 1) THEN
710	! remove old value (interior case)
711	zvap = -zcoef0 * ( rhd (ji ,jj+1,ikv) + rhd (ji,jj,ikv) + 2._wp * znad ) &
712	& * ( fsde3w(ji ,jj+1,ikv) - fsde3w(ji,jj,ikv) ) / e2v(ji,jj)
713	va(ji,jj,ikv) = va(ji,jj,ikv) - zhpj(ji,jj,ikv) - zvap
714	! put new value
715	! -zpshpj to avoid double contribution of the partial step in the top layer
716	zvap = -zcoef0 * ( arv(ji,jj) + 2._wp * znad ) * gzv(ji,jj) / e2v(ji,jj)
717	zhpj(ji,jj,ikv) = zhpj(ji,jj,ikv-1) + zcoef0 / e2v(ji,jj) * ge3rv(ji,jj) - zpshpj(ji,jj)
718	va(ji,jj,ikv) = va(ji,jj,ikv) + zhpj(ji,jj,ikv) + zvap
719	END IF
720	END DO
721	END DO
722
723	! set back to original density value into the ice shelf cell (maybe useless because it is masked)
724	rhd = zrhd
725	!
726	CALL wrk_dealloc( jpi,jpj,2, ztstop)
727	CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zhpj, zrhd)
728	CALL wrk_dealloc( jpi,jpj, ze3w, zp, zrhdtop_isf, zrhdtop_oce, ziceload, zdept, zpshpi, zpshpj)
729	!
730	END SUBROUTINE hpg_isf
731
732
733	SUBROUTINE hpg_djc( kt )
734	!!---------------------------------------------------------------------
735	!! * ROUTINE hpg_djc *
736	!!
737	!! ** Method : Density Jacobian with Cubic polynomial scheme
738	!!
739	!! Reference: Shchepetkin and McWilliams, J. Geophys. Res., 108(C3), 3090, 2003
740	!!----------------------------------------------------------------------
741	INTEGER, INTENT(in) :: kt ! ocean time-step index
742	!!
743	INTEGER :: ji, jj, jk ! dummy loop indices
744	REAL(wp) :: zcoef0, zep, cffw ! temporary scalars
745	REAL(wp) :: z1_10, cffu, cffx ! " "
746	REAL(wp) :: z1_12, cffv, cffy ! " "
747	REAL(wp), POINTER, DIMENSION(:,:,:) :: zhpi, zhpj
748	REAL(wp), POINTER, DIMENSION(:,:,:) :: dzx, dzy, dzz, dzu, dzv, dzw
749	REAL(wp), POINTER, DIMENSION(:,:,:) :: drhox, drhoy, drhoz, drhou, drhov, drhow
750	REAL(wp), POINTER, DIMENSION(:,:,:) :: rho_i, rho_j, rho_k
751	!!----------------------------------------------------------------------
752	!
753	CALL wrk_alloc( jpi, jpj, jpk, dzx , dzy , dzz , dzu , dzv , dzw )
754	CALL wrk_alloc( jpi, jpj, jpk, drhox, drhoy, drhoz, drhou, drhov, drhow )
755	CALL wrk_alloc( jpi, jpj, jpk, rho_i, rho_j, rho_k, zhpi, zhpj )
756	!
757
758	IF( kt == nit000 ) THEN
759	IF(lwp) WRITE(numout,*)
760	IF(lwp) WRITE(numout,*) 'dyn:hpg_djc : hydrostatic pressure gradient trend'
761	IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ s-coordinate case, density Jacobian with cubic polynomial scheme'
762	ENDIF
763
764	! Local constant initialization
765	zcoef0 = - grav * 0.5_wp
766	z1_10 = 1._wp / 10._wp
767	z1_12 = 1._wp / 12._wp
768
769	!----------------------------------------------------------------------------------------
770	! compute and store in provisional arrays elementary vertical and horizontal differences
771	!----------------------------------------------------------------------------------------
772
773	!!bug gm Not a true bug, but... dzz=e3w for dzx, dzy verify what it is really
774
775	DO jk = 2, jpkm1
776	DO jj = 2, jpjm1
777	DO ji = fs_2, fs_jpim1 ! vector opt.
778	drhoz(ji,jj,jk) = rhd (ji ,jj ,jk) - rhd (ji,jj,jk-1)
779	dzz (ji,jj,jk) = fsde3w(ji ,jj ,jk) - fsde3w(ji,jj,jk-1)
780	drhox(ji,jj,jk) = rhd (ji+1,jj ,jk) - rhd (ji,jj,jk )
781	dzx (ji,jj,jk) = fsde3w(ji+1,jj ,jk) - fsde3w(ji,jj,jk )
782	drhoy(ji,jj,jk) = rhd (ji ,jj+1,jk) - rhd (ji,jj,jk )
783	dzy (ji,jj,jk) = fsde3w(ji ,jj+1,jk) - fsde3w(ji,jj,jk )
784	END DO
785	END DO
786	END DO
787
788	!-------------------------------------------------------------------------
789	! compute harmonic averages using eq. 5.18
790	!-------------------------------------------------------------------------
791	zep = 1.e-15
792
793	!!bug gm drhoz not defined at level 1 and used (jk-1 with jk=2)
794	!!bug gm idem for drhox, drhoy et ji=jpi and jj=jpj
795
796	DO jk = 2, jpkm1
797	DO jj = 2, jpjm1
798	DO ji = fs_2, fs_jpim1 ! vector opt.
799	cffw = 2._wp * drhoz(ji ,jj ,jk) * drhoz(ji,jj,jk-1)
800
801	cffu = 2._wp * drhox(ji+1,jj ,jk) * drhox(ji,jj,jk )
802	cffx = 2._wp * dzx (ji+1,jj ,jk) * dzx (ji,jj,jk )
803
804	cffv = 2._wp * drhoy(ji ,jj+1,jk) * drhoy(ji,jj,jk )
805	cffy = 2._wp * dzy (ji ,jj+1,jk) * dzy (ji,jj,jk )
806
807	IF( cffw > zep) THEN
808	drhow(ji,jj,jk) = 2._wp * drhoz(ji,jj,jk) * drhoz(ji,jj,jk-1) &
809	& / ( drhoz(ji,jj,jk) + drhoz(ji,jj,jk-1) )
810	ELSE
811	drhow(ji,jj,jk) = 0._wp
812	ENDIF
813
814	dzw(ji,jj,jk) = 2._wp * dzz(ji,jj,jk) * dzz(ji,jj,jk-1) &
815	& / ( dzz(ji,jj,jk) + dzz(ji,jj,jk-1) )
816
817	IF( cffu > zep ) THEN
818	drhou(ji,jj,jk) = 2._wp * drhox(ji+1,jj,jk) * drhox(ji,jj,jk) &
819	& / ( drhox(ji+1,jj,jk) + drhox(ji,jj,jk) )
820	ELSE
821	drhou(ji,jj,jk ) = 0._wp
822	ENDIF
823
824	IF( cffx > zep ) THEN
825	dzu(ji,jj,jk) = 2._wp * dzx(ji+1,jj,jk) * dzx(ji,jj,jk) &
826	& / ( dzx(ji+1,jj,jk) + dzx(ji,jj,jk) )
827	ELSE
828	dzu(ji,jj,jk) = 0._wp
829	ENDIF
830
831	IF( cffv > zep ) THEN
832	drhov(ji,jj,jk) = 2._wp * drhoy(ji,jj+1,jk) * drhoy(ji,jj,jk) &
833	& / ( drhoy(ji,jj+1,jk) + drhoy(ji,jj,jk) )
834	ELSE
835	drhov(ji,jj,jk) = 0._wp
836	ENDIF
837
838	IF( cffy > zep ) THEN
839	dzv(ji,jj,jk) = 2._wp * dzy(ji,jj+1,jk) * dzy(ji,jj,jk) &
840	& / ( dzy(ji,jj+1,jk) + dzy(ji,jj,jk) )
841	ELSE
842	dzv(ji,jj,jk) = 0._wp
843	ENDIF
844
845	END DO
846	END DO
847	END DO
848
849	!----------------------------------------------------------------------------------
850	! apply boundary conditions at top and bottom using 5.36-5.37
851	!----------------------------------------------------------------------------------
852	drhow(:,:, 1 ) = 1.5_wp * ( drhoz(:,:, 2 ) - drhoz(:,:, 1 ) ) - 0.5_wp * drhow(:,:, 2 )
853	drhou(:,:, 1 ) = 1.5_wp * ( drhox(:,:, 2 ) - drhox(:,:, 1 ) ) - 0.5_wp * drhou(:,:, 2 )
854	drhov(:,:, 1 ) = 1.5_wp * ( drhoy(:,:, 2 ) - drhoy(:,:, 1 ) ) - 0.5_wp * drhov(:,:, 2 )
855
856	drhow(:,:,jpk) = 1.5_wp * ( drhoz(:,:,jpk) - drhoz(:,:,jpkm1) ) - 0.5_wp * drhow(:,:,jpkm1)
857	drhou(:,:,jpk) = 1.5_wp * ( drhox(:,:,jpk) - drhox(:,:,jpkm1) ) - 0.5_wp * drhou(:,:,jpkm1)
858	drhov(:,:,jpk) = 1.5_wp * ( drhoy(:,:,jpk) - drhoy(:,:,jpkm1) ) - 0.5_wp * drhov(:,:,jpkm1)
859
860
861	!--------------------------------------------------------------
862	! Upper half of top-most grid box, compute and store
863	!-------------------------------------------------------------
864
865	!!bug gm : e3w-de3w = 0.5*e3w .... and de3w(2)-de3w(1)=e3w(2) .... to be verified
866	! true if de3w is really defined as the sum of the e3w scale factors as, it seems to me, it should be
867
868	DO jj = 2, jpjm1
869	DO ji = fs_2, fs_jpim1 ! vector opt.
870	rho_k(ji,jj,1) = -grav * ( fse3w(ji,jj,1) - fsde3w(ji,jj,1) ) &
871	& * ( rhd(ji,jj,1) &
872	& + 0.5_wp * ( rhd(ji,jj,2) - rhd(ji,jj,1) ) &
873	& * ( fse3w (ji,jj,1) - fsde3w(ji,jj,1) ) &
874	& / ( fsde3w(ji,jj,2) - fsde3w(ji,jj,1) ) )
875	END DO
876	END DO
877
878	!!bug gm : here also, simplification is possible
879	!!bug gm : optimisation: 1/10 and 1/12 the division should be done before the loop
880
881	DO jk = 2, jpkm1
882	DO jj = 2, jpjm1
883	DO ji = fs_2, fs_jpim1 ! vector opt.
884
885	rho_k(ji,jj,jk) = zcoef0 * ( rhd (ji,jj,jk) + rhd (ji,jj,jk-1) ) &
886	& * ( fsde3w(ji,jj,jk) - fsde3w(ji,jj,jk-1) ) &
887	& - grav * z1_10 * ( &
888	& ( drhow (ji,jj,jk) - drhow (ji,jj,jk-1) ) &
889	& * ( fsde3w(ji,jj,jk) - fsde3w(ji,jj,jk-1) - z1_12 * ( dzw (ji,jj,jk) + dzw (ji,jj,jk-1) ) ) &
890	& - ( dzw (ji,jj,jk) - dzw (ji,jj,jk-1) ) &
891	& * ( rhd (ji,jj,jk) - rhd (ji,jj,jk-1) - z1_12 * ( drhow(ji,jj,jk) + drhow(ji,jj,jk-1) ) ) &
892	& )
893
894	rho_i(ji,jj,jk) = zcoef0 * ( rhd (ji+1,jj,jk) + rhd (ji,jj,jk) ) &
895	& * ( fsde3w(ji+1,jj,jk) - fsde3w(ji,jj,jk) ) &
896	& - grav* z1_10 * ( &
897	& ( drhou (ji+1,jj,jk) - drhou (ji,jj,jk) ) &
898	& * ( fsde3w(ji+1,jj,jk) - fsde3w(ji,jj,jk) - z1_12 * ( dzu (ji+1,jj,jk) + dzu (ji,jj,jk) ) ) &
899	& - ( dzu (ji+1,jj,jk) - dzu (ji,jj,jk) ) &
900	& * ( rhd (ji+1,jj,jk) - rhd (ji,jj,jk) - z1_12 * ( drhou(ji+1,jj,jk) + drhou(ji,jj,jk) ) ) &
901	& )
902
903	rho_j(ji,jj,jk) = zcoef0 * ( rhd (ji,jj+1,jk) + rhd (ji,jj,jk) ) &
904	& * ( fsde3w(ji,jj+1,jk) - fsde3w(ji,jj,jk) ) &
905	& - grav* z1_10 * ( &
906	& ( drhov (ji,jj+1,jk) - drhov (ji,jj,jk) ) &
907	& * ( fsde3w(ji,jj+1,jk) - fsde3w(ji,jj,jk) - z1_12 * ( dzv (ji,jj+1,jk) + dzv (ji,jj,jk) ) ) &
908	& - ( dzv (ji,jj+1,jk) - dzv (ji,jj,jk) ) &
909	& * ( rhd (ji,jj+1,jk) - rhd (ji,jj,jk) - z1_12 * ( drhov(ji,jj+1,jk) + drhov(ji,jj,jk) ) ) &
910	& )
911
912	END DO
913	END DO
914	END DO
915	CALL lbc_lnk(rho_k,'W',1.)
916	CALL lbc_lnk(rho_i,'U',1.)
917	CALL lbc_lnk(rho_j,'V',1.)
918
919
920	! ---------------
921	! Surface value
922	! ---------------
923	DO jj = 2, jpjm1
924	DO ji = fs_2, fs_jpim1 ! vector opt.
925	zhpi(ji,jj,1) = ( rho_k(ji+1,jj ,1) - rho_k(ji,jj,1) - rho_i(ji,jj,1) ) / e1u(ji,jj)
926	zhpj(ji,jj,1) = ( rho_k(ji ,jj+1,1) - rho_k(ji,jj,1) - rho_j(ji,jj,1) ) / e2v(ji,jj)
927	! add to the general momentum trend
928	ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
929	va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
930	END DO
931	END DO
932
933	! ----------------
934	! interior value (2=<jk=<jpkm1)
935	! ----------------
936	DO jk = 2, jpkm1
937	DO jj = 2, jpjm1
938	DO ji = fs_2, fs_jpim1 ! vector opt.
939	! hydrostatic pressure gradient along s-surfaces
940	zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) &
941	& + ( ( rho_k(ji+1,jj,jk) - rho_k(ji,jj,jk ) ) &
942	& - ( rho_i(ji ,jj,jk) - rho_i(ji,jj,jk-1) ) ) / e1u(ji,jj)
943	zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) &
944	& + ( ( rho_k(ji,jj+1,jk) - rho_k(ji,jj,jk ) ) &
945	& -( rho_j(ji,jj ,jk) - rho_j(ji,jj,jk-1) ) ) / e2v(ji,jj)
946	! add to the general momentum trend
947	ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
948	va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
949	END DO
950	END DO
951	END DO
952	!
953	CALL wrk_dealloc( jpi, jpj, jpk, dzx , dzy , dzz , dzu , dzv , dzw )
954	CALL wrk_dealloc( jpi, jpj, jpk, drhox, drhoy, drhoz, drhou, drhov, drhow )
955	CALL wrk_dealloc( jpi, jpj, jpk, rho_i, rho_j, rho_k, zhpi, zhpj )
956	!
957	END SUBROUTINE hpg_djc
958
959
960	SUBROUTINE hpg_prj( kt )
961	!!---------------------------------------------------------------------
962	!! * ROUTINE hpg_prj *
963	!!
964	!! ** Method : s-coordinate case.
965	!! A Pressure-Jacobian horizontal pressure gradient method
966	!! based on the constrained cubic-spline interpolation for
967	!! all vertical coordinate systems
968	!!
969	!! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
970	!!----------------------------------------------------------------------
971	INTEGER, PARAMETER :: polynomial_type = 1 ! 1: cubic spline, 2: linear
972	INTEGER, INTENT(in) :: kt ! ocean time-step index
973	!!
974	INTEGER :: ji, jj, jk, jkk ! dummy loop indices
975	REAL(wp) :: zcoef0, znad ! temporary scalars
976	!!
977	!! The local variables for the correction term
978	INTEGER :: jk1, jis, jid, jjs, jjd
979	REAL(wp) :: zuijk, zvijk, zpwes, zpwed, zpnss, zpnsd, zdeps
980	REAL(wp) :: zrhdt1
981	REAL(wp) :: zdpdx1, zdpdx2, zdpdy1, zdpdy2
982	REAL(wp), POINTER, DIMENSION(:,:,:) :: zdept, zrhh
983	REAL(wp), POINTER, DIMENSION(:,:,:) :: zhpi, zu, zv, fsp, xsp, asp, bsp, csp, dsp
984	REAL(wp), POINTER, DIMENSION(:,:) :: zsshu_n, zsshv_n
985	!!----------------------------------------------------------------------
986	!
987	CALL wrk_alloc( jpi,jpj,jpk, zhpi, zu, zv, fsp, xsp, asp, bsp, csp, dsp )
988	CALL wrk_alloc( jpi,jpj,jpk, zdept, zrhh )
989	CALL wrk_alloc( jpi,jpj, zsshu_n, zsshv_n )
990	!
991	IF( kt == nit000 ) THEN
992	IF(lwp) WRITE(numout,*)
993	IF(lwp) WRITE(numout,*) 'dyn:hpg_prj : hydrostatic pressure gradient trend'
994	IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ s-coordinate case, cubic spline pressure Jacobian'
995	ENDIF
996
997	!!----------------------------------------------------------------------
998	! Local constant initialization
999	zcoef0 = - grav
1000	znad = 0.0_wp
1001	IF( lk_vvl ) znad = 1._wp
1002
1003	! Clean 3-D work arrays
1004	zhpi(:,:,:) = 0._wp
1005	zrhh(:,:,:) = rhd(:,:,:)
1006
1007	! Preparing vertical density profile "zrhh(:,:,:)" for hybrid-sco coordinate
1008	DO jj = 1, jpj
1009	DO ji = 1, jpi
1010	jk = mbathy(ji,jj)
1011	IF( jk <= 0 ) THEN; zrhh(ji,jj,:) = 0._wp
1012	ELSE IF(jk == 1) THEN; zrhh(ji,jj, jk+1:jpk) = rhd(ji,jj,jk)
1013	ELSE IF(jk < jpkm1) THEN
1014	DO jkk = jk+1, jpk
1015	zrhh(ji,jj,jkk) = interp1(fsde3w(ji,jj,jkk), fsde3w(ji,jj,jkk-1), &
1016	fsde3w(ji,jj,jkk-2), rhd(ji,jj,jkk-1), rhd(ji,jj,jkk-2))
1017	END DO
1018	ENDIF
1019	END DO
1020	END DO
1021
1022	! Transfer the depth of "T(:,:,:)" to vertical coordinate "zdept(:,:,:)"
1023	DO jj = 1, jpj
1024	DO ji = 1, jpi
1025	zdept(ji,jj,1) = 0.5_wp * fse3w(ji,jj,1) - sshn(ji,jj) * znad
1026	END DO
1027	END DO
1028
1029	DO jk = 2, jpk
1030	DO jj = 1, jpj
1031	DO ji = 1, jpi
1032	zdept(ji,jj,jk) = zdept(ji,jj,jk-1) + fse3w(ji,jj,jk)
1033	END DO
1034	END DO
1035	END DO
1036
1037	fsp(:,:,:) = zrhh (:,:,:)
1038	xsp(:,:,:) = zdept(:,:,:)
1039
1040	! Construct the vertical density profile with the
1041	! constrained cubic spline interpolation
1042	! rho(z) = asp + bspz + cspz^2 + dsp*z^3
1043	CALL cspline(fsp,xsp,asp,bsp,csp,dsp,polynomial_type)
1044
1045	! Integrate the hydrostatic pressure "zhpi(:,:,:)" at "T(ji,jj,1)"
1046	DO jj = 2, jpj
1047	DO ji = 2, jpi
1048	zrhdt1 = zrhh(ji,jj,1) - interp3(zdept(ji,jj,1),asp(ji,jj,1), &
1049	bsp(ji,jj,1), csp(ji,jj,1), &
1050	dsp(ji,jj,1) ) * 0.25_wp * fse3w(ji,jj,1)
1051
1052	! assuming linear profile across the top half surface layer
1053	zhpi(ji,jj,1) = 0.5_wp * fse3w(ji,jj,1) * zrhdt1
1054	END DO
1055	END DO
1056
1057	! Calculate the pressure "zhpi(:,:,:)" at "T(ji,jj,2:jpkm1)"
1058	DO jk = 2, jpkm1
1059	DO jj = 2, jpj
1060	DO ji = 2, jpi
1061	zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) + &
1062	integ_spline(zdept(ji,jj,jk-1), zdept(ji,jj,jk),&
1063	asp(ji,jj,jk-1), bsp(ji,jj,jk-1), &
1064	csp(ji,jj,jk-1), dsp(ji,jj,jk-1))
1065	END DO
1066	END DO
1067	END DO
1068
1069	! Z coordinate of U(ji,jj,1:jpkm1) and V(ji,jj,1:jpkm1)
1070
1071	! Prepare zsshu_n and zsshv_n
1072	DO jj = 2, jpjm1
1073	DO ji = 2, jpim1
1074	zsshu_n(ji,jj) = (e12u(ji,jj) * sshn(ji,jj) + e12u(ji+1, jj) * sshn(ji+1,jj)) * &
1075	& r1_e12u(ji,jj) * umask(ji,jj,1) * 0.5_wp
1076	zsshv_n(ji,jj) = (e12v(ji,jj) * sshn(ji,jj) + e12v(ji+1, jj) * sshn(ji,jj+1)) * &
1077	& r1_e12v(ji,jj) * vmask(ji,jj,1) * 0.5_wp
1078	END DO
1079	END DO
1080
1081	DO jj = 2, jpjm1
1082	DO ji = 2, jpim1
1083	zu(ji,jj,1) = - ( fse3u(ji,jj,1) - zsshu_n(ji,jj) * znad)
1084	zv(ji,jj,1) = - ( fse3v(ji,jj,1) - zsshv_n(ji,jj) * znad)
1085	END DO
1086	END DO
1087
1088	DO jk = 2, jpkm1
1089	DO jj = 2, jpjm1
1090	DO ji = 2, jpim1
1091	zu(ji,jj,jk) = zu(ji,jj,jk-1)- fse3u(ji,jj,jk)
1092	zv(ji,jj,jk) = zv(ji,jj,jk-1)- fse3v(ji,jj,jk)
1093	END DO
1094	END DO
1095	END DO
1096
1097	DO jk = 1, jpkm1
1098	DO jj = 2, jpjm1
1099	DO ji = 2, jpim1
1100	zu(ji,jj,jk) = zu(ji,jj,jk) + 0.5_wp * fse3u(ji,jj,jk)
1101	zv(ji,jj,jk) = zv(ji,jj,jk) + 0.5_wp * fse3v(ji,jj,jk)
1102	END DO
1103	END DO
1104	END DO
1105
1106	DO jk = 1, jpkm1
1107	DO jj = 2, jpjm1
1108	DO ji = 2, jpim1
1109	zu(ji,jj,jk) = min(zu(ji,jj,jk), max(-zdept(ji,jj,jk), -zdept(ji+1,jj,jk)))
1110	zu(ji,jj,jk) = max(zu(ji,jj,jk), min(-zdept(ji,jj,jk), -zdept(ji+1,jj,jk)))
1111	zv(ji,jj,jk) = min(zv(ji,jj,jk), max(-zdept(ji,jj,jk), -zdept(ji,jj+1,jk)))
1112	zv(ji,jj,jk) = max(zv(ji,jj,jk), min(-zdept(ji,jj,jk), -zdept(ji,jj+1,jk)))
1113	END DO
1114	END DO
1115	END DO
1116
1117
1118	DO jk = 1, jpkm1
1119	DO jj = 2, jpjm1
1120	DO ji = 2, jpim1
1121	zpwes = 0._wp; zpwed = 0._wp
1122	zpnss = 0._wp; zpnsd = 0._wp
1123	zuijk = zu(ji,jj,jk)
1124	zvijk = zv(ji,jj,jk)
1125
1126	!!!!! for u equation
1127	IF( jk <= mbku(ji,jj) ) THEN
1128	IF( -zdept(ji+1,jj,jk) >= -zdept(ji,jj,jk) ) THEN
1129	jis = ji + 1; jid = ji
1130	ELSE
1131	jis = ji; jid = ji +1
1132	ENDIF
1133
1134	! integrate the pressure on the shallow side
1135	jk1 = jk
1136	DO WHILE ( -zdept(jis,jj,jk1) > zuijk )
1137	IF( jk1 == mbku(ji,jj) ) THEN
1138	zuijk = -zdept(jis,jj,jk1)
1139	EXIT
1140	ENDIF
1141	zdeps = MIN(zdept(jis,jj,jk1+1), -zuijk)
1142	zpwes = zpwes + &
1143	integ_spline(zdept(jis,jj,jk1), zdeps, &
1144	asp(jis,jj,jk1), bsp(jis,jj,jk1), &
1145	csp(jis,jj,jk1), dsp(jis,jj,jk1))
1146	jk1 = jk1 + 1
1147	END DO
1148
1149	! integrate the pressure on the deep side
1150	jk1 = jk
1151	DO WHILE ( -zdept(jid,jj,jk1) < zuijk )
1152	IF( jk1 == 1 ) THEN
1153	zdeps = zdept(jid,jj,1) + MIN(zuijk, sshn(jid,jj)*znad)
1154	zrhdt1 = zrhh(jid,jj,1) - interp3(zdept(jid,jj,1), asp(jid,jj,1), &
1155	bsp(jid,jj,1), csp(jid,jj,1), &
1156	dsp(jid,jj,1)) * zdeps
1157	zpwed = zpwed + 0.5_wp * (zrhh(jid,jj,1) + zrhdt1) * zdeps
1158	EXIT
1159	ENDIF
1160	zdeps = MAX(zdept(jid,jj,jk1-1), -zuijk)
1161	zpwed = zpwed + &
1162	integ_spline(zdeps, zdept(jid,jj,jk1), &
1163	asp(jid,jj,jk1-1), bsp(jid,jj,jk1-1), &
1164	csp(jid,jj,jk1-1), dsp(jid,jj,jk1-1) )
1165	jk1 = jk1 - 1
1166	END DO
1167
1168	! update the momentum trends in u direction
1169
1170	zdpdx1 = zcoef0 / e1u(ji,jj) * (zhpi(ji+1,jj,jk) - zhpi(ji,jj,jk))
1171	IF( lk_vvl ) THEN
1172	zdpdx2 = zcoef0 / e1u(ji,jj) * &
1173	( REAL(jis-jid, wp) * (zpwes + zpwed) + (sshn(ji+1,jj)-sshn(ji,jj)) )
1174	ELSE
1175	zdpdx2 = zcoef0 / e1u(ji,jj) * REAL(jis-jid, wp) * (zpwes + zpwed)
1176	ENDIF
1177
1178	ua(ji,jj,jk) = ua(ji,jj,jk) + (zdpdx1 + zdpdx2) * &
1179	& umask(ji,jj,jk) * tmask(ji,jj,jk) * tmask(ji+1,jj,jk)
1180	ENDIF
1181
1182	!!!!! for v equation
1183	IF( jk <= mbkv(ji,jj) ) THEN
1184	IF( -zdept(ji,jj+1,jk) >= -zdept(ji,jj,jk) ) THEN
1185	jjs = jj + 1; jjd = jj
1186	ELSE
1187	jjs = jj ; jjd = jj + 1
1188	ENDIF
1189
1190	! integrate the pressure on the shallow side
1191	jk1 = jk
1192	DO WHILE ( -zdept(ji,jjs,jk1) > zvijk )
1193	IF( jk1 == mbkv(ji,jj) ) THEN
1194	zvijk = -zdept(ji,jjs,jk1)
1195	EXIT
1196	ENDIF
1197	zdeps = MIN(zdept(ji,jjs,jk1+1), -zvijk)
1198	zpnss = zpnss + &
1199	integ_spline(zdept(ji,jjs,jk1), zdeps, &
1200	asp(ji,jjs,jk1), bsp(ji,jjs,jk1), &
1201	csp(ji,jjs,jk1), dsp(ji,jjs,jk1) )
1202	jk1 = jk1 + 1
1203	END DO
1204
1205	! integrate the pressure on the deep side
1206	jk1 = jk
1207	DO WHILE ( -zdept(ji,jjd,jk1) < zvijk )
1208	IF( jk1 == 1 ) THEN
1209	zdeps = zdept(ji,jjd,1) + MIN(zvijk, sshn(ji,jjd)*znad)
1210	zrhdt1 = zrhh(ji,jjd,1) - interp3(zdept(ji,jjd,1), asp(ji,jjd,1), &
1211	bsp(ji,jjd,1), csp(ji,jjd,1), &
1212	dsp(ji,jjd,1) ) * zdeps
1213	zpnsd = zpnsd + 0.5_wp * (zrhh(ji,jjd,1) + zrhdt1) * zdeps
1214	EXIT
1215	ENDIF
1216	zdeps = MAX(zdept(ji,jjd,jk1-1), -zvijk)
1217	zpnsd = zpnsd + &
1218	integ_spline(zdeps, zdept(ji,jjd,jk1), &
1219	asp(ji,jjd,jk1-1), bsp(ji,jjd,jk1-1), &
1220	csp(ji,jjd,jk1-1), dsp(ji,jjd,jk1-1) )
1221	jk1 = jk1 - 1
1222	END DO
1223
1224
1225	! update the momentum trends in v direction
1226
1227	zdpdy1 = zcoef0 / e2v(ji,jj) * (zhpi(ji,jj+1,jk) - zhpi(ji,jj,jk))
1228	IF( lk_vvl ) THEN
1229	zdpdy2 = zcoef0 / e2v(ji,jj) * &
1230	( REAL(jjs-jjd, wp) * (zpnss + zpnsd) + (sshn(ji,jj+1)-sshn(ji,jj)) )
1231	ELSE
1232	zdpdy2 = zcoef0 / e2v(ji,jj) * REAL(jjs-jjd, wp) * (zpnss + zpnsd )
1233	ENDIF
1234
1235	va(ji,jj,jk) = va(ji,jj,jk) + (zdpdy1 + zdpdy2)*&
1236	& vmask(ji,jj,jk)tmask(ji,jj,jk)tmask(ji,jj+1,jk)
1237	ENDIF
1238
1239
1240	END DO
1241	END DO
1242	END DO
1243	!
1244	CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zu, zv, fsp, xsp, asp, bsp, csp, dsp )
1245	CALL wrk_dealloc( jpi,jpj,jpk, zdept, zrhh )
1246	CALL wrk_dealloc( jpi,jpj, zsshu_n, zsshv_n )
1247	!
1248	END SUBROUTINE hpg_prj
1249
1250
1251	SUBROUTINE cspline(fsp, xsp, asp, bsp, csp, dsp, polynomial_type)
1252	!!----------------------------------------------------------------------
1253	!! * ROUTINE cspline *
1254	!!
1255	!! ** Purpose : constrained cubic spline interpolation
1256	!!
1257	!! ** Method : f(x) = asp + bspx + cspx^2 + dsp*x^3
1258	!!
1259	!! Reference: CJC Kruger, Constrained Cubic Spline Interpoltation
1260	!!----------------------------------------------------------------------
1261	IMPLICIT NONE
1262	REAL(wp), DIMENSION(:,:,:), INTENT(in) :: fsp, xsp ! value and coordinate
1263	REAL(wp), DIMENSION(:,:,:), INTENT(out) :: asp, bsp, csp, dsp ! coefficients of
1264	! the interpoated function
1265	INTEGER, INTENT(in) :: polynomial_type ! 1: cubic spline
1266	! 2: Linear
1267	!
1268	INTEGER :: ji, jj, jk ! dummy loop indices
1269	INTEGER :: jpi, jpj, jpkm1
1270	REAL(wp) :: zdf1, zdf2, zddf1, zddf2, ztmp1, ztmp2, zdxtmp
1271	REAL(wp) :: zdxtmp1, zdxtmp2, zalpha
1272	REAL(wp) :: zdf(size(fsp,3))
1273	!!----------------------------------------------------------------------
1274
1275	jpi = size(fsp,1)
1276	jpj = size(fsp,2)
1277	jpkm1 = size(fsp,3) - 1
1278
1279
1280	IF (polynomial_type == 1) THEN ! Constrained Cubic Spline
1281	DO ji = 1, jpi
1282	DO jj = 1, jpj
1283	!!Fritsch&Butland's method, 1984 (preferred, but more computation)
1284	! DO jk = 2, jpkm1-1
1285	! zdxtmp1 = xsp(ji,jj,jk) - xsp(ji,jj,jk-1)
1286	! zdxtmp2 = xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1287	! zdf1 = ( fsp(ji,jj,jk) - fsp(ji,jj,jk-1) ) / zdxtmp1
1288	! zdf2 = ( fsp(ji,jj,jk+1) - fsp(ji,jj,jk) ) / zdxtmp2
1289	!
1290	! zalpha = ( zdxtmp1 + 2._wp * zdxtmp2 ) / ( zdxtmp1 + zdxtmp2 ) / 3._wp
1291	!
1292	! IF(zdf1 * zdf2 <= 0._wp) THEN
1293	! zdf(jk) = 0._wp
1294	! ELSE
1295	! zdf(jk) = zdf1 * zdf2 / ( ( 1._wp - zalpha ) * zdf1 + zalpha * zdf2 )
1296	! ENDIF
1297	! END DO
1298
1299	!!Simply geometric average
1300	DO jk = 2, jpkm1-1
1301	zdf1 = (fsp(ji,jj,jk) - fsp(ji,jj,jk-1)) / (xsp(ji,jj,jk) - xsp(ji,jj,jk-1))
1302	zdf2 = (fsp(ji,jj,jk+1) - fsp(ji,jj,jk)) / (xsp(ji,jj,jk+1) - xsp(ji,jj,jk))
1303
1304	IF(zdf1 * zdf2 <= 0._wp) THEN
1305	zdf(jk) = 0._wp
1306	ELSE
1307	zdf(jk) = 2._wp * zdf1 * zdf2 / (zdf1 + zdf2)
1308	ENDIF
1309	END DO
1310
1311	zdf(1) = 1.5_wp * ( fsp(ji,jj,2) - fsp(ji,jj,1) ) / &
1312	& ( xsp(ji,jj,2) - xsp(ji,jj,1) ) - 0.5_wp * zdf(2)
1313	zdf(jpkm1) = 1.5_wp * ( fsp(ji,jj,jpkm1) - fsp(ji,jj,jpkm1-1) ) / &
1314	& ( xsp(ji,jj,jpkm1) - xsp(ji,jj,jpkm1-1) ) - &
1315	& 0.5_wp * zdf(jpkm1 - 1)
1316
1317	DO jk = 1, jpkm1 - 1
1318	zdxtmp = xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1319	ztmp1 = (zdf(jk+1) + 2._wp * zdf(jk)) / zdxtmp
1320	ztmp2 = 6._wp * (fsp(ji,jj,jk+1) - fsp(ji,jj,jk)) / zdxtmp / zdxtmp
1321	zddf1 = -2._wp * ztmp1 + ztmp2
1322	ztmp1 = (2._wp * zdf(jk+1) + zdf(jk)) / zdxtmp
1323	zddf2 = 2._wp * ztmp1 - ztmp2
1324
1325	dsp(ji,jj,jk) = (zddf2 - zddf1) / 6._wp / zdxtmp
1326	csp(ji,jj,jk) = ( xsp(ji,jj,jk+1) * zddf1 - xsp(ji,jj,jk)*zddf2 ) / 2._wp / zdxtmp
1327	bsp(ji,jj,jk) = ( fsp(ji,jj,jk+1) - fsp(ji,jj,jk) ) / zdxtmp - &
1328	& csp(ji,jj,jk) * ( xsp(ji,jj,jk+1) + xsp(ji,jj,jk) ) - &
1329	& dsp(ji,jj,jk) * ((xsp(ji,jj,jk+1) + xsp(ji,jj,jk))**2 - &
1330	& xsp(ji,jj,jk+1) * xsp(ji,jj,jk))
1331	asp(ji,jj,jk) = fsp(ji,jj,jk) - xsp(ji,jj,jk) * (bsp(ji,jj,jk) + &
1332	& (xsp(ji,jj,jk) * (csp(ji,jj,jk) + &
1333	& dsp(ji,jj,jk) * xsp(ji,jj,jk))))
1334	END DO
1335	END DO
1336	END DO
1337
1338	ELSE IF (polynomial_type == 2) THEN ! Linear
1339	DO ji = 1, jpi
1340	DO jj = 1, jpj
1341	DO jk = 1, jpkm1-1
1342	zdxtmp =xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1343	ztmp1 = fsp(ji,jj,jk+1) - fsp(ji,jj,jk)
1344
1345	dsp(ji,jj,jk) = 0._wp
1346	csp(ji,jj,jk) = 0._wp
1347	bsp(ji,jj,jk) = ztmp1 / zdxtmp
1348	asp(ji,jj,jk) = fsp(ji,jj,jk) - bsp(ji,jj,jk) * xsp(ji,jj,jk)
1349	END DO
1350	END DO
1351	END DO
1352
1353	ELSE
1354	CALL ctl_stop( 'invalid polynomial type in cspline' )
1355	ENDIF
1356
1357	END SUBROUTINE cspline
1358
1359
1360	FUNCTION interp1(x, xl, xr, fl, fr) RESULT(f)
1361	!!----------------------------------------------------------------------
1362	!! * ROUTINE interp1 *
1363	!!
1364	!! ** Purpose : 1-d linear interpolation
1365	!!
1366	!! ** Method : interpolation is straight forward
1367	!! extrapolation is also permitted (no value limit)
1368	!!----------------------------------------------------------------------
1369	IMPLICIT NONE
1370	REAL(wp), INTENT(in) :: x, xl, xr, fl, fr
1371	REAL(wp) :: f ! result of the interpolation (extrapolation)
1372	REAL(wp) :: zdeltx
1373	!!----------------------------------------------------------------------
1374
1375	zdeltx = xr - xl
1376	IF(abs(zdeltx) <= 10._wp * EPSILON(x)) THEN
1377	f = 0.5_wp * (fl + fr)
1378	ELSE
1379	f = ( (x - xl ) * fr - ( x - xr ) * fl ) / zdeltx
1380	ENDIF
1381
1382	END FUNCTION interp1
1383
1384
1385	FUNCTION interp2(x, a, b, c, d) RESULT(f)
1386	!!----------------------------------------------------------------------
1387	!! * ROUTINE interp1 *
1388	!!
1389	!! ** Purpose : 1-d constrained cubic spline interpolation
1390	!!
1391	!! ** Method : cubic spline interpolation
1392	!!
1393	!!----------------------------------------------------------------------
1394	IMPLICIT NONE
1395	REAL(wp), INTENT(in) :: x, a, b, c, d
1396	REAL(wp) :: f ! value from the interpolation
1397	!!----------------------------------------------------------------------
1398
1399	f = a + x* ( b + x * ( c + d * x ) )
1400
1401	END FUNCTION interp2
1402
1403
1404	FUNCTION interp3(x, a, b, c, d) RESULT(f)
1405	!!----------------------------------------------------------------------
1406	!! * ROUTINE interp1 *
1407	!!
1408	!! ** Purpose : Calculate the first order of deriavtive of
1409	!! a cubic spline function y=a+bx+cx^2+d*x^3
1410	!!
1411	!! ** Method : f=dy/dx=b+2cx+3dx^2
1412	!!
1413	!!----------------------------------------------------------------------
1414	IMPLICIT NONE
1415	REAL(wp), INTENT(in) :: x, a, b, c, d
1416	REAL(wp) :: f ! value from the interpolation
1417	!!----------------------------------------------------------------------
1418
1419	f = b + x * ( 2._wp * c + 3._wp * d * x)
1420
1421	END FUNCTION interp3
1422
1423
1424	FUNCTION integ_spline(xl, xr, a, b, c, d) RESULT(f)
1425	!!----------------------------------------------------------------------
1426	!! * ROUTINE interp1 *
1427	!!
1428	!! ** Purpose : 1-d constrained cubic spline integration
1429	!!
1430	!! ** Method : integrate polynomial a+bx+cx^2+dx^3 from xl to xr
1431	!!
1432	!!----------------------------------------------------------------------
1433	IMPLICIT NONE
1434	REAL(wp), INTENT(in) :: xl, xr, a, b, c, d
1435	REAL(wp) :: za1, za2, za3
1436	REAL(wp) :: f ! integration result
1437	!!----------------------------------------------------------------------
1438
1439	za1 = 0.5_wp * b
1440	za2 = c / 3.0_wp
1441	za3 = 0.25_wp * d
1442
1443	f = xr * ( a + xr * ( za1 + xr * ( za2 + za3 * xr ) ) ) - &
1444	& xl * ( a + xl * ( za1 + xl * ( za2 + za3 * xl ) ) )
1445
1446	END FUNCTION integ_spline
1447
1448	!!======================================================================
1449	END MODULE dynhpg
1450

Note: See TracBrowser for help on using the repository browser.

Download in other formats: