1 | MODULE p4zflx |
---|
2 | !!====================================================================== |
---|
3 | !! *** MODULE p4zflx *** |
---|
4 | !! TOP : PISCES CALCULATES GAS EXCHANGE AND CHEMISTRY AT SEA SURFACE |
---|
5 | !!====================================================================== |
---|
6 | !! History : - ! 1988-07 (E. MAIER-REIMER) Original code |
---|
7 | !! - ! 1998 (O. Aumont) additions |
---|
8 | !! - ! 1999 (C. Le Quere) modifications |
---|
9 | !! 1.0 ! 2004 (O. Aumont) modifications |
---|
10 | !! 2.0 ! 2007-12 (C. Ethe, G. Madec) F90 |
---|
11 | !! ! 2011-02 (J. Simeon, J. Orr) Include total atm P correction |
---|
12 | !!---------------------------------------------------------------------- |
---|
13 | #if defined key_pisces |
---|
14 | !!---------------------------------------------------------------------- |
---|
15 | !! 'key_pisces' PISCES bio-model |
---|
16 | !!---------------------------------------------------------------------- |
---|
17 | !! p4z_flx : CALCULATES GAS EXCHANGE AND CHEMISTRY AT SEA SURFACE |
---|
18 | !! p4z_flx_init : Read the namelist |
---|
19 | !! p4z_patm : Read sfc atm pressure [atm] for each grid cell |
---|
20 | !!---------------------------------------------------------------------- |
---|
21 | USE oce_trc ! shared variables between ocean and passive tracers |
---|
22 | USE trc ! passive tracers common variables |
---|
23 | USE sms_pisces ! PISCES Source Minus Sink variables |
---|
24 | USE p4zche ! Chemical model |
---|
25 | USE prtctl_trc ! print control for debugging |
---|
26 | USE iom ! I/O manager |
---|
27 | USE fldread ! read input fields |
---|
28 | #if defined key_cpl_carbon_cycle |
---|
29 | USE sbc_oce, ONLY : atm_co2 ! atmospheric pCO2 |
---|
30 | #endif |
---|
31 | |
---|
32 | IMPLICIT NONE |
---|
33 | PRIVATE |
---|
34 | |
---|
35 | PUBLIC p4z_flx |
---|
36 | PUBLIC p4z_flx_init |
---|
37 | PUBLIC p4z_flx_alloc |
---|
38 | |
---|
39 | ! !!** Namelist nampisext ** |
---|
40 | REAL(wp) :: atcco2 !: pre-industrial atmospheric [co2] (ppm) |
---|
41 | LOGICAL :: ln_co2int !: flag to read in a file and interpolate atmospheric pco2 or not |
---|
42 | CHARACTER(len=34) :: clname !: filename of pco2 values |
---|
43 | INTEGER :: nn_offset !: Offset model-data start year (default = 0) |
---|
44 | |
---|
45 | !! Variables related to reading atmospheric CO2 time history |
---|
46 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:) :: atcco2h, years |
---|
47 | INTEGER :: nmaxrec, numco2 |
---|
48 | |
---|
49 | ! !!* nampisatm namelist (Atmospheric PRessure) * |
---|
50 | LOGICAL, PUBLIC :: ln_presatm !: ref. pressure: global mean Patm (F) or a constant (F) |
---|
51 | |
---|
52 | REAL(wp) , ALLOCATABLE, SAVE, DIMENSION(:,:) :: patm ! atmospheric pressure at kt [N/m2] |
---|
53 | TYPE(FLD), ALLOCATABLE, DIMENSION(:) :: sf_patm ! structure of input fields (file informations, fields read) |
---|
54 | |
---|
55 | |
---|
56 | REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) :: oce_co2 !: ocean carbon flux |
---|
57 | REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) :: satmco2 !: atmospheric pco2 |
---|
58 | |
---|
59 | REAL(wp) :: xconv = 0.01_wp / 3600._wp !: coefficients for conversion |
---|
60 | |
---|
61 | !!* Substitution |
---|
62 | # include "top_substitute.h90" |
---|
63 | !!---------------------------------------------------------------------- |
---|
64 | !! NEMO/TOP 3.3 , NEMO Consortium (2010) |
---|
65 | !! $Id$ |
---|
66 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
---|
67 | !!---------------------------------------------------------------------- |
---|
68 | CONTAINS |
---|
69 | |
---|
70 | SUBROUTINE p4z_flx ( kt, knt ) |
---|
71 | !!--------------------------------------------------------------------- |
---|
72 | !! *** ROUTINE p4z_flx *** |
---|
73 | !! |
---|
74 | !! ** Purpose : CALCULATES GAS EXCHANGE AND CHEMISTRY AT SEA SURFACE |
---|
75 | !! |
---|
76 | !! ** Method : |
---|
77 | !! - Include total atm P correction via Esbensen & Kushnir (1981) |
---|
78 | !! - Pressure correction NOT done for key_cpl_carbon_cycle |
---|
79 | !! - Remove Wanninkhof chemical enhancement; |
---|
80 | !! - Add option for time-interpolation of atcco2.txt |
---|
81 | !!--------------------------------------------------------------------- |
---|
82 | ! |
---|
83 | INTEGER, INTENT(in) :: kt, knt ! |
---|
84 | ! |
---|
85 | INTEGER :: ji, jj, jm, iind, iindm1 |
---|
86 | REAL(wp) :: ztc, ztc2, ztc3, ztc4, zws, zkgwan |
---|
87 | REAL(wp) :: zfld, zflu, zfld16, zflu16, zfact |
---|
88 | REAL(wp) :: zph, zah2, zbot, zdic, zalk, zsch_o2, zalka, zsch_co2 |
---|
89 | REAL(wp) :: zyr_dec, zdco2dt |
---|
90 | CHARACTER (len=25) :: charout |
---|
91 | REAL(wp), POINTER, DIMENSION(:,:) :: zkgco2, zkgo2, zh2co3, zoflx, zw2d |
---|
92 | REAL(wp) :: zsch_dms, zfludms,zflddms |
---|
93 | REAL(wp) :: zfldco, zfluco, zsch_co, zkin_vis, zD |
---|
94 | REAL(wp) :: zfldcos, zflucos |
---|
95 | REAL(wp) :: zfldisp, zfluisp, zsch_isp, zsch_cos |
---|
96 | REAL(wp) :: zsch_n2o, zfldn2o, zflun2o |
---|
97 | REAL(wp), POINTER, DIMENSION(:,:) :: zkgdms, zdmsflx |
---|
98 | REAL(wp), POINTER, DIMENSION(:,:) :: zkgco, zcoflx, zkgisp, zispflx |
---|
99 | REAL(wp), POINTER, DIMENSION(:,:) :: zH_cos, zkgcos, zcosflx |
---|
100 | REAL(wp), POINTER, DIMENSION(:,:) :: zkgn2o, znflx |
---|
101 | |
---|
102 | !!--------------------------------------------------------------------- |
---|
103 | ! |
---|
104 | IF( nn_timing == 1 ) CALL timing_start('p4z_flx') |
---|
105 | ! |
---|
106 | CALL wrk_alloc( jpi, jpj, zkgco2, zkgo2, zh2co3, zoflx ) |
---|
107 | IF( lk_gas ) THEN |
---|
108 | CALL wrk_alloc( jpi, jpj, zkgco, zcoflx, zkgisp, zispflx ) |
---|
109 | CALL wrk_alloc( jpi, jpj, zcosflx, zkgcos, zH_cos ) |
---|
110 | CALL wrk_alloc( jpi, jpj, zkgdms, zdmsflx ) |
---|
111 | CALL wrk_alloc( jpi, jpj, zkgn2o, znflx ) |
---|
112 | ENDIF |
---|
113 | ! |
---|
114 | |
---|
115 | ! SURFACE CHEMISTRY (PCO2 AND [H+] IN |
---|
116 | ! SURFACE LAYER); THE RESULT OF THIS CALCULATION |
---|
117 | ! IS USED TO COMPUTE AIR-SEA FLUX OF CO2 |
---|
118 | |
---|
119 | IF( kt /= nit000 .AND. knt == 1 ) CALL p4z_patm( kt ) ! Get sea-level pressure (E&K [1981] climatology) for use in flux calcs |
---|
120 | |
---|
121 | IF( ln_co2int ) THEN |
---|
122 | ! Linear temporal interpolation of atmospheric pco2. atcco2.txt has annual values. |
---|
123 | ! Caveats: First column of .txt must be in years, decimal years preferably. |
---|
124 | ! For nn_offset, if your model year is iyy, nn_offset=(years(1)-iyy) |
---|
125 | ! then the first atmospheric CO2 record read is at years(1) |
---|
126 | zyr_dec = REAL( nyear + nn_offset, wp ) + REAL( nday_year, wp ) / REAL( nyear_len(1), wp ) |
---|
127 | jm = 1 |
---|
128 | DO WHILE( jm <= nmaxrec .AND. years(jm) < zyr_dec ) ; jm = jm + 1 ; END DO |
---|
129 | iind = jm ; iindm1 = jm - 1 |
---|
130 | zdco2dt = ( atcco2h(iind) - atcco2h(iindm1) ) / ( years(iind) - years(iindm1) + rtrn ) |
---|
131 | atcco2 = zdco2dt * ( zyr_dec - years(iindm1) ) + atcco2h(iindm1) |
---|
132 | satmco2(:,:) = atcco2 |
---|
133 | ENDIF |
---|
134 | |
---|
135 | #if defined key_cpl_carbon_cycle |
---|
136 | satmco2(:,:) = atm_co2(:,:) |
---|
137 | #endif |
---|
138 | |
---|
139 | DO jm = 1, 10 |
---|
140 | !CDIR NOVERRCHK |
---|
141 | DO jj = 1, jpj |
---|
142 | !CDIR NOVERRCHK |
---|
143 | DO ji = 1, jpi |
---|
144 | |
---|
145 | ! DUMMY VARIABLES FOR DIC, H+, AND BORATE |
---|
146 | zbot = borat(ji,jj,1) |
---|
147 | zfact = rhop(ji,jj,1) / 1000. + rtrn |
---|
148 | zdic = trb(ji,jj,1,jpdic) / zfact |
---|
149 | zph = MAX( hi(ji,jj,1), 1.e-10 ) / zfact |
---|
150 | zalka = trb(ji,jj,1,jptal) / zfact |
---|
151 | |
---|
152 | ! CALCULATE [ALK]([CO3--], [HCO3-]) |
---|
153 | zalk = zalka - ( akw3(ji,jj,1) / zph - zph / aphscale(ji,jj,1) & |
---|
154 | & + zbot / ( 1.+ zph / akb3(ji,jj,1) ) ) |
---|
155 | |
---|
156 | ! CALCULATE [H+] AND [H2CO3] |
---|
157 | zah2 = SQRT( (zdic-zalk)**2 + 4.* ( zalk * ak23(ji,jj,1) & |
---|
158 | & / ak13(ji,jj,1) ) * ( 2.* zdic - zalk ) ) |
---|
159 | zah2 = 0.5 * ak13(ji,jj,1) / zalk * ( ( zdic - zalk ) + zah2 ) |
---|
160 | zh2co3(ji,jj) = ( 2.* zdic - zalk ) / ( 2.+ ak13(ji,jj,1) / zah2 ) * zfact |
---|
161 | hi(ji,jj,1) = zah2 * zfact |
---|
162 | END DO |
---|
163 | END DO |
---|
164 | END DO |
---|
165 | |
---|
166 | |
---|
167 | ! -------------- |
---|
168 | ! COMPUTE FLUXES |
---|
169 | ! -------------- |
---|
170 | |
---|
171 | ! FIRST COMPUTE GAS EXCHANGE COEFFICIENTS |
---|
172 | ! ------------------------------------------- |
---|
173 | |
---|
174 | !CDIR NOVERRCHK |
---|
175 | DO jj = 1, jpj |
---|
176 | !CDIR NOVERRCHK |
---|
177 | DO ji = 1, jpi |
---|
178 | ztc = MIN( 35., tsn(ji,jj,1,jp_tem) ) |
---|
179 | ztc2 = ztc * ztc |
---|
180 | ztc3 = ztc * ztc2 |
---|
181 | ztc4 = ztc2 * ztc2 |
---|
182 | ! Compute the schmidt Number both O2 and CO2 |
---|
183 | zsch_co2 = 2116.8 - 136.25 * ztc + 4.7353 * ztc2 - 0.092307 * ztc3 + 0.0007555 * ztc4 |
---|
184 | zsch_o2 = 1920.4 - 135.6 * ztc + 5.2122 * ztc2 - 0.109390 * ztc3 + 0.0009377 * ztc4 |
---|
185 | ! wind speed |
---|
186 | zws = wndm(ji,jj) * wndm(ji,jj) |
---|
187 | ! Compute the piston velocity for O2 and CO2 |
---|
188 | zkgwan = 0.251 * zws |
---|
189 | zkgwan = zkgwan * xconv * ( 1.- fr_i(ji,jj) ) * tmask(ji,jj,1) |
---|
190 | # if defined key_degrad |
---|
191 | zkgwan = zkgwan * facvol(ji,jj,1) |
---|
192 | #endif |
---|
193 | ! compute gas exchange for CO2 and O2 |
---|
194 | zkgco2(ji,jj) = zkgwan * SQRT( 660./ zsch_co2 ) |
---|
195 | zkgo2 (ji,jj) = zkgwan * SQRT( 660./ zsch_o2 ) |
---|
196 | END DO |
---|
197 | END DO |
---|
198 | |
---|
199 | IF( lk_gas ) THEN |
---|
200 | !CDIR NOVERRCHK |
---|
201 | DO jj = 1, jpj |
---|
202 | !CDIR NOVERRCHK |
---|
203 | DO ji = 1, jpi |
---|
204 | ztc = MIN( 35., tsn(ji,jj,1,jp_tem) ) |
---|
205 | ztc2 = ztc * ztc |
---|
206 | ztc3 = ztc * ztc2 |
---|
207 | |
---|
208 | zsch_dms = 3628.5 - 234.58 * ztc + 7.8601 * ztc2 - 0.1148 * ztc3 |
---|
209 | !zsch_co = 1889.126 - 127.2150 * ztc + 4.499079 * ztc2 - |
---|
210 | !0.08973561 * ztc3 |
---|
211 | zsch_co = 2124 - 140.07 * ztc + 4.3825 * ztc2 - 0.0553 * ztc3 |
---|
212 | ! pb with the above equation - this one comes from Zafiriou 2008 see w/ B. Bonsang |
---|
213 | zsch_isp = 3546.535 - 217.2178 * ztc + 5.732073 * ztc2 - 0.06035193 * ztc3 |
---|
214 | !compute Schmidt number for cos, taken from Ulshofer |
---|
215 | zkin_vis = (1.792747 - 0.05126103 * ztc + 0.0005918645 * ztc2 ) * 1.E-6 ! m2/s |
---|
216 | zD = ( 10**( -1010. / ( ztc + 273.15 ) - 1.3246) ) * 1.E-4 ! cm2/s to m2/s |
---|
217 | zsch_cos = zkin_vis / zD |
---|
218 | zkgdms(ji,jj) = zkgwan * SQRT( 660./ zsch_dms ) |
---|
219 | zkgco (ji,jj) = zkgwan * SQRT( 660./ zsch_co ) |
---|
220 | zkgisp(ji,jj) = zkgwan * SQRT( 660./ zsch_isp) |
---|
221 | zkgcos(ji,jj) = zkgwan * SQRT( 660./ zsch_cos) |
---|
222 | zH_cos(ji,jj) = EXP( 12.722 - 3496./ ( ztc + 273.15 ) ) + rtrn |
---|
223 | ! |
---|
224 | zsch_n2o = 2301.1 - 151.1 * ztc + 4.7364 * ztc2 - 0.059431 * ztc3 |
---|
225 | zkgn2o(ji,jj) = zkgwan * SQRT( 660./ zsch_n2o ) |
---|
226 | END DO |
---|
227 | END DO |
---|
228 | ! |
---|
229 | ENDIF |
---|
230 | |
---|
231 | DO jj = 1, jpj |
---|
232 | DO ji = 1, jpi |
---|
233 | ! Compute CO2 flux for the sea and air |
---|
234 | zfld = satmco2(ji,jj) * patm(ji,jj) * tmask(ji,jj,1) * chemc(ji,jj) * zkgco2(ji,jj) ! (mol/L) * (m/s) |
---|
235 | zflu = zh2co3(ji,jj) * tmask(ji,jj,1) * zkgco2(ji,jj) ! (mol/L) (m/s) ? |
---|
236 | oce_co2(ji,jj) = ( zfld - zflu ) * rfact2 * e1e2t(ji,jj) * tmask(ji,jj,1) * 1000. |
---|
237 | ! compute the trend |
---|
238 | tra(ji,jj,1,jpdic) = tra(ji,jj,1,jpdic) + ( zfld - zflu ) * rfact2 / fse3t(ji,jj,1) |
---|
239 | |
---|
240 | ! Compute O2 flux |
---|
241 | zfld16 = patm(ji,jj) * chemo2(ji,jj,1) * tmask(ji,jj,1) * zkgo2(ji,jj) ! (mol/L) * (m/s) |
---|
242 | zflu16 = trb(ji,jj,1,jpoxy) * tmask(ji,jj,1) * zkgo2(ji,jj) |
---|
243 | zoflx(ji,jj) = zfld16 - zflu16 |
---|
244 | tra(ji,jj,1,jpoxy) = tra(ji,jj,1,jpoxy) + zoflx(ji,jj) * rfact2 / fse3t(ji,jj,1) |
---|
245 | END DO |
---|
246 | END DO |
---|
247 | |
---|
248 | |
---|
249 | IF( lk_gas ) THEN |
---|
250 | DO jj = 1, jpj |
---|
251 | DO ji = 1, jpi |
---|
252 | ! Compute DMS flux |
---|
253 | zfludms = trb(ji,jj,1,jpdms) * tmask(ji,jj,1) * zkgdms(ji,jj) |
---|
254 | zdmsflx(ji,jj) = -1. * zfludms |
---|
255 | tra(ji,jj,1,jpdms) = tra(ji,jj,1,jpdms) - ( zfludms ) / fse3t(ji,jj,1) |
---|
256 | |
---|
257 | ! Compute CO flux |
---|
258 | zfldco = atco * patm(ji,jj) * chemcos(ji,jj,1) *tmask(ji,jj,1) * zkgco(ji,jj) |
---|
259 | zfluco = trb(ji,jj,1,jpco) * tmask(ji,jj,1) * zkgco(ji,jj) |
---|
260 | zcoflx(ji,jj) = zfldco - zfluco |
---|
261 | tra(ji,jj,1,jpco) = tra(ji,jj,1,jpco) + zcoflx(ji,jj) / fse3t(ji,jj,1) |
---|
262 | |
---|
263 | ! Compute isoprene flux |
---|
264 | zfldisp = atisp * patm(ji,jj) * chemcos(ji,jj,2) *tmask(ji,jj,1) * zkgisp(ji,jj) ! (mol/L) * (m/s) |
---|
265 | zfluisp = trb(ji,jj,1,jpisp) * tmask(ji,jj,1) * zkgisp(ji,jj) |
---|
266 | zispflx(ji,jj) = zfldisp - zfluisp |
---|
267 | tra(ji,jj,1,jpisp) = tra(ji,jj,1,jpisp) + zispflx(ji,jj) / fse3t(ji,jj,1) |
---|
268 | |
---|
269 | ! Compute COS flux |
---|
270 | zfldcos = atccos * patm(ji,jj) * chemcos(ji,jj,3) *tmask(ji,jj,1) *zkgcos(ji,jj) ! (mol/L) * (m/s) |
---|
271 | zflucos = trb(ji,jj,1,jpcos) * tmask(ji,jj,1) * zkgcos(ji,jj) |
---|
272 | zcosflx(ji,jj) = zfldcos - zflucos |
---|
273 | tra(ji,jj,1,jpcos) = tra(ji,jj,1,jpcos) + zcosflx(ji,jj) / fse3t(ji,jj,1) |
---|
274 | |
---|
275 | ! Compute N2O flux |
---|
276 | zfldn2o = atcn2o * patm(ji,jj) * chemn2o(ji,jj) *tmask(ji,jj,1) * zkgn2o(ji,jj) |
---|
277 | zflun2o = trb(ji,jj,1,jpn2o) * tmask(ji,jj,1) * zkgn2o(ji,jj) |
---|
278 | znflx(ji,jj) = zfldn2o - zflun2o |
---|
279 | tra(ji,jj,1,jpn2o) = tra(ji,jj,1,jpn2o) + znflx(ji,jj) / fse3t(ji,jj,1) |
---|
280 | END DO |
---|
281 | END DO |
---|
282 | ENDIF |
---|
283 | |
---|
284 | |
---|
285 | t_oce_co2_flx = glob_sum( oce_co2(:,:) ) ! Total Flux of Carbon |
---|
286 | t_oce_co2_flx_cum = t_oce_co2_flx_cum + t_oce_co2_flx ! Cumulative Total Flux of Carbon |
---|
287 | ! t_atm_co2_flx = glob_sum( satmco2(:,:) * e1e2t(:,:) ) ! Total atmospheric pCO2 |
---|
288 | t_atm_co2_flx = atcco2 ! Total atmospheric pCO2 |
---|
289 | |
---|
290 | IF(ln_ctl) THEN ! print mean trends (used for debugging) |
---|
291 | WRITE(charout, FMT="('flx ')") |
---|
292 | CALL prt_ctl_trc_info(charout) |
---|
293 | CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm) |
---|
294 | ENDIF |
---|
295 | |
---|
296 | IF( lk_iomput .AND. knt == nrdttrc ) THEN |
---|
297 | CALL wrk_alloc( jpi, jpj, zw2d ) |
---|
298 | IF( iom_use( "Cflx" ) ) THEN |
---|
299 | zw2d(:,:) = oce_co2(:,:) / e1e2t(:,:) * rfact2r |
---|
300 | CALL iom_put( "Cflx" , zw2d ) |
---|
301 | ENDIF |
---|
302 | IF( iom_use( "Oflx" ) ) THEN |
---|
303 | zw2d(:,:) = zoflx(:,:) * 1000 * tmask(:,:,1) |
---|
304 | CALL iom_put( "Oflx" , zw2d ) |
---|
305 | ENDIF |
---|
306 | IF( iom_use( "Kg" ) ) THEN |
---|
307 | zw2d(:,:) = zkgco2(:,:) * tmask(:,:,1) |
---|
308 | CALL iom_put( "Kg" , zw2d ) |
---|
309 | ENDIF |
---|
310 | IF( iom_use( "Dpco2" ) ) THEN |
---|
311 | zw2d(:,:) = ( satmco2(:,:) * patm(:,:) - zh2co3(:,:) / ( chemc(:,:) + rtrn ) ) * tmask(:,:,1) |
---|
312 | CALL iom_put( "Dpco2" , zw2d ) |
---|
313 | ENDIF |
---|
314 | IF( iom_use( "Dpo2" ) ) THEN |
---|
315 | zw2d(:,:) = ( atcox * patm(:,:) - atcox * trb(:,:,1,jpoxy) / ( chemo2(:,:,1) + rtrn ) ) * tmask(:,:,1) |
---|
316 | CALL iom_put( "Dpo2" , zw2d ) |
---|
317 | ENDIF |
---|
318 | IF( iom_use( "tcflx" ) ) CALL iom_put( "tcflx" , t_oce_co2_flx * rfact2r ) ! molC/s |
---|
319 | CALL iom_put( "tcflxcum" , t_oce_co2_flx_cum ) ! molC |
---|
320 | ! |
---|
321 | IF (lk_gas) THEN |
---|
322 | IF ( iom_use( "DMSflx" ) ) THEN |
---|
323 | zw2d(:,:) = zdmsflx(:,:) * 1000 * tmask(:,:,1) |
---|
324 | CALL iom_put( "DMSflx" , zw2d ) |
---|
325 | ENDIF |
---|
326 | IF ( iom_use( "COflx" ) ) THEN |
---|
327 | zw2d(:,:) = zcoflx(:,:) * 1000 * tmask(:,:,1) |
---|
328 | CALL iom_put( "COflx" , zw2d ) |
---|
329 | ENDIF |
---|
330 | IF ( iom_use( "ISPflx" ) ) THEN |
---|
331 | zw2d(:,:) = zispflx(:,:) * 1000 * tmask(:,:,1) |
---|
332 | CALL iom_put( "ISPflx" , zw2d ) |
---|
333 | ENDIF |
---|
334 | IF ( iom_use( "COSflx" ) ) THEN |
---|
335 | zw2d(:,:) = zcosflx(:,:) * 1000 * tmask(:,:,1) |
---|
336 | CALL iom_put( "COSflx" , zw2d ) |
---|
337 | ENDIF |
---|
338 | IF ( iom_use( "H_cos" ) ) THEN |
---|
339 | zw2d(:,:) = zH_cos(:,:) * tmask(:,:,1) |
---|
340 | CALL iom_put( "H_cos" , zw2d ) |
---|
341 | ENDIF |
---|
342 | IF ( iom_use( "N2Oflx" ) ) THEN |
---|
343 | zw2d(:,:) = znflx(:,:) * 1000 * tmask(:,:,1) |
---|
344 | CALL iom_put( "N2Oflx" , zw2d ) |
---|
345 | ENDIF |
---|
346 | ENDIF |
---|
347 | |
---|
348 | CALL wrk_dealloc( jpi, jpj, zw2d ) |
---|
349 | ELSE |
---|
350 | IF( ln_diatrc ) THEN |
---|
351 | trc2d(:,:,jp_pcs0_2d ) = oce_co2(:,:) / e1e2t(:,:) * rfact2r |
---|
352 | trc2d(:,:,jp_pcs0_2d + 1) = zoflx(:,:) * 1000 * tmask(:,:,1) |
---|
353 | trc2d(:,:,jp_pcs0_2d + 2) = zkgco2(:,:) * tmask(:,:,1) |
---|
354 | trc2d(:,:,jp_pcs0_2d + 3) = ( satmco2(:,:) * patm(:,:) - zh2co3(:,:) / ( chemc(:,:) + rtrn ) ) * tmask(:,:,1) |
---|
355 | ENDIF |
---|
356 | ENDIF |
---|
357 | ! |
---|
358 | CALL wrk_dealloc( jpi, jpj, zkgco2, zkgo2, zh2co3, zoflx ) |
---|
359 | ! |
---|
360 | IF( nn_timing == 1 ) CALL timing_stop('p4z_flx') |
---|
361 | ! |
---|
362 | END SUBROUTINE p4z_flx |
---|
363 | |
---|
364 | |
---|
365 | SUBROUTINE p4z_flx_init |
---|
366 | !!---------------------------------------------------------------------- |
---|
367 | !! *** ROUTINE p4z_flx_init *** |
---|
368 | !! |
---|
369 | !! ** Purpose : Initialization of atmospheric conditions |
---|
370 | !! |
---|
371 | !! ** Method : Read the nampisext namelist and check the parameters |
---|
372 | !! called at the first timestep (nittrc000) |
---|
373 | !! ** input : Namelist nampisext |
---|
374 | !!---------------------------------------------------------------------- |
---|
375 | NAMELIST/nampisext/ln_co2int, atcco2, clname, & |
---|
376 | #ifdef key_gas |
---|
377 | & atccos, atcn2o, & |
---|
378 | #endif |
---|
379 | & nn_offset |
---|
380 | INTEGER :: jm |
---|
381 | INTEGER :: ios ! Local integer output status for namelist read |
---|
382 | !!---------------------------------------------------------------------- |
---|
383 | ! |
---|
384 | |
---|
385 | REWIND( numnatp_ref ) ! Namelist nampisext in reference namelist : Pisces atm. conditions |
---|
386 | READ ( numnatp_ref, nampisext, IOSTAT = ios, ERR = 901) |
---|
387 | 901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampisext in reference namelist', lwp ) |
---|
388 | |
---|
389 | REWIND( numnatp_cfg ) ! Namelist nampisext in configuration namelist : Pisces atm. conditions |
---|
390 | READ ( numnatp_cfg, nampisext, IOSTAT = ios, ERR = 902 ) |
---|
391 | 902 IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampisext in configuration namelist', lwp ) |
---|
392 | IF(lwm) WRITE ( numonp, nampisext ) |
---|
393 | ! |
---|
394 | IF(lwp) THEN ! control print |
---|
395 | WRITE(numout,*) ' ' |
---|
396 | WRITE(numout,*) ' Namelist parameters for air-sea exchange, nampisext' |
---|
397 | WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~' |
---|
398 | WRITE(numout,*) ' Choice for reading in the atm pCO2 file or constant value, ln_co2int =', ln_co2int |
---|
399 | WRITE(numout,*) ' ' |
---|
400 | ENDIF |
---|
401 | IF( .NOT.ln_co2int ) THEN |
---|
402 | IF(lwp) THEN ! control print |
---|
403 | WRITE(numout,*) ' Constant Atmospheric pCO2 value atcco2 =', atcco2 |
---|
404 | WRITE(numout,*) ' ' |
---|
405 | ENDIF |
---|
406 | satmco2(:,:) = atcco2 ! Initialisation of atmospheric pco2 |
---|
407 | ELSE |
---|
408 | IF(lwp) THEN |
---|
409 | WRITE(numout,*) ' Atmospheric pCO2 value from file clname =', TRIM( clname ) |
---|
410 | WRITE(numout,*) ' Offset model-data start year nn_offset =', nn_offset |
---|
411 | WRITE(numout,*) ' ' |
---|
412 | ENDIF |
---|
413 | CALL ctl_opn( numco2, TRIM( clname) , 'OLD', 'FORMATTED', 'SEQUENTIAL', -1 , numout, lwp ) |
---|
414 | jm = 0 ! Count the number of record in co2 file |
---|
415 | DO |
---|
416 | READ(numco2,*,END=100) |
---|
417 | jm = jm + 1 |
---|
418 | END DO |
---|
419 | 100 nmaxrec = jm - 1 |
---|
420 | ALLOCATE( years (nmaxrec) ) ; years (:) = 0._wp |
---|
421 | ALLOCATE( atcco2h(nmaxrec) ) ; atcco2h(:) = 0._wp |
---|
422 | |
---|
423 | REWIND(numco2) |
---|
424 | DO jm = 1, nmaxrec ! get xCO2 data |
---|
425 | READ(numco2, *) years(jm), atcco2h(jm) |
---|
426 | IF(lwp) WRITE(numout, '(f6.0,f7.2)') years(jm), atcco2h(jm) |
---|
427 | END DO |
---|
428 | CLOSE(numco2) |
---|
429 | ENDIF |
---|
430 | ! |
---|
431 | oce_co2(:,:) = 0._wp ! Initialization of Flux of Carbon |
---|
432 | t_oce_co2_flx = 0._wp |
---|
433 | t_atm_co2_flx = 0._wp |
---|
434 | ! |
---|
435 | CALL p4z_patm( nit000 ) |
---|
436 | ! |
---|
437 | END SUBROUTINE p4z_flx_init |
---|
438 | |
---|
439 | SUBROUTINE p4z_patm( kt ) |
---|
440 | |
---|
441 | !!---------------------------------------------------------------------- |
---|
442 | !! *** ROUTINE p4z_atm *** |
---|
443 | !! |
---|
444 | !! ** Purpose : Read and interpolate the external atmospheric sea-levl pressure |
---|
445 | !! ** Method : Read the files and interpolate the appropriate variables |
---|
446 | !! |
---|
447 | !!---------------------------------------------------------------------- |
---|
448 | !! * arguments |
---|
449 | INTEGER, INTENT( in ) :: kt ! ocean time step |
---|
450 | ! |
---|
451 | INTEGER :: ierr |
---|
452 | INTEGER :: ios ! Local integer output status for namelist read |
---|
453 | CHARACTER(len=100) :: cn_dir ! Root directory for location of ssr files |
---|
454 | TYPE(FLD_N) :: sn_patm ! informations about the fields to be read |
---|
455 | !! |
---|
456 | NAMELIST/nampisatm/ ln_presatm, sn_patm, cn_dir |
---|
457 | |
---|
458 | ! ! ----------------------- ! |
---|
459 | IF( kt == nit000 ) THEN ! First call kt=nittrc000 ! |
---|
460 | |
---|
461 | REWIND( numnatp_ref ) ! Namelist nampisatm in reference namelist : Pisces atm. sea level pressure file |
---|
462 | READ ( numnatp_ref, nampisatm, IOSTAT = ios, ERR = 901) |
---|
463 | 901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampisatm in reference namelist', lwp ) |
---|
464 | |
---|
465 | REWIND( numnatp_cfg ) ! Namelist nampisatm in configuration namelist : Pisces atm. sea level pressure file |
---|
466 | READ ( numnatp_cfg, nampisatm, IOSTAT = ios, ERR = 902 ) |
---|
467 | 902 IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampisatm in configuration namelist', lwp ) |
---|
468 | IF(lwm) WRITE ( numonp, nampisatm ) |
---|
469 | ! |
---|
470 | ! |
---|
471 | IF(lwp) THEN !* control print |
---|
472 | WRITE(numout,*) |
---|
473 | WRITE(numout,*) ' Namelist nampisatm : Atmospheric Pressure as external forcing' |
---|
474 | WRITE(numout,*) ' constant atmopsheric pressure (F) or from a file (T) ln_presatm = ', ln_presatm |
---|
475 | WRITE(numout,*) |
---|
476 | ENDIF |
---|
477 | ! |
---|
478 | IF( ln_presatm ) THEN |
---|
479 | ALLOCATE( sf_patm(1), STAT=ierr ) !* allocate and fill sf_patm (forcing structure) with sn_patm |
---|
480 | IF( ierr > 0 ) CALL ctl_stop( 'STOP', 'p4z_flx: unable to allocate sf_patm structure' ) |
---|
481 | ! |
---|
482 | CALL fld_fill( sf_patm, (/ sn_patm /), cn_dir, 'p4z_flx', 'Atmospheric pressure ', 'nampisatm' ) |
---|
483 | ALLOCATE( sf_patm(1)%fnow(jpi,jpj,1) ) |
---|
484 | IF( sn_patm%ln_tint ) ALLOCATE( sf_patm(1)%fdta(jpi,jpj,1,2) ) |
---|
485 | ENDIF |
---|
486 | ! |
---|
487 | IF( .NOT.ln_presatm ) patm(:,:) = 1.e0 ! Initialize patm if no reading from a file |
---|
488 | ! |
---|
489 | ENDIF |
---|
490 | ! |
---|
491 | IF( ln_presatm ) THEN |
---|
492 | CALL fld_read( kt, 1, sf_patm ) !* input Patm provided at kt + 1/2 |
---|
493 | patm(:,:) = sf_patm(1)%fnow(:,:,1) ! atmospheric pressure |
---|
494 | ENDIF |
---|
495 | ! |
---|
496 | END SUBROUTINE p4z_patm |
---|
497 | |
---|
498 | INTEGER FUNCTION p4z_flx_alloc() |
---|
499 | !!---------------------------------------------------------------------- |
---|
500 | !! *** ROUTINE p4z_flx_alloc *** |
---|
501 | !!---------------------------------------------------------------------- |
---|
502 | ALLOCATE( oce_co2(jpi,jpj), satmco2(jpi,jpj), patm(jpi,jpj), STAT=p4z_flx_alloc ) |
---|
503 | ! |
---|
504 | IF( p4z_flx_alloc /= 0 ) CALL ctl_warn('p4z_flx_alloc : failed to allocate arrays') |
---|
505 | ! |
---|
506 | END FUNCTION p4z_flx_alloc |
---|
507 | |
---|
508 | #else |
---|
509 | !!====================================================================== |
---|
510 | !! Dummy module : No PISCES bio-model |
---|
511 | !!====================================================================== |
---|
512 | CONTAINS |
---|
513 | SUBROUTINE p4z_flx( kt ) ! Empty routine |
---|
514 | INTEGER, INTENT( in ) :: kt |
---|
515 | WRITE(*,*) 'p4z_flx: You should not have seen this print! error?', kt |
---|
516 | END SUBROUTINE p4z_flx |
---|
517 | #endif |
---|
518 | |
---|
519 | !!====================================================================== |
---|
520 | END MODULE p4zflx |
---|