1 | MODULE dyncor_c1d |
---|
2 | !!====================================================================== |
---|
3 | !! *** MODULE dyncor_c1d *** |
---|
4 | !! Ocean Dynamics : Coriolis term in 1D configuration |
---|
5 | !!===================================================================== |
---|
6 | !! History : 2.0 ! 2004-09 (C. Ethe) Original code |
---|
7 | !! 3.0 ! 2008-04 (G. Madec) style only |
---|
8 | !!---------------------------------------------------------------------- |
---|
9 | #if defined key_c1d |
---|
10 | !!---------------------------------------------------------------------- |
---|
11 | !! 'key_c1d' 1D Configuration |
---|
12 | !!---------------------------------------------------------------------- |
---|
13 | !! cor_c1d : Coriolis factor at T-point (1D configuration) |
---|
14 | !! dyn_cor_c1d : vorticity trend due to Coriolis at T-point |
---|
15 | !!---------------------------------------------------------------------- |
---|
16 | USE oce ! ocean dynamics and tracers |
---|
17 | USE dom_oce ! ocean space and time domain |
---|
18 | USE phycst ! physical constants |
---|
19 | USE in_out_manager ! I/O manager |
---|
20 | USE prtctl ! Print control |
---|
21 | |
---|
22 | IMPLICIT NONE |
---|
23 | PRIVATE |
---|
24 | |
---|
25 | PUBLIC cor_c1d ! routine called by OPA.F90 |
---|
26 | PUBLIC dyn_cor_c1d ! routine called by step1d.F90 |
---|
27 | |
---|
28 | !! * Substitutions |
---|
29 | # include "vectopt_loop_substitute.h90" |
---|
30 | !!---------------------------------------------------------------------- |
---|
31 | !! NEMO/C1D 3.0 , LOCEAN-IPSL (2009) |
---|
32 | !! $Id$ |
---|
33 | !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt) |
---|
34 | !!---------------------------------------------------------------------- |
---|
35 | |
---|
36 | CONTAINS |
---|
37 | |
---|
38 | SUBROUTINE cor_c1d |
---|
39 | !!---------------------------------------------------------------------- |
---|
40 | !! *** ROUTINE cor_c1d *** |
---|
41 | !! |
---|
42 | !! ** Purpose : Compute the Coriolis factor at T-point |
---|
43 | !!---------------------------------------------------------------------- |
---|
44 | REAL(wp) :: zphi0, zbeta, zf0 ! temporary scalars |
---|
45 | !!---------------------------------------------------------------------- |
---|
46 | |
---|
47 | IF(lwp) WRITE(numout,*) |
---|
48 | IF(lwp) WRITE(numout,*) 'cor_c1d : Coriolis factor at T-point' |
---|
49 | IF(lwp) WRITE(numout,*) '~~~~~~~' |
---|
50 | |
---|
51 | SELECT CASE( jphgr_msh ) ! type of horizontal mesh |
---|
52 | ! |
---|
53 | CASE ( 0, 1, 4 ) ! mesh on the sphere |
---|
54 | ff(:,:) = 2. * omega * SIN( rad * gphit(:,:) ) |
---|
55 | ! |
---|
56 | CASE ( 2 ) ! f-plane at ppgphi0 |
---|
57 | ff(:,:) = 2. * omega * SIN( rad * ppgphi0 ) |
---|
58 | IF(lwp) WRITE(numout,*) ' f-plane: Coriolis parameter = constant = ', ff(1,1) |
---|
59 | ! |
---|
60 | CASE ( 3 ) ! beta-plane |
---|
61 | zbeta = 2. * omega * COS( rad * ppgphi0 ) / ra ! beta at latitude ppgphi0 |
---|
62 | zphi0 = ppgphi0 - FLOAT( jpjglo/2) * ppe2_m *1.e-3 / ( ra * rad ) ! latitude of the first row F-points |
---|
63 | zf0 = 2. * omega * SIN( rad * zphi0 ) ! compute f0 1st point south |
---|
64 | ff(:,:) = ( zf0 + zbeta * gphit(:,:) * 1.e+3 ) ! f = f0 +beta* y ( y=0 at south) |
---|
65 | IF(lwp) WRITE(numout,*) ' Beta-plane: Beta parameter = constant = ', ff(1,1) |
---|
66 | IF(lwp) WRITE(numout,*) ' Coriolis parameter varies from ', ff(1,1),' to ', ff(1,jpj) |
---|
67 | ! |
---|
68 | CASE ( 5 ) ! beta-plane and rotated domain |
---|
69 | zbeta = 2. * omega * COS( rad * ppgphi0 ) / ra ! beta at latitude ppgphi0 |
---|
70 | zphi0 = 15.e0 ! latitude of the first row F-points |
---|
71 | zf0 = 2. * omega * SIN( rad * zphi0 ) ! compute f0 1st point south |
---|
72 | ff(:,:) = ( zf0 + zbeta * ABS( gphit(:,:) - zphi0 ) * rad * ra ) ! f = f0 +beta* y ( y=0 at south) |
---|
73 | IF(lwp) WRITE(numout,*) ' Beta-plane: Beta parameter = constant = ', ff(1,1) |
---|
74 | IF(lwp) WRITE(numout,*) ' Coriolis parameter varies from ', ff(1,1),' to ', ff(1,jpj) |
---|
75 | ! |
---|
76 | END SELECT |
---|
77 | ! |
---|
78 | END SUBROUTINE cor_c1d |
---|
79 | |
---|
80 | |
---|
81 | SUBROUTINE dyn_cor_c1d( kt ) |
---|
82 | !!---------------------------------------------------------------------- |
---|
83 | !! *** ROUTINE dyn_cor_c1d *** |
---|
84 | !! |
---|
85 | !! ** Purpose : Compute the now total vorticity trend and add it to |
---|
86 | !! the general trend of the momentum equation |
---|
87 | !! |
---|
88 | !! ** Method : |
---|
89 | !! |
---|
90 | !! History : |
---|
91 | !! 9.0 ! 04-09 (C. Ethe) 1D configuration |
---|
92 | !!---------------------------------------------------------------------- |
---|
93 | INTEGER, INTENT( in ) :: kt ! ocean time-step index |
---|
94 | !! |
---|
95 | INTEGER :: ji, jj, jk ! dummy loop indices |
---|
96 | !!---------------------------------------------------------------------- |
---|
97 | ! |
---|
98 | IF( kt == nit000 ) THEN |
---|
99 | IF(lwp) WRITE(numout,*) |
---|
100 | IF(lwp) WRITE(numout,*) 'dyn_cor_c1d : total vorticity trend in 1D' |
---|
101 | IF(lwp) WRITE(numout,*) '~~~~~~~~~~' |
---|
102 | ENDIF |
---|
103 | ! |
---|
104 | DO jk = 1, jpkm1 |
---|
105 | DO jj = 2, jpjm1 |
---|
106 | DO ji = fs_2, fs_jpim1 ! vector opt. |
---|
107 | ua(ji,jj,jk) = ua(ji,jj,jk) + ff(ji,jj) * vn(ji,jj,jk) |
---|
108 | va(ji,jj,jk) = va(ji,jj,jk) - ff(ji,jj) * un(ji,jj,jk) |
---|
109 | END DO |
---|
110 | END DO |
---|
111 | END DO |
---|
112 | ! |
---|
113 | IF(ln_ctl) CALL prt_ctl( tab3d_1=ua, clinfo1=' cor - Ua: ', mask1=umask, & |
---|
114 | & tab3d_2=va, clinfo2=' Va: ' , mask2=vmask ) |
---|
115 | ! |
---|
116 | END SUBROUTINE dyn_cor_c1d |
---|
117 | |
---|
118 | #else |
---|
119 | !!---------------------------------------------------------------------- |
---|
120 | !! Default key NO 1D Configuration |
---|
121 | !!---------------------------------------------------------------------- |
---|
122 | CONTAINS |
---|
123 | SUBROUTINE cor_c1d ! Empty routine |
---|
124 | END SUBROUTINE cor_c1d |
---|
125 | SUBROUTINE dyn_cor_c1d ( kt ) ! Empty routine |
---|
126 | WRITE(*,*) 'dyn_cor_c1d: You should not have seen this print! error?', kt |
---|
127 | END SUBROUTINE dyn_cor_c1d |
---|
128 | #endif |
---|
129 | |
---|
130 | !!===================================================================== |
---|
131 | END MODULE dyncor_c1d |
---|