1 | MODULE zdftmx |
---|
2 | !!======================================================================== |
---|
3 | !! *** MODULE zdftmx *** |
---|
4 | !! Ocean physics: vertical tidal mixing coefficient |
---|
5 | !!======================================================================== |
---|
6 | !! History : 1.0 ! 2004-04 (L. Bessieres, G. Madec) Original code |
---|
7 | !! - ! 2006-08 (A. Koch-Larrouy) Indonesian strait |
---|
8 | !! 3.3 ! 2010-10 (C. Ethe, G. Madec) reorganisation of initialisation phase |
---|
9 | !!---------------------------------------------------------------------- |
---|
10 | #if defined key_zdftmx || defined key_esopa |
---|
11 | !!---------------------------------------------------------------------- |
---|
12 | !! 'key_zdftmx' Tidal vertical mixing |
---|
13 | !!---------------------------------------------------------------------- |
---|
14 | !! zdf_tmx : global momentum & tracer Kz with tidal induced Kz |
---|
15 | !! tmx_itf : Indonesian momentum & tracer Kz with tidal induced Kz |
---|
16 | !!---------------------------------------------------------------------- |
---|
17 | USE oce ! ocean dynamics and tracers variables |
---|
18 | USE dom_oce ! ocean space and time domain variables |
---|
19 | USE zdf_oce ! ocean vertical physics variables |
---|
20 | USE lbclnk ! ocean lateral boundary conditions (or mpp link) |
---|
21 | USE eosbn2 ! ocean equation of state |
---|
22 | USE phycst ! physical constants |
---|
23 | USE prtctl ! Print control |
---|
24 | USE in_out_manager ! I/O manager |
---|
25 | USE iom ! I/O Manager |
---|
26 | USE lib_mpp ! MPP library |
---|
27 | USE wrk_nemo ! work arrays |
---|
28 | USE timing ! Timing |
---|
29 | USE lib_fortran ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) |
---|
30 | |
---|
31 | IMPLICIT NONE |
---|
32 | PRIVATE |
---|
33 | |
---|
34 | PUBLIC zdf_tmx ! called in step module |
---|
35 | PUBLIC zdf_tmx_init ! called in opa module |
---|
36 | PUBLIC zdf_tmx_alloc ! called in nemogcm module |
---|
37 | |
---|
38 | LOGICAL, PUBLIC, PARAMETER :: lk_zdftmx = .TRUE. !: tidal mixing flag |
---|
39 | |
---|
40 | ! !!* Namelist namzdf_tmx : tidal mixing * |
---|
41 | REAL(wp) :: rn_htmx ! vertical decay scale for turbulence (meters) |
---|
42 | REAL(wp) :: rn_n2min ! threshold of the Brunt-Vaisala frequency (s-1) |
---|
43 | REAL(wp) :: rn_tfe ! tidal dissipation efficiency (St Laurent et al. 2002) |
---|
44 | REAL(wp) :: rn_me ! mixing efficiency (Osborn 1980) |
---|
45 | LOGICAL :: ln_tmx_itf ! Indonesian Through Flow (ITF): Koch-Larrouy et al. (2007) parameterization |
---|
46 | REAL(wp) :: rn_tfe_itf ! ITF tidal dissipation efficiency (St Laurent et al. 2002) |
---|
47 | |
---|
48 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: en_tmx ! energy available for tidal mixing (W/m2) |
---|
49 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: mask_itf ! mask to use over Indonesian area |
---|
50 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: az_tmx ! coefficient used to evaluate the tidal induced Kz |
---|
51 | |
---|
52 | !! * Substitutions |
---|
53 | # include "domzgr_substitute.h90" |
---|
54 | # include "vectopt_loop_substitute.h90" |
---|
55 | !!---------------------------------------------------------------------- |
---|
56 | !! NEMO/OPA 4.0 , NEMO Consortium (2011) |
---|
57 | !! $Id$ |
---|
58 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
---|
59 | !!---------------------------------------------------------------------- |
---|
60 | CONTAINS |
---|
61 | |
---|
62 | INTEGER FUNCTION zdf_tmx_alloc() |
---|
63 | !!---------------------------------------------------------------------- |
---|
64 | !! *** FUNCTION zdf_tmx_alloc *** |
---|
65 | !!---------------------------------------------------------------------- |
---|
66 | ALLOCATE(en_tmx(jpi,jpj), mask_itf(jpi,jpj), az_tmx(jpi,jpj,jpk), STAT=zdf_tmx_alloc ) |
---|
67 | ! |
---|
68 | IF( lk_mpp ) CALL mpp_sum ( zdf_tmx_alloc ) |
---|
69 | IF( zdf_tmx_alloc /= 0 ) CALL ctl_warn('zdf_tmx_alloc: failed to allocate arrays') |
---|
70 | END FUNCTION zdf_tmx_alloc |
---|
71 | |
---|
72 | |
---|
73 | SUBROUTINE zdf_tmx( kt ) |
---|
74 | !!---------------------------------------------------------------------- |
---|
75 | !! *** ROUTINE zdf_tmx *** |
---|
76 | !! |
---|
77 | !! ** Purpose : add to the vertical mixing coefficients the effect of |
---|
78 | !! tidal mixing (Simmons et al 2004). |
---|
79 | !! |
---|
80 | !! ** Method : - tidal-induced vertical mixing is given by: |
---|
81 | !! Kz_tides = az_tmx / max( rn_n2min, N^2 ) |
---|
82 | !! where az_tmx is a coefficient that specified the 3D space |
---|
83 | !! distribution of the faction of tidal energy taht is used |
---|
84 | !! for mixing. Its expression is set in zdf_tmx_init routine, |
---|
85 | !! following Simmons et al. 2004. |
---|
86 | !! NB: a specific bounding procedure is performed on av_tide |
---|
87 | !! so that the input tidal energy is actually almost used. The |
---|
88 | !! basic maximum value is 60 cm2/s, but values of 300 cm2/s |
---|
89 | !! can be reached in area where bottom stratification is too |
---|
90 | !! weak. |
---|
91 | !! |
---|
92 | !! - update av_tide in the Indonesian Through Flow area |
---|
93 | !! following Koch-Larrouy et al. (2007) parameterisation |
---|
94 | !! (see tmx_itf routine). |
---|
95 | !! |
---|
96 | !! - update the model vertical eddy viscosity and diffusivity: |
---|
97 | !! avt = avt + av_tides |
---|
98 | !! avm = avm + av_tides |
---|
99 | !! avmu = avmu + mi(av_tides) |
---|
100 | !! avmv = avmv + mj(av_tides) |
---|
101 | !! |
---|
102 | !! ** Action : avt, avm, avmu, avmv increased by tidal mixing |
---|
103 | !! |
---|
104 | !! References : Simmons et al. 2004, Ocean Modelling, 6, 3-4, 245-263. |
---|
105 | !! Koch-Larrouy et al. 2007, GRL. |
---|
106 | !!---------------------------------------------------------------------- |
---|
107 | USE oce, zav_tide => ua ! use ua as workspace |
---|
108 | !! |
---|
109 | INTEGER, INTENT(in) :: kt ! ocean time-step |
---|
110 | !! |
---|
111 | INTEGER :: ji, jj, jk ! dummy loop indices |
---|
112 | REAL(wp) :: ztpc ! scalar workspace |
---|
113 | REAL(wp), POINTER, DIMENSION(:,:) :: zkz |
---|
114 | !!---------------------------------------------------------------------- |
---|
115 | ! |
---|
116 | IF( nn_timing == 1 ) CALL timing_start('zdf_tmx') |
---|
117 | ! |
---|
118 | CALL wrk_alloc( jpi,jpj, zkz ) |
---|
119 | |
---|
120 | ! ! ----------------------- ! |
---|
121 | ! ! Standard tidal mixing ! (compute zav_tide) |
---|
122 | ! ! ----------------------- ! |
---|
123 | ! !* First estimation (with n2 bound by rn_n2min) bounded by 60 cm2/s |
---|
124 | zav_tide(:,:,:) = MIN( 60.e-4, az_tmx(:,:,:) / MAX( rn_n2min, rn2(:,:,:) ) ) |
---|
125 | |
---|
126 | zkz(:,:) = 0.e0 !* Associated potential energy consummed over the whole water column |
---|
127 | DO jk = 2, jpkm1 |
---|
128 | zkz(:,:) = zkz(:,:) + fse3w(:,:,jk) * MAX( 0.e0, rn2(:,:,jk) ) * rau0 * zav_tide(:,:,jk) * wmask(:,:,jk) |
---|
129 | END DO |
---|
130 | |
---|
131 | DO jj = 1, jpj !* Here zkz should be equal to en_tmx ==> multiply by en_tmx/zkz to recover en_tmx |
---|
132 | DO ji = 1, jpi |
---|
133 | IF( zkz(ji,jj) /= 0.e0 ) zkz(ji,jj) = en_tmx(ji,jj) / zkz(ji,jj) |
---|
134 | END DO |
---|
135 | END DO |
---|
136 | |
---|
137 | DO jk = 2, jpkm1 !* Mutiply by zkz to recover en_tmx, BUT bound by 30/6 ==> zav_tide bound by 300 cm2/s |
---|
138 | DO jj = 1, jpj !* Here zkz should be equal to en_tmx ==> multiply by en_tmx/zkz to recover en_tmx |
---|
139 | DO ji = 1, jpi |
---|
140 | zav_tide(ji,jj,jk) = zav_tide(ji,jj,jk) * MIN( zkz(ji,jj), 30./6. ) * wmask(ji,jj,jk) !kz max = 300 cm2/s |
---|
141 | END DO |
---|
142 | END DO |
---|
143 | END DO |
---|
144 | |
---|
145 | IF( kt == nit000 ) THEN !* check at first time-step: diagnose the energy consumed by zav_tide |
---|
146 | ztpc = 0.e0 |
---|
147 | DO jk= 1, jpk |
---|
148 | DO jj= 1, jpj |
---|
149 | DO ji= 1, jpi |
---|
150 | ztpc = ztpc + fse3w(ji,jj,jk) * e1t(ji,jj) * e2t(ji,jj) & |
---|
151 | & * MAX( 0.e0, rn2(ji,jj,jk) ) * zav_tide(ji,jj,jk) * tmask(ji,jj,jk) * tmask_i(ji,jj) |
---|
152 | END DO |
---|
153 | END DO |
---|
154 | END DO |
---|
155 | ztpc= rau0 / ( rn_tfe * rn_me ) * ztpc |
---|
156 | IF(lwp) WRITE(numout,*) |
---|
157 | IF(lwp) WRITE(numout,*) ' N Total power consumption by av_tide : ztpc = ', ztpc * 1.e-12 ,'TW' |
---|
158 | ENDIF |
---|
159 | |
---|
160 | ! ! ----------------------- ! |
---|
161 | ! ! ITF tidal mixing ! (update zav_tide) |
---|
162 | ! ! ----------------------- ! |
---|
163 | IF( ln_tmx_itf ) CALL tmx_itf( kt, zav_tide ) |
---|
164 | |
---|
165 | ! ! ----------------------- ! |
---|
166 | ! ! Update mixing coefs ! |
---|
167 | ! ! ----------------------- ! |
---|
168 | DO jk = 2, jpkm1 !* update momentum & tracer diffusivity with tidal mixing |
---|
169 | DO jj = 1, jpj !* Here zkz should be equal to en_tmx ==> multiply by en_tmx/zkz to recover en_tmx |
---|
170 | DO ji = 1, jpi |
---|
171 | avt(ji,jj,jk) = avt(ji,jj,jk) + zav_tide(ji,jj,jk) * wmask(ji,jj,jk) |
---|
172 | avm(ji,jj,jk) = avm(ji,jj,jk) + zav_tide(ji,jj,jk) * wmask(ji,jj,jk) |
---|
173 | END DO |
---|
174 | END DO |
---|
175 | END DO |
---|
176 | |
---|
177 | DO jk = 2, jpkm1 !* update momentum & tracer diffusivity with tidal mixing |
---|
178 | DO jj = 2, jpjm1 |
---|
179 | DO ji = fs_2, fs_jpim1 ! vector opt. |
---|
180 | avmu(ji,jj,jk) = avmu(ji,jj,jk) + 0.5 * ( zav_tide(ji,jj,jk) + zav_tide(ji+1,jj ,jk) ) * wumask(ji,jj,jk) |
---|
181 | avmv(ji,jj,jk) = avmv(ji,jj,jk) + 0.5 * ( zav_tide(ji,jj,jk) + zav_tide(ji ,jj+1,jk) ) * wvmask(ji,jj,jk) |
---|
182 | END DO |
---|
183 | END DO |
---|
184 | END DO |
---|
185 | CALL lbc_lnk( avmu, 'U', 1. ) ; CALL lbc_lnk( avmv, 'V', 1. ) ! lateral boundary condition |
---|
186 | |
---|
187 | ! !* output tidal mixing coefficient |
---|
188 | CALL iom_put( "av_tide", zav_tide ) |
---|
189 | |
---|
190 | IF(ln_ctl) CALL prt_ctl(tab3d_1=zav_tide , clinfo1=' tmx - av_tide: ', tab3d_2=avt, clinfo2=' avt: ', ovlap=1, kdim=jpk) |
---|
191 | ! |
---|
192 | CALL wrk_dealloc( jpi,jpj, zkz ) |
---|
193 | ! |
---|
194 | IF( nn_timing == 1 ) CALL timing_stop('zdf_tmx') |
---|
195 | ! |
---|
196 | END SUBROUTINE zdf_tmx |
---|
197 | |
---|
198 | |
---|
199 | SUBROUTINE tmx_itf( kt, pav ) |
---|
200 | !!---------------------------------------------------------------------- |
---|
201 | !! *** ROUTINE tmx_itf *** |
---|
202 | !! |
---|
203 | !! ** Purpose : modify the vertical eddy diffusivity coefficients |
---|
204 | !! (pav) in the Indonesian Through Flow area (ITF). |
---|
205 | !! |
---|
206 | !! ** Method : - Following Koch-Larrouy et al. (2007), in the ITF defined |
---|
207 | !! by msk_itf (read in a file, see tmx_init), the tidal |
---|
208 | !! mixing coefficient is computed with : |
---|
209 | !! * q=1 (i.e. all the tidal energy remains trapped in |
---|
210 | !! the area and thus is used for mixing) |
---|
211 | !! * the vertical distribution of the tifal energy is a |
---|
212 | !! proportional to N above the thermocline (d(N^2)/dz > 0) |
---|
213 | !! and to N^2 below the thermocline (d(N^2)/dz < 0) |
---|
214 | !! |
---|
215 | !! ** Action : av_tide updated in the ITF area (msk_itf) |
---|
216 | !! |
---|
217 | !! References : Koch-Larrouy et al. 2007, GRL |
---|
218 | !!---------------------------------------------------------------------- |
---|
219 | INTEGER , INTENT(in ) :: kt ! ocean time-step |
---|
220 | REAL(wp), INTENT(inout), DIMENSION(jpi,jpj,jpk) :: pav ! Tidal mixing coef. |
---|
221 | !! |
---|
222 | INTEGER :: ji, jj, jk ! dummy loop indices |
---|
223 | REAL(wp) :: zcoef, ztpc ! temporary scalar |
---|
224 | REAL(wp), DIMENSION(:,:) , POINTER :: zkz ! 2D workspace |
---|
225 | REAL(wp), DIMENSION(:,:) , POINTER :: zsum1 , zsum2 , zsum ! - - |
---|
226 | REAL(wp), DIMENSION(:,:,:), POINTER :: zempba_3d_1, zempba_3d_2 ! 3D workspace |
---|
227 | REAL(wp), DIMENSION(:,:,:), POINTER :: zempba_3d , zdn2dz ! - - |
---|
228 | REAL(wp), DIMENSION(:,:,:), POINTER :: zavt_itf ! - - |
---|
229 | !!---------------------------------------------------------------------- |
---|
230 | ! |
---|
231 | IF( nn_timing == 1 ) CALL timing_start('tmx_itf') |
---|
232 | ! |
---|
233 | CALL wrk_alloc( jpi,jpj, zkz, zsum1 , zsum2 , zsum ) |
---|
234 | CALL wrk_alloc( jpi,jpj,jpk, zempba_3d_1, zempba_3d_2, zempba_3d, zdn2dz, zavt_itf ) |
---|
235 | |
---|
236 | ! ! compute the form function using N2 at each time step |
---|
237 | zempba_3d_1(:,:,jpk) = 0.e0 |
---|
238 | zempba_3d_2(:,:,jpk) = 0.e0 |
---|
239 | DO jk = 1, jpkm1 |
---|
240 | zdn2dz (:,:,jk) = rn2(:,:,jk) - rn2(:,:,jk+1) ! Vertical profile of dN2/dz |
---|
241 | !CDIR NOVERRCHK |
---|
242 | zempba_3d_1(:,:,jk) = SQRT( MAX( 0.e0, rn2(:,:,jk) ) ) ! - - of N |
---|
243 | zempba_3d_2(:,:,jk) = MAX( 0.e0, rn2(:,:,jk) ) ! - - of N^2 |
---|
244 | END DO |
---|
245 | ! |
---|
246 | zsum (:,:) = 0.e0 |
---|
247 | zsum1(:,:) = 0.e0 |
---|
248 | zsum2(:,:) = 0.e0 |
---|
249 | DO jk= 2, jpk |
---|
250 | zsum1(:,:) = zsum1(:,:) + zempba_3d_1(:,:,jk) * fse3w(:,:,jk) * tmask(:,:,jk) * tmask(:,:,jk-1) |
---|
251 | zsum2(:,:) = zsum2(:,:) + zempba_3d_2(:,:,jk) * fse3w(:,:,jk) * tmask(:,:,jk) * tmask(:,:,jk-1) |
---|
252 | END DO |
---|
253 | DO jj = 1, jpj |
---|
254 | DO ji = 1, jpi |
---|
255 | IF( zsum1(ji,jj) /= 0.e0 ) zsum1(ji,jj) = 1.e0 / zsum1(ji,jj) |
---|
256 | IF( zsum2(ji,jj) /= 0.e0 ) zsum2(ji,jj) = 1.e0 / zsum2(ji,jj) |
---|
257 | END DO |
---|
258 | END DO |
---|
259 | |
---|
260 | DO jk= 1, jpk |
---|
261 | DO jj = 1, jpj |
---|
262 | DO ji = 1, jpi |
---|
263 | zcoef = 0.5 - SIGN( 0.5, zdn2dz(ji,jj,jk) ) ! =0 if dN2/dz > 0, =1 otherwise |
---|
264 | ztpc = zempba_3d_1(ji,jj,jk) * zsum1(ji,jj) * zcoef & |
---|
265 | & + zempba_3d_2(ji,jj,jk) * zsum2(ji,jj) * ( 1. - zcoef ) |
---|
266 | ! |
---|
267 | zempba_3d(ji,jj,jk) = ztpc |
---|
268 | zsum (ji,jj) = zsum(ji,jj) + ztpc * fse3w(ji,jj,jk) |
---|
269 | END DO |
---|
270 | END DO |
---|
271 | END DO |
---|
272 | DO jj = 1, jpj |
---|
273 | DO ji = 1, jpi |
---|
274 | IF( zsum(ji,jj) > 0.e0 ) zsum(ji,jj) = 1.e0 / zsum(ji,jj) |
---|
275 | END DO |
---|
276 | END DO |
---|
277 | |
---|
278 | ! ! first estimation bounded by 10 cm2/s (with n2 bounded by rn_n2min) |
---|
279 | zcoef = rn_tfe_itf / ( rn_tfe * rau0 ) |
---|
280 | DO jk = 1, jpk |
---|
281 | zavt_itf(:,:,jk) = MIN( 10.e-4, zcoef * en_tmx(:,:) * zsum(:,:) * zempba_3d(:,:,jk) & |
---|
282 | & / MAX( rn_n2min, rn2(:,:,jk) ) * tmask(:,:,jk) ) |
---|
283 | END DO |
---|
284 | |
---|
285 | zkz(:,:) = 0.e0 ! Associated potential energy consummed over the whole water column |
---|
286 | DO jk = 2, jpkm1 |
---|
287 | zkz(:,:) = zkz(:,:) + fse3w(:,:,jk) * MAX( 0.e0, rn2(:,:,jk) ) * rau0 * zavt_itf(:,:,jk) * tmask(:,:,jk) * tmask(:,:,jk-1) |
---|
288 | END DO |
---|
289 | |
---|
290 | DO jj = 1, jpj ! Here zkz should be equal to en_tmx ==> multiply by en_tmx/zkz to recover en_tmx |
---|
291 | DO ji = 1, jpi |
---|
292 | IF( zkz(ji,jj) /= 0.e0 ) zkz(ji,jj) = en_tmx(ji,jj) * rn_tfe_itf / rn_tfe / zkz(ji,jj) |
---|
293 | END DO |
---|
294 | END DO |
---|
295 | |
---|
296 | DO jk = 2, jpkm1 ! Mutiply by zkz to recover en_tmx, BUT bound by 30/6 ==> zavt_itf bound by 300 cm2/s |
---|
297 | zavt_itf(:,:,jk) = zavt_itf(:,:,jk) * MIN( zkz(:,:), 120./10. ) * tmask(:,:,jk) * tmask(:,:,jk-1) ! kz max = 120 cm2/s |
---|
298 | END DO |
---|
299 | |
---|
300 | IF( kt == nit000 ) THEN ! diagnose the nergy consumed by zavt_itf |
---|
301 | ztpc = 0.e0 |
---|
302 | DO jk= 1, jpk |
---|
303 | DO jj= 1, jpj |
---|
304 | DO ji= 1, jpi |
---|
305 | ztpc = ztpc + e1t(ji,jj) * e2t(ji,jj) * fse3w(ji,jj,jk) * MAX( 0.e0, rn2(ji,jj,jk) ) & |
---|
306 | & * zavt_itf(ji,jj,jk) * tmask(ji,jj,jk) * tmask_i(ji,jj) |
---|
307 | END DO |
---|
308 | END DO |
---|
309 | END DO |
---|
310 | ztpc= rau0 * ztpc / ( rn_me * rn_tfe_itf ) |
---|
311 | IF(lwp) WRITE(numout,*) ' N Total power consumption by zavt_itf: ztpc = ', ztpc * 1.e-12 ,'TW' |
---|
312 | ENDIF |
---|
313 | |
---|
314 | ! ! Update pav with the ITF mixing coefficient |
---|
315 | DO jk = 2, jpkm1 |
---|
316 | pav(:,:,jk) = pav (:,:,jk) * ( 1.e0 - mask_itf(:,:) ) & |
---|
317 | & + zavt_itf(:,:,jk) * mask_itf(:,:) |
---|
318 | END DO |
---|
319 | ! |
---|
320 | CALL wrk_dealloc( jpi,jpj, zkz, zsum1 , zsum2 , zsum ) |
---|
321 | CALL wrk_dealloc( jpi,jpj,jpk, zempba_3d_1, zempba_3d_2, zempba_3d, zdn2dz, zavt_itf ) |
---|
322 | ! |
---|
323 | IF( nn_timing == 1 ) CALL timing_stop('tmx_itf') |
---|
324 | ! |
---|
325 | END SUBROUTINE tmx_itf |
---|
326 | |
---|
327 | |
---|
328 | SUBROUTINE zdf_tmx_init |
---|
329 | !!---------------------------------------------------------------------- |
---|
330 | !! *** ROUTINE zdf_tmx_init *** |
---|
331 | !! |
---|
332 | !! ** Purpose : Initialization of the vertical tidal mixing, Reading |
---|
333 | !! of M2 and K1 tidal energy in nc files |
---|
334 | !! |
---|
335 | !! ** Method : - Read the namtmx namelist and check the parameters |
---|
336 | !! |
---|
337 | !! - Read the input data in NetCDF files : |
---|
338 | !! M2 and K1 tidal energy. The total tidal energy, en_tmx, |
---|
339 | !! is the sum of M2, K1 and S2 energy where S2 is assumed |
---|
340 | !! to be: S2=(1/2)^2 * M2 |
---|
341 | !! mask_itf, a mask array that determine where substituing |
---|
342 | !! the standard Simmons et al. (2005) formulation with the |
---|
343 | !! one of Koch_Larrouy et al. (2007). |
---|
344 | !! |
---|
345 | !! - Compute az_tmx, a 3D coefficient that allows to compute |
---|
346 | !! the standard tidal-induced vertical mixing as follows: |
---|
347 | !! Kz_tides = az_tmx / max( rn_n2min, N^2 ) |
---|
348 | !! with az_tmx a bottom intensified coefficient is given by: |
---|
349 | !! az_tmx(z) = en_tmx / ( rau0 * rn_htmx ) * EXP( -(H-z)/rn_htmx ) |
---|
350 | !! / ( 1. - EXP( - H /rn_htmx ) ) |
---|
351 | !! where rn_htmx the characteristic length scale of the bottom |
---|
352 | !! intensification, en_tmx the tidal energy, and H the ocean depth |
---|
353 | !! |
---|
354 | !! ** input : - Namlist namtmx |
---|
355 | !! - NetCDF file : M2_ORCA2.nc, K1_ORCA2.nc, and mask_itf.nc |
---|
356 | !! |
---|
357 | !! ** Action : - Increase by 1 the nstop flag is setting problem encounter |
---|
358 | !! - defined az_tmx used to compute tidal-induced mixing |
---|
359 | !! |
---|
360 | !! References : Simmons et al. 2004, Ocean Modelling, 6, 3-4, 245-263. |
---|
361 | !! Koch-Larrouy et al. 2007, GRL. |
---|
362 | !!---------------------------------------------------------------------- |
---|
363 | USE oce , zav_tide => ua ! ua used as workspace |
---|
364 | !! |
---|
365 | INTEGER :: ji, jj, jk ! dummy loop indices |
---|
366 | INTEGER :: inum ! local integer |
---|
367 | INTEGER :: ios |
---|
368 | REAL(wp) :: ztpc, ze_z ! local scalars |
---|
369 | REAL(wp), DIMENSION(:,:) , POINTER :: zem2, zek1 ! read M2 and K1 tidal energy |
---|
370 | REAL(wp), DIMENSION(:,:) , POINTER :: zkz ! total M2, K1 and S2 tidal energy |
---|
371 | REAL(wp), DIMENSION(:,:) , POINTER :: zfact ! used for vertical structure function |
---|
372 | REAL(wp), DIMENSION(:,:) , POINTER :: zhdep ! Ocean depth |
---|
373 | REAL(wp), DIMENSION(:,:,:), POINTER :: zpc ! power consumption |
---|
374 | !! |
---|
375 | NAMELIST/namzdf_tmx/ rn_htmx, rn_n2min, rn_tfe, rn_me, ln_tmx_itf, rn_tfe_itf |
---|
376 | !!---------------------------------------------------------------------- |
---|
377 | ! |
---|
378 | IF( nn_timing == 1 ) CALL timing_start('zdf_tmx_init') |
---|
379 | ! |
---|
380 | CALL wrk_alloc( jpi,jpj, zem2, zek1, zkz, zfact, zhdep ) |
---|
381 | CALL wrk_alloc( jpi,jpj,jpk, zpc ) |
---|
382 | |
---|
383 | REWIND( numnam_ref ) ! Namelist namzdf_tmx in reference namelist : Tidal Mixing |
---|
384 | READ ( numnam_ref, namzdf_tmx, IOSTAT = ios, ERR = 901) |
---|
385 | 901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namzdf_tmx in reference namelist', lwp ) |
---|
386 | |
---|
387 | REWIND( numnam_cfg ) ! Namelist namzdf_tmx in configuration namelist : Tidal Mixing |
---|
388 | READ ( numnam_cfg, namzdf_tmx, IOSTAT = ios, ERR = 902 ) |
---|
389 | 902 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namzdf_tmx in configuration namelist', lwp ) |
---|
390 | IF(lwm) WRITE ( numond, namzdf_tmx ) |
---|
391 | |
---|
392 | IF(lwp) THEN ! Control print |
---|
393 | WRITE(numout,*) |
---|
394 | WRITE(numout,*) 'zdf_tmx_init : tidal mixing' |
---|
395 | WRITE(numout,*) '~~~~~~~~~~~~' |
---|
396 | WRITE(numout,*) ' Namelist namzdf_tmx : set tidal mixing parameters' |
---|
397 | WRITE(numout,*) ' Vertical decay scale for turbulence = ', rn_htmx |
---|
398 | WRITE(numout,*) ' Brunt-Vaisala frequency threshold = ', rn_n2min |
---|
399 | WRITE(numout,*) ' Tidal dissipation efficiency = ', rn_tfe |
---|
400 | WRITE(numout,*) ' Mixing efficiency = ', rn_me |
---|
401 | WRITE(numout,*) ' ITF specific parameterisation = ', ln_tmx_itf |
---|
402 | WRITE(numout,*) ' ITF tidal dissipation efficiency = ', rn_tfe_itf |
---|
403 | ENDIF |
---|
404 | |
---|
405 | ! ! allocate tmx arrays |
---|
406 | IF( zdf_tmx_alloc() /= 0 ) CALL ctl_stop( 'STOP', 'zdf_tmx_init : unable to allocate tmx arrays' ) |
---|
407 | |
---|
408 | IF( ln_tmx_itf ) THEN ! read the Indonesian Through Flow mask |
---|
409 | CALL iom_open('mask_itf',inum) |
---|
410 | CALL iom_get (inum, jpdom_data, 'tmaskitf',mask_itf,1) ! |
---|
411 | CALL iom_close(inum) |
---|
412 | ENDIF |
---|
413 | |
---|
414 | ! read M2 tidal energy flux : W/m2 ( zem2 < 0 ) |
---|
415 | CALL iom_open('M2rowdrg',inum) |
---|
416 | CALL iom_get (inum, jpdom_data, 'field',zem2,1) ! |
---|
417 | CALL iom_close(inum) |
---|
418 | |
---|
419 | ! read K1 tidal energy flux : W/m2 ( zek1 < 0 ) |
---|
420 | CALL iom_open('K1rowdrg',inum) |
---|
421 | CALL iom_get (inum, jpdom_data, 'field',zek1,1) ! |
---|
422 | CALL iom_close(inum) |
---|
423 | |
---|
424 | ! Total tidal energy ( M2, S2 and K1 with S2=(1/2)^2 * M2 ) |
---|
425 | ! only the energy available for mixing is taken into account, |
---|
426 | ! (mixing efficiency tidal dissipation efficiency) |
---|
427 | en_tmx(:,:) = - rn_tfe * rn_me * ( zem2(:,:) * 1.25 + zek1(:,:) ) * ssmask(:,:) |
---|
428 | |
---|
429 | !============ |
---|
430 | !TG: Bug for VVL? Should this section be moved out of _init and be updated at every timestep? |
---|
431 | ! Vertical structure (az_tmx) |
---|
432 | DO jj = 1, jpj ! part independent of the level |
---|
433 | DO ji = 1, jpi |
---|
434 | zhdep(ji,jj) = gdepw_0(ji,jj,mbkt(ji,jj)+1) ! depth of the ocean |
---|
435 | zfact(ji,jj) = rau0 * rn_htmx * ( 1. - EXP( -zhdep(ji,jj) / rn_htmx ) ) |
---|
436 | IF( zfact(ji,jj) /= 0 ) zfact(ji,jj) = en_tmx(ji,jj) / zfact(ji,jj) |
---|
437 | END DO |
---|
438 | END DO |
---|
439 | DO jk= 1, jpk ! complete with the level-dependent part |
---|
440 | DO jj = 1, jpj |
---|
441 | DO ji = 1, jpi |
---|
442 | az_tmx(ji,jj,jk) = zfact(ji,jj) * EXP( -( zhdep(ji,jj)-gdepw_0(ji,jj,jk) ) / rn_htmx ) * tmask(ji,jj,jk) |
---|
443 | END DO |
---|
444 | END DO |
---|
445 | END DO |
---|
446 | !=========== |
---|
447 | |
---|
448 | IF( nprint == 1 .AND. lwp ) THEN |
---|
449 | ! Control print |
---|
450 | ! Total power consumption due to vertical mixing |
---|
451 | ! zpc = rau0 * 1/rn_me * rn2 * zav_tide |
---|
452 | zav_tide(:,:,:) = 0.e0 |
---|
453 | DO jk = 2, jpkm1 |
---|
454 | zav_tide(:,:,jk) = az_tmx(:,:,jk) / MAX( rn_n2min, rn2(:,:,jk) ) |
---|
455 | END DO |
---|
456 | |
---|
457 | ztpc = 0.e0 |
---|
458 | zpc(:,:,:) = MAX(rn_n2min,rn2(:,:,:)) * zav_tide(:,:,:) |
---|
459 | DO jk= 2, jpkm1 |
---|
460 | DO jj = 1, jpj |
---|
461 | DO ji = 1, jpi |
---|
462 | ztpc = ztpc + fse3w(ji,jj,jk) * e1t(ji,jj) * e2t(ji,jj) * zpc(ji,jj,jk) * wmask(ji,jj,jk) * tmask_i(ji,jj) |
---|
463 | END DO |
---|
464 | END DO |
---|
465 | END DO |
---|
466 | ztpc= rau0 * 1/(rn_tfe * rn_me) * ztpc |
---|
467 | |
---|
468 | WRITE(numout,*) |
---|
469 | WRITE(numout,*) ' Total power consumption of the tidally driven part of Kz : ztpc = ', ztpc * 1.e-12 ,'TW' |
---|
470 | |
---|
471 | |
---|
472 | ! control print 2 |
---|
473 | zav_tide(:,:,:) = MIN( zav_tide(:,:,:), 60.e-4 ) |
---|
474 | zkz(:,:) = 0.e0 |
---|
475 | DO jk = 2, jpkm1 |
---|
476 | DO jj = 1, jpj |
---|
477 | DO ji = 1, jpi |
---|
478 | zkz(ji,jj) = zkz(ji,jj) + fse3w(ji,jj,jk) * MAX(0.e0, rn2(ji,jj,jk)) * rau0 * zav_tide(ji,jj,jk) * wmask(ji,jj,jk) |
---|
479 | END DO |
---|
480 | END DO |
---|
481 | END DO |
---|
482 | ! Here zkz should be equal to en_tmx ==> multiply by en_tmx/zkz |
---|
483 | DO jj = 1, jpj |
---|
484 | DO ji = 1, jpi |
---|
485 | IF( zkz(ji,jj) /= 0.e0 ) THEN |
---|
486 | zkz(ji,jj) = en_tmx(ji,jj) / zkz(ji,jj) |
---|
487 | ENDIF |
---|
488 | END DO |
---|
489 | END DO |
---|
490 | ztpc = 1.e50 |
---|
491 | DO jj = 1, jpj |
---|
492 | DO ji = 1, jpi |
---|
493 | IF( zkz(ji,jj) /= 0.e0 ) THEN |
---|
494 | ztpc = Min( zkz(ji,jj), ztpc) |
---|
495 | ENDIF |
---|
496 | END DO |
---|
497 | END DO |
---|
498 | WRITE(numout,*) ' Min de zkz ', ztpc, ' Max = ', maxval(zkz(:,:) ) |
---|
499 | |
---|
500 | DO jk = 2, jpkm1 |
---|
501 | DO jj = 1, jpj |
---|
502 | DO ji = 1, jpi |
---|
503 | zav_tide(ji,jj,jk) = zav_tide(ji,jj,jk) * MIN( zkz(ji,jj), 30./6. ) * wmask(ji,jj,jk) !kz max = 300 cm2/s |
---|
504 | END DO |
---|
505 | END DO |
---|
506 | END DO |
---|
507 | ztpc = 0.e0 |
---|
508 | zpc(:,:,:) = Max(0.e0,rn2(:,:,:)) * zav_tide(:,:,:) |
---|
509 | DO jk= 1, jpk |
---|
510 | DO jj = 1, jpj |
---|
511 | DO ji = 1, jpi |
---|
512 | ztpc = ztpc + fse3w(ji,jj,jk) * e1t(ji,jj) * e2t(ji,jj) * zpc(ji,jj,jk) * wmask(ji,jj,jk) * tmask_i(ji,jj) |
---|
513 | END DO |
---|
514 | END DO |
---|
515 | END DO |
---|
516 | ztpc= rau0 * 1/(rn_tfe * rn_me) * ztpc |
---|
517 | WRITE(numout,*) ' 2 Total power consumption of the tidally driven part of Kz : ztpc = ', ztpc * 1.e-12 ,'TW' |
---|
518 | |
---|
519 | DO jk = 1, jpk |
---|
520 | ze_z = SUM( e1t(:,:) * e2t(:,:) * zav_tide(:,:,jk) * tmask_i(:,:) ) & |
---|
521 | & / MAX( 1.e-20, SUM( e1t(:,:) * e2t(:,:) * wmask (:,:,jk) * tmask_i(:,:) ) ) |
---|
522 | ztpc = 1.E50 |
---|
523 | DO jj = 1, jpj |
---|
524 | DO ji = 1, jpi |
---|
525 | IF( zav_tide(ji,jj,jk) /= 0.e0 ) ztpc =Min( ztpc, zav_tide(ji,jj,jk) ) |
---|
526 | END DO |
---|
527 | END DO |
---|
528 | WRITE(numout,*) ' N2 min - jk= ', jk,' ', ze_z * 1.e4,' cm2/s min= ',ztpc*1.e4, & |
---|
529 | & 'max= ', MAXVAL(zav_tide(:,:,jk) )*1.e4, ' cm2/s' |
---|
530 | END DO |
---|
531 | |
---|
532 | WRITE(numout,*) ' e_tide : ', SUM( e1t*e2t*en_tmx ) / ( rn_tfe * rn_me ) * 1.e-12, 'TW' |
---|
533 | WRITE(numout,*) |
---|
534 | WRITE(numout,*) ' Initial profile of tidal vertical mixing' |
---|
535 | DO jk = 1, jpk |
---|
536 | DO jj = 1,jpj |
---|
537 | DO ji = 1,jpi |
---|
538 | zkz(ji,jj) = az_tmx(ji,jj,jk) /MAX( rn_n2min, rn2(ji,jj,jk) ) |
---|
539 | END DO |
---|
540 | END DO |
---|
541 | ze_z = SUM( e1t(:,:) * e2t(:,:) * zkz(:,:) * tmask_i(:,:) ) & |
---|
542 | & / MAX( 1.e-20, SUM( e1t(:,:) * e2t(:,:) * wmask (:,:,jk) * tmask_i(:,:) ) ) |
---|
543 | WRITE(numout,*) ' jk= ', jk,' ', ze_z * 1.e4,' cm2/s' |
---|
544 | END DO |
---|
545 | DO jk = 1, jpk |
---|
546 | zkz(:,:) = az_tmx(:,:,jk) /rn_n2min |
---|
547 | ze_z = SUM( e1t(:,:) * e2t(:,:) * zkz(:,:) * tmask_i(:,:) ) & |
---|
548 | & / MAX( 1.e-20, SUM( e1t(:,:) * e2t(:,:) * wmask (:,:,jk) * tmask_i(:,:) ) ) |
---|
549 | WRITE(numout,*) |
---|
550 | WRITE(numout,*) ' N2 min - jk= ', jk,' ', ze_z * 1.e4,' cm2/s min= ',MINVAL(zkz)*1.e4, & |
---|
551 | & 'max= ', MAXVAL(zkz)*1.e4, ' cm2/s' |
---|
552 | END DO |
---|
553 | ! |
---|
554 | ENDIF |
---|
555 | ! |
---|
556 | CALL wrk_dealloc( jpi,jpj, zem2, zek1, zkz, zfact, zhdep ) |
---|
557 | CALL wrk_dealloc( jpi,jpj,jpk, zpc ) |
---|
558 | ! |
---|
559 | IF( nn_timing == 1 ) CALL timing_stop('zdf_tmx_init') |
---|
560 | ! |
---|
561 | END SUBROUTINE zdf_tmx_init |
---|
562 | |
---|
563 | #else |
---|
564 | !!---------------------------------------------------------------------- |
---|
565 | !! Default option Dummy module NO Tidal MiXing |
---|
566 | !!---------------------------------------------------------------------- |
---|
567 | LOGICAL, PUBLIC, PARAMETER :: lk_zdftmx = .FALSE. !: tidal mixing flag |
---|
568 | CONTAINS |
---|
569 | SUBROUTINE zdf_tmx_init ! Dummy routine |
---|
570 | WRITE(*,*) 'zdf_tmx: You should not have seen this print! error?' |
---|
571 | END SUBROUTINE zdf_tmx_init |
---|
572 | SUBROUTINE zdf_tmx( kt ) ! Dummy routine |
---|
573 | WRITE(*,*) 'zdf_tmx: You should not have seen this print! error?', kt |
---|
574 | END SUBROUTINE zdf_tmx |
---|
575 | #endif |
---|
576 | |
---|
577 | !!====================================================================== |
---|
578 | END MODULE zdftmx |
---|