New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
zdfiwm.F90 in branches/2017/dev_r7881_ENHANCE09_RK3/NEMOGCM/NEMO/OPA_SRC/ZDF – NEMO

source: branches/2017/dev_r7881_ENHANCE09_RK3/NEMOGCM/NEMO/OPA_SRC/ZDF/zdfiwm.F90 @ 8568

Last change on this file since 8568 was 8568, checked in by gm, 7 years ago

#1911 (ENHANCE-09): PART I.2 - _NONE option + remove zts + see associated wiki page
File size: 25.6 KB
Line 
1MODULE zdfiwm
2   !!========================================================================
3   !!                       ***  MODULE  zdfiwm  ***
4   !! Ocean physics: Internal gravity wave-driven vertical mixing
5   !!========================================================================
6   !! History :  1.0  !  2004-04  (L. Bessieres, G. Madec)  Original code
7   !!             -   !  2006-08  (A. Koch-Larrouy)  Indonesian strait
8   !!            3.3  !  2010-10  (C. Ethe, G. Madec)  reorganisation of initialisation phase
9   !!            3.6  !  2016-03  (C. de Lavergne)  New param: internal wave-driven mixing
10   !!            4.0  !  2017-04  (G. Madec)  renamed module, remove the old param. and the CPP keys
11   !!----------------------------------------------------------------------
12
13   !!----------------------------------------------------------------------
14   !!   zdf_iwm       : global     momentum & tracer Kz with wave induced Kz
15   !!   zdf_iwm_init  : global     momentum & tracer Kz with wave induced Kz
16   !!----------------------------------------------------------------------
17   USE oce            ! ocean dynamics and tracers variables
18   USE dom_oce        ! ocean space and time domain variables
19   USE zdf_oce        ! ocean vertical physics variables
20   USE zdfddm         ! ocean vertical physics: double diffusive mixing
21   USE lbclnk         ! ocean lateral boundary conditions (or mpp link)
22   USE eosbn2         ! ocean equation of state
23   USE phycst         ! physical constants
24   USE prtctl         ! Print control
25   USE in_out_manager ! I/O manager
26   USE iom            ! I/O Manager
27   USE lib_mpp        ! MPP library
28   USE wrk_nemo       ! work arrays
29   USE timing         ! Timing
30   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
31
32   IMPLICIT NONE
33   PRIVATE
34
35   PUBLIC   zdf_iwm         ! called in step module
36   PUBLIC   zdf_iwm_init    ! called in nemogcm module
37
38   !                       !!* Namelist  namzdf_iwm : internal wave-driven mixing *
39   INTEGER  ::  nn_zpyc     ! pycnocline-intensified mixing energy proportional to N (=1) or N^2 (=2)
40   LOGICAL  ::  ln_mevar    ! variable (=T) or constant (=F) mixing efficiency
41   LOGICAL  ::  ln_tsdiff   ! account for differential T/S wave-driven mixing (=T) or not (=F)
42
43   REAL(wp) ::  r1_6 = 1._wp / 6._wp
44
45   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   ebot_iwm     ! power available from high-mode wave breaking (W/m2)
46   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   epyc_iwm     ! power available from low-mode, pycnocline-intensified wave breaking (W/m2)
47   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   ecri_iwm     ! power available from low-mode, critical slope wave breaking (W/m2)
48   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   hbot_iwm     ! WKB decay scale for high-mode energy dissipation (m)
49   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   hcri_iwm     ! decay scale for low-mode critical slope dissipation (m)
50   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   emix_iwm     ! local energy density available for mixing (W/kg)
51   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   bflx_iwm     ! buoyancy flux Kz * N^2 (W/kg)
52   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   pcmap_iwm    ! vertically integrated buoyancy flux (W/m2)
53   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   zav_ratio    ! S/T diffusivity ratio (only for ln_tsdiff=T)
54   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   zav_wave     ! Internal wave-induced diffusivity
55
56   !! * Substitutions
57#  include "vectopt_loop_substitute.h90"
58   !!----------------------------------------------------------------------
59   !! NEMO/OPA 4.0 , NEMO Consortium (2016)
60   !! $Id: zdfiwm.F90 8093 2017-05-30 08:13:14Z gm $
61   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
62   !!----------------------------------------------------------------------
63CONTAINS
64
65   INTEGER FUNCTION zdf_iwm_alloc()
66      !!----------------------------------------------------------------------
67      !!                ***  FUNCTION zdf_iwm_alloc  ***
68      !!----------------------------------------------------------------------
69      ALLOCATE(     ebot_iwm(jpi,jpj),  epyc_iwm(jpi,jpj),  ecri_iwm(jpi,jpj)    ,   &
70      &             hbot_iwm(jpi,jpj),  hcri_iwm(jpi,jpj),  emix_iwm(jpi,jpj,jpk),   &
71      &         bflx_iwm(jpi,jpj,jpk), pcmap_iwm(jpi,jpj), zav_ratio(jpi,jpj,jpk),   & 
72      &         zav_wave(jpi,jpj,jpk), STAT=zdf_iwm_alloc     )
73      !
74      IF( lk_mpp             )   CALL mpp_sum ( zdf_iwm_alloc )
75      IF( zdf_iwm_alloc /= 0 )   CALL ctl_warn('zdf_iwm_alloc: failed to allocate arrays')
76   END FUNCTION zdf_iwm_alloc
77
78
79   SUBROUTINE zdf_iwm( kt, p_avm, p_avt, p_avs )
80      !!----------------------------------------------------------------------
81      !!                  ***  ROUTINE zdf_iwm  ***
82      !!                   
83      !! ** Purpose :   add to the vertical mixing coefficients the effect of
84      !!              breaking internal waves.
85      !!
86      !! ** Method  : - internal wave-driven vertical mixing is given by:
87      !!                  Kz_wave = min(  100 cm2/s, f(  Reb = emix_iwm /( Nu * N^2 )  )
88      !!              where emix_iwm is the 3D space distribution of the wave-breaking
89      !!              energy and Nu the molecular kinematic viscosity.
90      !!              The function f(Reb) is linear (constant mixing efficiency)
91      !!              if the namelist parameter ln_mevar = F and nonlinear if ln_mevar = T.
92      !!
93      !!              - Compute emix_iwm, the 3D power density that allows to compute
94      !!              Reb and therefrom the wave-induced vertical diffusivity.
95      !!              This is divided into three components:
96      !!                 1. Bottom-intensified low-mode dissipation at critical slopes
97      !!                     emix_iwm(z) = ( ecri_iwm / rau0 ) * EXP( -(H-z)/hcri_iwm )
98      !!                                   / ( 1. - EXP( - H/hcri_iwm ) ) * hcri_iwm
99      !!              where hcri_iwm is the characteristic length scale of the bottom
100      !!              intensification, ecri_iwm a map of available power, and H the ocean depth.
101      !!                 2. Pycnocline-intensified low-mode dissipation
102      !!                     emix_iwm(z) = ( epyc_iwm / rau0 ) * ( sqrt(rn2(z))^nn_zpyc )
103      !!                                   / SUM( sqrt(rn2(z))^nn_zpyc * e3w(z) )
104      !!              where epyc_iwm is a map of available power, and nn_zpyc
105      !!              is the chosen stratification-dependence of the internal wave
106      !!              energy dissipation.
107      !!                 3. WKB-height dependent high mode dissipation
108      !!                     emix_iwm(z) = ( ebot_iwm / rau0 ) * rn2(z) * EXP(-z_wkb(z)/hbot_iwm)
109      !!                                   / SUM( rn2(z) * EXP(-z_wkb(z)/hbot_iwm) * e3w(z) )
110      !!              where hbot_iwm is the characteristic length scale of the WKB bottom
111      !!              intensification, ebot_iwm is a map of available power, and z_wkb is the
112      !!              WKB-stretched height above bottom defined as
113      !!                    z_wkb(z) = H * SUM( sqrt(rn2(z'>=z)) * e3w(z'>=z) )
114      !!                                 / SUM( sqrt(rn2(z'))    * e3w(z')    )
115      !!
116      !!              - update the model vertical eddy viscosity and diffusivity:
117      !!                     avt  = avt  +    av_wave
118      !!                     avm  = avm  +    av_wave
119      !!
120      !!              - if namelist parameter ln_tsdiff = T, account for differential mixing:
121      !!                     avs  = avt  +    av_wave * diffusivity_ratio(Reb)
122      !!
123      !! ** Action  : - Define emix_iwm used to compute internal wave-induced mixing
124      !!              - avt, avs, avm, increased by internal wave-driven mixing   
125      !!
126      !! References :  de Lavergne et al. 2015, JPO; 2016, in prep.
127      !!----------------------------------------------------------------------
128      INTEGER                    , INTENT(in   ) ::   kt             ! ocean time step
129      REAL(wp), DIMENSION(:,:,:) , INTENT(inout) ::   p_avm          ! momentum Kz (w-points)
130      REAL(wp), DIMENSION(:,:,:) , INTENT(inout) ::   p_avt, p_avs   ! tracer   Kz (w-points)
131      !
132      INTEGER  ::   ji, jj, jk   ! dummy loop indices
133      REAL(wp) ::   zztmp        ! scalar workspace
134      REAL(wp), DIMENSION(jpi,jpj)     ::  zfact     ! Used for vertical structure
135      REAL(wp), DIMENSION(jpi,jpj)     ::  zhdep     ! Ocean depth
136      REAL(wp), DIMENSION(jpi,jpj,jpk) ::  zwkb      ! WKB-stretched height above bottom
137      REAL(wp), DIMENSION(jpi,jpj,jpk) ::  zweight   ! Weight for high mode vertical distribution
138      REAL(wp), DIMENSION(jpi,jpj,jpk) ::  znu_t     ! Molecular kinematic viscosity (T grid)
139      REAL(wp), DIMENSION(jpi,jpj,jpk) ::  znu_w     ! Molecular kinematic viscosity (W grid)
140      REAL(wp), DIMENSION(jpi,jpj,jpk) ::  zReb      ! Turbulence intensity parameter
141      !!----------------------------------------------------------------------
142      !
143      IF( ln_timing )   CALL timing_start('zdf_iwm')
144      !
145      !                      ! ----------------------------- !
146      !                      !  Internal wave-driven mixing  !  (compute zav_wave)
147      !                      ! ----------------------------- !
148      !                             
149      !                        !* Critical slope mixing: distribute energy over the time-varying ocean depth,
150      !                                                 using an exponential decay from the seafloor.
151      DO jj = 1, jpj                ! part independent of the level
152         DO ji = 1, jpi
153            zhdep(ji,jj) = gdepw_0(ji,jj,mbkt(ji,jj)+1)       ! depth of the ocean
154            zfact(ji,jj) = rau0 * (  1._wp - EXP( -zhdep(ji,jj) / hcri_iwm(ji,jj) )  )
155            IF( zfact(ji,jj) /= 0._wp )   zfact(ji,jj) = ecri_iwm(ji,jj) / zfact(ji,jj)
156         END DO
157      END DO
158
159      DO jk = 2, jpkm1              ! complete with the level-dependent part
160         emix_iwm(:,:,jk) = zfact(:,:) * (  EXP( ( gde3w_n(:,:,jk  ) - zhdep(:,:) ) / hcri_iwm(:,:) )                      &
161            &                             - EXP( ( gde3w_n(:,:,jk-1) - zhdep(:,:) ) / hcri_iwm(:,:) )  ) * wmask(:,:,jk)   &
162            &                          / ( gde3w_n(:,:,jk) - gde3w_n(:,:,jk-1) )
163
164!!gm delta(gde3w_n) = e3t_n  !!  Please verify the grid-point position w versus t-point
165!!gm it seems to me that only 1/hcri_iwm  is used ==>  compute it one for all
166
167      END DO
168
169      !                        !* Pycnocline-intensified mixing: distribute energy over the time-varying
170      !                        !* ocean depth as proportional to sqrt(rn2)^nn_zpyc
171      !                                          ! (NB: N2 is masked, so no use of wmask here)
172      SELECT CASE ( nn_zpyc )
173      !
174      CASE ( 1 )               ! Dissipation scales as N (recommended)
175         !
176         zfact(:,:) = 0._wp
177         DO jk = 2, jpkm1              ! part independent of the level
178            zfact(:,:) = zfact(:,:) + e3w_n(:,:,jk) * SQRT(  MAX( 0._wp, rn2(:,:,jk) )  ) * wmask(:,:,jk)
179         END DO
180         !
181         DO jj = 1, jpj
182            DO ji = 1, jpi
183               IF( zfact(ji,jj) /= 0 )   zfact(ji,jj) = epyc_iwm(ji,jj) / ( rau0 * zfact(ji,jj) )
184            END DO
185         END DO
186         !
187         DO jk = 2, jpkm1              ! complete with the level-dependent part
188            emix_iwm(:,:,jk) = emix_iwm(:,:,jk) + zfact(:,:) * SQRT(  MAX( 0._wp, rn2(:,:,jk) )  ) * wmask(:,:,jk)
189         END DO
190         !
191      CASE ( 2 )               ! Dissipation scales as N^2
192         !
193         zfact(:,:) = 0._wp
194         DO jk = 2, jpkm1              ! part independent of the level
195            zfact(:,:) = zfact(:,:) + e3w_n(:,:,jk) * MAX( 0._wp, rn2(:,:,jk) ) * wmask(:,:,jk)
196         END DO
197         !
198         DO jj= 1, jpj
199            DO ji = 1, jpi
200               IF( zfact(ji,jj) /= 0 )   zfact(ji,jj) = epyc_iwm(ji,jj) / ( rau0 * zfact(ji,jj) )
201            END DO
202         END DO
203         !
204         DO jk = 2, jpkm1              ! complete with the level-dependent part
205            emix_iwm(:,:,jk) = emix_iwm(:,:,jk) + zfact(:,:) * MAX( 0._wp, rn2(:,:,jk) ) * wmask(:,:,jk)
206         END DO
207         !
208      END SELECT
209
210      !                        !* WKB-height dependent mixing: distribute energy over the time-varying
211      !                        !* ocean depth as proportional to rn2 * exp(-z_wkb/rn_hbot)
212      !
213      zwkb (:,:,:) = 0._wp
214      zfact(:,:)   = 0._wp
215      DO jk = 2, jpkm1
216         zfact(:,:) = zfact(:,:) + e3w_n(:,:,jk) * SQRT(  MAX( 0._wp, rn2(:,:,jk) )  ) * wmask(:,:,jk)
217         zwkb(:,:,jk) = zfact(:,:)
218      END DO
219!!gm even better:
220!      DO jk = 2, jpkm1
221!         zwkb(:,:) = zwkb(:,:) + e3w_n(:,:,jk) * SQRT(  MAX( 0._wp, rn2(:,:,jk) )  )
222!      END DO
223!      zfact(:,:) = zwkb(:,:,jpkm1)
224!!gm or just use zwkb(k=jpk-1) instead of zfact...
225!!gm
226      !
227      DO jk = 2, jpkm1
228         DO jj = 1, jpj
229            DO ji = 1, jpi
230               IF( zfact(ji,jj) /= 0 )   zwkb(ji,jj,jk) = zhdep(ji,jj) * ( zfact(ji,jj) - zwkb(ji,jj,jk) )   &
231                  &                                     * wmask(ji,jj,jk) / zfact(ji,jj)
232            END DO
233         END DO
234      END DO
235      zwkb(:,:,1) = zhdep(:,:) * wmask(:,:,1)
236      !
237      zweight(:,:,:) = 0._wp
238      DO jk = 2, jpkm1
239         zweight(:,:,jk) = MAX( 0._wp, rn2(:,:,jk) ) * hbot_iwm(:,:) * wmask(:,:,jk)                    &
240            &   * (  EXP( -zwkb(:,:,jk) / hbot_iwm(:,:) ) - EXP( -zwkb(:,:,jk-1) / hbot_iwm(:,:) )  )
241      END DO
242      !
243      zfact(:,:) = 0._wp
244      DO jk = 2, jpkm1              ! part independent of the level
245         zfact(:,:) = zfact(:,:) + zweight(:,:,jk)
246      END DO
247      !
248      DO jj = 1, jpj
249         DO ji = 1, jpi
250            IF( zfact(ji,jj) /= 0 )   zfact(ji,jj) = ebot_iwm(ji,jj) / ( rau0 * zfact(ji,jj) )
251         END DO
252      END DO
253      !
254      DO jk = 2, jpkm1              ! complete with the level-dependent part
255         emix_iwm(:,:,jk) = emix_iwm(:,:,jk) + zweight(:,:,jk) * zfact(:,:) * wmask(:,:,jk)   &
256            &                                / ( gde3w_n(:,:,jk) - gde3w_n(:,:,jk-1) )
257!!gm  use of e3t_n just above?
258      END DO
259      !
260!!gm  this is to be replaced by just a constant value znu=1.e-6 m2/s
261      ! Calculate molecular kinematic viscosity
262      znu_t(:,:,:) = 1.e-4_wp * (  17.91_wp - 0.53810_wp * tsn(:,:,:,jp_tem) + 0.00694_wp * tsn(:,:,:,jp_tem) * tsn(:,:,:,jp_tem)  &
263         &                                  + 0.02305_wp * tsn(:,:,:,jp_sal)  ) * tmask(:,:,:) * r1_rau0
264      DO jk = 2, jpkm1
265         znu_w(:,:,jk) = 0.5_wp * ( znu_t(:,:,jk-1) + znu_t(:,:,jk) ) * wmask(:,:,jk)
266      END DO
267!!gm end
268      !
269      ! Calculate turbulence intensity parameter Reb
270      DO jk = 2, jpkm1
271         zReb(:,:,jk) = emix_iwm(:,:,jk) / MAX( 1.e-20_wp, znu_w(:,:,jk) * rn2(:,:,jk) )
272      END DO
273      !
274      ! Define internal wave-induced diffusivity
275      DO jk = 2, jpkm1
276         zav_wave(:,:,jk) = znu_w(:,:,jk) * zReb(:,:,jk) * r1_6   ! This corresponds to a constant mixing efficiency of 1/6
277      END DO
278      !
279      IF( ln_mevar ) THEN              ! Variable mixing efficiency case : modify zav_wave in the
280         DO jk = 2, jpkm1              ! energetic (Reb > 480) and buoyancy-controlled (Reb <10.224 ) regimes
281            DO jj = 1, jpj
282               DO ji = 1, jpi
283                  IF( zReb(ji,jj,jk) > 480.00_wp ) THEN
284                     zav_wave(ji,jj,jk) = 3.6515_wp * znu_w(ji,jj,jk) * SQRT( zReb(ji,jj,jk) )
285                  ELSEIF( zReb(ji,jj,jk) < 10.224_wp ) THEN
286                     zav_wave(ji,jj,jk) = 0.052125_wp * znu_w(ji,jj,jk) * zReb(ji,jj,jk) * SQRT( zReb(ji,jj,jk) )
287                  ENDIF
288               END DO
289            END DO
290         END DO
291      ENDIF
292      !
293      DO jk = 2, jpkm1                 ! Bound diffusivity by molecular value and 100 cm2/s
294         zav_wave(:,:,jk) = MIN(  MAX( 1.4e-7_wp, zav_wave(:,:,jk) ), 1.e-2_wp  ) * wmask(:,:,jk)
295      END DO
296      !
297      IF( kt == nit000 ) THEN        !* Control print at first time-step: diagnose the energy consumed by zav_wave
298         zztmp = 0._wp
299!!gm used of glosum 3D....
300         DO jk = 2, jpkm1
301            DO jj = 1, jpj
302               DO ji = 1, jpi
303                  zztmp = zztmp + e3w_n(ji,jj,jk) * e1e2t(ji,jj)   &
304                     &          * MAX( 0._wp, rn2(ji,jj,jk) ) * zav_wave(ji,jj,jk) * wmask(ji,jj,jk) * tmask_i(ji,jj)
305               END DO
306            END DO
307         END DO
308         IF( lk_mpp )   CALL mpp_sum( zztmp )
309         zztmp = rau0 * zztmp ! Global integral of rauo * Kz * N^2 = power contributing to mixing
310         !
311         IF(lwp) THEN
312            WRITE(numout,*)
313            WRITE(numout,*) 'zdf_iwm : Internal wave-driven mixing (iwm)'
314            WRITE(numout,*) '~~~~~~~ '
315            WRITE(numout,*)
316            WRITE(numout,*) '      Total power consumption by av_wave =  ', zztmp * 1.e-12_wp, 'TW'
317         ENDIF
318      ENDIF
319
320      !                          ! ----------------------- !
321      !                          !   Update  mixing coefs  !                         
322      !                          ! ----------------------- !
323      !     
324      IF( ln_tsdiff ) THEN          !* Option for differential mixing of salinity and temperature
325         DO jk = 2, jpkm1              ! Calculate S/T diffusivity ratio as a function of Reb
326            DO jj = 1, jpj
327               DO ji = 1, jpi
328                  zav_ratio(ji,jj,jk) = ( 0.505_wp + 0.495_wp *                                                                  &
329                      &   TANH(    0.92_wp * (   LOG10(  MAX( 1.e-20_wp, zReb(ji,jj,jk) * 5._wp * r1_6 )  ) - 0.60_wp   )    )   &
330                      &                 ) * wmask(ji,jj,jk)
331               END DO
332            END DO
333         END DO
334         CALL iom_put( "av_ratio", zav_ratio )
335         DO jk = 2, jpkm1           !* update momentum & tracer diffusivity with wave-driven mixing
336            p_avs(:,:,jk) = p_avs(:,:,jk) + zav_wave(:,:,jk) * zav_ratio(:,:,jk)
337            p_avt(:,:,jk) = p_avt(:,:,jk) + zav_wave(:,:,jk)
338            p_avm(:,:,jk) = p_avm(:,:,jk) + zav_wave(:,:,jk)
339         END DO
340         !
341      ELSE                          !* update momentum & tracer diffusivity with wave-driven mixing
342         DO jk = 2, jpkm1
343            p_avs(:,:,jk) = p_avs(:,:,jk) + zav_wave(:,:,jk)
344            p_avt(:,:,jk) = p_avt(:,:,jk) + zav_wave(:,:,jk)
345            p_avm(:,:,jk) = p_avm(:,:,jk) + zav_wave(:,:,jk)
346         END DO
347      ENDIF
348
349      !                             !* output internal wave-driven mixing coefficient
350      CALL iom_put( "av_wave", zav_wave )
351                                    !* output useful diagnostics: N^2, Kz * N^2 (bflx_iwm),
352                                    !  vertical integral of rau0 * Kz * N^2 (pcmap_iwm), energy density (emix_iwm)
353      IF( iom_use("bflx_iwm") .OR. iom_use("pcmap_iwm") ) THEN
354         bflx_iwm(:,:,:) = MAX( 0._wp, rn2(:,:,:) ) * zav_wave(:,:,:)
355         pcmap_iwm(:,:) = 0._wp
356         DO jk = 2, jpkm1
357            pcmap_iwm(:,:) = pcmap_iwm(:,:) + e3w_n(:,:,jk) * bflx_iwm(:,:,jk) * wmask(:,:,jk)
358         END DO
359         pcmap_iwm(:,:) = rau0 * pcmap_iwm(:,:)
360         CALL iom_put( "bflx_iwm", bflx_iwm )
361         CALL iom_put( "pcmap_iwm", pcmap_iwm )
362      ENDIF
363      CALL iom_put( "bn2", rn2 )
364      CALL iom_put( "emix_iwm", emix_iwm )
365     
366      IF(ln_ctl)   CALL prt_ctl(tab3d_1=zav_wave , clinfo1=' iwm - av_wave: ', tab3d_2=avt, clinfo2=' avt: ', ovlap=1, kdim=jpk)
367      !
368      IF( ln_timing )   CALL timing_stop('zdf_iwm')
369      !
370   END SUBROUTINE zdf_iwm
371
372
373   SUBROUTINE zdf_iwm_init
374      !!----------------------------------------------------------------------
375      !!                  ***  ROUTINE zdf_iwm_init  ***
376      !!                     
377      !! ** Purpose :   Initialization of the wave-driven vertical mixing, reading
378      !!              of input power maps and decay length scales in netcdf files.
379      !!
380      !! ** Method  : - Read the namzdf_iwm namelist and check the parameters
381      !!
382      !!              - Read the input data in NetCDF files :
383      !!              power available from high-mode wave breaking (mixing_power_bot.nc)
384      !!              power available from pycnocline-intensified wave-breaking (mixing_power_pyc.nc)
385      !!              power available from critical slope wave-breaking (mixing_power_cri.nc)
386      !!              WKB decay scale for high-mode wave-breaking (decay_scale_bot.nc)
387      !!              decay scale for critical slope wave-breaking (decay_scale_cri.nc)
388      !!
389      !! ** input   : - Namlist namzdf_iwm
390      !!              - NetCDF files : mixing_power_bot.nc, mixing_power_pyc.nc, mixing_power_cri.nc,
391      !!              decay_scale_bot.nc decay_scale_cri.nc
392      !!
393      !! ** Action  : - Increase by 1 the nstop flag is setting problem encounter
394      !!              - Define ebot_iwm, epyc_iwm, ecri_iwm, hbot_iwm, hcri_iwm
395      !!
396      !! References : de Lavergne et al. JPO, 2015 ; de Lavergne PhD 2016
397      !!              de Lavergne et al. in prep., 2017
398      !!----------------------------------------------------------------------
399      INTEGER  ::   ji, jj, jk   ! dummy loop indices
400      INTEGER  ::   inum         ! local integer
401      INTEGER  ::   ios
402      REAL(wp) ::   zbot, zpyc, zcri   ! local scalars
403      !!
404      NAMELIST/namzdf_iwm_new/ nn_zpyc, ln_mevar, ln_tsdiff
405      !!----------------------------------------------------------------------
406      !
407      IF( ln_timing )   CALL timing_start('zdf_iwm_init')
408      !
409      REWIND( numnam_ref )              ! Namelist namzdf_iwm in reference namelist : Wave-driven mixing
410      READ  ( numnam_ref, namzdf_iwm_new, IOSTAT = ios, ERR = 901)
411901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namzdf_iwm in reference namelist', lwp )
412      !
413      REWIND( numnam_cfg )              ! Namelist namzdf_iwm in configuration namelist : Wave-driven mixing
414      READ  ( numnam_cfg, namzdf_iwm_new, IOSTAT = ios, ERR = 902 )
415902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namzdf_iwm in configuration namelist', lwp )
416      IF(lwm) WRITE ( numond, namzdf_iwm_new )
417      !
418      IF(lwp) THEN                  ! Control print
419         WRITE(numout,*)
420         WRITE(numout,*) 'zdf_iwm_init : internal wave-driven mixing'
421         WRITE(numout,*) '~~~~~~~~~~~~'
422         WRITE(numout,*) '   Namelist namzdf_iwm_new : set wave-driven mixing parameters'
423         WRITE(numout,*) '      Pycnocline-intensified diss. scales as N (=1) or N^2 (=2) = ', nn_zpyc
424         WRITE(numout,*) '      Variable (T) or constant (F) mixing efficiency            = ', ln_mevar
425         WRITE(numout,*) '      Differential internal wave-driven mixing (T) or not (F)   = ', ln_tsdiff
426      ENDIF
427     
428      ! The new wave-driven mixing parameterization elevates avt and avm in the interior, and
429      ! ensures that avt remains larger than its molecular value (=1.4e-7). Therefore, avtb should
430      ! be set here to a very small value, and avmb to its (uniform) molecular value (=1.4e-6).
431      avmb(:) = 1.4e-6_wp        ! viscous molecular value
432      avtb(:) = 1.e-10_wp        ! very small diffusive minimum (background avt is specified in zdf_iwm)   
433      avtb_2d(:,:) = 1.e0_wp     ! uniform
434      IF(lwp) THEN                  ! Control print
435         WRITE(numout,*)
436         WRITE(numout,*) '   Force the background value applied to avm & avt in TKE to be everywhere ',   &
437            &               'the viscous molecular value & a very small diffusive value, resp.'
438      ENDIF
439           
440      !                             ! allocate iwm arrays
441      IF( zdf_iwm_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'zdf_iwm_init : unable to allocate iwm arrays' )
442      !
443      !                             ! read necessary fields
444      CALL iom_open('mixing_power_bot',inum)       ! energy flux for high-mode wave breaking [W/m2]
445      CALL iom_get  (inum, jpdom_data, 'field', ebot_iwm, 1 ) 
446      CALL iom_close(inum)
447      !
448      CALL iom_open('mixing_power_pyc',inum)       ! energy flux for pynocline-intensified wave breaking [W/m2]
449      CALL iom_get  (inum, jpdom_data, 'field', epyc_iwm, 1 )
450      CALL iom_close(inum)
451      !
452      CALL iom_open('mixing_power_cri',inum)       ! energy flux for critical slope wave breaking [W/m2]
453      CALL iom_get  (inum, jpdom_data, 'field', ecri_iwm, 1 )
454      CALL iom_close(inum)
455      !
456      CALL iom_open('decay_scale_bot',inum)        ! spatially variable decay scale for high-mode wave breaking [m]
457      CALL iom_get  (inum, jpdom_data, 'field', hbot_iwm, 1 )
458      CALL iom_close(inum)
459      !
460      CALL iom_open('decay_scale_cri',inum)        ! spatially variable decay scale for critical slope wave breaking [m]
461      CALL iom_get  (inum, jpdom_data, 'field', hcri_iwm, 1 )
462      CALL iom_close(inum)
463
464      ebot_iwm(:,:) = ebot_iwm(:,:) * ssmask(:,:)
465      epyc_iwm(:,:) = epyc_iwm(:,:) * ssmask(:,:)
466      ecri_iwm(:,:) = ecri_iwm(:,:) * ssmask(:,:)
467
468      ! Set once for all to zero the first and last vertical levels of appropriate variables
469      emix_iwm (:,:, 1 ) = 0._wp
470      emix_iwm (:,:,jpk) = 0._wp
471      zav_ratio(:,:, 1 ) = 0._wp
472      zav_ratio(:,:,jpk) = 0._wp
473      zav_wave (:,:, 1 ) = 0._wp
474      zav_wave (:,:,jpk) = 0._wp
475
476      zbot = glob_sum( e1e2t(:,:) * ebot_iwm(:,:) )
477      zpyc = glob_sum( e1e2t(:,:) * epyc_iwm(:,:) )
478      zcri = glob_sum( e1e2t(:,:) * ecri_iwm(:,:) )
479      IF(lwp) THEN
480         WRITE(numout,*) '      High-mode wave-breaking energy:             ', zbot * 1.e-12_wp, 'TW'
481         WRITE(numout,*) '      Pycnocline-intensifed wave-breaking energy: ', zpyc * 1.e-12_wp, 'TW'
482         WRITE(numout,*) '      Critical slope wave-breaking energy:        ', zcri * 1.e-12_wp, 'TW'
483      ENDIF
484      !
485      IF( ln_timing )   CALL timing_stop('zdf_iwm_init')
486      !
487   END SUBROUTINE zdf_iwm_init
488
489   !!======================================================================
490END MODULE zdfiwm
Note: See TracBrowser for help on using the repository browser.