New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zlys.F90 in branches/2017/dev_r7881_no_wrk_alloc/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z – NEMO

source: branches/2017/dev_r7881_no_wrk_alloc/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z/p4zlys.F90 @ 7910

Last change on this file since 7910 was 7910, checked in by timgraham, 7 years ago

All wrk_alloc removed
File size: 8.4 KB
Line 
1MODULE p4zlys
2   !!======================================================================
3   !!                         ***  MODULE p4zlys  ***
4   !! TOP :   PISCES
5   !!======================================================================
6   !! History :    -   !  1988-07  (E. MAIER-REIMER) Original code
7   !!              -   !  1998     (O. Aumont) additions
8   !!              -   !  1999     (C. Le Quere) modifications
9   !!             1.0  !  2004     (O. Aumont) modifications
10   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
11   !!                  !  2011-02  (J. Simeon, J. Orr)  Calcon salinity dependence
12   !!             3.4  !  2011-06  (O. Aumont, C. Ethe) Improvment of calcite dissolution
13   !!             3.6  !  2015-05  (O. Aumont) PISCES quota
14   !!----------------------------------------------------------------------
15   !!   p4z_lys        :   Compute the CaCO3 dissolution
16   !!   p4z_lys_init   :   Read the namelist parameters
17   !!----------------------------------------------------------------------
18   USE oce_trc         !  shared variables between ocean and passive tracers
19   USE trc             !  passive tracers common variables
20   USE sms_pisces      !  PISCES Source Minus Sink variables
21   USE p4zche          !  Chemical model
22   USE prtctl_trc      !  print control for debugging
23   USE iom             !  I/O manager
24
25   IMPLICIT NONE
26   PRIVATE
27
28   PUBLIC   p4z_lys         ! called in trcsms_pisces.F90
29   PUBLIC   p4z_lys_init    ! called in trcsms_pisces.F90
30
31   !! * Shared module variables
32   REAL(wp), PUBLIC :: kdca !: diss. rate constant calcite
33   REAL(wp), PUBLIC :: nca  !: order of reaction for calcite dissolution
34
35   !! * Module variables
36   REAL(wp) :: calcon = 1.03E-2           !: mean calcite concentration [Ca2+] in sea water [mole/kg solution]
37 
38   INTEGER  :: rmtss                      !: number of seconds per month
39
40   !!----------------------------------------------------------------------
41   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
42   !! $Id: p4zlys.F90 3321 2012-03-05 17:10:55Z cetlod $
43   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
44   !!----------------------------------------------------------------------
45
46CONTAINS
47
48   SUBROUTINE p4z_lys( kt, knt )
49      !!---------------------------------------------------------------------
50      !!                     ***  ROUTINE p4z_lys  ***
51      !!
52      !! ** Purpose :   CALCULATES DEGREE OF CACO3 SATURATION IN THE WATER
53      !!                COLUMN, DISSOLUTION/PRECIPITATION OF CACO3 AND LOSS
54      !!                OF CACO3 TO THE CACO3 SEDIMENT POOL.
55      !!
56      !! ** Method  : - ???
57      !!---------------------------------------------------------------------
58      !
59      INTEGER, INTENT(in) ::   kt, knt ! ocean time step
60      INTEGER  ::   ji, jj, jk, jn
61      REAL(wp) ::   zdispot, zfact, zcalcon
62      REAL(wp) ::   zomegaca, zexcess, zexcess0
63      CHARACTER (len=25) :: charout
64      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zco3, zcaldiss, zhinit, zhi, zco3sat
65      !!---------------------------------------------------------------------
66      !
67      IF( nn_timing == 1 )  CALL timing_start('p4z_lys')
68      !
69      !
70      zco3    (:,:,:) = 0.
71      zcaldiss(:,:,:) = 0.
72      zhinit(:,:,:)   = hi(:,:,:) * 1000. / ( rhop(:,:,:) + rtrn )
73      !     -------------------------------------------
74      !     COMPUTE [CO3--] and [H+] CONCENTRATIONS
75      !     -------------------------------------------
76
77      CALL solve_at_general(zhinit, zhi)
78
79      DO jk = 1, jpkm1
80         DO jj = 1, jpj
81            DO ji = 1, jpi
82               zco3(ji,jj,jk) = trb(ji,jj,jk,jpdic) * ak13(ji,jj,jk) * ak23(ji,jj,jk) / (zhi(ji,jj,jk)**2   &
83               &                + ak13(ji,jj,jk) * zhi(ji,jj,jk) + ak13(ji,jj,jk) * ak23(ji,jj,jk) + rtrn )
84               hi(ji,jj,jk)   = zhi(ji,jj,jk) * rhop(ji,jj,jk) / 1000.
85            END DO
86         END DO
87      END DO
88
89      !     ---------------------------------------------------------
90      !        CALCULATE DEGREE OF CACO3 SATURATION AND CORRESPONDING
91      !        DISSOLOUTION AND PRECIPITATION OF CACO3 (BE AWARE OF
92      !        MGCO3)
93      !     ---------------------------------------------------------
94
95      DO jk = 1, jpkm1
96         DO jj = 1, jpj
97            DO ji = 1, jpi
98
99               ! DEVIATION OF [CO3--] FROM SATURATION VALUE
100               ! Salinity dependance in zomegaca and divide by rhop/1000 to have good units
101               zcalcon  = calcon * ( salinprac(ji,jj,jk) / 35._wp )
102               zfact    = rhop(ji,jj,jk) / 1000._wp
103               zomegaca = ( zcalcon * zco3(ji,jj,jk) ) / ( aksp(ji,jj,jk) * zfact + rtrn )
104               zco3sat(ji,jj,jk) = aksp(ji,jj,jk) * zfact / ( zcalcon + rtrn )
105
106               ! SET DEGREE OF UNDER-/SUPERSATURATION
107               excess(ji,jj,jk) = 1._wp - zomegaca
108               zexcess0 = MAX( 0., excess(ji,jj,jk) )
109               zexcess  = zexcess0**nca
110
111               ! AMOUNT CACO3 (12C) THAT RE-ENTERS SOLUTION
112               !       (ACCORDING TO THIS FORMULATION ALSO SOME PARTICULATE
113               !       CACO3 GETS DISSOLVED EVEN IN THE CASE OF OVERSATURATION)
114               zdispot = kdca * zexcess * trb(ji,jj,jk,jpcal)
115              !  CHANGE OF [CO3--] , [ALK], PARTICULATE [CACO3],
116              !       AND [SUM(CO2)] DUE TO CACO3 DISSOLUTION/PRECIPITATION
117              zcaldiss(ji,jj,jk)  = zdispot * rfact2 / rmtss ! calcite dissolution
118              !
119              tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) + 2. * zcaldiss(ji,jj,jk)
120              tra(ji,jj,jk,jpcal) = tra(ji,jj,jk,jpcal) -      zcaldiss(ji,jj,jk)
121              tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) +      zcaldiss(ji,jj,jk)
122            END DO
123         END DO
124      END DO
125      !
126
127      IF( lk_iomput .AND. knt == nrdttrc ) THEN
128         IF( iom_use( "PH"     ) ) CALL iom_put( "PH"    , -1. * LOG10( hi(:,:,:) )          * tmask(:,:,:) )
129         IF( iom_use( "CO3"    ) ) CALL iom_put( "CO3"   , zco3(:,:,:)    * 1.e+3            * tmask(:,:,:) )
130         IF( iom_use( "CO3sat" ) ) CALL iom_put( "CO3sat", zco3sat(:,:,:) * 1.e+3            * tmask(:,:,:) )
131         IF( iom_use( "DCAL"   ) ) CALL iom_put( "DCAL"  , zcaldiss(:,:,:) * 1.e+3 * rfact2r * tmask(:,:,:) )
132      ENDIF
133      !
134      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
135        WRITE(charout, FMT="('lys ')")
136        CALL prt_ctl_trc_info(charout)
137        CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
138      ENDIF
139      !
140      !
141      IF( nn_timing == 1 )  CALL timing_stop('p4z_lys')
142      !
143   END SUBROUTINE p4z_lys
144
145   SUBROUTINE p4z_lys_init
146
147      !!----------------------------------------------------------------------
148      !!                  ***  ROUTINE p4z_lys_init  ***
149      !!
150      !! ** Purpose :   Initialization of CaCO3 dissolution parameters
151      !!
152      !! ** Method  :   Read the nampiscal namelist and check the parameters
153      !!      called at the first timestep (nittrc000)
154      !!
155      !! ** input   :   Namelist nampiscal
156      !!
157      !!----------------------------------------------------------------------
158      INTEGER  ::  ios                 ! Local integer output status for namelist read
159
160      NAMELIST/nampiscal/ kdca, nca
161      !!----------------------------------------------------------------------
162
163      REWIND( numnatp_ref )              ! Namelist nampiscal in reference namelist : Pisces CaCO3 dissolution
164      READ  ( numnatp_ref, nampiscal, IOSTAT = ios, ERR = 901)
165901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampiscal in reference namelist', lwp )
166
167      REWIND( numnatp_cfg )              ! Namelist nampiscal in configuration namelist : Pisces CaCO3 dissolution
168      READ  ( numnatp_cfg, nampiscal, IOSTAT = ios, ERR = 902 )
169902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampiscal in configuration namelist', lwp )
170      IF(lwm) WRITE ( numonp, nampiscal )
171
172      IF(lwp) THEN                         ! control print
173         WRITE(numout,*) ' '
174         WRITE(numout,*) ' Namelist parameters for CaCO3 dissolution, nampiscal'
175         WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
176         WRITE(numout,*) '    diss. rate constant calcite (per month)   kdca      =', kdca
177         WRITE(numout,*) '    order of reaction for calcite dissolution nca       =', nca
178      ENDIF
179
180      ! Number of seconds per month
181      rmtss =  nyear_len(1) * rday / raamo
182      !
183   END SUBROUTINE p4z_lys_init
184   !!======================================================================
185END MODULE p4zlys
Note: See TracBrowser for help on using the repository browser.