New URL for NEMO forge! http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.

traadv.F90 in branches/2016/dev_merge_2016/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

Context Navigation

source: branches/2016/dev_merge_2016/NEMOGCM/NEMO/OPA_SRC/TRA/traadv.F90 @ 7403

Last change on this file since 7403 was 7403, checked in by timgraham, 8 years ago
Merge dev_INGV_METO_merge_2016 into branch
Property svn:keywords set to `Id`
File size: 17.2 KB

Line
1	MODULE traadv
2	!!==============================================================================
3	!! * MODULE traadv *
4	!! Ocean active tracers: advection trend
5	!!==============================================================================
6	!! History : 2.0 ! 2005-11 (G. Madec) Original code
7	!! 3.3 ! 2010-09 (C. Ethe, G. Madec) merge TRC-TRA + switch from velocity to transport
8	!! 3.6 ! 2011-06 (G. Madec) Addition of Mixed Layer Eddy parameterisation
9	!! 3.7 ! 2014-05 (G. Madec) Add 2nd/4th order cases for CEN and FCT schemes
10	!! - ! 2014-12 (G. Madec) suppression of cross land advection option
11	!! 3.6 ! 2015-06 (E. Clementi) Addition of Stokes drift in case of wave coupling
12	!!----------------------------------------------------------------------
13
14	!!----------------------------------------------------------------------
15	!! tra_adv : compute ocean tracer advection trend
16	!! tra_adv_ctl : control the different options of advection scheme
17	!!----------------------------------------------------------------------
18	USE oce ! ocean dynamics and active tracers
19	USE dom_oce ! ocean space and time domain
20	USE domvvl ! variable vertical scale factors
21	USE traadv_cen ! centered scheme (tra_adv_cen routine)
22	USE traadv_fct ! FCT scheme (tra_adv_fct routine)
23	USE traadv_mus ! MUSCL scheme (tra_adv_mus routine)
24	USE traadv_ubs ! UBS scheme (tra_adv_ubs routine)
25	USE traadv_qck ! QUICKEST scheme (tra_adv_qck routine)
26	USE traadv_mle ! ML eddy induced velocity (tra_adv_mle routine)
27	USE ldftra ! lateral diffusion: eddy diffusivity & EIV coeff.
28	USE ldfslp ! Lateral diffusion: slopes of neutral surfaces
29	USE trd_oce ! trends: ocean variables
30	USE trdtra ! trends manager: tracers
31	!
32	USE in_out_manager ! I/O manager
33	USE iom ! I/O module
34	USE prtctl ! Print control
35	USE lib_mpp ! MPP library
36	USE wrk_nemo ! Memory Allocation
37	USE timing ! Timing
38	USE sbcwave ! wave module
39	USE sbc_oce ! surface boundary condition: ocean
40	USE diaptr ! Poleward heat transport
41
42	IMPLICIT NONE
43	PRIVATE
44
45	PUBLIC tra_adv ! routine called by step module
46	PUBLIC tra_adv_init ! routine called by opa module
47
48	! !!* Namelist namtra_adv *
49	LOGICAL :: ln_traadv_cen ! centered scheme flag
50	INTEGER :: nn_cen_h, nn_cen_v ! =2/4 : horizontal and vertical choices of the order of CEN scheme
51	LOGICAL :: ln_traadv_fct ! FCT scheme flag
52	INTEGER :: nn_fct_h, nn_fct_v ! =2/4 : horizontal and vertical choices of the order of FCT scheme
53	INTEGER :: nn_fct_zts ! >=1 : 2nd order FCT with vertical sub-timestepping
54	LOGICAL :: ln_traadv_mus ! MUSCL scheme flag
55	LOGICAL :: ln_mus_ups ! use upstream scheme in vivcinity of river mouths
56	LOGICAL :: ln_traadv_ubs ! UBS scheme flag
57	INTEGER :: nn_ubs_v ! =2/4 : vertical choice of the order of UBS scheme
58	LOGICAL :: ln_traadv_qck ! QUICKEST scheme flag
59
60	INTEGER :: nadv ! choice of the type of advection scheme
61	!
62	! ! associated indices:
63	INTEGER, PARAMETER :: np_NO_adv = 0 ! no T-S advection
64	INTEGER, PARAMETER :: np_CEN = 1 ! 2nd/4th order centered scheme
65	INTEGER, PARAMETER :: np_FCT = 2 ! 2nd/4th order Flux Corrected Transport scheme
66	INTEGER, PARAMETER :: np_FCT_zts = 3 ! 2nd order FCT scheme with vertical sub-timestepping
67	INTEGER, PARAMETER :: np_MUS = 4 ! MUSCL scheme
68	INTEGER, PARAMETER :: np_UBS = 5 ! 3rd order Upstream Biased Scheme
69	INTEGER, PARAMETER :: np_QCK = 6 ! QUICK scheme
70
71	!! * Substitutions
72	# include "vectopt_loop_substitute.h90"
73	!!----------------------------------------------------------------------
74	!! NEMO/OPA 3.7 , NEMO Consortium (2014)
75	!! $Id$
76	!! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
77	!!----------------------------------------------------------------------
78	CONTAINS
79
80	SUBROUTINE tra_adv( kt )
81	!!----------------------------------------------------------------------
82	!! * ROUTINE tra_adv *
83	!!
84	!! ** Purpose : compute the ocean tracer advection trend.
85	!!
86	!! ** Method : - Update (ua,va) with the advection term following nadv
87	!!----------------------------------------------------------------------
88	INTEGER, INTENT( in ) :: kt ! ocean time-step index
89	!
90	INTEGER :: jk ! dummy loop index
91	REAL(wp), POINTER, DIMENSION(:,:,:) :: zun, zvn, zwn
92	REAL(wp), POINTER, DIMENSION(:,:,:) :: ztrdt, ztrds ! 3D workspace
93	!!----------------------------------------------------------------------
94	!
95	IF( nn_timing == 1 ) CALL timing_start('tra_adv')
96	!
97	CALL wrk_alloc( jpi,jpj,jpk, zun, zvn, zwn )
98	!
99	! ! set time step
100	zun(:,:,:) = 0.0
101	zvn(:,:,:) = 0.0
102	zwn(:,:,:) = 0.0
103	!
104	IF( neuler == 0 .AND. kt == nit000 ) THEN ! at nit000
105	r2dt = rdt ! = rdt (restarting with Euler time stepping)
106	ELSEIF( kt <= nit000 + 1) THEN ! at nit000 or nit000+1
107	r2dt = 2._wp * rdt ! = 2 rdt (leapfrog)
108	ENDIF
109	!
110	! !== effective transport ==!
111	IF( ln_wave .AND. ln_sdw ) THEN
112	DO jk = 1, jpkm1
113	zun(:,:,jk) = e2u(:,:) * e3u_n(:,:,jk) * &
114	& ( un(:,:,jk) + usd3d(:,:,jk) ) ! eulerian transport + Stokes Drift
115	zvn(:,:,jk) = e1v(:,:) * e3v_n(:,:,jk) * &
116	& ( vn(:,:,jk) + vsd3d(:,:,jk) )
117	zwn(:,:,jk) = e1e2t(:,:) * &
118	& ( wn(:,:,jk) + wsd3d(:,:,jk) )
119	END DO
120	ELSE
121	DO jk = 1, jpkm1
122	zun(:,:,jk) = e2u (:,:) * e3u_n(:,:,jk) * un(:,:,jk) ! eulerian transport only
123	zvn(:,:,jk) = e1v (:,:) * e3v_n(:,:,jk) * vn(:,:,jk)
124	zwn(:,:,jk) = e1e2t(:,:) * wn(:,:,jk)
125	END DO
126	ENDIF
127	!
128	IF( ln_vvl_ztilde .OR. ln_vvl_layer ) THEN ! add z-tilde and/or vvl corrections
129	zun(:,:,:) = zun(:,:,:) + un_td(:,:,:)
130	zvn(:,:,:) = zvn(:,:,:) + vn_td(:,:,:)
131	ENDIF
132	!
133	zun(:,:,jpk) = 0._wp ! no transport trough the bottom
134	zvn(:,:,jpk) = 0._wp
135	zwn(:,:,jpk) = 0._wp
136	!
137	IF( ln_ldfeiv .AND. .NOT. ln_traldf_triad ) &
138	& CALL ldf_eiv_trp( kt, nit000, zun, zvn, zwn, 'TRA' ) ! add the eiv transport (if necessary)
139	!
140	IF( ln_mle ) CALL tra_adv_mle( kt, nit000, zun, zvn, zwn, 'TRA' ) ! add the mle transport (if necessary)
141	!
142	CALL iom_put( "uocetr_eff", zun ) ! output effective transport
143	CALL iom_put( "vocetr_eff", zvn )
144	CALL iom_put( "wocetr_eff", zwn )
145	!
146	!!gm ???
147	IF( ln_diaptr ) CALL dia_ptr( zvn ) ! diagnose the effective MSF
148	!!gm ???
149	!
150	IF( l_trdtra ) THEN !* Save ta and sa trends
151	CALL wrk_alloc( jpi, jpj, jpk, ztrdt, ztrds )
152	ztrdt(:,:,:) = tsa(:,:,:,jp_tem)
153	ztrds(:,:,:) = tsa(:,:,:,jp_sal)
154	ENDIF
155	!
156	SELECT CASE ( nadv ) !== compute advection trend and add it to general trend ==!
157	!
158	CASE ( np_CEN ) ! Centered scheme : 2nd / 4th order
159	CALL tra_adv_cen ( kt, nit000, 'TRA', zun, zvn, zwn , tsn, tsa, jpts, nn_cen_h, nn_cen_v )
160	CASE ( np_FCT ) ! FCT scheme : 2nd / 4th order
161	CALL tra_adv_fct ( kt, nit000, 'TRA', r2dt, zun, zvn, zwn, tsb, tsn, tsa, jpts, nn_fct_h, nn_fct_v )
162	CASE ( np_FCT_zts ) ! 2nd order FCT with vertical time-splitting
163	CALL tra_adv_fct_zts( kt, nit000, 'TRA', r2dt, zun, zvn, zwn, tsb, tsn, tsa, jpts , nn_fct_zts )
164	CASE ( np_MUS ) ! MUSCL
165	CALL tra_adv_mus ( kt, nit000, 'TRA', r2dt, zun, zvn, zwn, tsb, tsa, jpts , ln_mus_ups )
166	CASE ( np_UBS ) ! UBS
167	CALL tra_adv_ubs ( kt, nit000, 'TRA', r2dt, zun, zvn, zwn, tsb, tsn, tsa, jpts , nn_ubs_v )
168	CASE ( np_QCK ) ! QUICKEST
169	CALL tra_adv_qck ( kt, nit000, 'TRA', r2dt, zun, zvn, zwn, tsb, tsn, tsa, jpts )
170	!
171	END SELECT
172	!
173	IF( l_trdtra ) THEN ! save the advective trends for further diagnostics
174	DO jk = 1, jpkm1
175	ztrdt(:,:,jk) = tsa(:,:,jk,jp_tem) - ztrdt(:,:,jk)
176	ztrds(:,:,jk) = tsa(:,:,jk,jp_sal) - ztrds(:,:,jk)
177	END DO
178	CALL trd_tra( kt, 'TRA', jp_tem, jptra_totad, ztrdt )
179	CALL trd_tra( kt, 'TRA', jp_sal, jptra_totad, ztrds )
180	CALL wrk_dealloc( jpi, jpj, jpk, ztrdt, ztrds )
181	ENDIF
182	! ! print mean trends (used for debugging)
183	IF(ln_ctl) CALL prt_ctl( tab3d_1=tsa(:,:,:,jp_tem), clinfo1=' adv - Ta: ', mask1=tmask, &
184	& tab3d_2=tsa(:,:,:,jp_sal), clinfo2= ' Sa: ', mask2=tmask, clinfo3='tra' )
185	!
186	IF( nn_timing == 1 ) CALL timing_stop( 'tra_adv' )
187	!
188	CALL wrk_dealloc( jpi,jpj,jpk, zun, zvn, zwn )
189	!
190	END SUBROUTINE tra_adv
191
192
193	SUBROUTINE tra_adv_init
194	!!---------------------------------------------------------------------
195	!! * ROUTINE tra_adv_init *
196	!!
197	!! ** Purpose : Control the consistency between namelist options for
198	!! tracer advection schemes and set nadv
199	!!----------------------------------------------------------------------
200	INTEGER :: ioptio, ios ! Local integers
201	!
202	NAMELIST/namtra_adv/ ln_traadv_cen, nn_cen_h, nn_cen_v, & ! CEN
203	& ln_traadv_fct, nn_fct_h, nn_fct_v, nn_fct_zts, & ! FCT
204	& ln_traadv_mus, ln_mus_ups, & ! MUSCL
205	& ln_traadv_ubs, nn_ubs_v, & ! UBS
206	& ln_traadv_qck ! QCK
207	!!----------------------------------------------------------------------
208	!
209	! !== Namelist ==!
210	REWIND( numnam_ref ) ! Namelist namtra_adv in reference namelist : Tracer advection scheme
211	READ ( numnam_ref, namtra_adv, IOSTAT = ios, ERR = 901)
212	901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namtra_adv in reference namelist', lwp )
213	!
214	REWIND( numnam_cfg ) ! Namelist namtra_adv in configuration namelist : Tracer advection scheme
215	READ ( numnam_cfg, namtra_adv, IOSTAT = ios, ERR = 902 )
216	902 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namtra_adv in configuration namelist', lwp )
217	IF(lwm) WRITE( numond, namtra_adv )
218	!
219	IF(lwp) THEN ! Namelist print
220	WRITE(numout,*)
221	WRITE(numout,*) 'tra_adv_init : choice/control of the tracer advection scheme'
222	WRITE(numout,*) '~~~~~~~~~~~'
223	WRITE(numout,*) ' Namelist namtra_adv : chose a advection scheme for tracers'
224	WRITE(numout,*) ' centered scheme ln_traadv_cen = ', ln_traadv_cen
225	WRITE(numout,*) ' horizontal 2nd/4th order nn_cen_h = ', nn_fct_h
226	WRITE(numout,*) ' vertical 2nd/4th order nn_cen_v = ', nn_fct_v
227	WRITE(numout,*) ' Flux Corrected Transport scheme ln_traadv_fct = ', ln_traadv_fct
228	WRITE(numout,*) ' horizontal 2nd/4th order nn_fct_h = ', nn_fct_h
229	WRITE(numout,*) ' vertical 2nd/4th order nn_fct_v = ', nn_fct_v
230	WRITE(numout,*) ' 2nd order + vertical sub-timestepping nn_fct_zts = ', nn_fct_zts
231	WRITE(numout,*) ' MUSCL scheme ln_traadv_mus = ', ln_traadv_mus
232	WRITE(numout,*) ' + upstream scheme near river mouths ln_mus_ups = ', ln_mus_ups
233	WRITE(numout,*) ' UBS scheme ln_traadv_ubs = ', ln_traadv_ubs
234	WRITE(numout,*) ' vertical 2nd/4th order nn_ubs_v = ', nn_ubs_v
235	WRITE(numout,*) ' QUICKEST scheme ln_traadv_qck = ', ln_traadv_qck
236	ENDIF
237	!
238	ioptio = 0 !== Parameter control ==!
239	IF( ln_traadv_cen ) ioptio = ioptio + 1
240	IF( ln_traadv_fct ) ioptio = ioptio + 1
241	IF( ln_traadv_mus ) ioptio = ioptio + 1
242	IF( ln_traadv_ubs ) ioptio = ioptio + 1
243	IF( ln_traadv_qck ) ioptio = ioptio + 1
244	!
245	IF( ioptio == 0 ) THEN
246	nadv = np_NO_adv
247	CALL ctl_warn( 'tra_adv_init: You are running without tracer advection.' )
248	ENDIF
249	IF( ioptio /= 1 ) CALL ctl_stop( 'tra_adv_init: Choose ONE advection scheme in namelist namtra_adv' )
250	!
251	IF( ln_traadv_cen .AND. ( nn_cen_h /= 2 .AND. nn_cen_h /= 4 ) & ! Centered
252	.AND. ( nn_cen_v /= 2 .AND. nn_cen_v /= 4 ) ) THEN
253	CALL ctl_stop( 'tra_adv_init: CEN scheme, choose 2nd or 4th order' )
254	ENDIF
255	IF( ln_traadv_fct .AND. ( nn_fct_h /= 2 .AND. nn_fct_h /= 4 ) & ! FCT
256	.AND. ( nn_fct_v /= 2 .AND. nn_fct_v /= 4 ) ) THEN
257	CALL ctl_stop( 'tra_adv_init: FCT scheme, choose 2nd or 4th order' )
258	ENDIF
259	IF( ln_traadv_fct .AND. nn_fct_zts > 0 ) THEN
260	IF( nn_fct_h == 4 ) THEN
261	nn_fct_h = 2
262	CALL ctl_stop( 'tra_adv_init: force 2nd order FCT scheme, 4th order does not exist with sub-timestepping' )
263	ENDIF
264	IF( .NOT.ln_linssh ) THEN
265	CALL ctl_stop( 'tra_adv_init: vertical sub-timestepping not allow in non-linear free surface' )
266	ENDIF
267	IF( nn_fct_zts == 1 ) CALL ctl_warn( 'tra_adv_init: FCT with ONE sub-timestep = FCT without sub-timestep' )
268	ENDIF
269	IF( ln_traadv_ubs .AND. ( nn_ubs_v /= 2 .AND. nn_ubs_v /= 4 ) ) THEN ! UBS
270	CALL ctl_stop( 'tra_adv_init: UBS scheme, choose 2nd or 4th order' )
271	ENDIF
272	IF( ln_traadv_ubs .AND. nn_ubs_v == 4 ) THEN
273	CALL ctl_warn( 'tra_adv_init: UBS scheme, only 2nd FCT scheme available on the vertical. It will be used' )
274	ENDIF
275	IF( ln_isfcav ) THEN ! ice-shelf cavities
276	IF( ln_traadv_cen .AND. nn_cen_v == 4 .OR. & ! NO 4th order with ISF
277	& ln_traadv_fct .AND. nn_fct_v == 4 ) CALL ctl_stop( 'tra_adv_init: 4th order COMPACT scheme not allowed with ISF' )
278	ENDIF
279	!
280	! !== used advection scheme ==!
281	! ! set nadv
282	IF( ln_traadv_cen ) nadv = np_CEN
283	IF( ln_traadv_fct ) nadv = np_FCT
284	IF( ln_traadv_fct .AND. nn_fct_zts > 0 ) nadv = np_FCT_zts
285	IF( ln_traadv_mus ) nadv = np_MUS
286	IF( ln_traadv_ubs ) nadv = np_UBS
287	IF( ln_traadv_qck ) nadv = np_QCK
288	!
289	IF(lwp) THEN ! Print the choice
290	WRITE(numout,*)
291	SELECT CASE ( nadv )
292	CASE( np_NO_adv ) ; WRITE(numout,*) ' NO T-S advection'
293	CASE( np_CEN ) ; WRITE(numout,*) ' CEN scheme is used. Horizontal order: ', nn_cen_h, &
294	& ' Vertical order: ', nn_cen_v
295	CASE( np_FCT ) ; WRITE(numout,*) ' FCT scheme is used. Horizontal order: ', nn_fct_h, &
296	& ' Vertical order: ', nn_fct_v
297	CASE( np_FCT_zts ) ; WRITE(numout,*) ' use 2nd order FCT with ', nn_fct_zts,'vertical sub-timestepping'
298	CASE( np_MUS ) ; WRITE(numout,*) ' MUSCL scheme is used'
299	CASE( np_UBS ) ; WRITE(numout,*) ' UBS scheme is used'
300	CASE( np_QCK ) ; WRITE(numout,*) ' QUICKEST scheme is used'
301	END SELECT
302	ENDIF
303	!
304	CALL tra_adv_mle_init !== initialisation of the Mixed Layer Eddy parametrisation (MLE) ==!
305	!
306	END SUBROUTINE tra_adv_init
307
308	!!======================================================================
309	END MODULE traadv

Note: See TracBrowser for help on using the repository browser.

Download in other formats: