| 1 | MODULE limsbc |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE limsbc *** |
|---|
| 4 | !! computation of the flux at the sea ice/ocean interface |
|---|
| 5 | !!====================================================================== |
|---|
| 6 | !! History : - ! 2006-07 (M. Vancoppelle) LIM3 original code |
|---|
| 7 | !! 3.0 ! 2008-03 (C. Tallandier) surface module |
|---|
| 8 | !! - ! 2008-04 (C. Tallandier) split in 2 + new ice-ocean coupling |
|---|
| 9 | !! 3.3 ! 2010-05 (G. Madec) decrease ocean & ice reference salinities in the Baltic sea |
|---|
| 10 | !! ! + simplification of the ice-ocean stress calculation |
|---|
| 11 | !! 3.4 ! 2011-02 (G. Madec) dynamical allocation |
|---|
| 12 | !! - ! 2012 (D. Iovino) salt flux change |
|---|
| 13 | !! - ! 2012-05 (C. Rousset) add penetration solar flux |
|---|
| 14 | !! 3.5 ! 2012-10 (A. Coward, G. Madec) salt fluxes ; ice+snow mass |
|---|
| 15 | !!---------------------------------------------------------------------- |
|---|
| 16 | #if defined key_lim3 |
|---|
| 17 | !!---------------------------------------------------------------------- |
|---|
| 18 | !! 'key_lim3' LIM 3.0 sea-ice model |
|---|
| 19 | !!---------------------------------------------------------------------- |
|---|
| 20 | !! lim_sbc_alloc : allocate the limsbc arrays |
|---|
| 21 | !! lim_sbc_init : initialisation |
|---|
| 22 | !! lim_sbc_flx : updates mass, heat and salt fluxes at the ocean surface |
|---|
| 23 | !! lim_sbc_tau : update i- and j-stresses, and its modulus at the ocean surface |
|---|
| 24 | !!---------------------------------------------------------------------- |
|---|
| 25 | USE par_oce ! ocean parameters |
|---|
| 26 | USE oce , ONLY : sshn, sshb |
|---|
| 27 | USE phycst ! physical constants |
|---|
| 28 | USE dom_oce ! ocean domain |
|---|
| 29 | USE ice ! LIM sea-ice variables |
|---|
| 30 | USE sbc_ice , ONLY : emp_oce, qns_oce, qsr_oce, qemp_oce, emp_ice, qsr_ice, qemp_ice, qevap_ice, alb_ice, tn_ice, cldf_ice, & |
|---|
| 31 | & snwice_mass, snwice_mass_b, snwice_fmass |
|---|
| 32 | USE sbc_oce , ONLY : nn_fsbc, ln_ice_embd, sfx, fr_i, qsr_tot, qns, qsr, fmmflx, emp, taum, utau, vtau |
|---|
| 33 | USE sbccpl ! Surface boundary condition: coupled interface |
|---|
| 34 | USE albedoice ! albedo parameters |
|---|
| 35 | USE traqsr ! add penetration of solar flux in the calculation of heat budget |
|---|
| 36 | USE domvvl ! Variable volume |
|---|
| 37 | USE limctl ! |
|---|
| 38 | USE limcons ! |
|---|
| 39 | USE bdy_oce , ONLY: ln_bdy |
|---|
| 40 | ! |
|---|
| 41 | USE in_out_manager ! I/O manager |
|---|
| 42 | USE iom ! xIO server |
|---|
| 43 | USE lbclnk ! ocean lateral boundary condition - MPP exchanges |
|---|
| 44 | USE lib_mpp ! MPP library |
|---|
| 45 | USE lib_fortran ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) |
|---|
| 46 | |
|---|
| 47 | IMPLICIT NONE |
|---|
| 48 | PRIVATE |
|---|
| 49 | |
|---|
| 50 | PUBLIC lim_sbc_init ! called by ice_init |
|---|
| 51 | PUBLIC lim_sbc_flx ! called by ice_stp |
|---|
| 52 | PUBLIC lim_sbc_tau ! called by ice_stp |
|---|
| 53 | |
|---|
| 54 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: utau_oce, vtau_oce ! air-ocean surface i- & j-stress [N/m2] |
|---|
| 55 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: tmod_io ! modulus of the ice-ocean velocity [m/s] |
|---|
| 56 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: soce_0 , sice_0 ! cst SSS and ice salinity (levitating sea-ice) |
|---|
| 57 | |
|---|
| 58 | !! * Substitutions |
|---|
| 59 | # include "vectopt_loop_substitute.h90" |
|---|
| 60 | !!---------------------------------------------------------------------- |
|---|
| 61 | !! NEMO/LIM3 4.0 , UCL - NEMO Consortium (2011) |
|---|
| 62 | !! $Id$ |
|---|
| 63 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
|---|
| 64 | !!---------------------------------------------------------------------- |
|---|
| 65 | CONTAINS |
|---|
| 66 | |
|---|
| 67 | INTEGER FUNCTION lim_sbc_alloc() |
|---|
| 68 | !!------------------------------------------------------------------- |
|---|
| 69 | !! *** ROUTINE lim_sbc_alloc *** |
|---|
| 70 | !!------------------------------------------------------------------- |
|---|
| 71 | ALLOCATE( soce_0(jpi,jpj) , utau_oce(jpi,jpj) , & |
|---|
| 72 | & sice_0(jpi,jpj) , vtau_oce(jpi,jpj) , tmod_io(jpi,jpj), STAT=lim_sbc_alloc) |
|---|
| 73 | ! |
|---|
| 74 | IF( lk_mpp ) CALL mpp_sum( lim_sbc_alloc ) |
|---|
| 75 | IF( lim_sbc_alloc /= 0 ) CALL ctl_warn('lim_sbc_alloc: failed to allocate arrays') |
|---|
| 76 | END FUNCTION lim_sbc_alloc |
|---|
| 77 | |
|---|
| 78 | |
|---|
| 79 | SUBROUTINE lim_sbc_flx( kt ) |
|---|
| 80 | !!------------------------------------------------------------------- |
|---|
| 81 | !! *** ROUTINE lim_sbc_flx *** |
|---|
| 82 | !! |
|---|
| 83 | !! ** Purpose : Update the surface ocean boundary condition for heat |
|---|
| 84 | !! salt and mass over areas where sea-ice is non-zero |
|---|
| 85 | !! |
|---|
| 86 | !! ** Action : - computes the heat and freshwater/salt fluxes |
|---|
| 87 | !! at the ice-ocean interface. |
|---|
| 88 | !! - Update the ocean sbc |
|---|
| 89 | !! |
|---|
| 90 | !! ** Outputs : - qsr : sea heat flux: solar |
|---|
| 91 | !! - qns : sea heat flux: non solar |
|---|
| 92 | !! - emp : freshwater budget: volume flux |
|---|
| 93 | !! - sfx : salt flux |
|---|
| 94 | !! - fr_i : ice fraction |
|---|
| 95 | !! - tn_ice : sea-ice surface temperature |
|---|
| 96 | !! - alb_ice : sea-ice albedo (recomputed only for coupled mode) |
|---|
| 97 | !! |
|---|
| 98 | !! References : Goosse, H. et al. 1996, Bul. Soc. Roy. Sc. Liege, 65, 87-90. |
|---|
| 99 | !! Tartinville et al. 2001 Ocean Modelling, 3, 95-108. |
|---|
| 100 | !! These refs are now obsolete since everything has been revised |
|---|
| 101 | !! The ref should be Rousset et al., 2015 |
|---|
| 102 | !!--------------------------------------------------------------------- |
|---|
| 103 | INTEGER, INTENT(in) :: kt ! number of iteration |
|---|
| 104 | ! |
|---|
| 105 | INTEGER :: ji, jj, jl, jk ! dummy loop indices |
|---|
| 106 | REAL(wp) :: zqmass ! Heat flux associated with mass exchange ice->ocean (W.m-2) |
|---|
| 107 | REAL(wp) :: zqsr ! New solar flux received by the ocean |
|---|
| 108 | REAL(wp), DIMENSION(jpi,jpj,jpl) :: zalb_cs, zalb_os ! 3D workspace |
|---|
| 109 | REAL(wp), DIMENSION(jpi,jpj) :: zalb ! 2D workspace |
|---|
| 110 | !!--------------------------------------------------------------------- |
|---|
| 111 | |
|---|
| 112 | ! --- case we bypass ice thermodynamics --- ! |
|---|
| 113 | IF( .NOT. ln_limthd ) THEN ! we suppose ice is impermeable => ocean is isolated from atmosphere |
|---|
| 114 | hfx_in (:,:) = ( 1._wp - at_i_b(:,:) ) * ( qns_oce(:,:) + qsr_oce(:,:) ) + qemp_oce(:,:) |
|---|
| 115 | hfx_out (:,:) = ( 1._wp - at_i_b(:,:) ) * qns_oce(:,:) + qemp_oce(:,:) |
|---|
| 116 | ftr_ice (:,:,:) = 0._wp |
|---|
| 117 | emp_ice (:,:) = 0._wp |
|---|
| 118 | qemp_ice (:,:) = 0._wp |
|---|
| 119 | qevap_ice(:,:,:) = 0._wp |
|---|
| 120 | ENDIF |
|---|
| 121 | |
|---|
| 122 | ! albedo output |
|---|
| 123 | zalb(:,:) = 0._wp |
|---|
| 124 | WHERE ( at_i_b <= epsi06 ) ; zalb(:,:) = rn_alb_oce |
|---|
| 125 | ELSEWHERE ; zalb(:,:) = SUM( alb_ice * a_i_b, dim=3 ) / at_i_b |
|---|
| 126 | END WHERE |
|---|
| 127 | IF( iom_use('icealb' ) ) CALL iom_put( "icealb" , zalb(:,:) ) ! ice albedo output |
|---|
| 128 | |
|---|
| 129 | zalb(:,:) = SUM( alb_ice * a_i_b, dim=3 ) + rn_alb_oce * ( 1._wp - at_i_b ) |
|---|
| 130 | IF( iom_use('albedo' ) ) CALL iom_put( "albedo" , zalb(:,:) ) ! surface albedo output |
|---|
| 131 | |
|---|
| 132 | |
|---|
| 133 | DO jj = 1, jpj |
|---|
| 134 | DO ji = 1, jpi |
|---|
| 135 | |
|---|
| 136 | !------------------------------------------! |
|---|
| 137 | ! heat flux at the ocean surface ! |
|---|
| 138 | !------------------------------------------! |
|---|
| 139 | ! Solar heat flux reaching the ocean = zqsr (W.m-2) |
|---|
| 140 | !--------------------------------------------------- |
|---|
| 141 | zqsr = qsr_tot(ji,jj) |
|---|
| 142 | DO jl = 1, jpl |
|---|
| 143 | zqsr = zqsr - a_i_b(ji,jj,jl) * ( qsr_ice(ji,jj,jl) - ftr_ice(ji,jj,jl) ) |
|---|
| 144 | END DO |
|---|
| 145 | |
|---|
| 146 | ! Total heat flux reaching the ocean = hfx_out (W.m-2) |
|---|
| 147 | !--------------------------------------------------- |
|---|
| 148 | zqmass = hfx_thd(ji,jj) + hfx_dyn(ji,jj) + hfx_res(ji,jj) ! heat flux from snow is 0 (T=0 degC) |
|---|
| 149 | hfx_out(ji,jj) = hfx_out(ji,jj) + zqmass + zqsr |
|---|
| 150 | |
|---|
| 151 | ! Add the residual from heat diffusion equation and sublimation (W.m-2) |
|---|
| 152 | !---------------------------------------------------------------------- |
|---|
| 153 | hfx_out(ji,jj) = hfx_out(ji,jj) + hfx_err_dif(ji,jj) + & |
|---|
| 154 | & ( hfx_sub(ji,jj) - SUM( qevap_ice(ji,jj,:) * a_i_b(ji,jj,:) ) ) |
|---|
| 155 | |
|---|
| 156 | ! New qsr and qns used to compute the oceanic heat flux at the next time step |
|---|
| 157 | !---------------------------------------------------------------------------- |
|---|
| 158 | qsr(ji,jj) = zqsr |
|---|
| 159 | qns(ji,jj) = hfx_out(ji,jj) - zqsr |
|---|
| 160 | |
|---|
| 161 | ! Mass flux at the atm. surface |
|---|
| 162 | !----------------------------------- |
|---|
| 163 | wfx_sub(ji,jj) = wfx_snw_sub(ji,jj) + wfx_ice_sub(ji,jj) |
|---|
| 164 | |
|---|
| 165 | ! Mass flux at the ocean surface |
|---|
| 166 | !------------------------------------ |
|---|
| 167 | ! case of realistic freshwater flux (Tartinville et al., 2001) (presently ACTIVATED) |
|---|
| 168 | ! ------------------------------------------------------------------------------------- |
|---|
| 169 | ! The idea of this approach is that the system that we consider is the ICE-OCEAN system |
|---|
| 170 | ! Thus FW flux = External ( E-P+snow melt) |
|---|
| 171 | ! Salt flux = Exchanges in the ice-ocean system then converted into FW |
|---|
| 172 | ! Associated to Ice formation AND Ice melting |
|---|
| 173 | ! Even if i see Ice melting as a FW and SALT flux |
|---|
| 174 | ! |
|---|
| 175 | ! mass flux from ice/ocean |
|---|
| 176 | wfx_ice(ji,jj) = wfx_bog(ji,jj) + wfx_bom(ji,jj) + wfx_sum(ji,jj) + wfx_sni(ji,jj) & |
|---|
| 177 | + wfx_opw(ji,jj) + wfx_dyn(ji,jj) + wfx_res(ji,jj) + wfx_lam(ji,jj) |
|---|
| 178 | |
|---|
| 179 | IF ( ln_pnd_fw ) wfx_ice(ji,jj) = wfx_ice(ji,jj) + wfx_pnd(ji,jj) |
|---|
| 180 | |
|---|
| 181 | ! add the snow melt water to snow mass flux to the ocean |
|---|
| 182 | wfx_snw(ji,jj) = wfx_snw_sni(ji,jj) + wfx_snw_dyn(ji,jj) + wfx_snw_sum(ji,jj) |
|---|
| 183 | |
|---|
| 184 | ! mass flux at the ocean/ice interface |
|---|
| 185 | fmmflx(ji,jj) = - ( wfx_ice(ji,jj) + wfx_snw(ji,jj) + wfx_err_sub(ji,jj) ) ! F/M mass flux save at least for biogeochemical model |
|---|
| 186 | emp(ji,jj) = emp_oce(ji,jj) - wfx_ice(ji,jj) - wfx_snw(ji,jj) - wfx_err_sub(ji,jj) ! mass flux + F/M mass flux (always ice/ocean mass exchange) |
|---|
| 187 | |
|---|
| 188 | |
|---|
| 189 | ! Salt flux at the ocean surface |
|---|
| 190 | !------------------------------------------ |
|---|
| 191 | sfx(ji,jj) = sfx_bog(ji,jj) + sfx_bom(ji,jj) + sfx_sum(ji,jj) + sfx_sni(ji,jj) + sfx_opw(ji,jj) & |
|---|
| 192 | & + sfx_res(ji,jj) + sfx_dyn(ji,jj) + sfx_bri(ji,jj) + sfx_sub(ji,jj) + sfx_lam(ji,jj) |
|---|
| 193 | |
|---|
| 194 | ! Mass of snow and ice per unit area |
|---|
| 195 | !---------------------------------------- |
|---|
| 196 | ! save mass from the previous ice time step |
|---|
| 197 | snwice_mass_b(ji,jj) = snwice_mass(ji,jj) |
|---|
| 198 | ! new mass per unit area |
|---|
| 199 | snwice_mass (ji,jj) = tmask(ji,jj,1) * ( rhosn * vt_s(ji,jj) + rhoic * vt_i(ji,jj) ) |
|---|
| 200 | ! time evolution of snow+ice mass |
|---|
| 201 | snwice_fmass (ji,jj) = ( snwice_mass(ji,jj) - snwice_mass_b(ji,jj) ) * r1_rdtice |
|---|
| 202 | |
|---|
| 203 | END DO |
|---|
| 204 | END DO |
|---|
| 205 | |
|---|
| 206 | !-----------------------------------------------! |
|---|
| 207 | ! Storing the transmitted variables ! |
|---|
| 208 | !-----------------------------------------------! |
|---|
| 209 | fr_i (:,:) = at_i(:,:) ! Sea-ice fraction |
|---|
| 210 | tn_ice(:,:,:) = t_su(:,:,:) ! Ice surface temperature |
|---|
| 211 | |
|---|
| 212 | !------------------------------------------------------------------------! |
|---|
| 213 | ! Snow/ice albedo (only if sent to coupler, useless in forced mode) ! |
|---|
| 214 | !------------------------------------------------------------------------! |
|---|
| 215 | CALL albedo_ice( t_su, ht_i, ht_s, a_ip_frac, h_ip, ln_pnd_rad, zalb_cs, zalb_os ) ! cloud-sky and overcast-sky ice albedos |
|---|
| 216 | |
|---|
| 217 | alb_ice(:,:,:) = ( 1. - cldf_ice ) * zalb_cs(:,:,:) + cldf_ice * zalb_os(:,:,:) |
|---|
| 218 | |
|---|
| 219 | ! conservation test |
|---|
| 220 | IF( ln_limdiachk .AND. .NOT. ln_bdy) CALL lim_cons_final( 'limsbc' ) |
|---|
| 221 | |
|---|
| 222 | ! control prints |
|---|
| 223 | IF( ln_limctl ) CALL lim_prt( kt, iiceprt, jiceprt, 3, ' - Final state lim_sbc - ' ) |
|---|
| 224 | IF( ln_ctl ) CALL lim_prt3D( 'limsbc' ) |
|---|
| 225 | |
|---|
| 226 | END SUBROUTINE lim_sbc_flx |
|---|
| 227 | |
|---|
| 228 | |
|---|
| 229 | SUBROUTINE lim_sbc_tau( kt , pu_oce, pv_oce ) |
|---|
| 230 | !!------------------------------------------------------------------- |
|---|
| 231 | !! *** ROUTINE lim_sbc_tau *** |
|---|
| 232 | !! |
|---|
| 233 | !! ** Purpose : Update the ocean surface stresses due to the ice |
|---|
| 234 | !! |
|---|
| 235 | !! ** Action : * at each ice time step (every nn_fsbc time step): |
|---|
| 236 | !! - compute the modulus of ice-ocean relative velocity |
|---|
| 237 | !! (*rho*Cd) at T-point (C-grid) or I-point (B-grid) |
|---|
| 238 | !! tmod_io = rhoco * | U_ice-U_oce | |
|---|
| 239 | !! - update the modulus of stress at ocean surface |
|---|
| 240 | !! taum = (1-a) * taum + a * tmod_io * | U_ice-U_oce | |
|---|
| 241 | !! * at each ocean time step (every kt): |
|---|
| 242 | !! compute linearized ice-ocean stresses as |
|---|
| 243 | !! Utau = tmod_io * | U_ice - pU_oce | |
|---|
| 244 | !! using instantaneous current ocean velocity (usually before) |
|---|
| 245 | !! |
|---|
| 246 | !! NB: - ice-ocean rotation angle no more allowed |
|---|
| 247 | !! - here we make an approximation: taum is only computed every ice time step |
|---|
| 248 | !! This avoids mutiple average to pass from T -> U,V grids and next from U,V grids |
|---|
| 249 | !! to T grid. taum is used in TKE and GLS, which should not be too sensitive to this approximaton... |
|---|
| 250 | !! |
|---|
| 251 | !! ** Outputs : - utau, vtau : surface ocean i- and j-stress (u- & v-pts) updated with ice-ocean fluxes |
|---|
| 252 | !! - taum : modulus of the surface ocean stress (T-point) updated with ice-ocean fluxes |
|---|
| 253 | !!--------------------------------------------------------------------- |
|---|
| 254 | INTEGER , INTENT(in) :: kt ! ocean time-step index |
|---|
| 255 | REAL(wp), DIMENSION(jpi,jpj), INTENT(in) :: pu_oce, pv_oce ! surface ocean currents |
|---|
| 256 | ! |
|---|
| 257 | INTEGER :: ji, jj ! dummy loop indices |
|---|
| 258 | REAL(wp) :: zat_u, zutau_ice, zu_t, zmodt ! local scalar |
|---|
| 259 | REAL(wp) :: zat_v, zvtau_ice, zv_t, zrhoco ! - - |
|---|
| 260 | !!--------------------------------------------------------------------- |
|---|
| 261 | zrhoco = rau0 * rn_cio |
|---|
| 262 | ! |
|---|
| 263 | IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN !== Ice time-step only ==! (i.e. surface module time-step) |
|---|
| 264 | DO jj = 2, jpjm1 !* update the modulus of stress at ocean surface (T-point) |
|---|
| 265 | DO ji = fs_2, fs_jpim1 |
|---|
| 266 | ! ! 2*(U_ice-U_oce) at T-point |
|---|
| 267 | zu_t = u_ice(ji,jj) + u_ice(ji-1,jj) - u_oce(ji,jj) - u_oce(ji-1,jj) |
|---|
| 268 | zv_t = v_ice(ji,jj) + v_ice(ji,jj-1) - v_oce(ji,jj) - v_oce(ji,jj-1) |
|---|
| 269 | ! ! |U_ice-U_oce|^2 |
|---|
| 270 | zmodt = 0.25_wp * ( zu_t * zu_t + zv_t * zv_t ) |
|---|
| 271 | ! ! update the ocean stress modulus |
|---|
| 272 | taum(ji,jj) = ( 1._wp - at_i(ji,jj) ) * taum(ji,jj) + at_i(ji,jj) * zrhoco * zmodt |
|---|
| 273 | tmod_io(ji,jj) = zrhoco * SQRT( zmodt ) ! rhoco * |U_ice-U_oce| at T-point |
|---|
| 274 | END DO |
|---|
| 275 | END DO |
|---|
| 276 | CALL lbc_lnk_multi( taum, 'T', 1., tmod_io, 'T', 1. ) |
|---|
| 277 | ! |
|---|
| 278 | utau_oce(:,:) = utau(:,:) !* save the air-ocean stresses at ice time-step |
|---|
| 279 | vtau_oce(:,:) = vtau(:,:) |
|---|
| 280 | ! |
|---|
| 281 | ENDIF |
|---|
| 282 | ! |
|---|
| 283 | ! !== every ocean time-step ==! |
|---|
| 284 | ! |
|---|
| 285 | DO jj = 2, jpjm1 !* update the stress WITHOUT a ice-ocean rotation angle |
|---|
| 286 | DO ji = fs_2, fs_jpim1 ! Vect. Opt. |
|---|
| 287 | zat_u = ( at_i(ji,jj) + at_i(ji+1,jj) ) * 0.5_wp ! ice area at u and V-points |
|---|
| 288 | zat_v = ( at_i(ji,jj) + at_i(ji,jj+1) ) * 0.5_wp |
|---|
| 289 | ! ! linearized quadratic drag formulation |
|---|
| 290 | zutau_ice = 0.5_wp * ( tmod_io(ji,jj) + tmod_io(ji+1,jj) ) * ( u_ice(ji,jj) - pu_oce(ji,jj) ) |
|---|
| 291 | zvtau_ice = 0.5_wp * ( tmod_io(ji,jj) + tmod_io(ji,jj+1) ) * ( v_ice(ji,jj) - pv_oce(ji,jj) ) |
|---|
| 292 | ! ! stresses at the ocean surface |
|---|
| 293 | utau(ji,jj) = ( 1._wp - zat_u ) * utau_oce(ji,jj) + zat_u * zutau_ice |
|---|
| 294 | vtau(ji,jj) = ( 1._wp - zat_v ) * vtau_oce(ji,jj) + zat_v * zvtau_ice |
|---|
| 295 | END DO |
|---|
| 296 | END DO |
|---|
| 297 | CALL lbc_lnk_multi( utau, 'U', -1., vtau, 'V', -1. ) ! lateral boundary condition |
|---|
| 298 | ! |
|---|
| 299 | ! |
|---|
| 300 | END SUBROUTINE lim_sbc_tau |
|---|
| 301 | |
|---|
| 302 | |
|---|
| 303 | SUBROUTINE lim_sbc_init |
|---|
| 304 | !!------------------------------------------------------------------- |
|---|
| 305 | !! *** ROUTINE lim_sbc_init *** |
|---|
| 306 | !! |
|---|
| 307 | !! ** Purpose : Preparation of the file ice_evolu for the output of |
|---|
| 308 | !! the temporal evolution of key variables |
|---|
| 309 | !! |
|---|
| 310 | !! ** input : Namelist namicedia |
|---|
| 311 | !!------------------------------------------------------------------- |
|---|
| 312 | INTEGER :: ji, jj, jk ! dummy loop indices |
|---|
| 313 | REAL(wp) :: zcoefu, zcoefv, zcoeff ! local scalar |
|---|
| 314 | !!------------------------------------------------------------------- |
|---|
| 315 | ! |
|---|
| 316 | IF(lwp) WRITE(numout,*) |
|---|
| 317 | IF(lwp) WRITE(numout,*) 'lim_sbc_init : LIM-3 sea-ice - surface boundary condition' |
|---|
| 318 | IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~~ ' |
|---|
| 319 | |
|---|
| 320 | ! ! allocate lim_sbc array |
|---|
| 321 | IF( lim_sbc_alloc() /= 0 ) CALL ctl_stop( 'STOP', 'lim_sbc_init : unable to allocate standard arrays' ) |
|---|
| 322 | ! |
|---|
| 323 | soce_0(:,:) = soce ! constant SSS and ice salinity used in levitating sea-ice case |
|---|
| 324 | sice_0(:,:) = sice |
|---|
| 325 | ! ! decrease ocean & ice reference salinities in the Baltic Sea area |
|---|
| 326 | WHERE( 14._wp <= glamt(:,:) .AND. glamt(:,:) <= 32._wp .AND. & |
|---|
| 327 | & 54._wp <= gphit(:,:) .AND. gphit(:,:) <= 66._wp ) |
|---|
| 328 | soce_0(:,:) = 4._wp |
|---|
| 329 | sice_0(:,:) = 2._wp |
|---|
| 330 | END WHERE |
|---|
| 331 | ! |
|---|
| 332 | IF( .NOT. ln_rstart ) THEN |
|---|
| 333 | ! |
|---|
| 334 | snwice_mass (:,:) = tmask(:,:,1) * ( rhosn * vt_s(:,:) + rhoic * vt_i(:,:) ) ! snow+ice mass |
|---|
| 335 | snwice_mass_b(:,:) = snwice_mass(:,:) |
|---|
| 336 | ! |
|---|
| 337 | IF( ln_ice_embd ) THEN ! embedded sea-ice: deplete the initial ssh below sea-ice area |
|---|
| 338 | sshn(:,:) = sshn(:,:) - snwice_mass(:,:) * r1_rau0 |
|---|
| 339 | sshb(:,:) = sshb(:,:) - snwice_mass(:,:) * r1_rau0 |
|---|
| 340 | |
|---|
| 341 | !!gm I really don't like this stuff here... Find a way to put that elsewhere or differently |
|---|
| 342 | !!gm |
|---|
| 343 | IF( .NOT.ln_linssh ) THEN |
|---|
| 344 | DO jk = 1,jpkm1 ! adjust initial vertical scale factors |
|---|
| 345 | e3t_n(:,:,jk) = e3t_0(:,:,jk)*( 1._wp + sshn(:,:)*tmask(:,:,1)/(ht_0(:,:) + 1.0 - tmask(:,:,1)) ) |
|---|
| 346 | e3t_b(:,:,jk) = e3t_0(:,:,jk)*( 1._wp + sshb(:,:)*tmask(:,:,1)/(ht_0(:,:) + 1.0 - tmask(:,:,1)) ) |
|---|
| 347 | END DO |
|---|
| 348 | e3t_a(:,:,:) = e3t_b(:,:,:) |
|---|
| 349 | ! Reconstruction of all vertical scale factors at now and before time-steps |
|---|
| 350 | ! ========================================================================= |
|---|
| 351 | ! Horizontal scale factor interpolations |
|---|
| 352 | ! -------------------------------------- |
|---|
| 353 | CALL dom_vvl_interpol( e3t_b(:,:,:), e3u_b(:,:,:), 'U' ) |
|---|
| 354 | CALL dom_vvl_interpol( e3t_b(:,:,:), e3v_b(:,:,:), 'V' ) |
|---|
| 355 | CALL dom_vvl_interpol( e3t_n(:,:,:), e3u_n(:,:,:), 'U' ) |
|---|
| 356 | CALL dom_vvl_interpol( e3t_n(:,:,:), e3v_n(:,:,:), 'V' ) |
|---|
| 357 | CALL dom_vvl_interpol( e3u_n(:,:,:), e3f_n(:,:,:), 'F' ) |
|---|
| 358 | ! Vertical scale factor interpolations |
|---|
| 359 | ! ------------------------------------ |
|---|
| 360 | CALL dom_vvl_interpol( e3t_n(:,:,:), e3w_n (:,:,:), 'W' ) |
|---|
| 361 | CALL dom_vvl_interpol( e3u_n(:,:,:), e3uw_n(:,:,:), 'UW' ) |
|---|
| 362 | CALL dom_vvl_interpol( e3v_n(:,:,:), e3vw_n(:,:,:), 'VW' ) |
|---|
| 363 | CALL dom_vvl_interpol( e3u_b(:,:,:), e3uw_b(:,:,:), 'UW' ) |
|---|
| 364 | CALL dom_vvl_interpol( e3v_b(:,:,:), e3vw_b(:,:,:), 'VW' ) |
|---|
| 365 | ! t- and w- points depth |
|---|
| 366 | ! ---------------------- |
|---|
| 367 | !!gm not sure of that.... |
|---|
| 368 | gdept_n(:,:,1) = 0.5_wp * e3w_n(:,:,1) |
|---|
| 369 | gdepw_n(:,:,1) = 0.0_wp |
|---|
| 370 | gde3w_n(:,:,1) = gdept_n(:,:,1) - sshn(:,:) |
|---|
| 371 | DO jk = 2, jpk |
|---|
| 372 | gdept_n(:,:,jk) = gdept_n(:,:,jk-1) + e3w_n(:,:,jk) |
|---|
| 373 | gdepw_n(:,:,jk) = gdepw_n(:,:,jk-1) + e3t_n(:,:,jk-1) |
|---|
| 374 | gde3w_n(:,:,jk) = gdept_n(:,:,jk ) - sshn (:,:) |
|---|
| 375 | END DO |
|---|
| 376 | ENDIF |
|---|
| 377 | ENDIF |
|---|
| 378 | ENDIF ! .NOT. ln_rstart |
|---|
| 379 | ! |
|---|
| 380 | END SUBROUTINE lim_sbc_init |
|---|
| 381 | |
|---|
| 382 | #else |
|---|
| 383 | !!---------------------------------------------------------------------- |
|---|
| 384 | !! Default option : Dummy module NO LIM 3.0 sea-ice model |
|---|
| 385 | !!---------------------------------------------------------------------- |
|---|
| 386 | CONTAINS |
|---|
| 387 | SUBROUTINE lim_sbc ! Dummy routine |
|---|
| 388 | END SUBROUTINE lim_sbc |
|---|
| 389 | #endif |
|---|
| 390 | |
|---|
| 391 | !!====================================================================== |
|---|
| 392 | END MODULE limsbc |
|---|
