New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traldf_iso.F90 in branches/DEV_r2006_merge_TRA_TRC/NEMO/OPA_SRC/TRA – NEMO

source: branches/DEV_r2006_merge_TRA_TRC/NEMO/OPA_SRC/TRA/traldf_iso.F90 @ 2024

Last change on this file since 2024 was 2024, checked in by cetlod, 14 years ago

Merge of active and passive tracer advection/diffusion modules, see ticket:693
  • Property svn:eol-style set to native
  • Property svn:keywords set to Id
File size: 15.7 KB
Line 
1MODULE traldf_iso
2   !!======================================================================
3   !!                   ***  MODULE  traldf_iso  ***
4   !! Ocean  tracers:  horizontal component of the lateral tracer mixing trend
5   !!======================================================================
6   !! History :   OPA  !  1994-08  (G. Madec, M. Imbard)
7   !!                  !  1997-05  (G. Madec)  split into traldf and trazdf
8   !!             NEMO !  2002-08  (G. Madec)  Free form, F90
9   !!             1.0  !  2005-11  (G. Madec)  merge traldf and trazdf :-)
10   !!             3.0  !  2008-01  (C. Ethe, G. Madec) Merge TRA-TRC
11   !!----------------------------------------------------------------------
12#if   defined key_ldfslp   ||   defined key_esopa
13   !!----------------------------------------------------------------------
14   !!   'key_ldfslp'               slope of the lateral diffusive direction
15   !!----------------------------------------------------------------------
16   !!----------------------------------------------------------------------
17   !!   tra_ldf_iso  : update the tracer trend with the horizontal
18   !!                  component of a iso-neutral laplacian operator
19   !!                  and with the vertical part of
20   !!                  the isopycnal or geopotential s-coord. operator
21   !!----------------------------------------------------------------------
22   USE oce             ! ocean dynamics and active tracers
23   USE dom_oce         ! ocean space and time domain
24   USE ldftra_oce      ! ocean active tracers: lateral physics
25   USE zdf_oce         ! ocean vertical physics
26   USE in_out_manager  ! I/O manager
27   USE iom             !
28   USE ldfslp          ! iso-neutral slopes
29   USE diaptr          ! poleward transport diagnostics
30#if defined key_diaar5
31   USE phycst          ! physical constants
32   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
33#endif
34
35   IMPLICIT NONE
36   PRIVATE
37
38   PUBLIC   tra_ldf_iso   ! routine called by step.F90
39
40   !! * Substitutions
41#  include "domzgr_substitute.h90"
42#  include "ldftra_substitute.h90"
43#  include "vectopt_loop_substitute.h90"
44   !!----------------------------------------------------------------------
45   !!   OPA 9.0 , LOCEAN-IPSL (2005)
46   !! $Id$
47   !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt)
48   !!----------------------------------------------------------------------
49
50CONTAINS
51
52   SUBROUTINE tra_ldf_iso( kt   , cdtype, pgtu, pgtv,  &
53      &                    ptrab, ptraa , kjpt, pahtb0 )
54      !!----------------------------------------------------------------------
55      !!                  ***  ROUTINE tra_ldf_iso  ***
56      !!
57      !! ** Purpose :   Compute the before horizontal tracer (t & s) diffusive
58      !!      trend for a laplacian tensor (ezxcept the dz[ dz[.] ] term) and
59      !!      add it to the general trend of tracer equation.
60      !!
61      !! ** Method  :   The horizontal component of the lateral diffusive trends
62      !!      is provided by a 2nd order operator rotated along neural or geopo-
63      !!      tential surfaces to which an eddy induced advection can be added
64      !!      It is computed using before fields (forward in time) and isopyc-
65      !!      nal or geopotential slopes computed in routine ldfslp.
66      !!
67      !!      1st part :  masked horizontal derivative of T  ( di[ t ] )
68      !!      ========    with partial cell update if ln_zps=T.
69      !!
70      !!      2nd part :  horizontal fluxes of the lateral mixing operator
71      !!      ========   
72      !!         zftu = (aht+ahtb0) e2u*e3u/e1u di[ tb ]
73      !!               - aht       e2u*uslp    dk[ mi(mk(tb)) ]
74      !!         zftv = (aht+ahtb0) e1v*e3v/e2v dj[ tb ]
75      !!               - aht       e2u*vslp    dk[ mj(mk(tb)) ]
76      !!      take the horizontal divergence of the fluxes:
77      !!         difft = 1/(e1t*e2t*e3t) {  di-1[ zftu ] +  dj-1[ zftv ]  }
78      !!      Add this trend to the general trend (ta,sa):
79      !!         ta = ta + difft
80      !!
81      !!      3rd part: vertical trends of the lateral mixing operator
82      !!      ========  (excluding the vertical flux proportional to dk[t] )
83      !!      vertical fluxes associated with the rotated lateral mixing:
84      !!         zftw =-aht {  e2t*wslpi di[ mi(mk(tb)) ]
85      !!                     + e1t*wslpj dj[ mj(mk(tb)) ]  }
86      !!      take the horizontal divergence of the fluxes:
87      !!         difft = 1/(e1t*e2t*e3t) dk[ zftw ]
88      !!      Add this trend to the general trend (ta,sa):
89      !!         pta = pta + difft
90      !!
91      !! ** Action :   Update pta arrays with the before rotated diffusion
92      !!----------------------------------------------------------------------
93      !!* Module used
94      USE oce         , zftu => ua   ! use ua as workspace
95      USE oce         , zftv => va   ! use va as workspace
96      !!* Arguments
97      INTEGER         , INTENT(in   )                                ::   kt             ! ocean time-step index
98      CHARACTER(len=3), INTENT(in   )                                ::   cdtype         ! =TRA or TRC (tracer indicator)
99      INTEGER         , INTENT(in   )                                ::   kjpt            ! number of tracers
100      REAL(wp)        , INTENT(in   ), DIMENSION(jpi,jpj,kjpt  )     ::   pgtu, pgtv     ! tracer gradient at pstep levels
101      REAL(wp)        , INTENT(in   ), DIMENSION(jpi,jpj,jpk,kjpt)   ::   ptrab          ! before and now tracer fields
102      REAL(wp)        , INTENT(inout), DIMENSION(jpi,jpj,jpk,kjpt)   ::   ptraa          ! tracer trend
103      REAL(wp)        , INTENT(in   )                                ::   pahtb0         ! background diffusion coef
104      !!* Local declarations
105      INTEGER  ::  ji, jj, jk,jn   ! dummy loop indices
106      INTEGER  ::  iku, ikv     ! temporary integer
107      REAL(wp) ::  zmsku, zabe1, zcof1, zcoef3   ! temporary scalars
108      REAL(wp) ::  zmskv, zabe2, zcof2, zcoef4   !    "         "
109      REAL(wp) ::  zcoef0, zbtr, ztra                           !    "         "
110      REAL(wp), DIMENSION(jpi,jpj)     ::   zdkt, zdk1t         ! 2D workspace
111      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zdit, zdjt, ztfw     ! 3D workspace
112#if defined key_diaar5
113      REAL(wp), DIMENSION(jpi,jpj)     ::   z2d                  !  "         "
114      REAL(wp)                         ::   zztmp                !  "         "
115#endif
116      !!----------------------------------------------------------------------
117
118      IF( kt == nit000 ) THEN
119         IF(lwp) WRITE(numout,*)
120         IF(lwp) WRITE(numout,*) 'tra_ldf_iso : rotated laplacian diffusion operator'
121         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
122      ENDIF
123      !
124      !                                                          ! ===========
125      DO jn = 1, kjpt                                            ! tracer loop
126         !                                                       ! ===========
127         !                                               
128         !!----------------------------------------------------------------------
129         !!   I - masked horizontal derivative
130         !!----------------------------------------------------------------------
131         !!bug ajout.... why?   ( 1,jpj,:) and (jpi,1,:) should be sufficient....
132         zdit (1,:,:) = 0.e0     ;     zdit (jpi,:,:) = 0.e0
133         zdjt (1,:,:) = 0.e0     ;     zdjt (jpi,:,:) = 0.e0
134         !!end
135
136         ! Horizontal tracer gradient
137         DO jk = 1, jpkm1
138            DO jj = 1, jpjm1
139               DO ji = 1, fs_jpim1   ! vector opt.
140                  zdit(ji,jj,jk) = ( ptrab(ji+1,jj  ,jk,jn) - ptrab(ji,jj,jk,jn) ) * umask(ji,jj,jk)
141                  zdjt(ji,jj,jk) = ( ptrab(ji  ,jj+1,jk,jn) - ptrab(ji,jj,jk,jn) ) * vmask(ji,jj,jk)
142               END DO
143            END DO
144         END DO
145         IF( ln_zps ) THEN      ! partial steps correction at the last level
146            DO jj = 1, jpjm1
147               DO ji = 1, fs_jpim1   ! vector opt.
148                  ! last level
149                  iku = MIN( mbathy(ji,jj), mbathy(ji+1,jj  ) ) - 1
150                  ikv = MIN( mbathy(ji,jj), mbathy(ji  ,jj+1) ) - 1
151                  zdit(ji,jj,iku) = pgtu(ji,jj,jn)         
152                  zdjt(ji,jj,ikv) = pgtv(ji,jj,jn)     
153               END DO
154            END DO
155         ENDIF
156
157         !!----------------------------------------------------------------------
158         !!   II - horizontal trend  (full)
159         !!----------------------------------------------------------------------
160         
161!CDIR PARALLEL DO PRIVATE( zdk1t )
162         !                                                ! ===============
163         DO jk = 1, jpkm1                                 ! Horizontal slab
164            !                                             ! ===============
165            ! 1. Vertical tracer gradient at level jk and jk+1
166            ! ------------------------------------------------
167            ! surface boundary condition: zdkt(jk=1)=zdkt(jk=2)
168           
169            zdk1t(:,:) = ( ptrab(:,:,jk,jn) - ptrab(:,:,jk+1,jn) ) * tmask(:,:,jk+1)
170           
171            IF( jk == 1 ) THEN
172               zdkt(:,:) = zdk1t(:,:)
173            ELSE
174               zdkt(:,:) = ( ptrab(:,:,jk-1,jn) - ptrab(:,:,jk,jn) ) * tmask(:,:,jk)
175            ENDIF
176
177
178            ! 2. Horizontal fluxes
179            ! --------------------
180           
181            DO jj = 1 , jpjm1
182               DO ji = 1, fs_jpim1   ! vector opt.
183                  zabe1 = ( fsahtu(ji,jj,jk) + pahtb0 ) * e2u(ji,jj) * fse3u(ji,jj,jk) / e1u(ji,jj)
184                  zabe2 = ( fsahtv(ji,jj,jk) + pahtb0 ) * e1v(ji,jj) * fse3v(ji,jj,jk) / e2v(ji,jj)
185                 
186                  zmsku = 1. / MAX(  tmask(ji+1,jj,jk  ) + tmask(ji,jj,jk+1)   &
187                     &             + tmask(ji+1,jj,jk+1) + tmask(ji,jj,jk  ), 1. )
188                 
189                  zmskv = 1. / MAX(  tmask(ji,jj+1,jk  ) + tmask(ji,jj,jk+1)   &
190                     &             + tmask(ji,jj+1,jk+1) + tmask(ji,jj,jk  ), 1. )
191                 
192                  zcof1 = - fsahtu(ji,jj,jk) * e2u(ji,jj) * uslp(ji,jj,jk) * zmsku
193                  zcof2 = - fsahtv(ji,jj,jk) * e1v(ji,jj) * vslp(ji,jj,jk) * zmskv
194                  !
195                  zftu(ji,jj,jk ) = (  zabe1 * zdit(ji,jj,jk)   &
196                     &              + zcof1 * (  zdkt (ji+1,jj) + zdk1t(ji,jj)      &
197                     &                         + zdk1t(ji+1,jj) + zdkt (ji,jj)  )  ) * umask(ji,jj,jk)
198                  zftv(ji,jj,jk) = (  zabe2 * zdjt(ji,jj,jk)   &
199                     &              + zcof2 * (  zdkt (ji,jj+1) + zdk1t(ji,jj)      &
200                     &                         + zdk1t(ji,jj+1) + zdkt (ji,jj)  )  ) * vmask(ji,jj,jk)                 
201               END DO
202            END DO
203
204
205            ! II.4 Second derivative (divergence) and add to the general trend
206            ! ----------------------------------------------------------------
207            DO jj = 2 , jpjm1
208               DO ji = fs_2, fs_jpim1   ! vector opt.
209                  zbtr = 1.0 / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
210                  ztra = zbtr * ( zftu(ji,jj,jk) - zftu(ji-1,jj,jk) + zftv(ji,jj,jk) - zftv(ji,jj-1,jk)  )
211                  ptraa(ji,jj,jk,jn) = ptraa(ji,jj,jk,jn) + ztra
212               END DO
213            END DO
214            !                                          ! ===============
215         END DO                                        !   End of slab 
216         !                                             ! ===============
217         ! "Poleward" diffusive heat or salt transports
218         IF( cdtype == 'TRA' .AND. ln_diaptr .AND. ( MOD( kt, nf_ptr ) == 0 ) ) THEN
219            IF( jn == jp_tem)   pht_ldf(:) = ptr_vj( zftv(:,:,:) )
220            IF( jn == jp_sal)   pst_ldf(:) = ptr_vj( zftv(:,:,:) )
221         ENDIF
222 
223#if defined key_diaar5
224         IF( cdtype == 'TRA' .AND. jn == jp_tem  ) THEN
225            zztmp = 0.5 * rau0 * rcp 
226            z2d(:,:) = 0.e0 
227            DO jk = 1, jpkm1
228               DO jj = 2, jpjm1
229                  DO ji = fs_2, fs_jpim1   ! vector opt.
230                     z2d(ji,jj) = z2d(ji,jj) + zztmp * zftu(ji,jj,jk)   &
231            &                    * ( ptran(ji,jj,jk,jn) + ptran(ji+1,jj,jk,jn) ) * e1u(ji,jj) * fse3u(ji,jj,jk) 
232                  END DO
233               END DO
234            END DO
235            CALL lbc_lnk( z2d, 'U', -1. )
236            CALL iom_put( "udiff_heattr", z2d )                  ! heat transport in i-direction
237            z2d(:,:) = 0.e0 
238            DO jk = 1, jpkm1
239               DO jj = 2, jpjm1
240                  DO ji = fs_2, fs_jpim1   ! vector opt.
241                     z2d(ji,jj) = z2d(ji,jj) + zztmp * zftv(ji,jj,jk)   &
242           &                   * ( ptran(ji,jj,jk,jn) + ptran(ji,jj+1,jk,jn) ) * e2v(ji,jj) * fse3v(ji,jj,jk) 
243                  END DO
244               END DO
245            END DO
246            CALL lbc_lnk( z2d, 'V', -1. )
247            CALL iom_put( "vdiff_heattr", z2d )                  !  heat transport in i-direction
248         END IF
249#endif
250
251         !!----------------------------------------------------------------------
252         !!   III - vertical trend of T & S (extra diagonal terms only)
253         !!----------------------------------------------------------------------
254         
255         ! Local constant initialization
256         ! -----------------------------
257         ztfw(1,:,:) = 0.e0     ;     ztfw(jpi,:,:) = 0.e0
258         
259         ! Vertical fluxes
260         ! ---------------
261         
262         ! Surface and bottom vertical fluxes set to zero
263         ztfw(:,:, 1 ) = 0.e0      ;      ztfw(:,:,jpk) = 0.e0
264         
265         ! interior (2=<jk=<jpk-1)
266         DO jk = 2, jpkm1
267            DO jj = 2, jpjm1
268               DO ji = fs_2, fs_jpim1   ! vector opt.
269                  zcoef0 = - fsahtw(ji,jj,jk) * tmask(ji,jj,jk)
270                 
271                  zmsku = 1./MAX(   umask(ji  ,jj,jk-1) + umask(ji-1,jj,jk)      &
272                     &            + umask(ji-1,jj,jk-1) + umask(ji  ,jj,jk), 1.  )
273                 
274                  zmskv = 1./MAX(   vmask(ji,jj  ,jk-1) + vmask(ji,jj-1,jk)      &
275                     &            + vmask(ji,jj-1,jk-1) + vmask(ji,jj  ,jk), 1.  )
276                 
277                  zcoef3 = zcoef0 * e2t(ji,jj) * zmsku * wslpi (ji,jj,jk)
278                  zcoef4 = zcoef0 * e1t(ji,jj) * zmskv * wslpj (ji,jj,jk)
279                 
280                  ztfw(ji,jj,jk) = zcoef3 * (   zdit(ji  ,jj  ,jk-1) + zdit(ji-1,jj  ,jk)      &
281                     &                        + zdit(ji-1,jj  ,jk-1) + zdit(ji  ,jj  ,jk)  )   &
282                     &           + zcoef4 * (   zdjt(ji  ,jj  ,jk-1) + zdjt(ji  ,jj-1,jk)      &
283                     &                        + zdjt(ji  ,jj-1,jk-1) + zdjt(ji  ,jj  ,jk)  )
284               END DO
285            END DO
286         END DO
287         
288         
289         ! I.5 Divergence of vertical fluxes added to the general tracer trend
290         ! -------------------------------------------------------------------
291         
292         DO jk = 1, jpkm1
293            DO jj = 2, jpjm1
294               DO ji = fs_2, fs_jpim1   ! vector opt.
295                  zbtr = 1.0 / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
296                  ztra = (  ztfw(ji,jj,jk) - ztfw(ji,jj,jk+1)  ) * zbtr
297                  ptraa(ji,jj,jk,jn) = ptraa(ji,jj,jk,jn) + ztra
298               END DO
299            END DO
300         END DO
301         !
302      END DO
303      !
304   END SUBROUTINE tra_ldf_iso
305
306#else
307   !!----------------------------------------------------------------------
308   !!   default option :   Dummy code   NO rotation of the diffusive tensor
309   !!----------------------------------------------------------------------
310CONTAINS
311   SUBROUTINE tra_ldf_iso( kt )               ! Empty routine
312      WRITE(*,*) 'tra_ldf_iso: You should not have seen this print! error?', kt
313   END SUBROUTINE tra_ldf_iso
314#endif
315
316   !!==============================================================================
317END MODULE traldf_iso
Note: See TracBrowser for help on using the repository browser.