New URL for NEMO forge! http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.

bdydta.F90 in branches/2016/dev_r6522_SIMPLIF_3/NEMOGCM/NEMO/OPA_SRC/BDY – NEMO

Context Navigation

source: branches/2016/dev_r6522_SIMPLIF_3/NEMOGCM/NEMO/OPA_SRC/BDY/bdydta.F90 @ 6864

Last change on this file since 6864 was 6864, checked in by lovato, 8 years ago
#1729 - trunk: removed key_tide from the code and set usage of ln_tide. Tested with AMM12 and ORCA2_LIM_PISCES.
Property svn:keywords set to `Id`
File size: 40.0 KB

Line
1	MODULE bdydta
2	!!======================================================================
3	!! * MODULE bdydta *
4	!! Open boundary data : read the data for the unstructured open boundaries.
5	!!======================================================================
6	!! History : 1.0 ! 2005-01 (J. Chanut, A. Sellar) Original code
7	!! - ! 2007-01 (D. Storkey) Update to use IOM module
8	!! - ! 2007-07 (D. Storkey) add bdy_dta_fla
9	!! 3.0 ! 2008-04 (NEMO team) add in the reference version
10	!! 3.3 ! 2010-09 (E.O'Dea) modifications for Shelf configurations
11	!! 3.3 ! 2010-09 (D.Storkey) add ice boundary conditions
12	!! 3.4 ! 2011 (D. Storkey) rewrite in preparation for OBC-BDY merge
13	!! 3.6 ! 2012-01 (C. Rousset) add ice boundary conditions for lim3
14	!!----------------------------------------------------------------------
15	!! bdy_dta : read external data along open boundaries from file
16	!! bdy_dta_init : initialise arrays etc for reading of external data
17	!!----------------------------------------------------------------------
18	USE timing ! Timing
19	USE oce ! ocean dynamics and tracers
20	USE dom_oce ! ocean space and time domain
21	USE phycst ! physical constants
22	USE bdy_oce ! ocean open boundary conditions
23	USE bdytides ! tidal forcing at boundaries
24	USE fldread ! read input fields
25	USE iom ! IOM library
26	USE in_out_manager ! I/O logical units
27	#if defined key_lim2
28	USE ice_2
29	#elif defined key_lim3
30	USE ice
31	USE limvar ! redistribute ice input into categories
32	#endif
33	USE sbcapr
34	USE sbctide , ONLY: ln_tide ! Tidal forcing or not
35
36	IMPLICIT NONE
37	PRIVATE
38
39	PUBLIC bdy_dta ! routine called by step.F90 and dynspg_ts.F90
40	PUBLIC bdy_dta_init ! routine called by nemogcm.F90
41
42	INTEGER, ALLOCATABLE, DIMENSION(:) :: nb_bdy_fld ! Number of fields to update for each boundary set.
43	INTEGER :: nb_bdy_fld_sum ! Total number of fields to update for all boundary sets.
44	LOGICAL, DIMENSION(jp_bdy) :: ln_full_vel_array ! =T => full velocities in 3D boundary conditions
45	! =F => baroclinic velocities in 3D boundary conditions
46	!$AGRIF_DO_NOT_TREAT
47	TYPE(FLD), PUBLIC, ALLOCATABLE, DIMENSION(:), TARGET :: bf ! structure of input fields (file informations, fields read)
48	!$AGRIF_END_DO_NOT_TREAT
49	TYPE(MAP_POINTER), ALLOCATABLE, DIMENSION(:) :: nbmap_ptr ! array of pointers to nbmap
50
51	#if defined key_lim3
52	LOGICAL :: ll_bdylim3 ! determine whether ice input is lim2 (F) or lim3 (T) type
53	INTEGER :: jfld_hti, jfld_hts, jfld_ai ! indices of ice thickness, snow thickness and concentration in bf structure
54	#endif
55
56	!!----------------------------------------------------------------------
57	!! NEMO/OPA 3.3 , NEMO Consortium (2010)
58	!! $Id$
59	!! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
60	!!----------------------------------------------------------------------
61	CONTAINS
62
63	SUBROUTINE bdy_dta( kt, jit, time_offset )
64	!!----------------------------------------------------------------------
65	!! * SUBROUTINE bdy_dta *
66	!!
67	!! ** Purpose : Update external data for open boundary conditions
68	!!
69	!! ** Method : Use fldread.F90
70	!!
71	!!----------------------------------------------------------------------
72	INTEGER, INTENT(in) :: kt ! ocean time-step index
73	INTEGER, INTENT(in), OPTIONAL :: jit ! subcycle time-step index (for timesplitting option)
74	INTEGER, INTENT(in), OPTIONAL :: time_offset ! time offset in units of timesteps. NB. if jit
75	! ! is present then units = subcycle timesteps.
76	! ! time_offset = 0 => get data at "now" time level
77	! ! time_offset = -1 => get data at "before" time level
78	! ! time_offset = +1 => get data at "after" time level
79	! ! etc.
80	!
81	INTEGER :: ib_bdy, jfld, jstart, jend, ib, ii, ij, ik, igrd, jl ! local indices
82	INTEGER, DIMENSION(jpbgrd) :: ilen1
83	INTEGER, POINTER, DIMENSION(:) :: nblen, nblenrim ! short cuts
84	TYPE(OBC_DATA), POINTER :: dta ! short cut
85	!!---------------------------------------------------------------------------
86	!
87	IF( nn_timing == 1 ) CALL timing_start('bdy_dta')
88	!
89	! Initialise data arrays once for all from initial conditions where required
90	!---------------------------------------------------------------------------
91	IF( kt == nit000 .AND. .NOT.PRESENT(jit) ) THEN
92
93	! Calculate depth-mean currents
94	!-----------------------------
95
96	DO ib_bdy = 1, nb_bdy
97	!
98	nblen => idx_bdy(ib_bdy)%nblen
99	nblenrim => idx_bdy(ib_bdy)%nblenrim
100	dta => dta_bdy(ib_bdy)
101
102	IF( nn_dyn2d_dta(ib_bdy) == 0 ) THEN
103	ilen1(:) = nblen(:)
104	IF( dta%ll_ssh ) THEN
105	igrd = 1
106	DO ib = 1, ilen1(igrd)
107	ii = idx_bdy(ib_bdy)%nbi(ib,igrd)
108	ij = idx_bdy(ib_bdy)%nbj(ib,igrd)
109	dta_bdy(ib_bdy)%ssh(ib) = sshn(ii,ij) * tmask(ii,ij,1)
110	END DO
111	END IF
112	IF( dta%ll_u2d ) THEN
113	igrd = 2
114	DO ib = 1, ilen1(igrd)
115	ii = idx_bdy(ib_bdy)%nbi(ib,igrd)
116	ij = idx_bdy(ib_bdy)%nbj(ib,igrd)
117	dta_bdy(ib_bdy)%u2d(ib) = un_b(ii,ij) * umask(ii,ij,1)
118	END DO
119	END IF
120	IF( dta%ll_v2d ) THEN
121	igrd = 3
122	DO ib = 1, ilen1(igrd)
123	ii = idx_bdy(ib_bdy)%nbi(ib,igrd)
124	ij = idx_bdy(ib_bdy)%nbj(ib,igrd)
125	dta_bdy(ib_bdy)%v2d(ib) = vn_b(ii,ij) * vmask(ii,ij,1)
126	END DO
127	END IF
128	ENDIF
129
130	IF( nn_dyn3d_dta(ib_bdy) == 0 ) THEN
131	ilen1(:) = nblen(:)
132	IF( dta%ll_u3d ) THEN
133	igrd = 2
134	DO ib = 1, ilen1(igrd)
135	DO ik = 1, jpkm1
136	ii = idx_bdy(ib_bdy)%nbi(ib,igrd)
137	ij = idx_bdy(ib_bdy)%nbj(ib,igrd)
138	dta_bdy(ib_bdy)%u3d(ib,ik) = ( un(ii,ij,ik) - un_b(ii,ij) ) * umask(ii,ij,ik)
139	END DO
140	END DO
141	END IF
142	IF( dta%ll_v3d ) THEN
143	igrd = 3
144	DO ib = 1, ilen1(igrd)
145	DO ik = 1, jpkm1
146	ii = idx_bdy(ib_bdy)%nbi(ib,igrd)
147	ij = idx_bdy(ib_bdy)%nbj(ib,igrd)
148	dta_bdy(ib_bdy)%v3d(ib,ik) = ( vn(ii,ij,ik) - vn_b(ii,ij) ) * vmask(ii,ij,ik)
149	END DO
150	END DO
151	END IF
152	ENDIF
153
154	IF( nn_tra_dta(ib_bdy) == 0 ) THEN
155	ilen1(:) = nblen(:)
156	IF( dta%ll_tem ) THEN
157	igrd = 1
158	DO ib = 1, ilen1(igrd)
159	DO ik = 1, jpkm1
160	ii = idx_bdy(ib_bdy)%nbi(ib,igrd)
161	ij = idx_bdy(ib_bdy)%nbj(ib,igrd)
162	dta_bdy(ib_bdy)%tem(ib,ik) = tsn(ii,ij,ik,jp_tem) * tmask(ii,ij,ik)
163	END DO
164	END DO
165	END IF
166	IF( dta%ll_sal ) THEN
167	igrd = 1
168	DO ib = 1, ilen1(igrd)
169	DO ik = 1, jpkm1
170	ii = idx_bdy(ib_bdy)%nbi(ib,igrd)
171	ij = idx_bdy(ib_bdy)%nbj(ib,igrd)
172	dta_bdy(ib_bdy)%sal(ib,ik) = tsn(ii,ij,ik,jp_sal) * tmask(ii,ij,ik)
173	END DO
174	END DO
175	END IF
176	ENDIF
177
178	#if defined key_lim2
179	IF( nn_ice_lim_dta(ib_bdy) == 0 ) THEN
180	ilen1(:) = nblen(:)
181	IF( dta%ll_frld ) THEN
182	igrd = 1
183	DO ib = 1, ilen1(igrd)
184	ii = idx_bdy(ib_bdy)%nbi(ib,igrd)
185	ij = idx_bdy(ib_bdy)%nbj(ib,igrd)
186	dta_bdy(ib_bdy)%frld(ib) = frld(ii,ij) * tmask(ii,ij,1)
187	END DO
188	END IF
189	IF( dta%ll_hicif ) THEN
190	igrd = 1
191	DO ib = 1, ilen1(igrd)
192	ii = idx_bdy(ib_bdy)%nbi(ib,igrd)
193	ij = idx_bdy(ib_bdy)%nbj(ib,igrd)
194	dta_bdy(ib_bdy)%hicif(ib) = hicif(ii,ij) * tmask(ii,ij,1)
195	END DO
196	END IF
197	IF( dta%ll_hsnif ) THEN
198	igrd = 1
199	DO ib = 1, ilen1(igrd)
200	ii = idx_bdy(ib_bdy)%nbi(ib,igrd)
201	ij = idx_bdy(ib_bdy)%nbj(ib,igrd)
202	dta_bdy(ib_bdy)%hsnif(ib) = hsnif(ii,ij) * tmask(ii,ij,1)
203	END DO
204	END IF
205	ENDIF
206	#elif defined key_lim3
207	IF( nn_ice_lim_dta(ib_bdy) == 0 ) THEN
208	ilen1(:) = nblen(:)
209	IF( dta%ll_a_i ) THEN
210	igrd = 1
211	DO jl = 1, jpl
212	DO ib = 1, ilen1(igrd)
213	ii = idx_bdy(ib_bdy)%nbi(ib,igrd)
214	ij = idx_bdy(ib_bdy)%nbj(ib,igrd)
215	dta_bdy(ib_bdy)%a_i (ib,jl) = a_i(ii,ij,jl) * tmask(ii,ij,1)
216	END DO
217	END DO
218	ENDIF
219	IF( dta%ll_ht_i ) THEN
220	igrd = 1
221	DO jl = 1, jpl
222	DO ib = 1, ilen1(igrd)
223	ii = idx_bdy(ib_bdy)%nbi(ib,igrd)
224	ij = idx_bdy(ib_bdy)%nbj(ib,igrd)
225	dta_bdy(ib_bdy)%ht_i (ib,jl) = ht_i(ii,ij,jl) * tmask(ii,ij,1)
226	END DO
227	END DO
228	ENDIF
229	IF( dta%ll_ht_s ) THEN
230	igrd = 1
231	DO jl = 1, jpl
232	DO ib = 1, ilen1(igrd)
233	ii = idx_bdy(ib_bdy)%nbi(ib,igrd)
234	ij = idx_bdy(ib_bdy)%nbj(ib,igrd)
235	dta_bdy(ib_bdy)%ht_s (ib,jl) = ht_s(ii,ij,jl) * tmask(ii,ij,1)
236	END DO
237	END DO
238	ENDIF
239	ENDIF
240	#endif
241	END DO ! ib_bdy
242	!
243	ENDIF ! kt == nit000
244
245	! update external data from files
246	!--------------------------------
247
248	jstart = 1
249	DO ib_bdy = 1, nb_bdy
250	dta => dta_bdy(ib_bdy)
251	IF( nn_dta(ib_bdy) == 1 ) THEN ! skip this bit if no external data required
252
253	IF( PRESENT(jit) ) THEN
254	! Update barotropic boundary conditions only
255	! jit is optional argument for fld_read and bdytide_update
256	IF( cn_dyn2d(ib_bdy) /= 'none' ) THEN
257	IF( nn_dyn2d_dta(ib_bdy) == 2 ) THEN ! tidal harmonic forcing ONLY: initialise arrays
258	IF( dta%ll_ssh ) dta%ssh(:) = 0._wp
259	IF( dta%ll_u2d ) dta%u2d(:) = 0._wp
260	IF( dta%ll_u3d ) dta%v2d(:) = 0._wp
261	ENDIF
262	IF (cn_tra(ib_bdy) /= 'runoff') THEN
263	IF( nn_dyn2d_dta(ib_bdy) == 1 .OR. nn_dyn2d_dta(ib_bdy) == 3 ) THEN
264
265	jend = jstart + dta%nread(2) - 1
266	CALL fld_read( kt=kt, kn_fsbc=1, sd=bf(jstart:jend), map=nbmap_ptr(jstart:jend), &
267	& kit=jit, kt_offset=time_offset )
268
269	! If full velocities in boundary data then extract barotropic velocities from 3D fields
270	IF( ln_full_vel_array(ib_bdy) .AND. &
271	& ( nn_dyn2d_dta(ib_bdy) == 1 .OR. nn_dyn2d_dta(ib_bdy) == 3 .OR. &
272	& nn_dyn3d_dta(ib_bdy) == 1 ) )THEN
273
274	igrd = 2 ! zonal velocity
275	dta%u2d(:) = 0._wp
276	DO ib = 1, idx_bdy(ib_bdy)%nblen(igrd)
277	ii = idx_bdy(ib_bdy)%nbi(ib,igrd)
278	ij = idx_bdy(ib_bdy)%nbj(ib,igrd)
279	DO ik = 1, jpkm1
280	dta%u2d(ib) = dta%u2d(ib) &
281	& + e3u_n(ii,ij,ik) * umask(ii,ij,ik) * dta%u3d(ib,ik)
282	END DO
283	dta%u2d(ib) = dta%u2d(ib) * r1_hu_n(ii,ij)
284	END DO
285	igrd = 3 ! meridional velocity
286	dta%v2d(:) = 0._wp
287	DO ib = 1, idx_bdy(ib_bdy)%nblen(igrd)
288	ii = idx_bdy(ib_bdy)%nbi(ib,igrd)
289	ij = idx_bdy(ib_bdy)%nbj(ib,igrd)
290	DO ik = 1, jpkm1
291	dta%v2d(ib) = dta%v2d(ib) &
292	& + e3v_n(ii,ij,ik) * vmask(ii,ij,ik) * dta%v3d(ib,ik)
293	END DO
294	dta%v2d(ib) = dta%v2d(ib) * r1_hv_n(ii,ij)
295	END DO
296	ENDIF
297	ENDIF
298	IF( nn_dyn2d_dta(ib_bdy) .ge. 2 ) THEN ! update tidal harmonic forcing
299	CALL bdytide_update( kt=kt, idx=idx_bdy(ib_bdy), dta=dta, td=tides(ib_bdy), &
300	& jit=jit, time_offset=time_offset )
301	ENDIF
302	ENDIF
303	ENDIF
304	ELSE
305	IF (cn_tra(ib_bdy) == 'runoff') then ! runoff condition
306	jend = nb_bdy_fld(ib_bdy)
307	CALL fld_read( kt=kt, kn_fsbc=1, sd=bf(jstart:jend), &
308	& map=nbmap_ptr(jstart:jend), kt_offset=time_offset )
309	!
310	igrd = 2 ! zonal velocity
311	DO ib = 1, idx_bdy(ib_bdy)%nblen(igrd)
312	ii = idx_bdy(ib_bdy)%nbi(ib,igrd)
313	ij = idx_bdy(ib_bdy)%nbj(ib,igrd)
314	dta%u2d(ib) = dta%u2d(ib) / ( e2u(ii,ij) * hu_0(ii,ij) )
315	END DO
316	!
317	igrd = 3 ! meridional velocity
318	DO ib = 1, idx_bdy(ib_bdy)%nblen(igrd)
319	ii = idx_bdy(ib_bdy)%nbi(ib,igrd)
320	ij = idx_bdy(ib_bdy)%nbj(ib,igrd)
321	dta%v2d(ib) = dta%v2d(ib) / ( e1v(ii,ij) * hv_0(ii,ij) )
322	END DO
323	ELSE
324	IF( nn_dyn2d_dta(ib_bdy) == 2 ) THEN ! tidal harmonic forcing ONLY: initialise arrays
325	IF( dta%ll_ssh ) dta%ssh(:) = 0._wp
326	IF( dta%ll_u2d ) dta%u2d(:) = 0._wp
327	IF( dta%ll_v2d ) dta%v2d(:) = 0._wp
328	ENDIF
329	IF( dta%nread(1) .gt. 0 ) THEN ! update external data
330	jend = jstart + dta%nread(1) - 1
331	CALL fld_read( kt=kt, kn_fsbc=1, sd=bf(jstart:jend), &
332	& map=nbmap_ptr(jstart:jend), kt_offset=time_offset )
333	ENDIF
334	! If full velocities in boundary data then split into barotropic and baroclinic data
335	IF( ln_full_vel_array(ib_bdy) .and. &
336	& ( nn_dyn2d_dta(ib_bdy) == 1 .OR. nn_dyn2d_dta(ib_bdy) == 3 .OR. &
337	& nn_dyn3d_dta(ib_bdy) == 1 ) ) THEN
338	igrd = 2 ! zonal velocity
339	dta%u2d(:) = 0._wp
340	DO ib = 1, idx_bdy(ib_bdy)%nblen(igrd)
341	ii = idx_bdy(ib_bdy)%nbi(ib,igrd)
342	ij = idx_bdy(ib_bdy)%nbj(ib,igrd)
343	DO ik = 1, jpkm1
344	dta%u2d(ib) = dta%u2d(ib) &
345	& + e3u_n(ii,ij,ik) * umask(ii,ij,ik) * dta%u3d(ib,ik)
346	END DO
347	dta%u2d(ib) = dta%u2d(ib) * r1_hu_n(ii,ij)
348	DO ik = 1, jpkm1
349	dta%u3d(ib,ik) = dta%u3d(ib,ik) - dta%u2d(ib)
350	END DO
351	END DO
352	igrd = 3 ! meridional velocity
353	dta%v2d(:) = 0._wp
354	DO ib = 1, idx_bdy(ib_bdy)%nblen(igrd)
355	ii = idx_bdy(ib_bdy)%nbi(ib,igrd)
356	ij = idx_bdy(ib_bdy)%nbj(ib,igrd)
357	DO ik = 1, jpkm1
358	dta%v2d(ib) = dta%v2d(ib) &
359	& + e3v_n(ii,ij,ik) * vmask(ii,ij,ik) * dta%v3d(ib,ik)
360	END DO
361	dta%v2d(ib) = dta%v2d(ib) * r1_hv_n(ii,ij)
362	DO ik = 1, jpkm1
363	dta%v3d(ib,ik) = dta%v3d(ib,ik) - dta%v2d(ib)
364	END DO
365	END DO
366	ENDIF
367
368	ENDIF
369	#if defined key_lim3
370	IF( .NOT. ll_bdylim3 .AND. cn_ice_lim(ib_bdy) /= 'none' .AND. nn_ice_lim_dta(ib_bdy) == 1 ) THEN ! bdy ice input (case input is lim2 type)
371	CALL lim_var_itd ( bf(jfld_hti)%fnow(:,1,1), bf(jfld_hts)%fnow(:,1,1), bf(jfld_ai)%fnow(:,1,1), &
372	& dta_bdy(ib_bdy)%ht_i, dta_bdy(ib_bdy)%ht_s, dta_bdy(ib_bdy)%a_i )
373	ENDIF
374	#endif
375	ENDIF
376	jstart = jstart + dta%nread(1)
377	END IF ! nn_dta(ib_bdy) = 1
378	END DO ! ib_bdy
379
380	IF ( ln_tide ) THEN
381	IF (ln_dynspg_ts) THEN ! Fill temporary arrays with slow-varying bdy data
382	DO ib_bdy = 1, nb_bdy ! Tidal component added in ts loop
383	IF ( nn_dyn2d_dta(ib_bdy) .ge. 2 ) THEN
384	nblen => idx_bdy(ib_bdy)%nblen
385	nblenrim => idx_bdy(ib_bdy)%nblenrim
386	IF( cn_dyn2d(ib_bdy) == 'frs' ) THEN; ilen1(:)=nblen(:) ; ELSE ; ilen1(:)=nblenrim(:) ; ENDIF
387	IF ( dta_bdy(ib_bdy)%ll_ssh ) dta_bdy_s(ib_bdy)%ssh(1:ilen1(1)) = dta_bdy(ib_bdy)%ssh(1:ilen1(1))
388	IF ( dta_bdy(ib_bdy)%ll_u2d ) dta_bdy_s(ib_bdy)%u2d(1:ilen1(2)) = dta_bdy(ib_bdy)%u2d(1:ilen1(2))
389	IF ( dta_bdy(ib_bdy)%ll_v2d ) dta_bdy_s(ib_bdy)%v2d(1:ilen1(3)) = dta_bdy(ib_bdy)%v2d(1:ilen1(3))
390	ENDIF
391	END DO
392	ELSE ! Add tides if not split-explicit free surface else this is done in ts loop
393	!
394	CALL bdy_dta_tides( kt=kt, time_offset=time_offset )
395	ENDIF
396	ENDIF
397
398	IF ( ln_apr_obc ) THEN
399	DO ib_bdy = 1, nb_bdy
400	IF (cn_tra(ib_bdy) /= 'runoff')THEN
401	igrd = 1 ! meridional velocity
402	DO ib = 1, idx_bdy(ib_bdy)%nblenrim(igrd)
403	ii = idx_bdy(ib_bdy)%nbi(ib,igrd)
404	ij = idx_bdy(ib_bdy)%nbj(ib,igrd)
405	dta_bdy(ib_bdy)%ssh(ib) = dta_bdy(ib_bdy)%ssh(ib) + ssh_ib(ii,ij)
406	END DO
407	ENDIF
408	END DO
409	ENDIF
410	!
411	IF( nn_timing == 1 ) CALL timing_stop('bdy_dta')
412	!
413	END SUBROUTINE bdy_dta
414
415
416	SUBROUTINE bdy_dta_init
417	!!----------------------------------------------------------------------
418	!! * SUBROUTINE bdy_dta_init *
419	!!
420	!! ** Purpose : Initialise arrays for reading of external data
421	!! for open boundary conditions
422	!!
423	!! ** Method :
424	!!
425	!!----------------------------------------------------------------------
426	INTEGER :: ib_bdy, jfld, jstart, jend, ierror, ios ! Local integers
427	!
428	CHARACTER(len=100) :: cn_dir ! Root directory for location of data files
429	CHARACTER(len=100), DIMENSION(nb_bdy) :: cn_dir_array ! Root directory for location of data files
430	CHARACTER(len = 256):: clname ! temporary file name
431	LOGICAL :: ln_full_vel ! =T => full velocities in 3D boundary data
432	! =F => baroclinic velocities in 3D boundary data
433	INTEGER :: ilen_global ! Max length required for global bdy dta arrays
434	INTEGER, ALLOCATABLE, DIMENSION(:) :: ilen1, ilen3 ! size of 1st and 3rd dimensions of local arrays
435	INTEGER, ALLOCATABLE, DIMENSION(:) :: ibdy ! bdy set for a particular jfld
436	INTEGER, ALLOCATABLE, DIMENSION(:) :: igrid ! index for grid type (1,2,3 = T,U,V)
437	INTEGER, POINTER, DIMENSION(:) :: nblen, nblenrim ! short cuts
438	TYPE(OBC_DATA), POINTER :: dta ! short cut
439	#if defined key_lim3
440	INTEGER, DIMENSION(3) :: zdimsz ! number of elements in each of the 4 dimensions (i.e. i,j,t,ice-cat) for an array
441	INTEGER :: zndims ! number of dimensions in an array (i.e. 3 = wo ice cat; 4 = w ice cat)
442	INTEGER :: inum,id1 ! local integer
443	#endif
444	TYPE(FLD_N), ALLOCATABLE, DIMENSION(:) :: blf_i ! array of namelist information structures
445	TYPE(FLD_N) :: bn_tem, bn_sal, bn_u3d, bn_v3d !
446	TYPE(FLD_N) :: bn_ssh, bn_u2d, bn_v2d ! informations about the fields to be read
447	#if defined key_lim2
448	TYPE(FLD_N) :: bn_frld, bn_hicif, bn_hsnif !
449	#elif defined key_lim3
450	TYPE(FLD_N) :: bn_a_i, bn_ht_i, bn_ht_s
451	#endif
452	NAMELIST/nambdy_dta/ cn_dir, bn_tem, bn_sal, bn_u3d, bn_v3d, bn_ssh, bn_u2d, bn_v2d
453	#if defined key_lim2
454	NAMELIST/nambdy_dta/ bn_frld, bn_hicif, bn_hsnif
455	#elif defined key_lim3
456	NAMELIST/nambdy_dta/ bn_a_i, bn_ht_i, bn_ht_s
457	#endif
458	NAMELIST/nambdy_dta/ ln_full_vel
459	!!---------------------------------------------------------------------------
460	!
461	IF( nn_timing == 1 ) CALL timing_start('bdy_dta_init')
462	!
463	IF(lwp) WRITE(numout,*)
464	IF(lwp) WRITE(numout,*) 'bdy_dta_ini : initialization of data at the open boundaries'
465	IF(lwp) WRITE(numout,*) '~~~~~~~~~~'
466	IF(lwp) WRITE(numout,*) ''
467
468	! Set nn_dta
469	DO ib_bdy = 1, nb_bdy
470	nn_dta(ib_bdy) = MAX( nn_dyn2d_dta(ib_bdy) &
471	,nn_dyn3d_dta(ib_bdy) &
472	,nn_tra_dta(ib_bdy) &
473	#if ( defined key_lim2 \|\| defined key_lim3 )
474	,nn_ice_lim_dta(ib_bdy) &
475	#endif
476	)
477	IF(nn_dta(ib_bdy) > 1) nn_dta(ib_bdy) = 1
478	END DO
479
480	! Work out upper bound of how many fields there are to read in and allocate arrays
481	! ---------------------------------------------------------------------------
482	ALLOCATE( nb_bdy_fld(nb_bdy) )
483	nb_bdy_fld(:) = 0
484	DO ib_bdy = 1, nb_bdy
485	IF( cn_dyn2d(ib_bdy) /= 'none' .and. ( nn_dyn2d_dta(ib_bdy) == 1 .or. nn_dyn2d_dta(ib_bdy) == 3 ) ) THEN
486	nb_bdy_fld(ib_bdy) = nb_bdy_fld(ib_bdy) + 3
487	ENDIF
488	IF( cn_dyn3d(ib_bdy) /= 'none' .and. nn_dyn3d_dta(ib_bdy) == 1 ) THEN
489	nb_bdy_fld(ib_bdy) = nb_bdy_fld(ib_bdy) + 2
490	ENDIF
491	IF( cn_tra(ib_bdy) /= 'none' .and. nn_tra_dta(ib_bdy) == 1 ) THEN
492	nb_bdy_fld(ib_bdy) = nb_bdy_fld(ib_bdy) + 2
493	ENDIF
494	#if ( defined key_lim2 \|\| defined key_lim3 )
495	IF( cn_ice_lim(ib_bdy) /= 'none' .and. nn_ice_lim_dta(ib_bdy) == 1 ) THEN
496	nb_bdy_fld(ib_bdy) = nb_bdy_fld(ib_bdy) + 3
497	ENDIF
498	#endif
499	IF(lwp) WRITE(numout,*) 'Maximum number of files to open =',nb_bdy_fld(ib_bdy)
500	END DO
501
502	nb_bdy_fld_sum = SUM( nb_bdy_fld )
503
504	ALLOCATE( bf(nb_bdy_fld_sum), STAT=ierror )
505	IF( ierror > 0 ) THEN
506	CALL ctl_stop( 'bdy_dta: unable to allocate bf structure' ) ; RETURN
507	ENDIF
508	ALLOCATE( blf_i(nb_bdy_fld_sum), STAT=ierror )
509	IF( ierror > 0 ) THEN
510	CALL ctl_stop( 'bdy_dta: unable to allocate blf_i structure' ) ; RETURN
511	ENDIF
512	ALLOCATE( nbmap_ptr(nb_bdy_fld_sum), STAT=ierror )
513	IF( ierror > 0 ) THEN
514	CALL ctl_stop( 'bdy_dta: unable to allocate nbmap_ptr structure' ) ; RETURN
515	ENDIF
516	ALLOCATE( ilen1(nb_bdy_fld_sum), ilen3(nb_bdy_fld_sum) )
517	ALLOCATE( ibdy(nb_bdy_fld_sum) )
518	ALLOCATE( igrid(nb_bdy_fld_sum) )
519
520	! Read namelists
521	! --------------
522	REWIND(numnam_ref)
523	REWIND(numnam_cfg)
524	jfld = 0
525	DO ib_bdy = 1, nb_bdy
526	IF( nn_dta(ib_bdy) == 1 ) THEN
527	READ ( numnam_ref, nambdy_dta, IOSTAT = ios, ERR = 901)
528	901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'nambdy_dta in reference namelist', lwp )
529
530	READ ( numnam_cfg, nambdy_dta, IOSTAT = ios, ERR = 902 )
531	902 IF( ios /= 0 ) CALL ctl_nam ( ios , 'nambdy_dta in configuration namelist', lwp )
532	IF(lwm) WRITE( numond, nambdy_dta )
533
534	cn_dir_array(ib_bdy) = cn_dir
535	ln_full_vel_array(ib_bdy) = ln_full_vel
536
537	nblen => idx_bdy(ib_bdy)%nblen
538	nblenrim => idx_bdy(ib_bdy)%nblenrim
539	dta => dta_bdy(ib_bdy)
540	dta%nread(2) = 0
541
542	! Only read in necessary fields for this set.
543	! Important that barotropic variables come first.
544	IF( nn_dyn2d_dta(ib_bdy) == 1 .or. nn_dyn2d_dta(ib_bdy) == 3 ) THEN
545
546	IF( dta%ll_ssh ) THEN
547	if(lwp) write(numout,*) '++++++ reading in ssh field'
548	jfld = jfld + 1
549	blf_i(jfld) = bn_ssh
550	ibdy(jfld) = ib_bdy
551	igrid(jfld) = 1
552	ilen1(jfld) = nblen(igrid(jfld))
553	ilen3(jfld) = 1
554	dta%nread(2) = dta%nread(2) + 1
555	ENDIF
556
557	IF( dta%ll_u2d .and. .not. ln_full_vel_array(ib_bdy) ) THEN
558	if(lwp) write(numout,*) '++++++ reading in u2d field'
559	jfld = jfld + 1
560	blf_i(jfld) = bn_u2d
561	ibdy(jfld) = ib_bdy
562	igrid(jfld) = 2
563	ilen1(jfld) = nblen(igrid(jfld))
564	ilen3(jfld) = 1
565	dta%nread(2) = dta%nread(2) + 1
566	ENDIF
567
568	IF( dta%ll_v2d .and. .not. ln_full_vel_array(ib_bdy) ) THEN
569	if(lwp) write(numout,*) '++++++ reading in v2d field'
570	jfld = jfld + 1
571	blf_i(jfld) = bn_v2d
572	ibdy(jfld) = ib_bdy
573	igrid(jfld) = 3
574	ilen1(jfld) = nblen(igrid(jfld))
575	ilen3(jfld) = 1
576	dta%nread(2) = dta%nread(2) + 1
577	ENDIF
578
579	ENDIF
580
581	! read 3D velocities if baroclinic velocities require OR if
582	! barotropic velocities required and ln_full_vel set to .true.
583	IF( nn_dyn3d_dta(ib_bdy) == 1 .OR. &
584	& ( ln_full_vel_array(ib_bdy) .AND. ( nn_dyn2d_dta(ib_bdy) == 1 .or. nn_dyn2d_dta(ib_bdy) == 3 ) ) ) THEN
585
586	IF( dta%ll_u3d .OR. ( ln_full_vel_array(ib_bdy) .and. dta%ll_u2d ) ) THEN
587	if(lwp) write(numout,*) '++++++ reading in u3d field'
588	jfld = jfld + 1
589	blf_i(jfld) = bn_u3d
590	ibdy(jfld) = ib_bdy
591	igrid(jfld) = 2
592	ilen1(jfld) = nblen(igrid(jfld))
593	ilen3(jfld) = jpk
594	IF( ln_full_vel_array(ib_bdy) .and. dta%ll_u2d ) dta%nread(2) = dta%nread(2) + 1
595	ENDIF
596
597	IF( dta%ll_v3d .OR. ( ln_full_vel_array(ib_bdy) .and. dta%ll_v2d ) ) THEN
598	if(lwp) write(numout,*) '++++++ reading in v3d field'
599	jfld = jfld + 1
600	blf_i(jfld) = bn_v3d
601	ibdy(jfld) = ib_bdy
602	igrid(jfld) = 3
603	ilen1(jfld) = nblen(igrid(jfld))
604	ilen3(jfld) = jpk
605	IF( ln_full_vel_array(ib_bdy) .and. dta%ll_v2d ) dta%nread(2) = dta%nread(2) + 1
606	ENDIF
607
608	ENDIF
609
610	! temperature and salinity
611	IF( nn_tra_dta(ib_bdy) == 1 ) THEN
612
613	IF( dta%ll_tem ) THEN
614	if(lwp) write(numout,*) '++++++ reading in tem field'
615	jfld = jfld + 1
616	blf_i(jfld) = bn_tem
617	ibdy(jfld) = ib_bdy
618	igrid(jfld) = 1
619	ilen1(jfld) = nblen(igrid(jfld))
620	ilen3(jfld) = jpk
621	ENDIF
622
623	IF( dta%ll_sal ) THEN
624	if(lwp) write(numout,*) '++++++ reading in sal field'
625	jfld = jfld + 1
626	blf_i(jfld) = bn_sal
627	ibdy(jfld) = ib_bdy
628	igrid(jfld) = 1
629	ilen1(jfld) = nblen(igrid(jfld))
630	ilen3(jfld) = jpk
631	ENDIF
632
633	ENDIF
634
635	#if defined key_lim2
636	! sea ice
637	IF( nn_ice_lim_dta(ib_bdy) == 1 ) THEN
638
639	IF( dta%ll_frld ) THEN
640	jfld = jfld + 1
641	blf_i(jfld) = bn_frld
642	ibdy(jfld) = ib_bdy
643	igrid(jfld) = 1
644	ilen1(jfld) = nblen(igrid(jfld))
645	ilen3(jfld) = 1
646	ENDIF
647
648	IF( dta%ll_hicif ) THEN
649	jfld = jfld + 1
650	blf_i(jfld) = bn_hicif
651	ibdy(jfld) = ib_bdy
652	igrid(jfld) = 1
653	ilen1(jfld) = nblen(igrid(jfld))
654	ilen3(jfld) = 1
655	ENDIF
656
657	IF( dta%ll_hsnif ) THEN
658	jfld = jfld + 1
659	blf_i(jfld) = bn_hsnif
660	ibdy(jfld) = ib_bdy
661	igrid(jfld) = 1
662	ilen1(jfld) = nblen(igrid(jfld))
663	ilen3(jfld) = 1
664	ENDIF
665
666	ENDIF
667	#elif defined key_lim3
668	! sea ice
669	IF( nn_ice_lim_dta(ib_bdy) == 1 ) THEN
670	! Test for types of ice input (lim2 or lim3)
671	! Build file name to find dimensions
672	clname=TRIM(bn_a_i%clname)
673	IF( .NOT. bn_a_i%ln_clim ) THEN
674	WRITE(clname, '(a,"_y",i4.4)' ) TRIM( bn_a_i%clname ), nyear ! add year
675	IF( bn_a_i%cltype /= 'yearly' ) WRITE(clname, '(a,"m" ,i2.2)' ) TRIM( clname ), nmonth ! add month
676	ELSE
677	IF( bn_a_i%cltype /= 'yearly' ) WRITE(clname, '(a,"_m",i2.2)' ) TRIM( bn_a_i%clname ), nmonth ! add month
678	ENDIF
679	IF( bn_a_i%cltype == 'daily' .OR. bn_a_i%cltype(1:4) == 'week' ) &
680	& WRITE(clname, '(a,"d" ,i2.2)' ) TRIM( clname ), nday ! add day
681	!
682	CALL iom_open ( clname, inum )
683	id1 = iom_varid( inum, bn_a_i%clvar, kdimsz=zdimsz, kndims=zndims, ldstop = .FALSE. )
684	CALL iom_close ( inum )
685
686	IF ( zndims == 4 ) THEN
687	ll_bdylim3 = .TRUE. ! lim3 input
688	ELSE
689	ll_bdylim3 = .FALSE. ! lim2 input
690	ENDIF
691	! End test
692
693	IF( dta%ll_a_i ) THEN
694	jfld = jfld + 1
695	blf_i(jfld) = bn_a_i
696	ibdy(jfld) = ib_bdy
697	igrid(jfld) = 1
698	ilen1(jfld) = nblen(igrid(jfld))
699	IF ( ll_bdylim3 ) THEN ; ilen3(jfld)=jpl ; ELSE ; ilen3(jfld)=1 ; ENDIF
700	ENDIF
701
702	IF( dta%ll_ht_i ) THEN
703	jfld = jfld + 1
704	blf_i(jfld) = bn_ht_i
705	ibdy(jfld) = ib_bdy
706	igrid(jfld) = 1
707	ilen1(jfld) = nblen(igrid(jfld))
708	IF ( ll_bdylim3 ) THEN ; ilen3(jfld)=jpl ; ELSE ; ilen3(jfld)=1 ; ENDIF
709	ENDIF
710
711	IF( dta%ll_ht_s ) THEN
712	jfld = jfld + 1
713	blf_i(jfld) = bn_ht_s
714	ibdy(jfld) = ib_bdy
715	igrid(jfld) = 1
716	ilen1(jfld) = nblen(igrid(jfld))
717	IF ( ll_bdylim3 ) THEN ; ilen3(jfld)=jpl ; ELSE ; ilen3(jfld)=1 ; ENDIF
718	ENDIF
719
720	ENDIF
721	#endif
722	! Recalculate field counts
723	!-------------------------
724	IF( ib_bdy == 1 ) THEN
725	nb_bdy_fld_sum = 0
726	nb_bdy_fld(ib_bdy) = jfld
727	nb_bdy_fld_sum = jfld
728	ELSE
729	nb_bdy_fld(ib_bdy) = jfld - nb_bdy_fld_sum
730	nb_bdy_fld_sum = nb_bdy_fld_sum + nb_bdy_fld(ib_bdy)
731	ENDIF
732
733	dta%nread(1) = nb_bdy_fld(ib_bdy)
734
735	ENDIF ! nn_dta == 1
736	ENDDO ! ib_bdy
737
738	DO jfld = 1, nb_bdy_fld_sum
739	ALLOCATE( bf(jfld)%fnow(ilen1(jfld),1,ilen3(jfld)) )
740	IF( blf_i(jfld)%ln_tint ) ALLOCATE( bf(jfld)%fdta(ilen1(jfld),1,ilen3(jfld),2) )
741	nbmap_ptr(jfld)%ptr => idx_bdy(ibdy(jfld))%nbmap(:,igrid(jfld))
742	nbmap_ptr(jfld)%ll_unstruc = ln_coords_file(ibdy(jfld))
743	ENDDO
744
745	! fill bf with blf_i and control print
746	!-------------------------------------
747	jstart = 1
748	DO ib_bdy = 1, nb_bdy
749	jend = jstart - 1 + nb_bdy_fld(ib_bdy)
750	CALL fld_fill( bf(jstart:jend), blf_i(jstart:jend), cn_dir_array(ib_bdy), 'bdy_dta', &
751	& 'open boundary conditions', 'nambdy_dta' )
752	jstart = jend + 1
753	ENDDO
754
755	! Initialise local boundary data arrays
756	! nn_xxx_dta=0 : allocate space - will be filled from initial conditions later
757	! nn_xxx_dta=1 : point to "fnow" arrays
758	!-------------------------------------
759
760	jfld = 0
761	DO ib_bdy=1, nb_bdy
762
763	nblen => idx_bdy(ib_bdy)%nblen
764	dta => dta_bdy(ib_bdy)
765
766	if(lwp) then
767	write(numout,*) '++++++ dta%ll_ssh = ',dta%ll_ssh
768	write(numout,*) '++++++ dta%ll_u2d = ',dta%ll_u2d
769	write(numout,*) '++++++ dta%ll_v2d = ',dta%ll_v2d
770	write(numout,*) '++++++ dta%ll_u3d = ',dta%ll_u3d
771	write(numout,*) '++++++ dta%ll_v3d = ',dta%ll_v3d
772	write(numout,*) '++++++ dta%ll_tem = ',dta%ll_tem
773	write(numout,*) '++++++ dta%ll_sal = ',dta%ll_sal
774	endif
775
776	IF ( nn_dyn2d_dta(ib_bdy) == 0 .or. nn_dyn2d_dta(ib_bdy) == 2 ) THEN
777	if(lwp) write(numout,*) '++++++ dta%ssh/u2d/u3d allocated space'
778	IF( dta%ll_ssh ) ALLOCATE( dta%ssh(nblen(1)) )
779	IF( dta%ll_u2d ) ALLOCATE( dta%u2d(nblen(2)) )
780	IF( dta%ll_v2d ) ALLOCATE( dta%v2d(nblen(3)) )
781	ENDIF
782	IF ( nn_dyn2d_dta(ib_bdy) == 1 .or. nn_dyn2d_dta(ib_bdy) == 3 ) THEN
783	IF( dta%ll_ssh ) THEN
784	if(lwp) write(numout,*) '++++++ dta%ssh pointing to fnow'
785	jfld = jfld + 1
786	dta%ssh => bf(jfld)%fnow(:,1,1)
787	ENDIF
788	IF ( dta%ll_u2d ) THEN
789	IF ( ln_full_vel_array(ib_bdy) ) THEN
790	if(lwp) write(numout,*) '++++++ dta%u2d allocated space'
791	ALLOCATE( dta%u2d(nblen(2)) )
792	ELSE
793	if(lwp) write(numout,*) '++++++ dta%u2d pointing to fnow'
794	jfld = jfld + 1
795	dta%u2d => bf(jfld)%fnow(:,1,1)
796	ENDIF
797	ENDIF
798	IF ( dta%ll_v2d ) THEN
799	IF ( ln_full_vel_array(ib_bdy) ) THEN
800	if(lwp) write(numout,*) '++++++ dta%v2d allocated space'
801	ALLOCATE( dta%v2d(nblen(3)) )
802	ELSE
803	if(lwp) write(numout,*) '++++++ dta%v2d pointing to fnow'
804	jfld = jfld + 1
805	dta%v2d => bf(jfld)%fnow(:,1,1)
806	ENDIF
807	ENDIF
808	ENDIF
809
810	IF ( nn_dyn3d_dta(ib_bdy) == 0 ) THEN
811	if(lwp) write(numout,*) '++++++ dta%u3d/v3d allocated space'
812	IF( dta%ll_u3d ) ALLOCATE( dta_bdy(ib_bdy)%u3d(nblen(2),jpk) )
813	IF( dta%ll_v3d ) ALLOCATE( dta_bdy(ib_bdy)%v3d(nblen(3),jpk) )
814	ENDIF
815	IF ( nn_dyn3d_dta(ib_bdy) == 1 .or. &
816	& ( ln_full_vel_array(ib_bdy) .and. ( nn_dyn2d_dta(ib_bdy) == 1 .or. nn_dyn2d_dta(ib_bdy) == 3 ) ) ) THEN
817	IF ( dta%ll_u3d .or. ( ln_full_vel_array(ib_bdy) .and. dta%ll_u2d ) ) THEN
818	if(lwp) write(numout,*) '++++++ dta%u3d pointing to fnow'
819	jfld = jfld + 1
820	dta_bdy(ib_bdy)%u3d => bf(jfld)%fnow(:,1,:)
821	ENDIF
822	IF ( dta%ll_v3d .or. ( ln_full_vel_array(ib_bdy) .and. dta%ll_v2d ) ) THEN
823	if(lwp) write(numout,*) '++++++ dta%v3d pointing to fnow'
824	jfld = jfld + 1
825	dta_bdy(ib_bdy)%v3d => bf(jfld)%fnow(:,1,:)
826	ENDIF
827	ENDIF
828
829	IF( nn_tra_dta(ib_bdy) == 0 ) THEN
830	if(lwp) write(numout,*) '++++++ dta%tem/sal allocated space'
831	IF( dta%ll_tem ) ALLOCATE( dta_bdy(ib_bdy)%tem(nblen(1),jpk) )
832	IF( dta%ll_sal ) ALLOCATE( dta_bdy(ib_bdy)%sal(nblen(1),jpk) )
833	ELSE
834	IF( dta%ll_tem ) THEN
835	if(lwp) write(numout,*) '++++++ dta%tem pointing to fnow'
836	jfld = jfld + 1
837	dta_bdy(ib_bdy)%tem => bf(jfld)%fnow(:,1,:)
838	ENDIF
839	IF( dta%ll_sal ) THEN
840	if(lwp) write(numout,*) '++++++ dta%sal pointing to fnow'
841	jfld = jfld + 1
842	dta_bdy(ib_bdy)%sal => bf(jfld)%fnow(:,1,:)
843	ENDIF
844	ENDIF
845
846	#if defined key_lim2
847	IF (cn_ice_lim(ib_bdy) /= 'none') THEN
848	IF( nn_ice_lim_dta(ib_bdy) == 0 ) THEN
849	ALLOCATE( dta_bdy(ib_bdy)%frld(nblen(1)) )
850	ALLOCATE( dta_bdy(ib_bdy)%hicif(nblen(1)) )
851	ALLOCATE( dta_bdy(ib_bdy)%hsnif(nblen(1)) )
852	ELSE
853	jfld = jfld + 1
854	dta_bdy(ib_bdy)%frld => bf(jfld)%fnow(:,1,1)
855	jfld = jfld + 1
856	dta_bdy(ib_bdy)%hicif => bf(jfld)%fnow(:,1,1)
857	jfld = jfld + 1
858	dta_bdy(ib_bdy)%hsnif => bf(jfld)%fnow(:,1,1)
859	ENDIF
860	ENDIF
861	#elif defined key_lim3
862	IF (cn_ice_lim(ib_bdy) /= 'none') THEN
863	IF( nn_ice_lim_dta(ib_bdy) == 0 ) THEN
864	ALLOCATE( dta_bdy(ib_bdy)%a_i (nblen(1),jpl) )
865	ALLOCATE( dta_bdy(ib_bdy)%ht_i(nblen(1),jpl) )
866	ALLOCATE( dta_bdy(ib_bdy)%ht_s(nblen(1),jpl) )
867	ELSE
868	IF ( ll_bdylim3 ) THEN ! case input is lim3 type
869	jfld = jfld + 1
870	dta_bdy(ib_bdy)%a_i => bf(jfld)%fnow(:,1,:)
871	jfld = jfld + 1
872	dta_bdy(ib_bdy)%ht_i => bf(jfld)%fnow(:,1,:)
873	jfld = jfld + 1
874	dta_bdy(ib_bdy)%ht_s => bf(jfld)%fnow(:,1,:)
875	ELSE ! case input is lim2 type
876	jfld_ai = jfld + 1
877	jfld_hti = jfld + 2
878	jfld_hts = jfld + 3
879	jfld = jfld + 3
880	ALLOCATE( dta_bdy(ib_bdy)%a_i (nblen(1),jpl) )
881	ALLOCATE( dta_bdy(ib_bdy)%ht_i(nblen(1),jpl) )
882	ALLOCATE( dta_bdy(ib_bdy)%ht_s(nblen(1),jpl) )
883	dta_bdy(ib_bdy)%a_i (:,:) = 0._wp
884	dta_bdy(ib_bdy)%ht_i(:,:) = 0._wp
885	dta_bdy(ib_bdy)%ht_s(:,:) = 0._wp
886	ENDIF
887
888	ENDIF
889	ENDIF
890	#endif
891	!
892	END DO ! ib_bdy
893	!
894	IF( nn_timing == 1 ) CALL timing_stop('bdy_dta_init')
895	!
896	END SUBROUTINE bdy_dta_init
897
898	!!==============================================================================
899	END MODULE bdydta

Note: See TracBrowser for help on using the repository browser.

Download in other formats: