1 | MODULE trcsbc |
---|
2 | !!============================================================================== |
---|
3 | !! *** MODULE trcsbc *** |
---|
4 | !! Ocean passive tracers: surface boundary condition |
---|
5 | !!====================================================================== |
---|
6 | !! History : 8.2 ! 1998-10 (G. Madec, G. Roullet, M. Imbard) Original code |
---|
7 | !! 8.2 ! 2001-02 (D. Ludicone) sea ice and free surface |
---|
8 | !! 8.5 ! 2002-06 (G. Madec) F90: Free form and module |
---|
9 | !! 9.0 ! 2004-03 (C. Ethe) adapted for passive tracers |
---|
10 | !! ! 2006-08 (C. Deltel) Diagnose ML trends for passive tracers |
---|
11 | !!============================================================================== |
---|
12 | #if defined key_top |
---|
13 | !!---------------------------------------------------------------------- |
---|
14 | !! 'key_top' TOP models |
---|
15 | !!---------------------------------------------------------------------- |
---|
16 | !! trc_sbc : update the tracer trend at ocean surface |
---|
17 | !!---------------------------------------------------------------------- |
---|
18 | !! * Modules used |
---|
19 | USE oce_trc ! ocean dynamics and active tracers variables |
---|
20 | USE trc ! ocean passive tracers variables |
---|
21 | USE prtctl_trc ! Print control for debbuging |
---|
22 | USE trdmod_oce |
---|
23 | USE trdtra |
---|
24 | |
---|
25 | IMPLICIT NONE |
---|
26 | PRIVATE |
---|
27 | |
---|
28 | !! * Routine accessibility |
---|
29 | PUBLIC trc_sbc ! routine called by step.F90 |
---|
30 | |
---|
31 | !! * Substitutions |
---|
32 | # include "top_substitute.h90" |
---|
33 | !!---------------------------------------------------------------------- |
---|
34 | !! TOP 1.0 , LOCEAN-IPSL (2005) |
---|
35 | !! $Id$ |
---|
36 | !! This software is governed by the CeCILL licence see modipsl/doc/NEMO_CeCILL.txt |
---|
37 | !!---------------------------------------------------------------------- |
---|
38 | |
---|
39 | CONTAINS |
---|
40 | |
---|
41 | SUBROUTINE trc_sbc ( kt ) |
---|
42 | !!---------------------------------------------------------------------- |
---|
43 | !! *** ROUTINE trc_sbc *** |
---|
44 | !! |
---|
45 | !! ** Purpose : Compute the tracer surface boundary condition trend of |
---|
46 | !! (concentration/dilution effect) and add it to the general |
---|
47 | !! trend of tracer equations. |
---|
48 | !! |
---|
49 | !! ** Method : |
---|
50 | !! * concentration/dilution effect: |
---|
51 | !! The surface freshwater flux modify the ocean volume |
---|
52 | !! and thus the concentration of a tracer as : |
---|
53 | !! tra = tra + emp * trn / e3t for k=1 |
---|
54 | !! where emp, the surface freshwater budget (evaporation minus |
---|
55 | !! precipitation minus runoff) given in kg/m2/s is divided |
---|
56 | !! by 1035 kg/m3 (density of ocean water) to obtain m/s. |
---|
57 | !! |
---|
58 | !! ** Action : - Update the 1st level of tra with the trend associated |
---|
59 | !! with the tracer surface boundary condition |
---|
60 | !! |
---|
61 | !!---------------------------------------------------------------------- |
---|
62 | !! * Arguments |
---|
63 | INTEGER, INTENT( in ) :: kt ! ocean time-step index |
---|
64 | |
---|
65 | !! * Local declarations |
---|
66 | INTEGER :: ji, jj, jn ! dummy loop indices |
---|
67 | REAL(wp) :: ztra, zsrau, zse3t ! temporary scalars |
---|
68 | REAL(wp), DIMENSION(:,:,:), ALLOCATABLE :: ztrtrd |
---|
69 | CHARACTER (len=22) :: charout |
---|
70 | !!---------------------------------------------------------------------- |
---|
71 | |
---|
72 | IF( kt == nittrc000 ) THEN |
---|
73 | IF(lwp) WRITE(numout,*) |
---|
74 | IF(lwp) WRITE(numout,*) 'trc_sbc : Passive tracers surface boundary condition' |
---|
75 | IF(lwp) WRITE(numout,*) '~~~~~~~ ' |
---|
76 | ENDIF |
---|
77 | |
---|
78 | IF( l_trdtrc ) ALLOCATE( ztrtrd(jpi,jpj,jpk) ) |
---|
79 | |
---|
80 | ! 0. initialization |
---|
81 | zsrau = 1. / rau0 |
---|
82 | #if defined key_zco |
---|
83 | zse3t = 1. / e3t_0(1) |
---|
84 | #endif |
---|
85 | |
---|
86 | DO jn = 1, jptra |
---|
87 | ! 1. Concentration dillution effect on tra |
---|
88 | IF( l_trdtrc ) ztrtrd(:,:,:) = tra(:,:,:,jn) ! save trends |
---|
89 | |
---|
90 | DO jj = 2, jpj |
---|
91 | DO ji = fs_2, fs_jpim1 ! vector opt. |
---|
92 | #if ! defined key_zco |
---|
93 | zse3t = 1. / fse3t(ji,jj,1) |
---|
94 | #endif |
---|
95 | IF( lk_vvl ) THEN ; ztra = 0.e0 ! No concent./dilut. effect |
---|
96 | ELSE ; ztra = emps(ji,jj) * zsrau * trn(ji,jj,1,jn) * zse3t * tmask(ji,jj,1) |
---|
97 | ENDIF |
---|
98 | tra(ji,jj,1,jn) = tra(ji,jj,1,jn) + ztra |
---|
99 | END DO |
---|
100 | END DO |
---|
101 | |
---|
102 | IF( l_trdtrc ) THEN |
---|
103 | ztrtrd(:,:,:) = tra(:,:,:,jn) - ztrtrd(:,:,:) |
---|
104 | CALL trd_tra( kt, 'TRC', jn, jptra_trd_nsr, ztrtrd ) |
---|
105 | END IF |
---|
106 | ! ! =========== |
---|
107 | END DO ! tracer loop |
---|
108 | ! ! =========== |
---|
109 | |
---|
110 | IF( l_trdtrc ) DEALLOCATE( ztrtrd ) |
---|
111 | IF( ln_ctl ) THEN |
---|
112 | WRITE(charout, FMT="('sbc ')") ; CALL prt_ctl_trc_info(charout) |
---|
113 | CALL prt_ctl_trc( tab4d=tra, mask=tmask, clinfo=ctrcnm, clinfo2='trd' ) |
---|
114 | ENDIF |
---|
115 | |
---|
116 | END SUBROUTINE trc_sbc |
---|
117 | |
---|
118 | #else |
---|
119 | !!---------------------------------------------------------------------- |
---|
120 | !! Dummy module : NO passive tracer |
---|
121 | !!---------------------------------------------------------------------- |
---|
122 | CONTAINS |
---|
123 | SUBROUTINE trc_sbc (kt) ! Empty routine |
---|
124 | INTEGER, INTENT(in) :: kt |
---|
125 | WRITE(*,*) 'trc_sbc: You should not have seen this print! error?', kt |
---|
126 | END SUBROUTINE trc_sbc |
---|
127 | #endif |
---|
128 | |
---|
129 | !!====================================================================== |
---|
130 | END MODULE trcsbc |
---|