New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traadv_tvd.F90 in branches/DEV_r2006_merge_TRA_TRC/NEMO/OPA_SRC/TRA – NEMO

source: branches/DEV_r2006_merge_TRA_TRC/NEMO/OPA_SRC/TRA/traadv_tvd.F90 @ 2024

Last change on this file since 2024 was 2024, checked in by cetlod, 14 years ago

Merge of active and passive tracer advection/diffusion modules, see ticket:693
  • Property svn:eol-style set to native
  • Property svn:keywords set to Id
File size: 17.6 KB
Line 
1MODULE traadv_tvd
2   !!==============================================================================
3   !!                       ***  MODULE  traadv_tvd  ***
4   !! Ocean  tracers:  horizontal & vertical advective trend
5   !!==============================================================================
6   !! History :       !  95-12  (L. Mortier)  Original code
7   !!                 !  00-01  (H. Loukos)  adapted to ORCA
8   !!                 !  00-10  (MA Foujols E.Kestenare)  include file not routine
9   !!                 !  00-12  (E. Kestenare M. Levy)  fix bug in trtrd indexes
10   !!                 !  01-07  (E. Durand G. Madec)  adaptraation to ORCA config
11   !!            8.5  !  02-06  (G. Madec)  F90: Free form and module
12   !!            9.0  !  04-01  (A. de Miranda, G. Madec, J.M. Molines ): advective bbl
13   !!            9.0  !  08-04  (S. Cravatte) add the i-, j- & k- trends computation
14   !!            " "  !  09-11  (V. Garnier) Surface pressure gradient organization
15   !!            3.3  !  10-05 (C. Ethe, G. Madec)  merge TRC-TRA + switch from velocity to transport
16   !!----------------------------------------------------------------------
17
18
19   !!----------------------------------------------------------------------
20   !!   tra_adv_tvd  : update the tracer trend with the horizontal
21   !!                  and vertical advection trends using a TVD scheme
22   !!   nonosc       : compute monotonic tracer fluxes by a nonoscillatory
23   !!                  algorithm
24   !!----------------------------------------------------------------------
25   USE oce             ! ocean dynamics and active tracers
26   USE dom_oce         ! ocean space and time domain
27   USE trdmod_oce      ! tracers trends
28   USE trdtra      ! tracers trends
29   USE in_out_manager  ! I/O manager
30   USE dynspg_oce      ! choice/control of key cpp for surface pressure gradient
31   USE lib_mpp
32   USE lbclnk          ! ocean lateral boundary condition (or mpp link)
33   USE diaptr          ! poleward transport diagnostics
34
35
36   IMPLICIT NONE
37   PRIVATE
38
39   PUBLIC   tra_adv_tvd    ! routine called by step.F90
40
41   LOGICAL  :: l_trd       ! flag to compute trends
42
43   !! * Substitutions
44#  include "domzgr_substitute.h90"
45#  include "vectopt_loop_substitute.h90"
46   !!----------------------------------------------------------------------
47   !!   OPA 9.0 , LOCEAN-IPSL (2006)
48   !! $Id$
49   !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt)
50   !!----------------------------------------------------------------------
51
52CONTAINS
53
54   SUBROUTINE tra_adv_tvd ( kt   , cdtype, pun  , pvn, pwn, &
55      &                     ptrab, ptran , ptraa, kjpt   )
56      !!----------------------------------------------------------------------
57      !!                  ***  ROUTINE tra_adv_tvd  ***
58      !!
59      !! **  Purpose :   Compute the now trend due to total advection of
60      !!       tracers and add it to the general trend of tracer equations
61      !!
62      !! **  Method  :   TVD scheme, i.e. 2nd order centered scheme with
63      !!       corrected flux (monotonic correction)
64      !!       note: - this advection scheme needs a leap-frog time scheme
65      !!
66      !! ** Action : - update (ptraa) with the now advective tracer trends
67      !!             - save the trends
68      !!----------------------------------------------------------------------
69      !!* Module used
70      USE oce         , zwx => ua   ! use ua as workspace
71      USE oce         , zwy => va   ! use va as workspace
72      !!* Arguments
73      INTEGER         , INTENT(in   )                               ::   kt              ! ocean time-step index
74      CHARACTER(len=3), INTENT(in   )                               ::   cdtype          ! =TRA or TRC (tracer indicator)
75      INTEGER         , INTENT(in   )                               ::   kjpt            ! number of tracers
76      REAL(wp)        , INTENT(in   ), DIMENSION(jpi,jpj,jpk)       ::   pun, pvn, pwn   ! 3 ocean velocity components
77      REAL(wp)        , INTENT(in   ), DIMENSION(jpi,jpj,jpk,kjpt)  ::   ptrab, ptran        ! before and now tracer fields
78      REAL(wp)        , INTENT(inout), DIMENSION(jpi,jpj,jpk,kjpt)  ::   ptraa           ! tracer trend
79      !!* Local declarations
80      INTEGER  ::   ji, jj, jk, jn          ! dummy loop indices 
81      REAL(wp) ::   &
82         z2, z2dtt, zbtr, ztra,              &  ! temporary scalar
83         zfp_ui, zfp_vj, zfp_wk,             &  !    "         "
84         zfm_ui, zfm_vj, zfm_wk                 !    "         "
85      REAL(wp), DIMENSION (jpi,jpj,jpk) ::   zwi, zwz   ! temporary workspace
86      REAL(wp), DIMENSION (:,:,:), ALLOCATABLE :: ztrdx, ztrdy, ztrdz
87      !!----------------------------------------------------------------------
88
89      zwi(:,:,:) = 0.e0
90
91      IF( kt == nit000 .AND. lwp ) THEN
92         WRITE(numout,*)
93         WRITE(numout,*) 'tra_adv_tvd : TVD advection scheme'
94         WRITE(numout,*) '~~~~~~~~~~~'
95         !
96         l_trd = .FALSE.
97         IF( ( cdtype == 'TRA' .AND. l_trdtra ) .OR. ( cdtype == 'TRC' .AND. l_trdtrc ) ) l_trd = .TRUE.
98      ENDIF
99      !
100      IF( l_trd )  THEN
101        ALLOCATE( ztrdx(jpi,jpj,jpk) )      ;      ztrdx(:,:,:) = 0.
102        ALLOCATE( ztrdy(jpi,jpj,jpk) )      ;      ztrdy(:,:,:) = 0.
103        ALLOCATE( ztrdz(jpi,jpj,jpk) )      ;      ztrdz(:,:,:) = 0.
104      END IF
105      !
106      IF( neuler == 0 .AND. kt == nit000 ) THEN   ;    z2 = 1.
107      ELSE                                        ;    z2 = 2.
108      ENDIF
109      !
110      !                                                          ! ===========
111      DO jn = 1, kjpt                                            ! tracer loop
112         !                                                       ! ===========
113         ! 1. Bottom value : flux set to zero
114         ! ----------------------------------
115         zwx(:,:,jpk) = 0.e0    ;    zwz(:,:,jpk) = 0.e0
116         zwy(:,:,jpk) = 0.e0    ;    zwi(:,:,jpk) = 0.e0
117
118         ! 2. upstream advection with initial mass fluxes & intermediate update
119         ! --------------------------------------------------------------------
120         ! upstream tracer flux in the i and j direction
121         DO jk = 1, jpkm1
122            DO jj = 1, jpjm1
123               DO ji = 1, fs_jpim1   ! vector opt.
124                  ! upstream scheme
125                  zfp_ui = pun(ji,jj,jk) + ABS( pun(ji,jj,jk) )
126                  zfm_ui = pun(ji,jj,jk) - ABS( pun(ji,jj,jk) )
127                  zfp_vj = pvn(ji,jj,jk) + ABS( pvn(ji,jj,jk) )
128                  zfm_vj = pvn(ji,jj,jk) - ABS( pvn(ji,jj,jk) )
129                  zwx(ji,jj,jk) = 0.5 * ( zfp_ui * ptrab(ji,jj,jk,jn) + zfm_ui * ptrab(ji+1,jj  ,jk,jn) )
130                  zwy(ji,jj,jk) = 0.5 * ( zfp_vj * ptrab(ji,jj,jk,jn) + zfm_vj * ptrab(ji  ,jj+1,jk,jn) )
131               END DO
132            END DO
133         END DO
134
135         ! upstream tracer flux in the k direction
136         ! Surface value
137         IF( lk_vvl ) THEN   ;   zwz(:,:, 1 ) = 0.e0                         ! volume variable
138         ELSE                ;   zwz(:,:, 1 ) = pwn(:,:,1) * ptrab(:,:,1,jn)   ! linear free surface
139         ENDIF
140         ! Interior value
141         DO jk = 2, jpkm1
142            DO jj = 1, jpj
143               DO ji = 1, jpi
144                  zfp_wk = pwn(ji,jj,jk) + ABS( pwn(ji,jj,jk) )
145                  zfm_wk = pwn(ji,jj,jk) - ABS( pwn(ji,jj,jk) )
146                  zwz(ji,jj,jk) = 0.5 * ( zfp_wk * ptrab(ji,jj,jk,jn) + zfm_wk * ptrab(ji,jj,jk-1,jn) )
147               END DO
148            END DO
149         END DO
150
151         ! total advective trend
152         DO jk = 1, jpkm1
153            z2dtt = z2 * rdttra(jk)
154            DO jj = 2, jpjm1
155               DO ji = fs_2, fs_jpim1   ! vector opt.
156                  zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
157                  ! total intermediate advective trends
158                  ztra = - zbtr * (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
159                     &             + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
160                     &             + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) )
161                  ! update and guess with monotonic sheme
162                  ptraa(ji,jj,jk,jn) =   ptraa(ji,jj,jk,jn)         + ztra
163                  zwi(ji,jj,jk)    = ( ptrab(ji,jj,jk,jn) + z2dtt * ztra ) * tmask(ji,jj,jk)
164               END DO
165            END DO
166         END DO
167         !                             ! Lateral boundary conditions on zwi  (unchanged sign)
168         CALL lbc_lnk( zwi, 'T', 1. ) 
169
170         !                                 ! trend diagnostics (contribution of upstream fluxes)
171         IF( l_trd )  THEN 
172            ! store intermediate advective trends
173            ztrdx(:,:,:) = zwx(:,:,:)   ;    ztrdy(:,:,:) = zwy(:,:,:)  ;   ztrdz(:,:,:) = zwz(:,:,:)
174         END IF
175         !                                 ! "Poleward" heat and salt transports (contribution of upstream fluxes)
176         IF( cdtype == 'TRA' .AND. ln_diaptr .AND. ( MOD( kt, nf_ptr ) == 0 ) ) THEN 
177           IF( jn == jp_tem )  pht_adv(:) = ptr_vj( zwy(:,:,:) )
178           IF( jn == jp_sal )  pst_adv(:) = ptr_vj( zwy(:,:,:) )
179         ENDIF
180
181         ! 3. antidiffusive flux : high order minus low order
182         ! --------------------------------------------------
183         ! antidiffusive flux on i and j
184         DO jk = 1, jpkm1
185            DO jj = 1, jpjm1
186               DO ji = 1, fs_jpim1   ! vector opt.
187                  zwx(ji,jj,jk) = 0.5 * pun(ji,jj,jk) * ( ptran(ji,jj,jk,jn) + ptran(ji+1,jj,jk,jn) ) - zwx(ji,jj,jk)
188                  zwy(ji,jj,jk) = 0.5 * pvn(ji,jj,jk) * ( ptran(ji,jj,jk,jn) + ptran(ji,jj+1,jk,jn) ) - zwy(ji,jj,jk)
189               END DO
190            END DO
191         END DO
192     
193         ! antidiffusive flux on k
194         ! Surface value
195         zwz(:,:,1) = 0.e0
196         ! Interior value
197         DO jk = 2, jpkm1
198            DO jj = 1, jpj
199               DO ji = 1, jpi
200                  zwz(ji,jj,jk) = 0.5 * pwn(ji,jj,jk) * ( ptran(ji,jj,jk,jn) + ptran(ji,jj,jk-1,jn) ) - zwz(ji,jj,jk)
201               END DO
202            END DO
203         END DO
204
205         ! Lateral bondary conditions
206         CALL lbc_lnk( zwx, 'U', -1. )
207         CALL lbc_lnk( zwy, 'V', -1. )
208         CALL lbc_lnk( zwz, 'W',  1. )
209
210         ! 4. monotonicity algorithm
211         ! -------------------------
212         CALL nonosc( ptrab(:,:,:,jn), zwx, zwy, zwz, zwi, z2 )
213
214
215         ! 5. final trend with corrected fluxes
216         ! ------------------------------------
217         DO jk = 1, jpkm1
218            DO jj = 2, jpjm1
219               DO ji = fs_2, fs_jpim1   ! vector opt. 
220                  zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
221                  ! total advective trends
222                  ztra = - zbtr * (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
223                     &             + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
224                     &             + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) )
225                  ! add them to the general tracer trends
226                  ptraa(ji,jj,jk,jn) = ptraa(ji,jj,jk,jn) + ztra
227               END DO
228            END DO
229         END DO
230
231         !                                 ! trend diagnostics (contribution of upstream fluxes)
232         IF( l_trd )  THEN
233            ztrdx(:,:,:) = ztrdx(:,:,:) + zwx(:,:,:)  ! <<< Add to previously computed
234            ztrdy(:,:,:) = ztrdy(:,:,:) + zwy(:,:,:)  ! <<< Add to previously computed
235            ztrdz(:,:,:) = ztrdz(:,:,:) + zwz(:,:,:)  ! <<< Add to previously computed
236           
237            CALL trd_tra( kt, cdtype, jn, jptra_trd_xad, ztrdx, pun, ptran(:,:,:,jn) )   
238            CALL trd_tra( kt, cdtype, jn, jptra_trd_yad, ztrdy, pvn, ptran(:,:,:,jn) ) 
239            CALL trd_tra( kt, cdtype, jn, jptra_trd_zad, ztrdz, pwn, ptran(:,:,:,jn) ) 
240         END IF
241         !                                 ! "Poleward" heat and salt transports (contribution of upstream fluxes)
242         IF( cdtype == 'TRA' .AND. ln_diaptr .AND. ( MOD( kt, nf_ptr ) == 0 ) ) THEN 
243           IF( jn == jp_tem )  pht_adv(:) = ptr_vj( zwy(:,:,:) ) + pht_adv(:)
244           IF( jn == jp_sal )  pst_adv(:) = ptr_vj( zwy(:,:,:) ) + pst_adv(:)
245         ENDIF
246         !
247      ENDDO
248      !
249      IF( l_trd )  THEN
250        DEALLOCATE( ztrdx )     ;     DEALLOCATE( ztrdy )     ;      DEALLOCATE( ztrdz ) 
251      END IF
252      !
253   END SUBROUTINE tra_adv_tvd
254
255
256   SUBROUTINE nonosc( pbef, paa, pbb, pcc, paft, prdt )
257      !!---------------------------------------------------------------------
258      !!                    ***  ROUTINE nonosc  ***
259      !!     
260      !! **  Purpose :   compute monotonic tracer fluxes from the upstream
261      !!       scheme and the before field by a nonoscillatory algorithm
262      !!
263      !! **  Method  :   ... ???
264      !!       warning : pbef and paft must be masked, but the boundaries
265      !!       conditions on the fluxes are not necessary zalezak (1979)
266      !!       drange (1995) multi-dimensional forward-in-time and upstream-
267      !!       in-space based differencing for fluid
268      !!----------------------------------------------------------------------
269      REAL(wp), INTENT( in ) ::   prdt   ! ???
270      REAL(wp), DIMENSION (jpi,jpj,jpk), INTENT( in    ) ::   &
271         pbef,                            & ! before field
272         paft                               ! after field
273      REAL(wp), DIMENSION (jpi,jpj,jpk), INTENT( inout ) ::   &
274         paa,                             & ! monotonic flux in the i direction
275         pbb,                             & ! monotonic flux in the j direction
276         pcc                                ! monotonic flux in the k direction
277      !!
278      INTEGER ::   ji, jj, jk               ! dummy loop indices
279      INTEGER ::   ikm1
280      REAL(wp), DIMENSION (jpi,jpj,jpk) ::   zbetup, zbetdo
281      REAL(wp), DIMENSION (jpi,jpj,jpk) ::   zbup, zbdo
282      REAL(wp) ::   zpos, zneg, zbt, za, zb, zc, zbig, zrtrn, z2dtt
283      REAL(wp) ::   zau, zbu, zcu, zav, zbv, zcv
284      REAL(wp) ::   zup, zdo
285      !!----------------------------------------------------------------------
286
287      zbig = 1.e+40
288      zrtrn = 1.e-15
289      zbetup(:,:,jpk) = 0.e0   ;   zbetdo(:,:,jpk) = 0.e0
290
291
292      ! Search local extrema
293      ! --------------------
294      ! max/min of pbef & paft with large negative/positive value (-/+zbig) inside land
295      zbup = MAX( pbef * tmask - zbig * ( 1.e0 - tmask ),   &
296         &        paft * tmask - zbig * ( 1.e0 - tmask )  )
297      zbdo = MIN( pbef * tmask + zbig * ( 1.e0 - tmask ),   &
298         &        paft * tmask + zbig * ( 1.e0 - tmask )  )
299
300      DO jk = 1, jpkm1
301         ikm1 = MAX(jk-1,1)
302         z2dtt = prdt * rdttra(jk)
303         DO jj = 2, jpjm1
304            DO ji = fs_2, fs_jpim1   ! vector opt.
305
306               ! search maximum in neighbourhood
307               zup = MAX(  zbup(ji  ,jj  ,jk  ),   &
308                  &        zbup(ji-1,jj  ,jk  ), zbup(ji+1,jj  ,jk  ),   &
309                  &        zbup(ji  ,jj-1,jk  ), zbup(ji  ,jj+1,jk  ),   &
310                  &        zbup(ji  ,jj  ,ikm1), zbup(ji  ,jj  ,jk+1)  )
311
312               ! search minimum in neighbourhood
313               zdo = MIN(  zbdo(ji  ,jj  ,jk  ),   &
314                  &        zbdo(ji-1,jj  ,jk  ), zbdo(ji+1,jj  ,jk  ),   &
315                  &        zbdo(ji  ,jj-1,jk  ), zbdo(ji  ,jj+1,jk  ),   &
316                  &        zbdo(ji  ,jj  ,ikm1), zbdo(ji  ,jj  ,jk+1)  )
317
318               ! positive part of the flux
319               zpos = MAX( 0., paa(ji-1,jj  ,jk  ) ) - MIN( 0., paa(ji  ,jj  ,jk  ) )   &
320                  & + MAX( 0., pbb(ji  ,jj-1,jk  ) ) - MIN( 0., pbb(ji  ,jj  ,jk  ) )   &
321                  & + MAX( 0., pcc(ji  ,jj  ,jk+1) ) - MIN( 0., pcc(ji  ,jj  ,jk  ) )
322
323               ! negative part of the flux
324               zneg = MAX( 0., paa(ji  ,jj  ,jk  ) ) - MIN( 0., paa(ji-1,jj  ,jk  ) )   &
325                  & + MAX( 0., pbb(ji  ,jj  ,jk  ) ) - MIN( 0., pbb(ji  ,jj-1,jk  ) )   &
326                  & + MAX( 0., pcc(ji  ,jj  ,jk  ) ) - MIN( 0., pcc(ji  ,jj  ,jk+1) )
327
328               ! up & down beta terms
329               zbt = e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) / z2dtt
330               zbetup(ji,jj,jk) = ( zup            - paft(ji,jj,jk) ) / ( zpos + zrtrn ) * zbt
331               zbetdo(ji,jj,jk) = ( paft(ji,jj,jk) - zdo            ) / ( zneg + zrtrn ) * zbt
332            END DO
333         END DO
334      END DO
335
336      ! lateral boundary condition on zbetup & zbetdo   (unchanged sign)
337      CALL lbc_lnk( zbetup, 'T', 1. )
338      CALL lbc_lnk( zbetdo, 'T', 1. )
339
340
341      ! 3. monotonic flux in the i & j direction (paa & pbb)
342      ! ----------------------------------------
343      DO jk = 1, jpkm1
344         DO jj = 2, jpjm1
345            DO ji = fs_2, fs_jpim1   ! vector opt.
346               zau = MIN( 1.e0, zbetdo(ji,jj,jk), zbetup(ji+1,jj,jk) )
347               zbu = MIN( 1.e0, zbetup(ji,jj,jk), zbetdo(ji+1,jj,jk) )
348               zcu =       ( 0.5  + SIGN( 0.5 , paa(ji,jj,jk) ) )
349               paa(ji,jj,jk) = paa(ji,jj,jk) * ( zcu * zau + ( 1.e0 - zcu) * zbu )
350
351               zav = MIN( 1.e0, zbetdo(ji,jj,jk), zbetup(ji,jj+1,jk) )
352               zbv = MIN( 1.e0, zbetup(ji,jj,jk), zbetdo(ji,jj+1,jk) )
353               zcv =       ( 0.5  + SIGN( 0.5 , pbb(ji,jj,jk) ) )
354               pbb(ji,jj,jk) = pbb(ji,jj,jk) * ( zcv * zav + ( 1.e0 - zcv) * zbv )
355
356      ! monotonic flux in the k direction, i.e. pcc
357      ! -------------------------------------------
358               za = MIN( 1., zbetdo(ji,jj,jk+1), zbetup(ji,jj,jk) )
359               zb = MIN( 1., zbetup(ji,jj,jk+1), zbetdo(ji,jj,jk) )
360               zc =       ( 0.5  + SIGN( 0.5 , pcc(ji,jj,jk+1) ) )
361               pcc(ji,jj,jk+1) = pcc(ji,jj,jk+1) * ( zc * za + ( 1.e0 - zc) * zb )
362            END DO
363         END DO
364      END DO
365
366      ! lateral boundary condition on paa, pbb, pcc
367      CALL lbc_lnk( paa, 'U', -1. )      ! changed sign
368      CALL lbc_lnk( pbb, 'V', -1. )      ! changed sign
369      !
370   END SUBROUTINE nonosc
371
372   !!======================================================================
373END MODULE traadv_tvd
Note: See TracBrowser for help on using the repository browser.