New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
dynhpg.F90 in branches/DEV_r2006_merge_TRA_TRC/NEMO/OPA_SRC/DYN – NEMO

source: branches/DEV_r2006_merge_TRA_TRC/NEMO/OPA_SRC/DYN/dynhpg.F90 @ 2027

Last change on this file since 2027 was 2027, checked in by cetlod, 14 years ago

Reorganisation of the initialisation phase, see ticket:695
  • Property svn:eol-style set to native
  • Property svn:keywords set to Id
File size: 52.0 KB
Line 
1MODULE dynhpg
2   !!======================================================================
3   !!                       ***  MODULE  dynhpg  ***
4   !! Ocean dynamics:  hydrostatic pressure gradient trend
5   !!======================================================================
6   !! History :  1.0  !  87-09  (P. Andrich, M.-A. Foujols)  hpg_zco: Original code
7   !!            5.0  !  91-11  (G. Madec)
8   !!            7.0  !  96-01  (G. Madec)  hpg_sco: Original code for s-coordinates
9   !!            8.0  !  97-05  (G. Madec)  split dynber into dynkeg and dynhpg
10   !!            8.5  !  02-07  (G. Madec)  F90: Free form and module
11   !!            8.5  !  02-08  (A. Bozec)  hpg_zps: Original code
12   !!            9.0  !  05-10  (A. Beckmann, B.W. An)  various s-coordinate options
13   !!                           Original code for hpg_ctl, hpg_hel hpg_wdj, hpg_djc, hpg_rot
14   !!            9.0  !  05-11  (G. Madec) style & small optimisation
15   !!----------------------------------------------------------------------
16
17   !!----------------------------------------------------------------------
18   !!   dyn_hpg      : update the momentum trend with the now horizontal
19   !!                  gradient of the hydrostatic pressure
20   !!       hpg_init : initialisation and control of options
21   !!       hpg_zco  : z-coordinate scheme
22   !!       hpg_zps  : z-coordinate plus partial steps (interpolation)
23   !!       hpg_sco  : s-coordinate (standard jacobian formulation)
24   !!       hpg_hel  : s-coordinate (helsinki modification)
25   !!       hpg_wdj  : s-coordinate (weighted density jacobian)
26   !!       hpg_djc  : s-coordinate (Density Jacobian with Cubic polynomial)
27   !!       hpg_rot  : s-coordinate (ROTated axes scheme)
28   !!----------------------------------------------------------------------
29   USE oce             ! ocean dynamics and tracers
30   USE dom_oce         ! ocean space and time domain
31   USE phycst          ! physical constants
32   USE in_out_manager  ! I/O manager
33   USE trdmod          ! ocean dynamics trends
34   USE trdmod_oce      ! ocean variables trends
35   USE prtctl          ! Print control
36   USE lbclnk          ! lateral boundary condition
37
38   IMPLICIT NONE
39   PRIVATE
40
41   PUBLIC   dyn_hpg        ! routine called by step module
42   PUBLIC       hpg_init   ! routine called by opa module
43
44   !                                              !!* Namelist namdyn_hpg : hydrostatic pressure gradient
45   LOGICAL , PUBLIC ::   ln_hpg_zco    = .TRUE.    !: z-coordinate - full steps
46   LOGICAL , PUBLIC ::   ln_hpg_zps    = .FALSE.   !: z-coordinate - partial steps (interpolation)
47   LOGICAL , PUBLIC ::   ln_hpg_sco    = .FALSE.   !: s-coordinate (standard jacobian formulation)
48   LOGICAL , PUBLIC ::   ln_hpg_hel    = .FALSE.   !: s-coordinate (helsinki modification)
49   LOGICAL , PUBLIC ::   ln_hpg_wdj    = .FALSE.   !: s-coordinate (weighted density jacobian)
50   LOGICAL , PUBLIC ::   ln_hpg_djc    = .FALSE.   !: s-coordinate (Density Jacobian with Cubic polynomial)
51   LOGICAL , PUBLIC ::   ln_hpg_rot    = .FALSE.   !: s-coordinate (ROTated axes scheme)
52   REAL(wp), PUBLIC ::   rn_gamma      = 0.e0      !: weighting coefficient
53   LOGICAL , PUBLIC ::   ln_dynhpg_imp = .FALSE.   !: semi-implicite hpg flag
54   INTEGER , PUBLIC ::   nn_dynhpg_rst = 0         !: add dynhpg implicit variables in restart ot not
55
56   INTEGER  ::   nhpg  =  0   ! = 0 to 6, type of pressure gradient scheme used ! (deduced from ln_hpg_... flags)
57
58   !! * Substitutions
59#  include "domzgr_substitute.h90"
60#  include "vectopt_loop_substitute.h90"
61   !!----------------------------------------------------------------------
62   !!   OPA 9.0 , LOCEAN-IPSL (2005)
63   !! $Id$
64   !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt)
65   !!----------------------------------------------------------------------
66
67CONTAINS
68
69   SUBROUTINE dyn_hpg( kt )
70      !!---------------------------------------------------------------------
71      !!                  ***  ROUTINE dyn_hpg  ***
72      !!
73      !! ** Method  :   Call the hydrostatic pressure gradient routine
74      !!              using the scheme defined in the namelist
75      !!   
76      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
77      !!             - Save the trend (l_trddyn=T)
78      !!----------------------------------------------------------------------
79      INTEGER, INTENT(in) ::   kt   ! ocean time-step index
80      !!
81      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   ztrdu, ztrdv   ! 3D temporary workspace
82      !!----------------------------------------------------------------------
83   
84      IF( l_trddyn ) THEN                    ! Temporary saving of ua and va trends (l_trddyn)
85         ztrdu(:,:,:) = ua(:,:,:) 
86         ztrdv(:,:,:) = va(:,:,:) 
87      ENDIF     
88
89      SELECT CASE ( nhpg )      ! Hydrastatic pressure gradient computation
90      CASE (  0 )   ;   CALL hpg_zco    ( kt )      ! z-coordinate
91      CASE (  1 )   ;   CALL hpg_zps    ( kt )      ! z-coordinate plus partial steps (interpolation)
92      CASE (  2 )   ;   CALL hpg_sco    ( kt )      ! s-coordinate (standard jacobian formulation)
93      CASE (  3 )   ;   CALL hpg_hel    ( kt )      ! s-coordinate (helsinki modification)
94      CASE (  4 )   ;   CALL hpg_wdj    ( kt )      ! s-coordinate (weighted density jacobian)
95      CASE (  5 )   ;   CALL hpg_djc    ( kt )      ! s-coordinate (Density Jacobian with Cubic polynomial)
96      CASE (  6 )   ;   CALL hpg_rot    ( kt )      ! s-coordinate (ROTated axes scheme)
97      END SELECT
98
99      IF( l_trddyn ) THEN      ! save the hydrostatic pressure gradient trends for momentum trend diagnostics
100         ztrdu(:,:,:) = ua(:,:,:) - ztrdu(:,:,:)
101         ztrdv(:,:,:) = va(:,:,:) - ztrdv(:,:,:)
102         CALL trd_mod( ztrdu, ztrdv, jpdyn_trd_hpg, 'DYN', kt )
103      ENDIF         
104      !
105      IF(ln_ctl)   CALL prt_ctl( tab3d_1=ua, clinfo1=' hpg  - Ua: ', mask1=umask,   &
106         &                       tab3d_2=va, clinfo2=       ' Va: ', mask2=vmask, clinfo3='dyn' )
107      !
108   END SUBROUTINE dyn_hpg
109
110
111   SUBROUTINE hpg_init
112      !!----------------------------------------------------------------------
113      !!                 ***  ROUTINE hpg_init  ***
114      !!
115      !! ** Purpose :   initializations for the hydrostatic pressure gradient
116      !!              computation and consistency control
117      !!
118      !! ** Action  :   Read the namelist namdyn_hpg and check the consistency
119      !!      with the type of vertical coordinate used (zco, zps, sco)
120      !!----------------------------------------------------------------------
121      INTEGER ::   ioptio = 0      ! temporary integer
122      !!
123!     NAMELIST/namdyn_hpg/ ln_hpg_zco   , ln_hpg_zps   , ln_hpg_sco, ln_hpg_hel,   &
124!        &                 ln_hpg_wdj   , ln_hpg_djc   , ln_hpg_rot, rn_gamma  ,   &
125!        &                 ln_dynhpg_imp, nn_dynhpg_rst
126      !!----------------------------------------------------------------------
127
128!     REWIND ( numnam )               ! Namelist namdyn_hpg : already read in opa.F90 module
129!     READ   ( numnam, namdyn_hpg )
130
131      IF(lwp) THEN                    ! Control print
132         WRITE(numout,*)
133         WRITE(numout,*) 'dyn_hpg : hydrostatic pressure gradient'
134         WRITE(numout,*) '~~~~~~~'
135         WRITE(numout,*) '   Namelist namdyn_hpg : choice of hpg scheme'
136         WRITE(numout,*) '      z-coord. - full steps                             ln_hpg_zco    = ', ln_hpg_zco
137         WRITE(numout,*) '      z-coord. - partial steps (interpolation)          ln_hpg_zps    = ', ln_hpg_zps
138         WRITE(numout,*) '      s-coord. (standard jacobian formulation)          ln_hpg_sco    = ', ln_hpg_sco
139         WRITE(numout,*) '      s-coord. (helsinki modification)                  ln_hpg_hel    = ', ln_hpg_hel
140         WRITE(numout,*) '      s-coord. (weighted density jacobian)              ln_hpg_wdj    = ', ln_hpg_wdj
141         WRITE(numout,*) '      s-coord. (Density Jacobian: Cubic polynomial)     ln_hpg_djc    = ', ln_hpg_djc
142         WRITE(numout,*) '      s-coord. (ROTated axes scheme)                    ln_hpg_rot    = ', ln_hpg_rot
143         WRITE(numout,*) '      weighting coeff. (wdj scheme)                     rn_gamma      = ', rn_gamma
144         WRITE(numout,*) '      time stepping: centered (F) or semi-implicit (T)  ln_dynhpg_imp = ', ln_dynhpg_imp
145         WRITE(numout,*) '      add in restart dynhpg semi-implicit variable      nn_dynhpg_rst = ', nn_dynhpg_rst
146      ENDIF
147
148      IF( .NOT. ln_dynhpg_imp )   nn_dynhpg_rst = 0      ! force no adding dynhpg implicit variables in restart
149
150      IF( lk_vvl .AND. .NOT. ln_hpg_sco )   THEN
151         CALL ctl_stop( 'hpg_ctl : variable volume key_vvl compatible only with the standard jacobian formulation hpg_sco')
152      ENDIF
153
154      !                               ! Set nhpg from ln_hpg_... flags
155      IF( ln_hpg_zco )   nhpg = 0
156      IF( ln_hpg_zps )   nhpg = 1
157      IF( ln_hpg_sco )   nhpg = 2
158      IF( ln_hpg_hel )   nhpg = 3
159      IF( ln_hpg_wdj )   nhpg = 4
160      IF( ln_hpg_djc )   nhpg = 5
161      IF( ln_hpg_rot )   nhpg = 6
162
163      !                               ! Consitency check
164      ioptio = 0 
165      IF( ln_hpg_zco )   ioptio = ioptio + 1
166      IF( ln_hpg_zps )   ioptio = ioptio + 1
167      IF( ln_hpg_sco )   ioptio = ioptio + 1
168      IF( ln_hpg_hel )   ioptio = ioptio + 1
169      IF( ln_hpg_wdj )   ioptio = ioptio + 1
170      IF( ln_hpg_djc )   ioptio = ioptio + 1
171      IF( ln_hpg_rot )   ioptio = ioptio + 1
172      IF ( ioptio /= 1 )   CALL ctl_stop( ' NO or several hydrostatic pressure gradient options used' )
173
174      !
175   END SUBROUTINE hpg_init
176
177
178   SUBROUTINE hpg_zco( kt )
179      !!---------------------------------------------------------------------
180      !!                  ***  ROUTINE hpg_zco  ***
181      !!
182      !! ** Method  :   z-coordinate case, levels are horizontal surfaces.
183      !!      The now hydrostatic pressure gradient at a given level, jk,
184      !!      is computed by taking the vertical integral of the in-situ
185      !!      density gradient along the model level from the suface to that
186      !!      level:    zhpi = grav .....
187      !!                zhpj = grav .....
188      !!      add it to the general momentum trend (ua,va).
189      !!            ua = ua - 1/e1u * zhpi
190      !!            va = va - 1/e2v * zhpj
191      !!
192      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
193      !!----------------------------------------------------------------------
194      USE oce, ONLY :   zhpi => ta   ! use ta as 3D workspace
195      USE oce, ONLY :   zhpj => sa   ! use sa as 3D workspace
196      !!
197      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
198      !!
199      INTEGER  ::   ji, jj, jk       ! dummy loop indices
200      REAL(wp) ::   zcoef0, zcoef1   ! temporary scalars
201      !!----------------------------------------------------------------------
202     
203      IF( kt == nit000 ) THEN
204         IF(lwp) WRITE(numout,*)
205         IF(lwp) WRITE(numout,*) 'dyn:hpg_zco : hydrostatic pressure gradient trend'
206         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   z-coordinate case '
207      ENDIF
208     
209      ! Local constant initialization
210      zcoef0 = - grav * 0.5
211
212      ! Surface value
213      DO jj = 2, jpjm1
214         DO ji = fs_2, fs_jpim1   ! vector opt.
215            zcoef1 = zcoef0 * fse3w(ji,jj,1)
216            ! hydrostatic pressure gradient
217            zhpi(ji,jj,1) = zcoef1 * ( rhd(ji+1,jj,1) - rhd(ji,jj,1) ) / e1u(ji,jj)
218            zhpj(ji,jj,1) = zcoef1 * ( rhd(ji,jj+1,1) - rhd(ji,jj,1) ) / e2v(ji,jj)
219            ! add to the general momentum trend
220            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
221            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
222         END DO
223      END DO
224      !
225      ! interior value (2=<jk=<jpkm1)
226      DO jk = 2, jpkm1
227         DO jj = 2, jpjm1
228            DO ji = fs_2, fs_jpim1   ! vector opt.
229               zcoef1 = zcoef0 * fse3w(ji,jj,jk)
230               ! hydrostatic pressure gradient
231               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)   &
232                  &           + zcoef1 * (  ( rhd(ji+1,jj,jk)+rhd(ji+1,jj,jk-1) )   &
233                  &                       - ( rhd(ji  ,jj,jk)+rhd(ji  ,jj,jk-1) )  ) / e1u(ji,jj)
234
235               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)   &
236                  &           + zcoef1 * (  ( rhd(ji,jj+1,jk)+rhd(ji,jj+1,jk-1) )   &
237                  &                       - ( rhd(ji,jj,  jk)+rhd(ji,jj  ,jk-1) )  ) / e2v(ji,jj)
238               ! add to the general momentum trend
239               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
240               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
241            END DO
242         END DO
243      END DO
244      !
245   END SUBROUTINE hpg_zco
246
247
248   SUBROUTINE hpg_zps( kt )
249      !!---------------------------------------------------------------------
250      !!                 ***  ROUTINE hpg_zps  ***
251      !!                   
252      !! ** Method  :   z-coordinate plus partial steps case.  blahblah...
253      !!
254      !! ** Action  : - Update (ua,va) with the now hydrastatic pressure trend
255      !!----------------------------------------------------------------------
256      USE oce, ONLY :   zhpi => ta   ! use ta as 3D workspace
257      USE oce, ONLY :   zhpj => sa   ! use sa as 3D workspace
258      !!
259      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
260      !!
261      INTEGER  ::   ji, jj, jk                       ! dummy loop indices
262      INTEGER  ::   iku, ikv                         ! temporary integers
263      REAL(wp) ::   zcoef0, zcoef1, zcoef2, zcoef3   ! temporary scalars
264      !!----------------------------------------------------------------------
265
266      IF( kt == nit000 ) THEN
267         IF(lwp) WRITE(numout,*)
268         IF(lwp) WRITE(numout,*) 'dyn:hpg_zps : hydrostatic pressure gradient trend'
269         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   z-coordinate with partial steps - vector optimization'
270      ENDIF
271
272      ! Local constant initialization
273      zcoef0 = - grav * 0.5
274
275      !  Surface value
276      DO jj = 2, jpjm1
277         DO ji = fs_2, fs_jpim1   ! vector opt.
278            zcoef1 = zcoef0 * fse3w(ji,jj,1)
279            ! hydrostatic pressure gradient
280            zhpi(ji,jj,1) = zcoef1 * ( rhd(ji+1,jj  ,1) - rhd(ji,jj,1) ) / e1u(ji,jj)
281            zhpj(ji,jj,1) = zcoef1 * ( rhd(ji  ,jj+1,1) - rhd(ji,jj,1) ) / e2v(ji,jj)
282            ! add to the general momentum trend
283            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
284            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
285         END DO
286      END DO
287
288      ! interior value (2=<jk=<jpkm1)
289      DO jk = 2, jpkm1
290         DO jj = 2, jpjm1
291            DO ji = fs_2, fs_jpim1   ! vector opt.
292               zcoef1 = zcoef0 * fse3w(ji,jj,jk)
293               ! hydrostatic pressure gradient
294               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)   &
295                  &           + zcoef1 * (  ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) )   &
296                  &                       - ( rhd(ji  ,jj,jk) + rhd(ji  ,jj,jk-1) )  ) / e1u(ji,jj)
297
298               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)   &
299                  &           + zcoef1 * (  ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) )   &
300                  &                       - ( rhd(ji,jj,  jk) + rhd(ji,jj  ,jk-1) )  ) / e2v(ji,jj)
301               ! add to the general momentum trend
302               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
303               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
304            END DO
305         END DO
306      END DO
307
308      ! partial steps correction at the last level  (new gradient with  intgrd.F)
309# if defined key_vectopt_loop
310         jj = 1
311         DO ji = jpi+2, jpij-jpi-1   ! vector opt. (forced unrolling)
312# else
313      DO jj = 2, jpjm1
314         DO ji = 2, jpim1
315# endif
316            iku = MIN ( mbathy(ji,jj), mbathy(ji+1,jj) ) - 1
317            ikv = MIN ( mbathy(ji,jj), mbathy(ji,jj+1) ) - 1
318            zcoef2 = zcoef0 * MIN( fse3w(ji,jj,iku), fse3w(ji+1,jj  ,iku) )
319            zcoef3 = zcoef0 * MIN( fse3w(ji,jj,ikv), fse3w(ji  ,jj+1,ikv) )
320            ! on i-direction
321            IF ( iku > 2 ) THEN
322               ! subtract old value
323               ua(ji,jj,iku) = ua(ji,jj,iku) - zhpi(ji,jj,iku)
324               ! compute the new one
325               zhpi (ji,jj,iku) = zhpi(ji,jj,iku-1)   &
326                  + zcoef2 * ( rhd(ji+1,jj,iku-1) - rhd(ji,jj,iku-1) + gru(ji,jj) ) / e1u(ji,jj)
327               ! add the new one to the general momentum trend
328               ua(ji,jj,iku) = ua(ji,jj,iku) + zhpi(ji,jj,iku)
329            ENDIF
330            ! on j-direction
331            IF ( ikv > 2 ) THEN
332               ! subtract old value
333               va(ji,jj,ikv) = va(ji,jj,ikv) - zhpj(ji,jj,ikv)
334               ! compute the new one
335               zhpj (ji,jj,ikv) = zhpj(ji,jj,ikv-1)   &
336                  + zcoef3 * ( rhd(ji,jj+1,ikv-1) - rhd(ji,jj,ikv-1) + grv(ji,jj) ) / e2v(ji,jj)
337               ! add the new one to the general momentum trend
338               va(ji,jj,ikv) = va(ji,jj,ikv) + zhpj(ji,jj,ikv)
339            ENDIF
340# if ! defined key_vectopt_loop
341         END DO
342# endif
343      END DO
344      !
345   END SUBROUTINE hpg_zps
346
347
348   SUBROUTINE hpg_sco( kt )
349      !!---------------------------------------------------------------------
350      !!                  ***  ROUTINE hpg_sco  ***
351      !!
352      !! ** Method  :   s-coordinate case. Jacobian scheme.
353      !!      The now hydrostatic pressure gradient at a given level, jk,
354      !!      is computed by taking the vertical integral of the in-situ
355      !!      density gradient along the model level from the suface to that
356      !!      level. s-coordinates (ln_sco): a corrective term is added
357      !!      to the horizontal pressure gradient :
358      !!         zhpi = grav .....  + 1/e1u mi(rhd) di[ grav dep3w ]
359      !!         zhpj = grav .....  + 1/e2v mj(rhd) dj[ grav dep3w ]
360      !!      add it to the general momentum trend (ua,va).
361      !!         ua = ua - 1/e1u * zhpi
362      !!         va = va - 1/e2v * zhpj
363      !!
364      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
365      !!----------------------------------------------------------------------
366      USE oce, ONLY :   zhpi => ta   ! use ta as 3D workspace
367      USE oce, ONLY :   zhpj => sa   ! use sa as 3D workspace
368      !!
369      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
370      !!
371      INTEGER  ::   ji, jj, jk                 ! dummy loop indices
372      REAL(wp) ::   zcoef0, zuap, zvap, znad   ! temporary scalars
373      !!----------------------------------------------------------------------
374
375      IF( kt == nit000 ) THEN
376         IF(lwp) WRITE(numout,*)
377         IF(lwp) WRITE(numout,*) 'dyn:hpg_sco : hydrostatic pressure gradient trend'
378         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, OPA original scheme used'
379      ENDIF
380
381      ! Local constant initialization
382      zcoef0 = - grav * 0.5
383      ! To use density and not density anomaly
384      IF ( lk_vvl ) THEN   ;     znad = 1.            ! Variable volume
385      ELSE                 ;     znad = 0.e0          ! Fixed volume
386      ENDIF
387
388      ! Surface value
389      DO jj = 2, jpjm1
390         DO ji = fs_2, fs_jpim1   ! vector opt.   
391            ! hydrostatic pressure gradient along s-surfaces
392            zhpi(ji,jj,1) = zcoef0 / e1u(ji,jj) * ( fse3w(ji+1,jj  ,1) * ( znad + rhd(ji+1,jj  ,1) )   &
393               &                                  - fse3w(ji  ,jj  ,1) * ( znad + rhd(ji  ,jj  ,1) ) )
394            zhpj(ji,jj,1) = zcoef0 / e2v(ji,jj) * ( fse3w(ji  ,jj+1,1) * ( znad + rhd(ji  ,jj+1,1) )   &
395               &                                  - fse3w(ji  ,jj  ,1) * ( znad + rhd(ji  ,jj  ,1) ) )
396            ! s-coordinate pressure gradient correction
397            zuap = -zcoef0 * ( rhd   (ji+1,jj,1) + rhd   (ji,jj,1) + 2*znad )   &
398               &           * ( fsde3w(ji+1,jj,1) - fsde3w(ji,jj,1) ) / e1u(ji,jj)
399            zvap = -zcoef0 * ( rhd   (ji,jj+1,1) + rhd   (ji,jj,1) + 2*znad )   &
400               &           * ( fsde3w(ji,jj+1,1) - fsde3w(ji,jj,1) ) / e2v(ji,jj)
401            ! add to the general momentum trend
402            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1) + zuap
403            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1) + zvap
404         END DO 
405      END DO   
406           
407      ! interior value (2=<jk=<jpkm1)
408      DO jk = 2, jpkm1                                 
409         DO jj = 2, jpjm1     
410            DO ji = fs_2, fs_jpim1   ! vector opt.     
411               ! hydrostatic pressure gradient along s-surfaces
412               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) + zcoef0 / e1u(ji,jj)   & 
413                  &           * (  fse3w(ji+1,jj,jk) * ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) + 2*znad )   & 
414                  &              - fse3w(ji  ,jj,jk) * ( rhd(ji  ,jj,jk) + rhd(ji  ,jj,jk-1) + 2*znad )  )
415               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) + zcoef0 / e2v(ji,jj)   &
416                  &           * (  fse3w(ji,jj+1,jk) * ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) + 2*znad )   &
417                  &              - fse3w(ji,jj  ,jk) * ( rhd(ji,jj,  jk) + rhd(ji,jj  ,jk-1) + 2*znad )  )
418               ! s-coordinate pressure gradient correction
419               zuap = -zcoef0 * ( rhd   (ji+1,jj  ,jk) + rhd   (ji,jj,jk) + 2*znad )   &
420                  &           * ( fsde3w(ji+1,jj  ,jk) - fsde3w(ji,jj,jk) ) / e1u(ji,jj)
421               zvap = -zcoef0 * ( rhd   (ji  ,jj+1,jk) + rhd   (ji,jj,jk) + 2*znad )   &
422                  &           * ( fsde3w(ji  ,jj+1,jk) - fsde3w(ji,jj,jk) ) / e2v(ji,jj)
423               ! add to the general momentum trend
424               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk) + zuap
425               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk) + zvap
426            END DO
427         END DO
428      END DO
429      !
430   END SUBROUTINE hpg_sco
431
432
433   SUBROUTINE hpg_hel( kt )
434      !!---------------------------------------------------------------------
435      !!                  ***  ROUTINE hpg_hel  ***
436      !!
437      !! ** Method  :   s-coordinate case.
438      !!      The now hydrostatic pressure gradient at a given level
439      !!      jk is computed by taking the vertical integral of the in-situ
440      !!      density gradient along the model level from the suface to that
441      !!      level. s-coordinates (ln_sco): a corrective term is added
442      !!      to the horizontal pressure gradient :
443      !!         zhpi = grav .....  + 1/e1u mi(rhd) di[ grav dep3w ]
444      !!         zhpj = grav .....  + 1/e2v mj(rhd) dj[ grav dep3w ]
445      !!      add it to the general momentum trend (ua,va).
446      !!         ua = ua - 1/e1u * zhpi
447      !!         va = va - 1/e2v * zhpj
448      !!
449      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
450      !!             - Save the trend (l_trddyn=T)
451      !!----------------------------------------------------------------------
452      USE oce, ONLY :   zhpi => ta   ! use ta as 3D workspace
453      USE oce, ONLY :   zhpj => sa   ! use sa as 3D workspace
454      !!
455      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
456      !!
457      INTEGER  ::   ji, jj, jk           ! dummy loop indices
458      REAL(wp) ::   zcoef0, zuap, zvap   ! temporary scalars
459      !!----------------------------------------------------------------------
460
461      IF( kt == nit000 ) THEN
462         IF(lwp) WRITE(numout,*)
463         IF(lwp) WRITE(numout,*) 'dyn:hpg_hel : hydrostatic pressure gradient trend'
464         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, helsinki modified scheme'
465      ENDIF
466
467      ! Local constant initialization
468      zcoef0 = - grav * 0.5
469 
470      ! Surface value
471      DO jj = 2, jpjm1
472         DO ji = fs_2, fs_jpim1   ! vector opt.
473            ! hydrostatic pressure gradient along s-surfaces
474            zhpi(ji,jj,1) = zcoef0 / e1u(ji,jj) * ( fse3t(ji+1,jj  ,1) * rhd(ji+1,jj  ,1)  &
475               &                                  - fse3t(ji  ,jj  ,1) * rhd(ji  ,jj  ,1) )
476            zhpj(ji,jj,1) = zcoef0 / e2v(ji,jj) * ( fse3t(ji  ,jj+1,1) * rhd(ji  ,jj+1,1)  &
477               &                                  - fse3t(ji  ,jj  ,1) * rhd(ji  ,jj  ,1) )
478            ! s-coordinate pressure gradient correction
479            zuap = -zcoef0 * ( rhd   (ji+1,jj,1) + rhd   (ji,jj,1) )   &
480               &           * ( fsdept(ji+1,jj,1) - fsdept(ji,jj,1) ) / e1u(ji,jj)
481            zvap = -zcoef0 * ( rhd   (ji,jj+1,1) + rhd   (ji,jj,1) )   &
482               &           * ( fsdept(ji,jj+1,1) - fsdept(ji,jj,1) ) / e2v(ji,jj)
483            ! add to the general momentum trend
484            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1) + zuap
485            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1) + zvap
486         END DO
487      END DO
488      !
489      ! interior value (2=<jk=<jpkm1)
490      DO jk = 2, jpkm1
491         DO jj = 2, jpjm1
492            DO ji = fs_2, fs_jpim1   ! vector opt.
493               ! hydrostatic pressure gradient along s-surfaces
494               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) &
495                  &           +  zcoef0 / e1u(ji,jj) * ( fse3t(ji+1,jj,jk  ) * rhd(ji+1,jj,jk)     &
496                  &                                     -fse3t(ji  ,jj,jk  ) * rhd(ji  ,jj,jk)   ) &
497                  &           +  zcoef0 / e1u(ji,jj) * ( fse3t(ji+1,jj,jk-1) * rhd(ji+1,jj,jk-1)   &
498                  &                                     -fse3t(ji  ,jj,jk-1) * rhd(ji  ,jj,jk-1) )
499               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) &
500                  &           +  zcoef0 / e2v(ji,jj) * ( fse3t(ji,jj+1,jk  ) * rhd(ji,jj+1,jk)   &
501                  &                                     -fse3t(ji,jj  ,jk  ) * rhd(ji,jj,  jk)   ) &
502                  &           +  zcoef0 / e2v(ji,jj) * ( fse3t(ji,jj+1,jk-1) * rhd(ji,jj+1,jk-1) &
503                  &                                     -fse3t(ji,jj  ,jk-1) * rhd(ji,jj,  jk-1) )
504               ! s-coordinate pressure gradient correction
505               zuap = - zcoef0 * ( rhd   (ji+1,jj,jk) + rhd   (ji,jj,jk) )   &
506                  &            * ( fsdept(ji+1,jj,jk) - fsdept(ji,jj,jk) ) / e1u(ji,jj)
507               zvap = - zcoef0 * ( rhd   (ji,jj+1,jk) + rhd   (ji,jj,jk) )   &
508                  &            * ( fsdept(ji,jj+1,jk) - fsdept(ji,jj,jk) ) / e2v(ji,jj)
509               ! add to the general momentum trend
510               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk) + zuap
511               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk) + zvap
512            END DO
513         END DO
514      END DO
515      !
516   END SUBROUTINE hpg_hel
517
518
519   SUBROUTINE hpg_wdj( kt )
520      !!---------------------------------------------------------------------
521      !!                  ***  ROUTINE hpg_wdj  ***
522      !!
523      !! ** Method  :   Weighted Density Jacobian (wdj) scheme (song 1998)
524      !!      The weighting coefficients from the namelist parameter rn_gamma
525      !!      (alpha=0.5-rn_gamma ; beta=1-alpha=0.5+rn_gamma
526      !!
527      !! Reference : Song, Mon. Wea. Rev., 126, 3213-3230, 1998.
528      !!----------------------------------------------------------------------
529      USE oce, ONLY :   zhpi => ta   ! use ta as 3D workspace
530      USE oce, ONLY :   zhpj => sa   ! use sa as 3D workspace
531      !!
532      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
533      !!
534      INTEGER  ::   ji, jj, jk           ! dummy loop indices
535      REAL(wp) ::   zcoef0, zuap, zvap   ! temporary scalars
536      REAL(wp) ::   zalph , zbeta        !    "         "
537      !!----------------------------------------------------------------------
538
539      IF( kt == nit000 ) THEN
540         IF(lwp) WRITE(numout,*)
541         IF(lwp) WRITE(numout,*) 'dyn:hpg_wdj : hydrostatic pressure gradient trend'
542         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   Weighted Density Jacobian'
543      ENDIF
544
545      ! Local constant initialization
546      zcoef0 = - grav * 0.5
547      zalph  = 0.5 - rn_gamma    ! weighting coefficients (alpha=0.5-rn_gamma
548      zbeta  = 0.5 + rn_gamma    !                        (beta =1-alpha=0.5+rn_gamma
549
550      ! Surface value (no ponderation)
551      DO jj = 2, jpjm1
552         DO ji = fs_2, fs_jpim1   ! vector opt.
553            ! hydrostatic pressure gradient along s-surfaces
554            zhpi(ji,jj,1) = zcoef0 / e1u(ji,jj) * (  fse3w(ji+1,jj  ,1) * rhd(ji+1,jj  ,1)   &
555               &                                   - fse3w(ji  ,jj  ,1) * rhd(ji  ,jj  ,1)  )
556            zhpj(ji,jj,1) = zcoef0 / e2v(ji,jj) * (  fse3w(ji  ,jj+1,1) * rhd(ji  ,jj+1,1)   &
557               &                                   - fse3w(ji  ,jj  ,1) * rhd(ji,  jj  ,1)  )
558            ! s-coordinate pressure gradient correction
559            zuap = -zcoef0 * ( rhd   (ji+1,jj,1) + rhd   (ji,jj,1) )   &
560               &           * ( fsde3w(ji+1,jj,1) - fsde3w(ji,jj,1) ) / e1u(ji,jj)
561            zvap = -zcoef0 * ( rhd   (ji,jj+1,1) + rhd   (ji,jj,1) )   &
562               &           * ( fsde3w(ji,jj+1,1) - fsde3w(ji,jj,1) ) / e2v(ji,jj)
563            ! add to the general momentum trend
564            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1) + zuap
565            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1) + zvap
566         END DO
567      END DO
568
569      ! Interior value (2=<jk=<jpkm1) (weighted with zalph & zbeta)
570      DO jk = 2, jpkm1
571         DO jj = 2, jpjm1
572            DO ji = fs_2, fs_jpim1   ! vector opt.
573               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) + zcoef0 / e1u(ji,jj)                            &
574                  &           * (   (            fsde3w(ji+1,jj,jk  ) + fsde3w(ji,jj,jk  )        &
575                  &                            - fsde3w(ji+1,jj,jk-1) - fsde3w(ji,jj,jk-1)    )   &
576                  &               * (  zalph * ( rhd   (ji+1,jj,jk-1) - rhd   (ji,jj,jk-1) )      &
577                  &                  + zbeta * ( rhd   (ji+1,jj,jk  ) - rhd   (ji,jj,jk  ) )  )   &
578                  &             -   (            rhd   (ji+1,jj,jk  ) + rhd   (ji,jj,jk  )        &
579                  &                           - rhd   (ji+1,jj,jk-1) - rhd   (ji,jj,jk-1)     )   &
580                  &               * (  zalph * ( fsde3w(ji+1,jj,jk-1) - fsde3w(ji,jj,jk-1) )      &
581                  &                  + zbeta * ( fsde3w(ji+1,jj,jk  ) - fsde3w(ji,jj,jk  ) )  )  )
582               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) + zcoef0 / e2v(ji,jj)                            &
583                  &           * (   (           fsde3w(ji,jj+1,jk  ) + fsde3w(ji,jj,jk  )         &
584                  &                           - fsde3w(ji,jj+1,jk-1) - fsde3w(ji,jj,jk-1)     )   &
585                  &               * (  zalph * ( rhd   (ji,jj+1,jk-1) - rhd   (ji,jj,jk-1) )      &
586                  &                  + zbeta * ( rhd   (ji,jj+1,jk  ) - rhd   (ji,jj,jk  ) )  )   &
587                  &             -   (            rhd   (ji,jj+1,jk  ) + rhd   (ji,jj,jk  )        &
588                  &                            - rhd   (ji,jj+1,jk-1) - rhd   (ji,jj,jk-1)    )   &
589                  &               * (  zalph * ( fsde3w(ji,jj+1,jk-1) - fsde3w(ji,jj,jk-1) )      &
590                  &                  + zbeta * ( fsde3w(ji,jj+1,jk  ) - fsde3w(ji,jj,jk  ) )  )  )
591               ! add to the general momentum trend
592               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
593               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
594            END DO
595         END DO
596      END DO
597      !
598   END SUBROUTINE hpg_wdj
599
600
601   SUBROUTINE hpg_djc( kt )
602      !!---------------------------------------------------------------------
603      !!                  ***  ROUTINE hpg_djc  ***
604      !!
605      !! ** Method  :   Density Jacobian with Cubic polynomial scheme
606      !!
607      !! Reference: Shchepetkin and McWilliams, J. Geophys. Res., 108(C3), 3090, 2003
608      !!----------------------------------------------------------------------
609      USE oce, ONLY :   zhpi => ta   ! use ta as 3D workspace
610      USE oce, ONLY :   zhpj => sa   ! use sa as 3D workspace
611      !!
612      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
613      !!
614      INTEGER  ::   ji, jj, jk          ! dummy loop indices
615      REAL(wp) ::   zcoef0, zep, cffw   ! temporary scalars
616      REAL(wp) ::   z1_10, cffu, cffx   !    "         "
617      REAL(wp) ::   z1_12, cffv, cffy   !    "         "
618      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   drhox, dzx, drhou, dzu, rho_i   ! 3D workspace
619      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   drhoy, dzy, drhov, dzv, rho_j   !  "      "
620      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   drhoz, dzz, drhow, dzw, rho_k   !  "      "
621      !!----------------------------------------------------------------------
622
623      IF( kt == nit000 ) THEN
624         IF(lwp) WRITE(numout,*)
625         IF(lwp) WRITE(numout,*) 'dyn:hpg_djc : hydrostatic pressure gradient trend'
626         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, density Jacobian with cubic polynomial scheme'
627      ENDIF
628
629
630      ! Local constant initialization
631      zcoef0 = - grav * 0.5
632      z1_10  = 1.0 / 10.0
633      z1_12  = 1.0 / 12.0
634
635      !----------------------------------------------------------------------------------------
636      !  compute and store in provisional arrays elementary vertical and horizontal differences
637      !----------------------------------------------------------------------------------------
638
639!!bug gm   Not a true bug, but... dzz=e3w  for dzx, dzy verify what it is really
640
641      DO jk = 2, jpkm1
642         DO jj = 2, jpjm1
643            DO ji = fs_2, fs_jpim1   ! vector opt.
644               drhoz(ji,jj,jk) = rhd   (ji  ,jj  ,jk) - rhd   (ji,jj,jk-1)
645               dzz  (ji,jj,jk) = fsde3w(ji  ,jj  ,jk) - fsde3w(ji,jj,jk-1)
646               drhox(ji,jj,jk) = rhd   (ji+1,jj  ,jk) - rhd   (ji,jj,jk  )
647               dzx  (ji,jj,jk) = fsde3w(ji+1,jj  ,jk) - fsde3w(ji,jj,jk  )
648               drhoy(ji,jj,jk) = rhd   (ji  ,jj+1,jk) - rhd   (ji,jj,jk  )
649               dzy  (ji,jj,jk) = fsde3w(ji  ,jj+1,jk) - fsde3w(ji,jj,jk  )
650            END DO
651         END DO
652      END DO
653
654      !-------------------------------------------------------------------------
655      ! compute harmonic averages using eq. 5.18
656      !-------------------------------------------------------------------------
657      zep = 1.e-15
658
659!!bug  gm  drhoz not defined at level 1 and used (jk-1 with jk=2)
660!!bug  gm  idem for drhox, drhoy et ji=jpi and jj=jpj
661
662      DO jk = 2, jpkm1
663         DO jj = 2, jpjm1
664            DO ji = fs_2, fs_jpim1   ! vector opt.
665               cffw = 2.0 * drhoz(ji  ,jj  ,jk) * drhoz(ji,jj,jk-1)
666
667               cffu = 2.0 * drhox(ji+1,jj  ,jk) * drhox(ji,jj,jk  )
668               cffx = 2.0 * dzx  (ji+1,jj  ,jk) * dzx  (ji,jj,jk  )
669 
670               cffv = 2.0 * drhoy(ji  ,jj+1,jk) * drhoy(ji,jj,jk  )
671               cffy = 2.0 * dzy  (ji  ,jj+1,jk) * dzy  (ji,jj,jk  )
672
673               IF( cffw > zep) THEN
674                  drhow(ji,jj,jk) = 2.0 *   drhoz(ji,jj,jk) * drhoz(ji,jj,jk-1)   &
675                     &                  / ( drhoz(ji,jj,jk) + drhoz(ji,jj,jk-1) )
676               ELSE
677                  drhow(ji,jj,jk) = 0.e0
678               ENDIF
679
680               dzw(ji,jj,jk) = 2.0 *   dzz(ji,jj,jk) * dzz(ji,jj,jk-1)   &
681                  &                / ( dzz(ji,jj,jk) + dzz(ji,jj,jk-1) )
682
683               IF( cffu > zep ) THEN
684                  drhou(ji,jj,jk) = 2.0 *   drhox(ji+1,jj,jk) * drhox(ji,jj,jk)   &
685                     &                  / ( drhox(ji+1,jj,jk) + drhox(ji,jj,jk) )
686               ELSE
687                  drhou(ji,jj,jk ) = 0.e0
688               ENDIF
689
690               IF( cffx > zep ) THEN
691                  dzu(ji,jj,jk) = 2.0*dzx(ji+1,jj,jk)*dzx(ji,jj,jk)   &
692                     &            /(dzx(ji+1,jj,jk)+dzx(ji,jj,jk))
693               ELSE
694                  dzu(ji,jj,jk) = 0.e0
695               ENDIF
696
697               IF( cffv > zep ) THEN
698                  drhov(ji,jj,jk) = 2.0 *   drhoy(ji,jj+1,jk) * drhoy(ji,jj,jk)   &
699                     &                  / ( drhoy(ji,jj+1,jk) + drhoy(ji,jj,jk) )
700               ELSE
701                  drhov(ji,jj,jk) = 0.e0
702               ENDIF
703
704               IF( cffy > zep ) THEN
705                  dzv(ji,jj,jk) = 2.0 *   dzy(ji,jj+1,jk) * dzy(ji,jj,jk)   &
706                     &                / ( dzy(ji,jj+1,jk) + dzy(ji,jj,jk) )
707               ELSE
708                  dzv(ji,jj,jk) = 0.e0
709               ENDIF
710
711            END DO
712         END DO
713      END DO
714
715      !----------------------------------------------------------------------------------
716      ! apply boundary conditions at top and bottom using 5.36-5.37
717      !----------------------------------------------------------------------------------
718      drhow(:,:, 1 ) = 1.5 * ( drhoz(:,:, 2 ) - drhoz(:,:,  1  ) ) - 0.5 * drhow(:,:,  2  )
719      drhou(:,:, 1 ) = 1.5 * ( drhox(:,:, 2 ) - drhox(:,:,  1  ) ) - 0.5 * drhou(:,:,  2  )
720      drhov(:,:, 1 ) = 1.5 * ( drhoy(:,:, 2 ) - drhoy(:,:,  1  ) ) - 0.5 * drhov(:,:,  2  )
721
722      drhow(:,:,jpk) = 1.5 * ( drhoz(:,:,jpk) - drhoz(:,:,jpkm1) ) - 0.5 * drhow(:,:,jpkm1)
723      drhou(:,:,jpk) = 1.5 * ( drhox(:,:,jpk) - drhox(:,:,jpkm1) ) - 0.5 * drhou(:,:,jpkm1)
724      drhov(:,:,jpk) = 1.5 * ( drhoy(:,:,jpk) - drhoy(:,:,jpkm1) ) - 0.5 * drhov(:,:,jpkm1)
725
726
727      !--------------------------------------------------------------
728      ! Upper half of top-most grid box, compute and store
729      !-------------------------------------------------------------
730
731!!bug gm   :  e3w-de3w = 0.5*e3w  ....  and de3w(2)-de3w(1)=e3w(2) ....   to be verified
732!          true if de3w is really defined as the sum of the e3w scale factors as, it seems to me, it should be
733
734      DO jj = 2, jpjm1
735         DO ji = fs_2, fs_jpim1   ! vector opt.
736            rho_k(ji,jj,1) = -grav * ( fse3w(ji,jj,1) - fsde3w(ji,jj,1) )            &
737               &                   * (  rhd(ji,jj,1)                                 &
738               &                     + 0.5 * ( rhd(ji,jj,2) - rhd(ji,jj,1) )         &
739               &                           * ( fse3w (ji,jj,1) - fsde3w(ji,jj,1) )   &
740               &                           / ( fsde3w(ji,jj,2) - fsde3w(ji,jj,1) )  ) 
741         END DO
742      END DO
743
744!!bug gm    : here also, simplification is possible
745!!bug gm    : optimisation: 1/10 and 1/12 the division should be done before the loop
746
747      DO jk = 2, jpkm1
748         DO jj = 2, jpjm1
749            DO ji = fs_2, fs_jpim1   ! vector opt.
750
751               rho_k(ji,jj,jk) = zcoef0 * ( rhd   (ji,jj,jk) + rhd   (ji,jj,jk-1) )                                   &
752                  &                     * ( fsde3w(ji,jj,jk) - fsde3w(ji,jj,jk-1) )                                   &
753                  &            - grav * z1_10 * (                                                                     &
754                  &     ( drhow (ji,jj,jk) - drhow (ji,jj,jk-1) )                                                     &
755                  &   * ( fsde3w(ji,jj,jk) - fsde3w(ji,jj,jk-1) - z1_12 * ( dzw  (ji,jj,jk) + dzw  (ji,jj,jk-1) ) )   &
756                  &   - ( dzw   (ji,jj,jk) - dzw   (ji,jj,jk-1) )                                                     &
757                  &   * ( rhd   (ji,jj,jk) - rhd   (ji,jj,jk-1) - z1_12 * ( drhow(ji,jj,jk) + drhow(ji,jj,jk-1) ) )   &
758                  &                             )
759
760               rho_i(ji,jj,jk) = zcoef0 * ( rhd   (ji+1,jj,jk) + rhd   (ji,jj,jk) )                                   &
761                  &                     * ( fsde3w(ji+1,jj,jk) - fsde3w(ji,jj,jk) )                                   &
762                  &            - grav* z1_10 * (                                                                      &
763                  &     ( drhou (ji+1,jj,jk) - drhou (ji,jj,jk) )                                                     &
764                  &   * ( fsde3w(ji+1,jj,jk) - fsde3w(ji,jj,jk) - z1_12 * ( dzu  (ji+1,jj,jk) + dzu  (ji,jj,jk) ) )   &
765                  &   - ( dzu   (ji+1,jj,jk) - dzu   (ji,jj,jk) )                                                     &
766                  &   * ( rhd   (ji+1,jj,jk) - rhd   (ji,jj,jk) - z1_12 * ( drhou(ji+1,jj,jk) + drhou(ji,jj,jk) ) )   &
767                  &                            )
768
769               rho_j(ji,jj,jk) = zcoef0 * ( rhd   (ji,jj+1,jk) + rhd   (ji,jj,jk) )                                   &
770                  &                     * ( fsde3w(ji,jj+1,jk) - fsde3w(ji,jj,jk) )                                   &
771                  &            - grav* z1_10 * (                                                                      &
772                  &     ( drhov (ji,jj+1,jk) - drhov (ji,jj,jk) )                                                     &
773                  &   * ( fsde3w(ji,jj+1,jk) - fsde3w(ji,jj,jk) - z1_12 * ( dzv  (ji,jj+1,jk) + dzv  (ji,jj,jk) ) )   &
774                  &   - ( dzv   (ji,jj+1,jk) - dzv   (ji,jj,jk) )                                                     &
775                  &   * ( rhd   (ji,jj+1,jk) - rhd   (ji,jj,jk) - z1_12 * ( drhov(ji,jj+1,jk) + drhov(ji,jj,jk) ) )   &
776                  &                            )
777
778            END DO
779         END DO
780      END DO
781      CALL lbc_lnk(rho_k,'W',1.)
782      CALL lbc_lnk(rho_i,'U',1.)
783      CALL lbc_lnk(rho_j,'V',1.)
784
785
786      ! ---------------
787      !  Surface value
788      ! ---------------
789      DO jj = 2, jpjm1
790         DO ji = fs_2, fs_jpim1   ! vector opt.
791            zhpi(ji,jj,1) = ( rho_k(ji+1,jj  ,1) - rho_k(ji,jj,1) - rho_i(ji,jj,1) ) / e1u(ji,jj)
792            zhpj(ji,jj,1) = ( rho_k(ji  ,jj+1,1) - rho_k(ji,jj,1) - rho_j(ji,jj,1) ) / e2v(ji,jj)
793            ! add to the general momentum trend
794            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
795            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
796         END DO
797      END DO
798
799      ! ----------------
800      !  interior value   (2=<jk=<jpkm1)
801      ! ----------------
802      DO jk = 2, jpkm1
803         DO jj = 2, jpjm1 
804            DO ji = fs_2, fs_jpim1   ! vector opt.
805               ! hydrostatic pressure gradient along s-surfaces
806               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)                                &
807                  &           + (  ( rho_k(ji+1,jj,jk) - rho_k(ji,jj,jk  ) )    &
808                  &              - ( rho_i(ji  ,jj,jk) - rho_i(ji,jj,jk-1) )  ) / e1u(ji,jj)
809               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)                                &
810                  &           + (  ( rho_k(ji,jj+1,jk) - rho_k(ji,jj,jk  ) )    &
811                  &               -( rho_j(ji,jj  ,jk) - rho_j(ji,jj,jk-1) )  ) / e2v(ji,jj)
812               ! add to the general momentum trend
813               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
814               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
815            END DO
816         END DO
817      END DO
818      !
819   END SUBROUTINE hpg_djc
820
821
822   SUBROUTINE hpg_rot( kt )
823      !!---------------------------------------------------------------------
824      !!                  ***  ROUTINE hpg_rot  ***
825      !!
826      !! ** Method  :   rotated axes scheme (Thiem and Berntsen 2005)
827      !!
828      !! Reference: Thiem & Berntsen, Ocean Modelling, In press, 2005.
829      !!----------------------------------------------------------------------
830      USE oce, ONLY :   zhpi => ta   ! use ta as 3D workspace
831      USE oce, ONLY :   zhpj => sa   ! use sa as 3D workspace
832      !!
833      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
834      !!
835      INTEGER  ::   ji, jj, jk          ! dummy loop indices
836      REAL(wp) ::   zforg, zcoef0, zuap, zmskd1, zmskd1m   ! temporary scalar
837      REAL(wp) ::   zfrot        , zvap, zmskd2, zmskd2m   !    "         "
838      REAL(wp), DIMENSION(jpi,jpj)     ::   zdistr, zsina, zcosa                ! 2D workspace
839      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zhpiorg, zhpirot, zhpitra, zhpine   ! 3D workspace
840      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zhpjorg, zhpjrot, zhpjtra, zhpjne   !  "      "
841      !!----------------------------------------------------------------------
842
843      IF( kt == nit000 ) THEN
844         IF(lwp) WRITE(numout,*)
845         IF(lwp) WRITE(numout,*) 'dyn:hpg_rot : hydrostatic pressure gradient trend'
846         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, rotated axes scheme used'
847      ENDIF
848
849      ! -------------------------------
850      !  Local constant initialization
851      ! -------------------------------
852      zcoef0 = - grav * 0.5
853      zforg  = 0.95e0
854      zfrot  = 1.e0 - zforg
855
856      ! inverse of the distance between 2 diagonal T-points (defined at F-point) (here zcoef0/distance)
857      zdistr(:,:) = zcoef0 / SQRT( e1f(:,:)*e1f(:,:) + e2f(:,:)*e1f(:,:) )
858
859      ! sinus and cosinus of diagonal angle at F-point
860      zsina(:,:) = ATAN2( e2f(:,:), e1f(:,:) )
861      zcosa(:,:) = COS( zsina(:,:) )
862      zsina(:,:) = SIN( zsina(:,:) )
863
864      ! ---------------
865      !  Surface value
866      ! ---------------
867      ! compute and add to the general trend the pressure gradients along the axes
868      DO jj = 2, jpjm1
869         DO ji = fs_2, fs_jpim1   ! vector opt.
870            ! hydrostatic pressure gradient along s-surfaces
871            zhpiorg(ji,jj,1) = zcoef0 / e1u(ji,jj) * (  fse3t(ji+1,jj,1) * rhd(ji+1,jj,1)   &
872               &                                      - fse3t(ji  ,jj,1) * rhd(ji  ,jj,1)  )
873            zhpjorg(ji,jj,1) = zcoef0 / e2v(ji,jj) * (  fse3t(ji,jj+1,1) * rhd(ji,jj+1,1)   &
874               &                                      - fse3t(ji,jj  ,1) * rhd(ji,jj  ,1)  )
875            ! s-coordinate pressure gradient correction
876            zuap = -zcoef0 * ( rhd   (ji+1,jj  ,1) + rhd   (ji,jj,1) )   &
877               &           * ( fsdept(ji+1,jj  ,1) - fsdept(ji,jj,1) ) / e1u(ji,jj)
878            zvap = -zcoef0 * ( rhd   (ji  ,jj+1,1) + rhd   (ji,jj,1) )   &
879               &           * ( fsdept(ji  ,jj+1,1) - fsdept(ji,jj,1) ) / e2v(ji,jj)
880            ! add to the general momentum trend
881            ua(ji,jj,1) = ua(ji,jj,1) + zforg * ( zhpiorg(ji,jj,1) + zuap )
882            va(ji,jj,1) = va(ji,jj,1) + zforg * ( zhpjorg(ji,jj,1) + zvap )
883         END DO
884      END DO
885
886      ! compute the pressure gradients in the diagonal directions
887      DO jj = 1, jpjm1
888         DO ji = 1, fs_jpim1   ! vector opt.
889            zmskd1 = tmask(ji+1,jj+1,1) * tmask(ji  ,jj,1)      ! mask in the 1st diagnonal
890            zmskd2 = tmask(ji  ,jj+1,1) * tmask(ji+1,jj,1)      ! mask in the 2nd diagnonal
891            ! hydrostatic pressure gradient along s-surfaces
892            zhpitra(ji,jj,1) = zdistr(ji,jj) * zmskd1 * (  fse3t(ji+1,jj+1,1) * rhd(ji+1,jj+1,1)   &
893               &                                         - fse3t(ji  ,jj  ,1) * rhd(ji  ,jj  ,1)  )
894            zhpjtra(ji,jj,1) = zdistr(ji,jj) * zmskd2 * (  fse3t(ji  ,jj+1,1) * rhd(ji  ,jj+1,1)   &
895               &                                         - fse3t(ji+1,jj  ,1) * rhd(ji+1,jj  ,1)  )
896            ! s-coordinate pressure gradient correction
897            zuap = -zdistr(ji,jj) * zmskd1 * ( rhd   (ji+1,jj+1,1) + rhd   (ji  ,jj,1) )   &
898               &                           * ( fsdept(ji+1,jj+1,1) - fsdept(ji  ,jj,1) )
899            zvap = -zdistr(ji,jj) * zmskd2 * ( rhd   (ji  ,jj+1,1) + rhd   (ji+1,jj,1) )   &
900               &                           * ( fsdept(ji  ,jj+1,1) - fsdept(ji+1,jj,1) )
901            ! back rotation
902            zhpine(ji,jj,1) = zcosa(ji,jj) * ( zhpitra(ji,jj,1) + zuap )   &
903               &            - zsina(ji,jj) * ( zhpjtra(ji,jj,1) + zvap )
904            zhpjne(ji,jj,1) = zsina(ji,jj) * ( zhpitra(ji,jj,1) + zuap )   &
905               &            + zcosa(ji,jj) * ( zhpjtra(ji,jj,1) + zvap )
906         END DO
907      END DO
908
909      ! interpolate and add to the general trend the diagonal gradient
910      DO jj = 2, jpjm1
911         DO ji = fs_2, fs_jpim1   ! vector opt.
912            ! averaging
913            zhpirot(ji,jj,1) = 0.5 * ( zhpine(ji,jj,1) + zhpine(ji  ,jj-1,1) )
914            zhpjrot(ji,jj,1) = 0.5 * ( zhpjne(ji,jj,1) + zhpjne(ji-1,jj  ,1) )
915            ! add to the general momentum trend
916            ua(ji,jj,1) = ua(ji,jj,1) + zfrot * zhpirot(ji,jj,1) 
917            va(ji,jj,1) = va(ji,jj,1) + zfrot * zhpjrot(ji,jj,1) 
918         END DO
919      END DO
920
921      ! -----------------
922      ! 2. interior value (2=<jk=<jpkm1)
923      ! -----------------
924      ! compute and add to the general trend the pressure gradients along the axes
925      DO jk = 2, jpkm1
926         DO jj = 2, jpjm1
927            DO ji = fs_2, fs_jpim1   ! vector opt.
928               ! hydrostatic pressure gradient along s-surfaces
929               zhpiorg(ji,jj,jk) = zhpiorg(ji,jj,jk-1)                                                 &
930                  &              +  zcoef0 / e1u(ji,jj) * (  fse3t(ji+1,jj,jk  ) * rhd(ji+1,jj,jk  )   &
931                  &                                        - fse3t(ji  ,jj,jk  ) * rhd(ji  ,jj,jk  )   &
932                  &                                        + fse3t(ji+1,jj,jk-1) * rhd(ji+1,jj,jk-1)   &
933                  &                                        - fse3t(ji  ,jj,jk-1) * rhd(ji  ,jj,jk-1)  )
934               zhpjorg(ji,jj,jk) = zhpjorg(ji,jj,jk-1)                                                 &
935                  &              +  zcoef0 / e2v(ji,jj) * (  fse3t(ji,jj+1,jk  ) * rhd(ji,jj+1,jk  )   &
936                  &                                        - fse3t(ji,jj  ,jk  ) * rhd(ji,jj,  jk  )   &
937                  &                                        + fse3t(ji,jj+1,jk-1) * rhd(ji,jj+1,jk-1)   &
938                  &                                        - fse3t(ji,jj  ,jk-1) * rhd(ji,jj,  jk-1)  )
939               ! s-coordinate pressure gradient correction
940               zuap = - zcoef0 * ( rhd   (ji+1,jj  ,jk) + rhd   (ji,jj,jk) )   &
941                  &            * ( fsdept(ji+1,jj  ,jk) - fsdept(ji,jj,jk) ) / e1u(ji,jj)
942               zvap = - zcoef0 * ( rhd   (ji  ,jj+1,jk) + rhd   (ji,jj,jk) )   &
943                  &            * ( fsdept(ji  ,jj+1,jk) - fsdept(ji,jj,jk) ) / e2v(ji,jj)
944               ! add to the general momentum trend
945               ua(ji,jj,jk) = ua(ji,jj,jk) + zforg*( zhpiorg(ji,jj,jk) + zuap )
946               va(ji,jj,jk) = va(ji,jj,jk) + zforg*( zhpjorg(ji,jj,jk) + zvap )
947            END DO
948         END DO
949      END DO
950
951      ! compute the pressure gradients in the diagonal directions
952      DO jk = 2, jpkm1
953         DO jj = 1, jpjm1
954            DO ji = 1, fs_jpim1   ! vector opt.
955               zmskd1  = tmask(ji+1,jj+1,jk  ) * tmask(ji  ,jj,jk  )      ! level jk   mask in the 1st diagnonal
956               zmskd1m = tmask(ji+1,jj+1,jk-1) * tmask(ji  ,jj,jk-1)      ! level jk-1    "               "     
957               zmskd2  = tmask(ji  ,jj+1,jk  ) * tmask(ji+1,jj,jk  )      ! level jk   mask in the 2nd diagnonal
958               zmskd2m = tmask(ji  ,jj+1,jk-1) * tmask(ji+1,jj,jk-1)      ! level jk-1    "               "     
959               ! hydrostatic pressure gradient along s-surfaces
960               zhpitra(ji,jj,jk) = zhpitra(ji,jj,jk-1)                                                       &
961                  &              + zdistr(ji,jj) * zmskd1  * ( fse3t(ji+1,jj+1,jk  ) * rhd(ji+1,jj+1,jk)     &
962                  &                                           -fse3t(ji  ,jj  ,jk  ) * rhd(ji  ,jj  ,jk) )   &
963                  &              + zdistr(ji,jj) * zmskd1m * ( fse3t(ji+1,jj+1,jk-1) * rhd(ji+1,jj+1,jk-1)   &
964                  &                                           -fse3t(ji  ,jj  ,jk-1) * rhd(ji  ,jj  ,jk-1) )
965               zhpjtra(ji,jj,jk) = zhpjtra(ji,jj,jk-1)                                                       &
966                  &              + zdistr(ji,jj) * zmskd2  * ( fse3t(ji  ,jj+1,jk  ) * rhd(ji  ,jj+1,jk)     &
967                  &                                           -fse3t(ji+1,jj  ,jk  ) * rhd(ji+1,jj,  jk) )   &
968                  &              + zdistr(ji,jj) * zmskd2m * ( fse3t(ji  ,jj+1,jk-1) * rhd(ji  ,jj+1,jk-1)   &
969                  &                                           -fse3t(ji+1,jj  ,jk-1) * rhd(ji+1,jj,  jk-1) )
970               ! s-coordinate pressure gradient correction
971               zuap = - zdistr(ji,jj) * zmskd1 * ( rhd   (ji+1,jj+1,jk) + rhd   (ji  ,jj,jk) )   &
972                  &                            * ( fsdept(ji+1,jj+1,jk) - fsdept(ji  ,jj,jk) )
973               zvap = - zdistr(ji,jj) * zmskd2 * ( rhd   (ji  ,jj+1,jk) + rhd   (ji+1,jj,jk) )   &
974                  &                            * ( fsdept(ji  ,jj+1,jk) - fsdept(ji+1,jj,jk) )
975               ! back rotation
976               zhpine(ji,jj,jk) = zcosa(ji,jj) * ( zhpitra(ji,jj,jk) + zuap )   &
977                  &             - zsina(ji,jj) * ( zhpjtra(ji,jj,jk) + zvap )
978               zhpjne(ji,jj,jk) = zsina(ji,jj) * ( zhpitra(ji,jj,jk) + zuap )   &
979                  &             + zcosa(ji,jj) * ( zhpjtra(ji,jj,jk) + zvap )
980            END DO
981         END DO
982      END DO
983
984      ! interpolate and add to the general trend
985      DO jk = 2, jpkm1
986         DO jj = 2, jpjm1
987            DO ji = fs_2, fs_jpim1   ! vector opt.
988               ! averaging
989               zhpirot(ji,jj,jk) = 0.5 * ( zhpine(ji,jj,jk) + zhpine(ji  ,jj-1,jk) )
990               zhpjrot(ji,jj,jk) = 0.5 * ( zhpjne(ji,jj,jk) + zhpjne(ji-1,jj  ,jk) )
991               ! add to the general momentum trend
992               ua(ji,jj,jk) = ua(ji,jj,jk) + zfrot * zhpirot(ji,jj,jk) 
993               va(ji,jj,jk) = va(ji,jj,jk) + zfrot * zhpjrot(ji,jj,jk) 
994            END DO
995         END DO
996      END DO
997      !
998   END SUBROUTINE hpg_rot
999
1000   !!======================================================================
1001END MODULE dynhpg
Note: See TracBrowser for help on using the repository browser.