1 | MODULE zdftmx |
---|
2 | !!======================================================================== |
---|
3 | !! *** MODULE zdftmx *** |
---|
4 | !! Ocean physics: vertical tidal mixing coefficient |
---|
5 | !!======================================================================== |
---|
6 | !! History : 1.0 ! 2004-04 (L. Bessieres, G. Madec) Original code |
---|
7 | !! - ! 2006-08 (A. Koch-Larrouy) Indonesian strait |
---|
8 | !! 3.3 ! 2010-10 (C. Ethe, G. Madec) reorganisation of initialisation phase |
---|
9 | !!---------------------------------------------------------------------- |
---|
10 | #if defined key_zdftmx |
---|
11 | !!---------------------------------------------------------------------- |
---|
12 | !! 'key_zdftmx' Tidal vertical mixing |
---|
13 | !!---------------------------------------------------------------------- |
---|
14 | !! zdf_tmx : global momentum & tracer Kz with tidal induced Kz |
---|
15 | !! tmx_itf : Indonesian momentum & tracer Kz with tidal induced Kz |
---|
16 | !!---------------------------------------------------------------------- |
---|
17 | USE oce ! ocean dynamics and tracers variables |
---|
18 | USE dom_oce ! ocean space and time domain variables |
---|
19 | USE zdf_oce ! ocean vertical physics variables |
---|
20 | USE lbclnk ! ocean lateral boundary conditions (or mpp link) |
---|
21 | USE eosbn2 ! ocean equation of state |
---|
22 | USE phycst ! physical constants |
---|
23 | USE prtctl ! Print control |
---|
24 | USE in_out_manager ! I/O manager |
---|
25 | USE iom ! I/O Manager |
---|
26 | USE lib_mpp ! MPP library |
---|
27 | USE wrk_nemo ! work arrays |
---|
28 | USE timing ! Timing |
---|
29 | USE lib_fortran ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) |
---|
30 | |
---|
31 | IMPLICIT NONE |
---|
32 | PRIVATE |
---|
33 | |
---|
34 | PUBLIC zdf_tmx ! called in step module |
---|
35 | PUBLIC zdf_tmx_init ! called in opa module |
---|
36 | PUBLIC zdf_tmx_alloc ! called in nemogcm module |
---|
37 | |
---|
38 | LOGICAL, PUBLIC, PARAMETER :: lk_zdftmx = .TRUE. !: tidal mixing flag |
---|
39 | |
---|
40 | ! !!* Namelist namzdf_tmx : tidal mixing * |
---|
41 | REAL(wp) :: rn_htmx ! vertical decay scale for turbulence (meters) |
---|
42 | REAL(wp) :: rn_n2min ! threshold of the Brunt-Vaisala frequency (s-1) |
---|
43 | REAL(wp) :: rn_tfe ! tidal dissipation efficiency (St Laurent et al. 2002) |
---|
44 | REAL(wp) :: rn_me ! mixing efficiency (Osborn 1980) |
---|
45 | LOGICAL :: ln_tmx_itf ! Indonesian Through Flow (ITF): Koch-Larrouy et al. (2007) parameterization |
---|
46 | REAL(wp) :: rn_tfe_itf ! ITF tidal dissipation efficiency (St Laurent et al. 2002) |
---|
47 | |
---|
48 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: en_tmx ! energy available for tidal mixing (W/m2) |
---|
49 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: mask_itf ! mask to use over Indonesian area |
---|
50 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: az_tmx ! coefficient used to evaluate the tidal induced Kz |
---|
51 | |
---|
52 | !! * Substitutions |
---|
53 | # include "vectopt_loop_substitute.h90" |
---|
54 | !!---------------------------------------------------------------------- |
---|
55 | !! NEMO/OPA 3.7 , NEMO Consortium (2014) |
---|
56 | !! $Id$ |
---|
57 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
---|
58 | !!---------------------------------------------------------------------- |
---|
59 | CONTAINS |
---|
60 | |
---|
61 | INTEGER FUNCTION zdf_tmx_alloc() |
---|
62 | !!---------------------------------------------------------------------- |
---|
63 | !! *** FUNCTION zdf_tmx_alloc *** |
---|
64 | !!---------------------------------------------------------------------- |
---|
65 | ALLOCATE(en_tmx(jpi,jpj), mask_itf(jpi,jpj), az_tmx(jpi,jpj,jpk), STAT=zdf_tmx_alloc ) |
---|
66 | ! |
---|
67 | IF( lk_mpp ) CALL mpp_sum ( zdf_tmx_alloc ) |
---|
68 | IF( zdf_tmx_alloc /= 0 ) CALL ctl_warn('zdf_tmx_alloc: failed to allocate arrays') |
---|
69 | END FUNCTION zdf_tmx_alloc |
---|
70 | |
---|
71 | |
---|
72 | SUBROUTINE zdf_tmx( kt ) |
---|
73 | !!---------------------------------------------------------------------- |
---|
74 | !! *** ROUTINE zdf_tmx *** |
---|
75 | !! |
---|
76 | !! ** Purpose : add to the vertical mixing coefficients the effect of |
---|
77 | !! tidal mixing (Simmons et al 2004). |
---|
78 | !! |
---|
79 | !! ** Method : - tidal-induced vertical mixing is given by: |
---|
80 | !! Kz_tides = az_tmx / max( rn_n2min, N^2 ) |
---|
81 | !! where az_tmx is a coefficient that specified the 3D space |
---|
82 | !! distribution of the faction of tidal energy taht is used |
---|
83 | !! for mixing. Its expression is set in zdf_tmx_init routine, |
---|
84 | !! following Simmons et al. 2004. |
---|
85 | !! NB: a specific bounding procedure is performed on av_tide |
---|
86 | !! so that the input tidal energy is actually almost used. The |
---|
87 | !! basic maximum value is 60 cm2/s, but values of 300 cm2/s |
---|
88 | !! can be reached in area where bottom stratification is too |
---|
89 | !! weak. |
---|
90 | !! |
---|
91 | !! - update av_tide in the Indonesian Through Flow area |
---|
92 | !! following Koch-Larrouy et al. (2007) parameterisation |
---|
93 | !! (see tmx_itf routine). |
---|
94 | !! |
---|
95 | !! - update the model vertical eddy viscosity and diffusivity: |
---|
96 | !! avt = avt + av_tides |
---|
97 | !! avm = avm + av_tides |
---|
98 | !! avmu = avmu + mi(av_tides) |
---|
99 | !! avmv = avmv + mj(av_tides) |
---|
100 | !! |
---|
101 | !! ** Action : avt, avm, avmu, avmv increased by tidal mixing |
---|
102 | !! |
---|
103 | !! References : Simmons et al. 2004, Ocean Modelling, 6, 3-4, 245-263. |
---|
104 | !! Koch-Larrouy et al. 2007, GRL. |
---|
105 | !!---------------------------------------------------------------------- |
---|
106 | INTEGER, INTENT(in) :: kt ! ocean time-step |
---|
107 | ! |
---|
108 | INTEGER :: ji, jj, jk ! dummy loop indices |
---|
109 | REAL(wp) :: ztpc ! scalar workspace |
---|
110 | REAL(wp), POINTER, DIMENSION(:,:) :: zkz |
---|
111 | REAL(wp), POINTER, DIMENSION(:,:,:) :: zav_tide |
---|
112 | !!---------------------------------------------------------------------- |
---|
113 | ! |
---|
114 | IF( nn_timing == 1 ) CALL timing_start('zdf_tmx') |
---|
115 | ! |
---|
116 | CALL wrk_alloc( jpi,jpj, zkz ) |
---|
117 | CALL wrk_alloc( jpi,jpj,jpk, zav_tide ) |
---|
118 | ! |
---|
119 | ! ! ----------------------- ! |
---|
120 | ! ! Standard tidal mixing ! (compute zav_tide) |
---|
121 | ! ! ----------------------- ! |
---|
122 | ! !* First estimation (with n2 bound by rn_n2min) bounded by 60 cm2/s |
---|
123 | zav_tide(:,:,:) = MIN( 60.e-4, az_tmx(:,:,:) / MAX( rn_n2min, rn2(:,:,:) ) ) |
---|
124 | |
---|
125 | zkz(:,:) = 0.e0 !* Associated potential energy consummed over the whole water column |
---|
126 | DO jk = 2, jpkm1 |
---|
127 | zkz(:,:) = zkz(:,:) + e3w_n(:,:,jk) * MAX( 0.e0, rn2(:,:,jk) ) * rau0 * zav_tide(:,:,jk) * wmask(:,:,jk) |
---|
128 | END DO |
---|
129 | |
---|
130 | DO jj = 1, jpj !* Here zkz should be equal to en_tmx ==> multiply by en_tmx/zkz to recover en_tmx |
---|
131 | DO ji = 1, jpi |
---|
132 | IF( zkz(ji,jj) /= 0.e0 ) zkz(ji,jj) = en_tmx(ji,jj) / zkz(ji,jj) |
---|
133 | END DO |
---|
134 | END DO |
---|
135 | |
---|
136 | DO jk = 2, jpkm1 !* Mutiply by zkz to recover en_tmx, BUT bound by 30/6 ==> zav_tide bound by 300 cm2/s |
---|
137 | zav_tide(:,:,jk) = zav_tide(:,:,jk) * MIN( zkz(:,:), 30./6. ) * wmask(:,:,jk) !kz max = 300 cm2/s |
---|
138 | END DO |
---|
139 | |
---|
140 | IF( kt == nit000 ) THEN !* check at first time-step: diagnose the energy consumed by zav_tide |
---|
141 | ztpc = 0._wp |
---|
142 | DO jk= 1, jpk |
---|
143 | DO jj= 1, jpj |
---|
144 | DO ji= 1, jpi |
---|
145 | ztpc = ztpc + e3w_n(ji,jj,jk) * e1e2t(ji,jj) & |
---|
146 | & * MAX( 0.e0, rn2(ji,jj,jk) ) * zav_tide(ji,jj,jk) * tmask(ji,jj,jk) * tmask_i(ji,jj) |
---|
147 | END DO |
---|
148 | END DO |
---|
149 | END DO |
---|
150 | ztpc= rau0 / ( rn_tfe * rn_me ) * ztpc |
---|
151 | IF( lk_mpp ) CALL mpp_sum( ztpc ) |
---|
152 | IF(lwp) WRITE(numout,*) |
---|
153 | IF(lwp) WRITE(numout,*) ' N Total power consumption by av_tide : ztpc = ', ztpc * 1.e-12 ,'TW' |
---|
154 | ENDIF |
---|
155 | |
---|
156 | ! ! ----------------------- ! |
---|
157 | ! ! ITF tidal mixing ! (update zav_tide) |
---|
158 | ! ! ----------------------- ! |
---|
159 | IF( ln_tmx_itf ) CALL tmx_itf( kt, zav_tide ) |
---|
160 | |
---|
161 | ! ! ----------------------- ! |
---|
162 | ! ! Update mixing coefs ! |
---|
163 | ! ! ----------------------- ! |
---|
164 | DO jk = 2, jpkm1 !* update momentum & tracer diffusivity with tidal mixing |
---|
165 | avt(:,:,jk) = avt(:,:,jk) + zav_tide(:,:,jk) * wmask(:,:,jk) |
---|
166 | avm(:,:,jk) = avm(:,:,jk) + zav_tide(:,:,jk) * wmask(:,:,jk) |
---|
167 | DO jj = 2, jpjm1 |
---|
168 | DO ji = fs_2, fs_jpim1 ! vector opt. |
---|
169 | avmu(ji,jj,jk) = avmu(ji,jj,jk) + 0.5 * ( zav_tide(ji,jj,jk) + zav_tide(ji+1,jj ,jk) ) * wumask(ji,jj,jk) |
---|
170 | avmv(ji,jj,jk) = avmv(ji,jj,jk) + 0.5 * ( zav_tide(ji,jj,jk) + zav_tide(ji ,jj+1,jk) ) * wvmask(ji,jj,jk) |
---|
171 | END DO |
---|
172 | END DO |
---|
173 | END DO |
---|
174 | CALL lbc_lnk( avmu, 'U', 1. ) ; CALL lbc_lnk( avmv, 'V', 1. ) ! lateral boundary condition |
---|
175 | |
---|
176 | ! !* output tidal mixing coefficient |
---|
177 | CALL iom_put( "av_tide", zav_tide ) |
---|
178 | |
---|
179 | IF(ln_ctl) CALL prt_ctl(tab3d_1=zav_tide , clinfo1=' tmx - av_tide: ', tab3d_2=avt, clinfo2=' avt: ', ovlap=1, kdim=jpk) |
---|
180 | ! |
---|
181 | CALL wrk_dealloc( jpi,jpj, zkz ) |
---|
182 | CALL wrk_dealloc( jpi,jpj,jpk, zav_tide ) |
---|
183 | ! |
---|
184 | IF( nn_timing == 1 ) CALL timing_stop('zdf_tmx') |
---|
185 | ! |
---|
186 | END SUBROUTINE zdf_tmx |
---|
187 | |
---|
188 | |
---|
189 | SUBROUTINE tmx_itf( kt, pav ) |
---|
190 | !!---------------------------------------------------------------------- |
---|
191 | !! *** ROUTINE tmx_itf *** |
---|
192 | !! |
---|
193 | !! ** Purpose : modify the vertical eddy diffusivity coefficients |
---|
194 | !! (pav) in the Indonesian Through Flow area (ITF). |
---|
195 | !! |
---|
196 | !! ** Method : - Following Koch-Larrouy et al. (2007), in the ITF defined |
---|
197 | !! by msk_itf (read in a file, see tmx_init), the tidal |
---|
198 | !! mixing coefficient is computed with : |
---|
199 | !! * q=1 (i.e. all the tidal energy remains trapped in |
---|
200 | !! the area and thus is used for mixing) |
---|
201 | !! * the vertical distribution of the tifal energy is a |
---|
202 | !! proportional to N above the thermocline (d(N^2)/dz > 0) |
---|
203 | !! and to N^2 below the thermocline (d(N^2)/dz < 0) |
---|
204 | !! |
---|
205 | !! ** Action : av_tide updated in the ITF area (msk_itf) |
---|
206 | !! |
---|
207 | !! References : Koch-Larrouy et al. 2007, GRL |
---|
208 | !!---------------------------------------------------------------------- |
---|
209 | INTEGER , INTENT(in ) :: kt ! ocean time-step |
---|
210 | REAL(wp), INTENT(inout), DIMENSION(jpi,jpj,jpk) :: pav ! Tidal mixing coef. |
---|
211 | !! |
---|
212 | INTEGER :: ji, jj, jk ! dummy loop indices |
---|
213 | REAL(wp) :: zcoef, ztpc ! temporary scalar |
---|
214 | REAL(wp), DIMENSION(:,:) , POINTER :: zkz ! 2D workspace |
---|
215 | REAL(wp), DIMENSION(:,:) , POINTER :: zsum1 , zsum2 , zsum ! - - |
---|
216 | REAL(wp), DIMENSION(:,:,:), POINTER :: zempba_3d_1, zempba_3d_2 ! 3D workspace |
---|
217 | REAL(wp), DIMENSION(:,:,:), POINTER :: zempba_3d , zdn2dz ! - - |
---|
218 | REAL(wp), DIMENSION(:,:,:), POINTER :: zavt_itf ! - - |
---|
219 | !!---------------------------------------------------------------------- |
---|
220 | ! |
---|
221 | IF( nn_timing == 1 ) CALL timing_start('tmx_itf') |
---|
222 | ! |
---|
223 | CALL wrk_alloc( jpi,jpj, zkz, zsum1 , zsum2 , zsum ) |
---|
224 | CALL wrk_alloc( jpi,jpj,jpk, zempba_3d_1, zempba_3d_2, zempba_3d, zdn2dz, zavt_itf ) |
---|
225 | |
---|
226 | ! ! compute the form function using N2 at each time step |
---|
227 | zempba_3d_1(:,:,jpk) = 0.e0 |
---|
228 | zempba_3d_2(:,:,jpk) = 0.e0 |
---|
229 | DO jk = 1, jpkm1 |
---|
230 | zdn2dz (:,:,jk) = rn2(:,:,jk) - rn2(:,:,jk+1) ! Vertical profile of dN2/dz |
---|
231 | zempba_3d_1(:,:,jk) = SQRT( MAX( 0.e0, rn2(:,:,jk) ) ) ! - - of N |
---|
232 | zempba_3d_2(:,:,jk) = MAX( 0.e0, rn2(:,:,jk) ) ! - - of N^2 |
---|
233 | END DO |
---|
234 | ! |
---|
235 | zsum (:,:) = 0.e0 |
---|
236 | zsum1(:,:) = 0.e0 |
---|
237 | zsum2(:,:) = 0.e0 |
---|
238 | DO jk= 2, jpk |
---|
239 | zsum1(:,:) = zsum1(:,:) + zempba_3d_1(:,:,jk) * e3w_n(:,:,jk) * wmask(:,:,jk) |
---|
240 | zsum2(:,:) = zsum2(:,:) + zempba_3d_2(:,:,jk) * e3w_n(:,:,jk) * wmask(:,:,jk) |
---|
241 | END DO |
---|
242 | DO jj = 1, jpj |
---|
243 | DO ji = 1, jpi |
---|
244 | IF( zsum1(ji,jj) /= 0.e0 ) zsum1(ji,jj) = 1.e0 / zsum1(ji,jj) |
---|
245 | IF( zsum2(ji,jj) /= 0.e0 ) zsum2(ji,jj) = 1.e0 / zsum2(ji,jj) |
---|
246 | END DO |
---|
247 | END DO |
---|
248 | |
---|
249 | DO jk= 1, jpk |
---|
250 | DO jj = 1, jpj |
---|
251 | DO ji = 1, jpi |
---|
252 | zcoef = 0.5 - SIGN( 0.5, zdn2dz(ji,jj,jk) ) ! =0 if dN2/dz > 0, =1 otherwise |
---|
253 | ztpc = zempba_3d_1(ji,jj,jk) * zsum1(ji,jj) * zcoef & |
---|
254 | & + zempba_3d_2(ji,jj,jk) * zsum2(ji,jj) * ( 1. - zcoef ) |
---|
255 | ! |
---|
256 | zempba_3d(ji,jj,jk) = ztpc |
---|
257 | zsum (ji,jj) = zsum(ji,jj) + ztpc * e3w_n(ji,jj,jk) |
---|
258 | END DO |
---|
259 | END DO |
---|
260 | END DO |
---|
261 | DO jj = 1, jpj |
---|
262 | DO ji = 1, jpi |
---|
263 | IF( zsum(ji,jj) > 0.e0 ) zsum(ji,jj) = 1.e0 / zsum(ji,jj) |
---|
264 | END DO |
---|
265 | END DO |
---|
266 | |
---|
267 | ! ! first estimation bounded by 10 cm2/s (with n2 bounded by rn_n2min) |
---|
268 | zcoef = rn_tfe_itf / ( rn_tfe * rau0 ) |
---|
269 | DO jk = 1, jpk |
---|
270 | zavt_itf(:,:,jk) = MIN( 10.e-4, zcoef * en_tmx(:,:) * zsum(:,:) * zempba_3d(:,:,jk) & |
---|
271 | & / MAX( rn_n2min, rn2(:,:,jk) ) * tmask(:,:,jk) ) |
---|
272 | END DO |
---|
273 | |
---|
274 | zkz(:,:) = 0.e0 ! Associated potential energy consummed over the whole water column |
---|
275 | DO jk = 2, jpkm1 |
---|
276 | zkz(:,:) = zkz(:,:) + e3w_n(:,:,jk) * MAX( 0.e0, rn2(:,:,jk) ) * rau0 * zavt_itf(:,:,jk) * wmask(:,:,jk) |
---|
277 | END DO |
---|
278 | |
---|
279 | DO jj = 1, jpj ! Here zkz should be equal to en_tmx ==> multiply by en_tmx/zkz to recover en_tmx |
---|
280 | DO ji = 1, jpi |
---|
281 | IF( zkz(ji,jj) /= 0.e0 ) zkz(ji,jj) = en_tmx(ji,jj) * rn_tfe_itf / rn_tfe / zkz(ji,jj) |
---|
282 | END DO |
---|
283 | END DO |
---|
284 | |
---|
285 | DO jk = 2, jpkm1 ! Mutiply by zkz to recover en_tmx, BUT bound by 30/6 ==> zavt_itf bound by 300 cm2/s |
---|
286 | zavt_itf(:,:,jk) = zavt_itf(:,:,jk) * MIN( zkz(:,:), 120./10. ) * wmask(:,:,jk) ! kz max = 120 cm2/s |
---|
287 | END DO |
---|
288 | |
---|
289 | IF( kt == nit000 ) THEN ! diagnose the nergy consumed by zavt_itf |
---|
290 | ztpc = 0.e0 |
---|
291 | DO jk= 1, jpk |
---|
292 | DO jj= 1, jpj |
---|
293 | DO ji= 1, jpi |
---|
294 | ztpc = ztpc + e1e2t(ji,jj) * e3w_n(ji,jj,jk) * MAX( 0.e0, rn2(ji,jj,jk) ) & |
---|
295 | & * zavt_itf(ji,jj,jk) * tmask(ji,jj,jk) * tmask_i(ji,jj) |
---|
296 | END DO |
---|
297 | END DO |
---|
298 | END DO |
---|
299 | IF( lk_mpp ) CALL mpp_sum( ztpc ) |
---|
300 | ztpc= rau0 * ztpc / ( rn_me * rn_tfe_itf ) |
---|
301 | IF(lwp) WRITE(numout,*) ' N Total power consumption by zavt_itf: ztpc = ', ztpc * 1.e-12 ,'TW' |
---|
302 | ENDIF |
---|
303 | |
---|
304 | ! ! Update pav with the ITF mixing coefficient |
---|
305 | DO jk = 2, jpkm1 |
---|
306 | pav(:,:,jk) = pav (:,:,jk) * ( 1.e0 - mask_itf(:,:) ) & |
---|
307 | & + zavt_itf(:,:,jk) * mask_itf(:,:) |
---|
308 | END DO |
---|
309 | ! |
---|
310 | CALL wrk_dealloc( jpi,jpj, zkz, zsum1 , zsum2 , zsum ) |
---|
311 | CALL wrk_dealloc( jpi,jpj,jpk, zempba_3d_1, zempba_3d_2, zempba_3d, zdn2dz, zavt_itf ) |
---|
312 | ! |
---|
313 | IF( nn_timing == 1 ) CALL timing_stop('tmx_itf') |
---|
314 | ! |
---|
315 | END SUBROUTINE tmx_itf |
---|
316 | |
---|
317 | |
---|
318 | SUBROUTINE zdf_tmx_init |
---|
319 | !!---------------------------------------------------------------------- |
---|
320 | !! *** ROUTINE zdf_tmx_init *** |
---|
321 | !! |
---|
322 | !! ** Purpose : Initialization of the vertical tidal mixing, Reading |
---|
323 | !! of M2 and K1 tidal energy in nc files |
---|
324 | !! |
---|
325 | !! ** Method : - Read the namtmx namelist and check the parameters |
---|
326 | !! |
---|
327 | !! - Read the input data in NetCDF files : |
---|
328 | !! M2 and K1 tidal energy. The total tidal energy, en_tmx, |
---|
329 | !! is the sum of M2, K1 and S2 energy where S2 is assumed |
---|
330 | !! to be: S2=(1/2)^2 * M2 |
---|
331 | !! mask_itf, a mask array that determine where substituing |
---|
332 | !! the standard Simmons et al. (2005) formulation with the |
---|
333 | !! one of Koch_Larrouy et al. (2007). |
---|
334 | !! |
---|
335 | !! - Compute az_tmx, a 3D coefficient that allows to compute |
---|
336 | !! the standard tidal-induced vertical mixing as follows: |
---|
337 | !! Kz_tides = az_tmx / max( rn_n2min, N^2 ) |
---|
338 | !! with az_tmx a bottom intensified coefficient is given by: |
---|
339 | !! az_tmx(z) = en_tmx / ( rau0 * rn_htmx ) * EXP( -(H-z)/rn_htmx ) |
---|
340 | !! / ( 1. - EXP( - H /rn_htmx ) ) |
---|
341 | !! where rn_htmx the characteristic length scale of the bottom |
---|
342 | !! intensification, en_tmx the tidal energy, and H the ocean depth |
---|
343 | !! |
---|
344 | !! ** input : - Namlist namtmx |
---|
345 | !! - NetCDF file : M2_ORCA2.nc, K1_ORCA2.nc, and mask_itf.nc |
---|
346 | !! |
---|
347 | !! ** Action : - Increase by 1 the nstop flag is setting problem encounter |
---|
348 | !! - defined az_tmx used to compute tidal-induced mixing |
---|
349 | !! |
---|
350 | !! References : Simmons et al. 2004, Ocean Modelling, 6, 3-4, 245-263. |
---|
351 | !! Koch-Larrouy et al. 2007, GRL. |
---|
352 | !!---------------------------------------------------------------------- |
---|
353 | INTEGER :: ji, jj, jk ! dummy loop indices |
---|
354 | INTEGER :: inum ! local integer |
---|
355 | INTEGER :: ios |
---|
356 | REAL(wp) :: ztpc, ze_z ! local scalars |
---|
357 | REAL(wp), DIMENSION(:,:) , POINTER :: zem2, zek1 ! read M2 and K1 tidal energy |
---|
358 | REAL(wp), DIMENSION(:,:) , POINTER :: zkz ! total M2, K1 and S2 tidal energy |
---|
359 | REAL(wp), DIMENSION(:,:) , POINTER :: zfact ! used for vertical structure function |
---|
360 | REAL(wp), DIMENSION(:,:) , POINTER :: zhdep ! Ocean depth |
---|
361 | REAL(wp), DIMENSION(:,:,:), POINTER :: zpc, zav_tide ! power consumption |
---|
362 | !! |
---|
363 | NAMELIST/namzdf_tmx/ rn_htmx, rn_n2min, rn_tfe, rn_me, ln_tmx_itf, rn_tfe_itf |
---|
364 | !!---------------------------------------------------------------------- |
---|
365 | ! |
---|
366 | IF( nn_timing == 1 ) CALL timing_start('zdf_tmx_init') |
---|
367 | ! |
---|
368 | CALL wrk_alloc( jpi,jpj, zem2, zek1, zkz, zfact, zhdep ) |
---|
369 | CALL wrk_alloc( jpi,jpj,jpk, zpc, zav_tide ) |
---|
370 | ! |
---|
371 | REWIND( numnam_ref ) ! Namelist namzdf_tmx in reference namelist : Tidal Mixing |
---|
372 | READ ( numnam_ref, namzdf_tmx, IOSTAT = ios, ERR = 901) |
---|
373 | 901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namzdf_tmx in reference namelist', lwp ) |
---|
374 | ! |
---|
375 | REWIND( numnam_cfg ) ! Namelist namzdf_tmx in configuration namelist : Tidal Mixing |
---|
376 | READ ( numnam_cfg, namzdf_tmx, IOSTAT = ios, ERR = 902 ) |
---|
377 | 902 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namzdf_tmx in configuration namelist', lwp ) |
---|
378 | IF(lwm) WRITE ( numond, namzdf_tmx ) |
---|
379 | ! |
---|
380 | IF(lwp) THEN ! Control print |
---|
381 | WRITE(numout,*) |
---|
382 | WRITE(numout,*) 'zdf_tmx_init : tidal mixing' |
---|
383 | WRITE(numout,*) '~~~~~~~~~~~~' |
---|
384 | WRITE(numout,*) ' Namelist namzdf_tmx : set tidal mixing parameters' |
---|
385 | WRITE(numout,*) ' Vertical decay scale for turbulence = ', rn_htmx |
---|
386 | WRITE(numout,*) ' Brunt-Vaisala frequency threshold = ', rn_n2min |
---|
387 | WRITE(numout,*) ' Tidal dissipation efficiency = ', rn_tfe |
---|
388 | WRITE(numout,*) ' Mixing efficiency = ', rn_me |
---|
389 | WRITE(numout,*) ' ITF specific parameterisation = ', ln_tmx_itf |
---|
390 | WRITE(numout,*) ' ITF tidal dissipation efficiency = ', rn_tfe_itf |
---|
391 | ENDIF |
---|
392 | ! ! allocate tmx arrays |
---|
393 | IF( zdf_tmx_alloc() /= 0 ) CALL ctl_stop( 'STOP', 'zdf_tmx_init : unable to allocate tmx arrays' ) |
---|
394 | |
---|
395 | IF( ln_tmx_itf ) THEN ! read the Indonesian Through Flow mask |
---|
396 | CALL iom_open('mask_itf',inum) |
---|
397 | CALL iom_get (inum, jpdom_data, 'tmaskitf',mask_itf,1) ! |
---|
398 | CALL iom_close(inum) |
---|
399 | ENDIF |
---|
400 | ! ! read M2 tidal energy flux : W/m2 ( zem2 < 0 ) |
---|
401 | CALL iom_open('M2rowdrg',inum) |
---|
402 | CALL iom_get (inum, jpdom_data, 'field',zem2,1) ! |
---|
403 | CALL iom_close(inum) |
---|
404 | ! ! read K1 tidal energy flux : W/m2 ( zek1 < 0 ) |
---|
405 | CALL iom_open('K1rowdrg',inum) |
---|
406 | CALL iom_get (inum, jpdom_data, 'field',zek1,1) ! |
---|
407 | CALL iom_close(inum) |
---|
408 | ! ! Total tidal energy ( M2, S2 and K1 with S2=(1/2)^2 * M2 ) |
---|
409 | ! ! only the energy available for mixing is taken into account, |
---|
410 | ! ! (mixing efficiency tidal dissipation efficiency) |
---|
411 | en_tmx(:,:) = - rn_tfe * rn_me * ( zem2(:,:) * 1.25 + zek1(:,:) ) * ssmask(:,:) |
---|
412 | |
---|
413 | !============ |
---|
414 | !TG: Bug for VVL? Should this section be moved out of _init and be updated at every timestep? |
---|
415 | !!gm : you are right, but tidal mixing acts in deep ocean (H>500m) where e3 is O(100m) |
---|
416 | !! the error is thus ~1% which I feel comfortable with, compared to uncertainties in tidal energy dissipation. |
---|
417 | ! ! Vertical structure (az_tmx) |
---|
418 | DO jj = 1, jpj ! part independent of the level |
---|
419 | DO ji = 1, jpi |
---|
420 | zhdep(ji,jj) = gdepw_0(ji,jj,mbkt(ji,jj)+1) ! depth of the ocean |
---|
421 | zfact(ji,jj) = rau0 * rn_htmx * ( 1. - EXP( -zhdep(ji,jj) / rn_htmx ) ) |
---|
422 | IF( zfact(ji,jj) /= 0 ) zfact(ji,jj) = en_tmx(ji,jj) / zfact(ji,jj) |
---|
423 | END DO |
---|
424 | END DO |
---|
425 | DO jk= 1, jpk ! complete with the level-dependent part |
---|
426 | DO jj = 1, jpj |
---|
427 | DO ji = 1, jpi |
---|
428 | az_tmx(ji,jj,jk) = zfact(ji,jj) * EXP( -( zhdep(ji,jj)-gdepw_0(ji,jj,jk) ) / rn_htmx ) * tmask(ji,jj,jk) |
---|
429 | END DO |
---|
430 | END DO |
---|
431 | END DO |
---|
432 | !=========== |
---|
433 | ! |
---|
434 | IF( nprint == 1 .AND. lwp ) THEN |
---|
435 | ! Control print |
---|
436 | ! Total power consumption due to vertical mixing |
---|
437 | ! zpc = rau0 * 1/rn_me * rn2 * zav_tide |
---|
438 | zav_tide(:,:,:) = 0.e0 |
---|
439 | DO jk = 2, jpkm1 |
---|
440 | zav_tide(:,:,jk) = az_tmx(:,:,jk) / MAX( rn_n2min, rn2(:,:,jk) ) |
---|
441 | END DO |
---|
442 | ! |
---|
443 | ztpc = 0._wp |
---|
444 | zpc(:,:,:) = MAX(rn_n2min,rn2(:,:,:)) * zav_tide(:,:,:) |
---|
445 | DO jk= 2, jpkm1 |
---|
446 | DO jj = 1, jpj |
---|
447 | DO ji = 1, jpi |
---|
448 | ztpc = ztpc + e3w_n(ji,jj,jk) * e1e2t(ji,jj) * zpc(ji,jj,jk) * wmask(ji,jj,jk) * tmask_i(ji,jj) |
---|
449 | END DO |
---|
450 | END DO |
---|
451 | END DO |
---|
452 | IF( lk_mpp ) CALL mpp_sum( ztpc ) |
---|
453 | ztpc= rau0 * 1/(rn_tfe * rn_me) * ztpc |
---|
454 | ! |
---|
455 | WRITE(numout,*) |
---|
456 | WRITE(numout,*) ' Total power consumption of the tidally driven part of Kz : ztpc = ', ztpc * 1.e-12 ,'TW' |
---|
457 | ! |
---|
458 | ! control print 2 |
---|
459 | zav_tide(:,:,:) = MIN( zav_tide(:,:,:), 60.e-4 ) |
---|
460 | zkz(:,:) = 0._wp |
---|
461 | DO jk = 2, jpkm1 |
---|
462 | zkz(:,:) = zkz(:,:) + e3w_n(:,:,jk) * MAX(0.e0, rn2(:,:,jk)) * rau0 * zav_tide(:,:,jk) * wmask(:,:,jk) |
---|
463 | END DO |
---|
464 | ! Here zkz should be equal to en_tmx ==> multiply by en_tmx/zkz |
---|
465 | DO jj = 1, jpj |
---|
466 | DO ji = 1, jpi |
---|
467 | IF( zkz(ji,jj) /= 0.e0 ) THEN |
---|
468 | zkz(ji,jj) = en_tmx(ji,jj) / zkz(ji,jj) |
---|
469 | ENDIF |
---|
470 | END DO |
---|
471 | END DO |
---|
472 | ztpc = 1.e50 |
---|
473 | DO jj = 1, jpj |
---|
474 | DO ji = 1, jpi |
---|
475 | IF( zkz(ji,jj) /= 0.e0 ) THEN |
---|
476 | ztpc = Min( zkz(ji,jj), ztpc) |
---|
477 | ENDIF |
---|
478 | END DO |
---|
479 | END DO |
---|
480 | WRITE(numout,*) ' Min de zkz ', ztpc, ' Max = ', maxval(zkz(:,:) ) |
---|
481 | ! |
---|
482 | DO jk = 2, jpkm1 |
---|
483 | zav_tide(:,:,jk) = zav_tide(:,:,jk) * MIN( zkz(:,:), 30./6. ) * wmask(:,:,jk) !kz max = 300 cm2/s |
---|
484 | END DO |
---|
485 | ztpc = 0._wp |
---|
486 | zpc(:,:,:) = Max(0.e0,rn2(:,:,:)) * zav_tide(:,:,:) |
---|
487 | DO jk= 1, jpk |
---|
488 | DO jj = 1, jpj |
---|
489 | DO ji = 1, jpi |
---|
490 | ztpc = ztpc + e3w_n(ji,jj,jk) * e1e2t(ji,jj) * zpc(ji,jj,jk) * wmask(ji,jj,jk) * tmask_i(ji,jj) |
---|
491 | END DO |
---|
492 | END DO |
---|
493 | END DO |
---|
494 | IF( lk_mpp ) CALL mpp_sum( ztpc ) |
---|
495 | ztpc= rau0 * 1/(rn_tfe * rn_me) * ztpc |
---|
496 | WRITE(numout,*) ' 2 Total power consumption of the tidally driven part of Kz : ztpc = ', ztpc * 1.e-12 ,'TW' |
---|
497 | !!gm bug mpp in these diagnostics |
---|
498 | DO jk = 1, jpk |
---|
499 | ze_z = SUM( e1e2t(:,:) * zav_tide(:,:,jk) * tmask_i(:,:) ) & |
---|
500 | & / MAX( 1.e-20, SUM( e1e2t(:,:) * wmask (:,:,jk) * tmask_i(:,:) ) ) |
---|
501 | ztpc = 1.e50 |
---|
502 | DO jj = 1, jpj |
---|
503 | DO ji = 1, jpi |
---|
504 | IF( zav_tide(ji,jj,jk) /= 0.e0 ) ztpc = MIN( ztpc, zav_tide(ji,jj,jk) ) |
---|
505 | END DO |
---|
506 | END DO |
---|
507 | WRITE(numout,*) ' N2 min - jk= ', jk,' ', ze_z * 1.e4,' cm2/s min= ',ztpc*1.e4, & |
---|
508 | & 'max= ', MAXVAL(zav_tide(:,:,jk) )*1.e4, ' cm2/s' |
---|
509 | END DO |
---|
510 | |
---|
511 | WRITE(numout,*) ' e_tide : ', SUM( e1e2t*en_tmx ) / ( rn_tfe * rn_me ) * 1.e-12, 'TW' |
---|
512 | WRITE(numout,*) |
---|
513 | WRITE(numout,*) ' Initial profile of tidal vertical mixing' |
---|
514 | DO jk = 1, jpk |
---|
515 | DO jj = 1,jpj |
---|
516 | DO ji = 1,jpi |
---|
517 | zkz(ji,jj) = az_tmx(ji,jj,jk) /MAX( rn_n2min, rn2(ji,jj,jk) ) |
---|
518 | END DO |
---|
519 | END DO |
---|
520 | ze_z = SUM( e1e2t(:,:) * zkz (:,:) * tmask_i(:,:) ) & |
---|
521 | & / MAX( 1.e-20, SUM( e1e2t(:,:) * wmask(:,:,jk) * tmask_i(:,:) ) ) |
---|
522 | WRITE(numout,*) ' jk= ', jk,' ', ze_z * 1.e4,' cm2/s' |
---|
523 | END DO |
---|
524 | DO jk = 1, jpk |
---|
525 | zkz(:,:) = az_tmx(:,:,jk) /rn_n2min |
---|
526 | ze_z = SUM( e1e2t(:,:) * zkz (:,:) * tmask_i(:,:) ) & |
---|
527 | & / MAX( 1.e-20, SUM( e1e2t(:,:) * wmask(:,:,jk) * tmask_i(:,:) ) ) |
---|
528 | WRITE(numout,*) |
---|
529 | WRITE(numout,*) ' N2 min - jk= ', jk,' ', ze_z * 1.e4,' cm2/s min= ',MINVAL(zkz)*1.e4, & |
---|
530 | & 'max= ', MAXVAL(zkz)*1.e4, ' cm2/s' |
---|
531 | END DO |
---|
532 | !!gm end bug mpp |
---|
533 | ! |
---|
534 | ENDIF |
---|
535 | ! |
---|
536 | CALL wrk_dealloc( jpi,jpj, zem2, zek1, zkz, zfact, zhdep ) |
---|
537 | CALL wrk_dealloc( jpi,jpj,jpk, zpc, zav_tide ) |
---|
538 | ! |
---|
539 | IF( nn_timing == 1 ) CALL timing_stop('zdf_tmx_init') |
---|
540 | ! |
---|
541 | END SUBROUTINE zdf_tmx_init |
---|
542 | |
---|
543 | #elif defined key_zdftmx_new |
---|
544 | !!---------------------------------------------------------------------- |
---|
545 | !! 'key_zdftmx_new' Internal wave-driven vertical mixing |
---|
546 | !!---------------------------------------------------------------------- |
---|
547 | !! zdf_tmx : global momentum & tracer Kz with wave induced Kz |
---|
548 | !! zdf_tmx_init : global momentum & tracer Kz with wave induced Kz |
---|
549 | !!---------------------------------------------------------------------- |
---|
550 | USE oce ! ocean dynamics and tracers variables |
---|
551 | USE dom_oce ! ocean space and time domain variables |
---|
552 | USE zdf_oce ! ocean vertical physics variables |
---|
553 | USE zdfddm ! ocean vertical physics: double diffusive mixing |
---|
554 | USE lbclnk ! ocean lateral boundary conditions (or mpp link) |
---|
555 | USE eosbn2 ! ocean equation of state |
---|
556 | USE phycst ! physical constants |
---|
557 | USE prtctl ! Print control |
---|
558 | USE in_out_manager ! I/O manager |
---|
559 | USE iom ! I/O Manager |
---|
560 | USE lib_mpp ! MPP library |
---|
561 | USE wrk_nemo ! work arrays |
---|
562 | USE timing ! Timing |
---|
563 | USE lib_fortran ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) |
---|
564 | |
---|
565 | IMPLICIT NONE |
---|
566 | PRIVATE |
---|
567 | |
---|
568 | PUBLIC zdf_tmx ! called in step module |
---|
569 | PUBLIC zdf_tmx_init ! called in nemogcm module |
---|
570 | PUBLIC zdf_tmx_alloc ! called in nemogcm module |
---|
571 | |
---|
572 | LOGICAL, PUBLIC, PARAMETER :: lk_zdftmx = .TRUE. !: wave-driven mixing flag |
---|
573 | |
---|
574 | ! !!* Namelist namzdf_tmx : internal wave-driven mixing * |
---|
575 | INTEGER :: nn_zpyc ! pycnocline-intensified mixing energy proportional to N (=1) or N^2 (=2) |
---|
576 | LOGICAL :: ln_mevar ! variable (=T) or constant (=F) mixing efficiency |
---|
577 | LOGICAL :: ln_tsdiff ! account for differential T/S wave-driven mixing (=T) or not (=F) |
---|
578 | |
---|
579 | REAL(wp) :: r1_6 = 1._wp / 6._wp |
---|
580 | |
---|
581 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: ebot_tmx ! power available from high-mode wave breaking (W/m2) |
---|
582 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: epyc_tmx ! power available from low-mode, pycnocline-intensified wave breaking (W/m2) |
---|
583 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: ecri_tmx ! power available from low-mode, critical slope wave breaking (W/m2) |
---|
584 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: hbot_tmx ! WKB decay scale for high-mode energy dissipation (m) |
---|
585 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: hcri_tmx ! decay scale for low-mode critical slope dissipation (m) |
---|
586 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: emix_tmx ! local energy density available for mixing (W/kg) |
---|
587 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: bflx_tmx ! buoyancy flux Kz * N^2 (W/kg) |
---|
588 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: pcmap_tmx ! vertically integrated buoyancy flux (W/m2) |
---|
589 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: zav_ratio ! S/T diffusivity ratio (only for ln_tsdiff=T) |
---|
590 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: zav_wave ! Internal wave-induced diffusivity |
---|
591 | |
---|
592 | !! * Substitutions |
---|
593 | # include "zdfddm_substitute.h90" |
---|
594 | # include "vectopt_loop_substitute.h90" |
---|
595 | !!---------------------------------------------------------------------- |
---|
596 | !! NEMO/OPA 4.0 , NEMO Consortium (2016) |
---|
597 | !! $Id$ |
---|
598 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
---|
599 | !!---------------------------------------------------------------------- |
---|
600 | CONTAINS |
---|
601 | |
---|
602 | INTEGER FUNCTION zdf_tmx_alloc() |
---|
603 | !!---------------------------------------------------------------------- |
---|
604 | !! *** FUNCTION zdf_tmx_alloc *** |
---|
605 | !!---------------------------------------------------------------------- |
---|
606 | ALLOCATE( ebot_tmx(jpi,jpj), epyc_tmx(jpi,jpj), ecri_tmx(jpi,jpj) , & |
---|
607 | & hbot_tmx(jpi,jpj), hcri_tmx(jpi,jpj), emix_tmx(jpi,jpj,jpk), & |
---|
608 | & bflx_tmx(jpi,jpj,jpk), pcmap_tmx(jpi,jpj), zav_ratio(jpi,jpj,jpk), & |
---|
609 | & zav_wave(jpi,jpj,jpk), STAT=zdf_tmx_alloc ) |
---|
610 | ! |
---|
611 | IF( lk_mpp ) CALL mpp_sum ( zdf_tmx_alloc ) |
---|
612 | IF( zdf_tmx_alloc /= 0 ) CALL ctl_warn('zdf_tmx_alloc: failed to allocate arrays') |
---|
613 | END FUNCTION zdf_tmx_alloc |
---|
614 | |
---|
615 | |
---|
616 | SUBROUTINE zdf_tmx( kt ) |
---|
617 | !!---------------------------------------------------------------------- |
---|
618 | !! *** ROUTINE zdf_tmx *** |
---|
619 | !! |
---|
620 | !! ** Purpose : add to the vertical mixing coefficients the effect of |
---|
621 | !! breaking internal waves. |
---|
622 | !! |
---|
623 | !! ** Method : - internal wave-driven vertical mixing is given by: |
---|
624 | !! Kz_wave = min( 100 cm2/s, f( Reb = emix_tmx /( Nu * N^2 ) ) |
---|
625 | !! where emix_tmx is the 3D space distribution of the wave-breaking |
---|
626 | !! energy and Nu the molecular kinematic viscosity. |
---|
627 | !! The function f(Reb) is linear (constant mixing efficiency) |
---|
628 | !! if the namelist parameter ln_mevar = F and nonlinear if ln_mevar = T. |
---|
629 | !! |
---|
630 | !! - Compute emix_tmx, the 3D power density that allows to compute |
---|
631 | !! Reb and therefrom the wave-induced vertical diffusivity. |
---|
632 | !! This is divided into three components: |
---|
633 | !! 1. Bottom-intensified low-mode dissipation at critical slopes |
---|
634 | !! emix_tmx(z) = ( ecri_tmx / rau0 ) * EXP( -(H-z)/hcri_tmx ) |
---|
635 | !! / ( 1. - EXP( - H/hcri_tmx ) ) * hcri_tmx |
---|
636 | !! where hcri_tmx is the characteristic length scale of the bottom |
---|
637 | !! intensification, ecri_tmx a map of available power, and H the ocean depth. |
---|
638 | !! 2. Pycnocline-intensified low-mode dissipation |
---|
639 | !! emix_tmx(z) = ( epyc_tmx / rau0 ) * ( sqrt(rn2(z))^nn_zpyc ) |
---|
640 | !! / SUM( sqrt(rn2(z))^nn_zpyc * e3w(z) ) |
---|
641 | !! where epyc_tmx is a map of available power, and nn_zpyc |
---|
642 | !! is the chosen stratification-dependence of the internal wave |
---|
643 | !! energy dissipation. |
---|
644 | !! 3. WKB-height dependent high mode dissipation |
---|
645 | !! emix_tmx(z) = ( ebot_tmx / rau0 ) * rn2(z) * EXP(-z_wkb(z)/hbot_tmx) |
---|
646 | !! / SUM( rn2(z) * EXP(-z_wkb(z)/hbot_tmx) * e3w(z) ) |
---|
647 | !! where hbot_tmx is the characteristic length scale of the WKB bottom |
---|
648 | !! intensification, ebot_tmx is a map of available power, and z_wkb is the |
---|
649 | !! WKB-stretched height above bottom defined as |
---|
650 | !! z_wkb(z) = H * SUM( sqrt(rn2(z'>=z)) * e3w(z'>=z) ) |
---|
651 | !! / SUM( sqrt(rn2(z')) * e3w(z') ) |
---|
652 | !! |
---|
653 | !! - update the model vertical eddy viscosity and diffusivity: |
---|
654 | !! avt = avt + av_wave |
---|
655 | !! avm = avm + av_wave |
---|
656 | !! avmu = avmu + mi(av_wave) |
---|
657 | !! avmv = avmv + mj(av_wave) |
---|
658 | !! |
---|
659 | !! - if namelist parameter ln_tsdiff = T, account for differential mixing: |
---|
660 | !! avs = avt + av_wave * diffusivity_ratio(Reb) |
---|
661 | !! |
---|
662 | !! ** Action : - Define emix_tmx used to compute internal wave-induced mixing |
---|
663 | !! - avt, avs, avm, avmu, avmv increased by internal wave-driven mixing |
---|
664 | !! |
---|
665 | !! References : de Lavergne et al. 2015, JPO; 2016, in prep. |
---|
666 | !!---------------------------------------------------------------------- |
---|
667 | INTEGER, INTENT(in) :: kt ! ocean time-step |
---|
668 | ! |
---|
669 | INTEGER :: ji, jj, jk ! dummy loop indices |
---|
670 | REAL(wp) :: ztpc ! scalar workspace |
---|
671 | REAL(wp), DIMENSION(:,:) , POINTER :: zfact ! Used for vertical structure |
---|
672 | REAL(wp), DIMENSION(:,:) , POINTER :: zhdep ! Ocean depth |
---|
673 | REAL(wp), DIMENSION(:,:,:), POINTER :: zwkb ! WKB-stretched height above bottom |
---|
674 | REAL(wp), DIMENSION(:,:,:), POINTER :: zweight ! Weight for high mode vertical distribution |
---|
675 | REAL(wp), DIMENSION(:,:,:), POINTER :: znu_t ! Molecular kinematic viscosity (T grid) |
---|
676 | REAL(wp), DIMENSION(:,:,:), POINTER :: znu_w ! Molecular kinematic viscosity (W grid) |
---|
677 | REAL(wp), DIMENSION(:,:,:), POINTER :: zReb ! Turbulence intensity parameter |
---|
678 | !!---------------------------------------------------------------------- |
---|
679 | ! |
---|
680 | IF( nn_timing == 1 ) CALL timing_start('zdf_tmx') |
---|
681 | ! |
---|
682 | CALL wrk_alloc( jpi,jpj, zfact, zhdep ) |
---|
683 | CALL wrk_alloc( jpi,jpj,jpk, zwkb, zweight, znu_t, znu_w, zReb ) |
---|
684 | |
---|
685 | ! ! ----------------------------- ! |
---|
686 | ! ! Internal wave-driven mixing ! (compute zav_wave) |
---|
687 | ! ! ----------------------------- ! |
---|
688 | ! |
---|
689 | ! !* Critical slope mixing: distribute energy over the time-varying ocean depth, |
---|
690 | ! using an exponential decay from the seafloor. |
---|
691 | DO jj = 1, jpj ! part independent of the level |
---|
692 | DO ji = 1, jpi |
---|
693 | zhdep(ji,jj) = gdepw_0(ji,jj,mbkt(ji,jj)+1) ! depth of the ocean |
---|
694 | zfact(ji,jj) = rau0 * ( 1._wp - EXP( -zhdep(ji,jj) / hcri_tmx(ji,jj) ) ) |
---|
695 | IF( zfact(ji,jj) /= 0 ) zfact(ji,jj) = ecri_tmx(ji,jj) / zfact(ji,jj) |
---|
696 | END DO |
---|
697 | END DO |
---|
698 | |
---|
699 | DO jk = 2, jpkm1 ! complete with the level-dependent part |
---|
700 | emix_tmx(:,:,jk) = zfact(:,:) * ( EXP( ( gde3w_n(:,:,jk ) - zhdep(:,:) ) / hcri_tmx(:,:) ) & |
---|
701 | & - EXP( ( gde3w_n(:,:,jk-1) - zhdep(:,:) ) / hcri_tmx(:,:) ) ) * wmask(:,:,jk) & |
---|
702 | & / ( gde3w_n(:,:,jk) - gde3w_n(:,:,jk-1) ) |
---|
703 | END DO |
---|
704 | |
---|
705 | ! !* Pycnocline-intensified mixing: distribute energy over the time-varying |
---|
706 | ! !* ocean depth as proportional to sqrt(rn2)^nn_zpyc |
---|
707 | |
---|
708 | SELECT CASE ( nn_zpyc ) |
---|
709 | |
---|
710 | CASE ( 1 ) ! Dissipation scales as N (recommended) |
---|
711 | |
---|
712 | zfact(:,:) = 0._wp |
---|
713 | DO jk = 2, jpkm1 ! part independent of the level |
---|
714 | zfact(:,:) = zfact(:,:) + e3w_n(:,:,jk) * SQRT( MAX( 0._wp, rn2(:,:,jk) ) ) * wmask(:,:,jk) |
---|
715 | END DO |
---|
716 | |
---|
717 | DO jj = 1, jpj |
---|
718 | DO ji = 1, jpi |
---|
719 | IF( zfact(ji,jj) /= 0 ) zfact(ji,jj) = epyc_tmx(ji,jj) / ( rau0 * zfact(ji,jj) ) |
---|
720 | END DO |
---|
721 | END DO |
---|
722 | |
---|
723 | DO jk = 2, jpkm1 ! complete with the level-dependent part |
---|
724 | emix_tmx(:,:,jk) = emix_tmx(:,:,jk) + zfact(:,:) * SQRT( MAX( 0._wp, rn2(:,:,jk) ) ) * wmask(:,:,jk) |
---|
725 | END DO |
---|
726 | |
---|
727 | CASE ( 2 ) ! Dissipation scales as N^2 |
---|
728 | |
---|
729 | zfact(:,:) = 0._wp |
---|
730 | DO jk = 2, jpkm1 ! part independent of the level |
---|
731 | zfact(:,:) = zfact(:,:) + e3w_n(:,:,jk) * MAX( 0._wp, rn2(:,:,jk) ) * wmask(:,:,jk) |
---|
732 | END DO |
---|
733 | |
---|
734 | DO jj= 1, jpj |
---|
735 | DO ji = 1, jpi |
---|
736 | IF( zfact(ji,jj) /= 0 ) zfact(ji,jj) = epyc_tmx(ji,jj) / ( rau0 * zfact(ji,jj) ) |
---|
737 | END DO |
---|
738 | END DO |
---|
739 | |
---|
740 | DO jk = 2, jpkm1 ! complete with the level-dependent part |
---|
741 | emix_tmx(:,:,jk) = emix_tmx(:,:,jk) + zfact(:,:) * MAX( 0._wp, rn2(:,:,jk) ) * wmask(:,:,jk) |
---|
742 | END DO |
---|
743 | |
---|
744 | END SELECT |
---|
745 | |
---|
746 | ! !* WKB-height dependent mixing: distribute energy over the time-varying |
---|
747 | ! !* ocean depth as proportional to rn2 * exp(-z_wkb/rn_hbot) |
---|
748 | |
---|
749 | zwkb(:,:,:) = 0._wp |
---|
750 | zfact(:,:) = 0._wp |
---|
751 | DO jk = 2, jpkm1 |
---|
752 | zfact(:,:) = zfact(:,:) + e3w_n(:,:,jk) * SQRT( MAX( 0._wp, rn2(:,:,jk) ) ) * wmask(:,:,jk) |
---|
753 | zwkb(:,:,jk) = zfact(:,:) |
---|
754 | END DO |
---|
755 | |
---|
756 | DO jk = 2, jpkm1 |
---|
757 | DO jj = 1, jpj |
---|
758 | DO ji = 1, jpi |
---|
759 | IF( zfact(ji,jj) /= 0 ) zwkb(ji,jj,jk) = zhdep(ji,jj) * ( zfact(ji,jj) - zwkb(ji,jj,jk) ) & |
---|
760 | & * tmask(ji,jj,jk) / zfact(ji,jj) |
---|
761 | END DO |
---|
762 | END DO |
---|
763 | END DO |
---|
764 | zwkb(:,:,1) = zhdep(:,:) * tmask(:,:,1) |
---|
765 | |
---|
766 | zweight(:,:,:) = 0._wp |
---|
767 | DO jk = 2, jpkm1 |
---|
768 | zweight(:,:,jk) = MAX( 0._wp, rn2(:,:,jk) ) * hbot_tmx(:,:) * wmask(:,:,jk) & |
---|
769 | & * ( EXP( -zwkb(:,:,jk) / hbot_tmx(:,:) ) - EXP( -zwkb(:,:,jk-1) / hbot_tmx(:,:) ) ) |
---|
770 | END DO |
---|
771 | |
---|
772 | zfact(:,:) = 0._wp |
---|
773 | DO jk = 2, jpkm1 ! part independent of the level |
---|
774 | zfact(:,:) = zfact(:,:) + zweight(:,:,jk) |
---|
775 | END DO |
---|
776 | |
---|
777 | DO jj = 1, jpj |
---|
778 | DO ji = 1, jpi |
---|
779 | IF( zfact(ji,jj) /= 0 ) zfact(ji,jj) = ebot_tmx(ji,jj) / ( rau0 * zfact(ji,jj) ) |
---|
780 | END DO |
---|
781 | END DO |
---|
782 | |
---|
783 | DO jk = 2, jpkm1 ! complete with the level-dependent part |
---|
784 | emix_tmx(:,:,jk) = emix_tmx(:,:,jk) + zweight(:,:,jk) * zfact(:,:) * wmask(:,:,jk) & |
---|
785 | & / ( gde3w_n(:,:,jk) - gde3w_n(:,:,jk-1) ) |
---|
786 | END DO |
---|
787 | |
---|
788 | |
---|
789 | ! Calculate molecular kinematic viscosity |
---|
790 | znu_t(:,:,:) = 1.e-4_wp * ( 17.91_wp - 0.53810_wp * tsn(:,:,:,jp_tem) + 0.00694_wp * tsn(:,:,:,jp_tem) * tsn(:,:,:,jp_tem) & |
---|
791 | & + 0.02305_wp * tsn(:,:,:,jp_sal) ) * tmask(:,:,:) * r1_rau0 |
---|
792 | DO jk = 2, jpkm1 |
---|
793 | znu_w(:,:,jk) = 0.5_wp * ( znu_t(:,:,jk-1) + znu_t(:,:,jk) ) * wmask(:,:,jk) |
---|
794 | END DO |
---|
795 | |
---|
796 | ! Calculate turbulence intensity parameter Reb |
---|
797 | DO jk = 2, jpkm1 |
---|
798 | zReb(:,:,jk) = emix_tmx(:,:,jk) / MAX( 1.e-20_wp, znu_w(:,:,jk) * rn2(:,:,jk) ) |
---|
799 | END DO |
---|
800 | |
---|
801 | ! Define internal wave-induced diffusivity |
---|
802 | DO jk = 2, jpkm1 |
---|
803 | zav_wave(:,:,jk) = znu_w(:,:,jk) * zReb(:,:,jk) * r1_6 ! This corresponds to a constant mixing efficiency of 1/6 |
---|
804 | END DO |
---|
805 | |
---|
806 | IF( ln_mevar ) THEN ! Variable mixing efficiency case : modify zav_wave in the |
---|
807 | DO jk = 2, jpkm1 ! energetic (Reb > 480) and buoyancy-controlled (Reb <10.224 ) regimes |
---|
808 | DO jj = 1, jpj |
---|
809 | DO ji = 1, jpi |
---|
810 | IF( zReb(ji,jj,jk) > 480.00_wp ) THEN |
---|
811 | zav_wave(ji,jj,jk) = 3.6515_wp * znu_w(ji,jj,jk) * SQRT( zReb(ji,jj,jk) ) |
---|
812 | ELSEIF( zReb(ji,jj,jk) < 10.224_wp ) THEN |
---|
813 | zav_wave(ji,jj,jk) = 0.052125_wp * znu_w(ji,jj,jk) * zReb(ji,jj,jk) * SQRT( zReb(ji,jj,jk) ) |
---|
814 | ENDIF |
---|
815 | END DO |
---|
816 | END DO |
---|
817 | END DO |
---|
818 | ENDIF |
---|
819 | |
---|
820 | DO jk = 2, jpkm1 ! Bound diffusivity by molecular value and 100 cm2/s |
---|
821 | zav_wave(:,:,jk) = MIN( MAX( 1.4e-7_wp, zav_wave(:,:,jk) ), 1.e-2_wp ) * wmask(:,:,jk) |
---|
822 | END DO |
---|
823 | |
---|
824 | IF( kt == nit000 ) THEN !* Control print at first time-step: diagnose the energy consumed by zav_wave |
---|
825 | ztpc = 0._wp |
---|
826 | DO jk = 2, jpkm1 |
---|
827 | DO jj = 1, jpj |
---|
828 | DO ji = 1, jpi |
---|
829 | ztpc = ztpc + e3w_n(ji,jj,jk) * e1e2t(ji,jj) & |
---|
830 | & * MAX( 0._wp, rn2(ji,jj,jk) ) * zav_wave(ji,jj,jk) * wmask(ji,jj,jk) * tmask_i(ji,jj) |
---|
831 | END DO |
---|
832 | END DO |
---|
833 | END DO |
---|
834 | IF( lk_mpp ) CALL mpp_sum( ztpc ) |
---|
835 | ztpc = rau0 * ztpc ! Global integral of rauo * Kz * N^2 = power contributing to mixing |
---|
836 | |
---|
837 | IF(lwp) THEN |
---|
838 | WRITE(numout,*) |
---|
839 | WRITE(numout,*) 'zdf_tmx : Internal wave-driven mixing (tmx)' |
---|
840 | WRITE(numout,*) '~~~~~~~ ' |
---|
841 | WRITE(numout,*) |
---|
842 | WRITE(numout,*) ' Total power consumption by av_wave: ztpc = ', ztpc * 1.e-12_wp, 'TW' |
---|
843 | ENDIF |
---|
844 | ENDIF |
---|
845 | |
---|
846 | ! ! ----------------------- ! |
---|
847 | ! ! Update mixing coefs ! |
---|
848 | ! ! ----------------------- ! |
---|
849 | ! |
---|
850 | IF( ln_tsdiff ) THEN !* Option for differential mixing of salinity and temperature |
---|
851 | DO jk = 2, jpkm1 ! Calculate S/T diffusivity ratio as a function of Reb |
---|
852 | DO jj = 1, jpj |
---|
853 | DO ji = 1, jpi |
---|
854 | zav_ratio(ji,jj,jk) = ( 0.505_wp + 0.495_wp * & |
---|
855 | & TANH( 0.92_wp * ( LOG10( MAX( 1.e-20_wp, zReb(ji,jj,jk) * 5._wp * r1_6 ) ) - 0.60_wp ) ) & |
---|
856 | & ) * wmask(ji,jj,jk) |
---|
857 | END DO |
---|
858 | END DO |
---|
859 | END DO |
---|
860 | CALL iom_put( "av_ratio", zav_ratio ) |
---|
861 | DO jk = 2, jpkm1 !* update momentum & tracer diffusivity with wave-driven mixing |
---|
862 | fsavs(:,:,jk) = avt(:,:,jk) + zav_wave(:,:,jk) * zav_ratio(:,:,jk) |
---|
863 | avt (:,:,jk) = avt(:,:,jk) + zav_wave(:,:,jk) |
---|
864 | avm (:,:,jk) = avm(:,:,jk) + zav_wave(:,:,jk) |
---|
865 | END DO |
---|
866 | ! |
---|
867 | ELSE !* update momentum & tracer diffusivity with wave-driven mixing |
---|
868 | DO jk = 2, jpkm1 |
---|
869 | fsavs(:,:,jk) = avt(:,:,jk) + zav_wave(:,:,jk) |
---|
870 | avt (:,:,jk) = avt(:,:,jk) + zav_wave(:,:,jk) |
---|
871 | avm (:,:,jk) = avm(:,:,jk) + zav_wave(:,:,jk) |
---|
872 | END DO |
---|
873 | ENDIF |
---|
874 | |
---|
875 | DO jk = 2, jpkm1 !* update momentum diffusivity at wu and wv points |
---|
876 | DO jj = 2, jpjm1 |
---|
877 | DO ji = fs_2, fs_jpim1 ! vector opt. |
---|
878 | avmu(ji,jj,jk) = avmu(ji,jj,jk) + 0.5_wp * ( zav_wave(ji,jj,jk) + zav_wave(ji+1,jj ,jk) ) * wumask(ji,jj,jk) |
---|
879 | avmv(ji,jj,jk) = avmv(ji,jj,jk) + 0.5_wp * ( zav_wave(ji,jj,jk) + zav_wave(ji ,jj+1,jk) ) * wvmask(ji,jj,jk) |
---|
880 | END DO |
---|
881 | END DO |
---|
882 | END DO |
---|
883 | CALL lbc_lnk( avmu, 'U', 1. ) ; CALL lbc_lnk( avmv, 'V', 1. ) ! lateral boundary condition |
---|
884 | |
---|
885 | ! !* output internal wave-driven mixing coefficient |
---|
886 | CALL iom_put( "av_wave", zav_wave ) |
---|
887 | !* output useful diagnostics: N^2, Kz * N^2 (bflx_tmx), |
---|
888 | ! vertical integral of rau0 * Kz * N^2 (pcmap_tmx), energy density (emix_tmx) |
---|
889 | IF( iom_use("bflx_tmx") .OR. iom_use("pcmap_tmx") ) THEN |
---|
890 | bflx_tmx(:,:,:) = MAX( 0._wp, rn2(:,:,:) ) * zav_wave(:,:,:) |
---|
891 | pcmap_tmx(:,:) = 0._wp |
---|
892 | DO jk = 2, jpkm1 |
---|
893 | pcmap_tmx(:,:) = pcmap_tmx(:,:) + e3w_n(:,:,jk) * bflx_tmx(:,:,jk) * wmask(:,:,jk) |
---|
894 | END DO |
---|
895 | pcmap_tmx(:,:) = rau0 * pcmap_tmx(:,:) |
---|
896 | CALL iom_put( "bflx_tmx", bflx_tmx ) |
---|
897 | CALL iom_put( "pcmap_tmx", pcmap_tmx ) |
---|
898 | ENDIF |
---|
899 | CALL iom_put( "bn2", rn2 ) |
---|
900 | CALL iom_put( "emix_tmx", emix_tmx ) |
---|
901 | |
---|
902 | CALL wrk_dealloc( jpi,jpj, zfact, zhdep ) |
---|
903 | CALL wrk_dealloc( jpi,jpj,jpk, zwkb, zweight, znu_t, znu_w, zReb ) |
---|
904 | |
---|
905 | IF(ln_ctl) CALL prt_ctl(tab3d_1=zav_wave , clinfo1=' tmx - av_wave: ', tab3d_2=avt, clinfo2=' avt: ', ovlap=1, kdim=jpk) |
---|
906 | ! |
---|
907 | IF( nn_timing == 1 ) CALL timing_stop('zdf_tmx') |
---|
908 | ! |
---|
909 | END SUBROUTINE zdf_tmx |
---|
910 | |
---|
911 | |
---|
912 | SUBROUTINE zdf_tmx_init |
---|
913 | !!---------------------------------------------------------------------- |
---|
914 | !! *** ROUTINE zdf_tmx_init *** |
---|
915 | !! |
---|
916 | !! ** Purpose : Initialization of the wave-driven vertical mixing, reading |
---|
917 | !! of input power maps and decay length scales in netcdf files. |
---|
918 | !! |
---|
919 | !! ** Method : - Read the namzdf_tmx namelist and check the parameters |
---|
920 | !! |
---|
921 | !! - Read the input data in NetCDF files : |
---|
922 | !! power available from high-mode wave breaking (mixing_power_bot.nc) |
---|
923 | !! power available from pycnocline-intensified wave-breaking (mixing_power_pyc.nc) |
---|
924 | !! power available from critical slope wave-breaking (mixing_power_cri.nc) |
---|
925 | !! WKB decay scale for high-mode wave-breaking (decay_scale_bot.nc) |
---|
926 | !! decay scale for critical slope wave-breaking (decay_scale_cri.nc) |
---|
927 | !! |
---|
928 | !! ** input : - Namlist namzdf_tmx |
---|
929 | !! - NetCDF files : mixing_power_bot.nc, mixing_power_pyc.nc, mixing_power_cri.nc, |
---|
930 | !! decay_scale_bot.nc decay_scale_cri.nc |
---|
931 | !! |
---|
932 | !! ** Action : - Increase by 1 the nstop flag is setting problem encounter |
---|
933 | !! - Define ebot_tmx, epyc_tmx, ecri_tmx, hbot_tmx, hcri_tmx |
---|
934 | !! |
---|
935 | !! References : de Lavergne et al. 2015, JPO; 2016, in prep. |
---|
936 | !! |
---|
937 | !!---------------------------------------------------------------------- |
---|
938 | INTEGER :: ji, jj, jk ! dummy loop indices |
---|
939 | INTEGER :: inum ! local integer |
---|
940 | INTEGER :: ios |
---|
941 | REAL(wp) :: zbot, zpyc, zcri ! local scalars |
---|
942 | !! |
---|
943 | NAMELIST/namzdf_tmx_new/ nn_zpyc, ln_mevar, ln_tsdiff |
---|
944 | !!---------------------------------------------------------------------- |
---|
945 | ! |
---|
946 | IF( nn_timing == 1 ) CALL timing_start('zdf_tmx_init') |
---|
947 | ! |
---|
948 | REWIND( numnam_ref ) ! Namelist namzdf_tmx in reference namelist : Wave-driven mixing |
---|
949 | READ ( numnam_ref, namzdf_tmx_new, IOSTAT = ios, ERR = 901) |
---|
950 | 901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namzdf_tmx in reference namelist', lwp ) |
---|
951 | ! |
---|
952 | REWIND( numnam_cfg ) ! Namelist namzdf_tmx in configuration namelist : Wave-driven mixing |
---|
953 | READ ( numnam_cfg, namzdf_tmx_new, IOSTAT = ios, ERR = 902 ) |
---|
954 | 902 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namzdf_tmx in configuration namelist', lwp ) |
---|
955 | IF(lwm) WRITE ( numond, namzdf_tmx_new ) |
---|
956 | ! |
---|
957 | IF(lwp) THEN ! Control print |
---|
958 | WRITE(numout,*) |
---|
959 | WRITE(numout,*) 'zdf_tmx_init : internal wave-driven mixing' |
---|
960 | WRITE(numout,*) '~~~~~~~~~~~~' |
---|
961 | WRITE(numout,*) ' Namelist namzdf_tmx_new : set wave-driven mixing parameters' |
---|
962 | WRITE(numout,*) ' Pycnocline-intensified diss. scales as N (=1) or N^2 (=2) = ', nn_zpyc |
---|
963 | WRITE(numout,*) ' Variable (T) or constant (F) mixing efficiency = ', ln_mevar |
---|
964 | WRITE(numout,*) ' Differential internal wave-driven mixing (T) or not (F) = ', ln_tsdiff |
---|
965 | ENDIF |
---|
966 | |
---|
967 | ! The new wave-driven mixing parameterization elevates avt and avm in the interior, and |
---|
968 | ! ensures that avt remains larger than its molecular value (=1.4e-7). Therefore, avtb should |
---|
969 | ! be set here to a very small value, and avmb to its (uniform) molecular value (=1.4e-6). |
---|
970 | avmb(:) = 1.4e-6_wp ! viscous molecular value |
---|
971 | avtb(:) = 1.e-10_wp ! very small diffusive minimum (background avt is specified in zdf_tmx) |
---|
972 | avtb_2d(:,:) = 1.e0_wp ! uniform |
---|
973 | IF(lwp) THEN ! Control print |
---|
974 | WRITE(numout,*) |
---|
975 | WRITE(numout,*) ' Force the background value applied to avm & avt in TKE to be everywhere ', & |
---|
976 | & 'the viscous molecular value & a very small diffusive value, resp.' |
---|
977 | ENDIF |
---|
978 | |
---|
979 | IF( .NOT.lk_zdfddm ) CALL ctl_stop( 'STOP', 'zdf_tmx_init_new : key_zdftmx_new requires key_zdfddm' ) |
---|
980 | |
---|
981 | ! ! allocate tmx arrays |
---|
982 | IF( zdf_tmx_alloc() /= 0 ) CALL ctl_stop( 'STOP', 'zdf_tmx_init : unable to allocate tmx arrays' ) |
---|
983 | ! |
---|
984 | ! ! read necessary fields |
---|
985 | CALL iom_open('mixing_power_bot',inum) ! energy flux for high-mode wave breaking [W/m2] |
---|
986 | CALL iom_get (inum, jpdom_data, 'field', ebot_tmx, 1 ) |
---|
987 | CALL iom_close(inum) |
---|
988 | ! |
---|
989 | CALL iom_open('mixing_power_pyc',inum) ! energy flux for pynocline-intensified wave breaking [W/m2] |
---|
990 | CALL iom_get (inum, jpdom_data, 'field', epyc_tmx, 1 ) |
---|
991 | CALL iom_close(inum) |
---|
992 | ! |
---|
993 | CALL iom_open('mixing_power_cri',inum) ! energy flux for critical slope wave breaking [W/m2] |
---|
994 | CALL iom_get (inum, jpdom_data, 'field', ecri_tmx, 1 ) |
---|
995 | CALL iom_close(inum) |
---|
996 | ! |
---|
997 | CALL iom_open('decay_scale_bot',inum) ! spatially variable decay scale for high-mode wave breaking [m] |
---|
998 | CALL iom_get (inum, jpdom_data, 'field', hbot_tmx, 1 ) |
---|
999 | CALL iom_close(inum) |
---|
1000 | ! |
---|
1001 | CALL iom_open('decay_scale_cri',inum) ! spatially variable decay scale for critical slope wave breaking [m] |
---|
1002 | CALL iom_get (inum, jpdom_data, 'field', hcri_tmx, 1 ) |
---|
1003 | CALL iom_close(inum) |
---|
1004 | |
---|
1005 | ebot_tmx(:,:) = ebot_tmx(:,:) * ssmask(:,:) |
---|
1006 | epyc_tmx(:,:) = epyc_tmx(:,:) * ssmask(:,:) |
---|
1007 | ecri_tmx(:,:) = ecri_tmx(:,:) * ssmask(:,:) |
---|
1008 | |
---|
1009 | ! Set once for all to zero the first and last vertical levels of appropriate variables |
---|
1010 | emix_tmx (:,:, 1 ) = 0._wp |
---|
1011 | emix_tmx (:,:,jpk) = 0._wp |
---|
1012 | zav_ratio(:,:, 1 ) = 0._wp |
---|
1013 | zav_ratio(:,:,jpk) = 0._wp |
---|
1014 | zav_wave (:,:, 1 ) = 0._wp |
---|
1015 | zav_wave (:,:,jpk) = 0._wp |
---|
1016 | |
---|
1017 | zbot = glob_sum( e1e2t(:,:) * ebot_tmx(:,:) ) |
---|
1018 | zpyc = glob_sum( e1e2t(:,:) * epyc_tmx(:,:) ) |
---|
1019 | zcri = glob_sum( e1e2t(:,:) * ecri_tmx(:,:) ) |
---|
1020 | IF(lwp) THEN |
---|
1021 | WRITE(numout,*) ' High-mode wave-breaking energy: ', zbot * 1.e-12_wp, 'TW' |
---|
1022 | WRITE(numout,*) ' Pycnocline-intensifed wave-breaking energy: ', zpyc * 1.e-12_wp, 'TW' |
---|
1023 | WRITE(numout,*) ' Critical slope wave-breaking energy: ', zcri * 1.e-12_wp, 'TW' |
---|
1024 | ENDIF |
---|
1025 | ! |
---|
1026 | IF( nn_timing == 1 ) CALL timing_stop('zdf_tmx_init') |
---|
1027 | ! |
---|
1028 | END SUBROUTINE zdf_tmx_init |
---|
1029 | |
---|
1030 | #else |
---|
1031 | !!---------------------------------------------------------------------- |
---|
1032 | !! Default option Dummy module NO Tidal MiXing |
---|
1033 | !!---------------------------------------------------------------------- |
---|
1034 | LOGICAL, PUBLIC, PARAMETER :: lk_zdftmx = .FALSE. !: tidal mixing flag |
---|
1035 | CONTAINS |
---|
1036 | SUBROUTINE zdf_tmx_init ! Dummy routine |
---|
1037 | WRITE(*,*) 'zdf_tmx: You should not have seen this print! error?' |
---|
1038 | END SUBROUTINE zdf_tmx_init |
---|
1039 | SUBROUTINE zdf_tmx( kt ) ! Dummy routine |
---|
1040 | WRITE(*,*) 'zdf_tmx: You should not have seen this print! error?', kt |
---|
1041 | END SUBROUTINE zdf_tmx |
---|
1042 | #endif |
---|
1043 | |
---|
1044 | !!====================================================================== |
---|
1045 | END MODULE zdftmx |
---|