1 | MODULE p4zsed |
---|
2 | !!====================================================================== |
---|
3 | !! *** MODULE p4sed *** |
---|
4 | !! TOP : PISCES Compute loss of organic matter in the sediments |
---|
5 | !!====================================================================== |
---|
6 | !! History : 1.0 ! 2004-03 (O. Aumont) Original code |
---|
7 | !! 2.0 ! 2007-12 (C. Ethe, G. Madec) F90 |
---|
8 | !! 3.4 ! 2011-06 (C. Ethe) USE of fldread |
---|
9 | !! 3.5 ! 2012-07 (O. Aumont) improvment of river input of nutrients |
---|
10 | !!---------------------------------------------------------------------- |
---|
11 | #if defined key_pisces |
---|
12 | !!---------------------------------------------------------------------- |
---|
13 | !! 'key_pisces' PISCES bio-model |
---|
14 | !!---------------------------------------------------------------------- |
---|
15 | !! p4z_sed : Compute loss of organic matter in the sediments |
---|
16 | !!---------------------------------------------------------------------- |
---|
17 | USE oce_trc ! shared variables between ocean and passive tracers |
---|
18 | USE trc ! passive tracers common variables |
---|
19 | USE sms_pisces ! PISCES Source Minus Sink variables |
---|
20 | USE p4zsink ! vertical flux of particulate matter due to sinking |
---|
21 | USE p4zopt ! optical model |
---|
22 | USE p4zlim ! Co-limitations of differents nutrients |
---|
23 | USE p4zrem ! Remineralisation of organic matter |
---|
24 | USE p4zsbc ! External source of nutrients |
---|
25 | USE p4zint ! interpolation and computation of various fields |
---|
26 | USE iom ! I/O manager |
---|
27 | USE prtctl_trc ! print control for debugging |
---|
28 | |
---|
29 | IMPLICIT NONE |
---|
30 | PRIVATE |
---|
31 | |
---|
32 | PUBLIC p4z_sed |
---|
33 | |
---|
34 | !! * Module variables |
---|
35 | REAL(wp) :: ryyss !: number of seconds per year |
---|
36 | REAL(wp) :: r1_ryyss !: inverse of ryyss |
---|
37 | REAL(wp) :: r1_rday !: inverse of rday |
---|
38 | |
---|
39 | INTEGER :: numnit |
---|
40 | |
---|
41 | |
---|
42 | !!* Substitution |
---|
43 | # include "top_substitute.h90" |
---|
44 | !!---------------------------------------------------------------------- |
---|
45 | !! NEMO/TOP 3.3 , NEMO Consortium (2010) |
---|
46 | !! $Header:$ |
---|
47 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
---|
48 | !!---------------------------------------------------------------------- |
---|
49 | CONTAINS |
---|
50 | |
---|
51 | SUBROUTINE p4z_sed( kt, jnt ) |
---|
52 | !!--------------------------------------------------------------------- |
---|
53 | !! *** ROUTINE p4z_sed *** |
---|
54 | !! |
---|
55 | !! ** Purpose : Compute loss of organic matter in the sediments. This |
---|
56 | !! is by no way a sediment model. The loss is simply |
---|
57 | !! computed to balance the inout from rivers and dust |
---|
58 | !! |
---|
59 | !! ** Method : - ??? |
---|
60 | !!--------------------------------------------------------------------- |
---|
61 | ! |
---|
62 | INTEGER, INTENT(in) :: kt, jnt ! ocean time step |
---|
63 | INTEGER :: ji, jj, jk, ikt |
---|
64 | #if ! defined key_sed |
---|
65 | REAL(wp) :: zsumsedsi, zsumsedpo4, zsumsedcal |
---|
66 | REAL(wp) :: zrivalk, zrivsil, zrivno3 |
---|
67 | #endif |
---|
68 | REAL(wp) :: zwflux, zfminus, zfplus |
---|
69 | REAL(wp) :: zlim, zfact, zfactcal |
---|
70 | REAL(wp) :: zo2, zno3, zflx, zpdenit, z1pdenit, zdenitt, zolimit |
---|
71 | REAL(wp) :: zsiloss, zcaloss, zws3, zws4, zwsc, zdep, zwstpoc |
---|
72 | REAL(wp) :: ztrfer, ztrpo4, zwdust, zlight |
---|
73 | REAL(wp) :: zrdenittot, zsdenittot, znitrpottot |
---|
74 | ! |
---|
75 | CHARACTER (len=25) :: charout |
---|
76 | REAL(wp), POINTER, DIMENSION(:,: ) :: zpdep, zsidep, zwork1, zwork2, zwork3, zwork4 |
---|
77 | REAL(wp), POINTER, DIMENSION(:,: ) :: zdenit2d, zironice, zbureff |
---|
78 | REAL(wp), POINTER, DIMENSION(:,: ) :: zwsbio3, zwsbio4, zwscal |
---|
79 | REAL(wp), POINTER, DIMENSION(:,:,:) :: znitrpot, zirondep, zsoufer |
---|
80 | !!--------------------------------------------------------------------- |
---|
81 | ! |
---|
82 | IF( nn_timing == 1 ) CALL timing_start('p4z_sed') |
---|
83 | ! |
---|
84 | IF( kt == nittrc000 .AND. jnt == 1 ) THEN |
---|
85 | ryyss = nyear_len(1) * rday ! number of seconds per year and per month |
---|
86 | r1_rday = 1. / rday |
---|
87 | r1_ryyss = 1. / ryyss |
---|
88 | IF( ln_check_mass .AND. lwp) & |
---|
89 | & CALL ctl_opn( numnit, 'nitrogen.budget', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE., narea ) |
---|
90 | ENDIF |
---|
91 | ! |
---|
92 | ! Allocate temporary workspace |
---|
93 | CALL wrk_alloc( jpi, jpj, zdenit2d, zwork1, zwork2, zwork3, zwork4, zbureff ) |
---|
94 | CALL wrk_alloc( jpi, jpj, zwsbio3, zwsbio4, zwscal ) |
---|
95 | CALL wrk_alloc( jpi, jpj, jpk, znitrpot, zsoufer ) |
---|
96 | |
---|
97 | zdenit2d(:,:) = 0.e0 |
---|
98 | zbureff (:,:) = 0.e0 |
---|
99 | zwork1 (:,:) = 0.e0 |
---|
100 | zwork2 (:,:) = 0.e0 |
---|
101 | zwork3 (:,:) = 0.e0 |
---|
102 | zwork4 (:,:) = 0.e0 |
---|
103 | |
---|
104 | ! Iron input/uptake due to sea ice : Crude parameterization based on Lancelot et al. |
---|
105 | ! ---------------------------------------------------- |
---|
106 | IF( ln_ironice ) THEN |
---|
107 | ! |
---|
108 | CALL wrk_alloc( jpi, jpj, zironice ) |
---|
109 | ! |
---|
110 | DO jj = 1, jpj |
---|
111 | DO ji = 1, jpi |
---|
112 | zdep = rfact2 / fse3t(ji,jj,1) |
---|
113 | zwflux = fmmflx(ji,jj) / 1000._wp |
---|
114 | zfminus = MIN( 0._wp, -zwflux ) * trn(ji,jj,1,jpfer) * zdep |
---|
115 | zfplus = MAX( 0._wp, -zwflux ) * icefeinput * zdep |
---|
116 | zironice(ji,jj) = zfplus + zfminus |
---|
117 | END DO |
---|
118 | END DO |
---|
119 | ! |
---|
120 | trn(:,:,1,jpfer) = trn(:,:,1,jpfer) + zironice(:,:) |
---|
121 | ! |
---|
122 | IF( ln_diatrc .AND. lk_iomput .AND. jnt == nrdttrc ) & |
---|
123 | & CALL iom_put( "Ironice", zironice(:,:) * 1.e+3 * rfact2r * fse3t(:,:,1) * tmask(:,:,1) ) ! iron flux from ice |
---|
124 | CALL wrk_dealloc( jpi, jpj, zironice ) |
---|
125 | ! |
---|
126 | ENDIF |
---|
127 | |
---|
128 | ! Add the external input of nutrients from dust deposition |
---|
129 | ! ---------------------------------------------------------- |
---|
130 | IF( ln_dust ) THEN |
---|
131 | ! |
---|
132 | CALL wrk_alloc( jpi, jpj, zpdep, zsidep ) |
---|
133 | CALL wrk_alloc( jpi, jpj, jpk, zirondep ) |
---|
134 | ! ! Iron and Si deposition at the surface |
---|
135 | IF( ln_solub ) THEN |
---|
136 | zirondep(:,:,1) = solub(:,:) * dust(:,:) * mfrac * rfact2 / fse3t(:,:,1) / 55.85 + 3.e-10 * r1_ryyss |
---|
137 | ELSE |
---|
138 | zirondep(:,:,1) = dustsolub * dust(:,:) * mfrac * rfact2 / fse3t(:,:,1) / 55.85 + 3.e-10 * r1_ryyss |
---|
139 | ENDIF |
---|
140 | zsidep(:,:) = 8.8 * 0.075 * dust(:,:) * mfrac * rfact2 / fse3t(:,:,1) / 28.1 |
---|
141 | zpdep (:,:) = 0.1 * 0.021 * dust(:,:) * mfrac * rfact2 / fse3t(:,:,1) / 31. / po4r |
---|
142 | ! ! Iron solubilization of particles in the water column |
---|
143 | ! ! dust in kg/m2/s ---> 1/55.85 to put in mol/Fe ; wdust in m/j |
---|
144 | zwdust = 0.03 * rday / ( wdust * 55.85 ) / ( 270. * rday ) |
---|
145 | DO jk = 2, jpkm1 |
---|
146 | zirondep(:,:,jk) = dust(:,:) * mfrac * zwdust * rfact2 * EXP( -fsdept(:,:,jk) / 540. ) |
---|
147 | END DO |
---|
148 | ! ! Iron solubilization of particles in the water column |
---|
149 | trn(:,:,1,jppo4) = trn(:,:,1,jppo4) + zpdep (:,:) |
---|
150 | trn(:,:,1,jpsil) = trn(:,:,1,jpsil) + zsidep (:,:) |
---|
151 | trn(:,:,:,jpfer) = trn(:,:,:,jpfer) + zirondep(:,:,:) |
---|
152 | ! |
---|
153 | IF( ln_diatrc ) THEN |
---|
154 | zfact = 1.e+3 * rfact2r |
---|
155 | IF( lk_iomput ) THEN |
---|
156 | IF( jnt == nrdttrc ) THEN |
---|
157 | CALL iom_put( "Irondep", zirondep(:,:,1) * zfact * fse3t(:,:,1) * tmask(:,:,1) ) ! surface downward dust depo of iron |
---|
158 | CALL iom_put( "pdust" , dust(:,:) / ( wdust * rday ) * tmask(:,:,1) ) ! dust concentration at surface |
---|
159 | ENDIF |
---|
160 | ELSE |
---|
161 | trc2d(:,:,jp_pcs0_2d + 11) = zirondep(:,:,1) * zfact * fse3t(:,:,1) * tmask(:,:,1) |
---|
162 | ENDIF |
---|
163 | ENDIF |
---|
164 | CALL wrk_dealloc( jpi, jpj, zpdep, zsidep ) |
---|
165 | CALL wrk_dealloc( jpi, jpj, jpk, zirondep ) |
---|
166 | ! |
---|
167 | ENDIF |
---|
168 | |
---|
169 | ! Add the external input of nutrients from river |
---|
170 | ! ---------------------------------------------------------- |
---|
171 | IF( ln_river ) THEN |
---|
172 | trn(:,:,1,jppo4) = trn(:,:,1,jppo4) + rivdip(:,:) * rfact2 |
---|
173 | trn(:,:,1,jpno3) = trn(:,:,1,jpno3) + rivdin(:,:) * rfact2 |
---|
174 | trn(:,:,1,jpfer) = trn(:,:,1,jpfer) + rivdic(:,:) * 5.e-5 * rfact2 |
---|
175 | trn(:,:,1,jpsil) = trn(:,:,1,jpsil) + rivdsi(:,:) * rfact2 |
---|
176 | trn(:,:,1,jpdic) = trn(:,:,1,jpdic) + rivdic(:,:) * rfact2 |
---|
177 | trn(:,:,1,jptal) = trn(:,:,1,jptal) + ( rivalk(:,:) - rno3 * rivdin(:,:) ) * rfact2 |
---|
178 | ENDIF |
---|
179 | |
---|
180 | ! Add the external input of nutrients from nitrogen deposition |
---|
181 | ! ---------------------------------------------------------- |
---|
182 | IF( ln_ndepo ) THEN |
---|
183 | trn(:,:,1,jpno3) = trn(:,:,1,jpno3) + nitdep(:,:) * rfact2 |
---|
184 | trn(:,:,1,jptal) = trn(:,:,1,jptal) - rno3 * nitdep(:,:) * rfact2 |
---|
185 | ENDIF |
---|
186 | |
---|
187 | ! Add the external input of iron from sediment mobilization |
---|
188 | ! ------------------------------------------------------ |
---|
189 | IF( ln_ironsed ) THEN |
---|
190 | trn(:,:,:,jpfer) = trn(:,:,:,jpfer) + ironsed(:,:,:) * rfact2 |
---|
191 | ! |
---|
192 | IF( ln_diatrc .AND. lk_iomput .AND. jnt == nrdttrc ) & |
---|
193 | & CALL iom_put( "Ironsed", ironsed(:,:,:) * 1.e+3 * tmask(:,:,:) ) ! iron inputs from sediments |
---|
194 | ENDIF |
---|
195 | |
---|
196 | ! Add the external input of iron from hydrothermal vents |
---|
197 | ! ------------------------------------------------------ |
---|
198 | IF( ln_hydrofe ) THEN |
---|
199 | trn(:,:,:,jpfer) = trn(:,:,:,jpfer) + hydrofe(:,:,:) * rfact2 |
---|
200 | ! |
---|
201 | IF( ln_diatrc .AND. lk_iomput .AND. jnt == nrdttrc ) & |
---|
202 | & CALL iom_put( "HYDR", hydrofe(:,:,:) * 1.e+3 * tmask(:,:,:) ) ! hydrothermal iron input |
---|
203 | ENDIF |
---|
204 | |
---|
205 | |
---|
206 | ! OA: Warning, the following part is necessary, especially with Kriest |
---|
207 | ! to avoid CFL problems above the sediments |
---|
208 | ! -------------------------------------------------------------------- |
---|
209 | DO jj = 1, jpj |
---|
210 | DO ji = 1, jpi |
---|
211 | ikt = mbkt(ji,jj) |
---|
212 | zdep = fse3t(ji,jj,ikt) / xstep |
---|
213 | zwsbio4(ji,jj) = MIN( 0.99 * zdep, wsbio4(ji,jj,ikt) ) |
---|
214 | zwscal (ji,jj) = MIN( 0.99 * zdep, wscal (ji,jj,ikt) ) |
---|
215 | zwsbio3(ji,jj) = MIN( 0.99 * zdep, wsbio3(ji,jj,ikt) ) |
---|
216 | END DO |
---|
217 | END DO |
---|
218 | |
---|
219 | #if ! defined key_sed |
---|
220 | ! Computation of the sediment denitrification proportion: The metamodel from midlleburg (2006) is being used |
---|
221 | ! Computation of the fraction of organic matter that is permanently buried from Dunne's model |
---|
222 | ! ------------------------------------------------------- |
---|
223 | DO jj = 1, jpj |
---|
224 | DO ji = 1, jpi |
---|
225 | IF( tmask(ji,jj,1) == 1 ) THEN |
---|
226 | ikt = mbkt(ji,jj) |
---|
227 | # if defined key_kriest |
---|
228 | zflx = trn(ji,jj,ikt,jppoc) * zwsbio3(ji,jj) * 1E3 * 1E6 / 1E4 |
---|
229 | # else |
---|
230 | zflx = ( trn(ji,jj,ikt,jpgoc) * zwsbio4(ji,jj) & |
---|
231 | & + trn(ji,jj,ikt,jppoc) * zwsbio3(ji,jj) ) * 1E3 * 1E6 / 1E4 |
---|
232 | #endif |
---|
233 | zflx = LOG10( MAX( 1E-3, zflx ) ) |
---|
234 | zo2 = LOG10( MAX( 10. , trn(ji,jj,ikt,jpoxy) * 1E6 ) ) |
---|
235 | zno3 = LOG10( MAX( 1. , trn(ji,jj,ikt,jpno3) * 1E6 * rno3 ) ) |
---|
236 | zdep = LOG10( fsdepw(ji,jj,ikt+1) ) |
---|
237 | zdenit2d(ji,jj) = -2.2567 - 1.185 * zflx - 0.221 * zflx**2 - 0.3995 * zno3 * zo2 + 1.25 * zno3 & |
---|
238 | & + 0.4721 * zo2 - 0.0996 * zdep + 0.4256 * zflx * zo2 |
---|
239 | zdenit2d(ji,jj) = 10.0**( zdenit2d(ji,jj) ) |
---|
240 | ! |
---|
241 | zflx = ( trn(ji,jj,ikt,jpgoc) * zwsbio4(ji,jj) & |
---|
242 | & + trn(ji,jj,ikt,jppoc) * zwsbio3(ji,jj) ) * 1E6 |
---|
243 | zbureff(ji,jj) = 0.013 + 0.53 * zflx**2 / ( 7.0 + zflx )**2 |
---|
244 | ENDIF |
---|
245 | END DO |
---|
246 | END DO |
---|
247 | |
---|
248 | ! Loss of biogenic silicon, Caco3 organic carbon in the sediments. |
---|
249 | ! First, the total loss is computed. |
---|
250 | ! The factor for calcite comes from the alkalinity effect |
---|
251 | ! ------------------------------------------------------------- |
---|
252 | DO jj = 1, jpj |
---|
253 | DO ji = 1, jpi |
---|
254 | IF( tmask(ji,jj,1) == 1 ) THEN |
---|
255 | ikt = mbkt(ji,jj) |
---|
256 | # if defined key_kriest |
---|
257 | zwork1(ji,jj) = trn(ji,jj,ikt,jpgsi) * zwscal (ji,jj) |
---|
258 | zwork2(ji,jj) = trn(ji,jj,ikt,jppoc) * zwsbio3(ji,jj) |
---|
259 | # else |
---|
260 | zwork1(ji,jj) = trn(ji,jj,ikt,jpgsi) * zwsbio4(ji,jj) |
---|
261 | zwork2(ji,jj) = trn(ji,jj,ikt,jpgoc) * zwsbio4(ji,jj) + trn(ji,jj,ikt,jppoc) * zwsbio3(ji,jj) |
---|
262 | # endif |
---|
263 | ! For calcite, burial efficiency is made a function of saturation |
---|
264 | zfactcal = MIN( excess(ji,jj,ikt), 0.2 ) |
---|
265 | zfactcal = MIN( 1., 1.3 * ( 0.2 - zfactcal ) / ( 0.4 - zfactcal ) ) |
---|
266 | zwork3(ji,jj) = trn(ji,jj,ikt,jpcal) * zwscal(ji,jj) * 2.e0 * zfactcal |
---|
267 | ENDIF |
---|
268 | END DO |
---|
269 | END DO |
---|
270 | zsumsedsi = glob_sum( zwork1(:,:) * e1e2t(:,:) ) * r1_rday |
---|
271 | zsumsedpo4 = glob_sum( zwork2(:,:) * e1e2t(:,:) ) * r1_rday |
---|
272 | zsumsedcal = glob_sum( zwork3(:,:) * e1e2t(:,:) ) * r1_rday |
---|
273 | #endif |
---|
274 | |
---|
275 | ! This loss is scaled at each bottom grid cell for equilibrating the total budget of silica in the ocean. |
---|
276 | ! Thus, the amount of silica lost in the sediments equal the supply at the surface (dust+rivers) |
---|
277 | ! ------------------------------------------------------ |
---|
278 | #if ! defined key_sed |
---|
279 | zrivsil = 1._wp - ( sumdepsi + rivdsiinput * r1_ryyss ) / ( zsumsedsi + rtrn ) |
---|
280 | #endif |
---|
281 | |
---|
282 | DO jj = 1, jpj |
---|
283 | DO ji = 1, jpi |
---|
284 | ikt = mbkt(ji,jj) |
---|
285 | zdep = xstep / fse3t(ji,jj,ikt) |
---|
286 | zws4 = zwsbio4(ji,jj) * zdep |
---|
287 | zwsc = zwscal (ji,jj) * zdep |
---|
288 | # if defined key_kriest |
---|
289 | zsiloss = trn(ji,jj,ikt,jpgsi) * zws4 |
---|
290 | # else |
---|
291 | zsiloss = trn(ji,jj,ikt,jpgsi) * zwsc |
---|
292 | # endif |
---|
293 | zcaloss = trn(ji,jj,ikt,jpcal) * zwsc |
---|
294 | ! |
---|
295 | trn(ji,jj,ikt,jpgsi) = trn(ji,jj,ikt,jpgsi) - zsiloss |
---|
296 | trn(ji,jj,ikt,jpcal) = trn(ji,jj,ikt,jpcal) - zcaloss |
---|
297 | #if ! defined key_sed |
---|
298 | trn(ji,jj,ikt,jpsil) = trn(ji,jj,ikt,jpsil) + zsiloss * zrivsil |
---|
299 | zfactcal = MIN( excess(ji,jj,ikt), 0.2 ) |
---|
300 | zfactcal = MIN( 1., 1.3 * ( 0.2 - zfactcal ) / ( 0.4 - zfactcal ) ) |
---|
301 | zrivalk = 1._wp - ( rivalkinput * r1_ryyss ) * zfactcal / ( zsumsedcal + rtrn ) |
---|
302 | trn(ji,jj,ikt,jptal) = trn(ji,jj,ikt,jptal) + zcaloss * zrivalk * 2.0 |
---|
303 | trn(ji,jj,ikt,jpdic) = trn(ji,jj,ikt,jpdic) + zcaloss * zrivalk |
---|
304 | #endif |
---|
305 | END DO |
---|
306 | END DO |
---|
307 | |
---|
308 | DO jj = 1, jpj |
---|
309 | DO ji = 1, jpi |
---|
310 | ikt = mbkt(ji,jj) |
---|
311 | zdep = xstep / fse3t(ji,jj,ikt) |
---|
312 | zws4 = zwsbio4(ji,jj) * zdep |
---|
313 | zws3 = zwsbio3(ji,jj) * zdep |
---|
314 | zrivno3 = 1. - zbureff(ji,jj) |
---|
315 | # if ! defined key_kriest |
---|
316 | trn(ji,jj,ikt,jpgoc) = trn(ji,jj,ikt,jpgoc) - trn(ji,jj,ikt,jpgoc) * zws4 |
---|
317 | trn(ji,jj,ikt,jppoc) = trn(ji,jj,ikt,jppoc) - trn(ji,jj,ikt,jppoc) * zws3 |
---|
318 | trn(ji,jj,ikt,jpbfe) = trn(ji,jj,ikt,jpbfe) - trn(ji,jj,ikt,jpbfe) * zws4 |
---|
319 | trn(ji,jj,ikt,jpsfe) = trn(ji,jj,ikt,jpsfe) - trn(ji,jj,ikt,jpsfe) * zws3 |
---|
320 | zwstpoc = trn(ji,jj,ikt,jpgoc) * zws4 + trn(ji,jj,ikt,jppoc) * zws3 |
---|
321 | # else |
---|
322 | trn(ji,jj,ikt,jpnum) = trn(ji,jj,ikt,jpnum) - trn(ji,jj,ikt,jpnum) * zws4 |
---|
323 | trn(ji,jj,ikt,jppoc) = trn(ji,jj,ikt,jppoc) - trn(ji,jj,ikt,jppoc) * zws3 |
---|
324 | trn(ji,jj,ikt,jpsfe) = trn(ji,jj,ikt,jpsfe) - trn(ji,jj,ikt,jpsfe) * zws3 |
---|
325 | zwstpoc = trn(ji,jj,ikt,jppoc) * zws3 |
---|
326 | # endif |
---|
327 | |
---|
328 | #if ! defined key_sed |
---|
329 | ! The 0.5 factor in zpdenit and zdenitt is to avoid negative NO3 concentration after both denitrification |
---|
330 | ! in the sediments and just above the sediments. Not very clever, but simpliest option. |
---|
331 | zpdenit = MIN( 0.5 * ( trn(ji,jj,ikt,jpno3) - rtrn ) / rdenit, zdenit2d(ji,jj) * zwstpoc * zrivno3 ) |
---|
332 | z1pdenit = zwstpoc * zrivno3 - zpdenit |
---|
333 | zolimit = MIN( ( trn(ji,jj,ikt,jpoxy) - rtrn ) / o2ut, z1pdenit * ( 1.- nitrfac(ji,jj,ikt) ) ) |
---|
334 | zdenitt = MIN( 0.5 * ( trn(ji,jj,ikt,jpno3) - rtrn ) / rdenit, z1pdenit * nitrfac(ji,jj,ikt) ) |
---|
335 | trn(ji,jj,ikt,jpdoc) = trn(ji,jj,ikt,jpdoc) + z1pdenit - zolimit - zdenitt |
---|
336 | trn(ji,jj,ikt,jppo4) = trn(ji,jj,ikt,jppo4) + zpdenit + zolimit + zdenitt |
---|
337 | trn(ji,jj,ikt,jpnh4) = trn(ji,jj,ikt,jpnh4) + zpdenit + zolimit + zdenitt |
---|
338 | trn(ji,jj,ikt,jpno3) = trn(ji,jj,ikt,jpno3) - rdenit * (zpdenit + zdenitt) |
---|
339 | trn(ji,jj,ikt,jpoxy) = trn(ji,jj,ikt,jpoxy) - zolimit * o2ut |
---|
340 | trn(ji,jj,ikt,jptal) = trn(ji,jj,ikt,jptal) + rno3 * (zolimit + (1.+rdenit) * (zpdenit + zdenitt) ) |
---|
341 | trn(ji,jj,ikt,jpdic) = trn(ji,jj,ikt,jpdic) + zpdenit + zolimit + zdenitt |
---|
342 | zwork4(ji,jj) = rdenit * zpdenit * fse3t(ji,jj,ikt) |
---|
343 | #endif |
---|
344 | END DO |
---|
345 | END DO |
---|
346 | |
---|
347 | ! Nitrogen fixation process |
---|
348 | ! Small source iron from particulate inorganic iron |
---|
349 | !----------------------------------- |
---|
350 | DO jk = 1, jpkm1 |
---|
351 | DO jj = 1, jpj |
---|
352 | DO ji = 1, jpi |
---|
353 | ! ! Potential nitrogen fixation dependant on temperature and iron |
---|
354 | zlim = ( 1.- xnanono3(ji,jj,jk) - xnanonh4(ji,jj,jk) ) |
---|
355 | IF( zlim <= 0.2 ) zlim = 0.01 |
---|
356 | #if defined key_degrad |
---|
357 | zfact = zlim * rfact2 * facvol(ji,jj,jk) |
---|
358 | #else |
---|
359 | zfact = zlim * rfact2 |
---|
360 | #endif |
---|
361 | ztrfer = biron(ji,jj,jk) / ( concfediaz + biron(ji,jj,jk) ) |
---|
362 | ztrpo4 = trn (ji,jj,jk,jppo4) / ( concnnh4 + trn (ji,jj,jk,jppo4) ) |
---|
363 | zlight = ( 1.- EXP( -etot(ji,jj,jk) / diazolight ) ) |
---|
364 | znitrpot(ji,jj,jk) = MAX( 0.e0, ( 0.6 * tgfunc(ji,jj,jk) - 2.15 ) * r1_rday ) & |
---|
365 | & * zfact * MIN( ztrfer, ztrpo4 ) * zlight |
---|
366 | zsoufer(ji,jj,jk) = zlight * 2E-11 / (2E-11 + biron(ji,jj,jk)) |
---|
367 | END DO |
---|
368 | END DO |
---|
369 | END DO |
---|
370 | |
---|
371 | ! Nitrogen change due to nitrogen fixation |
---|
372 | ! ---------------------------------------- |
---|
373 | DO jk = 1, jpkm1 |
---|
374 | DO jj = 1, jpj |
---|
375 | DO ji = 1, jpi |
---|
376 | zfact = znitrpot(ji,jj,jk) * nitrfix |
---|
377 | trn(ji,jj,jk,jpnh4) = trn(ji,jj,jk,jpnh4) + zfact |
---|
378 | trn(ji,jj,jk,jptal) = trn(ji,jj,jk,jptal) + rno3 * zfact |
---|
379 | trn(ji,jj,jk,jpoxy) = trn(ji,jj,jk,jpoxy) + o2nit * zfact |
---|
380 | trn(ji,jj,jk,jppo4) = trn(ji,jj,jk,jppo4) + concdnh4 / ( concdnh4 + trn(ji,jj,jk,jppo4) ) & |
---|
381 | & * 0.002 * trn(ji,jj,jk,jpdoc) * rfact2 / rday |
---|
382 | trn(ji,jj,jk,jpfer) = trn(ji,jj,jk,jpfer) + 0.002 * 4E-10 * zsoufer(ji,jj,jk) * rfact2 / rday |
---|
383 | END DO |
---|
384 | END DO |
---|
385 | END DO |
---|
386 | |
---|
387 | |
---|
388 | IF( ln_check_mass ) THEN |
---|
389 | ! Global budget of N SMS : denitrification in the water column and in the sediment |
---|
390 | ! nitrogen fixation by the diazotrophs |
---|
391 | ! -------------------------------------------------------------------------------- |
---|
392 | zrdenittot = glob_sum ( denitr(:,:,:) * rdenit * xnegtr(:,:,:) * cvol(:,:,:) ) |
---|
393 | zsdenittot = glob_sum ( zwork4(:,:) * e1e2t(:,:) ) |
---|
394 | znitrpottot = glob_sum ( znitrpot(:,:,:) * nitrfix * cvol(:,:,:) ) |
---|
395 | IF( kt == nitend .AND. jnt == nrdttrc ) THEN |
---|
396 | zfact = 1.e+3 * rfact2r * rno3 * ryyss * 14. / 1e12 |
---|
397 | IF(lwp) WRITE(numnit,9100) ndastp, znitrpottot * nitrfix * zfact, zrdenittot * zfact , zsdenittot * zfact |
---|
398 | ENDIF |
---|
399 | ENDIF |
---|
400 | ! |
---|
401 | IF( ln_diatrc ) THEN |
---|
402 | zfact = 1.e+3 * rfact2r |
---|
403 | IF( lk_iomput ) THEN |
---|
404 | IF( jnt == nrdttrc ) THEN |
---|
405 | CALL iom_put( "Nfix" , znitrpot(:,:,:) * nitrfix * rno3 * zfact * tmask(:,:,:) ) ! nitrogen fixation |
---|
406 | CALL iom_put( "Sdenit", zwork4(:,:) * rno3 * zfact * tmask(:,:,1) ) ! Nitrate reduction in the sediments |
---|
407 | ENDIF |
---|
408 | ELSE |
---|
409 | trc2d(:,:,jp_pcs0_2d + 12) = znitrpot(:,:,1) * nitrfix * zfact * fse3t(:,:,1) * tmask(:,:,1) |
---|
410 | ENDIF |
---|
411 | ENDIF |
---|
412 | ! |
---|
413 | IF(ln_ctl) THEN ! print mean trends (USEd for debugging) |
---|
414 | WRITE(charout, fmt="('sed ')") |
---|
415 | CALL prt_ctl_trc_info(charout) |
---|
416 | CALL prt_ctl_trc(tab4d=trn, mask=tmask, clinfo=ctrcnm) |
---|
417 | ENDIF |
---|
418 | ! |
---|
419 | CALL wrk_dealloc( jpi, jpj, zdenit2d, zwork1, zwork2, zwork3, zwork4, zbureff ) |
---|
420 | CALL wrk_dealloc( jpi, jpj, zwsbio3, zwsbio4, zwscal ) |
---|
421 | CALL wrk_dealloc( jpi, jpj, jpk, znitrpot, zsoufer ) |
---|
422 | ! |
---|
423 | IF( nn_timing == 1 ) CALL timing_stop('p4z_sed') |
---|
424 | ! |
---|
425 | 9100 FORMAT(i8,3f10.5) |
---|
426 | ! |
---|
427 | END SUBROUTINE p4z_sed |
---|
428 | |
---|
429 | #else |
---|
430 | !!====================================================================== |
---|
431 | !! Dummy module : No PISCES bio-model |
---|
432 | !!====================================================================== |
---|
433 | CONTAINS |
---|
434 | SUBROUTINE p4z_sed ! Empty routine |
---|
435 | END SUBROUTINE p4z_sed |
---|
436 | #endif |
---|
437 | |
---|
438 | !!====================================================================== |
---|
439 | END MODULE p4zsed |
---|