New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traadv_fct.F90 in branches/2016/dev_merge_2016/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: branches/2016/dev_merge_2016/NEMOGCM/NEMO/OPA_SRC/TRA/traadv_fct.F90 @ 7403

Last change on this file since 7403 was 7403, checked in by timgraham, 8 years ago

Merge dev_INGV_METO_merge_2016 into branch
  • Property svn:keywords set to Id
File size: 41.9 KB
Line 
1MODULE traadv_fct
2   !!==============================================================================
3   !!                       ***  MODULE  traadv_fct  ***
4   !! Ocean  tracers:  horizontal & vertical advective trend (2nd/4th order Flux Corrected Transport method)
5   !!==============================================================================
6   !! History :  3.7  !  2015-09  (L. Debreu, G. Madec)  original code (inspired from traadv_tvd.F90)
7   !!----------------------------------------------------------------------
8
9   !!----------------------------------------------------------------------
10   !!  tra_adv_fct    : update the tracer trend with a 3D advective trends using a 2nd or 4th order FCT scheme
11   !!  tra_adv_fct_zts: update the tracer trend with a 3D advective trends using a 2nd order FCT scheme
12   !!                   with sub-time-stepping in the vertical direction
13   !!  nonosc         : compute monotonic tracer fluxes by a non-oscillatory algorithm
14   !!  interp_4th_cpt : 4th order compact scheme for the vertical component of the advection
15   !!----------------------------------------------------------------------
16   USE oce            ! ocean dynamics and active tracers
17   USE dom_oce        ! ocean space and time domain
18   USE trc_oce        ! share passive tracers/Ocean variables
19   USE trd_oce        ! trends: ocean variables
20   USE trdtra         ! tracers trends
21   USE diaptr         ! poleward transport diagnostics
22   USE diaar5         ! AR5 diagnostics
23   USE phycst, ONLY: rau0_rcp
24   !
25   USE in_out_manager ! I/O manager
26   USE iom
27   USE lib_mpp        ! MPP library
28   USE lbclnk         ! ocean lateral boundary condition (or mpp link)
29   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
30   USE wrk_nemo       ! Memory Allocation
31   USE timing         ! Timing
32
33   IMPLICIT NONE
34   PRIVATE
35
36   PUBLIC   tra_adv_fct        ! routine called by traadv.F90
37   PUBLIC   tra_adv_fct_zts    ! routine called by traadv.F90
38   PUBLIC   interp_4th_cpt     ! routine called by traadv_cen.F90
39
40   LOGICAL  ::   l_trd   ! flag to compute trends
41   LOGICAL  ::   l_ptr   ! flag to compute poleward transport
42   LOGICAL  ::   l_hst   ! flag to compute heat/salt transport
43   REAL(wp) ::   r1_6 = 1._wp / 6._wp   ! =1/6
44
45   !! * Substitutions
46#  include "vectopt_loop_substitute.h90"
47   !!----------------------------------------------------------------------
48   !! NEMO/OPA 3.7 , NEMO Consortium (2014)
49   !! $Id$
50   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
51   !!----------------------------------------------------------------------
52CONTAINS
53
54   SUBROUTINE tra_adv_fct( kt, kit000, cdtype, p2dt, pun, pvn, pwn,       &
55      &                                              ptb, ptn, pta, kjpt, kn_fct_h, kn_fct_v )
56      !!----------------------------------------------------------------------
57      !!                  ***  ROUTINE tra_adv_fct  ***
58      !!
59      !! **  Purpose :   Compute the now trend due to total advection of tracers
60      !!               and add it to the general trend of tracer equations
61      !!
62      !! **  Method  : - 2nd or 4th FCT scheme on the horizontal direction
63      !!               (choice through the value of kn_fct)
64      !!               - on the vertical the 4th order is a compact scheme
65      !!               - corrected flux (monotonic correction)
66      !!
67      !! ** Action : - update pta  with the now advective tracer trends
68      !!             - send trends to trdtra module for further diagnostcs (l_trdtra=T)
69      !!             - htr_adv, str_adv : poleward advective heat and salt transport (ln_diaptr=T)
70      !!----------------------------------------------------------------------
71      INTEGER                              , INTENT(in   ) ::   kt              ! ocean time-step index
72      INTEGER                              , INTENT(in   ) ::   kit000          ! first time step index
73      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype          ! =TRA or TRC (tracer indicator)
74      INTEGER                              , INTENT(in   ) ::   kjpt            ! number of tracers
75      INTEGER                              , INTENT(in   ) ::   kn_fct_h        ! order of the FCT scheme (=2 or 4)
76      INTEGER                              , INTENT(in   ) ::   kn_fct_v        ! order of the FCT scheme (=2 or 4)
77      REAL(wp)                             , INTENT(in   ) ::   p2dt            ! tracer time-step
78      REAL(wp), DIMENSION(jpi,jpj,jpk     ), INTENT(in   ) ::   pun, pvn, pwn   ! 3 ocean velocity components
79      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptb, ptn        ! before and now tracer fields
80      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pta             ! tracer trend
81      !
82      INTEGER  ::   ji, jj, jk, jn                           ! dummy loop indices 
83      REAL(wp) ::   ztra                                     ! local scalar
84      REAL(wp) ::   zfp_ui, zfp_vj, zfp_wk, zC2t_u, zC4t_u   !   -      -
85      REAL(wp) ::   zfm_ui, zfm_vj, zfm_wk, zC2t_v, zC4t_v   !   -      -
86      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zwi, zwx, zwy, zwz, ztu, ztv, zltu, zltv, ztw
87      REAL(wp), POINTER, DIMENSION(:,:,:) ::   ztrdx, ztrdy, ztrdz, zptry
88      REAL(wp), POINTER, DIMENSION(:,:)   :: z2d
89      !!----------------------------------------------------------------------
90      !
91      IF( nn_timing == 1 )  CALL timing_start('tra_adv_fct')
92      !
93      CALL wrk_alloc( jpi,jpj,jpk,   zwi, zwx, zwy, zwz, ztu, ztv, zltu, zltv, ztw )
94      !
95      IF( kt == kit000 )  THEN
96         IF(lwp) WRITE(numout,*)
97         IF(lwp) WRITE(numout,*) 'tra_adv_fct : FCT advection scheme on ', cdtype
98         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
99      ENDIF
100      !
101      l_trd = .FALSE.
102      l_hst = .FALSE.
103      l_ptr = .FALSE.
104      IF( ( cdtype == 'TRA'   .AND. l_trdtra ) .OR. ( cdtype == 'TRC' .AND. l_trdtrc ) )     l_trd = .TRUE.
105      IF(   cdtype == 'TRA'   .AND. ln_diaptr )                                              l_ptr = .TRUE. 
106      IF(   cdtype == 'TRA' .AND. ( iom_use("uadv_heattr") .OR. iom_use("vadv_heattr") .OR. &
107         &                          iom_use("uadv_salttr") .OR. iom_use("vadv_salttr")  ) )  l_hst = .TRUE.
108      !
109      IF( l_trd .OR. l_hst )  THEN
110         CALL wrk_alloc( jpi, jpj, jpk, ztrdx, ztrdy, ztrdz )
111         ztrdx(:,:,:) = 0._wp   ;    ztrdy(:,:,:) = 0._wp   ;   ztrdz(:,:,:) = 0._wp
112      ENDIF
113      !
114      IF( l_ptr ) THEN 
115         CALL wrk_alloc( jpi, jpj, jpk, zptry )
116         zptry(:,:,:) = 0._wp
117      ENDIF
118      !                          ! surface & bottom value : flux set to zero one for all
119      zwz(:,:, 1 ) = 0._wp           
120      zwx(:,:,jpk) = 0._wp   ;   zwy(:,:,jpk) = 0._wp    ;    zwz(:,:,jpk) = 0._wp
121      !
122      zwi(:,:,:) = 0._wp       
123      !
124      DO jn = 1, kjpt            !==  loop over the tracers  ==!
125         !
126         !        !==  upstream advection with initial mass fluxes & intermediate update  ==!
127         !                    !* upstream tracer flux in the i and j direction
128         DO jk = 1, jpkm1
129            DO jj = 1, jpjm1
130               DO ji = 1, fs_jpim1   ! vector opt.
131                  ! upstream scheme
132                  zfp_ui = pun(ji,jj,jk) + ABS( pun(ji,jj,jk) )
133                  zfm_ui = pun(ji,jj,jk) - ABS( pun(ji,jj,jk) )
134                  zfp_vj = pvn(ji,jj,jk) + ABS( pvn(ji,jj,jk) )
135                  zfm_vj = pvn(ji,jj,jk) - ABS( pvn(ji,jj,jk) )
136                  zwx(ji,jj,jk) = 0.5 * ( zfp_ui * ptb(ji,jj,jk,jn) + zfm_ui * ptb(ji+1,jj  ,jk,jn) )
137                  zwy(ji,jj,jk) = 0.5 * ( zfp_vj * ptb(ji,jj,jk,jn) + zfm_vj * ptb(ji  ,jj+1,jk,jn) )
138               END DO
139            END DO
140         END DO
141         !                    !* upstream tracer flux in the k direction *!
142         DO jk = 2, jpkm1        ! Interior value ( multiplied by wmask)
143            DO jj = 1, jpj
144               DO ji = 1, jpi
145                  zfp_wk = pwn(ji,jj,jk) + ABS( pwn(ji,jj,jk) )
146                  zfm_wk = pwn(ji,jj,jk) - ABS( pwn(ji,jj,jk) )
147                  zwz(ji,jj,jk) = 0.5 * ( zfp_wk * ptb(ji,jj,jk,jn) + zfm_wk * ptb(ji,jj,jk-1,jn) ) * wmask(ji,jj,jk)
148               END DO
149            END DO
150         END DO
151         IF( ln_linssh ) THEN    ! top ocean value (only in linear free surface as zwz has been w-masked)
152            IF( ln_isfcav ) THEN             ! top of the ice-shelf cavities and at the ocean surface
153               DO jj = 1, jpj
154                  DO ji = 1, jpi
155                     zwz(ji,jj, mikt(ji,jj) ) = pwn(ji,jj,mikt(ji,jj)) * ptb(ji,jj,mikt(ji,jj),jn)   ! linear free surface
156                  END DO
157               END DO   
158            ELSE                             ! no cavities: only at the ocean surface
159               zwz(:,:,1) = pwn(:,:,1) * ptb(:,:,1,jn)
160            ENDIF
161         ENDIF
162         !               
163         DO jk = 1, jpkm1     !* trend and after field with monotonic scheme
164            DO jj = 2, jpjm1
165               DO ji = fs_2, fs_jpim1   ! vector opt.
166                  !                             ! total intermediate advective trends
167                  ztra = - (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
168                     &      + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
169                     &      + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) ) * r1_e1e2t(ji,jj)
170                  !                             ! update and guess with monotonic sheme
171                  pta(ji,jj,jk,jn) =                     pta(ji,jj,jk,jn) +        ztra   / e3t_n(ji,jj,jk) * tmask(ji,jj,jk)
172                  zwi(ji,jj,jk)    = ( e3t_b(ji,jj,jk) * ptb(ji,jj,jk,jn) + p2dt * ztra ) / e3t_a(ji,jj,jk) * tmask(ji,jj,jk)
173               END DO
174            END DO
175         END DO
176         CALL lbc_lnk( zwi, 'T', 1. )  ! Lateral boundary conditions on zwi  (unchanged sign)
177         !               
178         IF( l_trd .OR. l_hst )  THEN             ! trend diagnostics (contribution of upstream fluxes)
179            ztrdx(:,:,:) = zwx(:,:,:)   ;   ztrdy(:,:,:) = zwy(:,:,:)   ;   ztrdz(:,:,:) = zwz(:,:,:)
180         END IF
181         !                             ! "Poleward" heat and salt transports (contribution of upstream fluxes)
182         IF( l_ptr )  zptry(:,:,:) = zwy(:,:,:) 
183         !
184         !        !==  anti-diffusive flux : high order minus low order  ==!
185         !
186         SELECT CASE( kn_fct_h )    !* horizontal anti-diffusive fluxes
187         !
188         CASE(  2  )                   !- 2nd order centered
189            DO jk = 1, jpkm1
190               DO jj = 1, jpjm1
191                  DO ji = 1, fs_jpim1   ! vector opt.
192                     zwx(ji,jj,jk) = 0.5_wp * pun(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji+1,jj,jk,jn) ) - zwx(ji,jj,jk)
193                     zwy(ji,jj,jk) = 0.5_wp * pvn(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji,jj+1,jk,jn) ) - zwy(ji,jj,jk)
194                  END DO
195               END DO
196            END DO
197            !
198         CASE(  4  )                   !- 4th order centered
199            zltu(:,:,jpk) = 0._wp            ! Bottom value : flux set to zero
200            zltv(:,:,jpk) = 0._wp
201            DO jk = 1, jpkm1                 ! Laplacian
202               DO jj = 1, jpjm1                    ! 1st derivative (gradient)
203                  DO ji = 1, fs_jpim1   ! vector opt.
204                     ztu(ji,jj,jk) = ( ptn(ji+1,jj  ,jk,jn) - ptn(ji,jj,jk,jn) ) * umask(ji,jj,jk)
205                     ztv(ji,jj,jk) = ( ptn(ji  ,jj+1,jk,jn) - ptn(ji,jj,jk,jn) ) * vmask(ji,jj,jk)
206                  END DO
207               END DO
208               DO jj = 2, jpjm1                    ! 2nd derivative * 1/ 6
209                  DO ji = fs_2, fs_jpim1   ! vector opt.
210                     zltu(ji,jj,jk) = (  ztu(ji,jj,jk) + ztu(ji-1,jj,jk)  ) * r1_6
211                     zltv(ji,jj,jk) = (  ztv(ji,jj,jk) + ztv(ji,jj-1,jk)  ) * r1_6
212                  END DO
213               END DO
214            END DO
215            CALL lbc_lnk( zltu, 'T', 1. )   ;    CALL lbc_lnk( zltv, 'T', 1. )   ! Lateral boundary cond. (unchanged sgn)
216            !
217            DO jk = 1, jpkm1                 ! Horizontal advective fluxes
218               DO jj = 1, jpjm1
219                  DO ji = 1, fs_jpim1   ! vector opt.
220                     zC2t_u = ptn(ji,jj,jk,jn) + ptn(ji+1,jj  ,jk,jn)   ! 2 x C2 interpolation of T at u- & v-points
221                     zC2t_v = ptn(ji,jj,jk,jn) + ptn(ji  ,jj+1,jk,jn)
222                     !                                                  ! C4 minus upstream advective fluxes
223                     zwx(ji,jj,jk) =  0.5_wp * pun(ji,jj,jk) * ( zC2t_u + zltu(ji,jj,jk) - zltu(ji+1,jj,jk) ) - zwx(ji,jj,jk)
224                     zwy(ji,jj,jk) =  0.5_wp * pvn(ji,jj,jk) * ( zC2t_v + zltv(ji,jj,jk) - zltv(ji,jj+1,jk) ) - zwy(ji,jj,jk)
225                  END DO
226               END DO
227            END DO         
228            !
229         CASE(  41 )                   !- 4th order centered       ==>>   !!gm coding attempt   need to be tested
230            ztu(:,:,jpk) = 0._wp             ! Bottom value : flux set to zero
231            ztv(:,:,jpk) = 0._wp
232            DO jk = 1, jpkm1                 ! 1st derivative (gradient)
233               DO jj = 1, jpjm1
234                  DO ji = 1, fs_jpim1   ! vector opt.
235                     ztu(ji,jj,jk) = ( ptn(ji+1,jj  ,jk,jn) - ptn(ji,jj,jk,jn) ) * umask(ji,jj,jk)
236                     ztv(ji,jj,jk) = ( ptn(ji  ,jj+1,jk,jn) - ptn(ji,jj,jk,jn) ) * vmask(ji,jj,jk)
237                  END DO
238               END DO
239            END DO
240            CALL lbc_lnk( ztu, 'U', -1. )   ;    CALL lbc_lnk( ztv, 'V', -1. )   ! Lateral boundary cond. (unchanged sgn)
241            !
242            DO jk = 1, jpkm1                 ! Horizontal advective fluxes
243               DO jj = 2, jpjm1
244                  DO ji = 2, fs_jpim1   ! vector opt.
245                     zC2t_u = ptn(ji,jj,jk,jn) + ptn(ji+1,jj  ,jk,jn)   ! 2 x C2 interpolation of T at u- & v-points (x2)
246                     zC2t_v = ptn(ji,jj,jk,jn) + ptn(ji  ,jj+1,jk,jn)
247                     !                                                  ! C4 interpolation of T at u- & v-points (x2)
248                     zC4t_u =  zC2t_u + r1_6 * ( ztu(ji-1,jj  ,jk) - ztu(ji+1,jj  ,jk) )
249                     zC4t_v =  zC2t_v + r1_6 * ( ztv(ji  ,jj-1,jk) - ztv(ji  ,jj+1,jk) )
250                     !                                                  ! C4 minus upstream advective fluxes
251                     zwx(ji,jj,jk) =  0.5_wp * pun(ji,jj,jk) * zC4t_u - zwx(ji,jj,jk)
252                     zwy(ji,jj,jk) =  0.5_wp * pvn(ji,jj,jk) * zC4t_v - zwy(ji,jj,jk)
253                  END DO
254               END DO
255            END DO
256            !
257         END SELECT
258         !                     
259         SELECT CASE( kn_fct_v )    !* vertical anti-diffusive fluxes (w-masked interior values)
260         !
261         CASE(  2  )                   !- 2nd order centered
262            DO jk = 2, jpkm1   
263               DO jj = 2, jpjm1
264                  DO ji = fs_2, fs_jpim1
265                     zwz(ji,jj,jk) =  (  pwn(ji,jj,jk) * 0.5_wp * ( ptn(ji,jj,jk,jn) + ptn(ji,jj,jk-1,jn) )   &
266                        &              - zwz(ji,jj,jk)  ) * wmask(ji,jj,jk)
267                  END DO
268               END DO
269            END DO
270            !
271         CASE(  4  )                   !- 4th order COMPACT
272            CALL interp_4th_cpt( ptn(:,:,:,jn) , ztw )   ! zwt = COMPACT interpolation of T at w-point
273            DO jk = 2, jpkm1
274               DO jj = 2, jpjm1
275                  DO ji = fs_2, fs_jpim1
276                     zwz(ji,jj,jk) = ( pwn(ji,jj,jk) * ztw(ji,jj,jk) - zwz(ji,jj,jk) ) * wmask(ji,jj,jk)
277                  END DO
278               END DO
279            END DO
280            !
281         END SELECT
282         IF( ln_linssh ) THEN    ! top ocean value: high order = upstream  ==>>  zwz=0
283            zwz(:,:,1) = 0._wp   ! only ocean surface as interior zwz values have been w-masked
284         ENDIF
285         !
286         CALL lbc_lnk( zwx, 'U', -1. )   ;   CALL lbc_lnk( zwy, 'V', -1. )         ! Lateral bondary conditions
287         CALL lbc_lnk( zwz, 'W',  1. )
288         !
289         !        !==  monotonicity algorithm  ==!
290         !
291         CALL nonosc( ptb(:,:,:,jn), zwx, zwy, zwz, zwi, p2dt )
292         !
293         !        !==  final trend with corrected fluxes  ==!
294         !
295         DO jk = 1, jpkm1
296            DO jj = 2, jpjm1
297               DO ji = fs_2, fs_jpim1   ! vector opt. 
298                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) - (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
299                     &                                   + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
300                     &                                   + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) ) &
301                     &                                * r1_e1e2t(ji,jj) / e3t_n(ji,jj,jk)
302               END DO
303            END DO
304         END DO
305         !
306         IF( l_trd .OR. l_hst ) THEN     ! trend diagnostics (contribution of upstream fluxes)
307            ztrdx(:,:,:) = ztrdx(:,:,:) + zwx(:,:,:)  ! <<< Add to previously computed
308            ztrdy(:,:,:) = ztrdy(:,:,:) + zwy(:,:,:)  ! <<< Add to previously computed
309            ztrdz(:,:,:) = ztrdz(:,:,:) + zwz(:,:,:)  ! <<< Add to previously computed
310         ENDIF
311            !
312         IF( l_trd ) THEN
313            CALL trd_tra( kt, cdtype, jn, jptra_xad, ztrdx, pun, ptn(:,:,:,jn) )
314            CALL trd_tra( kt, cdtype, jn, jptra_yad, ztrdy, pvn, ptn(:,:,:,jn) )
315            CALL trd_tra( kt, cdtype, jn, jptra_zad, ztrdz, pwn, ptn(:,:,:,jn) )
316            !
317         END IF
318         !                                !  heat/salt transport
319         IF( l_hst )  CALL dia_ar5_hst( jn, 'adv', ztrdx(:,:,:), ztrdy(:,:,:) )
320
321         !                                ! "Poleward" heat and salt transports (contribution of upstream fluxes)
322         IF( l_ptr ) THEN 
323            zptry(:,:,:) = zptry(:,:,:) + zwy(:,:,:)  ! <<< Add to previously computed
324            CALL dia_ptr_hst( jn, 'adv', zptry(:,:,:) )
325         ENDIF
326         !
327      END DO                     ! end of tracer loop
328      !
329                              CALL wrk_dealloc( jpi,jpj,jpk,    zwi, zwx, zwy, zwz, ztu, ztv, zltu, zltv, ztw )
330      IF( l_trd .OR. l_hst )  CALL wrk_dealloc( jpi, jpj, jpk, ztrdx, ztrdy, ztrdz )
331      IF( l_ptr )             CALL wrk_dealloc( jpi, jpj, jpk, zptry )
332      !
333      IF( nn_timing == 1 )  CALL timing_stop('tra_adv_fct')
334      !
335   END SUBROUTINE tra_adv_fct
336
337
338   SUBROUTINE tra_adv_fct_zts( kt, kit000, cdtype, p2dt, pun, pvn, pwn,      &
339      &                                                  ptb, ptn, pta, kjpt, kn_fct_zts )
340      !!----------------------------------------------------------------------
341      !!                  ***  ROUTINE tra_adv_fct_zts  ***
342      !!
343      !! **  Purpose :   Compute the now trend due to total advection of
344      !!       tracers and add it to the general trend of tracer equations
345      !!
346      !! **  Method  :   TVD ZTS scheme, i.e. 2nd order centered scheme with
347      !!       corrected flux (monotonic correction). This version use sub-
348      !!       timestepping for the vertical advection which increases stability
349      !!       when vertical metrics are small.
350      !!       note: - this advection scheme needs a leap-frog time scheme
351      !!
352      !! ** Action : - update (pta) with the now advective tracer trends
353      !!             - save the trends
354      !!----------------------------------------------------------------------
355      INTEGER                              , INTENT(in   ) ::   kt              ! ocean time-step index
356      INTEGER                              , INTENT(in   ) ::   kit000          ! first time step index
357      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype          ! =TRA or TRC (tracer indicator)
358      INTEGER                              , INTENT(in   ) ::   kjpt            ! number of tracers
359      INTEGER                              , INTENT(in   ) ::   kn_fct_zts      ! number of number of vertical sub-timesteps
360      REAL(wp)                             , INTENT(in   ) ::   p2dt            ! tracer time-step
361      REAL(wp), DIMENSION(jpi,jpj,jpk     ), INTENT(in   ) ::   pun, pvn, pwn   ! 3 ocean velocity components
362      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptb, ptn        ! before and now tracer fields
363      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pta             ! tracer trend
364      !
365      REAL(wp), DIMENSION( jpk )                           ::   zts             ! length of sub-timestep for vertical advection
366      REAL(wp)                                             ::   zr_p2dt         ! reciprocal of tracer timestep
367      INTEGER  ::   ji, jj, jk, jl, jn       ! dummy loop indices 
368      INTEGER  ::   jtb, jtn, jta   ! sub timestep pointers for leap-frog/euler forward steps
369      INTEGER  ::   jtaken          ! toggle for collecting appropriate fluxes from sub timesteps
370      REAL(wp) ::   z_rzts          ! Fractional length of Euler forward sub-timestep for vertical advection
371      REAL(wp) ::   ztra            ! local scalar
372      REAL(wp) ::   zfp_ui, zfp_vj, zfp_wk   !   -      -
373      REAL(wp) ::   zfm_ui, zfm_vj, zfm_wk   !   -      -
374      REAL(wp), POINTER, DIMENSION(:,:  )   ::   zwx_sav , zwy_sav
375      REAL(wp), POINTER, DIMENSION(:,:,:)   ::   zwi, zwx, zwy, zwz, zhdiv, zwzts, zwz_sav
376      REAL(wp), POINTER, DIMENSION(:,:,:)   ::   ztrdx, ztrdy, ztrdz
377      REAL(wp), POINTER, DIMENSION(:,:,:) :: zptry
378      REAL(wp), POINTER, DIMENSION(:,:,:,:) ::   ztrs
379      !!----------------------------------------------------------------------
380      !
381      IF( nn_timing == 1 )  CALL timing_start('tra_adv_fct_zts')
382      !
383      CALL wrk_alloc( jpi,jpj,             zwx_sav, zwy_sav )
384      CALL wrk_alloc( jpi,jpj,jpk,         zwx, zwy, zwz, zwi, zhdiv, zwzts, zwz_sav )
385      CALL wrk_alloc( jpi,jpj,jpk,kjpt+1,  ztrs )
386      !
387      IF( kt == kit000 )  THEN
388         IF(lwp) WRITE(numout,*)
389         IF(lwp) WRITE(numout,*) 'tra_adv_fct_zts : 2nd order FCT scheme with ', kn_fct_zts, ' vertical sub-timestep on ', cdtype
390         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
391      ENDIF
392      !
393      l_trd = .FALSE.
394      l_hst = .FALSE.
395      l_ptr = .FALSE.
396      IF( ( cdtype == 'TRA' .AND. l_trdtra ) .OR. ( cdtype == 'TRC' .AND. l_trdtrc ) )      l_trd = .TRUE.
397      IF(   cdtype == 'TRA' .AND. ln_diaptr )                                               l_ptr = .TRUE. 
398      IF(   cdtype == 'TRA' .AND. ( iom_use("uadv_heattr") .OR. iom_use("vadv_heattr") .OR. &
399         &                          iom_use("uadv_salttr") .OR. iom_use("vadv_salttr")  ) ) l_hst = .TRUE.
400      !
401      IF( l_trd .OR. l_hst )  THEN
402         CALL wrk_alloc( jpi,jpj,jpk,   ztrdx, ztrdy, ztrdz )
403         ztrdx(:,:,:) = 0._wp  ;    ztrdy(:,:,:) = 0._wp  ;   ztrdz(:,:,:) = 0._wp
404      ENDIF
405      !
406      IF( l_ptr ) THEN 
407         CALL wrk_alloc( jpi, jpj,jpk, zptry )
408         zptry(:,:,:) = 0._wp
409      ENDIF
410      zwi(:,:,:) = 0._wp
411      z_rzts = 1._wp / REAL( kn_fct_zts, wp )
412      zr_p2dt = 1._wp / p2dt
413      !
414      ! surface & Bottom value : flux set to zero for all tracers
415      zwz(:,:, 1 ) = 0._wp
416      zwx(:,:,jpk) = 0._wp   ;    zwz(:,:,jpk) = 0._wp
417      zwy(:,:,jpk) = 0._wp   ;    zwi(:,:,jpk) = 0._wp
418      !
419      !                                                          ! ===========
420      DO jn = 1, kjpt                                            ! tracer loop
421         !                                                       ! ===========
422         !
423         ! Upstream advection with initial mass fluxes & intermediate update
424         DO jk = 1, jpkm1        ! upstream tracer flux in the i and j direction
425            DO jj = 1, jpjm1
426               DO ji = 1, fs_jpim1   ! vector opt.
427                  ! upstream scheme
428                  zfp_ui = pun(ji,jj,jk) + ABS( pun(ji,jj,jk) )
429                  zfm_ui = pun(ji,jj,jk) - ABS( pun(ji,jj,jk) )
430                  zfp_vj = pvn(ji,jj,jk) + ABS( pvn(ji,jj,jk) )
431                  zfm_vj = pvn(ji,jj,jk) - ABS( pvn(ji,jj,jk) )
432                  zwx(ji,jj,jk) = 0.5_wp * ( zfp_ui * ptb(ji,jj,jk,jn) + zfm_ui * ptb(ji+1,jj  ,jk,jn) )
433                  zwy(ji,jj,jk) = 0.5_wp * ( zfp_vj * ptb(ji,jj,jk,jn) + zfm_vj * ptb(ji  ,jj+1,jk,jn) )
434               END DO
435            END DO
436         END DO
437         !                       ! upstream tracer flux in the k direction
438         DO jk = 2, jpkm1              ! Interior value
439            DO jj = 1, jpj
440               DO ji = 1, jpi
441                  zfp_wk = pwn(ji,jj,jk) + ABS( pwn(ji,jj,jk) )
442                  zfm_wk = pwn(ji,jj,jk) - ABS( pwn(ji,jj,jk) )
443                  zwz(ji,jj,jk) = 0.5_wp * ( zfp_wk * ptb(ji,jj,jk,jn) + zfm_wk * ptb(ji,jj,jk-1,jn) ) * wmask(ji,jj,jk)
444               END DO
445            END DO
446         END DO
447         IF( ln_linssh ) THEN          ! top value : linear free surface case only (as zwz is multiplied by wmask)
448            IF( ln_isfcav ) THEN             ! ice-shelf cavities: top value
449               DO jj = 1, jpj
450                  DO ji = 1, jpi
451                     zwz(ji,jj, mikt(ji,jj) ) = pwn(ji,jj,mikt(ji,jj)) * ptb(ji,jj,mikt(ji,jj),jn) 
452                  END DO
453               END DO   
454            ELSE                             ! no cavities, surface value
455               zwz(:,:,1) = pwn(:,:,1) * ptb(:,:,1,jn)
456            ENDIF
457         ENDIF
458         !
459         DO jk = 1, jpkm1         ! total advective trend
460            DO jj = 2, jpjm1
461               DO ji = fs_2, fs_jpim1   ! vector opt.
462                  !                             ! total intermediate advective trends
463                  ztra = - (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
464                     &      + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
465                     &      + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1)   ) * r1_e1e2t(ji,jj)
466                  !                             ! update and guess with monotonic sheme
467                  pta(ji,jj,jk,jn) =                     pta(ji,jj,jk,jn) +        ztra   / e3t_n(ji,jj,jk) * tmask(ji,jj,jk)
468                  zwi(ji,jj,jk)    = ( e3t_b(ji,jj,jk) * ptb(ji,jj,jk,jn) + p2dt * ztra ) / e3t_a(ji,jj,jk) * tmask(ji,jj,jk)
469               END DO
470            END DO
471         END DO
472         !                           
473         CALL lbc_lnk( zwi, 'T', 1. )     ! Lateral boundary conditions on zwi  (unchanged sign)
474         !               
475         IF( l_trd .OR. l_hst )  THEN                ! trend diagnostics (contribution of upstream fluxes)
476            ztrdx(:,:,:) = zwx(:,:,:)   ;    ztrdy(:,:,:) = zwy(:,:,:)  ;   ztrdz(:,:,:) = zwz(:,:,:)
477         END IF
478         !                                ! "Poleward" heat and salt transports (contribution of upstream fluxes)
479         IF( l_ptr )  zptry(:,:,:) = zwy(:,:,:)
480
481         ! 3. anti-diffusive flux : high order minus low order
482         ! ---------------------------------------------------
483
484         DO jk = 1, jpkm1                    !* horizontal anti-diffusive fluxes
485            !
486            DO jj = 1, jpjm1
487               DO ji = 1, fs_jpim1   ! vector opt.
488                  zwx_sav(ji,jj) = zwx(ji,jj,jk)
489                  zwy_sav(ji,jj) = zwy(ji,jj,jk)
490                  !
491                  zwx(ji,jj,jk) = 0.5_wp * pun(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji+1,jj,jk,jn) )
492                  zwy(ji,jj,jk) = 0.5_wp * pvn(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji,jj+1,jk,jn) )
493               END DO
494            END DO
495            !
496            DO jj = 2, jpjm1                    ! partial horizontal divergence
497               DO ji = fs_2, fs_jpim1
498                  zhdiv(ji,jj,jk) = (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk)   &
499                     &               + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk)  )
500               END DO
501            END DO
502            !
503            DO jj = 1, jpjm1
504               DO ji = 1, fs_jpim1   ! vector opt.
505                  zwx(ji,jj,jk) = zwx(ji,jj,jk) - zwx_sav(ji,jj)
506                  zwy(ji,jj,jk) = zwy(ji,jj,jk) - zwy_sav(ji,jj)
507               END DO
508            END DO
509         END DO
510         !
511         !                                !* vertical anti-diffusive flux
512         zwz_sav(:,:,:)   = zwz(:,:,:)
513         ztrs   (:,:,:,1) = ptb(:,:,:,jn)
514         ztrs   (:,:,1,2) = ptb(:,:,1,jn)
515         ztrs   (:,:,1,3) = ptb(:,:,1,jn)
516         zwzts  (:,:,:)   = 0._wp
517         !
518         DO jl = 1, kn_fct_zts                  ! Start of sub timestepping loop
519            !
520            IF( jl == 1 ) THEN                        ! Euler forward to kick things off
521               jtb = 1   ;   jtn = 1   ;   jta = 2
522               zts(:) = p2dt * z_rzts
523               jtaken = MOD( kn_fct_zts + 1 , 2)            ! Toggle to collect every second flux
524               !                                            ! starting at jl =1 if kn_fct_zts is odd;
525               !                                            ! starting at jl =2 otherwise
526            ELSEIF( jl == 2 ) THEN                    ! First leapfrog step
527               jtb = 1   ;   jtn = 2   ;   jta = 3
528               zts(:) = 2._wp * p2dt * z_rzts
529            ELSE                                      ! Shuffle pointers for subsequent leapfrog steps
530               jtb = MOD(jtb,3) + 1
531               jtn = MOD(jtn,3) + 1
532               jta = MOD(jta,3) + 1
533            ENDIF
534            DO jk = 2, jpkm1                          ! interior value
535               DO jj = 2, jpjm1
536                  DO ji = fs_2, fs_jpim1
537                     zwz(ji,jj,jk) = 0.5_wp * pwn(ji,jj,jk) * ( ztrs(ji,jj,jk,jtn) + ztrs(ji,jj,jk-1,jtn) ) * wmask(ji,jj,jk)
538                     IF( jtaken == 0 )   zwzts(ji,jj,jk) = zwzts(ji,jj,jk) + zwz(ji,jj,jk) * zts(jk)    ! Accumulate time-weighted vertcal flux
539                  END DO
540               END DO
541            END DO
542            IF( ln_linssh ) THEN                    ! top value (only in linear free surface case)
543               IF( ln_isfcav ) THEN                      ! ice-shelf cavities
544                  DO jj = 1, jpj
545                     DO ji = 1, jpi
546                        zwz(ji,jj, mikt(ji,jj) ) = pwn(ji,jj,mikt(ji,jj)) * ptb(ji,jj,mikt(ji,jj),jn)   ! linear free surface
547                     END DO
548                  END DO   
549               ELSE                                      ! no ocean cavities
550                  zwz(:,:,1) = pwn(:,:,1) * ptb(:,:,1,jn)
551               ENDIF
552            ENDIF
553            !
554            jtaken = MOD( jtaken + 1 , 2 )
555            !
556            DO jk = 2, jpkm1                             ! total advective trends
557               DO jj = 2, jpjm1
558                  DO ji = fs_2, fs_jpim1
559                     ztrs(ji,jj,jk,jta) = ztrs(ji,jj,jk,jtb)                                                 &
560                        &               - zts(jk) * (  zhdiv(ji,jj,jk) + zwz(ji,jj,jk) - zwz(ji,jj,jk+1) )   &
561                        &                         * r1_e1e2t(ji,jj) / e3t_n(ji,jj,jk)
562                  END DO
563               END DO
564            END DO
565            !
566         END DO
567
568         DO jk = 2, jpkm1          ! Anti-diffusive vertical flux using average flux from the sub-timestepping
569            DO jj = 2, jpjm1
570               DO ji = fs_2, fs_jpim1
571                  zwz(ji,jj,jk) = ( zwzts(ji,jj,jk) * zr_p2dt - zwz_sav(ji,jj,jk) ) * wmask(ji,jj,jk)
572               END DO
573            END DO
574         END DO
575         CALL lbc_lnk( zwx, 'U', -1. )   ;   CALL lbc_lnk( zwy, 'V', -1. )         ! Lateral bondary conditions
576         CALL lbc_lnk( zwz, 'W',  1. )
577
578         ! 4. monotonicity algorithm
579         ! -------------------------
580         CALL nonosc( ptb(:,:,:,jn), zwx, zwy, zwz, zwi, p2dt )
581
582
583         ! 5. final trend with corrected fluxes
584         ! ------------------------------------
585         DO jk = 1, jpkm1
586            DO jj = 2, jpjm1
587               DO ji = fs_2, fs_jpim1   ! vector opt. 
588                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + (   zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )       &
589                     &                                    + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1)   )   &
590                     &                                * r1_e1e2t(ji,jj) / e3t_n(ji,jj,jk)
591               END DO
592            END DO
593         END DO
594
595        !
596         IF( l_trd .OR. l_hst ) THEN     ! trend diagnostics (contribution of upstream fluxes)
597            ztrdx(:,:,:) = ztrdx(:,:,:) + zwx(:,:,:)  ! <<< Add to previously computed
598            ztrdy(:,:,:) = ztrdy(:,:,:) + zwy(:,:,:)  ! <<< Add to previously computed
599            ztrdz(:,:,:) = ztrdz(:,:,:) + zwz(:,:,:)  ! <<< Add to previously computed
600         ENDIF
601            !
602         IF( l_trd ) THEN
603            CALL trd_tra( kt, cdtype, jn, jptra_xad, ztrdx, pun, ptn(:,:,:,jn) )
604            CALL trd_tra( kt, cdtype, jn, jptra_yad, ztrdy, pvn, ptn(:,:,:,jn) )
605            CALL trd_tra( kt, cdtype, jn, jptra_zad, ztrdz, pwn, ptn(:,:,:,jn) )
606            !
607         END IF
608         !                                             ! heat/salt transport
609         IF( l_hst )  CALL dia_ar5_hst( jn, 'adv', ztrdx(:,:,:), ztrdy(:,:,:) )
610
611         !                                            ! "Poleward" heat and salt transports (contribution of upstream fluxes)
612         IF( l_ptr ) THEN 
613            zptry(:,:,:) = zptry(:,:,:) + zwy(:,:,:)  ! <<< Add to previously computed
614            CALL dia_ptr_hst( jn, 'adv', zptry(:,:,:) )
615         ENDIF
616         !
617      END DO
618      !
619                              CALL wrk_alloc( jpi,jpj,             zwx_sav, zwy_sav )
620                              CALL wrk_alloc( jpi,jpj, jpk,        zwx, zwy, zwz, zwi, zhdiv, zwzts, zwz_sav )
621                              CALL wrk_alloc( jpi,jpj,jpk,kjpt+1,  ztrs )
622      IF( l_trd .OR. l_hst )  CALL wrk_dealloc( jpi, jpj, jpk, ztrdx, ztrdy, ztrdz )
623      IF( l_ptr )             CALL wrk_dealloc( jpi, jpj, jpk, zptry )
624      !
625      IF( nn_timing == 1 )  CALL timing_stop('tra_adv_fct_zts')
626      !
627   END SUBROUTINE tra_adv_fct_zts
628
629
630   SUBROUTINE nonosc( pbef, paa, pbb, pcc, paft, p2dt )
631      !!---------------------------------------------------------------------
632      !!                    ***  ROUTINE nonosc  ***
633      !!     
634      !! **  Purpose :   compute monotonic tracer fluxes from the upstream
635      !!       scheme and the before field by a nonoscillatory algorithm
636      !!
637      !! **  Method  :   ... ???
638      !!       warning : pbef and paft must be masked, but the boundaries
639      !!       conditions on the fluxes are not necessary zalezak (1979)
640      !!       drange (1995) multi-dimensional forward-in-time and upstream-
641      !!       in-space based differencing for fluid
642      !!----------------------------------------------------------------------
643      REAL(wp)                         , INTENT(in   ) ::   p2dt            ! tracer time-step
644      REAL(wp), DIMENSION (jpi,jpj,jpk), INTENT(in   ) ::   pbef, paft      ! before & after field
645      REAL(wp), DIMENSION (jpi,jpj,jpk), INTENT(inout) ::   paa, pbb, pcc   ! monotonic fluxes in the 3 directions
646      !
647      INTEGER  ::   ji, jj, jk   ! dummy loop indices
648      INTEGER  ::   ikm1         ! local integer
649      REAL(wp) ::   zpos, zneg, zbt, za, zb, zc, zbig, zrtrn    ! local scalars
650      REAL(wp) ::   zau, zbu, zcu, zav, zbv, zcv, zup, zdo            !   -      -
651      REAL(wp), POINTER, DIMENSION(:,:,:) :: zbetup, zbetdo, zbup, zbdo
652      !!----------------------------------------------------------------------
653      !
654      IF( nn_timing == 1 )  CALL timing_start('nonosc')
655      !
656      CALL wrk_alloc( jpi, jpj, jpk, zbetup, zbetdo, zbup, zbdo )
657      !
658      zbig  = 1.e+40_wp
659      zrtrn = 1.e-15_wp
660      zbetup(:,:,:) = 0._wp   ;   zbetdo(:,:,:) = 0._wp
661
662      ! Search local extrema
663      ! --------------------
664      ! max/min of pbef & paft with large negative/positive value (-/+zbig) inside land
665      zbup = MAX( pbef * tmask - zbig * ( 1._wp - tmask ),   &
666         &        paft * tmask - zbig * ( 1._wp - tmask )  )
667      zbdo = MIN( pbef * tmask + zbig * ( 1._wp - tmask ),   &
668         &        paft * tmask + zbig * ( 1._wp - tmask )  )
669
670      DO jk = 1, jpkm1
671         ikm1 = MAX(jk-1,1)
672         DO jj = 2, jpjm1
673            DO ji = fs_2, fs_jpim1   ! vector opt.
674
675               ! search maximum in neighbourhood
676               zup = MAX(  zbup(ji  ,jj  ,jk  ),   &
677                  &        zbup(ji-1,jj  ,jk  ), zbup(ji+1,jj  ,jk  ),   &
678                  &        zbup(ji  ,jj-1,jk  ), zbup(ji  ,jj+1,jk  ),   &
679                  &        zbup(ji  ,jj  ,ikm1), zbup(ji  ,jj  ,jk+1)  )
680
681               ! search minimum in neighbourhood
682               zdo = MIN(  zbdo(ji  ,jj  ,jk  ),   &
683                  &        zbdo(ji-1,jj  ,jk  ), zbdo(ji+1,jj  ,jk  ),   &
684                  &        zbdo(ji  ,jj-1,jk  ), zbdo(ji  ,jj+1,jk  ),   &
685                  &        zbdo(ji  ,jj  ,ikm1), zbdo(ji  ,jj  ,jk+1)  )
686
687               ! positive part of the flux
688               zpos = MAX( 0., paa(ji-1,jj  ,jk  ) ) - MIN( 0., paa(ji  ,jj  ,jk  ) )   &
689                  & + MAX( 0., pbb(ji  ,jj-1,jk  ) ) - MIN( 0., pbb(ji  ,jj  ,jk  ) )   &
690                  & + MAX( 0., pcc(ji  ,jj  ,jk+1) ) - MIN( 0., pcc(ji  ,jj  ,jk  ) )
691
692               ! negative part of the flux
693               zneg = MAX( 0., paa(ji  ,jj  ,jk  ) ) - MIN( 0., paa(ji-1,jj  ,jk  ) )   &
694                  & + MAX( 0., pbb(ji  ,jj  ,jk  ) ) - MIN( 0., pbb(ji  ,jj-1,jk  ) )   &
695                  & + MAX( 0., pcc(ji  ,jj  ,jk  ) ) - MIN( 0., pcc(ji  ,jj  ,jk+1) )
696
697               ! up & down beta terms
698               zbt = e1e2t(ji,jj) * e3t_n(ji,jj,jk) / p2dt
699               zbetup(ji,jj,jk) = ( zup            - paft(ji,jj,jk) ) / ( zpos + zrtrn ) * zbt
700               zbetdo(ji,jj,jk) = ( paft(ji,jj,jk) - zdo            ) / ( zneg + zrtrn ) * zbt
701            END DO
702         END DO
703      END DO
704      CALL lbc_lnk( zbetup, 'T', 1. )   ;   CALL lbc_lnk( zbetdo, 'T', 1. )   ! lateral boundary cond. (unchanged sign)
705
706      ! 3. monotonic flux in the i & j direction (paa & pbb)
707      ! ----------------------------------------
708      DO jk = 1, jpkm1
709         DO jj = 2, jpjm1
710            DO ji = fs_2, fs_jpim1   ! vector opt.
711               zau = MIN( 1._wp, zbetdo(ji,jj,jk), zbetup(ji+1,jj,jk) )
712               zbu = MIN( 1._wp, zbetup(ji,jj,jk), zbetdo(ji+1,jj,jk) )
713               zcu =       ( 0.5  + SIGN( 0.5 , paa(ji,jj,jk) ) )
714               paa(ji,jj,jk) = paa(ji,jj,jk) * ( zcu * zau + ( 1._wp - zcu) * zbu )
715
716               zav = MIN( 1._wp, zbetdo(ji,jj,jk), zbetup(ji,jj+1,jk) )
717               zbv = MIN( 1._wp, zbetup(ji,jj,jk), zbetdo(ji,jj+1,jk) )
718               zcv =       ( 0.5  + SIGN( 0.5 , pbb(ji,jj,jk) ) )
719               pbb(ji,jj,jk) = pbb(ji,jj,jk) * ( zcv * zav + ( 1._wp - zcv) * zbv )
720
721      ! monotonic flux in the k direction, i.e. pcc
722      ! -------------------------------------------
723               za = MIN( 1., zbetdo(ji,jj,jk+1), zbetup(ji,jj,jk) )
724               zb = MIN( 1., zbetup(ji,jj,jk+1), zbetdo(ji,jj,jk) )
725               zc =       ( 0.5  + SIGN( 0.5 , pcc(ji,jj,jk+1) ) )
726               pcc(ji,jj,jk+1) = pcc(ji,jj,jk+1) * ( zc * za + ( 1._wp - zc) * zb )
727            END DO
728         END DO
729      END DO
730      CALL lbc_lnk( paa, 'U', -1. )   ;   CALL lbc_lnk( pbb, 'V', -1. )   ! lateral boundary condition (changed sign)
731      !
732      CALL wrk_dealloc( jpi, jpj, jpk, zbetup, zbetdo, zbup, zbdo )
733      !
734      IF( nn_timing == 1 )  CALL timing_stop('nonosc')
735      !
736   END SUBROUTINE nonosc
737
738
739   SUBROUTINE interp_4th_cpt( pt_in, pt_out )
740      !!----------------------------------------------------------------------
741      !!                  ***  ROUTINE interp_4th_cpt  ***
742      !!
743      !! **  Purpose :   Compute the interpolation of tracer at w-point
744      !!
745      !! **  Method  :   4th order compact interpolation
746      !!----------------------------------------------------------------------
747      REAL(wp),DIMENSION(jpi,jpj,jpk), INTENT(in   ) ::   pt_in    ! now tracer fields
748      REAL(wp),DIMENSION(jpi,jpj,jpk), INTENT(  out) ::   pt_out   ! now tracer field interpolated at w-pts
749      !
750      INTEGER :: ji, jj, jk   ! dummy loop integers
751      REAL(wp),DIMENSION(jpi,jpj,jpk) :: zwd, zwi, zws, zwrm, zwt
752      !!----------------------------------------------------------------------
753     
754      DO jk = 3, jpkm1        !==  build the three diagonal matrix  ==!
755         DO jj = 1, jpj
756            DO ji = 1, jpi
757               zwd (ji,jj,jk) = 4._wp
758               zwi (ji,jj,jk) = 1._wp
759               zws (ji,jj,jk) = 1._wp
760               zwrm(ji,jj,jk) = 3._wp * ( pt_in(ji,jj,jk-1) + pt_in(ji,jj,jk) )
761               !
762               IF( tmask(ji,jj,jk+1) == 0._wp) THEN   ! Switch to second order centered at bottom
763                  zwd (ji,jj,jk) = 1._wp
764                  zwi (ji,jj,jk) = 0._wp
765                  zws (ji,jj,jk) = 0._wp
766                  zwrm(ji,jj,jk) = 0.5 * ( pt_in(ji,jj,jk-1) + pt_in(ji,jj,jk) )   
767               ENDIF
768            END DO
769         END DO
770      END DO
771      !
772      jk=2                                            ! Switch to second order centered at top
773      DO jj=1,jpj
774         DO ji=1,jpi
775            zwd (ji,jj,jk) = 1._wp
776            zwi (ji,jj,jk) = 0._wp
777            zws (ji,jj,jk) = 0._wp
778            zwrm(ji,jj,jk) = 0.5 * ( pt_in(ji,jj,jk-1) + pt_in(ji,jj,jk) )
779         END DO
780      END DO   
781      !
782      !                       !==  tridiagonal solve  ==!
783      DO jj = 1, jpj                ! first recurrence
784         DO ji = 1, jpi
785            zwt(ji,jj,2) = zwd(ji,jj,2)
786         END DO
787      END DO
788      DO jk = 3, jpkm1
789         DO jj = 1, jpj
790            DO ji = 1, jpi
791               zwt(ji,jj,jk) = zwd(ji,jj,jk) - zwi(ji,jj,jk) * zws(ji,jj,jk-1) /zwt(ji,jj,jk-1)
792            END DO
793         END DO
794      END DO
795      !
796      DO jj = 1, jpj                ! second recurrence:    Zk = Yk - Ik / Tk-1  Zk-1
797         DO ji = 1, jpi
798            pt_out(ji,jj,2) = zwrm(ji,jj,2)
799         END DO
800      END DO
801      DO jk = 3, jpkm1
802         DO jj = 1, jpj
803            DO ji = 1, jpi
804               pt_out(ji,jj,jk) = zwrm(ji,jj,jk) - zwi(ji,jj,jk) / zwt(ji,jj,jk-1) *pt_out(ji,jj,jk-1)             
805            END DO
806         END DO
807      END DO
808
809      DO jj = 1, jpj                ! third recurrence: Xk = (Zk - Sk Xk+1 ) / Tk
810         DO ji = 1, jpi
811            pt_out(ji,jj,jpkm1) = pt_out(ji,jj,jpkm1) / zwt(ji,jj,jpkm1)
812         END DO
813      END DO
814      DO jk = jpk-2, 2, -1
815         DO jj = 1, jpj
816            DO ji = 1, jpi
817               pt_out(ji,jj,jk) = ( pt_out(ji,jj,jk) - zws(ji,jj,jk) * pt_out(ji,jj,jk+1) ) / zwt(ji,jj,jk)
818            END DO
819         END DO
820      END DO
821      !   
822   END SUBROUTINE interp_4th_cpt
823   
824   !!======================================================================
825END MODULE traadv_fct
Note: See TracBrowser for help on using the repository browser.