New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p5zsink.F90 in branches/CNRS/dev_r4826_PISCES_QUOTA/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z – NEMO

source: branches/CNRS/dev_r4826_PISCES_QUOTA/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z/p5zsink.F90 @ 5288

Last change on this file since 5288 was 5288, checked in by aumont, 9 years ago

various bug fixes and updates of PISCES quota
  • Property svn:executable set to *
File size: 39.0 KB
Line 
1MODULE p5zsink
2   !!======================================================================
3   !!                         ***  MODULE p5zsink  ***
4   !! TOP :  PISCES  vertical flux of particulate matter due to gravitational sinking
5   !!======================================================================
6   !! History :   1.0  !  2004     (O. Aumont) Original code
7   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8   !!             3.4  !  2011-06  (O. Aumont, C. Ethe) Change aggregation formula
9   !!             3.5  !  2012-07  (O. Aumont) Introduce potential time-splitting
10   !!             3.6  !  2015-05  (O. Aumont) PISCES quota
11   !!----------------------------------------------------------------------
12#if defined key_pisces_quota
13   !!----------------------------------------------------------------------
14   !!   p5z_sink       :  Compute vertical flux of particulate matter due to gravitational sinking
15   !!   p5z_sink_init  :  Unitialisation of sinking speed parameters
16   !!   p5z_sink_alloc :  Allocate sinking speed variables
17   !!----------------------------------------------------------------------
18   USE oce_trc         !  shared variables between ocean and passive tracers
19   USE trc             !  passive tracers common variables
20   USE sms_pisces      !  PISCES Source Minus Sink variables
21   USE prtctl_trc      !  print control for debugging
22   USE iom             !  I/O manager
23   USE lib_mpp
24
25   IMPLICIT NONE
26   PRIVATE
27
28   PUBLIC   p5z_sink         ! called in p5zbio.F90
29   PUBLIC   p5z_sink_init    ! called in trcsms_pisces.F90
30   PUBLIC   p5z_sink_alloc
31
32   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   wsbio3   !: POC sinking speed
33   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   wsbio4   !: GOC sinking speed
34   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   wscal    !: Calcite and BSi sinking speeds
35
36   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   sinking, sinking2  !: POC sinking fluxes
37   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   sinkingn, sinking2n  !: POC sinking fluxes
38   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   sinkingp, sinking2p  !: POC sinking fluxes
39   !                                                          !  (different meanings depending on the parameterization)
40   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   sinkcal, sinksil   !: CaCO3 and BSi sinking fluxes
41   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   sinkfer            !: Small BFe sinking fluxes
42#if ! defined key_kriest
43   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   sinkfer2           !: Big iron sinking fluxes
44#endif
45
46   INTEGER  :: iksed  = 10
47
48#if  defined key_kriest
49   REAL(wp) ::  xkr_sfact    !: Sinking factor
50   REAL(wp) ::  xkr_stick    !: Stickiness
51   REAL(wp) ::  xkr_nnano    !: Nbr of cell in nano size class
52   REAL(wp) ::  xkr_ndiat    !: Nbr of cell in diatoms size class
53   REAL(wp) ::  xkr_nmicro   !: Nbr of cell in microzoo size class
54   REAL(wp) ::  xkr_nmeso    !: Nbr of cell in mesozoo  size class
55   REAL(wp) ::  xkr_naggr    !: Nbr of cell in aggregates  size class
56
57   REAL(wp) ::  xkr_frac 
58
59   REAL(wp), PUBLIC ::  xkr_dnano       !: Size of particles in nano pool
60   REAL(wp), PUBLIC ::  xkr_ddiat       !: Size of particles in diatoms pool
61   REAL(wp), PUBLIC ::  xkr_dmicro      !: Size of particles in microzoo pool
62   REAL(wp), PUBLIC ::  xkr_dmeso       !: Size of particles in mesozoo pool
63   REAL(wp), PUBLIC ::  xkr_daggr       !: Size of particles in aggregates pool
64   REAL(wp), PUBLIC ::  xkr_wsbio_min   !: min vertical particle speed
65   REAL(wp), PUBLIC ::  xkr_wsbio_max   !: max vertical particle speed
66
67   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:) ::   xnumm   !:  maximum number of particles in aggregates
68#endif
69
70   !!* Substitution
71#  include "top_substitute.h90"
72   !!----------------------------------------------------------------------
73   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
74   !! $Id: p4zsink.F90 3160 2011-11-20 14:27:18Z cetlod $
75   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
76   !!----------------------------------------------------------------------
77CONTAINS
78
79#if ! defined key_kriest
80   !!----------------------------------------------------------------------
81   !!   'standard sinking parameterisation'                  ???
82   !!----------------------------------------------------------------------
83
84   SUBROUTINE p5z_sink ( kt, jnt )
85      !!---------------------------------------------------------------------
86      !!                     ***  ROUTINE p5z_sink  ***
87      !!
88      !! ** Purpose :   Compute vertical flux of particulate matter due to
89      !!                gravitational sinking
90      !!
91      !! ** Method  : - ???
92      !!---------------------------------------------------------------------
93      INTEGER, INTENT(in) :: kt, jnt
94      INTEGER  ::   ji, jj, jk, jit
95      INTEGER  ::   iiter1, iiter2
96      REAL(wp) ::   zaggpoc1, zaggpoc2, zaggpoc3, zaggpoc4
97      REAL(wp) ::   zaggpoc , zaggfe, zaggdoc, zaggdoc2, zaggdoc3
98      REAL(wp) ::   zaggpon , zaggdon, zaggdon2, zaggdon3
99      REAL(wp) ::   zaggpop, zaggdop, zaggdop2, zaggdop3
100      REAL(wp) ::   zaggtmp, zfact, zwsmax, zmax, zstep
101      REAL(wp) ::   zrfact2
102      INTEGER  ::   ik1
103      CHARACTER (len=25) :: charout
104      !!---------------------------------------------------------------------
105      !
106      IF( nn_timing == 1 )  CALL timing_start('p5z_sink')
107      !
108      !    Sinking speeds of detritus is increased with depth as shown
109      !    by data and from the coagulation theory
110      !    -----------------------------------------------------------
111      DO jk = 1, jpkm1
112         DO jj = 1, jpj
113            DO ji = 1,jpi
114               zmax  = MAX( heup_01(ji,jj), hmld(ji,jj) )
115               zfact = MAX( 0., fsdepw(ji,jj,jk+1) - zmax ) / 5000._wp
116               wsbio4(ji,jj,jk) = wsbio2 
117            END DO
118         END DO
119      END DO
120
121      ! limit the values of the sinking speeds to avoid numerical instabilities 
122      wsbio3(:,:,:) = wsbio
123      wscal(:,:,:) = wsbio4(:,:,:)
124      !
125      ! OA This is (I hope) a temporary solution for the problem that may
126      ! OA arise in specific situation where the CFL criterion is broken
127      ! OA for vertical sedimentation of particles. To avoid this, a time
128      ! OA splitting algorithm has been coded. A specific maximum
129      ! OA iteration number is provided and may be specified in the namelist
130      ! OA This is to avoid very large iteration number when explicit free
131      ! OA surface is used (for instance). When niter?max is set to 1,
132      ! OA this computation is skipped. The crude old threshold method is
133      ! OA then applied. This also happens when niter exceeds nitermax.
134      IF( MAX( niter1max, niter2max ) == 1 ) THEN
135        iiter1 = 1
136        iiter2 = 1
137      ELSE
138        iiter1 = 1
139        iiter2 = 1
140        DO jk = 1, jpkm1
141          DO jj = 1, jpj
142             DO ji = 1, jpi
143                IF( tmask(ji,jj,jk) == 1) THEN
144                   zwsmax =  0.5 * fse3t(ji,jj,jk) / xstep
145                   iiter1 =  MAX( iiter1, INT( wsbio3(ji,jj,jk) / zwsmax ) )
146                   iiter2 =  MAX( iiter2, INT( wsbio4(ji,jj,jk) / zwsmax ) )
147                ENDIF
148             END DO
149          END DO
150        END DO
151        IF( lk_mpp ) THEN
152           CALL mpp_max( iiter1 )
153           CALL mpp_max( iiter2 )
154        ENDIF
155        iiter1 = MIN( iiter1, niter1max )
156        iiter2 = MIN( iiter2, niter2max )
157      ENDIF
158
159      DO jk = 1,jpkm1
160         DO jj = 1, jpj
161            DO ji = 1, jpi
162               IF( tmask(ji,jj,jk) == 1 ) THEN
163                 zwsmax = 0.5 * fse3t(ji,jj,jk) / xstep
164                 wsbio3(ji,jj,jk) = MIN( wsbio3(ji,jj,jk), zwsmax * FLOAT( iiter1 ) )
165                 wsbio4(ji,jj,jk) = MIN( wsbio4(ji,jj,jk), zwsmax * FLOAT( iiter2 ) )
166               ENDIF
167            END DO
168         END DO
169      END DO
170
171      !  Initializa to zero all the sinking arrays
172      !   -----------------------------------------
173      sinking (:,:,:) = 0.e0
174      sinking2(:,:,:) = 0.e0
175      sinkingn (:,:,:) = 0.e0
176      sinking2n(:,:,:) = 0.e0
177      sinkingp (:,:,:) = 0.e0
178      sinking2p(:,:,:) = 0.e0
179      sinkcal (:,:,:) = 0.e0
180      sinkfer (:,:,:) = 0.e0
181      sinksil (:,:,:) = 0.e0
182      sinkfer2(:,:,:) = 0.e0
183
184      !   Compute the sedimentation term using p4zsink2 for all the sinking particles
185      !   -----------------------------------------------------
186      DO jit = 1, iiter1
187        CALL p4z_sink2( wsbio3, sinking , jppoc, iiter1 )
188        CALL p4z_sink2( wsbio3, sinkingn , jppon, iiter1 )
189        CALL p4z_sink2( wsbio3, sinkingp , jppop, iiter1 )
190        CALL p4z_sink2( wsbio3, sinkfer , jpsfe, iiter1 )
191      END DO
192
193      DO jit = 1, iiter2
194        CALL p4z_sink2( wsbio4, sinking2, jpgoc, iiter2 )
195        CALL p4z_sink2( wsbio4, sinking2n, jpgon, iiter2 )
196        CALL p4z_sink2( wsbio4, sinking2p, jpgop, iiter2 )
197        CALL p4z_sink2( wsbio4, sinkfer2, jpbfe, iiter2 )
198        CALL p4z_sink2( wscal , sinksil , jpgsi, iiter2 )
199        CALL p4z_sink2( wscal , sinkcal , jpcal, iiter2 )
200      END DO
201
202      !  Exchange between organic matter compartments due to coagulation/disaggregation
203      !  ---------------------------------------------------
204      DO jk = 1, jpkm1
205         DO jj = 1, jpj
206            DO ji = 1, jpi
207               !
208               zstep = xstep 
209# if defined key_degrad
210               zstep = zstep * facvol(ji,jj,jk)
211# endif
212               zfact = zstep * xdiss(ji,jj,jk)
213               !  Part I : Coagulation dependent on turbulence
214               zaggtmp = 25.9  * zfact * trn(ji,jj,jk,jppoc)
215               zaggpoc1 = zaggtmp * trn(ji,jj,jk,jppoc)
216               zaggtmp = 4452. * zfact * trn(ji,jj,jk,jpgoc)
217               zaggpoc2 = zaggtmp * trn(ji,jj,jk,jppoc)
218
219               ! Part II : Differential settling
220
221               !  Aggregation of small into large particles
222               zaggtmp =  47.1 * zstep * trn(ji,jj,jk,jpgoc)
223               zaggpoc3 = zaggtmp * trn(ji,jj,jk,jppoc)
224               zaggtmp =  3.3  * zstep * trn(ji,jj,jk,jppoc)
225               zaggpoc4 = zaggtmp * trn(ji,jj,jk,jppoc)
226
227               zaggpoc   = zaggpoc1 + zaggpoc2 + zaggpoc3 + zaggpoc4
228               zaggpon = zaggpoc * trn(ji,jj,jk,jppon) / ( trn(ji,jj,jk,jppoc) + rtrn)
229               zaggpop = zaggpoc * trn(ji,jj,jk,jppop) / ( trn(ji,jj,jk,jppoc) + rtrn)
230               zaggfe = zaggpoc * trn(ji,jj,jk,jpsfe) / ( trn(ji,jj,jk,jppoc)  + rtrn )
231
232               ! Aggregation of DOC to POC :
233               ! 1st term is shear aggregation of DOC-DOC
234               ! 2nd term is shear aggregation of DOC-POC
235               ! 3rd term is differential settling of DOC-POC
236               zaggtmp = ( ( 0.369 * 0.3 * trn(ji,jj,jk,jpdoc) + 102.4 * trn(ji,jj,jk,jppoc) ) * zfact       &
237               &            + 2.4 * zstep * trn(ji,jj,jk,jppoc) )
238               zaggdoc  = zaggtmp * 0.3 * trn(ji,jj,jk,jpdoc)
239               zaggdon  = zaggtmp * 0.3 * trn(ji,jj,jk,jpdon)
240               zaggdop  = zaggtmp * 0.3 * trn(ji,jj,jk,jpdop)
241
242               ! transfer of DOC to GOC :
243               ! 1st term is shear aggregation
244               ! 2nd term is differential settling
245               zaggtmp = ( 3.53E3 * zfact + 0.1 * zstep ) * trn(ji,jj,jk,jpgoc)
246               zaggdoc2 = zaggtmp * 0.3 * trn(ji,jj,jk,jpdoc)
247               zaggdon2 = zaggtmp * 0.3 * trn(ji,jj,jk,jpdon)
248               zaggdop2 = zaggtmp * 0.3 * trn(ji,jj,jk,jpdop)
249
250               ! tranfer of DOC to POC due to brownian motion
251               zaggtmp = ( 5095. * trn(ji,jj,jk,jppoc) + 114. * 0.3 * trn(ji,jj,jk,jpdoc) ) *zstep
252               zaggdoc3 =  zaggtmp * 0.3 * trn(ji,jj,jk,jpdoc)
253               zaggdon3 =  zaggtmp * 0.3 * trn(ji,jj,jk,jpdon)
254               zaggdop3 =  zaggtmp * 0.3 * trn(ji,jj,jk,jpdop)
255
256               !  Update the trends
257               tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) - zaggpoc + zaggdoc + zaggdoc3
258               tra(ji,jj,jk,jppon) = tra(ji,jj,jk,jppon) - zaggpon + zaggdon + zaggdon3
259               tra(ji,jj,jk,jppop) = tra(ji,jj,jk,jppop) - zaggpop + zaggdop + zaggdop3
260               tra(ji,jj,jk,jpgoc) = tra(ji,jj,jk,jpgoc) + zaggpoc + zaggdoc2
261               tra(ji,jj,jk,jpgon) = tra(ji,jj,jk,jpgon) + zaggpon + zaggdon2
262               tra(ji,jj,jk,jpgop) = tra(ji,jj,jk,jpgop) + zaggpop + zaggdop2
263               tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) - zaggfe
264               tra(ji,jj,jk,jpbfe) = tra(ji,jj,jk,jpbfe) + zaggfe
265               tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) - zaggdoc - zaggdoc2 - zaggdoc3
266               tra(ji,jj,jk,jpdon) = tra(ji,jj,jk,jpdon) - zaggdon - zaggdon2 - zaggdon3
267               tra(ji,jj,jk,jpdop) = tra(ji,jj,jk,jpdop) - zaggdop - zaggdop2 - zaggdop3
268               !
269            END DO
270         END DO
271      END DO
272
273     ! Total primary production per year
274     t_oce_co2_exp = t_oce_co2_exp + glob_sum( ( sinking(:,:,iksed+1) + sinking2(:,:,iksed+1) ) * e1e2t(:,:) * tmask(:,:,1) )
275     !
276     IF( ln_diatrc ) THEN
277         zrfact2 = 1.e3 * rfact2r
278         ik1  = iksed + 1
279         IF( lk_iomput ) THEN
280           IF( jnt == nrdttrc ) THEN
281              CALL iom_put( "EPC100"  , ( sinking(:,:,ik1) + sinking2(:,:,ik1) ) * zrfact2 * tmask(:,:,1) ) ! Export of carbon at 100m
282              CALL iom_put( "EPFE100" , ( sinkfer(:,:,ik1) + sinkfer2(:,:,ik1) ) * zrfact2 * tmask(:,:,1) ) ! Export of iron at 100m
283              CALL iom_put( "EPCAL100",   sinkcal(:,:,ik1)                       * zrfact2 * tmask(:,:,1) ) ! Export of calcite  at 100m
284              CALL iom_put( "EPSI100" ,   sinksil(:,:,ik1)                       * zrfact2 * tmask(:,:,1) ) ! Export of biogenic silica at 100m
285           ENDIF
286         ELSE
287           trc2d(:,:,jp_pcs0_2d + 4) = sinking (:,:,ik1) * zrfact2 * tmask(:,:,1)
288           trc2d(:,:,jp_pcs0_2d + 5) = sinking2(:,:,ik1) * zrfact2 * tmask(:,:,1)
289           trc2d(:,:,jp_pcs0_2d + 6) = sinkfer (:,:,ik1) * zrfact2 * tmask(:,:,1)
290           trc2d(:,:,jp_pcs0_2d + 7) = sinkfer2(:,:,ik1) * zrfact2 * tmask(:,:,1)
291           trc2d(:,:,jp_pcs0_2d + 8) = sinksil (:,:,ik1) * zrfact2 * tmask(:,:,1)
292           trc2d(:,:,jp_pcs0_2d + 9) = sinkcal (:,:,ik1) * zrfact2 * tmask(:,:,1)
293         ENDIF
294      ENDIF
295      !
296      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
297         WRITE(charout, FMT="('sink')")
298         CALL prt_ctl_trc_info(charout)
299         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
300      ENDIF
301      !
302      IF( nn_timing == 1 )  CALL timing_stop('p5z_sink')
303      !
304   END SUBROUTINE p5z_sink
305
306   SUBROUTINE p5z_sink_init
307      !!----------------------------------------------------------------------
308      !!                  ***  ROUTINE p5z_sink_init  ***
309      !!----------------------------------------------------------------------
310
311      t_oce_co2_exp = 0._wp
312      !
313   END SUBROUTINE p5z_sink_init
314
315#else
316   !!----------------------------------------------------------------------
317   !!   'Kriest sinking parameterisation'        key_kriest          ???
318   !!----------------------------------------------------------------------
319
320   SUBROUTINE p5z_sink ( kt, jnt )
321      !!---------------------------------------------------------------------
322      !!                ***  ROUTINE p5z_sink  ***
323      !!
324      !! ** Purpose :   Compute vertical flux of particulate matter due to
325      !!              gravitational sinking - Kriest parameterization
326      !!
327      !! ** Method  : - ???
328      !!---------------------------------------------------------------------
329      !
330      INTEGER, INTENT(in) :: kt, jnt
331      !
332      INTEGER  :: ji, jj, jk, jit, niter1, niter2
333      REAL(wp) :: zagg1, zagg2, zagg3, zagg4, zagg5, zfract, zaggsi, zaggsh
334      REAL(wp) :: zagg , zaggdoc, zaggdoc1, znumdoc
335      REAL(wp) :: znum , zeps, zfm, zgm, zsm, zfactn, zfactp
336      REAL(wp) :: zdiv , zdiv1, zdiv2, zdiv3, zdiv4, zdiv5
337      REAL(wp) :: zval1, zval2, zval3, zval4
338      REAL(wp) :: zrfact2
339      INTEGER  :: ik1
340      CHARACTER (len=25) :: charout
341      REAL(wp), POINTER, DIMENSION(:,:,:) :: znum3d 
342      !!---------------------------------------------------------------------
343      !
344      IF( nn_timing == 1 )  CALL timing_start('p5z_sink')
345      !
346      CALL wrk_alloc( jpi, jpj, jpk, znum3d )
347      !
348      !     Initialisation of variables used to compute Sinking Speed
349      !     ---------------------------------------------------------
350
351      znum3d(:,:,:) = 0.e0
352      zval1 = 1. + xkr_zeta
353      zval2 = 1. + xkr_zeta + xkr_eta
354      zval3 = 1. + xkr_eta
355
356      !     Computation of the vertical sinking speed : Kriest et Evans, 2000
357      !     -----------------------------------------------------------------
358
359      DO jk = 1, jpkm1
360         DO jj = 1, jpj
361            DO ji = 1, jpi
362               IF( tmask(ji,jj,jk) /= 0.e0 ) THEN
363                  znum = trn(ji,jj,jk,jppoc) / ( trn(ji,jj,jk,jpnum) + rtrn ) / xkr_massp
364                  ! -------------- To avoid sinking speed over 50 m/day -------
365                  znum  = MIN( xnumm(jk), znum )
366                  znum  = MAX( 1.1      , znum )
367                  znum3d(ji,jj,jk) = znum
368                  !------------------------------------------------------------
369                  zeps  = ( zval1 * znum - 1. )/ ( znum - 1. )
370                  zfm   = xkr_frac**( 1. - zeps )
371                  zgm   = xkr_frac**( zval1 - zeps )
372                  zdiv  = MAX( 1.e-4, ABS( zeps - zval2 ) ) * SIGN( 1., ( zeps - zval2 ) )
373                  zdiv1 = zeps - zval3
374                  wsbio3(ji,jj,jk) = xkr_wsbio_min * ( zeps - zval1 ) / zdiv    &
375                     &             - xkr_wsbio_max *   zgm * xkr_eta  / zdiv
376                  wsbio4(ji,jj,jk) = xkr_wsbio_min *   ( zeps-1. )    / zdiv1   &
377                     &             - xkr_wsbio_max *   zfm * xkr_eta  / zdiv1
378                  IF( znum == 1.1)   wsbio3(ji,jj,jk) = wsbio4(ji,jj,jk)
379               ENDIF
380            END DO
381         END DO
382      END DO
383
384      wscal(:,:,:) = MAX( wsbio3(:,:,:), 30._wp )
385
386      !   INITIALIZE TO ZERO ALL THE SINKING ARRAYS
387      !   -----------------------------------------
388
389      sinking (:,:,:) = 0.e0
390      sinkingn(:,:,:) = 0.e0
391      sinkingp(:,:,:) = 0.e0
392      sinking2(:,:,:) = 0.e0
393      sinkcal (:,:,:) = 0.e0
394      sinkfer (:,:,:) = 0.e0
395      sinksil (:,:,:) = 0.e0
396
397     !   Compute the sedimentation term using p4zsink2 for all the sinking particles
398     !   -----------------------------------------------------
399
400      niter1 = niter1max
401      niter2 = niter2max
402
403      DO jit = 1, niter1
404        CALL p4z_sink2( wsbio3, sinking , jppoc, niter1 )
405        CALL p4z_sink2( wsbio3, sinkingn, jppon, niter1 )
406        CALL p4z_sink2( wsbio3, sinkingp, jppop, niter1 )
407        CALL p4z_sink2( wsbio3, sinkfer , jpsfe, niter1 )
408        CALL p4z_sink2( wscal , sinksil , jpgsi, niter1 )
409        CALL p4z_sink2( wscal , sinkcal , jpcal, niter1 )
410      END DO
411
412      DO jit = 1, niter2
413        CALL p4z_sink2( wsbio4, sinking2, jpnum, niter2 )
414      END DO
415
416     !  Exchange between organic matter compartments due to coagulation/disaggregation
417     !  ---------------------------------------------------
418
419      zval1 = 1. + xkr_zeta
420      zval2 = 1. + xkr_eta
421      zval3 = 3. + xkr_eta
422      zval4 = 4. + xkr_eta
423
424      DO jk = 1,jpkm1
425         DO jj = 1,jpj
426            DO ji = 1,jpi
427               IF( tmask(ji,jj,jk) /= 0.e0 ) THEN
428
429                  znum = trn(ji,jj,jk,jppoc)/(trn(ji,jj,jk,jpnum)+rtrn) / xkr_massp
430                  !-------------- To avoid sinking speed over 50 m/day -------
431                  znum  = min(xnumm(jk),znum)
432                  znum  = MAX( 1.1,znum)
433                  !------------------------------------------------------------
434                  zeps  = ( zval1 * znum - 1.) / ( znum - 1.)
435                  zdiv  = MAX( 1.e-4, ABS( zeps - zval3) ) * SIGN( 1., zeps - zval3 )
436                  zdiv1 = MAX( 1.e-4, ABS( zeps - 4.   ) ) * SIGN( 1., zeps - 4.    )
437                  zdiv2 = zeps - 2.
438                  zdiv3 = zeps - 3.
439                  zdiv4 = zeps - zval2
440                  zdiv5 = 2.* zeps - zval4
441                  zfm   = xkr_frac**( 1.- zeps )
442                  zsm   = xkr_frac**xkr_eta
443
444                  !    Part I : Coagulation dependant on turbulence
445                  !    ----------------------------------------------
446                  zagg1 =  0.163  * trn(ji,jj,jk,jpnum)**2                                 &
447                     &            * 2.*( (zfm-1.)*(zfm*xkr_mass_max**3-xkr_mass_min**3)    &
448                     &            * (zeps-1)/zdiv1 + 3.*(zfm*xkr_mass_max-xkr_mass_min)    &
449                     &            * (zfm*xkr_mass_max**2-xkr_mass_min**2)                  &
450                     &            * (zeps-1.)**2/(zdiv2*zdiv3)) 
451                  zagg2 =  2*0.163*trn(ji,jj,jk,jpnum)**2*zfm                        &
452                     &            * ((xkr_mass_max**3+3.*(xkr_mass_max**2            &
453                     &            * xkr_mass_min*(zeps-1.)/zdiv2                     &
454                     &            + xkr_mass_max*xkr_mass_min**2*(zeps-1.)/zdiv3)    &
455                     &            + xkr_mass_min**3*(zeps-1)/zdiv1)                  &
456                     &            - zfm*xkr_mass_max**3*(1.+3.*((zeps-1.)            &
457                     &            / (zeps-2.)+(zeps-1.)/zdiv3)+(zeps-1.)/zdiv1))   
458
459                  zagg3 =  0.163*trn(ji,jj,jk,jpnum)**2*zfm**2*8. * xkr_mass_max**3 
460                 
461                 !    Aggregation of small into large particles
462                 !    Part II : Differential settling
463                 !    ----------------------------------------------
464                  zagg4 =  2.*3.141*0.125*trn(ji,jj,jk,jpnum)**2*                       &
465                     &                 xkr_wsbio_min*(zeps-1.)**2                         &
466                     &                 *(xkr_mass_min**2*((1.-zsm*zfm)/(zdiv3*zdiv4)      &
467                     &                 -(1.-zfm)/(zdiv*(zeps-1.)))-                       &
468                     &                 ((zfm*zfm*xkr_mass_max**2*zsm-xkr_mass_min**2)     &
469                     &                 *xkr_eta)/(zdiv*zdiv3*zdiv5) )   
470
471                  zagg5 =   2.*3.141*0.125*trn(ji,jj,jk,jpnum)**2                         &
472                     &                 *(zeps-1.)*zfm*xkr_wsbio_min                        &
473                     &                 *(zsm*(xkr_mass_min**2-zfm*xkr_mass_max**2)         &
474                     &                 /zdiv3-(xkr_mass_min**2-zfm*zsm*xkr_mass_max**2)    &
475                     &                 /zdiv) 
476
477                  !
478                  !     Fractionnation by swimming organisms
479                  !     ------------------------------------
480                  zfract = 2.*3.141*0.125*trn(ji,jj,jk,jpmes)*12./0.12/0.06**3*trn(ji,jj,jk,jpnum)  &
481                    &      * (0.01/xkr_mass_min)**(1.-zeps)*0.1**2  &
482                    &      * 10000.*xstep
483
484                  !     Aggregation of DOC to small particles
485                  !     --------------------------------------
486                  zaggdoc = 0.83 * trn(ji,jj,jk,jpdoc) * xstep * xdiss(ji,jj,jk) * trn(ji,jj,jk,jpdoc)   &
487                     &        + 0.005 * 231. * trn(ji,jj,jk,jpdoc) * xstep * trn(ji,jj,jk,jpdoc)
488                  zaggdoc1 = 271. * trn(ji,jj,jk,jppoc) * xstep * xdiss(ji,jj,jk) * trn(ji,jj,jk,jpdoc)  &
489                     &  + 0.02 * 16706. * trn(ji,jj,jk,jppoc) * xstep * trn(ji,jj,jk,jpdoc)
490
491# if defined key_degrad
492                   zagg1   = zagg1   * facvol(ji,jj,jk)                 
493                   zagg2   = zagg2   * facvol(ji,jj,jk)                 
494                   zagg3   = zagg3   * facvol(ji,jj,jk)                 
495                   zagg4   = zagg4   * facvol(ji,jj,jk)                 
496                   zagg5   = zagg5   * facvol(ji,jj,jk)                 
497                   zaggdoc = zaggdoc * facvol(ji,jj,jk)                 
498                   zaggdoc1 = zaggdoc1 * facvol(ji,jj,jk)
499# endif
500                  zaggsh = ( zagg1 + zagg2 + zagg3 ) * rfact2 * xdiss(ji,jj,jk) / 1000.
501                  zaggsi = ( zagg4 + zagg5 ) * xstep / 10.
502                  zagg = 0.5 * xkr_stick * ( zaggsh + zaggsi )
503                  !
504                  znumdoc = trn(ji,jj,jk,jpnum) / ( trn(ji,jj,jk,jppoc) + rtrn )
505                  tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) + zaggdoc + zaggdoc1
506                  zfactn  = trn(ji,jj,jk,jpdon) / ( trn(ji,jj,jk,jpdoc) + rtrn )
507                  tra(ji,jj,jk,jppon) = tra(ji,jj,jk,jppon) + ( zaggdoc + zaggdoc1 ) * zfactn
508                  zfactp  = trn(ji,jj,jk,jpdop) / ( trn(ji,jj,jk,jpdoc) + rtrn )
509                  tra(ji,jj,jk,jppop) = tra(ji,jj,jk,jppop) + ( zaggdoc + zaggdoc1 ) * zfactp
510                  tra(ji,jj,jk,jpnum) = tra(ji,jj,jk,jpnum) + zfract + zaggdoc / xkr_massp - zagg
511                  tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) - zaggdoc - zaggdoc1
512
513               ENDIF
514            END DO
515         END DO
516      END DO
517
518     ! Total primary production per year
519     t_oce_co2_exp = t_oce_co2_exp + glob_sum( ( sinking(:,:,:) ) * cvol(:,:,:) )
520     !
521      IF( ln_diatrc ) THEN
522         !
523         ik1 = iksed + 1
524         zrfact2 = 1.e3 * rfact2r
525         IF( jnt == nrdttrc ) THEN
526           CALL iom_put( "POCFlx"  , sinking (:,:,:)      * zrfact2 * tmask(:,:,:) )  ! POC export
527           CALL iom_put( "NumFlx"  , sinking2 (:,:,:)     * zrfact2 * tmask(:,:,:) )  ! Num export
528           CALL iom_put( "SiFlx"   , sinksil (:,:,:)      * zrfact2 * tmask(:,:,:) )  ! Silica export
529           CALL iom_put( "CaCO3Flx", sinkcal (:,:,:)      * zrfact2 * tmask(:,:,:) )  ! Calcite export
530           CALL iom_put( "xnum"    , znum3d  (:,:,:)                * tmask(:,:,:) )  ! Number of particles in aggregats
531           CALL iom_put( "W1"      , wsbio3  (:,:,:)                * tmask(:,:,:) )  ! sinking speed of POC
532           CALL iom_put( "W2"      , wsbio4  (:,:,:)                * tmask(:,:,:) )  ! sinking speed of aggregats
533         ENDIF
534# if ! defined key_iomput
535         trc2d(:,:  ,jp_pcs0_2d + 4)  = sinking (:,:,ik1)    * zrfact2 * tmask(:,:,1)
536         trc2d(:,:  ,jp_pcs0_2d + 5)  = sinking2(:,:,ik1)    * zrfact2 * tmask(:,:,1)
537         trc2d(:,:  ,jp_pcs0_2d + 6)  = sinkfer (:,:,ik1)    * zrfact2 * tmask(:,:,1)
538         trc2d(:,:  ,jp_pcs0_2d + 7)  = sinksil (:,:,ik1)    * zrfact2 * tmask(:,:,1)
539         trc2d(:,:  ,jp_pcs0_2d + 8)  = sinkcal (:,:,ik1)    * zrfact2 * tmask(:,:,1)
540         trc3d(:,:,:,jp_pcs0_3d + 11) = sinking (:,:,:)      * zrfact2 * tmask(:,:,:)
541         trc3d(:,:,:,jp_pcs0_3d + 12) = sinking2(:,:,:)      * zrfact2 * tmask(:,:,:)
542         trc3d(:,:,:,jp_pcs0_3d + 13) = sinksil (:,:,:)      * zrfact2 * tmask(:,:,:)
543         trc3d(:,:,:,jp_pcs0_3d + 14) = sinkcal (:,:,:)      * zrfact2 * tmask(:,:,:)
544         trc3d(:,:,:,jp_pcs0_3d + 15) = znum3d  (:,:,:)                * tmask(:,:,:)
545         trc3d(:,:,:,jp_pcs0_3d + 16) = wsbio3  (:,:,:)                * tmask(:,:,:)
546         trc3d(:,:,:,jp_pcs0_3d + 17) = wsbio4  (:,:,:)                * tmask(:,:,:)
547# endif
548        !
549      ENDIF
550      !
551      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
552         WRITE(charout, FMT="('sink')")
553         CALL prt_ctl_trc_info(charout)
554         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
555      ENDIF
556      !
557      CALL wrk_dealloc( jpi, jpj, jpk, znum3d )
558      !
559      IF( nn_timing == 1 )  CALL timing_stop('p5z_sink')
560      !
561   END SUBROUTINE p5z_sink
562
563
564   SUBROUTINE p5z_sink_init
565      !!----------------------------------------------------------------------
566      !!                  ***  ROUTINE p5z_sink_init  ***
567      !!
568      !! ** Purpose :   Initialization of sinking parameters
569      !!                Kriest parameterization only
570      !!
571      !! ** Method  :   Read the nampiskrs namelist and check the parameters
572      !!      called at the first timestep
573      !!
574      !! ** input   :   Namelist nampiskrs
575      !!----------------------------------------------------------------------
576      INTEGER  ::   jk, jn, kiter
577      INTEGER  ::   ios                 ! Local integer output status for namelist read
578      REAL(wp) ::   znum, zdiv
579      REAL(wp) ::   zws, zwr, zwl,wmax, znummax
580      REAL(wp) ::   zmin, zmax, zl, zr, xacc
581      !
582      NAMELIST/nampiskrs/ xkr_sfact, xkr_stick ,  &
583         &                xkr_nnano, xkr_ndiat, xkr_nmicro, xkr_nmeso, xkr_naggr
584      !!----------------------------------------------------------------------
585      !
586      IF( nn_timing == 1 )  CALL timing_start('p5z_sink_init')
587      !
588
589      REWIND( numnatp_ref )              ! Namelist nampiskrs in reference namelist : Pisces sinking Kriest
590      READ  ( numnatp_ref, nampiskrs, IOSTAT = ios, ERR = 901)
591901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampiskrs in reference namelist', lwp )
592
593      REWIND( numnatp_cfg )              ! Namelist nampiskrs in configuration namelist : Pisces sinking Kriest
594      READ  ( numnatp_cfg, nampiskrs, IOSTAT = ios, ERR = 902 )
595902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampiskrs in configuration namelist', lwp )
596      IF(lwm) WRITE ( numonp, nampiskrs )
597
598      IF(lwp) THEN
599         WRITE(numout,*)
600         WRITE(numout,*) ' Namelist : nampiskrs'
601         WRITE(numout,*) '    Sinking factor                           xkr_sfact    = ', xkr_sfact
602         WRITE(numout,*) '    Stickiness                               xkr_stick    = ', xkr_stick
603         WRITE(numout,*) '    Nbr of cell in nano size class           xkr_nnano    = ', xkr_nnano
604         WRITE(numout,*) '    Nbr of cell in diatoms size class        xkr_ndiat    = ', xkr_ndiat
605         WRITE(numout,*) '    Nbr of cell in microzoo size class       xkr_nmicro   = ', xkr_nmicro
606         WRITE(numout,*) '    Nbr of cell in mesozoo size class        xkr_nmeso    = ', xkr_nmeso
607         WRITE(numout,*) '    Nbr of cell in aggregates size class     xkr_naggr    = ', xkr_naggr
608      ENDIF
609
610
611      ! max and min vertical particle speed
612      xkr_wsbio_min = xkr_sfact * xkr_mass_min**xkr_eta
613      xkr_wsbio_max = xkr_sfact * xkr_mass_max**xkr_eta
614      IF (lwp) WRITE(numout,*) ' max and min vertical particle speed ', xkr_wsbio_min, xkr_wsbio_max
615
616      !
617      !    effect of the sizes of the different living pools on particle numbers
618      !    nano = 2um-20um -> mean size=6.32 um -> ws=2.596 -> xnum=xnnano=2.337
619      !    diat and microzoo = 10um-200um -> 44.7 -> 8.732 -> xnum=xndiat=3.718
620      !    mesozoo = 200um-2mm -> 632.45 -> 45.14 -> xnum=xnmeso=7.147
621      !    aggregates = 200um-10mm -> 1414 -> 74.34 -> xnum=xnaggr=9.877
622      !    doc aggregates = 1um
623      ! ----------------------------------------------------------
624
625      xkr_dnano = 1. / ( xkr_massp * xkr_nnano )
626      xkr_ddiat = 1. / ( xkr_massp * xkr_ndiat )
627      xkr_dmicro = 1. / ( xkr_massp * xkr_nmicro )
628      xkr_dmeso = 1. / ( xkr_massp * xkr_nmeso )
629      xkr_daggr = 1. / ( xkr_massp * xkr_naggr )
630
631      !!---------------------------------------------------------------------
632      !!    'key_kriest'                                                  ???
633      !!---------------------------------------------------------------------
634      !  COMPUTATION OF THE VERTICAL PROFILE OF MAXIMUM SINKING SPEED
635      !  Search of the maximum number of particles in aggregates for each k-level.
636      !  Bissection Method
637      !--------------------------------------------------------------------
638      IF (lwp) THEN
639        WRITE(numout,*)
640        WRITE(numout,*)'    kriest : Compute maximum number of particles in aggregates'
641      ENDIF
642
643      xacc     =  0.001_wp
644      kiter    = 50
645      zmin     =  1.10_wp
646      zmax     = xkr_mass_max / xkr_mass_min
647      xkr_frac = zmax
648
649      DO jk = 1,jpk
650         zl = zmin
651         zr = zmax
652         wmax = 0.5 * fse3t(1,1,jk) * rday * float(niter1max) / rfact2
653         zdiv = xkr_zeta + xkr_eta - xkr_eta * zl
654         znum = zl - 1.
655         zwl =  xkr_wsbio_min * xkr_zeta / zdiv &
656            & - ( xkr_wsbio_max * xkr_eta * znum * &
657            &     xkr_frac**( -xkr_zeta / znum ) / zdiv ) &
658            & - wmax
659
660         zdiv = xkr_zeta + xkr_eta - xkr_eta * zr
661         znum = zr - 1.
662         zwr =  xkr_wsbio_min * xkr_zeta / zdiv &
663            & - ( xkr_wsbio_max * xkr_eta * znum * &
664            &     xkr_frac**( -xkr_zeta / znum ) / zdiv ) &
665            & - wmax
666iflag:   DO jn = 1, kiter
667            IF    ( zwl == 0._wp ) THEN   ;   znummax = zl
668            ELSEIF( zwr == 0._wp ) THEN   ;   znummax = zr
669            ELSE
670               znummax = ( zr + zl ) / 2.
671               zdiv = xkr_zeta + xkr_eta - xkr_eta * znummax
672               znum = znummax - 1.
673               zws =  xkr_wsbio_min * xkr_zeta / zdiv &
674                  & - ( xkr_wsbio_max * xkr_eta * znum * &
675                  &     xkr_frac**( -xkr_zeta / znum ) / zdiv ) &
676                  & - wmax
677               IF( zws * zwl < 0. ) THEN   ;   zr = znummax
678               ELSE                        ;   zl = znummax
679               ENDIF
680               zdiv = xkr_zeta + xkr_eta - xkr_eta * zl
681               znum = zl - 1.
682               zwl =  xkr_wsbio_min * xkr_zeta / zdiv &
683                  & - ( xkr_wsbio_max * xkr_eta * znum * &
684                  &     xkr_frac**( -xkr_zeta / znum ) / zdiv ) &
685                  & - wmax
686
687               zdiv = xkr_zeta + xkr_eta - xkr_eta * zr
688               znum = zr - 1.
689               zwr =  xkr_wsbio_min * xkr_zeta / zdiv &
690                  & - ( xkr_wsbio_max * xkr_eta * znum * &
691                  &     xkr_frac**( -xkr_zeta / znum ) / zdiv ) &
692                  & - wmax
693               !
694               IF ( ABS ( zws )  <= xacc ) EXIT iflag
695               !
696            ENDIF
697            !
698         END DO iflag
699
700         xnumm(jk) = znummax
701         IF (lwp) WRITE(numout,*) '       jk = ', jk, ' wmax = ', wmax,' xnum max = ', xnumm(jk)
702         !
703      END DO
704      !
705      t_oce_co2_exp = 0._wp
706      !
707      IF( nn_timing == 1 )  CALL timing_stop('p5z_sink_init')
708      !
709  END SUBROUTINE p5z_sink_init
710
711#endif
712
713   SUBROUTINE p4z_sink2( pwsink, psinkflx, jp_tra, kiter )
714      !!---------------------------------------------------------------------
715      !!                     ***  ROUTINE p4z_sink2  ***
716      !!
717      !! ** Purpose :   Compute the sedimentation terms for the various sinking
718      !!     particles. The scheme used to compute the trends is based
719      !!     on MUSCL.
720      !!
721      !! ** Method  : - this ROUTINE compute not exactly the advection but the
722      !!      transport term, i.e.  div(u*tra).
723      !!---------------------------------------------------------------------
724      !
725      INTEGER , INTENT(in   )                         ::   jp_tra    ! tracer index index     
726      INTEGER , INTENT(in   )                         ::   kiter     ! number of iterations for time-splitting
727      REAL(wp), INTENT(in   ), DIMENSION(jpi,jpj,jpk) ::   pwsink    ! sinking speed
728      REAL(wp), INTENT(inout), DIMENSION(jpi,jpj,jpk) ::   psinkflx  ! sinking fluxe
729      !!
730      INTEGER  ::   ji, jj, jk, jn
731      REAL(wp) ::   zigma,zew,zign, zflx, zstep
732      REAL(wp), POINTER, DIMENSION(:,:,:) :: ztraz, zakz, zwsink2, ztrb 
733      !!---------------------------------------------------------------------
734      !
735      IF( nn_timing == 1 )  CALL timing_start('p4z_sink2')
736      !
737      ! Allocate temporary workspace
738      CALL wrk_alloc( jpi, jpj, jpk, ztraz, zakz, zwsink2, ztrb )
739
740      zstep = rfact2 / FLOAT( kiter ) / 2.
741
742      ztraz(:,:,:) = 0.e0
743      zakz (:,:,:) = 0.e0
744      ztrb (:,:,:) = trn(:,:,:,jp_tra)
745
746      DO jk = 1, jpkm1
747         zwsink2(:,:,jk+1) = -pwsink(:,:,jk) / rday * tmask(:,:,jk+1) 
748      END DO
749      zwsink2(:,:,1) = 0.e0
750      IF( lk_degrad ) THEN
751         zwsink2(:,:,:) = zwsink2(:,:,:) * facvol(:,:,:)
752      ENDIF
753
754
755      ! Vertical advective flux
756      DO jn = 1, 2
757         !  first guess of the slopes interior values
758         DO jk = 2, jpkm1
759            ztraz(:,:,jk) = ( trn(:,:,jk-1,jp_tra) - trn(:,:,jk,jp_tra) ) * tmask(:,:,jk)
760         END DO
761         ztraz(:,:,1  ) = 0.0
762         ztraz(:,:,jpk) = 0.0
763
764         ! slopes
765         DO jk = 2, jpkm1
766            DO jj = 1,jpj
767               DO ji = 1, jpi
768                  zign = 0.25 + SIGN( 0.25, ztraz(ji,jj,jk) * ztraz(ji,jj,jk+1) )
769                  zakz(ji,jj,jk) = ( ztraz(ji,jj,jk) + ztraz(ji,jj,jk+1) ) * zign
770               END DO
771            END DO
772         END DO
773         
774         ! Slopes limitation
775         DO jk = 2, jpkm1
776            DO jj = 1, jpj
777               DO ji = 1, jpi
778                  zakz(ji,jj,jk) = SIGN( 1., zakz(ji,jj,jk) ) *        &
779                     &             MIN( ABS( zakz(ji,jj,jk) ), 2. * ABS(ztraz(ji,jj,jk+1)), 2. * ABS(ztraz(ji,jj,jk) ) )
780               END DO
781            END DO
782         END DO
783         
784         ! vertical advective flux
785         DO jk = 1, jpkm1
786            DO jj = 1, jpj     
787               DO ji = 1, jpi   
788                  zigma = zwsink2(ji,jj,jk+1) * zstep / fse3w(ji,jj,jk+1)
789                  zew   = zwsink2(ji,jj,jk+1)
790                  psinkflx(ji,jj,jk+1) = -zew * ( trn(ji,jj,jk,jp_tra) - 0.5 * ( 1 + zigma ) * zakz(ji,jj,jk) ) * zstep
791               END DO
792            END DO
793         END DO
794         !
795         ! Boundary conditions
796         psinkflx(:,:,1  ) = 0.e0
797         psinkflx(:,:,jpk) = 0.e0
798         
799         DO jk=1,jpkm1
800            DO jj = 1,jpj
801               DO ji = 1, jpi
802                  zflx = ( psinkflx(ji,jj,jk) - psinkflx(ji,jj,jk+1) ) / fse3t(ji,jj,jk)
803                  trn(ji,jj,jk,jp_tra) = trn(ji,jj,jk,jp_tra) + zflx
804               END DO
805            END DO
806         END DO
807
808      ENDDO
809
810      DO jk = 1,jpkm1
811         DO jj = 1,jpj
812            DO ji = 1, jpi
813               zflx = ( psinkflx(ji,jj,jk) - psinkflx(ji,jj,jk+1) ) / fse3t(ji,jj,jk)
814               ztrb(ji,jj,jk) = ztrb(ji,jj,jk) + 2. * zflx
815            END DO
816         END DO
817      END DO
818
819      trn(:,:,:,jp_tra) = ztrb(:,:,:)
820      psinkflx(:,:,:)   = 2. * psinkflx(:,:,:)
821      !
822      CALL wrk_dealloc( jpi, jpj, jpk, ztraz, zakz, zwsink2, ztrb )
823      !
824      IF( nn_timing == 1 )  CALL timing_stop('p4z_sink2')
825      !
826   END SUBROUTINE p4z_sink2
827
828
829   INTEGER FUNCTION p5z_sink_alloc()
830      !!----------------------------------------------------------------------
831      !!                     ***  ROUTINE p5z_sink_alloc  ***
832      !!----------------------------------------------------------------------
833      ALLOCATE( wsbio3 (jpi,jpj,jpk) , wsbio4  (jpi,jpj,jpk) , wscal(jpi,jpj,jpk) ,     &
834         &      sinking(jpi,jpj,jpk) , sinking2(jpi,jpj,jpk)  ,     &               
835         &      sinkingn(jpi,jpj,jpk) , sinking2n(jpi,jpj,jpk) ,     &
836         &      sinkingp(jpi,jpj,jpk) , sinking2p(jpi,jpj,jpk) ,     &
837
838         &      sinkcal(jpi,jpj,jpk) , sinksil (jpi,jpj,jpk)   ,     &   
839#if defined key_kriest
840         &      xnumm(jpk)                                                        ,     &               
841#else
842         &      sinkfer2(jpi,jpj,jpk)                                             ,     &               
843#endif
844         &      sinkfer(jpi,jpj,jpk)     , STAT=p5z_sink_alloc )               
845         !
846      IF( p5z_sink_alloc /= 0 ) CALL ctl_warn('p5z_sink_alloc : failed to allocate arrays.')
847      !
848   END FUNCTION p5z_sink_alloc
849   
850#else
851   !!======================================================================
852   !!  Dummy module :                                   No PISCES bio-model
853   !!======================================================================
854CONTAINS
855   SUBROUTINE p5z_sink                    ! Empty routine
856   END SUBROUTINE p5z_sink
857#endif 
858
859   !!======================================================================
860END MODULE  p5zsink
Note: See TracBrowser for help on using the repository browser.