Context Navigation

sbcrnf.F90 @ 15603

Last change on this file since 15603 was 15603, checked in by mattmartin, 3 years ago
Updated NEMO branch for coupled NWP at GO6 to include stochastic model perturbations. For more info see ticket: https://code.metoffice.gov.uk/trac/nwpscience/ticket/1125.
File size: 30.0 KB

Line
1	MODULE sbcrnf
2	!!======================================================================
3	!! * MODULE sbcrnf *
4	!! Ocean forcing: river runoff
5	!!=====================================================================
6	!! History : OPA ! 2000-11 (R. Hordoir, E. Durand) NetCDF FORMAT
7	!! NEMO 1.0 ! 2002-09 (G. Madec) F90: Free form and module
8	!! 3.0 ! 2006-07 (G. Madec) Surface module
9	!! 3.2 ! 2009-04 (B. Lemaire) Introduce iom_put
10	!! 3.3 ! 2010-10 (R. Furner, G. Madec) runoff distributed over ocean levels
11	!!----------------------------------------------------------------------
12
13	!!----------------------------------------------------------------------
14	!! sbc_rnf : monthly runoffs read in a NetCDF file
15	!! sbc_rnf_init : runoffs initialisation
16	!! rnf_mouth : set river mouth mask
17	!!----------------------------------------------------------------------
18	USE dom_oce ! ocean space and time domain
19	USE phycst ! physical constants
20	USE sbc_oce ! surface boundary condition variables
21	USE sbcisf ! PM we could remove it I think
22	USE closea ! closed seas
23	USE fldread ! read input field at current time step
24	USE in_out_manager ! I/O manager
25	USE iom ! I/O module
26	USE lib_mpp ! MPP library
27	USE eosbn2
28	USE wrk_nemo ! Memory allocation
29	USE timing
30
31	IMPLICIT NONE
32	PRIVATE
33
34	PUBLIC sbc_rnf ! routine call in sbcmod module
35	PUBLIC sbc_rnf_div ! routine called in divcurl module
36	PUBLIC sbc_rnf_alloc ! routine call in sbcmod module
37	PUBLIC sbc_rnf_init ! (PUBLIC for TAM)
38	! !!* namsbc_rnf namelist *
39	CHARACTER(len=100) :: cn_dir !: Root directory for location of rnf files
40	LOGICAL :: ln_rnf_depth !: depth river runoffs attribute specified in a file
41	LOGICAL :: ln_rnf_depth_ini !: depth river runoffs computed at the initialisation
42	REAL(wp) :: rn_rnf_max !: maximum value of the runoff climatologie ( ln_rnf_depth_ini = .true )
43	REAL(wp) :: rn_dep_max !: depth over which runoffs is spread ( ln_rnf_depth_ini = .true )
44	INTEGER :: nn_rnf_depth_file !: create (=1) a runoff depth file or not (=0)
45	LOGICAL :: ln_rnf_tem !: temperature river runoffs attribute specified in a file
46	LOGICAL , PUBLIC :: ln_rnf_sal !: salinity river runoffs attribute specified in a file
47	TYPE(FLD_N) , PUBLIC :: sn_rnf !: information about the runoff file to be read
48	TYPE(FLD_N) :: sn_cnf !: information about the runoff mouth file to be read
49	TYPE(FLD_N) :: sn_s_rnf !: information about the salinities of runoff file to be read
50	TYPE(FLD_N) :: sn_t_rnf !: information about the temperatures of runoff file to be read
51	TYPE(FLD_N) :: sn_dep_rnf !: information about the depth which river inflow affects
52	LOGICAL , PUBLIC :: ln_rnf_mouth !: specific treatment in mouths vicinity
53	REAL(wp) :: rn_hrnf !: runoffs, depth over which enhanced vertical mixing is used
54	REAL(wp) , PUBLIC :: rn_avt_rnf !: runoffs, value of the additional vertical mixing coef. [m2/s]
55	REAL(wp) , PUBLIC :: rn_rfact !: multiplicative factor for runoff
56	REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) :: rn_avt_rnf0
57
58	LOGICAL , PUBLIC :: l_rnfcpl = .false. ! runoffs recieved from oasis
59
60	INTEGER , PUBLIC :: nkrnf = 0 !: nb of levels over which Kz is increased at river mouths
61	REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) :: rnfmsk !: river mouth mask (hori.)
62	REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:) :: rnfmsk_z !: river mouth mask (vert.)
63	REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) :: h_rnf !: depth of runoff in m
64	INTEGER, PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) :: nk_rnf !: depth of runoff in model levels
65	REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: rnf_tsc_b, rnf_tsc !: before and now T & S runoff contents [K.m/s & PSU.m/s]
66
67	TYPE(FLD), ALLOCATABLE, DIMENSION(:) :: sf_rnf ! structure: river runoff (file information, fields read)
68	TYPE(FLD), ALLOCATABLE, DIMENSION(:) :: sf_s_rnf ! structure: river runoff salinity (file information, fields read)
69	TYPE(FLD), ALLOCATABLE, DIMENSION(:) :: sf_t_rnf ! structure: river runoff temperature (file information, fields read)
70
71	!! * Substitutions
72	# include "domzgr_substitute.h90"
73	!!----------------------------------------------------------------------
74	!! NEMO/OPA 3.3 , NEMO Consortium (2010)
75	!! $Id$
76	!! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
77	!!----------------------------------------------------------------------
78	CONTAINS
79
80	INTEGER FUNCTION sbc_rnf_alloc()
81	!!----------------------------------------------------------------------
82	!! * ROUTINE sbc_rnf_alloc *
83	!!----------------------------------------------------------------------
84	ALLOCATE( rnfmsk(jpi,jpj) , rnfmsk_z(jpk) , &
85	& h_rnf (jpi,jpj) , nk_rnf (jpi,jpj) , &
86	& rnf_tsc_b(jpi,jpj,jpts) , rnf_tsc (jpi,jpj,jpts) , STAT=sbc_rnf_alloc )
87	!
88	IF( lk_mpp ) CALL mpp_sum ( sbc_rnf_alloc )
89	IF( sbc_rnf_alloc > 0 ) CALL ctl_warn('sbc_rnf_alloc: allocation of arrays failed')
90	END FUNCTION sbc_rnf_alloc
91
92
93	SUBROUTINE sbc_rnf( kt )
94	!!----------------------------------------------------------------------
95	!! * ROUTINE sbc_rnf *
96	!!
97	!! ** Purpose : Introduce a climatological run off forcing
98	!!
99	!! ** Method : Set each river mouth with a monthly climatology
100	!! provided from different data.
101	!! CAUTION : upward water flux, runoff forced to be < 0
102	!!
103	!! ** Action : runoff updated runoff field at time-step kt
104	!!----------------------------------------------------------------------
105	INTEGER, INTENT(in) :: kt ! ocean time step
106	!
107	INTEGER :: ji, jj ! dummy loop indices
108	INTEGER :: z_err = 0 ! dummy integer for error handling
109	!!----------------------------------------------------------------------
110	REAL(wp), DIMENSION(:,:), POINTER :: ztfrz ! freezing point used for temperature correction
111	!
112	CALL wrk_alloc( jpi,jpj, ztfrz)
113	!
114	! !-------------------!
115	! ! Update runoff !
116	! !-------------------!
117	!
118	IF( .NOT. l_rnfcpl ) CALL fld_read ( kt, nn_fsbc, sf_rnf ) ! Read Runoffs data and provide it at kt
119	IF( ln_rnf_tem ) CALL fld_read ( kt, nn_fsbc, sf_t_rnf ) ! idem for runoffs temperature if required
120	IF( ln_rnf_sal ) CALL fld_read ( kt, nn_fsbc, sf_s_rnf ) ! idem for runoffs salinity if required
121	!
122	IF( MOD( kt - 1, nn_fsbc ) == 0 ) THEN
123	!
124	IF( .NOT. l_rnfcpl ) rnf(:,:) = rn_rfact * ( sf_rnf(1)%fnow(:,:,1) ) ! updated runoff value at time step kt
125	CALL lbc_lnk(rnf(:,:), 'T', 1._wp)
126	!
127	! ! set temperature & salinity content of runoffs
128	IF( ln_rnf_tem ) THEN ! use runoffs temperature data
129	rnf_tsc(:,:,jp_tem) = ( sf_t_rnf(1)%fnow(:,:,1) ) * rnf(:,:) * r1_rau0
130	WHERE( sf_t_rnf(1)%fnow(:,:,1) == -999._wp ) ! if missing data value use SST as runoffs temperature
131	rnf_tsc(:,:,jp_tem) = sst_m(:,:) * rnf(:,:) * r1_rau0
132	END WHERE
133	WHERE( sf_t_rnf(1)%fnow(:,:,1) == -222._wp ) ! where fwf comes from melting of ice shelves or iceberg
134	ztfrz(:,:) = -1.9 !tfreez( sss_m(:,:) ) !PM to be discuss (trouble if sensitivity study)
135	rnf_tsc(:,:,jp_tem) = ztfrz(:,:) * rnf(:,:) * r1_rau0 - rnf(:,:) * lfusisf * r1_rau0_rcp
136	END WHERE
137	ELSE ! use SST as runoffs temperature
138	rnf_tsc(:,:,jp_tem) = sst_m(:,:) * rnf(:,:) * r1_rau0
139	ENDIF
140	! ! use runoffs salinity data
141	IF( ln_rnf_sal ) rnf_tsc(:,:,jp_sal) = ( sf_s_rnf(1)%fnow(:,:,1) ) * rnf(:,:) * r1_rau0
142	! ! else use S=0 for runoffs (done one for all in the init)
143	CALL iom_put( "runoffs", rnf ) ! output runoffs arrays
144	ENDIF
145	!
146	! ! ---------------------------------------- !
147	IF( kt == nit000 ) THEN ! set the forcing field at nit000 - 1 !
148	! ! ---------------------------------------- !
149	IF( ln_rstart .AND. & !* Restart: read in restart file
150	& iom_varid( numror, 'rnf_b', ldstop = .FALSE. ) > 0 ) THEN
151	IF(lwp .AND. nprint > 0) WRITE(numout,*) ' nit000-1 runoff forcing fields red in the restart file'
152	IF(nn_timing == 2) CALL timing_start('iom_rstget')
153	CALL iom_get( numror, jpdom_autoglo, 'rnf_b', rnf_b ) ! before runoff
154	CALL iom_get( numror, jpdom_autoglo, 'rnf_hc_b', rnf_tsc_b(:,:,jp_tem) ) ! before heat content of runoff
155	CALL iom_get( numror, jpdom_autoglo, 'rnf_sc_b', rnf_tsc_b(:,:,jp_sal) ) ! before salinity content of runoff
156	IF(nn_timing == 2) CALL timing_stop('iom_rstget')
157	ELSE !* no restart: set from nit000 values
158	IF(lwp) WRITE(numout,*) ' nit000-1 runoff forcing fields set to nit000'
159	rnf_b (:,: ) = rnf (:,: )
160	rnf_tsc_b(:,:,:) = rnf_tsc(:,:,:)
161	ENDIF
162
163	IF(lwp .AND. lflush) CALL flush(numout)
164
165	ENDIF
166	! ! ---------------------------------------- !
167	IF( lrst_oce ) THEN ! Write in the ocean restart file !
168	! ! ---------------------------------------- !
169	IF(lwp .AND. nprint > 0) THEN
170	WRITE(numout,*)
171	WRITE(numout,*) 'sbcrnf : runoff forcing fields written in ocean restart file ', &
172	& 'at it= ', kt,' date= ', ndastp
173	WRITE(numout,*) '~~~~'
174	IF(lflush) CALL flush(numout)
175	ENDIF
176	IF(nn_timing == 2) CALL timing_start('iom_rstput')
177	CALL iom_rstput( kt, nitrst, numrow, 'rnf_b' , rnf )
178	CALL iom_rstput( kt, nitrst, numrow, 'rnf_hc_b', rnf_tsc(:,:,jp_tem) )
179	CALL iom_rstput( kt, nitrst, numrow, 'rnf_sc_b', rnf_tsc(:,:,jp_sal) )
180	IF(nn_timing == 2) CALL timing_stop('iom_rstput')
181	ENDIF
182	!
183	CALL wrk_dealloc( jpi,jpj, ztfrz)
184	!
185	END SUBROUTINE sbc_rnf
186
187
188	SUBROUTINE sbc_rnf_div( phdivn )
189	!!----------------------------------------------------------------------
190	!! * ROUTINE sbc_rnf *
191	!!
192	!! ** Purpose : update the horizontal divergence with the runoff inflow
193	!!
194	!! ** Method :
195	!! CAUTION : rnf is positive (inflow) decreasing the
196	!! divergence and expressed in m/s
197	!!
198	!! ** Action : phdivn decreased by the runoff inflow
199	!!----------------------------------------------------------------------
200	REAL(wp), DIMENSION(:,:,:), INTENT(inout) :: phdivn ! horizontal divergence
201	!!
202	INTEGER :: ji, jj, jk ! dummy loop indices
203	REAL(wp) :: zfact ! local scalar
204	!!----------------------------------------------------------------------
205	!
206	zfact = 0.5_wp
207	!
208	IF( ln_rnf_depth .OR. ln_rnf_depth_ini ) THEN !== runoff distributed over several levels ==!
209	IF( lk_vvl ) THEN ! variable volume case
210	DO jj = 1, jpj ! update the depth over which runoffs are distributed
211	DO ji = 1, jpi
212	h_rnf(ji,jj) = 0._wp
213	DO jk = 1, nk_rnf(ji,jj) ! recalculates h_rnf to be the depth in metres
214	h_rnf(ji,jj) = h_rnf(ji,jj) + fse3t(ji,jj,jk) ! to the bottom of the relevant grid box
215	END DO
216	! ! apply the runoff input flow
217	DO jk = 1, nk_rnf(ji,jj)
218	phdivn(ji,jj,jk) = phdivn(ji,jj,jk) - ( rnf(ji,jj) + rnf_b(ji,jj) ) * zfact * r1_rau0 / h_rnf(ji,jj)
219	END DO
220	END DO
221	END DO
222	ELSE ! constant volume case : just apply the runoff input flow
223	DO jj = 1, jpj
224	DO ji = 1, jpi
225	DO jk = 1, nk_rnf(ji,jj)
226	phdivn(ji,jj,jk) = phdivn(ji,jj,jk) - ( rnf(ji,jj) + rnf_b(ji,jj) ) * zfact * r1_rau0 / h_rnf(ji,jj)
227	END DO
228	END DO
229	END DO
230	ENDIF
231	ELSE !== runoff put only at the surface ==!
232	IF( lk_vvl ) THEN ! variable volume case
233	h_rnf(:,:) = fse3t(:,:,1) ! recalculate h_rnf to be depth of top box
234	ENDIF
235	phdivn(:,:,1) = phdivn(:,:,1) - ( rnf(:,:) + rnf_b(:,:) ) * zfact * r1_rau0 / fse3t(:,:,1)
236	ENDIF
237	!
238	END SUBROUTINE sbc_rnf_div
239
240
241	SUBROUTINE sbc_rnf_init
242	!!----------------------------------------------------------------------
243	!! * ROUTINE sbc_rnf_init *
244	!!
245	!! ** Purpose : Initialisation of the runoffs if (ln_rnf=T)
246	!!
247	!! ** Method : - read the runoff namsbc_rnf namelist
248	!!
249	!! ** Action : - read parameters
250	!!----------------------------------------------------------------------
251	CHARACTER(len=32) :: rn_dep_file ! runoff file name
252	INTEGER :: ji, jj, jk, jm ! dummy loop indices
253	INTEGER :: ierror, inum ! temporary integer
254	INTEGER :: ios ! Local integer output status for namelist read
255	INTEGER :: nbrec ! temporary integer
256	REAL(wp) :: zacoef
257	REAL(wp), DIMENSION(12) :: zrec ! times records
258	REAL(wp), DIMENSION(:,:,:), ALLOCATABLE :: zrnfcl
259	REAL(wp), DIMENSION(:,: ), ALLOCATABLE :: zrnf
260	!
261	NAMELIST/namsbc_rnf/ cn_dir , ln_rnf_depth, ln_rnf_tem, ln_rnf_sal, &
262	& sn_rnf, sn_cnf , sn_s_rnf , sn_t_rnf , sn_dep_rnf, &
263	& ln_rnf_mouth , rn_hrnf , rn_avt_rnf, rn_rfact, &
264	& ln_rnf_depth_ini , rn_dep_max , rn_rnf_max, nn_rnf_depth_file
265	!!----------------------------------------------------------------------
266	!
267	! !== allocate runoff arrays
268	IF( sbc_rnf_alloc() /= 0 ) CALL ctl_stop( 'STOP', 'sbc_rnf_alloc : unable to allocate arrays' )
269	!
270	IF( .NOT. ln_rnf ) THEN ! no specific treatment in vicinity of river mouths
271	ln_rnf_mouth = .FALSE. ! default definition needed for example by sbc_ssr or by tra_adv_muscl
272	nkrnf = 0
273	rnf (:,:) = 0.0_wp
274	rnf_b (:,:) = 0.0_wp
275	rnfmsk (:,:) = 0.0_wp
276	rnfmsk_z(:) = 0.0_wp
277	RETURN
278	ENDIF
279	!
280	! ! ============
281	! ! Namelist
282	! ! ============
283	!
284	REWIND( numnam_ref ) ! Namelist namsbc_rnf in reference namelist : Runoffs
285	READ ( numnam_ref, namsbc_rnf, IOSTAT = ios, ERR = 901)
286	901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc_rnf in reference namelist', lwp )
287
288	REWIND( numnam_cfg ) ! Namelist namsbc_rnf in configuration namelist : Runoffs
289	READ ( numnam_cfg, namsbc_rnf, IOSTAT = ios, ERR = 902 )
290	902 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc_rnf in configuration namelist', lwp )
291	IF(lwm .AND. nprint > 2) WRITE ( numond, namsbc_rnf )
292	!
293	! ! Control print
294	IF(lwp) THEN
295	WRITE(numout,*)
296	WRITE(numout,*) 'sbc_rnf : runoff '
297	WRITE(numout,*) '~~~~~~~ '
298	WRITE(numout,*) ' Namelist namsbc_rnf'
299	WRITE(numout,*) ' specific river mouths treatment ln_rnf_mouth = ', ln_rnf_mouth
300	WRITE(numout,*) ' river mouth additional Kz rn_avt_rnf = ', rn_avt_rnf
301	WRITE(numout,*) ' depth of river mouth additional mixing rn_hrnf = ', rn_hrnf
302	WRITE(numout,*) ' multiplicative factor for runoff rn_rfact = ', rn_rfact
303	IF(lflush) CALL flush(numout)
304	ENDIF
305	! ! ==================
306	! ! Type of runoff
307	! ! ==================
308	!
309	IF( .NOT. l_rnfcpl ) THEN
310	ALLOCATE( sf_rnf(1), STAT=ierror ) ! Create sf_rnf structure (runoff inflow)
311	IF(lwp) WRITE(numout,*)
312	IF(lwp) WRITE(numout,*) ' runoffs inflow read in a file'
313	IF(lwp .AND. lflush) CALL flush(numout)
314	IF( ierror > 0 ) THEN
315	CALL ctl_stop( 'sbc_rnf: unable to allocate sf_rnf structure' ) ; RETURN
316	ENDIF
317	ALLOCATE( sf_rnf(1)%fnow(jpi,jpj,1) )
318	IF( sn_rnf%ln_tint ) ALLOCATE( sf_rnf(1)%fdta(jpi,jpj,1,2) )
319	CALL fld_fill( sf_rnf, (/ sn_rnf /), cn_dir, 'sbc_rnf_init', 'read runoffs data', 'namsbc_rnf' )
320	ENDIF
321	!
322	IF( ln_rnf_tem ) THEN ! Create (if required) sf_t_rnf structure
323	IF(lwp) WRITE(numout,*)
324	IF(lwp) WRITE(numout,*) ' runoffs temperatures read in a file'
325	IF(lwp .AND. lflush) CALL flush(numout)
326	ALLOCATE( sf_t_rnf(1), STAT=ierror )
327	IF( ierror > 0 ) THEN
328	CALL ctl_stop( 'sbc_rnf_init: unable to allocate sf_t_rnf structure' ) ; RETURN
329	ENDIF
330	ALLOCATE( sf_t_rnf(1)%fnow(jpi,jpj,1) )
331	IF( sn_t_rnf%ln_tint ) ALLOCATE( sf_t_rnf(1)%fdta(jpi,jpj,1,2) )
332	CALL fld_fill (sf_t_rnf, (/ sn_t_rnf /), cn_dir, 'sbc_rnf_init', 'read runoff temperature data', 'namsbc_rnf' )
333	ENDIF
334	!
335	IF( ln_rnf_sal ) THEN ! Create (if required) sf_s_rnf and sf_t_rnf structures
336	IF(lwp) WRITE(numout,*)
337	IF(lwp) WRITE(numout,*) ' runoffs salinities read in a file'
338	IF(lwp .AND. lflush) CALL flush(numout)
339	ALLOCATE( sf_s_rnf(1), STAT=ierror )
340	IF( ierror > 0 ) THEN
341	CALL ctl_stop( 'sbc_rnf_init: unable to allocate sf_s_rnf structure' ) ; RETURN
342	ENDIF
343	ALLOCATE( sf_s_rnf(1)%fnow(jpi,jpj,1) )
344	IF( sn_s_rnf%ln_tint ) ALLOCATE( sf_s_rnf(1)%fdta(jpi,jpj,1,2) )
345	CALL fld_fill (sf_s_rnf, (/ sn_s_rnf /), cn_dir, 'sbc_rnf_init', 'read runoff salinity data', 'namsbc_rnf' )
346	ENDIF
347	!
348	IF( ln_rnf_depth ) THEN ! depth of runoffs set from a file
349	IF(lwp) WRITE(numout,*)
350	IF(lwp) WRITE(numout,*) ' runoffs depth read in a file'
351	IF(lwp .AND. lflush) CALL flush(numout)
352	rn_dep_file = TRIM( cn_dir )//TRIM( sn_dep_rnf%clname )
353	IF( .NOT. sn_dep_rnf%ln_clim ) THEN ; WRITE(rn_dep_file, '(a,"_y",i4)' ) TRIM( rn_dep_file ), nyear ! add year
354	IF( sn_dep_rnf%cltype == 'monthly' ) WRITE(rn_dep_file, '(a,"m",i2)' ) TRIM( rn_dep_file ), nmonth ! add month
355	ENDIF
356	CALL iom_open ( rn_dep_file, inum ) ! open file
357	CALL iom_get ( inum, jpdom_data, sn_dep_rnf%clvar, h_rnf ) ! read the river mouth array
358	CALL iom_close( inum ) ! close file
359	!
360	nk_rnf(:,:) = 0 ! set the number of level over which river runoffs are applied
361	DO jj = 1, jpj
362	DO ji = 1, jpi
363	IF( h_rnf(ji,jj) > 0._wp ) THEN
364	jk = 2
365	DO WHILE ( jk /= mbkt(ji,jj) .AND. gdept_0(ji,jj,jk) < h_rnf(ji,jj) ) ; jk = jk + 1
366	END DO
367	nk_rnf(ji,jj) = jk
368	ELSEIF( h_rnf(ji,jj) == -1._wp ) THEN ; nk_rnf(ji,jj) = 1
369	ELSEIF( h_rnf(ji,jj) == -999._wp ) THEN ; nk_rnf(ji,jj) = mbkt(ji,jj)
370	ELSE
371	CALL ctl_stop( 'sbc_rnf_init: runoff depth not positive, and not -999 or -1, rnf value in file fort.999' )
372	WRITE(999,*) 'ji, jj, h_rnf(ji,jj) :', ji, jj, h_rnf(ji,jj)
373	ENDIF
374	END DO
375	END DO
376	DO jj = 1, jpj ! set the associated depth
377	DO ji = 1, jpi
378	h_rnf(ji,jj) = 0._wp
379	DO jk = 1, nk_rnf(ji,jj)
380	h_rnf(ji,jj) = h_rnf(ji,jj) + fse3t(ji,jj,jk)
381	END DO
382	END DO
383	END DO
384	!
385	ELSE IF( ln_rnf_depth_ini ) THEN ! runoffs applied at the surface
386	!
387	IF(lwp) WRITE(numout,*)
388	IF(lwp) WRITE(numout,*) ' depth of runoff computed once from max value of runoff'
389	IF(lwp) WRITE(numout,*) ' max value of the runoff climatologie (over global domain) rn_rnf_max = ', rn_rnf_max
390	IF(lwp) WRITE(numout,*) ' depth over which runoffs is spread rn_dep_max = ', rn_dep_max
391	IF(lwp) WRITE(numout,*) ' create (=1) a runoff depth file or not (=0) nn_rnf_depth_file = ', nn_rnf_depth_file
392	IF(lwp .AND. lflush) CALL flush(numout)
393
394	CALL iom_open( TRIM( sn_rnf%clname ), inum ) ! open runoff file
395	CALL iom_gettime( inum, zrec, kntime=nbrec)
396	ALLOCATE( zrnfcl(jpi,jpj,nbrec) ) ; ALLOCATE( zrnf(jpi,jpj) )
397	DO jm = 1, nbrec
398	CALL iom_get( inum, jpdom_data, TRIM( sn_rnf%clvar ), zrnfcl(:,:,jm), jm )
399	END DO
400	CALL iom_close( inum )
401	zrnf(:,:) = MAXVAL( zrnfcl(:,:,:), DIM=3 ) ! maximum value in time
402	DEALLOCATE( zrnfcl )
403	!
404	h_rnf(:,:) = 1.
405	!
406	zacoef = rn_dep_max / rn_rnf_max ! coef of linear relation between runoff and its depth (150m for max of runoff)
407	!
408	WHERE( zrnf(:,:) > 0._wp ) h_rnf(:,:) = zacoef * zrnf(:,:) ! compute depth for all runoffs
409	!
410	DO jj = 1, jpj ! take in account min depth of ocean rn_hmin
411	DO ji = 1, jpi
412	IF( zrnf(ji,jj) > 0._wp ) THEN
413	jk = mbkt(ji,jj)
414	h_rnf(ji,jj) = MIN( h_rnf(ji,jj), gdept_0(ji,jj,jk ) )
415	ENDIF
416	END DO
417	END DO
418	!
419	nk_rnf(:,:) = 0 ! number of levels on which runoffs are distributed
420	DO jj = 1, jpj
421	DO ji = 1, jpi
422	IF( zrnf(ji,jj) > 0._wp ) THEN
423	jk = 2
424	DO WHILE ( jk /= mbkt(ji,jj) .AND. gdept_0(ji,jj,jk) < h_rnf(ji,jj) ) ; jk = jk + 1
425	END DO
426	nk_rnf(ji,jj) = jk
427	ELSE
428	nk_rnf(ji,jj) = 1
429	ENDIF
430	END DO
431	END DO
432	!
433	DEALLOCATE( zrnf )
434	!
435	DO jj = 1, jpj ! set the associated depth
436	DO ji = 1, jpi
437	h_rnf(ji,jj) = 0._wp
438	DO jk = 1, nk_rnf(ji,jj)
439	h_rnf(ji,jj) = h_rnf(ji,jj) + fse3t(ji,jj,jk)
440	END DO
441	END DO
442	END DO
443	!
444	IF( nn_rnf_depth_file == 1 ) THEN ! save output nb levels for runoff
445	IF(lwp) WRITE(numout,*) ' create runoff depht file'
446	IF(lwp .AND. lflush) CALL flush(numout)
447	CALL iom_open ( TRIM( sn_dep_rnf%clname ), inum, ldwrt = .TRUE., kiolib = jprstlib )
448	CALL iom_rstput( 0, 0, inum, 'rodepth', h_rnf )
449	CALL iom_close ( inum )
450	ENDIF
451	ELSE ! runoffs applied at the surface
452	nk_rnf(:,:) = 1
453	h_rnf (:,:) = fse3t(:,:,1)
454	ENDIF
455	!
456	rnf(:,:) = 0._wp ! runoff initialisation
457	rnf_tsc(:,:,:) = 0._wp ! runoffs temperature & salinty contents initilisation
458	!
459	! ! ========================
460	! ! River mouth vicinity
461	! ! ========================
462	!
463	IF( ln_rnf_mouth ) THEN ! Specific treatment in vicinity of river mouths :
464	! ! - Increase Kz in surface layers ( rn_hrnf > 0 )
465	! ! - set to zero SSS damping (ln_ssr=T)
466	! ! - mixed upstream-centered (ln_traadv_cen2=T)
467	!
468	ALLOCATE ( rn_avt_rnf0(jpi,jpj) )
469	rn_avt_rnf0(:,:) = rn_avt_rnf
470	!
471	IF ( ln_rnf_depth ) CALL ctl_warn( 'sbc_rnf_init: increased mixing turned on but effects may already', &
472	& 'be spread through depth by ln_rnf_depth' )
473	!
474	nkrnf = 0 ! Number of level over which Kz increase
475	IF( rn_hrnf > 0._wp ) THEN
476	nkrnf = 2
477	DO WHILE( nkrnf /= jpkm1 .AND. gdepw_1d(nkrnf+1) < rn_hrnf ) ; nkrnf = nkrnf + 1
478	END DO
479	IF( ln_sco ) CALL ctl_warn( 'sbc_rnf: number of levels over which Kz is increased is computed for zco...' )
480	ENDIF
481	IF(lwp) WRITE(numout,*)
482	IF(lwp) WRITE(numout,*) ' Specific treatment used in vicinity of river mouths :'
483	IF(lwp) WRITE(numout,*) ' - Increase Kz in surface layers (if rn_hrnf > 0 )'
484	IF(lwp) WRITE(numout,*) ' by ', rn_avt_rnf,' m2/s over ', nkrnf, ' w-levels'
485	IF(lwp) WRITE(numout,*) ' - set to zero SSS damping (if ln_ssr=T)'
486	IF(lwp) WRITE(numout,*) ' - mixed upstream-centered (if ln_traadv_cen2=T)'
487	IF(lwp .AND. lflush) CALL flush(numout)
488	!
489	CALL rnf_mouth ! set river mouth mask
490	!
491	ELSE ! No treatment at river mouths
492	IF(lwp) WRITE(numout,*)
493	IF(lwp) WRITE(numout,*) ' No specific treatment at river mouths'
494	IF(lwp .AND. lflush) CALL flush(numout)
495	rnfmsk (:,:) = 0._wp
496	rnfmsk_z(:) = 0._wp
497	nkrnf = 0
498	ENDIF
499	!
500	END SUBROUTINE sbc_rnf_init
501
502
503	SUBROUTINE rnf_mouth
504	!!----------------------------------------------------------------------
505	!! * ROUTINE rnf_mouth *
506	!!
507	!! ** Purpose : define the river mouths mask
508	!!
509	!! ** Method : read the river mouth mask (=0/1) in the river runoff
510	!! climatological file. Defined a given vertical structure.
511	!! CAUTION, the vertical structure is hard coded on the
512	!! first 5 levels.
513	!! This fields can be used to:
514	!! - set an upstream advection scheme
515	!! (ln_rnf_mouth=T and ln_traadv_cen2=T)
516	!! - increase vertical on the top nn_krnf vertical levels
517	!! at river runoff input grid point (nn_krnf>=2, see step.F90)
518	!! - set to zero SSS restoring flux at river mouth grid points
519	!!
520	!! ** Action : rnfmsk set to 1 at river runoff input, 0 elsewhere
521	!! rnfmsk_z vertical structure
522	!!----------------------------------------------------------------------
523	INTEGER :: inum ! temporary integers
524	CHARACTER(len=140) :: cl_rnfile ! runoff file name
525	!!----------------------------------------------------------------------
526	!
527	IF(lwp) WRITE(numout,*)
528	IF(lwp) WRITE(numout,*) 'rnf_mouth : river mouth mask'
529	IF(lwp) WRITE(numout,*) '~~~~~~~~~ '
530	IF(lwp .AND. lflush) CALL flush(numout)
531	!
532	cl_rnfile = TRIM( cn_dir )//TRIM( sn_cnf%clname )
533	IF( .NOT. sn_cnf%ln_clim ) THEN ; WRITE(cl_rnfile, '(a,"_y",i4)' ) TRIM( cl_rnfile ), nyear ! add year
534	IF( sn_cnf%cltype == 'monthly' ) WRITE(cl_rnfile, '(a,"m",i2)' ) TRIM( cl_rnfile ), nmonth ! add month
535	ENDIF
536	!
537	! horizontal mask (read in NetCDF file)
538	CALL iom_open ( cl_rnfile, inum ) ! open file
539	CALL iom_get ( inum, jpdom_data, sn_cnf%clvar, rnfmsk ) ! read the river mouth array
540	CALL iom_close( inum ) ! close file
541	!
542	IF( nn_closea == 1 ) CALL clo_rnf( rnfmsk ) ! closed sea inflow set as ruver mouth
543	!
544	rnfmsk_z(:) = 0._wp ! vertical structure
545	rnfmsk_z(1) = 1.0
546	rnfmsk_z(2) = 1.0 ! **********
547	rnfmsk_z(3) = 0.5 ! HARD CODED on the 5 first levels
548	rnfmsk_z(4) = 0.25 ! **********
549	rnfmsk_z(5) = 0.125
550	!
551	END SUBROUTINE rnf_mouth
552
553	!!======================================================================
554	END MODULE sbcrnf

Note: See TracBrowser for help on using the repository browser.

New URL for NEMO forge! http://forge.nemo-ocean.eu

Context Navigation

source: branches/UKMO/dev_r5518_GO6_starthour_obsoper/NEMOGCM/NEMO/OPA_SRC/SBC/sbcrnf.F90 @ 15603

Download in other formats: