New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zprod.F90 in branches/CNRS/dev_r6526_PISCES_GAS/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z – NEMO

source: branches/CNRS/dev_r6526_PISCES_GAS/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z/p4zprod.F90 @ 6532

Last change on this file since 6532 was 6530, checked in by cetlod, 8 years ago

1st implementation of PISCES GAS
File size: 34.7 KB
Line 
1MODULE p4zprod
2   !!======================================================================
3   !!                         ***  MODULE p4zprod  ***
4   !! TOP :  Growth Rate of the two phytoplanktons groups
5   !!======================================================================
6   !! History :   1.0  !  2004     (O. Aumont) Original code
7   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8   !!             3.4  !  2011-05  (O. Aumont, C. Ethe) New parameterization of light limitation
9   !!----------------------------------------------------------------------
10#if defined key_pisces
11   !!----------------------------------------------------------------------
12   !!   'key_pisces'                                       PISCES bio-model
13   !!----------------------------------------------------------------------
14   !!   p4z_prod       :   Compute the growth Rate of the two phytoplanktons groups
15   !!   p4z_prod_init  :   Initialization of the parameters for growth
16   !!   p4z_prod_alloc :   Allocate variables for growth
17   !!----------------------------------------------------------------------
18   USE oce_trc         !  shared variables between ocean and passive tracers
19   USE trc             !  passive tracers common variables
20   USE sms_pisces      !  PISCES Source Minus Sink variables
21   USE p4zopt          !  optical model
22   USE p4zlim          !  Co-limitations of differents nutrients
23   USE prtctl_trc      !  print control for debugging
24   USE iom             !  I/O manager
25
26   IMPLICIT NONE
27   PRIVATE
28
29   PUBLIC   p4z_prod         ! called in p4zbio.F90
30   PUBLIC   p4z_prod_init    ! called in trcsms_pisces.F90
31   PUBLIC   p4z_prod_alloc
32
33   !! * Shared module variables
34   LOGICAL , PUBLIC ::  ln_newprod      !:
35   REAL(wp), PUBLIC ::  pislope         !:
36   REAL(wp), PUBLIC ::  pislope2        !:
37   REAL(wp), PUBLIC ::  xadap           !:
38   REAL(wp), PUBLIC ::  excret          !:
39   REAL(wp), PUBLIC ::  excret2         !:
40   REAL(wp), PUBLIC ::  bresp           !:
41   REAL(wp), PUBLIC ::  chlcnm          !:
42   REAL(wp), PUBLIC ::  chlcdm          !:
43   REAL(wp), PUBLIC ::  chlcmin         !:
44   REAL(wp), PUBLIC ::  fecnm           !:
45   REAL(wp), PUBLIC ::  fecdm           !:
46   REAL(wp), PUBLIC ::  grosip          !:
47#if defined key_gas
48   REAL(wp), PUBLIC ::  xnanoco    !:
49   REAL(wp), PUBLIC ::  xdiaco     !:
50   REAL(wp), PUBLIC ::  xnanoIsp   !:
51   REAL(wp), PUBLIC ::  xdiaIsp    !:
52#endif
53
54   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   prmax    !: optimal production = f(temperature)
55   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   quotan   !: proxy of N quota in Nanophyto
56   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   quotad   !: proxy of N quota in diatomee
57   
58   REAL(wp) :: r1_rday                !: 1 / rday
59   REAL(wp) :: texcret                !: 1 - excret
60   REAL(wp) :: texcret2               !: 1 - excret2       
61
62
63   !!* Substitution
64#  include "top_substitute.h90"
65   !!----------------------------------------------------------------------
66   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
67   !! $Id: p4zprod.F90 3160 2011-11-20 14:27:18Z cetlod $
68   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
69   !!----------------------------------------------------------------------
70CONTAINS
71
72   SUBROUTINE p4z_prod( kt , knt )
73      !!---------------------------------------------------------------------
74      !!                     ***  ROUTINE p4z_prod  ***
75      !!
76      !! ** Purpose :   Compute the phytoplankton production depending on
77      !!              light, temperature and nutrient availability
78      !!
79      !! ** Method  : - ???
80      !!---------------------------------------------------------------------
81      !
82      INTEGER, INTENT(in) :: kt, knt
83      !
84      INTEGER  ::   ji, jj, jk
85      REAL(wp) ::   zsilfac, znanotot, zdiattot, zconctemp, zconctemp2
86      REAL(wp) ::   zratio, zmax, zsilim, ztn, zadap
87      REAL(wp) ::   zlim, zsilfac2, zsiborn, zprod, zproreg, zproreg2
88      REAL(wp) ::   zmxltst, zmxlday, zmaxday
89      REAL(wp) ::   zpislopen  , zpislope2n
90      REAL(wp) ::   zrum, zcodel, zargu, zval
91      REAL(wp) ::   zfact
92      CHARACTER (len=25) :: charout
93      REAL(wp), POINTER, DIMENSION(:,:  ) :: zmixnano, zmixdiat, zstrn, zw2d
94      REAL(wp), POINTER, DIMENSION(:,:,:) :: zpislopead, zpislopead2, zprdia, zprbio, zprdch, zprnch, zysopt, zw3d   
95      REAL(wp), POINTER, DIMENSION(:,:,:) :: zprorca, zprorcad, zprofed, zprofen, zprochln, zprochld, zpronew, zpronewd
96      REAL(wp) ::  zstep
97      REAL(wp), POINTER, DIMENSION(:,:,:) :: zproco, zproisp
98      !!---------------------------------------------------------------------
99      !
100      IF( nn_timing == 1 )  CALL timing_start('p4z_prod')
101      !
102      !  Allocate temporary workspace
103      CALL wrk_alloc( jpi, jpj,      zmixnano, zmixdiat, zstrn                                                  )
104      CALL wrk_alloc( jpi, jpj, jpk, zpislopead, zpislopead2, zprdia, zprbio, zprdch, zprnch, zysopt            ) 
105      CALL wrk_alloc( jpi, jpj, jpk, zprorca, zprorcad, zprofed, zprofen, zprochln, zprochld, zpronew, zpronewd )
106      !
107      zprorca (:,:,:) = 0._wp
108      zprorcad(:,:,:) = 0._wp
109      zprofed (:,:,:) = 0._wp
110      zprofen (:,:,:) = 0._wp
111      zprochln(:,:,:) = 0._wp
112      zprochld(:,:,:) = 0._wp
113      zpronew (:,:,:) = 0._wp
114      zpronewd(:,:,:) = 0._wp
115      zprdia  (:,:,:) = 0._wp
116      zprbio  (:,:,:) = 0._wp
117      zprdch  (:,:,:) = 0._wp
118      zprnch  (:,:,:) = 0._wp
119      zysopt  (:,:,:) = 0._wp
120      !
121      IF( lk_gas ) THEN
122         CALL wrk_alloc( jpi, jpj, jpk,  zproco, zproisp )
123         zproco  (:,:,:) = 0._wp
124         zproisp (:,:,:) = 0._wp
125      ENDIF
126
127
128      ! Computation of the optimal production
129      prmax(:,:,:) = 0.6_wp * r1_rday * tgfunc(:,:,:) 
130      IF( lk_degrad )  prmax(:,:,:) = prmax(:,:,:) * facvol(:,:,:) 
131
132      ! compute the day length depending on latitude and the day
133      zrum = REAL( nday_year - 80, wp ) / REAL( nyear_len(1), wp )
134      zcodel = ASIN(  SIN( zrum * rpi * 2._wp ) * SIN( rad * 23.5_wp )  )
135
136      ! day length in hours
137      zstrn(:,:) = 0.
138      DO jj = 1, jpj
139         DO ji = 1, jpi
140            zargu = TAN( zcodel ) * TAN( gphit(ji,jj) * rad )
141            zargu = MAX( -1., MIN(  1., zargu ) )
142            zstrn(ji,jj) = MAX( 0.0, 24. - 2. * ACOS( zargu ) / rad / 15. )
143         END DO
144      END DO
145
146      ! Impact of the day duration on phytoplankton growth
147      DO jk = 1, jpkm1
148         DO jj = 1 ,jpj
149            DO ji = 1, jpi
150               IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
151                  zval = MAX( 1., zstrn(ji,jj) )
152                  zval = 1.5 * zval / ( 12. + zval )
153                  zprbio(ji,jj,jk) = prmax(ji,jj,jk) * zval
154                  zprdia(ji,jj,jk) = zprbio(ji,jj,jk)
155               ENDIF
156            END DO
157         END DO
158      END DO
159
160      ! Maximum light intensity
161      WHERE( zstrn(:,:) < 1.e0 ) zstrn(:,:) = 24.
162      zstrn(:,:) = 24. / zstrn(:,:)
163
164      IF( ln_newprod ) THEN
165!CDIR NOVERRCHK
166         DO jk = 1, jpkm1
167!CDIR NOVERRCHK
168            DO jj = 1, jpj
169!CDIR NOVERRCHK
170               DO ji = 1, jpi
171                  ! Computation of the P-I slope for nanos and diatoms
172                  IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
173                      ztn         = MAX( 0., tsn(ji,jj,jk,jp_tem) - 15. )
174                      zadap       = xadap * ztn / ( 2.+ ztn )
175                      zconctemp   = MAX( 0.e0 , trb(ji,jj,jk,jpdia) - xsizedia )
176                      zconctemp2  = trb(ji,jj,jk,jpdia) - zconctemp
177                      znanotot    = enano(ji,jj,jk) * zstrn(ji,jj)
178                      zdiattot    = ediat(ji,jj,jk) * zstrn(ji,jj)
179                      !
180                      zpislopead (ji,jj,jk) = pislope * ( 1.+ zadap  * EXP( -znanotot ) )  &
181                         &                   * trb(ji,jj,jk,jpnch) /( trb(ji,jj,jk,jpphy) * 12. + rtrn)
182                      !
183                      zpislopead2(ji,jj,jk) = (pislope * zconctemp2 + pislope2 * zconctemp) / ( trb(ji,jj,jk,jpdia) + rtrn )   &
184                         &                   * trb(ji,jj,jk,jpdch) /( trb(ji,jj,jk,jpdia) * 12. + rtrn)
185
186                      ! Computation of production function for Carbon
187                      !  ---------------------------------------------
188                      zpislopen  = zpislopead (ji,jj,jk) / ( ( r1_rday + bresp * r1_rday ) * rday + rtrn)
189                      zpislope2n = zpislopead2(ji,jj,jk) / ( ( r1_rday + bresp * r1_rday ) * rday + rtrn)
190                      zprbio(ji,jj,jk) = zprbio(ji,jj,jk) * ( 1.- EXP( -zpislopen  * znanotot )  )
191                      zprdia(ji,jj,jk) = zprdia(ji,jj,jk) * ( 1.- EXP( -zpislope2n * zdiattot )  )
192
193                      !  Computation of production function for Chlorophyll
194                      !--------------------------------------------------
195                      zmaxday  = 1._wp / ( prmax(ji,jj,jk) * rday + rtrn )
196                      zprnch(ji,jj,jk) = prmax(ji,jj,jk) * ( 1.- EXP( -zpislopead (ji,jj,jk) * zmaxday * znanotot ) )
197                      zprdch(ji,jj,jk) = prmax(ji,jj,jk) * ( 1.- EXP( -zpislopead2(ji,jj,jk) * zmaxday * zdiattot ) )
198                  ENDIF
199               END DO
200            END DO
201         END DO
202      ELSE
203!CDIR NOVERRCHK
204         DO jk = 1, jpkm1
205!CDIR NOVERRCHK
206            DO jj = 1, jpj
207!CDIR NOVERRCHK
208               DO ji = 1, jpi
209
210                  ! Computation of the P-I slope for nanos and diatoms
211                  IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
212                      ztn         = MAX( 0., tsn(ji,jj,jk,jp_tem) - 15. )
213                      zadap       = ztn / ( 2.+ ztn )
214                      zconctemp   = MAX( 0.e0 , trb(ji,jj,jk,jpdia) - xsizedia )
215                      zconctemp2  = trb(ji,jj,jk,jpdia) - zconctemp
216                      znanotot    = enano(ji,jj,jk) * zstrn(ji,jj)
217                      zdiattot    = ediat(ji,jj,jk) * zstrn(ji,jj)
218                      !
219                      zpislopead (ji,jj,jk) = pislope  * ( 1.+ zadap  * EXP( -znanotot ) )
220                      zpislopead2(ji,jj,jk) = (pislope * zconctemp2 + pislope2 * zconctemp)  / ( trb(ji,jj,jk,jpdia) + rtrn )
221
222                      zpislopen =  zpislopead(ji,jj,jk) * trb(ji,jj,jk,jpnch)                &
223                        &          / ( trb(ji,jj,jk,jpphy) * 12.                  + rtrn )   &
224                        &          / ( prmax(ji,jj,jk) * rday * xlimphy(ji,jj,jk) + rtrn )
225
226                      zpislope2n = zpislopead2(ji,jj,jk) * trb(ji,jj,jk,jpdch)                &
227                        &          / ( trb(ji,jj,jk,jpdia) * 12.                  + rtrn )   &
228                        &          / ( prmax(ji,jj,jk) * rday * xlimdia(ji,jj,jk) + rtrn )
229
230                      ! Computation of production function for Carbon
231                      !  ---------------------------------------------
232                      zprbio(ji,jj,jk) = zprbio(ji,jj,jk) * ( 1.- EXP( -zpislopen  * znanotot ) )
233                      zprdia(ji,jj,jk) = zprdia(ji,jj,jk) * ( 1.- EXP( -zpislope2n * zdiattot ) )
234
235                      !  Computation of production function for Chlorophyll
236                      !--------------------------------------------------
237                      zprnch(ji,jj,jk) = prmax(ji,jj,jk) * ( 1.- EXP( -zpislopen  * enano(ji,jj,jk) ) )
238                      zprdch(ji,jj,jk) = prmax(ji,jj,jk) * ( 1.- EXP( -zpislope2n * ediat(ji,jj,jk) ) )
239                  ENDIF
240               END DO
241            END DO
242         END DO
243      ENDIF
244
245
246      !  Computation of a proxy of the N/C ratio
247      !  ---------------------------------------
248!CDIR NOVERRCHK
249      DO jk = 1, jpkm1
250!CDIR NOVERRCHK
251         DO jj = 1, jpj
252!CDIR NOVERRCHK
253            DO ji = 1, jpi
254                zval = MIN( xnanopo4(ji,jj,jk), ( xnanonh4(ji,jj,jk) + xnanono3(ji,jj,jk) ) )   &
255                &      * prmax(ji,jj,jk) / ( zprbio(ji,jj,jk) + rtrn )
256                quotan(ji,jj,jk) = MIN( 1., 0.2 + 0.8 * zval )
257                zval = MIN( xdiatpo4(ji,jj,jk), ( xdiatnh4(ji,jj,jk) + xdiatno3(ji,jj,jk) ) )   &
258                &      * prmax(ji,jj,jk) / ( zprdia(ji,jj,jk) + rtrn )
259                quotad(ji,jj,jk) = MIN( 1., 0.2 + 0.8 * zval )
260            END DO
261         END DO
262      END DO
263
264
265      DO jk = 1, jpkm1
266         DO jj = 1, jpj
267            DO ji = 1, jpi
268
269                IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
270                   !    Si/C of diatoms
271                   !    ------------------------
272                   !    Si/C increases with iron stress and silicate availability
273                   !    Si/C is arbitrariliy increased for very high Si concentrations
274                   !    to mimic the very high ratios observed in the Southern Ocean (silpot2)
275                  zlim  = trb(ji,jj,jk,jpsil) / ( trb(ji,jj,jk,jpsil) + xksi1 )
276                  zsilim = MIN( zprdia(ji,jj,jk) / ( prmax(ji,jj,jk) + rtrn ), xlimsi(ji,jj,jk) )
277                  zsilfac = 4.4 * EXP( -4.23 * zsilim ) * MAX( 0.e0, MIN( 1., 2.2 * ( zlim - 0.5 ) )  ) + 1.e0
278                  zsiborn = trb(ji,jj,jk,jpsil) * trb(ji,jj,jk,jpsil) * trb(ji,jj,jk,jpsil)
279                  IF (gphit(ji,jj) < -30 ) THEN
280                    zsilfac2 = 1. + 2. * zsiborn / ( zsiborn + xksi2**3 )
281                  ELSE
282                    zsilfac2 = 1. +      zsiborn / ( zsiborn + xksi2**3 )
283                  ENDIF
284                  zysopt(ji,jj,jk) = grosip * zlim * zsilfac * zsilfac2
285              ENDIF
286            END DO
287         END DO
288      END DO
289
290      !  Computation of the limitation term due to a mixed layer deeper than the euphotic depth
291      DO jj = 1, jpj
292         DO ji = 1, jpi
293            zmxltst = MAX( 0.e0, hmld(ji,jj) - heup(ji,jj) )
294            zmxlday = zmxltst * zmxltst * r1_rday
295            zmixnano(ji,jj) = 1. - zmxlday / ( 2. + zmxlday )
296            zmixdiat(ji,jj) = 1. - zmxlday / ( 4. + zmxlday )
297         END DO
298      END DO
299 
300      !  Mixed-layer effect on production                                                                               
301      DO jk = 1, jpkm1
302         DO jj = 1, jpj
303            DO ji = 1, jpi
304               IF( fsdepw(ji,jj,jk+1) <= hmld(ji,jj) ) THEN
305                  zprbio(ji,jj,jk) = zprbio(ji,jj,jk) * zmixnano(ji,jj)
306                  zprdia(ji,jj,jk) = zprdia(ji,jj,jk) * zmixdiat(ji,jj)
307               ENDIF
308            END DO
309         END DO
310      END DO
311
312      ! Computation of the various production terms
313!CDIR NOVERRCHK
314      DO jk = 1, jpkm1
315!CDIR NOVERRCHK
316         DO jj = 1, jpj
317!CDIR NOVERRCHK
318            DO ji = 1, jpi
319               IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
320                  !  production terms for nanophyto.
321                  zprorca(ji,jj,jk) = zprbio(ji,jj,jk)  * xlimphy(ji,jj,jk) * trb(ji,jj,jk,jpphy) * rfact2
322                  zpronew(ji,jj,jk) = zprorca(ji,jj,jk) * xnanono3(ji,jj,jk) / ( xnanono3(ji,jj,jk) + xnanonh4(ji,jj,jk) + rtrn )
323                  !
324                  zratio = trb(ji,jj,jk,jpnfe) / ( trb(ji,jj,jk,jpphy) + rtrn )
325                  zratio = zratio / fecnm 
326                  zmax   = MAX( 0., ( 1. - zratio ) / ABS( 1.05 - zratio ) ) 
327                  zprofen(ji,jj,jk) = fecnm * prmax(ji,jj,jk)  &
328                  &             * ( 4. - 4.5 * xlimnfe(ji,jj,jk) / ( xlimnfe(ji,jj,jk) + 0.5 ) )    &
329                  &             * biron(ji,jj,jk) / ( biron(ji,jj,jk) + concnfe(ji,jj,jk) )  &
330                  &             * zmax * trb(ji,jj,jk,jpphy) * rfact2
331                  !  production terms for diatomees
332                  zprorcad(ji,jj,jk) = zprdia(ji,jj,jk) * xlimdia(ji,jj,jk) * trb(ji,jj,jk,jpdia) * rfact2
333                  zpronewd(ji,jj,jk) = zprorcad(ji,jj,jk) * xdiatno3(ji,jj,jk) / ( xdiatno3(ji,jj,jk) + xdiatnh4(ji,jj,jk) + rtrn )
334                  !
335                  zratio = trb(ji,jj,jk,jpdfe) / ( trb(ji,jj,jk,jpdia) + rtrn )
336                  zratio = zratio / fecdm 
337                  zmax   = MAX( 0., ( 1. - zratio ) / ABS( 1.05 - zratio ) ) 
338                  zprofed(ji,jj,jk) = fecdm * prmax(ji,jj,jk)  &
339                  &             * ( 4. - 4.5 * xlimdfe(ji,jj,jk) / ( xlimdfe(ji,jj,jk) + 0.5 ) )    &
340                  &             * biron(ji,jj,jk) / ( biron(ji,jj,jk) + concdfe(ji,jj,jk) )  &
341                  &             * zmax * trb(ji,jj,jk,jpdia) * rfact2
342               ENDIF
343            END DO
344         END DO
345      END DO
346
347      IF( ln_newprod ) THEN
348!CDIR NOVERRCHK
349         DO jk = 1, jpkm1
350!CDIR NOVERRCHK
351            DO jj = 1, jpj
352!CDIR NOVERRCHK
353               DO ji = 1, jpi
354                  IF( fsdepw(ji,jj,jk+1) <= hmld(ji,jj) ) THEN
355                     zprnch(ji,jj,jk) = zprnch(ji,jj,jk) * zmixnano(ji,jj)
356                     zprdch(ji,jj,jk) = zprdch(ji,jj,jk) * zmixdiat(ji,jj)
357                  ENDIF
358                  IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
359                     !  production terms for nanophyto. ( chlorophyll )
360                     znanotot = enano(ji,jj,jk) * zstrn(ji,jj)
361                     zprod    = rday * zprorca(ji,jj,jk) * zprnch(ji,jj,jk) * xlimphy(ji,jj,jk)
362                     zprochln(ji,jj,jk) = chlcmin * 12. * zprorca (ji,jj,jk)
363                     zprochln(ji,jj,jk) = zprochln(ji,jj,jk) + (chlcnm-chlcmin) * 12. * zprod / &
364                                        & (  zpislopead(ji,jj,jk) * znanotot +rtrn)
365                     !  production terms for diatomees ( chlorophyll )
366                     zdiattot = ediat(ji,jj,jk) * zstrn(ji,jj)
367                     zprod = rday * zprorcad(ji,jj,jk) * zprdch(ji,jj,jk) * xlimdia(ji,jj,jk)
368                     zprochld(ji,jj,jk) = chlcmin * 12. * zprorcad(ji,jj,jk)
369                     zprochld(ji,jj,jk) = zprochld(ji,jj,jk) + (chlcdm-chlcmin) * 12. * zprod / &
370                                        & ( zpislopead2(ji,jj,jk) * zdiattot +rtrn )
371                  ENDIF
372               END DO
373            END DO
374         END DO
375      ELSE
376!CDIR NOVERRCHK
377         DO jk = 1, jpkm1
378!CDIR NOVERRCHK
379            DO jj = 1, jpj
380!CDIR NOVERRCHK
381               DO ji = 1, jpi
382                  IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
383                     !  production terms for nanophyto. ( chlorophyll )
384                     znanotot = enano(ji,jj,jk)
385                     zprod = rday * zprorca(ji,jj,jk) * zprnch(ji,jj,jk) * trb(ji,jj,jk,jpphy) * xlimphy(ji,jj,jk)
386                     zprochln(ji,jj,jk) = chlcmin * 12. * zprorca (ji,jj,jk)
387                     zprochln(ji,jj,jk) = zprochln(ji,jj,jk) + (chlcnm-chlcmin) * 144. * zprod            &
388                     &                    / ( zpislopead(ji,jj,jk) * trb(ji,jj,jk,jpnch) * znanotot +rtrn )
389                     !  production terms for diatomees ( chlorophyll )
390                     zdiattot = ediat(ji,jj,jk)
391                     zprod = rday * zprorcad(ji,jj,jk) * zprdch(ji,jj,jk) * trb(ji,jj,jk,jpdia) * xlimdia(ji,jj,jk)
392                     zprochld(ji,jj,jk) = chlcmin * 12. * zprorcad(ji,jj,jk)
393                     zprochld(ji,jj,jk) = zprochld(ji,jj,jk) + (chlcdm-chlcmin) * 144. * zprod             &
394                     &                    / ( zpislopead2(ji,jj,jk) * trb(ji,jj,jk,jpdch) * zdiattot +rtrn )
395                  ENDIF
396               END DO
397            END DO
398         END DO
399      ENDIF
400
401      !   Update the arrays TRA which contain the biological sources and sinks
402      DO jk = 1, jpkm1
403         DO jj = 1, jpj
404           DO ji =1 ,jpi
405              zproreg  = zprorca(ji,jj,jk) - zpronew(ji,jj,jk)
406              zproreg2 = zprorcad(ji,jj,jk) - zpronewd(ji,jj,jk)
407              tra(ji,jj,jk,jppo4) = tra(ji,jj,jk,jppo4) - zprorca(ji,jj,jk) - zprorcad(ji,jj,jk)
408              tra(ji,jj,jk,jpno3) = tra(ji,jj,jk,jpno3) - zpronew(ji,jj,jk) - zpronewd(ji,jj,jk)
409              tra(ji,jj,jk,jpnh4) = tra(ji,jj,jk,jpnh4) - zproreg - zproreg2
410              tra(ji,jj,jk,jpphy) = tra(ji,jj,jk,jpphy) + zprorca(ji,jj,jk) * texcret
411              tra(ji,jj,jk,jpnch) = tra(ji,jj,jk,jpnch) + zprochln(ji,jj,jk) * texcret
412              tra(ji,jj,jk,jpnfe) = tra(ji,jj,jk,jpnfe) + zprofen(ji,jj,jk) * texcret
413              tra(ji,jj,jk,jpdia) = tra(ji,jj,jk,jpdia) + zprorcad(ji,jj,jk) * texcret2
414              tra(ji,jj,jk,jpdch) = tra(ji,jj,jk,jpdch) + zprochld(ji,jj,jk) * texcret2
415              tra(ji,jj,jk,jpdfe) = tra(ji,jj,jk,jpdfe) + zprofed(ji,jj,jk) * texcret2
416              tra(ji,jj,jk,jpdsi) = tra(ji,jj,jk,jpdsi) + zprorcad(ji,jj,jk) * zysopt(ji,jj,jk) * texcret2
417              tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) + excret2 * zprorcad(ji,jj,jk) + excret * zprorca(ji,jj,jk)
418              tra(ji,jj,jk,jpoxy) = tra(ji,jj,jk,jpoxy) + o2ut * ( zproreg + zproreg2) &
419                 &                + ( o2ut + o2nit ) * ( zpronew(ji,jj,jk) + zpronewd(ji,jj,jk) )
420              tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) - texcret * zprofen(ji,jj,jk) - texcret2 * zprofed(ji,jj,jk)
421              tra(ji,jj,jk,jpsil) = tra(ji,jj,jk,jpsil) - texcret2 * zprorcad(ji,jj,jk) * zysopt(ji,jj,jk)
422              tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) - zprorca(ji,jj,jk) - zprorcad(ji,jj,jk)
423              tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) + rno3 * ( zpronew(ji,jj,jk) + zpronewd(ji,jj,jk) ) &
424                 &                                      - rno3 * ( zproreg + zproreg2 )
425          END DO
426        END DO
427     END DO
428     !
429     IF( lk_gas ) THEN
430        zstep = xstep * 1.e-6
431        DO jk = 1, jpkm1
432           DO jj = 1, jpj
433             DO ji =1 ,jpi
434               ! update the dms with sources & sinks
435               tra(ji,jj,jk,jpdms) = tra(ji,jj,jk,jpdms) &
436                  &                + xeffic(ji,jj,jk) * ( xcelld(ji,jj,jk) * zprorcad(ji,jj,jk ) * excret2 &
437                  &                                     + xcelln(ji,jj,jk) * zprorca(ji,jj,jk)   * excret )
438               ! production rate of CO & Isoprene : function of phytoplancton
439               ! growth
440               zproco(ji,jj,jk)  = zstep * ( xnanoco  * trb(ji,jj,jk,jpnch) + xdiaco  * trb(ji,jj,jk,jpdch) )
441               zproisp(ji,jj,jk) = zstep * ( xnanoIsp * trb(ji,jj,jk,jpnch) + xdiaIsp * trb(ji,jj,jk,jpdch) )
442               ! Add the trends
443               tra(ji,jj,jk,jpco)  = tra(ji,jj,jk,jpco)  + zproco(ji,jj,jk)
444               tra(ji,jj,jk,jpisp) = tra(ji,jj,jk,jpisp) + zproisp(ji,jj,jk)
445             END DO
446           END DO
447        END DO
448     ENDIF
449
450
451    ! Total primary production per year
452    IF( iom_use( "tintpp" ) .OR. ( ln_check_mass .AND. kt == nitend .AND. knt == nrdttrc )  )  &
453         & tpp = glob_sum( ( zprorca(:,:,:) + zprorcad(:,:,:) ) * cvol(:,:,:) )
454
455    IF( lk_iomput ) THEN
456       IF( knt == nrdttrc ) THEN
457          CALL wrk_alloc( jpi, jpj,      zw2d )
458          CALL wrk_alloc( jpi, jpj, jpk, zw3d )
459          zfact = 1.e+3 * rfact2r  !  conversion from mol/l/kt to  mol/m3/s
460          !
461          IF( iom_use( "PPPHY" ) .OR. iom_use( "PPPHY2" ) )  THEN
462              zw3d(:,:,:) = zprorca (:,:,:) * zfact * tmask(:,:,:)  ! primary production by nanophyto
463              CALL iom_put( "PPPHY"  , zw3d )
464              !
465              zw3d(:,:,:) = zprorcad(:,:,:) * zfact * tmask(:,:,:)  ! primary production by diatomes
466              CALL iom_put( "PPPHY2"  , zw3d )
467          ENDIF
468          IF( iom_use( "PPNEWN" ) .OR. iom_use( "PPNEWD" ) )  THEN
469              zw3d(:,:,:) = zpronew (:,:,:) * zfact * tmask(:,:,:)  ! new primary production by nanophyto
470              CALL iom_put( "PPNEWN"  , zw3d )
471              !
472              zw3d(:,:,:) = zpronewd(:,:,:) * zfact * tmask(:,:,:)  ! new primary production by diatomes
473              CALL iom_put( "PPNEWD"  , zw3d )
474          ENDIF
475          IF( iom_use( "PBSi" ) )  THEN
476              zw3d(:,:,:) = zprorcad(:,:,:) * zfact * tmask(:,:,:) * zysopt(:,:,:) ! biogenic silica production
477              CALL iom_put( "PBSi"  , zw3d )
478          ENDIF
479          IF( iom_use( "PFeN" ) .OR. iom_use( "PFeD" ) )  THEN
480              zw3d(:,:,:) = zprofen(:,:,:) * zfact * tmask(:,:,:)  ! biogenic iron production by nanophyto
481              CALL iom_put( "PFeN"  , zw3d )
482              !
483              zw3d(:,:,:) = zprofed(:,:,:) * zfact * tmask(:,:,:)  ! biogenic iron production by  diatomes
484              CALL iom_put( "PFeD"  , zw3d )
485          ENDIF
486          IF( iom_use( "Mumax" ) )  THEN
487              zw3d(:,:,:) = prmax(:,:,:) * tmask(:,:,:)   ! Maximum growth rate
488              CALL iom_put( "Mumax"  , zw3d )
489          ENDIF
490          IF( iom_use( "MuN" ) .OR. iom_use( "MuD" ) )  THEN
491              zw3d(:,:,:) = zprbio(:,:,:) * xlimphy(:,:,:) * tmask(:,:,:)  ! Realized growth rate for nanophyto
492              CALL iom_put( "MuN"  , zw3d )
493              !
494              zw3d(:,:,:) =  zprdia(:,:,:) * xlimdia(:,:,:) * tmask(:,:,:)  ! Realized growth rate for diatoms
495              CALL iom_put( "MuD"  , zw3d )
496          ENDIF
497          IF( iom_use( "LNlight" ) .OR. iom_use( "LDlight" ) )  THEN
498              zw3d(:,:,:) = zprbio (:,:,:) / (prmax(:,:,:) + rtrn) * tmask(:,:,:) ! light limitation term
499              CALL iom_put( "LNlight"  , zw3d )
500              !
501              zw3d(:,:,:) =  zprdia (:,:,:) / (prmax(:,:,:) + rtrn) * tmask(:,:,:)  ! light limitation term
502              CALL iom_put( "LDlight"  , zw3d )
503          ENDIF
504          IF( iom_use( "TPP" ) )  THEN
505              zw3d(:,:,:) = ( zprorca(:,:,:) + zprorcad(:,:,:) ) * zfact * tmask(:,:,:)  ! total primary production
506              CALL iom_put( "TPP"  , zw3d )
507          ENDIF
508          IF( iom_use( "TPNEW" ) )  THEN
509              zw3d(:,:,:) = ( zpronew(:,:,:) + zpronewd(:,:,:) ) * zfact * tmask(:,:,:)  ! total new production
510              CALL iom_put( "TPNEW"  , zw3d )
511          ENDIF
512          IF( iom_use( "TPBFE" ) )  THEN
513              zw3d(:,:,:) = ( zprofen(:,:,:) + zprofed(:,:,:) ) * zfact * tmask(:,:,:)  ! total biogenic iron production
514              CALL iom_put( "TPBFE"  , zw3d )
515          ENDIF
516          IF( iom_use( "INTPPPHY" ) .OR. iom_use( "INTPPPHY2" ) ) THEN 
517             zw2d(:,:) = 0.
518             DO jk = 1, jpkm1
519               zw2d(:,:) = zw2d(:,:) + zprorca (:,:,jk) * fse3t(:,:,jk) * zfact * tmask(:,:,jk)  ! vert. integrated  primary produc. by nano
520             ENDDO
521             CALL iom_put( "INTPPPHY" , zw2d )
522             !
523             zw2d(:,:) = 0.
524             DO jk = 1, jpkm1
525                zw2d(:,:) = zw2d(:,:) + zprorcad(:,:,jk) * fse3t(:,:,jk) * zfact * tmask(:,:,jk) ! vert. integrated  primary produc. by diatom
526             ENDDO
527             CALL iom_put( "INTPPPHY2" , zw2d )
528          ENDIF
529          IF( iom_use( "INTPP" ) ) THEN   
530             zw2d(:,:) = 0.
531             DO jk = 1, jpkm1
532                zw2d(:,:) = zw2d(:,:) + ( zprorca(:,:,jk) + zprorcad(:,:,jk) ) * fse3t(:,:,jk) * zfact * tmask(:,:,jk) ! vert. integrated pp
533             ENDDO
534             CALL iom_put( "INTPP" , zw2d )
535          ENDIF
536          IF( iom_use( "INTPNEW" ) ) THEN   
537             zw2d(:,:) = 0.
538             DO jk = 1, jpkm1
539                zw2d(:,:) = zw2d(:,:) + ( zpronew(:,:,jk) + zpronewd(:,:,jk) ) * fse3t(:,:,jk) * zfact * tmask(:,:,jk)  ! vert. integrated new prod
540             ENDDO
541             CALL iom_put( "INTPNEW" , zw2d )
542          ENDIF
543          IF( iom_use( "INTPBFE" ) ) THEN           !   total biogenic iron production  ( vertically integrated )
544             zw2d(:,:) = 0.
545             DO jk = 1, jpkm1
546                zw2d(:,:) = zw2d(:,:) + ( zprofen(:,:,jk) + zprofed(:,:,jk) ) * fse3t(:,:,jk) * zfact * tmask(:,:,jk) ! vert integr. bfe prod
547             ENDDO
548            CALL iom_put( "INTPBFE" , zw2d )
549          ENDIF
550          IF( iom_use( "INTPBSI" ) ) THEN           !   total biogenic silica production  ( vertically integrated )
551             zw2d(:,:) = 0.
552             DO jk = 1, jpkm1
553                zw2d(:,:) = zw2d(:,:) + zprorcad(:,:,jk) * zysopt(:,:,jk) * fse3t(:,:,jk) * zfact * tmask(:,:,jk)  ! vert integr. bsi prod
554             ENDDO
555             CALL iom_put( "INTPBSI" , zw2d )
556          ENDIF
557          IF( iom_use( "tintpp" ) )  CALL iom_put( "tintpp" , tpp * zfact )  !  global total integrated primary production molC/s
558          !
559          IF( lk_gas ) THEN
560              IF( iom_use( "SCquotan" ) )  THEN
561                zw3d(:,:,:) = xcelln(:,:,:) * tmask(:,:,:)  ! Quota S/C for Nanos
562                CALL iom_put( "SCquotan"  , zw3d )
563              ENDIF
564              IF( iom_use( "SCquotad" ) )  THEN
565                zw3d(:,:,:) = xcelld(:,:,:) * tmask(:,:,:)  ! Quota S/C for Diatoms
566                CALL iom_put( "SCquotad"  , zw3d )
567              ENDIF
568              IF( iom_use( "Yield" ) )  THEN
569                zw3d(:,:,:) = xeffic(:,:,:) * tmask(:,:,:)  ! DMSP to DMS Yield
570                CALL iom_put( "Yield"  , zw3d )
571              ENDIF
572              IF( iom_use( "BioprodCO" ) )  THEN
573                zw3d(:,:,:) = zproco(:,:,:) * zfact * tmask(:,:,:)  !  Biological Production of CO
574                CALL iom_put( "BioprodCO"  , zw3d )
575              ENDIF
576              IF( iom_use( "BioprodISP" ) )  THEN
577                zw3d(:,:,:) = zproisp(:,:,:) * zfact * tmask(:,:,:)  !  Biological Production of ISP
578                CALL iom_put( "BioprodISP"  , zw3d )
579              ENDIF
580          ENDIF
581          !
582          CALL wrk_dealloc( jpi, jpj,      zw2d )
583          CALL wrk_dealloc( jpi, jpj, jpk, zw3d )
584       ENDIF
585     ELSE
586        IF( ln_diatrc ) THEN
587           zfact = 1.e+3 * rfact2r
588           trc3d(:,:,:,jp_pcs0_3d + 4)  = zprorca (:,:,:) * zfact * tmask(:,:,:)
589           trc3d(:,:,:,jp_pcs0_3d + 5)  = zprorcad(:,:,:) * zfact * tmask(:,:,:)
590           trc3d(:,:,:,jp_pcs0_3d + 6)  = zpronew (:,:,:) * zfact * tmask(:,:,:)
591           trc3d(:,:,:,jp_pcs0_3d + 7)  = zpronewd(:,:,:) * zfact * tmask(:,:,:)
592           trc3d(:,:,:,jp_pcs0_3d + 8)  = zprorcad(:,:,:) * zfact * tmask(:,:,:) * zysopt(:,:,:)
593           trc3d(:,:,:,jp_pcs0_3d + 9)  = zprofed (:,:,:) * zfact * tmask(:,:,:)
594#  if ! defined key_kriest
595           trc3d(:,:,:,jp_pcs0_3d + 10) = zprofen (:,:,:) * zfact * tmask(:,:,:)
596#  endif
597        ENDIF
598     ENDIF
599
600     IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
601         WRITE(charout, FMT="('prod')")
602         CALL prt_ctl_trc_info(charout)
603         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
604     ENDIF
605     !
606                  CALL wrk_dealloc( jpi, jpj,      zmixnano, zmixdiat, zstrn                                                  )
607                  CALL wrk_dealloc( jpi, jpj, jpk, zpislopead, zpislopead2, zprdia, zprbio, zprdch, zprnch, zysopt            ) 
608                  CALL wrk_dealloc( jpi, jpj, jpk, zprorca, zprorcad, zprofed, zprofen, zprochln, zprochld, zpronew, zpronewd )
609     IF( lk_gas ) CALL wrk_dealloc( jpi, jpj, jpk,  zproco, zproisp )
610     !
611     IF( nn_timing == 1 )  CALL timing_stop('p4z_prod')
612     !
613   END SUBROUTINE p4z_prod
614
615
616   SUBROUTINE p4z_prod_init
617      !!----------------------------------------------------------------------
618      !!                  ***  ROUTINE p4z_prod_init  ***
619      !!
620      !! ** Purpose :   Initialization of phytoplankton production parameters
621      !!
622      !! ** Method  :   Read the nampisprod namelist and check the parameters
623      !!      called at the first timestep (nittrc000)
624      !!
625      !! ** input   :   Namelist nampisprod
626      !!----------------------------------------------------------------------
627      !
628      NAMELIST/nampisprod/ pislope, pislope2, xadap, ln_newprod, bresp, excret, excret2,  &
629#if defined key_gas
630         &                 xnanoco, xdiaco, xnanoIsp, xdiaIsp,    &
631#endif
632         &                 chlcnm, chlcdm, chlcmin, fecnm, fecdm, grosip
633      INTEGER :: ios                 ! Local integer output status for namelist read
634      !!----------------------------------------------------------------------
635
636      REWIND( numnatp_ref )              ! Namelist nampisprod in reference namelist : Pisces phytoplankton production
637      READ  ( numnatp_ref, nampisprod, IOSTAT = ios, ERR = 901)
638901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampisprod in reference namelist', lwp )
639
640      REWIND( numnatp_cfg )              ! Namelist nampisprod in configuration namelist : Pisces phytoplankton production
641      READ  ( numnatp_cfg, nampisprod, IOSTAT = ios, ERR = 902 )
642902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampisprod in configuration namelist', lwp )
643      IF(lwm) WRITE ( numonp, nampisprod )
644
645      IF(lwp) THEN                         ! control print
646         WRITE(numout,*) ' '
647         WRITE(numout,*) ' Namelist parameters for phytoplankton growth, nampisprod'
648         WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
649         WRITE(numout,*) '    Enable new parame. of production (T/F)   ln_newprod   =', ln_newprod
650         WRITE(numout,*) '    mean Si/C ratio                           grosip       =', grosip
651         WRITE(numout,*) '    P-I slope                                 pislope      =', pislope
652         WRITE(numout,*) '    Acclimation factor to low light           xadap       =', xadap
653         WRITE(numout,*) '    excretion ratio of nanophytoplankton      excret       =', excret
654         WRITE(numout,*) '    excretion ratio of diatoms                excret2      =', excret2
655         IF( ln_newprod )  THEN
656            WRITE(numout,*) '    basal respiration in phytoplankton        bresp        =', bresp
657            WRITE(numout,*) '    Maximum Chl/C in phytoplankton            chlcmin      =', chlcmin
658         ENDIF
659         WRITE(numout,*) '    P-I slope  for diatoms                    pislope2     =', pislope2
660         WRITE(numout,*) '    Minimum Chl/C in nanophytoplankton        chlcnm       =', chlcnm
661         WRITE(numout,*) '    Minimum Chl/C in diatoms                  chlcdm       =', chlcdm
662         WRITE(numout,*) '    Maximum Fe/C in nanophytoplankton         fecnm        =', fecnm
663         WRITE(numout,*) '    Minimum Fe/C in diatoms                   fecdm        =', fecdm
664#if defined key_gas
665         WRITE(numout,*) '    Production of CO via nanophyto       (µmol.gChla-1.d-1)  xnanoco   =', xnanoco
666         WRITE(numout,*) '    Production of CO via diatome         (µmol.gChla-1.d-1)  xdiaco    =', xdiaco
667         WRITE(numout,*) '    Production of isoprene via nanophyto (µmol.gChla-1.d-1)  xnanoIsp  =', xnanoIsp
668         WRITE(numout,*) '    Production of isoprene via diatome   (µmol.gChla-1.d-1)  xdiaIsp   =', xdiaIsp
669#endif
670      ENDIF
671      !
672      r1_rday   = 1._wp / rday 
673      texcret   = 1._wp - excret
674      texcret2  = 1._wp - excret2
675      tpp       = 0._wp
676      !
677   END SUBROUTINE p4z_prod_init
678
679
680   INTEGER FUNCTION p4z_prod_alloc()
681      !!----------------------------------------------------------------------
682      !!                     ***  ROUTINE p4z_prod_alloc  ***
683      !!----------------------------------------------------------------------
684      ALLOCATE( prmax(jpi,jpj,jpk), quotan(jpi,jpj,jpk), quotad(jpi,jpj,jpk), STAT = p4z_prod_alloc )
685      !
686      IF( p4z_prod_alloc /= 0 ) CALL ctl_warn('p4z_prod_alloc : failed to allocate arrays.')
687      !
688   END FUNCTION p4z_prod_alloc
689
690#else
691   !!======================================================================
692   !!  Dummy module :                                   No PISCES bio-model
693   !!======================================================================
694CONTAINS
695   SUBROUTINE p4z_prod                    ! Empty routine
696   END SUBROUTINE p4z_prod
697#endif 
698
699   !!======================================================================
700END MODULE  p4zprod
Note: See TracBrowser for help on using the repository browser.