1 | MODULE limsbc_2 |
---|
2 | !!====================================================================== |
---|
3 | !! *** MODULE limsbc_2 *** |
---|
4 | !! LIM-2 : updates the fluxes at the ocean surface with ice-ocean fluxes |
---|
5 | !!====================================================================== |
---|
6 | !! History : LIM ! 2000-01 (H. Goosse) Original code |
---|
7 | !! 1.0 ! 2002-07 (C. Ethe, G. Madec) re-writing F90 |
---|
8 | !! 3.0 ! 2006-07 (G. Madec) surface module |
---|
9 | !! 3.3 ! 2009-05 (G. Garric, C. Bricaud) addition of the lim2_evp case |
---|
10 | !! - ! 2010-11 (G. Madec) ice-ocean stress computed at each ocean time-step |
---|
11 | !! 3.3.1 ! 2011-01 (A. R. Porter, STFC Daresbury) dynamical allocation |
---|
12 | !! 3.5 ! 2012-11 ((G. Madec, Y. Aksenov, A. Coward) salt and heat fluxes associated with e-p |
---|
13 | !!---------------------------------------------------------------------- |
---|
14 | #if defined key_lim2 |
---|
15 | !!---------------------------------------------------------------------- |
---|
16 | !! 'key_lim2' LIM 2.0 sea-ice model |
---|
17 | !!---------------------------------------------------------------------- |
---|
18 | !! lim_sbc_alloc_2 : allocate the limsbc arrays |
---|
19 | !! lim_sbc_init : initialisation |
---|
20 | !! lim_sbc_flx_2 : update mass, heat and salt fluxes at the ocean surface |
---|
21 | !! lim_sbc_tau_2 : update i- and j-stresses, and its modulus at the ocean surface |
---|
22 | !!---------------------------------------------------------------------- |
---|
23 | USE par_oce ! ocean parameters |
---|
24 | USE phycst ! physical constants |
---|
25 | USE dom_oce ! ocean domain |
---|
26 | USE domvvl ! ocean vertical scale factors |
---|
27 | USE dom_ice_2 ! LIM-2: ice domain |
---|
28 | USE ice_2 ! LIM-2: ice variables |
---|
29 | USE sbc_ice ! surface boundary condition: ice |
---|
30 | USE sbc_oce ! surface boundary condition: ocean |
---|
31 | USE sbccpl |
---|
32 | USE oce , ONLY : sshn, sshb, snwice_mass, snwice_mass_b, snwice_fmass |
---|
33 | USE albedo ! albedo parameters |
---|
34 | USE lbclnk ! ocean lateral boundary condition - MPP exchanges |
---|
35 | USE lib_mpp ! MPP library |
---|
36 | USE wrk_nemo ! work arrays |
---|
37 | USE in_out_manager ! I/O manager |
---|
38 | USE iom ! I/O library |
---|
39 | USE prtctl ! Print control |
---|
40 | USE lib_fortran ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) |
---|
41 | |
---|
42 | IMPLICIT NONE |
---|
43 | PRIVATE |
---|
44 | |
---|
45 | PUBLIC lim_sbc_init_2 ! called by ice_init_2 |
---|
46 | PUBLIC lim_sbc_flx_2 ! called by sbc_ice_lim_2 |
---|
47 | PUBLIC lim_sbc_tau_2 ! called by sbc_ice_lim_2 |
---|
48 | PUBLIC lim_bio_meanqsr_2 ! called by sbc_ice_lim_2 |
---|
49 | |
---|
50 | REAL(wp) :: r1_rdtice ! = 1. / rdt_ice |
---|
51 | REAL(wp) :: epsi16 = 1.e-16_wp ! constant values |
---|
52 | REAL(wp) :: rzero = 0._wp ! - - |
---|
53 | REAL(wp) :: rone = 1._wp ! - - |
---|
54 | ! |
---|
55 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: soce_0, sice_0 ! constant SSS and ice salinity used in levitating sea-ice case |
---|
56 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: utau_oce, vtau_oce ! air-ocean surface i- & j-stress [N/m2] |
---|
57 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: tmod_io ! modulus of the ice-ocean relative velocity [m/s] |
---|
58 | |
---|
59 | !! * Substitutions |
---|
60 | # include "vectopt_loop_substitute.h90" |
---|
61 | # include "domzgr_substitute.h90" |
---|
62 | !!---------------------------------------------------------------------- |
---|
63 | !! NEMO/LIM2 4.0 , UCL - NEMO Consortium (2011) |
---|
64 | !! $Id$ |
---|
65 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
---|
66 | !!---------------------------------------------------------------------- |
---|
67 | CONTAINS |
---|
68 | |
---|
69 | INTEGER FUNCTION lim_sbc_alloc_2() |
---|
70 | !!------------------------------------------------------------------- |
---|
71 | !! *** ROUTINE lim_sbc_alloc_2 *** |
---|
72 | !!------------------------------------------------------------------- |
---|
73 | ALLOCATE( soce_0(jpi,jpj) , utau_oce(jpi,jpj) , & |
---|
74 | & sice_0(jpi,jpj) , vtau_oce(jpi,jpj) , tmod_io(jpi,jpj), STAT=lim_sbc_alloc_2) |
---|
75 | ! |
---|
76 | IF( lk_mpp ) CALL mpp_sum( lim_sbc_alloc_2 ) |
---|
77 | IF( lim_sbc_alloc_2 /= 0 ) CALL ctl_warn('lim_sbc_alloc_2: failed to allocate arrays.') |
---|
78 | ! |
---|
79 | END FUNCTION lim_sbc_alloc_2 |
---|
80 | |
---|
81 | |
---|
82 | SUBROUTINE lim_sbc_flx_2( kt ) |
---|
83 | !!------------------------------------------------------------------- |
---|
84 | !! *** ROUTINE lim_sbc_2 *** |
---|
85 | !! |
---|
86 | !! ** Purpose : Update surface ocean boundary condition over areas |
---|
87 | !! that are at least partially covered by sea-ice |
---|
88 | !! |
---|
89 | !! ** Action : - comput. of the momentum, heat and freshwater/salt |
---|
90 | !! fluxes at the ice-ocean interface. |
---|
91 | !! - Update the fluxes provided to the ocean |
---|
92 | !! |
---|
93 | !! ** Outputs : - qsr : sea heat flux : solar |
---|
94 | !! - qns : sea heat flux : non solar (including heat content of the mass flux) |
---|
95 | !! - emp : freshwater budget: mass flux |
---|
96 | !! - sfx : freshwater budget: salt flux due to Freezing/Melting |
---|
97 | !! - fr_i : ice fraction |
---|
98 | !! - tn_ice : sea-ice surface temperature |
---|
99 | !! - alb_ice : sea-ice albedo (lk_cpl=T) |
---|
100 | !! |
---|
101 | !! References : Goosse, H. et al. 1996, Bul. Soc. Roy. Sc. Liege, 65, 87-90. |
---|
102 | !! Tartinville et al. 2001 Ocean Modelling, 3, 95-108. |
---|
103 | !!--------------------------------------------------------------------- |
---|
104 | INTEGER, INTENT(in) :: kt ! number of iteration |
---|
105 | !! |
---|
106 | INTEGER :: ji, jj ! dummy loop indices |
---|
107 | INTEGER :: ii0, ii1, ij0, ij1 ! local integers |
---|
108 | INTEGER :: ifvt, i1mfr, idfr, iflt ! - - |
---|
109 | INTEGER :: ial, iadv, ifral, ifrdv ! - - |
---|
110 | REAL(wp) :: zqsr, zqns, zfmm ! local scalars |
---|
111 | REAL(wp) :: zinda, zfsalt, zemp ! - - |
---|
112 | REAL(wp) :: zemp_snw, zqhc, zcd ! - - |
---|
113 | REAL(wp) :: zswitch ! - - |
---|
114 | REAL(wp), POINTER, DIMENSION(:,:) :: zqnsoce ! 2D workspace |
---|
115 | REAL(wp), POINTER, DIMENSION(:,:,:) :: zalb, zalbp ! 2D/3D workspace |
---|
116 | !!--------------------------------------------------------------------- |
---|
117 | |
---|
118 | CALL wrk_alloc( jpi, jpj, zqnsoce ) |
---|
119 | CALL wrk_alloc( jpi, jpj, 1, zalb, zalbp ) |
---|
120 | |
---|
121 | SELECT CASE( nn_ice_embd ) ! levitating or embedded sea-ice option |
---|
122 | CASE( 0 ) ; zswitch = 1 ! (0) standard levitating sea-ice : salt exchange only |
---|
123 | CASE( 1, 2 ) ; zswitch = 0 ! (1) levitating sea-ice: salt and volume exchange but no pressure effect |
---|
124 | ! (2) embedded sea-ice : salt and volume fluxes and pressure |
---|
125 | END SELECT ! |
---|
126 | |
---|
127 | !------------------------------------------! |
---|
128 | ! heat flux at the ocean surface ! |
---|
129 | !------------------------------------------! |
---|
130 | |
---|
131 | zqnsoce(:,:) = qns(:,:) |
---|
132 | DO jj = 1, jpj |
---|
133 | DO ji = 1, jpi |
---|
134 | zinda = 1.0 - MAX( rzero , SIGN( rone, - ( 1.0 - pfrld(ji,jj) ) ) ) |
---|
135 | ifvt = zinda * MAX( rzero , SIGN( rone, - phicif(ji,jj) ) ) |
---|
136 | i1mfr = 1.0 - MAX( rzero , SIGN( rone, - ( 1.0 - frld(ji,jj) ) ) ) |
---|
137 | idfr = 1.0 - MAX( rzero , SIGN( rone, frld(ji,jj) - pfrld(ji,jj) ) ) |
---|
138 | iflt = zinda * (1 - i1mfr) * (1 - ifvt ) |
---|
139 | ial = ifvt * i1mfr + ( 1 - ifvt ) * idfr |
---|
140 | iadv = ( 1 - i1mfr ) * zinda |
---|
141 | ifral = ( 1 - i1mfr * ( 1 - ial ) ) |
---|
142 | ifrdv = ( 1 - ifral * ( 1 - ial ) ) * iadv |
---|
143 | |
---|
144 | !!$ attempt to explain the tricky flags set above.... |
---|
145 | !!$ zinda = 1.0 - AINT( pfrld(ji,jj) ) ! = 0. if ice-free ocean else 1. (after ice adv, but before ice thermo) |
---|
146 | !!$ i1mfr = 1.0 - AINT( frld(ji,jj) ) ! = 0. if ice-free ocean else 1. (after ice thermo) |
---|
147 | !!$ |
---|
148 | !!$ IF( phicif(ji,jj) <= 0. ) THEN ; ifvt = zinda ! = zinda if previous thermodynamic step overmelted the ice??? |
---|
149 | !!$ ELSE ; ifvt = 0. ! |
---|
150 | !!$ ENDIF |
---|
151 | !!$ |
---|
152 | !!$ IF( frld(ji,jj) >= pfrld(ji,jj) ) THEN ; idfr = 0. ! = 0. if lead fraction increases due to ice thermodynamics |
---|
153 | !!$ ELSE ; idfr = 1. |
---|
154 | !!$ ENDIF |
---|
155 | !!$ |
---|
156 | !!$ iflt = zinda * (1 - i1mfr) * (1 - ifvt ) ! = 1. if ice (not only snow) at previous time and ice-free ocean currently |
---|
157 | !!$ |
---|
158 | !!$ ial = ifvt * i1mfr + ( 1 - ifvt ) * idfr |
---|
159 | !!$ = i1mfr if ifvt = 1 i.e. |
---|
160 | !!$ = idfr if ifvt = 0 |
---|
161 | !!$! snow no ice ice ice or nothing lead fraction increases |
---|
162 | !!$! at previous now at previous |
---|
163 | !!$! -> ice area increases ??? -> ice area decreases ??? |
---|
164 | !!$ |
---|
165 | !!$ iadv = ( 1 - i1mfr ) * zinda |
---|
166 | !!$! pure ocean ice at |
---|
167 | !!$! at current previous |
---|
168 | !!$! -> = 1. if ice disapear between previous and current |
---|
169 | !!$ |
---|
170 | !!$ ifral = ( 1 - i1mfr * ( 1 - ial ) ) |
---|
171 | !!$! ice at ??? |
---|
172 | !!$! current |
---|
173 | !!$! -> ??? |
---|
174 | !!$ |
---|
175 | !!$ ifrdv = ( 1 - ifral * ( 1 - ial ) ) * iadv |
---|
176 | !!$! ice disapear |
---|
177 | !!$ |
---|
178 | !!$ |
---|
179 | |
---|
180 | ! computation the solar flux at ocean surface |
---|
181 | IF( lk_cpl ) THEN |
---|
182 | zqsr = qsr_tot(ji,jj) + ( fstric(ji,jj) - qsr_ice(ji,jj,1) ) * ( 1.0 - pfrld(ji,jj) ) |
---|
183 | ELSE |
---|
184 | zqsr = pfrld(ji,jj) * qsr(ji,jj) + ( 1. - pfrld(ji,jj) ) * fstric(ji,jj) |
---|
185 | ENDIF |
---|
186 | ! computation the non solar heat flux at ocean surface |
---|
187 | zqns = - ( 1. - thcm(ji,jj) ) * zqsr & ! part of the solar energy used in leads |
---|
188 | & + iflt * ( fscmbq(ji,jj) + ffltbif(ji,jj) ) & |
---|
189 | & + ifral * ( ial * qcmif(ji,jj) + (1 - ial) * qldif(ji,jj) ) * r1_rdtice & |
---|
190 | & + ifrdv * ( qfvbq(ji,jj) + qdtcn(ji,jj) ) * r1_rdtice |
---|
191 | |
---|
192 | fsbbq(ji,jj) = ( 1.0 - ( ifvt + iflt ) ) * fscmbq(ji,jj) ! store residual heat flux (to put into the ocean at the next time-step) |
---|
193 | zqhc = ( rdq_snw(ji,jj) & |
---|
194 | & + rdq_ice(ji,jj) * ( 1.- zswitch) ) * r1_rdtice ! heat flux due to snow ( & ice heat content, |
---|
195 | ! ! if ice/ocean mass exchange active) |
---|
196 | qsr (ji,jj) = zqsr ! solar heat flux |
---|
197 | qns (ji,jj) = zqns - fdtcn(ji,jj) + zqhc ! non solar heat flux |
---|
198 | ! |
---|
199 | ! !------------------------------------------! |
---|
200 | ! ! mass and salt flux at the ocean surface ! |
---|
201 | ! !------------------------------------------! |
---|
202 | ! |
---|
203 | ! mass flux at the ocean-atmosphere interface (open ocean fraction = leads area) |
---|
204 | ! ! coupled mode: |
---|
205 | IF( lk_cpl ) THEN |
---|
206 | zemp = + emp_tot(ji,jj) & ! net mass flux over the grid cell (ice+ocean area) |
---|
207 | & - emp_ice(ji,jj) * ( 1. - pfrld(ji,jj) ) ! minus the mass flux intercepted by sea-ice |
---|
208 | ELSE |
---|
209 | ! ! forced mode: |
---|
210 | zemp = + emp(ji,jj) * frld(ji,jj) & ! mass flux over open ocean fraction |
---|
211 | & - tprecip(ji,jj) * ( 1. - frld(ji,jj) ) & ! liquid precip. over ice reaches directly the ocean |
---|
212 | & + sprecip(ji,jj) * ( 1. - pfrld(ji,jj) ) ! snow is intercepted by sea-ice (previous frld) |
---|
213 | ENDIF |
---|
214 | ! |
---|
215 | ! mass flux at the ocean/ice interface (sea ice fraction) |
---|
216 | zemp_snw = rdm_snw(ji,jj) * r1_rdtice ! snow melting = pure water that enters the ocean |
---|
217 | zfmm = rdm_ice(ji,jj) * r1_rdtice ! Freezing minus Melting (F-M) |
---|
218 | |
---|
219 | fmmflx(ji,jj) = zfmm ! F/M mass flux save at least for biogeochemical model |
---|
220 | |
---|
221 | ! salt flux at the ice/ocean interface (sea ice fraction) [PSU*kg/m2/s] |
---|
222 | zfsalt = - sice_0(ji,jj) * zfmm ! F-M salt exchange |
---|
223 | zcd = soce_0(ji,jj) * zfmm ! concentration/dilution term due to F-M |
---|
224 | ! |
---|
225 | ! salt flux only : add concentration dilution term in salt flux and no F-M term in volume flux |
---|
226 | ! salt and mass fluxes : non concentration dilution term in salt flux and add F-M term in volume flux |
---|
227 | sfx (ji,jj) = zfsalt + zswitch * zcd ! salt flux (+ C/D if no ice/ocean mass exchange) |
---|
228 | emp (ji,jj) = zemp + zemp_snw + ( 1.- zswitch) * zfmm ! mass flux (+ F/M mass flux if ice/ocean mass exchange) |
---|
229 | ! |
---|
230 | END DO |
---|
231 | END DO |
---|
232 | ! !------------------------------------------! |
---|
233 | ! ! mass of snow and ice per unit area ! |
---|
234 | ! !------------------------------------------! |
---|
235 | IF( nn_ice_embd /= 0 ) THEN ! embedded sea-ice (mass required) |
---|
236 | snwice_mass_b(:,:) = snwice_mass(:,:) ! save mass from the previous ice time step |
---|
237 | ! ! new mass per unit area |
---|
238 | snwice_mass (:,:) = tms(:,:) * ( rhosn * hsnif(:,:) + rhoic * hicif(:,:) ) * ( 1.0 - frld(:,:) ) |
---|
239 | ! ! time evolution of snow+ice mass |
---|
240 | snwice_fmass (:,:) = ( snwice_mass(:,:) - snwice_mass_b(:,:) ) / rdt_ice |
---|
241 | ENDIF |
---|
242 | |
---|
243 | IF( iom_use('hflx_ice_cea' ) ) CALL iom_put( 'hflx_ice_cea', - fdtcn(:,:) ) |
---|
244 | IF( iom_use('qns_io_cea' ) ) CALL iom_put( 'qns_io_cea', qns(:,:) - zqnsoce(:,:) * pfrld(:,:) ) |
---|
245 | IF( iom_use('qsr_io_cea' ) ) CALL iom_put( 'qsr_io_cea', fstric(:,:) * (1.e0 - pfrld(:,:)) ) |
---|
246 | |
---|
247 | IF( iom_use('isnwmlt_cea' ) ) CALL iom_put( 'isnwmlt_cea' , rdm_snw(:,:) * r1_rdtice ) |
---|
248 | IF( iom_use('fsal_virt_cea') ) CALL iom_put( 'fsal_virt_cea', soce_0(:,:) * rdm_ice(:,:) * r1_rdtice ) |
---|
249 | IF( iom_use('fsal_real_cea') ) CALL iom_put( 'fsal_real_cea', - sice_0(:,:) * rdm_ice(:,:) * r1_rdtice ) |
---|
250 | |
---|
251 | !-----------------------------------------------! |
---|
252 | ! Coupling variables ! |
---|
253 | !-----------------------------------------------! |
---|
254 | |
---|
255 | IF( lk_cpl) THEN |
---|
256 | tn_ice(:,:,1) = sist(:,:) ! sea-ice surface temperature |
---|
257 | ht_i(:,:,1) = hicif(:,:) |
---|
258 | ht_s(:,:,1) = hsnif(:,:) |
---|
259 | a_i(:,:,1) = fr_i(:,:) |
---|
260 | ! ! Computation of snow/ice and ocean albedo |
---|
261 | CALL albedo_ice( tn_ice, ht_i, ht_s, zalbp, zalb ) |
---|
262 | alb_ice(:,:,1) = 0.5 * ( zalbp(:,:,1) + zalb (:,:,1) ) ! Ice albedo (mean clear and overcast skys) |
---|
263 | IF( iom_use('icealb_cea' ) ) CALL iom_put( 'icealb_cea', alb_ice(:,:,1) * fr_i(:,:) ) ! ice albedo |
---|
264 | ENDIF |
---|
265 | |
---|
266 | IF(ln_ctl) THEN ! control print |
---|
267 | CALL prt_ctl(tab2d_1=qsr , clinfo1=' lim_sbc: qsr : ', tab2d_2=qns , clinfo2=' qns : ') |
---|
268 | CALL prt_ctl(tab2d_1=emp , clinfo1=' lim_sbc: emp : ', tab2d_2=sfx , clinfo2=' sfx : ') |
---|
269 | CALL prt_ctl(tab2d_1=fr_i , clinfo1=' lim_sbc: fr_i : ', tab2d_2=tn_ice(:,:,1), clinfo2=' tn_ice : ') |
---|
270 | ENDIF |
---|
271 | ! |
---|
272 | CALL wrk_dealloc( jpi, jpj, zqnsoce ) |
---|
273 | CALL wrk_dealloc( jpi, jpj, 1, zalb, zalbp ) |
---|
274 | ! |
---|
275 | END SUBROUTINE lim_sbc_flx_2 |
---|
276 | |
---|
277 | |
---|
278 | SUBROUTINE lim_sbc_tau_2( kt , pu_oce, pv_oce ) |
---|
279 | !!------------------------------------------------------------------- |
---|
280 | !! *** ROUTINE lim_sbc_tau_2 *** |
---|
281 | !! |
---|
282 | !! ** Purpose : Update the ocean surface stresses due to the ice |
---|
283 | !! |
---|
284 | !! ** Action : * at each ice time step (every nn_fsbc time step): |
---|
285 | !! - compute the modulus of ice-ocean relative velocity |
---|
286 | !! at T-point (C-grid) or I-point (B-grid) |
---|
287 | !! tmod_io = rhoco * | U_ice-U_oce | |
---|
288 | !! - update the modulus of stress at ocean surface |
---|
289 | !! taum = frld * taum + (1-frld) * tmod_io * | U_ice-U_oce | |
---|
290 | !! * at each ocean time step (each kt): |
---|
291 | !! compute linearized ice-ocean stresses as |
---|
292 | !! Utau = tmod_io * | U_ice - pU_oce | |
---|
293 | !! using instantaneous current ocean velocity (usually before) |
---|
294 | !! |
---|
295 | !! NB: - the averaging operator used depends on the ice dynamics grid (cp_ice_msh='I' or 'C') |
---|
296 | !! - ice-ocean rotation angle only allowed in cp_ice_msh='I' case |
---|
297 | !! - here we make an approximation: taum is only computed every ice time step |
---|
298 | !! This avoids mutiple average to pass from T -> U,V grids and next from U,V grids |
---|
299 | !! to T grid. taum is used in TKE and GLS, which should not be too sensitive to this approximation... |
---|
300 | !! |
---|
301 | !! ** Outputs : - utau, vtau : surface ocean i- and j-stress (u- & v-pts) updated with ice-ocean fluxes |
---|
302 | !! - taum : modulus of the surface ocean stress (T-point) updated with ice-ocean fluxes |
---|
303 | !!--------------------------------------------------------------------- |
---|
304 | INTEGER , INTENT(in) :: kt ! ocean time-step index |
---|
305 | REAL(wp), DIMENSION(jpi,jpj), INTENT(in) :: pu_oce, pv_oce ! surface ocean currents |
---|
306 | !! |
---|
307 | INTEGER :: ji, jj ! dummy loop indices |
---|
308 | REAL(wp) :: zfrldu, zat_u, zu_i, zutau_ice, zu_t, zmodt ! local scalar |
---|
309 | REAL(wp) :: zfrldv, zat_v, zv_i, zvtau_ice, zv_t, zmodi ! - - |
---|
310 | REAL(wp) :: zsang, zumt ! - - |
---|
311 | REAL(wp), POINTER, DIMENSION(:,:) :: ztio_u, ztio_v ! ocean stress below sea-ice |
---|
312 | !!--------------------------------------------------------------------- |
---|
313 | ! |
---|
314 | CALL wrk_alloc( jpi, jpj, ztio_u, ztio_v ) |
---|
315 | ! |
---|
316 | SELECT CASE( cp_ice_msh ) |
---|
317 | ! !-----------------------! |
---|
318 | CASE( 'I' ) ! B-grid ice dynamics ! I-point (i.e. F-point with sea-ice indexation) |
---|
319 | ! !--=--------------------! |
---|
320 | ! |
---|
321 | IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN !== Ice time-step only ==! (i.e. surface module time-step) |
---|
322 | !CDIR NOVERRCHK |
---|
323 | DO jj = 1, jpj !* modulus of ice-ocean relative velocity at I-point |
---|
324 | !CDIR NOVERRCHK |
---|
325 | DO ji = 1, jpi |
---|
326 | zu_i = u_ice(ji,jj) - u_oce(ji,jj) ! ice-ocean relative velocity at I-point |
---|
327 | zv_i = v_ice(ji,jj) - v_oce(ji,jj) |
---|
328 | tmod_io(ji,jj) = SQRT( zu_i * zu_i + zv_i * zv_i ) ! modulus of this velocity (at I-point) |
---|
329 | END DO |
---|
330 | END DO |
---|
331 | !CDIR NOVERRCHK |
---|
332 | DO jj = 1, jpjm1 !* update the modulus of stress at ocean surface (T-point) |
---|
333 | !CDIR NOVERRCHK |
---|
334 | DO ji = 1, jpim1 ! NO vector opt. |
---|
335 | ! ! modulus of U_ice-U_oce at T-point |
---|
336 | zumt = 0.25_wp * ( tmod_io(ji+1,jj) + tmod_io(ji ,jj ) & |
---|
337 | & + tmod_io(ji,jj+1) + tmod_io(ji+1,jj+1) ) |
---|
338 | ! ! update the modulus of stress at ocean surface |
---|
339 | taum(ji,jj) = frld(ji,jj) * taum(ji,jj) + ( 1._wp - frld(ji,jj) ) * rhoco * zumt * zumt |
---|
340 | END DO |
---|
341 | END DO |
---|
342 | CALL lbc_lnk( taum, 'T', 1. ) |
---|
343 | ! |
---|
344 | utau_oce(:,:) = utau(:,:) !* save the air-ocean stresses at ice time-step |
---|
345 | vtau_oce(:,:) = vtau(:,:) |
---|
346 | ! |
---|
347 | ENDIF |
---|
348 | ! |
---|
349 | ! !== at each ocean time-step ==! |
---|
350 | ! |
---|
351 | ! !* ice/ocean stress WITH a ice-ocean rotation angle at I-point |
---|
352 | DO jj = 2, jpj |
---|
353 | zsang = SIGN( 1._wp, gphif(1,jj) ) * sangvg ! change the cosine angle sign in the SH |
---|
354 | DO ji = 2, jpi ! NO vect. opt. possible |
---|
355 | ! ... ice-ocean relative velocity at I-point using instantaneous surface ocean current at u- & v-pts |
---|
356 | zu_i = u_ice(ji,jj) - 0.5_wp * ( pu_oce(ji-1,jj ) + pu_oce(ji-1,jj-1) ) * tmu(ji,jj) |
---|
357 | zv_i = v_ice(ji,jj) - 0.5_wp * ( pv_oce(ji ,jj-1) + pv_oce(ji-1,jj-1) ) * tmu(ji,jj) |
---|
358 | ! ... components of stress with a ice-ocean rotation angle |
---|
359 | zmodi = rhoco * tmod_io(ji,jj) |
---|
360 | ztio_u(ji,jj) = zmodi * ( cangvg * zu_i - zsang * zv_i ) |
---|
361 | ztio_v(ji,jj) = zmodi * ( cangvg * zv_i + zsang * zu_i ) |
---|
362 | END DO |
---|
363 | END DO |
---|
364 | ! !* surface ocean stresses at u- and v-points |
---|
365 | DO jj = 2, jpjm1 |
---|
366 | DO ji = 2, jpim1 ! NO vector opt. |
---|
367 | ! ! ice-ocean stress at U and V-points (from I-point values) |
---|
368 | zutau_ice = 0.5_wp * ( ztio_u(ji+1,jj) + ztio_u(ji+1,jj+1) ) |
---|
369 | zvtau_ice = 0.5_wp * ( ztio_v(ji,jj+1) + ztio_v(ji+1,jj+1) ) |
---|
370 | ! ! open-ocean (lead) fraction at U- & V-points (from T-point values) |
---|
371 | zfrldu = 0.5_wp * ( frld(ji,jj) + frld(ji+1,jj) ) |
---|
372 | zfrldv = 0.5_wp * ( frld(ji,jj) + frld(ji,jj+1) ) |
---|
373 | ! ! update the surface ocean stress (ice-cover wheighted) |
---|
374 | utau(ji,jj) = zfrldu * utau_oce(ji,jj) + ( 1._wp - zfrldu ) * zutau_ice |
---|
375 | vtau(ji,jj) = zfrldv * vtau_oce(ji,jj) + ( 1._wp - zfrldv ) * zvtau_ice |
---|
376 | END DO |
---|
377 | END DO |
---|
378 | CALL lbc_lnk( utau, 'U', -1. ) ; CALL lbc_lnk( vtau, 'V', -1. ) ! lateral boundary condition |
---|
379 | ! |
---|
380 | ! |
---|
381 | ! !-----------------------! |
---|
382 | CASE( 'C' ) ! C-grid ice dynamics ! U & V-points (same as in the ocean) |
---|
383 | ! !--=--------------------! |
---|
384 | ! |
---|
385 | IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN !== Ice time-step only ==! (i.e. surface module time-step) |
---|
386 | !CDIR NOVERRCHK |
---|
387 | DO jj = 2, jpjm1 !* modulus of the ice-ocean velocity at T-point |
---|
388 | !CDIR NOVERRCHK |
---|
389 | DO ji = fs_2, fs_jpim1 |
---|
390 | zu_t = u_ice(ji,jj) + u_ice(ji-1,jj) - u_oce(ji,jj) - u_oce(ji-1,jj) ! 2*(U_ice-U_oce) at T-point |
---|
391 | zv_t = v_ice(ji,jj) + v_ice(ji,jj-1) - v_oce(ji,jj) - v_oce(ji,jj-1) |
---|
392 | zmodt = 0.25_wp * ( zu_t * zu_t + zv_t * zv_t ) ! |U_ice-U_oce|^2 |
---|
393 | ! ! update the modulus of stress at ocean surface |
---|
394 | taum (ji,jj) = frld(ji,jj) * taum(ji,jj) + ( 1._wp - frld(ji,jj) ) * rhoco * zmodt |
---|
395 | tmod_io(ji,jj) = SQRT( zmodt ) * rhoco ! rhoco*|Uice-Uoce| |
---|
396 | END DO |
---|
397 | END DO |
---|
398 | CALL lbc_lnk( taum, 'T', 1. ) ; CALL lbc_lnk( tmod_io, 'T', 1. ) |
---|
399 | ! |
---|
400 | utau_oce(:,:) = utau(:,:) !* save the air-ocean stresses at ice time-step |
---|
401 | vtau_oce(:,:) = vtau(:,:) |
---|
402 | ! |
---|
403 | ENDIF |
---|
404 | ! |
---|
405 | ! !== at each ocean time-step ==! |
---|
406 | ! |
---|
407 | DO jj = 2, jpjm1 !* ice stress over ocean WITHOUT a ice-ocean rotation angle |
---|
408 | DO ji = fs_2, fs_jpim1 |
---|
409 | ! ! ocean area at u- & v-points |
---|
410 | zfrldu = 0.5_wp * ( frld(ji,jj) + frld(ji+1,jj) ) |
---|
411 | zfrldv = 0.5_wp * ( frld(ji,jj) + frld(ji,jj+1) ) |
---|
412 | ! ! quadratic drag formulation without rotation |
---|
413 | ! ! using instantaneous surface ocean current |
---|
414 | zutau_ice = 0.5 * ( tmod_io(ji,jj) + tmod_io(ji+1,jj) ) * ( u_ice(ji,jj) - pu_oce(ji,jj) ) |
---|
415 | zvtau_ice = 0.5 * ( tmod_io(ji,jj) + tmod_io(ji,jj+1) ) * ( v_ice(ji,jj) - pv_oce(ji,jj) ) |
---|
416 | ! ! update the surface ocean stress (ice-cover wheighted) |
---|
417 | utau(ji,jj) = zfrldu * utau_oce(ji,jj) + ( 1._wp - zfrldu ) * zutau_ice |
---|
418 | vtau(ji,jj) = zfrldv * vtau_oce(ji,jj) + ( 1._wp - zfrldv ) * zvtau_ice |
---|
419 | END DO |
---|
420 | END DO |
---|
421 | CALL lbc_lnk( utau, 'U', -1. ) ; CALL lbc_lnk( vtau, 'V', -1. ) ! lateral boundary condition |
---|
422 | ! |
---|
423 | END SELECT |
---|
424 | |
---|
425 | IF(ln_ctl) CALL prt_ctl( tab2d_1=utau, clinfo1=' lim_sbc: utau : ', mask1=umask, & |
---|
426 | & tab2d_2=vtau, clinfo2=' vtau : ' , mask2=vmask ) |
---|
427 | ! |
---|
428 | CALL wrk_dealloc( jpi, jpj, ztio_u, ztio_v ) |
---|
429 | ! |
---|
430 | END SUBROUTINE lim_sbc_tau_2 |
---|
431 | |
---|
432 | SUBROUTINE lim_bio_meanqsr_2 |
---|
433 | !!--------------------------------------------------------------------- |
---|
434 | !! *** ROUTINE lim_bio_meanqsr |
---|
435 | !! |
---|
436 | !! ** Purpose : provide daily qsr_mean for PISCES when |
---|
437 | !! analytic diurnal cycle is applied in physic |
---|
438 | !! |
---|
439 | !! ** Method : add part under ice |
---|
440 | !! |
---|
441 | !!--------------------------------------------------------------------- |
---|
442 | |
---|
443 | qsr_mean(:,:) = pfrld(:,:) * qsr_mean(:,:) + ( 1. - pfrld(:,:) ) * fstric_daymean(:,:) |
---|
444 | |
---|
445 | END SUBROUTINE lim_bio_meanqsr_2 |
---|
446 | |
---|
447 | SUBROUTINE lim_sbc_init_2 |
---|
448 | !!------------------------------------------------------------------- |
---|
449 | !! *** ROUTINE lim_sbc_init *** |
---|
450 | !! |
---|
451 | !! ** Purpose : Preparation of the file ice_evolu for the output of |
---|
452 | !! the temporal evolution of key variables |
---|
453 | !! |
---|
454 | !! ** input : Namelist namicedia |
---|
455 | !!------------------------------------------------------------------- |
---|
456 | ! |
---|
457 | INTEGER :: jk ! local integer |
---|
458 | ! |
---|
459 | IF(lwp) WRITE(numout,*) |
---|
460 | IF(lwp) WRITE(numout,*) 'lim_sbc_init_2 : LIM-2 sea-ice - surface boundary condition' |
---|
461 | IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~~~~ ' |
---|
462 | |
---|
463 | ! ! allocate lim_sbc arrays |
---|
464 | IF( lim_sbc_alloc_2() /= 0 ) CALL ctl_stop( 'STOP', 'lim_sbc_flx_2 : unable to allocate arrays' ) |
---|
465 | ! |
---|
466 | r1_rdtice = 1._wp / rdt_ice |
---|
467 | ! |
---|
468 | soce_0(:,:) = soce ! constant SSS and ice salinity used in levitating sea-ice case |
---|
469 | sice_0(:,:) = sice |
---|
470 | ! |
---|
471 | IF( cp_cfg == "orca" ) THEN ! decrease ocean & ice reference salinities in the Baltic sea |
---|
472 | WHERE( 14._wp <= glamt(:,:) .AND. glamt(:,:) <= 32._wp .AND. & |
---|
473 | & 54._wp <= gphit(:,:) .AND. gphit(:,:) <= 66._wp ) |
---|
474 | soce_0(:,:) = 4._wp |
---|
475 | sice_0(:,:) = 2._wp |
---|
476 | END WHERE |
---|
477 | ENDIF |
---|
478 | ! ! embedded sea ice |
---|
479 | IF( nn_ice_embd /= 0 ) THEN ! mass exchanges between ice and ocean (case 1 or 2) set the snow+ice mass |
---|
480 | snwice_mass (:,:) = tms(:,:) * ( rhosn * hsnif(:,:) + rhoic * hicif(:,:) ) * ( 1.0 - frld(:,:) ) |
---|
481 | snwice_mass_b(:,:) = snwice_mass(:,:) |
---|
482 | ELSE |
---|
483 | snwice_mass (:,:) = 0.e0 ! no mass exchanges |
---|
484 | snwice_mass_b(:,:) = 0.e0 ! no mass exchanges |
---|
485 | snwice_fmass (:,:) = 0.e0 ! no mass exchanges |
---|
486 | ENDIF |
---|
487 | IF( nn_ice_embd == 2 .AND. & ! full embedment (case 2) & no restart : |
---|
488 | & .NOT.ln_rstart ) THEN ! deplete the initial ssh below sea-ice area |
---|
489 | sshn(:,:) = sshn(:,:) - snwice_mass(:,:) * r1_rau0 |
---|
490 | sshb(:,:) = sshb(:,:) - snwice_mass(:,:) * r1_rau0 |
---|
491 | do jk = 1,jpkm1 ! adjust initial vertical scale factors |
---|
492 | fse3t_n(:,:,jk) = e3t_0(:,:,jk)*( 1._wp + sshn(:,:)*tmask(:,:,1)/(ht_0(:,:) + 1.0 - tmask(:,:,1)) ) |
---|
493 | fse3t_b(:,:,jk) = e3t_0(:,:,jk)*( 1._wp + sshb(:,:)*tmask(:,:,1)/(ht_0(:,:) + 1.0 - tmask(:,:,1)) ) |
---|
494 | end do |
---|
495 | fse3t_a(:,:,:) = fse3t_b(:,:,:) |
---|
496 | ! Reconstruction of all vertical scale factors at now and before time steps |
---|
497 | ! ============================================================================= |
---|
498 | ! Horizontal scale factor interpolations |
---|
499 | ! -------------------------------------- |
---|
500 | CALL dom_vvl_interpol( fse3t_b(:,:,:), fse3u_b(:,:,:), 'U' ) |
---|
501 | CALL dom_vvl_interpol( fse3t_b(:,:,:), fse3v_b(:,:,:), 'V' ) |
---|
502 | CALL dom_vvl_interpol( fse3t_n(:,:,:), fse3u_n(:,:,:), 'U' ) |
---|
503 | CALL dom_vvl_interpol( fse3t_n(:,:,:), fse3v_n(:,:,:), 'V' ) |
---|
504 | CALL dom_vvl_interpol( fse3u_n(:,:,:), fse3f_n(:,:,:), 'F' ) |
---|
505 | ! Vertical scale factor interpolations |
---|
506 | ! ------------------------------------ |
---|
507 | CALL dom_vvl_interpol( fse3t_n(:,:,:), fse3w_n (:,:,:), 'W' ) |
---|
508 | CALL dom_vvl_interpol( fse3u_n(:,:,:), fse3uw_n(:,:,:), 'UW' ) |
---|
509 | CALL dom_vvl_interpol( fse3v_n(:,:,:), fse3vw_n(:,:,:), 'VW' ) |
---|
510 | CALL dom_vvl_interpol( fse3u_b(:,:,:), fse3uw_b(:,:,:), 'UW' ) |
---|
511 | CALL dom_vvl_interpol( fse3v_b(:,:,:), fse3vw_b(:,:,:), 'VW' ) |
---|
512 | ! t- and w- points depth |
---|
513 | ! ---------------------- |
---|
514 | fsdept_n(:,:,1) = 0.5_wp * fse3w_n(:,:,1) |
---|
515 | fsdepw_n(:,:,1) = 0.0_wp |
---|
516 | fsde3w_n(:,:,1) = fsdept_n(:,:,1) - sshn(:,:) |
---|
517 | DO jk = 2, jpk |
---|
518 | fsdept_n(:,:,jk) = fsdept_n(:,:,jk-1) + fse3w_n(:,:,jk) |
---|
519 | fsdepw_n(:,:,jk) = fsdepw_n(:,:,jk-1) + fse3t_n(:,:,jk-1) |
---|
520 | fsde3w_n(:,:,jk) = fsdept_n(:,:,jk ) - sshn (:,:) |
---|
521 | END DO |
---|
522 | ENDIF |
---|
523 | ! |
---|
524 | END SUBROUTINE lim_sbc_init_2 |
---|
525 | |
---|
526 | #else |
---|
527 | !!---------------------------------------------------------------------- |
---|
528 | !! Default option Empty module NO LIM 2.0 sea-ice model |
---|
529 | !!---------------------------------------------------------------------- |
---|
530 | #endif |
---|
531 | |
---|
532 | !!====================================================================== |
---|
533 | END MODULE limsbc_2 |
---|