New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zprod.F90 in branches/2016/dev_r7012_ROBUST5_CNRS/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z – NEMO

source: branches/2016/dev_r7012_ROBUST5_CNRS/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z/p4zprod.F90 @ 7041

Last change on this file since 7041 was 7041, checked in by cetlod, 8 years ago

ROBUST5_CNRS : implementation of part I of new TOP interface - 1st step -, see ticket #1782
File size: 29.2 KB
Line 
1MODULE p4zprod
2   !!======================================================================
3   !!                         ***  MODULE p4zprod  ***
4   !! TOP :  Growth Rate of the two phytoplanktons groups
5   !!======================================================================
6   !! History :   1.0  !  2004     (O. Aumont) Original code
7   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8   !!             3.4  !  2011-05  (O. Aumont, C. Ethe) New parameterization of light limitation
9   !!----------------------------------------------------------------------
10#if defined key_pisces
11   !!----------------------------------------------------------------------
12   !!   'key_pisces'                                       PISCES bio-model
13   !!----------------------------------------------------------------------
14   !!   p4z_prod       :   Compute the growth Rate of the two phytoplanktons groups
15   !!   p4z_prod_init  :   Initialization of the parameters for growth
16   !!   p4z_prod_alloc :   Allocate variables for growth
17   !!----------------------------------------------------------------------
18   USE oce_trc         !  shared variables between ocean and passive tracers
19   USE trc             !  passive tracers common variables
20   USE sms_pisces      !  PISCES Source Minus Sink variables
21   USE p4zopt          !  optical model
22   USE p4zlim          !  Co-limitations of differents nutrients
23   USE prtctl_trc      !  print control for debugging
24   USE iom             !  I/O manager
25
26   IMPLICIT NONE
27   PRIVATE
28
29   PUBLIC   p4z_prod         ! called in p4zbio.F90
30   PUBLIC   p4z_prod_init    ! called in trcsms_pisces.F90
31   PUBLIC   p4z_prod_alloc
32
33   !! * Shared module variables
34   LOGICAL , PUBLIC ::  ln_newprod      !:
35   REAL(wp), PUBLIC ::  pislope         !:
36   REAL(wp), PUBLIC ::  pislope2        !:
37   REAL(wp), PUBLIC ::  xadap           !:
38   REAL(wp), PUBLIC ::  excret          !:
39   REAL(wp), PUBLIC ::  excret2         !:
40   REAL(wp), PUBLIC ::  bresp           !:
41   REAL(wp), PUBLIC ::  chlcnm          !:
42   REAL(wp), PUBLIC ::  chlcdm          !:
43   REAL(wp), PUBLIC ::  chlcmin         !:
44   REAL(wp), PUBLIC ::  fecnm           !:
45   REAL(wp), PUBLIC ::  fecdm           !:
46   REAL(wp), PUBLIC ::  grosip          !:
47
48   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   prmax    !: optimal production = f(temperature)
49   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   quotan   !: proxy of N quota in Nanophyto
50   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   quotad   !: proxy of N quota in diatomee
51   
52   REAL(wp) :: r1_rday                !: 1 / rday
53   REAL(wp) :: texcret                !: 1 - excret
54   REAL(wp) :: texcret2               !: 1 - excret2       
55
56   !!----------------------------------------------------------------------
57   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
58   !! $Id: p4zprod.F90 3160 2011-11-20 14:27:18Z cetlod $
59   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
60   !!----------------------------------------------------------------------
61CONTAINS
62
63   SUBROUTINE p4z_prod( kt , knt )
64      !!---------------------------------------------------------------------
65      !!                     ***  ROUTINE p4z_prod  ***
66      !!
67      !! ** Purpose :   Compute the phytoplankton production depending on
68      !!              light, temperature and nutrient availability
69      !!
70      !! ** Method  : - ???
71      !!---------------------------------------------------------------------
72      !
73      INTEGER, INTENT(in) :: kt, knt
74      !
75      INTEGER  ::   ji, jj, jk
76      REAL(wp) ::   zsilfac, znanotot, zdiattot, zconctemp, zconctemp2
77      REAL(wp) ::   zratio, zmax, zsilim, ztn, zadap
78      REAL(wp) ::   zlim, zsilfac2, zsiborn, zprod, zproreg, zproreg2
79      REAL(wp) ::   zmxltst, zmxlday, zmaxday
80      REAL(wp) ::   zpislopen  , zpislope2n
81      REAL(wp) ::   zrum, zcodel, zargu, zval
82      REAL(wp) ::   zfact
83      CHARACTER (len=25) :: charout
84      REAL(wp), POINTER, DIMENSION(:,:  ) :: zmixnano, zmixdiat, zstrn, zw2d
85      REAL(wp), POINTER, DIMENSION(:,:,:) :: zpislopead, zpislopead2, zprdia, zprbio, zprdch, zprnch, zysopt, zw3d   
86      REAL(wp), POINTER, DIMENSION(:,:,:) :: zprorca, zprorcad, zprofed, zprofen, zprochln, zprochld, zpronew, zpronewd
87      !!---------------------------------------------------------------------
88      !
89      IF( nn_timing == 1 )  CALL timing_start('p4z_prod')
90      !
91      !  Allocate temporary workspace
92      CALL wrk_alloc( jpi, jpj,      zmixnano, zmixdiat, zstrn                                                  )
93      CALL wrk_alloc( jpi, jpj, jpk, zpislopead, zpislopead2, zprdia, zprbio, zprdch, zprnch, zysopt            ) 
94      CALL wrk_alloc( jpi, jpj, jpk, zprorca, zprorcad, zprofed, zprofen, zprochln, zprochld, zpronew, zpronewd )
95      !
96      zprorca (:,:,:) = 0._wp
97      zprorcad(:,:,:) = 0._wp
98      zprofed (:,:,:) = 0._wp
99      zprofen (:,:,:) = 0._wp
100      zprochln(:,:,:) = 0._wp
101      zprochld(:,:,:) = 0._wp
102      zpronew (:,:,:) = 0._wp
103      zpronewd(:,:,:) = 0._wp
104      zprdia  (:,:,:) = 0._wp
105      zprbio  (:,:,:) = 0._wp
106      zprdch  (:,:,:) = 0._wp
107      zprnch  (:,:,:) = 0._wp
108      zysopt  (:,:,:) = 0._wp
109
110      ! Computation of the optimal production
111      prmax(:,:,:) = 0.6_wp * r1_rday * tgfunc(:,:,:) 
112
113      ! compute the day length depending on latitude and the day
114      zrum = REAL( nday_year - 80, wp ) / REAL( nyear_len(1), wp )
115      zcodel = ASIN(  SIN( zrum * rpi * 2._wp ) * SIN( rad * 23.5_wp )  )
116
117      ! day length in hours
118      zstrn(:,:) = 0.
119      DO jj = 1, jpj
120         DO ji = 1, jpi
121            zargu = TAN( zcodel ) * TAN( gphit(ji,jj) * rad )
122            zargu = MAX( -1., MIN(  1., zargu ) )
123            zstrn(ji,jj) = MAX( 0.0, 24. - 2. * ACOS( zargu ) / rad / 15. )
124         END DO
125      END DO
126
127      ! Impact of the day duration on phytoplankton growth
128      DO jk = 1, jpkm1
129         DO jj = 1 ,jpj
130            DO ji = 1, jpi
131               IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
132                  zval = MAX( 1., zstrn(ji,jj) )
133                  zval = 1.5 * zval / ( 12. + zval )
134                  zprbio(ji,jj,jk) = prmax(ji,jj,jk) * zval * ( 1. - fr_i(ji,jj) )
135                  zprdia(ji,jj,jk) = zprbio(ji,jj,jk)
136               ENDIF
137            END DO
138         END DO
139      END DO
140
141      ! Maximum light intensity
142      WHERE( zstrn(:,:) < 1.e0 ) zstrn(:,:) = 24.
143      zstrn(:,:) = 24. / zstrn(:,:)
144
145      IF( ln_newprod ) THEN
146         DO jk = 1, jpkm1
147            DO jj = 1, jpj
148               DO ji = 1, jpi
149                  ! Computation of the P-I slope for nanos and diatoms
150                  IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
151                      ztn         = MAX( 0., tsn(ji,jj,jk,jp_tem) - 15. )
152                      zadap       = xadap * ztn / ( 2.+ ztn )
153                      zconctemp   = MAX( 0.e0 , trb(ji,jj,jk,jpdia) - xsizedia )
154                      zconctemp2  = trb(ji,jj,jk,jpdia) - zconctemp
155                      znanotot    = enano(ji,jj,jk) * zstrn(ji,jj)
156                      zdiattot    = ediat(ji,jj,jk) * zstrn(ji,jj)
157                      !
158                      zpislopead (ji,jj,jk) = pislope * ( 1.+ zadap  * EXP( -znanotot ) )  &
159                         &                   * trb(ji,jj,jk,jpnch) /( trb(ji,jj,jk,jpphy) * 12. + rtrn)
160                      !
161                      zpislopead2(ji,jj,jk) = (pislope * zconctemp2 + pislope2 * zconctemp) / ( trb(ji,jj,jk,jpdia) + rtrn )   &
162                         &                   * trb(ji,jj,jk,jpdch) /( trb(ji,jj,jk,jpdia) * 12. + rtrn)
163
164                      ! Computation of production function for Carbon
165                      !  ---------------------------------------------
166                      zpislopen  = zpislopead (ji,jj,jk) / ( ( r1_rday + bresp * r1_rday ) * rday + rtrn)
167                      zpislope2n = zpislopead2(ji,jj,jk) / ( ( r1_rday + bresp * r1_rday ) * rday + rtrn)
168                      zprbio(ji,jj,jk) = zprbio(ji,jj,jk) * ( 1.- EXP( -zpislopen  * znanotot )  )
169                      zprdia(ji,jj,jk) = zprdia(ji,jj,jk) * ( 1.- EXP( -zpislope2n * zdiattot )  )
170
171                      !  Computation of production function for Chlorophyll
172                      !--------------------------------------------------
173                      zmaxday  = 1._wp / ( prmax(ji,jj,jk) * rday + rtrn )
174                      zprnch(ji,jj,jk) = prmax(ji,jj,jk) * ( 1.- EXP( -zpislopead (ji,jj,jk) * zmaxday * znanotot ) )
175                      zprdch(ji,jj,jk) = prmax(ji,jj,jk) * ( 1.- EXP( -zpislopead2(ji,jj,jk) * zmaxday * zdiattot ) )
176                  ENDIF
177               END DO
178            END DO
179         END DO
180      ELSE
181         DO jk = 1, jpkm1
182            DO jj = 1, jpj
183               DO ji = 1, jpi
184
185                  ! Computation of the P-I slope for nanos and diatoms
186                  IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
187                      ztn         = MAX( 0., tsn(ji,jj,jk,jp_tem) - 15. )
188                      zadap       = ztn / ( 2.+ ztn )
189                      zconctemp   = MAX( 0.e0 , trb(ji,jj,jk,jpdia) - xsizedia )
190                      zconctemp2  = trb(ji,jj,jk,jpdia) - zconctemp
191                      znanotot    = enano(ji,jj,jk) * zstrn(ji,jj)
192                      zdiattot    = ediat(ji,jj,jk) * zstrn(ji,jj)
193                      !
194                      zpislopead (ji,jj,jk) = pislope  * ( 1.+ zadap  * EXP( -znanotot ) )
195                      zpislopead2(ji,jj,jk) = (pislope * zconctemp2 + pislope2 * zconctemp)  / ( trb(ji,jj,jk,jpdia) + rtrn )
196
197                      zpislopen =  zpislopead(ji,jj,jk) * trb(ji,jj,jk,jpnch)                &
198                        &          / ( trb(ji,jj,jk,jpphy) * 12.                  + rtrn )   &
199                        &          / ( prmax(ji,jj,jk) * rday * xlimphy(ji,jj,jk) + rtrn )
200
201                      zpislope2n = zpislopead2(ji,jj,jk) * trb(ji,jj,jk,jpdch)                &
202                        &          / ( trb(ji,jj,jk,jpdia) * 12.                  + rtrn )   &
203                        &          / ( prmax(ji,jj,jk) * rday * xlimdia(ji,jj,jk) + rtrn )
204
205                      ! Computation of production function for Carbon
206                      !  ---------------------------------------------
207                      zprbio(ji,jj,jk) = zprbio(ji,jj,jk) * ( 1.- EXP( -zpislopen  * znanotot ) )
208                      zprdia(ji,jj,jk) = zprdia(ji,jj,jk) * ( 1.- EXP( -zpislope2n * zdiattot ) )
209
210                      !  Computation of production function for Chlorophyll
211                      !--------------------------------------------------
212                      zprnch(ji,jj,jk) = prmax(ji,jj,jk) * ( 1.- EXP( -zpislopen  * enano(ji,jj,jk) ) )
213                      zprdch(ji,jj,jk) = prmax(ji,jj,jk) * ( 1.- EXP( -zpislope2n * ediat(ji,jj,jk) ) )
214                  ENDIF
215               END DO
216            END DO
217         END DO
218      ENDIF
219
220
221      !  Computation of a proxy of the N/C ratio
222      !  ---------------------------------------
223      DO jk = 1, jpkm1
224         DO jj = 1, jpj
225            DO ji = 1, jpi
226                zval = MIN( xnanopo4(ji,jj,jk), ( xnanonh4(ji,jj,jk) + xnanono3(ji,jj,jk) ) )   &
227                &      * prmax(ji,jj,jk) / ( zprbio(ji,jj,jk) + rtrn )
228                quotan(ji,jj,jk) = MIN( 1., 0.2 + 0.8 * zval )
229                zval = MIN( xdiatpo4(ji,jj,jk), ( xdiatnh4(ji,jj,jk) + xdiatno3(ji,jj,jk) ) )   &
230                &      * prmax(ji,jj,jk) / ( zprdia(ji,jj,jk) + rtrn )
231                quotad(ji,jj,jk) = MIN( 1., 0.2 + 0.8 * zval )
232            END DO
233         END DO
234      END DO
235
236
237      DO jk = 1, jpkm1
238         DO jj = 1, jpj
239            DO ji = 1, jpi
240
241                IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
242                   !    Si/C of diatoms
243                   !    ------------------------
244                   !    Si/C increases with iron stress and silicate availability
245                   !    Si/C is arbitrariliy increased for very high Si concentrations
246                   !    to mimic the very high ratios observed in the Southern Ocean (silpot2)
247                  zlim  = trb(ji,jj,jk,jpsil) / ( trb(ji,jj,jk,jpsil) + xksi1 )
248                  zsilim = MIN( zprdia(ji,jj,jk) / ( prmax(ji,jj,jk) + rtrn ), xlimsi(ji,jj,jk) )
249                  zsilfac = 4.4 * EXP( -4.23 * zsilim ) * MAX( 0.e0, MIN( 1., 2.2 * ( zlim - 0.5 ) )  ) + 1.e0
250                  zsiborn = trb(ji,jj,jk,jpsil) * trb(ji,jj,jk,jpsil) * trb(ji,jj,jk,jpsil)
251                  IF (gphit(ji,jj) < -30 ) THEN
252                    zsilfac2 = 1. + 2. * zsiborn / ( zsiborn + xksi2**3 )
253                  ELSE
254                    zsilfac2 = 1. +      zsiborn / ( zsiborn + xksi2**3 )
255                  ENDIF
256                  zysopt(ji,jj,jk) = grosip * zlim * zsilfac * zsilfac2
257              ENDIF
258            END DO
259         END DO
260      END DO
261
262      !  Computation of the limitation term due to a mixed layer deeper than the euphotic depth
263      DO jj = 1, jpj
264         DO ji = 1, jpi
265            zmxltst = MAX( 0.e0, hmld(ji,jj) - heup(ji,jj) )
266            zmxlday = zmxltst * zmxltst * r1_rday
267            zmixnano(ji,jj) = 1. - zmxlday / ( 2. + zmxlday )
268            zmixdiat(ji,jj) = 1. - zmxlday / ( 4. + zmxlday )
269         END DO
270      END DO
271 
272      !  Mixed-layer effect on production                                                                               
273      DO jk = 1, jpkm1
274         DO jj = 1, jpj
275            DO ji = 1, jpi
276               IF( gdepw_n(ji,jj,jk+1) <= hmld(ji,jj) ) THEN
277                  zprbio(ji,jj,jk) = zprbio(ji,jj,jk) * zmixnano(ji,jj)
278                  zprdia(ji,jj,jk) = zprdia(ji,jj,jk) * zmixdiat(ji,jj)
279               ENDIF
280               zprbio(ji,jj,jk) = zprbio(ji,jj,jk) * ( 1. - fr_i(ji,jj) )
281               zprdia(ji,jj,jk) = zprdia(ji,jj,jk) * ( 1. - fr_i(ji,jj) )
282            END DO
283         END DO
284      END DO
285
286      ! Computation of the various production terms
287      DO jk = 1, jpkm1
288         DO jj = 1, jpj
289            DO ji = 1, jpi
290               IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
291                  !  production terms for nanophyto.
292                  zprorca(ji,jj,jk) = zprbio(ji,jj,jk)  * xlimphy(ji,jj,jk) * trb(ji,jj,jk,jpphy) * rfact2
293                  zpronew(ji,jj,jk) = zprorca(ji,jj,jk) * xnanono3(ji,jj,jk) / ( xnanono3(ji,jj,jk) + xnanonh4(ji,jj,jk) + rtrn )
294                  !
295                  zratio = trb(ji,jj,jk,jpnfe) / ( trb(ji,jj,jk,jpphy) + rtrn )
296                  zratio = zratio / fecnm 
297                  zmax   = MAX( 0., ( 1. - zratio ) / ABS( 1.05 - zratio ) ) 
298                  zprofen(ji,jj,jk) = fecnm * prmax(ji,jj,jk)  &
299                  &             * ( 4. - 4.5 * xlimnfe(ji,jj,jk) / ( xlimnfe(ji,jj,jk) + 0.5 ) )    &
300                  &             * biron(ji,jj,jk) / ( biron(ji,jj,jk) + concnfe(ji,jj,jk) )  &
301                  &             * zmax * trb(ji,jj,jk,jpphy) * rfact2
302                  !  production terms for diatomees
303                  zprorcad(ji,jj,jk) = zprdia(ji,jj,jk) * xlimdia(ji,jj,jk) * trb(ji,jj,jk,jpdia) * rfact2
304                  zpronewd(ji,jj,jk) = zprorcad(ji,jj,jk) * xdiatno3(ji,jj,jk) / ( xdiatno3(ji,jj,jk) + xdiatnh4(ji,jj,jk) + rtrn )
305                  !
306                  zratio = trb(ji,jj,jk,jpdfe) / ( trb(ji,jj,jk,jpdia) + rtrn )
307                  zratio = zratio / fecdm 
308                  zmax   = MAX( 0., ( 1. - zratio ) / ABS( 1.05 - zratio ) ) 
309                  zprofed(ji,jj,jk) = fecdm * prmax(ji,jj,jk)  &
310                  &             * ( 4. - 4.5 * xlimdfe(ji,jj,jk) / ( xlimdfe(ji,jj,jk) + 0.5 ) )    &
311                  &             * biron(ji,jj,jk) / ( biron(ji,jj,jk) + concdfe(ji,jj,jk) )  &
312                  &             * zmax * trb(ji,jj,jk,jpdia) * rfact2
313               ENDIF
314            END DO
315         END DO
316      END DO
317
318      DO jk = 1, jpkm1
319         DO jj = 1, jpj
320            DO ji = 1, jpi
321               IF( gdepw_n(ji,jj,jk+1) <= hmld(ji,jj) ) THEN
322                  zprnch(ji,jj,jk) = zprnch(ji,jj,jk) * zmixnano(ji,jj)
323                  zprdch(ji,jj,jk) = zprdch(ji,jj,jk) * zmixdiat(ji,jj)
324               ENDIF
325               IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
326                  !  production terms for nanophyto. ( chlorophyll )
327                  znanotot = enano(ji,jj,jk) * zstrn(ji,jj)
328                  zprod    = rday * zprorca(ji,jj,jk) * zprnch(ji,jj,jk) * xlimphy(ji,jj,jk)
329                  zprochln(ji,jj,jk) = chlcmin * 12. * zprorca (ji,jj,jk)
330                  zprochln(ji,jj,jk) = zprochln(ji,jj,jk) + (chlcnm-chlcmin) * 12. * zprod / &
331                                     & (  zpislopead(ji,jj,jk) * znanotot +rtrn)
332                  !  production terms for diatomees ( chlorophyll )
333                  zdiattot = ediat(ji,jj,jk) * zstrn(ji,jj)
334                  zprod = rday * zprorcad(ji,jj,jk) * zprdch(ji,jj,jk) * xlimdia(ji,jj,jk)
335                  zprochld(ji,jj,jk) = chlcmin * 12. * zprorcad(ji,jj,jk)
336                  zprochld(ji,jj,jk) = zprochld(ji,jj,jk) + (chlcdm-chlcmin) * 12. * zprod / &
337                                     & ( zpislopead2(ji,jj,jk) * zdiattot +rtrn )
338               ENDIF
339            END DO
340         END DO
341      END DO
342
343      !   Update the arrays TRA which contain the biological sources and sinks
344      DO jk = 1, jpkm1
345         DO jj = 1, jpj
346           DO ji =1 ,jpi
347              zproreg  = zprorca(ji,jj,jk) - zpronew(ji,jj,jk)
348              zproreg2 = zprorcad(ji,jj,jk) - zpronewd(ji,jj,jk)
349              tra(ji,jj,jk,jppo4) = tra(ji,jj,jk,jppo4) - zprorca(ji,jj,jk) - zprorcad(ji,jj,jk)
350              tra(ji,jj,jk,jpno3) = tra(ji,jj,jk,jpno3) - zpronew(ji,jj,jk) - zpronewd(ji,jj,jk)
351              tra(ji,jj,jk,jpnh4) = tra(ji,jj,jk,jpnh4) - zproreg - zproreg2
352              tra(ji,jj,jk,jpphy) = tra(ji,jj,jk,jpphy) + zprorca(ji,jj,jk) * texcret
353              tra(ji,jj,jk,jpnch) = tra(ji,jj,jk,jpnch) + zprochln(ji,jj,jk) * texcret
354              tra(ji,jj,jk,jpnfe) = tra(ji,jj,jk,jpnfe) + zprofen(ji,jj,jk) * texcret
355              tra(ji,jj,jk,jpdia) = tra(ji,jj,jk,jpdia) + zprorcad(ji,jj,jk) * texcret2
356              tra(ji,jj,jk,jpdch) = tra(ji,jj,jk,jpdch) + zprochld(ji,jj,jk) * texcret2
357              tra(ji,jj,jk,jpdfe) = tra(ji,jj,jk,jpdfe) + zprofed(ji,jj,jk) * texcret2
358              tra(ji,jj,jk,jpdsi) = tra(ji,jj,jk,jpdsi) + zprorcad(ji,jj,jk) * zysopt(ji,jj,jk) * texcret2
359              tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) + excret2 * zprorcad(ji,jj,jk) + excret * zprorca(ji,jj,jk)
360              tra(ji,jj,jk,jpoxy) = tra(ji,jj,jk,jpoxy) + o2ut * ( zproreg + zproreg2) &
361                 &                + ( o2ut + o2nit ) * ( zpronew(ji,jj,jk) + zpronewd(ji,jj,jk) )
362              tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) - texcret * zprofen(ji,jj,jk) - texcret2 * zprofed(ji,jj,jk)
363              tra(ji,jj,jk,jpsil) = tra(ji,jj,jk,jpsil) - texcret2 * zprorcad(ji,jj,jk) * zysopt(ji,jj,jk)
364              tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) - zprorca(ji,jj,jk) - zprorcad(ji,jj,jk)
365              tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) + rno3 * ( zpronew(ji,jj,jk) + zpronewd(ji,jj,jk) ) &
366                 &                                      - rno3 * ( zproreg + zproreg2 )
367          END DO
368        END DO
369     END DO
370
371
372    ! Total primary production per year
373    IF( iom_use( "tintpp" ) .OR. ( ln_check_mass .AND. kt == nitend .AND. knt == nrdttrc )  )  &
374         & tpp = glob_sum( ( zprorca(:,:,:) + zprorcad(:,:,:) ) * cvol(:,:,:) )
375
376    IF( lk_iomput ) THEN
377       IF( knt == nrdttrc ) THEN
378          CALL wrk_alloc( jpi, jpj,      zw2d )
379          CALL wrk_alloc( jpi, jpj, jpk, zw3d )
380          zfact = 1.e+3 * rfact2r  !  conversion from mol/l/kt to  mol/m3/s
381          !
382          IF( iom_use( "PPPHY" ) .OR. iom_use( "PPPHY2" ) )  THEN
383              zw3d(:,:,:) = zprorca (:,:,:) * zfact * tmask(:,:,:)  ! primary production by nanophyto
384              CALL iom_put( "PPPHY"  , zw3d )
385              !
386              zw3d(:,:,:) = zprorcad(:,:,:) * zfact * tmask(:,:,:)  ! primary production by diatomes
387              CALL iom_put( "PPPHY2"  , zw3d )
388          ENDIF
389          IF( iom_use( "PPNEWN" ) .OR. iom_use( "PPNEWD" ) )  THEN
390              zw3d(:,:,:) = zpronew (:,:,:) * zfact * tmask(:,:,:)  ! new primary production by nanophyto
391              CALL iom_put( "PPNEWN"  , zw3d )
392              !
393              zw3d(:,:,:) = zpronewd(:,:,:) * zfact * tmask(:,:,:)  ! new primary production by diatomes
394              CALL iom_put( "PPNEWD"  , zw3d )
395          ENDIF
396          IF( iom_use( "PBSi" ) )  THEN
397              zw3d(:,:,:) = zprorcad(:,:,:) * zfact * tmask(:,:,:) * zysopt(:,:,:) ! biogenic silica production
398              CALL iom_put( "PBSi"  , zw3d )
399          ENDIF
400          IF( iom_use( "PFeN" ) .OR. iom_use( "PFeD" ) )  THEN
401              zw3d(:,:,:) = zprofen(:,:,:) * zfact * tmask(:,:,:)  ! biogenic iron production by nanophyto
402              CALL iom_put( "PFeN"  , zw3d )
403              !
404              zw3d(:,:,:) = zprofed(:,:,:) * zfact * tmask(:,:,:)  ! biogenic iron production by  diatomes
405              CALL iom_put( "PFeD"  , zw3d )
406          ENDIF
407          IF( iom_use( "Mumax" ) )  THEN
408              zw3d(:,:,:) = prmax(:,:,:) * tmask(:,:,:)   ! Maximum growth rate
409              CALL iom_put( "Mumax"  , zw3d )
410          ENDIF
411          IF( iom_use( "MuN" ) .OR. iom_use( "MuD" ) )  THEN
412              zw3d(:,:,:) = zprbio(:,:,:) * xlimphy(:,:,:) * tmask(:,:,:)  ! Realized growth rate for nanophyto
413              CALL iom_put( "MuN"  , zw3d )
414              !
415              zw3d(:,:,:) =  zprdia(:,:,:) * xlimdia(:,:,:) * tmask(:,:,:)  ! Realized growth rate for diatoms
416              CALL iom_put( "MuD"  , zw3d )
417          ENDIF
418          IF( iom_use( "LNlight" ) .OR. iom_use( "LDlight" ) )  THEN
419              zw3d(:,:,:) = zprbio (:,:,:) / (prmax(:,:,:) + rtrn) * tmask(:,:,:) ! light limitation term
420              CALL iom_put( "LNlight"  , zw3d )
421              !
422              zw3d(:,:,:) =  zprdia (:,:,:) / (prmax(:,:,:) + rtrn) * tmask(:,:,:)  ! light limitation term
423              CALL iom_put( "LDlight"  , zw3d )
424          ENDIF
425          IF( iom_use( "TPP" ) )  THEN
426              zw3d(:,:,:) = ( zprorca(:,:,:) + zprorcad(:,:,:) ) * zfact * tmask(:,:,:)  ! total primary production
427              CALL iom_put( "TPP"  , zw3d )
428          ENDIF
429          IF( iom_use( "TPNEW" ) )  THEN
430              zw3d(:,:,:) = ( zpronew(:,:,:) + zpronewd(:,:,:) ) * zfact * tmask(:,:,:)  ! total new production
431              CALL iom_put( "TPNEW"  , zw3d )
432          ENDIF
433          IF( iom_use( "TPBFE" ) )  THEN
434              zw3d(:,:,:) = ( zprofen(:,:,:) + zprofed(:,:,:) ) * zfact * tmask(:,:,:)  ! total biogenic iron production
435              CALL iom_put( "TPBFE"  , zw3d )
436          ENDIF
437          IF( iom_use( "INTPPPHY" ) .OR. iom_use( "INTPPPHY2" ) ) THEN 
438             zw2d(:,:) = 0.
439             DO jk = 1, jpkm1
440               zw2d(:,:) = zw2d(:,:) + zprorca (:,:,jk) * e3t_n(:,:,jk) * zfact * tmask(:,:,jk)  ! vert. integrated  primary produc. by nano
441             ENDDO
442             CALL iom_put( "INTPPPHY" , zw2d )
443             !
444             zw2d(:,:) = 0.
445             DO jk = 1, jpkm1
446                zw2d(:,:) = zw2d(:,:) + zprorcad(:,:,jk) * e3t_n(:,:,jk) * zfact * tmask(:,:,jk) ! vert. integrated  primary produc. by diatom
447             ENDDO
448             CALL iom_put( "INTPPPHY2" , zw2d )
449          ENDIF
450          IF( iom_use( "INTPP" ) ) THEN   
451             zw2d(:,:) = 0.
452             DO jk = 1, jpkm1
453                zw2d(:,:) = zw2d(:,:) + ( zprorca(:,:,jk) + zprorcad(:,:,jk) ) * e3t_n(:,:,jk) * zfact * tmask(:,:,jk) ! vert. integrated pp
454             ENDDO
455             CALL iom_put( "INTPP" , zw2d )
456          ENDIF
457          IF( iom_use( "INTPNEW" ) ) THEN   
458             zw2d(:,:) = 0.
459             DO jk = 1, jpkm1
460                zw2d(:,:) = zw2d(:,:) + ( zpronew(:,:,jk) + zpronewd(:,:,jk) ) * e3t_n(:,:,jk) * zfact * tmask(:,:,jk)  ! vert. integrated new prod
461             ENDDO
462             CALL iom_put( "INTPNEW" , zw2d )
463          ENDIF
464          IF( iom_use( "INTPBFE" ) ) THEN           !   total biogenic iron production  ( vertically integrated )
465             zw2d(:,:) = 0.
466             DO jk = 1, jpkm1
467                zw2d(:,:) = zw2d(:,:) + ( zprofen(:,:,jk) + zprofed(:,:,jk) ) * e3t_n(:,:,jk) * zfact * tmask(:,:,jk) ! vert integr. bfe prod
468             ENDDO
469            CALL iom_put( "INTPBFE" , zw2d )
470          ENDIF
471          IF( iom_use( "INTPBSI" ) ) THEN           !   total biogenic silica production  ( vertically integrated )
472             zw2d(:,:) = 0.
473             DO jk = 1, jpkm1
474                zw2d(:,:) = zw2d(:,:) + zprorcad(:,:,jk) * zysopt(:,:,jk) * e3t_n(:,:,jk) * zfact * tmask(:,:,jk)  ! vert integr. bsi prod
475             ENDDO
476             CALL iom_put( "INTPBSI" , zw2d )
477          ENDIF
478          IF( iom_use( "tintpp" ) )  CALL iom_put( "tintpp" , tpp * zfact )  !  global total integrated primary production molC/s
479          !
480          CALL wrk_dealloc( jpi, jpj,      zw2d )
481          CALL wrk_dealloc( jpi, jpj, jpk, zw3d )
482       ENDIF
483     ENDIF
484
485     IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
486         WRITE(charout, FMT="('prod')")
487         CALL prt_ctl_trc_info(charout)
488         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
489     ENDIF
490     !
491     CALL wrk_dealloc( jpi, jpj,      zmixnano, zmixdiat, zstrn                                                  )
492     CALL wrk_dealloc( jpi, jpj, jpk, zpislopead, zpislopead2, zprdia, zprbio, zprdch, zprnch, zysopt            ) 
493     CALL wrk_dealloc( jpi, jpj, jpk, zprorca, zprorcad, zprofed, zprofen, zprochln, zprochld, zpronew, zpronewd )
494     !
495     IF( nn_timing == 1 )  CALL timing_stop('p4z_prod')
496     !
497   END SUBROUTINE p4z_prod
498
499
500   SUBROUTINE p4z_prod_init
501      !!----------------------------------------------------------------------
502      !!                  ***  ROUTINE p4z_prod_init  ***
503      !!
504      !! ** Purpose :   Initialization of phytoplankton production parameters
505      !!
506      !! ** Method  :   Read the nampisprod namelist and check the parameters
507      !!      called at the first timestep (nittrc000)
508      !!
509      !! ** input   :   Namelist nampisprod
510      !!----------------------------------------------------------------------
511      !
512      NAMELIST/nampisprod/ pislope, pislope2, xadap, ln_newprod, bresp, excret, excret2,  &
513         &                 chlcnm, chlcdm, chlcmin, fecnm, fecdm, grosip
514      INTEGER :: ios                 ! Local integer output status for namelist read
515      !!----------------------------------------------------------------------
516
517      REWIND( numnatp_ref )              ! Namelist nampisprod in reference namelist : Pisces phytoplankton production
518      READ  ( numnatp_ref, nampisprod, IOSTAT = ios, ERR = 901)
519901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampisprod in reference namelist', lwp )
520
521      REWIND( numnatp_cfg )              ! Namelist nampisprod in configuration namelist : Pisces phytoplankton production
522      READ  ( numnatp_cfg, nampisprod, IOSTAT = ios, ERR = 902 )
523902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampisprod in configuration namelist', lwp )
524      IF(lwm) WRITE ( numonp, nampisprod )
525
526      IF(lwp) THEN                         ! control print
527         WRITE(numout,*) ' '
528         WRITE(numout,*) ' Namelist parameters for phytoplankton growth, nampisprod'
529         WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
530         WRITE(numout,*) '    Enable new parame. of production (T/F)   ln_newprod   =', ln_newprod
531         WRITE(numout,*) '    mean Si/C ratio                           grosip       =', grosip
532         WRITE(numout,*) '    P-I slope                                 pislope      =', pislope
533         WRITE(numout,*) '    Acclimation factor to low light           xadap       =', xadap
534         WRITE(numout,*) '    excretion ratio of nanophytoplankton      excret       =', excret
535         WRITE(numout,*) '    excretion ratio of diatoms                excret2      =', excret2
536         IF( ln_newprod )  THEN
537            WRITE(numout,*) '    basal respiration in phytoplankton        bresp        =', bresp
538            WRITE(numout,*) '    Maximum Chl/C in phytoplankton            chlcmin      =', chlcmin
539         ENDIF
540         WRITE(numout,*) '    P-I slope  for diatoms                    pislope2     =', pislope2
541         WRITE(numout,*) '    Minimum Chl/C in nanophytoplankton        chlcnm       =', chlcnm
542         WRITE(numout,*) '    Minimum Chl/C in diatoms                  chlcdm       =', chlcdm
543         WRITE(numout,*) '    Maximum Fe/C in nanophytoplankton         fecnm        =', fecnm
544         WRITE(numout,*) '    Minimum Fe/C in diatoms                   fecdm        =', fecdm
545      ENDIF
546      !
547      r1_rday   = 1._wp / rday 
548      texcret   = 1._wp - excret
549      texcret2  = 1._wp - excret2
550      tpp       = 0._wp
551      !
552   END SUBROUTINE p4z_prod_init
553
554
555   INTEGER FUNCTION p4z_prod_alloc()
556      !!----------------------------------------------------------------------
557      !!                     ***  ROUTINE p4z_prod_alloc  ***
558      !!----------------------------------------------------------------------
559      ALLOCATE( prmax(jpi,jpj,jpk), quotan(jpi,jpj,jpk), quotad(jpi,jpj,jpk), STAT = p4z_prod_alloc )
560      !
561      IF( p4z_prod_alloc /= 0 ) CALL ctl_warn('p4z_prod_alloc : failed to allocate arrays.')
562      !
563   END FUNCTION p4z_prod_alloc
564
565#else
566   !!======================================================================
567   !!  Dummy module :                                   No PISCES bio-model
568   !!======================================================================
569CONTAINS
570   SUBROUTINE p4z_prod                    ! Empty routine
571   END SUBROUTINE p4z_prod
572#endif 
573
574   !!======================================================================
575END MODULE p4zprod
Note: See TracBrowser for help on using the repository browser.