1 | MODULE bdydta |
---|
2 | !!====================================================================== |
---|
3 | !! *** MODULE bdydta *** |
---|
4 | !! Open boundary data : read the data for the unstructured open boundaries. |
---|
5 | !!====================================================================== |
---|
6 | !! History : 1.0 ! 2005-01 (J. Chanut, A. Sellar) Original code |
---|
7 | !! - ! 2007-01 (D. Storkey) Update to use IOM module |
---|
8 | !! - ! 2007-07 (D. Storkey) add bdy_dta_fla |
---|
9 | !! 3.0 ! 2008-04 (NEMO team) add in the reference version |
---|
10 | !! 3.3 ! 2010-09 (E.O'Dea) modifications for Shelf configurations |
---|
11 | !! 3.3 ! 2010-09 (D.Storkey) add ice boundary conditions |
---|
12 | !! 3.4 ! 2011 (D. Storkey) rewrite in preparation for OBC-BDY merge |
---|
13 | !! 3.6 ! 2012-01 (C. Rousset) add ice boundary conditions for lim3 |
---|
14 | !!---------------------------------------------------------------------- |
---|
15 | !! bdy_dta : read external data along open boundaries from file |
---|
16 | !! bdy_dta_init : initialise arrays etc for reading of external data |
---|
17 | !!---------------------------------------------------------------------- |
---|
18 | USE timing ! Timing |
---|
19 | USE oce ! ocean dynamics and tracers |
---|
20 | USE dom_oce ! ocean space and time domain |
---|
21 | USE phycst ! physical constants |
---|
22 | USE bdy_oce ! ocean open boundary conditions |
---|
23 | USE bdytides ! tidal forcing at boundaries |
---|
24 | USE fldread ! read input fields |
---|
25 | USE iom ! IOM library |
---|
26 | USE in_out_manager ! I/O logical units |
---|
27 | #if defined key_lim3 |
---|
28 | USE ice |
---|
29 | USE icevar ! redistribute ice input into categories |
---|
30 | #endif |
---|
31 | USE sbcapr |
---|
32 | USE sbctide ! Tidal forcing or not |
---|
33 | |
---|
34 | IMPLICIT NONE |
---|
35 | PRIVATE |
---|
36 | |
---|
37 | PUBLIC bdy_dta ! routine called by step.F90 and dynspg_ts.F90 |
---|
38 | PUBLIC bdy_dta_init ! routine called by nemogcm.F90 |
---|
39 | |
---|
40 | INTEGER, ALLOCATABLE, DIMENSION(:) :: nb_bdy_fld ! Number of fields to update for each boundary set. |
---|
41 | INTEGER :: nb_bdy_fld_sum ! Total number of fields to update for all boundary sets. |
---|
42 | LOGICAL, DIMENSION(jp_bdy) :: ln_full_vel_array ! =T => full velocities in 3D boundary conditions |
---|
43 | ! =F => baroclinic velocities in 3D boundary conditions |
---|
44 | !$AGRIF_DO_NOT_TREAT |
---|
45 | TYPE(FLD), PUBLIC, ALLOCATABLE, DIMENSION(:), TARGET :: bf ! structure of input fields (file informations, fields read) |
---|
46 | !$AGRIF_END_DO_NOT_TREAT |
---|
47 | TYPE(MAP_POINTER), ALLOCATABLE, DIMENSION(:) :: nbmap_ptr ! array of pointers to nbmap |
---|
48 | |
---|
49 | #if defined key_lim3 |
---|
50 | LOGICAL :: ll_bdylim3 ! determine whether ice input is 1cat (F) or Xcat (T) type |
---|
51 | INTEGER :: jfld_hti, jfld_hts, jfld_ai ! indices of ice thickness, snow thickness and concentration in bf structure |
---|
52 | #endif |
---|
53 | |
---|
54 | !!---------------------------------------------------------------------- |
---|
55 | !! NEMO/OPA 3.3 , NEMO Consortium (2010) |
---|
56 | !! $Id$ |
---|
57 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
---|
58 | !!---------------------------------------------------------------------- |
---|
59 | CONTAINS |
---|
60 | |
---|
61 | SUBROUTINE bdy_dta( kt, jit, time_offset ) |
---|
62 | !!---------------------------------------------------------------------- |
---|
63 | !! *** SUBROUTINE bdy_dta *** |
---|
64 | !! |
---|
65 | !! ** Purpose : Update external data for open boundary conditions |
---|
66 | !! |
---|
67 | !! ** Method : Use fldread.F90 |
---|
68 | !! |
---|
69 | !!---------------------------------------------------------------------- |
---|
70 | INTEGER, INTENT(in) :: kt ! ocean time-step index |
---|
71 | INTEGER, INTENT(in), OPTIONAL :: jit ! subcycle time-step index (for timesplitting option) |
---|
72 | INTEGER, INTENT(in), OPTIONAL :: time_offset ! time offset in units of timesteps. NB. if jit |
---|
73 | ! ! is present then units = subcycle timesteps. |
---|
74 | ! ! time_offset = 0 => get data at "now" time level |
---|
75 | ! ! time_offset = -1 => get data at "before" time level |
---|
76 | ! ! time_offset = +1 => get data at "after" time level |
---|
77 | ! ! etc. |
---|
78 | ! |
---|
79 | INTEGER :: ib_bdy, jfld, jstart, jend, ib, ii, ij, ik, igrd, jl ! local indices |
---|
80 | INTEGER, DIMENSION(jpbgrd) :: ilen1 |
---|
81 | INTEGER, POINTER, DIMENSION(:) :: nblen, nblenrim ! short cuts |
---|
82 | TYPE(OBC_DATA), POINTER :: dta ! short cut |
---|
83 | !!--------------------------------------------------------------------------- |
---|
84 | ! |
---|
85 | IF( nn_timing == 1 ) CALL timing_start('bdy_dta') |
---|
86 | ! |
---|
87 | ! Initialise data arrays once for all from initial conditions where required |
---|
88 | !--------------------------------------------------------------------------- |
---|
89 | IF( kt == nit000 .AND. .NOT.PRESENT(jit) ) THEN |
---|
90 | |
---|
91 | ! Calculate depth-mean currents |
---|
92 | !----------------------------- |
---|
93 | |
---|
94 | DO ib_bdy = 1, nb_bdy |
---|
95 | ! |
---|
96 | nblen => idx_bdy(ib_bdy)%nblen |
---|
97 | nblenrim => idx_bdy(ib_bdy)%nblenrim |
---|
98 | dta => dta_bdy(ib_bdy) |
---|
99 | |
---|
100 | IF( nn_dyn2d_dta(ib_bdy) == 0 ) THEN |
---|
101 | ilen1(:) = nblen(:) |
---|
102 | IF( dta%ll_ssh ) THEN |
---|
103 | igrd = 1 |
---|
104 | DO ib = 1, ilen1(igrd) |
---|
105 | ii = idx_bdy(ib_bdy)%nbi(ib,igrd) |
---|
106 | ij = idx_bdy(ib_bdy)%nbj(ib,igrd) |
---|
107 | dta_bdy(ib_bdy)%ssh(ib) = sshn(ii,ij) * tmask(ii,ij,1) |
---|
108 | END DO |
---|
109 | END IF |
---|
110 | IF( dta%ll_u2d ) THEN |
---|
111 | igrd = 2 |
---|
112 | DO ib = 1, ilen1(igrd) |
---|
113 | ii = idx_bdy(ib_bdy)%nbi(ib,igrd) |
---|
114 | ij = idx_bdy(ib_bdy)%nbj(ib,igrd) |
---|
115 | dta_bdy(ib_bdy)%u2d(ib) = un_b(ii,ij) * umask(ii,ij,1) |
---|
116 | END DO |
---|
117 | END IF |
---|
118 | IF( dta%ll_v2d ) THEN |
---|
119 | igrd = 3 |
---|
120 | DO ib = 1, ilen1(igrd) |
---|
121 | ii = idx_bdy(ib_bdy)%nbi(ib,igrd) |
---|
122 | ij = idx_bdy(ib_bdy)%nbj(ib,igrd) |
---|
123 | dta_bdy(ib_bdy)%v2d(ib) = vn_b(ii,ij) * vmask(ii,ij,1) |
---|
124 | END DO |
---|
125 | END IF |
---|
126 | ENDIF |
---|
127 | |
---|
128 | IF( nn_dyn3d_dta(ib_bdy) == 0 ) THEN |
---|
129 | ilen1(:) = nblen(:) |
---|
130 | IF( dta%ll_u3d ) THEN |
---|
131 | igrd = 2 |
---|
132 | DO ib = 1, ilen1(igrd) |
---|
133 | DO ik = 1, jpkm1 |
---|
134 | ii = idx_bdy(ib_bdy)%nbi(ib,igrd) |
---|
135 | ij = idx_bdy(ib_bdy)%nbj(ib,igrd) |
---|
136 | dta_bdy(ib_bdy)%u3d(ib,ik) = ( un(ii,ij,ik) - un_b(ii,ij) ) * umask(ii,ij,ik) |
---|
137 | END DO |
---|
138 | END DO |
---|
139 | END IF |
---|
140 | IF( dta%ll_v3d ) THEN |
---|
141 | igrd = 3 |
---|
142 | DO ib = 1, ilen1(igrd) |
---|
143 | DO ik = 1, jpkm1 |
---|
144 | ii = idx_bdy(ib_bdy)%nbi(ib,igrd) |
---|
145 | ij = idx_bdy(ib_bdy)%nbj(ib,igrd) |
---|
146 | dta_bdy(ib_bdy)%v3d(ib,ik) = ( vn(ii,ij,ik) - vn_b(ii,ij) ) * vmask(ii,ij,ik) |
---|
147 | END DO |
---|
148 | END DO |
---|
149 | END IF |
---|
150 | ENDIF |
---|
151 | |
---|
152 | IF( nn_tra_dta(ib_bdy) == 0 ) THEN |
---|
153 | ilen1(:) = nblen(:) |
---|
154 | IF( dta%ll_tem ) THEN |
---|
155 | igrd = 1 |
---|
156 | DO ib = 1, ilen1(igrd) |
---|
157 | DO ik = 1, jpkm1 |
---|
158 | ii = idx_bdy(ib_bdy)%nbi(ib,igrd) |
---|
159 | ij = idx_bdy(ib_bdy)%nbj(ib,igrd) |
---|
160 | dta_bdy(ib_bdy)%tem(ib,ik) = tsn(ii,ij,ik,jp_tem) * tmask(ii,ij,ik) |
---|
161 | END DO |
---|
162 | END DO |
---|
163 | END IF |
---|
164 | IF( dta%ll_sal ) THEN |
---|
165 | igrd = 1 |
---|
166 | DO ib = 1, ilen1(igrd) |
---|
167 | DO ik = 1, jpkm1 |
---|
168 | ii = idx_bdy(ib_bdy)%nbi(ib,igrd) |
---|
169 | ij = idx_bdy(ib_bdy)%nbj(ib,igrd) |
---|
170 | dta_bdy(ib_bdy)%sal(ib,ik) = tsn(ii,ij,ik,jp_sal) * tmask(ii,ij,ik) |
---|
171 | END DO |
---|
172 | END DO |
---|
173 | END IF |
---|
174 | ENDIF |
---|
175 | |
---|
176 | #if defined key_lim3 |
---|
177 | IF( nn_ice_lim_dta(ib_bdy) == 0 ) THEN |
---|
178 | ilen1(:) = nblen(:) |
---|
179 | IF( dta%ll_a_i ) THEN |
---|
180 | igrd = 1 |
---|
181 | DO jl = 1, jpl |
---|
182 | DO ib = 1, ilen1(igrd) |
---|
183 | ii = idx_bdy(ib_bdy)%nbi(ib,igrd) |
---|
184 | ij = idx_bdy(ib_bdy)%nbj(ib,igrd) |
---|
185 | dta_bdy(ib_bdy)%a_i (ib,jl) = a_i(ii,ij,jl) * tmask(ii,ij,1) |
---|
186 | END DO |
---|
187 | END DO |
---|
188 | ENDIF |
---|
189 | IF( dta%ll_ht_i ) THEN |
---|
190 | igrd = 1 |
---|
191 | DO jl = 1, jpl |
---|
192 | DO ib = 1, ilen1(igrd) |
---|
193 | ii = idx_bdy(ib_bdy)%nbi(ib,igrd) |
---|
194 | ij = idx_bdy(ib_bdy)%nbj(ib,igrd) |
---|
195 | dta_bdy(ib_bdy)%ht_i (ib,jl) = ht_i(ii,ij,jl) * tmask(ii,ij,1) |
---|
196 | END DO |
---|
197 | END DO |
---|
198 | ENDIF |
---|
199 | IF( dta%ll_ht_s ) THEN |
---|
200 | igrd = 1 |
---|
201 | DO jl = 1, jpl |
---|
202 | DO ib = 1, ilen1(igrd) |
---|
203 | ii = idx_bdy(ib_bdy)%nbi(ib,igrd) |
---|
204 | ij = idx_bdy(ib_bdy)%nbj(ib,igrd) |
---|
205 | dta_bdy(ib_bdy)%ht_s (ib,jl) = ht_s(ii,ij,jl) * tmask(ii,ij,1) |
---|
206 | END DO |
---|
207 | END DO |
---|
208 | ENDIF |
---|
209 | ENDIF |
---|
210 | #endif |
---|
211 | END DO ! ib_bdy |
---|
212 | ! |
---|
213 | ENDIF ! kt == nit000 |
---|
214 | |
---|
215 | ! update external data from files |
---|
216 | !-------------------------------- |
---|
217 | |
---|
218 | jstart = 1 |
---|
219 | DO ib_bdy = 1, nb_bdy |
---|
220 | dta => dta_bdy(ib_bdy) |
---|
221 | IF( nn_dta(ib_bdy) == 1 ) THEN ! skip this bit if no external data required |
---|
222 | |
---|
223 | IF( PRESENT(jit) ) THEN |
---|
224 | ! Update barotropic boundary conditions only |
---|
225 | ! jit is optional argument for fld_read and bdytide_update |
---|
226 | IF( cn_dyn2d(ib_bdy) /= 'none' ) THEN |
---|
227 | IF( nn_dyn2d_dta(ib_bdy) == 2 ) THEN ! tidal harmonic forcing ONLY: initialise arrays |
---|
228 | IF( dta%ll_ssh ) dta%ssh(:) = 0._wp |
---|
229 | IF( dta%ll_u2d ) dta%u2d(:) = 0._wp |
---|
230 | IF( dta%ll_u3d ) dta%v2d(:) = 0._wp |
---|
231 | ENDIF |
---|
232 | IF (cn_tra(ib_bdy) /= 'runoff') THEN |
---|
233 | IF( nn_dyn2d_dta(ib_bdy) == 1 .OR. nn_dyn2d_dta(ib_bdy) == 3 ) THEN |
---|
234 | |
---|
235 | jend = jstart + dta%nread(2) - 1 |
---|
236 | IF( ln_full_vel_array(ib_bdy) ) THEN |
---|
237 | CALL fld_read( kt=kt, kn_fsbc=1, sd=bf(jstart:jend), map=nbmap_ptr(jstart:jend), & |
---|
238 | & kit=jit, kt_offset=time_offset , jpk_bdy=nb_jpk_bdy, fvl=ln_full_vel_array(ib_bdy) ) |
---|
239 | ELSE |
---|
240 | CALL fld_read( kt=kt, kn_fsbc=1, sd=bf(jstart:jend), map=nbmap_ptr(jstart:jend), & |
---|
241 | & kit=jit, kt_offset=time_offset ) |
---|
242 | ENDIF |
---|
243 | |
---|
244 | ! If full velocities in boundary data then extract barotropic velocities from 3D fields |
---|
245 | IF( ln_full_vel_array(ib_bdy) .AND. & |
---|
246 | & ( nn_dyn2d_dta(ib_bdy) == 1 .OR. nn_dyn2d_dta(ib_bdy) == 3 .OR. & |
---|
247 | & nn_dyn3d_dta(ib_bdy) == 1 ) )THEN |
---|
248 | |
---|
249 | igrd = 2 ! zonal velocity |
---|
250 | dta%u2d(:) = 0._wp |
---|
251 | DO ib = 1, idx_bdy(ib_bdy)%nblen(igrd) |
---|
252 | ii = idx_bdy(ib_bdy)%nbi(ib,igrd) |
---|
253 | ij = idx_bdy(ib_bdy)%nbj(ib,igrd) |
---|
254 | DO ik = 1, jpkm1 |
---|
255 | dta%u2d(ib) = dta%u2d(ib) & |
---|
256 | & + e3u_n(ii,ij,ik) * umask(ii,ij,ik) * dta%u3d(ib,ik) |
---|
257 | END DO |
---|
258 | dta%u2d(ib) = dta%u2d(ib) * r1_hu_n(ii,ij) |
---|
259 | END DO |
---|
260 | igrd = 3 ! meridional velocity |
---|
261 | dta%v2d(:) = 0._wp |
---|
262 | DO ib = 1, idx_bdy(ib_bdy)%nblen(igrd) |
---|
263 | ii = idx_bdy(ib_bdy)%nbi(ib,igrd) |
---|
264 | ij = idx_bdy(ib_bdy)%nbj(ib,igrd) |
---|
265 | DO ik = 1, jpkm1 |
---|
266 | dta%v2d(ib) = dta%v2d(ib) & |
---|
267 | & + e3v_n(ii,ij,ik) * vmask(ii,ij,ik) * dta%v3d(ib,ik) |
---|
268 | END DO |
---|
269 | dta%v2d(ib) = dta%v2d(ib) * r1_hv_n(ii,ij) |
---|
270 | END DO |
---|
271 | ENDIF |
---|
272 | ENDIF |
---|
273 | IF( nn_dyn2d_dta(ib_bdy) .ge. 2 ) THEN ! update tidal harmonic forcing |
---|
274 | CALL bdytide_update( kt=kt, idx=idx_bdy(ib_bdy), dta=dta, td=tides(ib_bdy), & |
---|
275 | & jit=jit, time_offset=time_offset ) |
---|
276 | ENDIF |
---|
277 | ENDIF |
---|
278 | ENDIF |
---|
279 | ELSE |
---|
280 | IF (cn_tra(ib_bdy) == 'runoff') then ! runoff condition |
---|
281 | jend = nb_bdy_fld(ib_bdy) |
---|
282 | CALL fld_read( kt=kt, kn_fsbc=1, sd=bf(jstart:jend), & |
---|
283 | & map=nbmap_ptr(jstart:jend), kt_offset=time_offset ) |
---|
284 | ! |
---|
285 | igrd = 2 ! zonal velocity |
---|
286 | DO ib = 1, idx_bdy(ib_bdy)%nblen(igrd) |
---|
287 | ii = idx_bdy(ib_bdy)%nbi(ib,igrd) |
---|
288 | ij = idx_bdy(ib_bdy)%nbj(ib,igrd) |
---|
289 | dta%u2d(ib) = dta%u2d(ib) / ( e2u(ii,ij) * hu_0(ii,ij) ) |
---|
290 | END DO |
---|
291 | ! |
---|
292 | igrd = 3 ! meridional velocity |
---|
293 | DO ib = 1, idx_bdy(ib_bdy)%nblen(igrd) |
---|
294 | ii = idx_bdy(ib_bdy)%nbi(ib,igrd) |
---|
295 | ij = idx_bdy(ib_bdy)%nbj(ib,igrd) |
---|
296 | dta%v2d(ib) = dta%v2d(ib) / ( e1v(ii,ij) * hv_0(ii,ij) ) |
---|
297 | END DO |
---|
298 | ELSE |
---|
299 | IF( nn_dyn2d_dta(ib_bdy) == 2 ) THEN ! tidal harmonic forcing ONLY: initialise arrays |
---|
300 | IF( dta%ll_ssh ) dta%ssh(:) = 0._wp |
---|
301 | IF( dta%ll_u2d ) dta%u2d(:) = 0._wp |
---|
302 | IF( dta%ll_v2d ) dta%v2d(:) = 0._wp |
---|
303 | ENDIF |
---|
304 | IF( dta%nread(1) .gt. 0 ) THEN ! update external data |
---|
305 | jend = jstart + dta%nread(1) - 1 |
---|
306 | CALL fld_read( kt=kt, kn_fsbc=1, sd=bf(jstart:jend), & |
---|
307 | & map=nbmap_ptr(jstart:jend), kt_offset=time_offset, jpk_bdy=nb_jpk_bdy, fvl=ln_full_vel_array(ib_bdy) ) |
---|
308 | ENDIF |
---|
309 | ! If full velocities in boundary data then split into barotropic and baroclinic data |
---|
310 | IF( ln_full_vel_array(ib_bdy) .and. & |
---|
311 | & ( nn_dyn2d_dta(ib_bdy) == 1 .OR. nn_dyn2d_dta(ib_bdy) == 3 .OR. & |
---|
312 | & nn_dyn3d_dta(ib_bdy) == 1 ) ) THEN |
---|
313 | igrd = 2 ! zonal velocity |
---|
314 | dta%u2d(:) = 0._wp |
---|
315 | DO ib = 1, idx_bdy(ib_bdy)%nblen(igrd) |
---|
316 | ii = idx_bdy(ib_bdy)%nbi(ib,igrd) |
---|
317 | ij = idx_bdy(ib_bdy)%nbj(ib,igrd) |
---|
318 | DO ik = 1, jpkm1 |
---|
319 | dta%u2d(ib) = dta%u2d(ib) & |
---|
320 | & + e3u_n(ii,ij,ik) * umask(ii,ij,ik) * dta%u3d(ib,ik) |
---|
321 | END DO |
---|
322 | dta%u2d(ib) = dta%u2d(ib) * r1_hu_n(ii,ij) |
---|
323 | DO ik = 1, jpkm1 |
---|
324 | dta%u3d(ib,ik) = dta%u3d(ib,ik) - dta%u2d(ib) |
---|
325 | END DO |
---|
326 | END DO |
---|
327 | igrd = 3 ! meridional velocity |
---|
328 | dta%v2d(:) = 0._wp |
---|
329 | DO ib = 1, idx_bdy(ib_bdy)%nblen(igrd) |
---|
330 | ii = idx_bdy(ib_bdy)%nbi(ib,igrd) |
---|
331 | ij = idx_bdy(ib_bdy)%nbj(ib,igrd) |
---|
332 | DO ik = 1, jpkm1 |
---|
333 | dta%v2d(ib) = dta%v2d(ib) & |
---|
334 | & + e3v_n(ii,ij,ik) * vmask(ii,ij,ik) * dta%v3d(ib,ik) |
---|
335 | END DO |
---|
336 | dta%v2d(ib) = dta%v2d(ib) * r1_hv_n(ii,ij) |
---|
337 | DO ik = 1, jpkm1 |
---|
338 | dta%v3d(ib,ik) = dta%v3d(ib,ik) - dta%v2d(ib) |
---|
339 | END DO |
---|
340 | END DO |
---|
341 | ENDIF |
---|
342 | |
---|
343 | ENDIF |
---|
344 | #if defined key_lim3 |
---|
345 | IF( .NOT. ll_bdylim3 .AND. cn_ice_lim(ib_bdy) /= 'none' .AND. nn_ice_lim_dta(ib_bdy) == 1 ) THEN ! bdy ice input (case input is 1cat) |
---|
346 | CALL ice_var_itd ( bf(jfld_hti)%fnow(:,1,1), bf(jfld_hts)%fnow(:,1,1), bf(jfld_ai)%fnow(:,1,1), & |
---|
347 | & dta_bdy(ib_bdy)%ht_i, dta_bdy(ib_bdy)%ht_s, dta_bdy(ib_bdy)%a_i ) |
---|
348 | ENDIF |
---|
349 | #endif |
---|
350 | ENDIF |
---|
351 | jstart = jstart + dta%nread(1) |
---|
352 | END IF ! nn_dta(ib_bdy) = 1 |
---|
353 | END DO ! ib_bdy |
---|
354 | |
---|
355 | IF ( ln_tide ) THEN |
---|
356 | IF (ln_dynspg_ts) THEN ! Fill temporary arrays with slow-varying bdy data |
---|
357 | DO ib_bdy = 1, nb_bdy ! Tidal component added in ts loop |
---|
358 | IF ( nn_dyn2d_dta(ib_bdy) .ge. 2 ) THEN |
---|
359 | nblen => idx_bdy(ib_bdy)%nblen |
---|
360 | nblenrim => idx_bdy(ib_bdy)%nblenrim |
---|
361 | IF( cn_dyn2d(ib_bdy) == 'frs' ) THEN; ilen1(:)=nblen(:) ; ELSE ; ilen1(:)=nblenrim(:) ; ENDIF |
---|
362 | IF ( dta_bdy(ib_bdy)%ll_ssh ) dta_bdy_s(ib_bdy)%ssh(1:ilen1(1)) = dta_bdy(ib_bdy)%ssh(1:ilen1(1)) |
---|
363 | IF ( dta_bdy(ib_bdy)%ll_u2d ) dta_bdy_s(ib_bdy)%u2d(1:ilen1(2)) = dta_bdy(ib_bdy)%u2d(1:ilen1(2)) |
---|
364 | IF ( dta_bdy(ib_bdy)%ll_v2d ) dta_bdy_s(ib_bdy)%v2d(1:ilen1(3)) = dta_bdy(ib_bdy)%v2d(1:ilen1(3)) |
---|
365 | ENDIF |
---|
366 | END DO |
---|
367 | ELSE ! Add tides if not split-explicit free surface else this is done in ts loop |
---|
368 | ! |
---|
369 | CALL bdy_dta_tides( kt=kt, time_offset=time_offset ) |
---|
370 | ENDIF |
---|
371 | ENDIF |
---|
372 | |
---|
373 | IF ( ln_apr_obc ) THEN |
---|
374 | DO ib_bdy = 1, nb_bdy |
---|
375 | IF (cn_tra(ib_bdy) /= 'runoff')THEN |
---|
376 | igrd = 1 ! meridional velocity |
---|
377 | DO ib = 1, idx_bdy(ib_bdy)%nblenrim(igrd) |
---|
378 | ii = idx_bdy(ib_bdy)%nbi(ib,igrd) |
---|
379 | ij = idx_bdy(ib_bdy)%nbj(ib,igrd) |
---|
380 | dta_bdy(ib_bdy)%ssh(ib) = dta_bdy(ib_bdy)%ssh(ib) + ssh_ib(ii,ij) |
---|
381 | END DO |
---|
382 | ENDIF |
---|
383 | END DO |
---|
384 | ENDIF |
---|
385 | ! |
---|
386 | IF( nn_timing == 1 ) CALL timing_stop('bdy_dta') |
---|
387 | ! |
---|
388 | END SUBROUTINE bdy_dta |
---|
389 | |
---|
390 | |
---|
391 | SUBROUTINE bdy_dta_init |
---|
392 | !!---------------------------------------------------------------------- |
---|
393 | !! *** SUBROUTINE bdy_dta_init *** |
---|
394 | !! |
---|
395 | !! ** Purpose : Initialise arrays for reading of external data |
---|
396 | !! for open boundary conditions |
---|
397 | !! |
---|
398 | !! ** Method : |
---|
399 | !! |
---|
400 | !!---------------------------------------------------------------------- |
---|
401 | INTEGER :: ib_bdy, jfld, jstart, jend, ierror, ios ! Local integers |
---|
402 | ! |
---|
403 | CHARACTER(len=100) :: cn_dir ! Root directory for location of data files |
---|
404 | CHARACTER(len=100), DIMENSION(nb_bdy) :: cn_dir_array ! Root directory for location of data files |
---|
405 | CHARACTER(len = 256):: clname ! temporary file name |
---|
406 | LOGICAL :: ln_full_vel ! =T => full velocities in 3D boundary data |
---|
407 | ! =F => baroclinic velocities in 3D boundary data |
---|
408 | INTEGER :: ilen_global ! Max length required for global bdy dta arrays |
---|
409 | INTEGER, ALLOCATABLE, DIMENSION(:) :: ilen1, ilen3 ! size of 1st and 3rd dimensions of local arrays |
---|
410 | INTEGER, ALLOCATABLE, DIMENSION(:) :: ibdy ! bdy set for a particular jfld |
---|
411 | INTEGER, ALLOCATABLE, DIMENSION(:) :: igrid ! index for grid type (1,2,3 = T,U,V) |
---|
412 | INTEGER, POINTER, DIMENSION(:) :: nblen, nblenrim ! short cuts |
---|
413 | TYPE(OBC_DATA), POINTER :: dta ! short cut |
---|
414 | #if defined key_lim3 |
---|
415 | INTEGER :: zndims ! number of dimensions in an array (i.e. 3 = wo ice cat; 4 = w ice cat) |
---|
416 | INTEGER :: inum,id1 ! local integer |
---|
417 | #endif |
---|
418 | TYPE(FLD_N), ALLOCATABLE, DIMENSION(:) :: blf_i ! array of namelist information structures |
---|
419 | TYPE(FLD_N) :: bn_tem, bn_sal, bn_u3d, bn_v3d ! |
---|
420 | TYPE(FLD_N) :: bn_ssh, bn_u2d, bn_v2d ! informations about the fields to be read |
---|
421 | #if defined key_lim3 |
---|
422 | TYPE(FLD_N) :: bn_a_i, bn_ht_i, bn_ht_s |
---|
423 | #endif |
---|
424 | NAMELIST/nambdy_dta/ cn_dir, bn_tem, bn_sal, bn_u3d, bn_v3d, bn_ssh, bn_u2d, bn_v2d |
---|
425 | #if defined key_lim3 |
---|
426 | NAMELIST/nambdy_dta/ bn_a_i, bn_ht_i, bn_ht_s |
---|
427 | #endif |
---|
428 | NAMELIST/nambdy_dta/ ln_full_vel, nb_jpk_bdy |
---|
429 | !!--------------------------------------------------------------------------- |
---|
430 | ! |
---|
431 | IF( nn_timing == 1 ) CALL timing_start('bdy_dta_init') |
---|
432 | ! |
---|
433 | IF(lwp) WRITE(numout,*) |
---|
434 | IF(lwp) WRITE(numout,*) 'bdy_dta_ini : initialization of data at the open boundaries' |
---|
435 | IF(lwp) WRITE(numout,*) '~~~~~~~~~~' |
---|
436 | IF(lwp) WRITE(numout,*) '' |
---|
437 | |
---|
438 | ! Set nn_dta |
---|
439 | DO ib_bdy = 1, nb_bdy |
---|
440 | nn_dta(ib_bdy) = MAX( nn_dyn2d_dta(ib_bdy) & |
---|
441 | ,nn_dyn3d_dta(ib_bdy) & |
---|
442 | ,nn_tra_dta(ib_bdy) & |
---|
443 | #if defined key_lim3 |
---|
444 | ,nn_ice_lim_dta(ib_bdy) & |
---|
445 | #endif |
---|
446 | ) |
---|
447 | IF(nn_dta(ib_bdy) > 1) nn_dta(ib_bdy) = 1 |
---|
448 | END DO |
---|
449 | |
---|
450 | ! Work out upper bound of how many fields there are to read in and allocate arrays |
---|
451 | ! --------------------------------------------------------------------------- |
---|
452 | ALLOCATE( nb_bdy_fld(nb_bdy) ) |
---|
453 | nb_bdy_fld(:) = 0 |
---|
454 | DO ib_bdy = 1, nb_bdy |
---|
455 | IF( cn_dyn2d(ib_bdy) /= 'none' .and. ( nn_dyn2d_dta(ib_bdy) == 1 .or. nn_dyn2d_dta(ib_bdy) == 3 ) ) THEN |
---|
456 | nb_bdy_fld(ib_bdy) = nb_bdy_fld(ib_bdy) + 3 |
---|
457 | ENDIF |
---|
458 | IF( cn_dyn3d(ib_bdy) /= 'none' .and. nn_dyn3d_dta(ib_bdy) == 1 ) THEN |
---|
459 | nb_bdy_fld(ib_bdy) = nb_bdy_fld(ib_bdy) + 2 |
---|
460 | ENDIF |
---|
461 | IF( cn_tra(ib_bdy) /= 'none' .and. nn_tra_dta(ib_bdy) == 1 ) THEN |
---|
462 | nb_bdy_fld(ib_bdy) = nb_bdy_fld(ib_bdy) + 2 |
---|
463 | ENDIF |
---|
464 | #if defined key_lim3 |
---|
465 | IF( cn_ice_lim(ib_bdy) /= 'none' .and. nn_ice_lim_dta(ib_bdy) == 1 ) THEN |
---|
466 | nb_bdy_fld(ib_bdy) = nb_bdy_fld(ib_bdy) + 3 |
---|
467 | ENDIF |
---|
468 | #endif |
---|
469 | IF(lwp) WRITE(numout,*) 'Maximum number of files to open =',nb_bdy_fld(ib_bdy) |
---|
470 | END DO |
---|
471 | |
---|
472 | nb_bdy_fld_sum = SUM( nb_bdy_fld ) |
---|
473 | |
---|
474 | ALLOCATE( bf(nb_bdy_fld_sum), STAT=ierror ) |
---|
475 | IF( ierror > 0 ) THEN |
---|
476 | CALL ctl_stop( 'bdy_dta: unable to allocate bf structure' ) ; RETURN |
---|
477 | ENDIF |
---|
478 | ALLOCATE( blf_i(nb_bdy_fld_sum), STAT=ierror ) |
---|
479 | IF( ierror > 0 ) THEN |
---|
480 | CALL ctl_stop( 'bdy_dta: unable to allocate blf_i structure' ) ; RETURN |
---|
481 | ENDIF |
---|
482 | ALLOCATE( nbmap_ptr(nb_bdy_fld_sum), STAT=ierror ) |
---|
483 | IF( ierror > 0 ) THEN |
---|
484 | CALL ctl_stop( 'bdy_dta: unable to allocate nbmap_ptr structure' ) ; RETURN |
---|
485 | ENDIF |
---|
486 | ALLOCATE( ilen1(nb_bdy_fld_sum), ilen3(nb_bdy_fld_sum) ) |
---|
487 | ALLOCATE( ibdy(nb_bdy_fld_sum) ) |
---|
488 | ALLOCATE( igrid(nb_bdy_fld_sum) ) |
---|
489 | |
---|
490 | ! Read namelists |
---|
491 | ! -------------- |
---|
492 | REWIND(numnam_ref) |
---|
493 | REWIND(numnam_cfg) |
---|
494 | jfld = 0 |
---|
495 | DO ib_bdy = 1, nb_bdy |
---|
496 | IF( nn_dta(ib_bdy) == 1 ) THEN |
---|
497 | READ ( numnam_ref, nambdy_dta, IOSTAT = ios, ERR = 901) |
---|
498 | 901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'nambdy_dta in reference namelist', lwp ) |
---|
499 | |
---|
500 | READ ( numnam_cfg, nambdy_dta, IOSTAT = ios, ERR = 902 ) |
---|
501 | 902 IF( ios /= 0 ) CALL ctl_nam ( ios , 'nambdy_dta in configuration namelist', lwp ) |
---|
502 | IF(lwm) WRITE( numond, nambdy_dta ) |
---|
503 | |
---|
504 | cn_dir_array(ib_bdy) = cn_dir |
---|
505 | ln_full_vel_array(ib_bdy) = ln_full_vel |
---|
506 | |
---|
507 | nblen => idx_bdy(ib_bdy)%nblen |
---|
508 | nblenrim => idx_bdy(ib_bdy)%nblenrim |
---|
509 | dta => dta_bdy(ib_bdy) |
---|
510 | dta%nread(2) = 0 |
---|
511 | |
---|
512 | ! Only read in necessary fields for this set. |
---|
513 | ! Important that barotropic variables come first. |
---|
514 | IF( nn_dyn2d_dta(ib_bdy) == 1 .or. nn_dyn2d_dta(ib_bdy) == 3 ) THEN |
---|
515 | |
---|
516 | IF( dta%ll_ssh ) THEN |
---|
517 | if(lwp) write(numout,*) '++++++ reading in ssh field' |
---|
518 | jfld = jfld + 1 |
---|
519 | blf_i(jfld) = bn_ssh |
---|
520 | ibdy(jfld) = ib_bdy |
---|
521 | igrid(jfld) = 1 |
---|
522 | ilen1(jfld) = nblen(igrid(jfld)) |
---|
523 | ilen3(jfld) = 1 |
---|
524 | dta%nread(2) = dta%nread(2) + 1 |
---|
525 | ENDIF |
---|
526 | |
---|
527 | IF( dta%ll_u2d .and. .not. ln_full_vel_array(ib_bdy) ) THEN |
---|
528 | if(lwp) write(numout,*) '++++++ reading in u2d field' |
---|
529 | jfld = jfld + 1 |
---|
530 | blf_i(jfld) = bn_u2d |
---|
531 | ibdy(jfld) = ib_bdy |
---|
532 | igrid(jfld) = 2 |
---|
533 | ilen1(jfld) = nblen(igrid(jfld)) |
---|
534 | ilen3(jfld) = 1 |
---|
535 | dta%nread(2) = dta%nread(2) + 1 |
---|
536 | ENDIF |
---|
537 | |
---|
538 | IF( dta%ll_v2d .and. .not. ln_full_vel_array(ib_bdy) ) THEN |
---|
539 | if(lwp) write(numout,*) '++++++ reading in v2d field' |
---|
540 | jfld = jfld + 1 |
---|
541 | blf_i(jfld) = bn_v2d |
---|
542 | ibdy(jfld) = ib_bdy |
---|
543 | igrid(jfld) = 3 |
---|
544 | ilen1(jfld) = nblen(igrid(jfld)) |
---|
545 | ilen3(jfld) = 1 |
---|
546 | dta%nread(2) = dta%nread(2) + 1 |
---|
547 | ENDIF |
---|
548 | |
---|
549 | ENDIF |
---|
550 | |
---|
551 | ! read 3D velocities if baroclinic velocities require OR if |
---|
552 | ! barotropic velocities required and ln_full_vel set to .true. |
---|
553 | IF( nn_dyn3d_dta(ib_bdy) == 1 .OR. & |
---|
554 | & ( ln_full_vel_array(ib_bdy) .AND. ( nn_dyn2d_dta(ib_bdy) == 1 .or. nn_dyn2d_dta(ib_bdy) == 3 ) ) ) THEN |
---|
555 | |
---|
556 | IF( dta%ll_u3d .OR. ( ln_full_vel_array(ib_bdy) .and. dta%ll_u2d ) ) THEN |
---|
557 | if(lwp) write(numout,*) '++++++ reading in u3d field' |
---|
558 | jfld = jfld + 1 |
---|
559 | blf_i(jfld) = bn_u3d |
---|
560 | ibdy(jfld) = ib_bdy |
---|
561 | igrid(jfld) = 2 |
---|
562 | ilen1(jfld) = nblen(igrid(jfld)) |
---|
563 | ilen3(jfld) = jpk |
---|
564 | IF( ln_full_vel_array(ib_bdy) .and. dta%ll_u2d ) dta%nread(2) = dta%nread(2) + 1 |
---|
565 | ENDIF |
---|
566 | |
---|
567 | IF( dta%ll_v3d .OR. ( ln_full_vel_array(ib_bdy) .and. dta%ll_v2d ) ) THEN |
---|
568 | if(lwp) write(numout,*) '++++++ reading in v3d field' |
---|
569 | jfld = jfld + 1 |
---|
570 | blf_i(jfld) = bn_v3d |
---|
571 | ibdy(jfld) = ib_bdy |
---|
572 | igrid(jfld) = 3 |
---|
573 | ilen1(jfld) = nblen(igrid(jfld)) |
---|
574 | ilen3(jfld) = jpk |
---|
575 | IF( ln_full_vel_array(ib_bdy) .and. dta%ll_v2d ) dta%nread(2) = dta%nread(2) + 1 |
---|
576 | ENDIF |
---|
577 | |
---|
578 | ENDIF |
---|
579 | |
---|
580 | ! temperature and salinity |
---|
581 | IF( nn_tra_dta(ib_bdy) == 1 ) THEN |
---|
582 | |
---|
583 | IF( dta%ll_tem ) THEN |
---|
584 | if(lwp) write(numout,*) '++++++ reading in tem field' |
---|
585 | jfld = jfld + 1 |
---|
586 | blf_i(jfld) = bn_tem |
---|
587 | ibdy(jfld) = ib_bdy |
---|
588 | igrid(jfld) = 1 |
---|
589 | ilen1(jfld) = nblen(igrid(jfld)) |
---|
590 | ilen3(jfld) = jpk |
---|
591 | ENDIF |
---|
592 | |
---|
593 | IF( dta%ll_sal ) THEN |
---|
594 | if(lwp) write(numout,*) '++++++ reading in sal field' |
---|
595 | jfld = jfld + 1 |
---|
596 | blf_i(jfld) = bn_sal |
---|
597 | ibdy(jfld) = ib_bdy |
---|
598 | igrid(jfld) = 1 |
---|
599 | ilen1(jfld) = nblen(igrid(jfld)) |
---|
600 | ilen3(jfld) = jpk |
---|
601 | ENDIF |
---|
602 | |
---|
603 | ENDIF |
---|
604 | |
---|
605 | #if defined key_lim3 |
---|
606 | ! sea ice |
---|
607 | IF( nn_ice_lim_dta(ib_bdy) == 1 ) THEN |
---|
608 | ! Test for types of ice input (1cat or Xcat) |
---|
609 | ! Build file name to find dimensions |
---|
610 | clname=TRIM( cn_dir )//TRIM(bn_a_i%clname) |
---|
611 | IF( .NOT. bn_a_i%ln_clim ) THEN |
---|
612 | WRITE(clname, '(a,"_y",i4.4)' ) TRIM( clname ), nyear ! add year |
---|
613 | IF( bn_a_i%cltype /= 'yearly' ) WRITE(clname, '(a,"m" ,i2.2)' ) TRIM( clname ), nmonth ! add month |
---|
614 | ELSE |
---|
615 | IF( bn_a_i%cltype /= 'yearly' ) WRITE(clname, '(a,"_m",i2.2)' ) TRIM( clname ), nmonth ! add month |
---|
616 | ENDIF |
---|
617 | IF( bn_a_i%cltype == 'daily' .OR. bn_a_i%cltype(1:4) == 'week' ) & |
---|
618 | & WRITE(clname, '(a,"d" ,i2.2)' ) TRIM( clname ), nday ! add day |
---|
619 | ! |
---|
620 | CALL iom_open ( clname, inum ) |
---|
621 | id1 = iom_varid( inum, bn_a_i%clvar, kndims=zndims, ldstop = .FALSE. ) |
---|
622 | CALL iom_close ( inum ) |
---|
623 | |
---|
624 | IF ( zndims == 4 ) THEN |
---|
625 | ll_bdylim3 = .TRUE. ! Xcat input |
---|
626 | ELSE |
---|
627 | ll_bdylim3 = .FALSE. ! 1cat input |
---|
628 | ENDIF |
---|
629 | ! End test |
---|
630 | |
---|
631 | IF( dta%ll_a_i ) THEN |
---|
632 | jfld = jfld + 1 |
---|
633 | blf_i(jfld) = bn_a_i |
---|
634 | ibdy(jfld) = ib_bdy |
---|
635 | igrid(jfld) = 1 |
---|
636 | ilen1(jfld) = nblen(igrid(jfld)) |
---|
637 | IF ( ll_bdylim3 ) THEN ; ilen3(jfld)=jpl ; ELSE ; ilen3(jfld)=1 ; ENDIF |
---|
638 | ENDIF |
---|
639 | |
---|
640 | IF( dta%ll_ht_i ) THEN |
---|
641 | jfld = jfld + 1 |
---|
642 | blf_i(jfld) = bn_ht_i |
---|
643 | ibdy(jfld) = ib_bdy |
---|
644 | igrid(jfld) = 1 |
---|
645 | ilen1(jfld) = nblen(igrid(jfld)) |
---|
646 | IF ( ll_bdylim3 ) THEN ; ilen3(jfld)=jpl ; ELSE ; ilen3(jfld)=1 ; ENDIF |
---|
647 | ENDIF |
---|
648 | |
---|
649 | IF( dta%ll_ht_s ) THEN |
---|
650 | jfld = jfld + 1 |
---|
651 | blf_i(jfld) = bn_ht_s |
---|
652 | ibdy(jfld) = ib_bdy |
---|
653 | igrid(jfld) = 1 |
---|
654 | ilen1(jfld) = nblen(igrid(jfld)) |
---|
655 | IF ( ll_bdylim3 ) THEN ; ilen3(jfld)=jpl ; ELSE ; ilen3(jfld)=1 ; ENDIF |
---|
656 | ENDIF |
---|
657 | |
---|
658 | ENDIF |
---|
659 | #endif |
---|
660 | ! Recalculate field counts |
---|
661 | !------------------------- |
---|
662 | IF( ib_bdy == 1 ) THEN |
---|
663 | nb_bdy_fld_sum = 0 |
---|
664 | nb_bdy_fld(ib_bdy) = jfld |
---|
665 | nb_bdy_fld_sum = jfld |
---|
666 | ELSE |
---|
667 | nb_bdy_fld(ib_bdy) = jfld - nb_bdy_fld_sum |
---|
668 | nb_bdy_fld_sum = nb_bdy_fld_sum + nb_bdy_fld(ib_bdy) |
---|
669 | ENDIF |
---|
670 | |
---|
671 | dta%nread(1) = nb_bdy_fld(ib_bdy) |
---|
672 | |
---|
673 | ENDIF ! nn_dta == 1 |
---|
674 | ENDDO ! ib_bdy |
---|
675 | |
---|
676 | DO jfld = 1, nb_bdy_fld_sum |
---|
677 | ALLOCATE( bf(jfld)%fnow(ilen1(jfld),1,ilen3(jfld)) ) |
---|
678 | IF( blf_i(jfld)%ln_tint ) ALLOCATE( bf(jfld)%fdta(ilen1(jfld),1,ilen3(jfld),2) ) |
---|
679 | nbmap_ptr(jfld)%ptr => idx_bdy(ibdy(jfld))%nbmap(:,igrid(jfld)) |
---|
680 | nbmap_ptr(jfld)%ll_unstruc = ln_coords_file(ibdy(jfld)) |
---|
681 | ENDDO |
---|
682 | |
---|
683 | ! fill bf with blf_i and control print |
---|
684 | !------------------------------------- |
---|
685 | jstart = 1 |
---|
686 | DO ib_bdy = 1, nb_bdy |
---|
687 | jend = jstart - 1 + nb_bdy_fld(ib_bdy) |
---|
688 | CALL fld_fill( bf(jstart:jend), blf_i(jstart:jend), cn_dir_array(ib_bdy), 'bdy_dta', & |
---|
689 | & 'open boundary conditions', 'nambdy_dta' ) |
---|
690 | jstart = jend + 1 |
---|
691 | ENDDO |
---|
692 | |
---|
693 | ! Initialise local boundary data arrays |
---|
694 | ! nn_xxx_dta=0 : allocate space - will be filled from initial conditions later |
---|
695 | ! nn_xxx_dta=1 : point to "fnow" arrays |
---|
696 | !------------------------------------- |
---|
697 | |
---|
698 | jfld = 0 |
---|
699 | DO ib_bdy=1, nb_bdy |
---|
700 | |
---|
701 | nblen => idx_bdy(ib_bdy)%nblen |
---|
702 | dta => dta_bdy(ib_bdy) |
---|
703 | |
---|
704 | if(lwp) then |
---|
705 | write(numout,*) '++++++ dta%ll_ssh = ',dta%ll_ssh |
---|
706 | write(numout,*) '++++++ dta%ll_u2d = ',dta%ll_u2d |
---|
707 | write(numout,*) '++++++ dta%ll_v2d = ',dta%ll_v2d |
---|
708 | write(numout,*) '++++++ dta%ll_u3d = ',dta%ll_u3d |
---|
709 | write(numout,*) '++++++ dta%ll_v3d = ',dta%ll_v3d |
---|
710 | write(numout,*) '++++++ dta%ll_tem = ',dta%ll_tem |
---|
711 | write(numout,*) '++++++ dta%ll_sal = ',dta%ll_sal |
---|
712 | endif |
---|
713 | |
---|
714 | IF ( nn_dyn2d_dta(ib_bdy) == 0 .or. nn_dyn2d_dta(ib_bdy) == 2 ) THEN |
---|
715 | if(lwp) write(numout,*) '++++++ dta%ssh/u2d/u3d allocated space' |
---|
716 | IF( dta%ll_ssh ) ALLOCATE( dta%ssh(nblen(1)) ) |
---|
717 | IF( dta%ll_u2d ) ALLOCATE( dta%u2d(nblen(2)) ) |
---|
718 | IF( dta%ll_v2d ) ALLOCATE( dta%v2d(nblen(3)) ) |
---|
719 | ENDIF |
---|
720 | IF ( nn_dyn2d_dta(ib_bdy) == 1 .or. nn_dyn2d_dta(ib_bdy) == 3 ) THEN |
---|
721 | IF( dta%ll_ssh ) THEN |
---|
722 | if(lwp) write(numout,*) '++++++ dta%ssh pointing to fnow' |
---|
723 | jfld = jfld + 1 |
---|
724 | dta%ssh => bf(jfld)%fnow(:,1,1) |
---|
725 | ENDIF |
---|
726 | IF ( dta%ll_u2d ) THEN |
---|
727 | IF ( ln_full_vel_array(ib_bdy) ) THEN |
---|
728 | if(lwp) write(numout,*) '++++++ dta%u2d allocated space' |
---|
729 | ALLOCATE( dta%u2d(nblen(2)) ) |
---|
730 | ELSE |
---|
731 | if(lwp) write(numout,*) '++++++ dta%u2d pointing to fnow' |
---|
732 | jfld = jfld + 1 |
---|
733 | dta%u2d => bf(jfld)%fnow(:,1,1) |
---|
734 | ENDIF |
---|
735 | ENDIF |
---|
736 | IF ( dta%ll_v2d ) THEN |
---|
737 | IF ( ln_full_vel_array(ib_bdy) ) THEN |
---|
738 | if(lwp) write(numout,*) '++++++ dta%v2d allocated space' |
---|
739 | ALLOCATE( dta%v2d(nblen(3)) ) |
---|
740 | ELSE |
---|
741 | if(lwp) write(numout,*) '++++++ dta%v2d pointing to fnow' |
---|
742 | jfld = jfld + 1 |
---|
743 | dta%v2d => bf(jfld)%fnow(:,1,1) |
---|
744 | ENDIF |
---|
745 | ENDIF |
---|
746 | ENDIF |
---|
747 | |
---|
748 | IF ( nn_dyn3d_dta(ib_bdy) == 0 ) THEN |
---|
749 | if(lwp) write(numout,*) '++++++ dta%u3d/v3d allocated space' |
---|
750 | IF( dta%ll_u3d ) ALLOCATE( dta_bdy(ib_bdy)%u3d(nblen(2),jpk) ) |
---|
751 | IF( dta%ll_v3d ) ALLOCATE( dta_bdy(ib_bdy)%v3d(nblen(3),jpk) ) |
---|
752 | ENDIF |
---|
753 | IF ( nn_dyn3d_dta(ib_bdy) == 1 .or. & |
---|
754 | & ( ln_full_vel_array(ib_bdy) .and. ( nn_dyn2d_dta(ib_bdy) == 1 .or. nn_dyn2d_dta(ib_bdy) == 3 ) ) ) THEN |
---|
755 | IF ( dta%ll_u3d .or. ( ln_full_vel_array(ib_bdy) .and. dta%ll_u2d ) ) THEN |
---|
756 | if(lwp) write(numout,*) '++++++ dta%u3d pointing to fnow' |
---|
757 | jfld = jfld + 1 |
---|
758 | dta_bdy(ib_bdy)%u3d => bf(jfld)%fnow(:,1,:) |
---|
759 | ENDIF |
---|
760 | IF ( dta%ll_v3d .or. ( ln_full_vel_array(ib_bdy) .and. dta%ll_v2d ) ) THEN |
---|
761 | if(lwp) write(numout,*) '++++++ dta%v3d pointing to fnow' |
---|
762 | jfld = jfld + 1 |
---|
763 | dta_bdy(ib_bdy)%v3d => bf(jfld)%fnow(:,1,:) |
---|
764 | ENDIF |
---|
765 | ENDIF |
---|
766 | |
---|
767 | IF( nn_tra_dta(ib_bdy) == 0 ) THEN |
---|
768 | if(lwp) write(numout,*) '++++++ dta%tem/sal allocated space' |
---|
769 | IF( dta%ll_tem ) ALLOCATE( dta_bdy(ib_bdy)%tem(nblen(1),jpk) ) |
---|
770 | IF( dta%ll_sal ) ALLOCATE( dta_bdy(ib_bdy)%sal(nblen(1),jpk) ) |
---|
771 | ELSE |
---|
772 | IF( dta%ll_tem ) THEN |
---|
773 | if(lwp) write(numout,*) '++++++ dta%tem pointing to fnow' |
---|
774 | jfld = jfld + 1 |
---|
775 | dta_bdy(ib_bdy)%tem => bf(jfld)%fnow(:,1,:) |
---|
776 | ENDIF |
---|
777 | IF( dta%ll_sal ) THEN |
---|
778 | if(lwp) write(numout,*) '++++++ dta%sal pointing to fnow' |
---|
779 | jfld = jfld + 1 |
---|
780 | dta_bdy(ib_bdy)%sal => bf(jfld)%fnow(:,1,:) |
---|
781 | ENDIF |
---|
782 | ENDIF |
---|
783 | |
---|
784 | #if defined key_lim3 |
---|
785 | IF (cn_ice_lim(ib_bdy) /= 'none') THEN |
---|
786 | IF( nn_ice_lim_dta(ib_bdy) == 0 ) THEN |
---|
787 | ALLOCATE( dta_bdy(ib_bdy)%a_i (nblen(1),jpl) ) |
---|
788 | ALLOCATE( dta_bdy(ib_bdy)%ht_i(nblen(1),jpl) ) |
---|
789 | ALLOCATE( dta_bdy(ib_bdy)%ht_s(nblen(1),jpl) ) |
---|
790 | ELSE |
---|
791 | IF ( ll_bdylim3 ) THEN ! case input is Xcat |
---|
792 | jfld = jfld + 1 |
---|
793 | dta_bdy(ib_bdy)%a_i => bf(jfld)%fnow(:,1,:) |
---|
794 | jfld = jfld + 1 |
---|
795 | dta_bdy(ib_bdy)%ht_i => bf(jfld)%fnow(:,1,:) |
---|
796 | jfld = jfld + 1 |
---|
797 | dta_bdy(ib_bdy)%ht_s => bf(jfld)%fnow(:,1,:) |
---|
798 | ELSE ! case input is 1cat |
---|
799 | jfld_ai = jfld + 1 |
---|
800 | jfld_hti = jfld + 2 |
---|
801 | jfld_hts = jfld + 3 |
---|
802 | jfld = jfld + 3 |
---|
803 | ALLOCATE( dta_bdy(ib_bdy)%a_i (nblen(1),jpl) ) |
---|
804 | ALLOCATE( dta_bdy(ib_bdy)%ht_i(nblen(1),jpl) ) |
---|
805 | ALLOCATE( dta_bdy(ib_bdy)%ht_s(nblen(1),jpl) ) |
---|
806 | dta_bdy(ib_bdy)%a_i (:,:) = 0._wp |
---|
807 | dta_bdy(ib_bdy)%ht_i(:,:) = 0._wp |
---|
808 | dta_bdy(ib_bdy)%ht_s(:,:) = 0._wp |
---|
809 | ENDIF |
---|
810 | |
---|
811 | ENDIF |
---|
812 | ENDIF |
---|
813 | #endif |
---|
814 | ! |
---|
815 | END DO ! ib_bdy |
---|
816 | ! |
---|
817 | IF( nn_timing == 1 ) CALL timing_stop('bdy_dta_init') |
---|
818 | ! |
---|
819 | END SUBROUTINE bdy_dta_init |
---|
820 | |
---|
821 | !!============================================================================== |
---|
822 | END MODULE bdydta |
---|