New URL for NEMO forge! http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.

sbcice_lim.F90 in branches/2016/dev_merge_2016/NEMOGCM/NEMO/OPA_SRC/SBC – NEMO

Context Navigation

source: branches/2016/dev_merge_2016/NEMOGCM/NEMO/OPA_SRC/SBC/sbcice_lim.F90 @ 7412

Last change on this file since 7412 was 7412, checked in by lovato, 8 years ago
Merge dev_NOC_CMCC_merge_2016 into branch
Property svn:keywords set to `Id`
File size: 31.8 KB

Line
1	MODULE sbcice_lim
2	!!======================================================================
3	!! * MODULE sbcice_lim *
4	!! Surface module : update the ocean surface boundary condition over ice
5	!! & covered area using LIM sea-ice model
6	!! Sea-Ice model : LIM-3 Sea ice model time-stepping
7	!!=====================================================================
8	!! History : 2.0 ! 2006-12 (M. Vancoppenolle) Original code
9	!! 3.0 ! 2008-02 (C. Talandier) Surface module from icestp.F90
10	!! - ! 2008-04 (G. Madec) sltyle and lim_ctl routine
11	!! 3.3 ! 2010-11 (G. Madec) ice-ocean stress always computed at each ocean time-step
12	!! 3.4 ! 2011-01 (A Porter) dynamical allocation
13	!! - ! 2012-10 (C. Rousset) add lim_diahsb
14	!! 3.6 ! 2014-07 (M. Vancoppenolle, G. Madec, O. Marti) revise coupled interface
15	!!----------------------------------------------------------------------
16	#if defined key_lim3
17	!!----------------------------------------------------------------------
18	!! 'key_lim3' : LIM 3.0 sea-ice model
19	!!----------------------------------------------------------------------
20	!! sbc_ice_lim : sea-ice model time-stepping and update ocean sbc over ice-covered area
21	!!----------------------------------------------------------------------
22	USE oce ! ocean dynamics and tracers
23	USE dom_oce ! ocean space and time domain
24	USE ice ! LIM-3: ice variables
25	USE thd_ice ! LIM-3: thermodynamical variables
26	USE dom_ice ! LIM-3: ice domain
27	!
28	USE sbc_oce ! Surface boundary condition: ocean fields
29	USE sbc_ice ! Surface boundary condition: ice fields
30	USE sbcblk_core ! Surface boundary condition: CORE bulk
31	USE sbcblk_clio ! Surface boundary condition: CLIO bulk
32	USE sbccpl ! Surface boundary condition: coupled interface
33	USE albedo ! ocean & ice albedo
34	!
35	USE phycst ! Define parameters for the routines
36	USE eosbn2 ! equation of state
37	USE limdyn ! Ice dynamics
38	USE limtrp ! Ice transport
39	USE limhdf ! Ice horizontal diffusion
40	USE limthd ! Ice thermodynamics
41	USE limitd_me ! Mechanics on ice thickness distribution
42	USE limsbc ! sea surface boundary condition
43	USE limdiahsb ! Ice budget diagnostics
44	USE limwri ! Ice outputs
45	USE limrst ! Ice restarts
46	USE limupdate1 ! update of global variables
47	USE limupdate2 ! update of global variables
48	USE limvar ! Ice variables switch
49	USE limctl !
50	USE limmsh ! LIM mesh
51	USE limistate ! LIM initial state
52	USE limthd_sal ! LIM ice thermodynamics: salinity
53	!
54	USE c1d ! 1D vertical configuration
55	USE in_out_manager ! I/O manager
56	USE iom ! I/O manager library
57	USE prtctl ! Print control
58	USE lib_fortran !
59	USE lbclnk ! lateral boundary condition - MPP link
60	USE lib_mpp ! MPP library
61	USE wrk_nemo ! work arrays
62	USE timing ! Timing
63
64	USE bdy_oce , ONLY: ln_bdy
65	USE bdyice_lim ! unstructured open boundary data (bdy_ice_lim routine)
66
67	IMPLICIT NONE
68	PRIVATE
69
70	PUBLIC sbc_ice_lim ! routine called by sbcmod.F90
71	PUBLIC sbc_lim_init ! routine called by sbcmod.F90
72
73	!! * Substitutions
74	# include "vectopt_loop_substitute.h90"
75	!!----------------------------------------------------------------------
76	!! NEMO/OPA 4.0 , UCL NEMO Consortium (2011)
77	!! $Id$
78	!! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
79	!!----------------------------------------------------------------------
80	CONTAINS
81
82	SUBROUTINE sbc_ice_lim( kt, kblk )
83	!!---------------------------------------------------------------------
84	!! * ROUTINE sbc_ice_lim *
85	!!
86	!! ** Purpose : update the ocean surface boundary condition via the
87	!! Louvain la Neuve Sea Ice Model time stepping
88	!!
89	!! ** Method : ice model time stepping
90	!! - call the ice dynamics routine
91	!! - call the ice advection/diffusion routine
92	!! - call the ice thermodynamics routine
93	!! - call the routine that computes mass and
94	!! heat fluxes at the ice/ocean interface
95	!! - save the outputs
96	!! - save the outputs for restart when necessary
97	!!
98	!! ** Action : - time evolution of the LIM sea-ice model
99	!! - update all sbc variables below sea-ice:
100	!! utau, vtau, taum, wndm, qns , qsr, emp , sfx
101	!!---------------------------------------------------------------------
102	INTEGER, INTENT(in) :: kt ! ocean time step
103	INTEGER, INTENT(in) :: kblk ! type of bulk (=3 CLIO, =4 CORE, =5 COUPLED)
104	!!
105	INTEGER :: jl ! dummy loop index
106	REAL(wp), POINTER, DIMENSION(:,:,:) :: zalb_os, zalb_cs ! ice albedo under overcast/clear sky
107	REAL(wp), POINTER, DIMENSION(:,: ) :: zutau_ice, zvtau_ice
108	!!----------------------------------------------------------------------
109
110	IF( nn_timing == 1 ) CALL timing_start('sbc_ice_lim')
111
112	!-----------------------!
113	! --- Ice time step --- !
114	!-----------------------!
115	IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN
116
117	! mean surface ocean current at ice velocity point (C-grid dynamics : U- & V-points as the ocean)
118	u_oce(:,:) = ssu_m(:,:) * umask(:,:,1)
119	v_oce(:,:) = ssv_m(:,:) * vmask(:,:,1)
120
121	! masked sea surface freezing temperature [Kelvin] (set to rt0 over land)
122	CALL eos_fzp( sss_m(:,:) , t_bo(:,:) )
123	t_bo(:,:) = ( t_bo(:,:) + rt0 ) * tmask(:,:,1) + rt0 * ( 1._wp - tmask(:,:,1) )
124
125	! Mask sea ice surface temperature (set to rt0 over land)
126	DO jl = 1, jpl
127	t_su(:,:,jl) = t_su(:,:,jl) * tmask(:,:,1) + rt0 * ( 1._wp - tmask(:,:,1) )
128	END DO
129	!
130	!------------------------------------------------!
131	! --- Dynamical coupling with the atmosphere --- !
132	!------------------------------------------------!
133	! It provides the following fields:
134	! utau_ice, vtau_ice : surface ice stress (U- & V-points) [N/m2]
135	!-----------------------------------------------------------------
136	SELECT CASE( kblk )
137	CASE( jp_clio ) ; CALL blk_ice_clio_tau ! CLIO bulk formulation
138	CASE( jp_core ) ; CALL blk_ice_core_tau ! CORE bulk formulation
139	CASE( jp_purecpl ) ; CALL sbc_cpl_ice_tau( utau_ice , vtau_ice ) ! Coupled formulation
140	END SELECT
141
142	IF( ln_mixcpl) THEN ! Case of a mixed Bulk/Coupled formulation
143	CALL wrk_alloc( jpi,jpj , zutau_ice, zvtau_ice)
144	CALL sbc_cpl_ice_tau( zutau_ice , zvtau_ice )
145	utau_ice(:,:) = utau_ice(:,:) * xcplmask(:,:,0) + zutau_ice(:,:) * ( 1. - xcplmask(:,:,0) )
146	vtau_ice(:,:) = vtau_ice(:,:) * xcplmask(:,:,0) + zvtau_ice(:,:) * ( 1. - xcplmask(:,:,0) )
147	CALL wrk_dealloc( jpi,jpj , zutau_ice, zvtau_ice)
148	ENDIF
149
150	!-------------------------------------------------------!
151	! --- ice dynamics and transport (except in 1D case) ---!
152	!-------------------------------------------------------!
153	numit = numit + nn_fsbc ! Ice model time step
154	!
155	CALL sbc_lim_bef ! Store previous ice values
156	CALL sbc_lim_diag0 ! set diag of mass, heat and salt fluxes to 0
157	CALL lim_rst_opn( kt ) ! Open Ice restart file
158	!
159	IF( .NOT. lk_c1d ) THEN
160	!
161	CALL lim_dyn( kt ) ! Ice dynamics ( rheology/dynamics )
162	!
163	CALL lim_trp( kt ) ! Ice transport ( Advection/diffusion )
164	!
165	IF( nn_monocat /= 2 ) CALL lim_itd_me ! Mechanical redistribution ! (ridging/rafting)
166	!
167	IF( ln_bdy ) CALL bdy_ice_lim( kt ) ! bdy ice thermo
168	IF( ln_bdy .AND. ln_icectl ) CALL lim_prt( kt, iiceprt, jiceprt, 1, ' - ice thermo bdy - ' )
169	!
170	CALL lim_update1( kt ) ! Corrections
171	!
172	ENDIF
173
174	! previous lead fraction and ice volume for flux calculations
175	CALL sbc_lim_bef
176	CALL lim_var_glo2eqv ! ht_i and ht_s for ice albedo calculation
177	CALL lim_var_agg(1) ! at_i for coupling (via pfrld)
178	pfrld(:,:) = 1._wp - at_i(:,:)
179	phicif(:,:) = vt_i(:,:)
180
181	!------------------------------------------------------!
182	! --- Thermodynamical coupling with the atmosphere --- !
183	!------------------------------------------------------!
184	! It provides the following fields:
185	! qsr_ice , qns_ice : solar & non solar heat flux over ice (T-point) [W/m2]
186	! qla_ice : latent heat flux over ice (T-point) [W/m2]
187	! dqns_ice, dqla_ice : non solar & latent heat sensistivity (T-point) [W/m2]
188	! tprecip , sprecip : total & solid precipitation (T-point) [Kg/m2/s]
189	! fr1_i0 , fr2_i0 : 1sr & 2nd fraction of qsr penetration in ice [%]
190	!----------------------------------------------------------------------------------------
191	CALL wrk_alloc( jpi,jpj,jpl, zalb_os, zalb_cs )
192	CALL albedo_ice( t_su, ht_i, ht_s, zalb_cs, zalb_os ) ! cloud-sky and overcast-sky ice albedos
193
194	SELECT CASE( kblk )
195	CASE( jp_clio ) ! CLIO bulk formulation
196	! In CLIO the cloud fraction is read in the climatology and the all-sky albedo
197	! (alb_ice) is computed within the bulk routine
198	CALL blk_ice_clio_flx( t_su, zalb_cs, zalb_os, alb_ice )
199	IF( ln_mixcpl ) CALL sbc_cpl_ice_flx( p_frld=pfrld, palbi=alb_ice, psst=sst_m, pist=t_su )
200	IF( nn_limflx /= 2 ) CALL ice_lim_flx( t_su, alb_ice, qns_ice, qsr_ice, dqns_ice, evap_ice, devap_ice, nn_limflx )
201	CASE( jp_core ) ! CORE bulk formulation
202	! albedo depends on cloud fraction because of non-linear spectral effects
203	alb_ice(:,:,:) = ( 1. - cldf_ice ) * zalb_cs(:,:,:) + cldf_ice * zalb_os(:,:,:)
204	CALL blk_ice_core_flx( t_su, alb_ice )
205	IF( ln_mixcpl ) CALL sbc_cpl_ice_flx( p_frld=pfrld, palbi=alb_ice, psst=sst_m, pist=t_su )
206	IF( nn_limflx /= 2 ) CALL ice_lim_flx( t_su, alb_ice, qns_ice, qsr_ice, dqns_ice, evap_ice, devap_ice, nn_limflx )
207	CASE ( jp_purecpl )
208	! albedo depends on cloud fraction because of non-linear spectral effects
209	alb_ice(:,:,:) = ( 1. - cldf_ice ) * zalb_cs(:,:,:) + cldf_ice * zalb_os(:,:,:)
210	CALL sbc_cpl_ice_flx( p_frld=pfrld, palbi=alb_ice, psst=sst_m, pist=t_su )
211	IF( nn_limflx == 2 ) CALL ice_lim_flx( t_su, alb_ice, qns_ice, qsr_ice, dqns_ice, evap_ice, devap_ice, nn_limflx )
212	END SELECT
213	CALL wrk_dealloc( jpi,jpj,jpl, zalb_os, zalb_cs )
214
215	!----------------------------!
216	! --- ice thermodynamics --- !
217	!----------------------------!
218	CALL lim_thd( kt ) ! Ice thermodynamics
219	!
220	CALL lim_update2( kt ) ! Corrections
221	!
222	CALL lim_sbc_flx( kt ) ! Update surface ocean mass, heat and salt fluxes
223	!
224	IF(ln_limdiaout) CALL lim_diahsb ! Diagnostics and outputs
225	!
226	CALL lim_wri( 1 ) ! Ice outputs
227	!
228	IF( kt == nit000 .AND. ln_rstart ) &
229	& CALL iom_close( numrir ) ! close input ice restart file
230	!
231	IF( lrst_ice ) CALL lim_rst_write( kt ) ! Ice restart file
232	!
233	IF( ln_icectl ) CALL lim_ctl( kt ) ! alerts in case of model crash
234	!
235	ENDIF ! End sea-ice time step only
236
237	!-------------------------!
238	! --- Ocean time step --- !
239	!-------------------------!
240	! Update surface ocean stresses (only in ice-dynamic case) otherwise the atm.-ocean stresses are used everywhere
241	IF( ln_limdyn ) CALL lim_sbc_tau( kt, ub(:,:,1), vb(:,:,1) ) ! using before instantaneous surf. currents
242	!!gm remark, the ocean-ice stress is not saved in ice diag call above ..... find a solution!!!
243	!
244	IF( nn_timing == 1 ) CALL timing_stop('sbc_ice_lim')
245	!
246	END SUBROUTINE sbc_ice_lim
247
248
249	SUBROUTINE sbc_lim_init
250	!!----------------------------------------------------------------------
251	!! * ROUTINE sbc_lim_init *
252	!!
253	!! ** purpose : Allocate all the dynamic arrays of the LIM-3 modules
254	!!----------------------------------------------------------------------
255	INTEGER :: ji, jj, ierr
256	!!----------------------------------------------------------------------
257	IF(lwp) WRITE(numout,*)
258	IF(lwp) WRITE(numout,*) 'sbc_ice_lim : update ocean surface boudary condition'
259	IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ via Louvain la Neuve Ice Model (LIM-3) time stepping'
260	!
261	! ! Open the reference and configuration namelist files and namelist output file
262	CALL ctl_opn( numnam_ice_ref, 'namelist_ice_ref', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, numout, lwp )
263	CALL ctl_opn( numnam_ice_cfg, 'namelist_ice_cfg', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, numout, lwp )
264	IF(lwm) CALL ctl_opn( numoni, 'output.namelist.ice', 'UNKNOWN', 'FORMATTED', 'SEQUENTIAL', -1, numout, lwp, 1 )
265	!
266	CALL ice_run ! set some ice run parameters
267	!
268	! ! Allocate the ice arrays
269	ierr = ice_alloc () ! ice variables
270	ierr = ierr + dom_ice_alloc () ! domain
271	ierr = ierr + sbc_ice_alloc () ! surface forcing
272	ierr = ierr + thd_ice_alloc () ! thermodynamics
273	ierr = ierr + lim_itd_me_alloc () ! ice thickness distribution - mechanics
274	!
275	IF( lk_mpp ) CALL mpp_sum( ierr )
276	IF( ierr /= 0 ) CALL ctl_stop('STOP', 'sbc_lim_init : unable to allocate ice arrays')
277	!
278	! ! adequation jpk versus ice/snow layers/categories
279	IF( jpl > jpk .OR. (nlay_i+1) > jpk .OR. nlay_s > jpk ) &
280	& CALL ctl_stop( 'STOP', &
281	& 'sbc_lim_init: the 3rd dimension of workspace arrays is too small.', &
282	& 'use more ocean levels or less ice/snow layers/categories.' )
283	!
284	CALL lim_itd_init ! ice thickness distribution initialization
285	!
286	CALL lim_hdf_init ! set ice horizontal diffusion computation parameters
287	!
288	CALL lim_thd_init ! set ice thermodynics parameters
289	!
290	CALL lim_thd_sal_init ! set ice salinity parameters
291	!
292	CALL lim_msh ! ice mesh initialization
293	!
294	CALL lim_itd_me_init ! ice thickness distribution initialization for mecanical deformation
295	! ! Initial sea-ice state
296	IF( .NOT. ln_rstart ) THEN ! start from rest: sea-ice deduced from sst
297	numit = 0
298	numit = nit000 - 1
299	CALL lim_istate
300	ELSE ! start from a restart file
301	CALL lim_rst_read
302	numit = nit000 - 1
303	ENDIF
304	CALL lim_var_agg(1)
305	CALL lim_var_glo2eqv
306	!
307	CALL lim_sbc_init ! ice surface boundary condition
308	!
309	fr_i(:,:) = at_i(:,:) ! initialisation of sea-ice fraction
310	tn_ice(:,:,:) = t_su(:,:,:) ! initialisation of surface temp for coupled simu
311	!
312	DO jj = 1, jpj
313	DO ji = 1, jpi
314	IF( gphit(ji,jj) > 0._wp ) THEN ; rn_amax_2d(ji,jj) = rn_amax_n ! NH
315	ELSE ; rn_amax_2d(ji,jj) = rn_amax_s ! SH
316	ENDIF
317	ENDDO
318	ENDDO
319	!
320	nstart = numit + nn_fsbc
321	nitrun = nitend - nit000 + 1
322	nlast = numit + nitrun
323	!
324	IF( nstock == 0 ) nstock = nlast + 1
325	!
326	END SUBROUTINE sbc_lim_init
327
328
329	SUBROUTINE ice_run
330	!!-------------------------------------------------------------------
331	!! * ROUTINE ice_run *
332	!!
333	!! ** Purpose : Definition some run parameter for ice model
334	!!
335	!! ** Method : Read the namicerun namelist and check the parameter
336	!! values called at the first timestep (nit000)
337	!!
338	!! ** input : Namelist namicerun
339	!!-------------------------------------------------------------------
340	INTEGER :: ios ! Local integer output status for namelist read
341	NAMELIST/namicerun/ jpl, nlay_i, nlay_s, cn_icerst_in, cn_icerst_indir, cn_icerst_out, cn_icerst_outdir, &
342	& ln_limdyn, rn_amax_n, rn_amax_s, ln_limdiahsb, ln_limdiaout, ln_icectl, iiceprt, jiceprt
343	!!-------------------------------------------------------------------
344	!
345	REWIND( numnam_ice_ref ) ! Namelist namicerun in reference namelist : Parameters for ice
346	READ ( numnam_ice_ref, namicerun, IOSTAT = ios, ERR = 901)
347	901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namicerun in reference namelist', lwp )
348	!
349	REWIND( numnam_ice_cfg ) ! Namelist namicerun in configuration namelist : Parameters for ice
350	READ ( numnam_ice_cfg, namicerun, IOSTAT = ios, ERR = 902 )
351	902 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namicerun in configuration namelist', lwp )
352	IF(lwm) WRITE( numoni, namicerun )
353	!
354	IF(lwp) THEN ! control print
355	WRITE(numout,*)
356	WRITE(numout,*) 'ice_run : ice share parameters for dynamics/advection/thermo of sea-ice'
357	WRITE(numout,*) ' ~~~~~~'
358	WRITE(numout,*) ' number of ice categories = ', jpl
359	WRITE(numout,*) ' number of ice layers = ', nlay_i
360	WRITE(numout,*) ' number of snow layers = ', nlay_s
361	WRITE(numout,*) ' switch for ice dynamics (1) or not (0) ln_limdyn = ', ln_limdyn
362	WRITE(numout,*) ' maximum ice concentration for NH = ', rn_amax_n
363	WRITE(numout,*) ' maximum ice concentration for SH = ', rn_amax_s
364	WRITE(numout,*) ' Diagnose heat/salt budget or not ln_limdiahsb = ', ln_limdiahsb
365	WRITE(numout,*) ' Output heat/salt budget or not ln_limdiaout = ', ln_limdiaout
366	WRITE(numout,*) ' control prints in ocean.out for (i,j)=(iiceprt,jiceprt) = ', ln_icectl
367	WRITE(numout,*) ' i-index for control prints (ln_icectl=true) = ', iiceprt
368	WRITE(numout,*) ' j-index for control prints (ln_icectl=true) = ', jiceprt
369	ENDIF
370	!
371	! sea-ice timestep and inverse
372	rdt_ice = nn_fsbc * rdt
373	r1_rdtice = 1._wp / rdt_ice
374
375	! inverse of nlay_i and nlay_s
376	r1_nlay_i = 1._wp / REAL( nlay_i, wp )
377	r1_nlay_s = 1._wp / REAL( nlay_s, wp )
378	!
379	IF( lwp .AND. ln_bdy .AND. ln_limdiahsb ) &
380	& CALL ctl_warn('online conservation check activated but it does not work with BDY')
381	!
382	END SUBROUTINE ice_run
383
384
385	SUBROUTINE lim_itd_init
386	!!------------------------------------------------------------------
387	!! * ROUTINE lim_itd_init *
388	!!
389	!! ** Purpose : Initializes the ice thickness distribution
390	!! ** Method : ...
391	!! ** input : Namelist namiceitd
392	!!-------------------------------------------------------------------
393	INTEGER :: ios ! Local integer output status for namelist read
394	NAMELIST/namiceitd/ nn_catbnd, rn_himean
395	!
396	INTEGER :: jl ! dummy loop index
397	REAL(wp) :: zc1, zc2, zc3, zx1 ! local scalars
398	REAL(wp) :: zhmax, znum, zden, zalpha !
399	!!------------------------------------------------------------------
400	!
401	REWIND( numnam_ice_ref ) ! Namelist namiceitd in reference namelist : Parameters for ice
402	READ ( numnam_ice_ref, namiceitd, IOSTAT = ios, ERR = 903)
403	903 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namiceitd in reference namelist', lwp )
404	!
405	REWIND( numnam_ice_cfg ) ! Namelist namiceitd in configuration namelist : Parameters for ice
406	READ ( numnam_ice_cfg, namiceitd, IOSTAT = ios, ERR = 904 )
407	904 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namiceitd in configuration namelist', lwp )
408	IF(lwm) WRITE( numoni, namiceitd )
409	!
410	IF(lwp) THEN ! control print
411	WRITE(numout,*)
412	WRITE(numout,*) 'ice_itd : ice cat distribution'
413	WRITE(numout,*) ' ~~~~~~'
414	WRITE(numout,*) ' shape of ice categories distribution nn_catbnd = ', nn_catbnd
415	WRITE(numout,*) ' mean ice thickness in the domain (used if nn_catbnd=2) rn_himean = ', rn_himean
416	ENDIF
417	!
418	!----------------------------------
419	!- Thickness categories boundaries
420	!----------------------------------
421	IF(lwp) WRITE(numout,*)
422	IF(lwp) WRITE(numout,*) 'lim_itd_init : Initialization of ice cat distribution '
423	IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~'
424	!
425	hi_max(:) = 0._wp
426	!
427	SELECT CASE ( nn_catbnd ) ! type of ice categories distribution
428	!
429	CASE (1) !== tanh function (CICE) ==!
430	zc1 = 3._wp / REAL( jpl, wp )
431	zc2 = 10._wp * zc1
432	zc3 = 3._wp
433	DO jl = 1, jpl
434	zx1 = REAL( jl-1, wp ) / REAL( jpl, wp )
435	hi_max(jl) = hi_max(jl-1) + zc1 + zc2 * (1._wp + TANH( zc3 * (zx1 - 1._wp ) ) )
436	END DO
437	!
438	CASE (2) !== h^(-alpha) function ==!
439	zalpha = 0.05_wp
440	zhmax = 3._wp * rn_himean
441	DO jl = 1, jpl
442	znum = jpl * ( zhmax+1 )**zalpha
443	zden = REAL( jpl-jl , wp ) * ( zhmax + 1._wp )**zalpha + REAL( jl , wp )
444	hi_max(jl) = ( znum / zden )**(1./zalpha) - 1
445	END DO
446	!
447	END SELECT
448	!
449	DO jl = 1, jpl ! mean thickness by category
450	hi_mean(jl) = ( hi_max(jl) + hi_max(jl-1) ) * 0.5_wp
451	END DO
452	!
453	hi_max(jpl) = 99._wp ! set to a big value to ensure that all ice is thinner than hi_max(jpl)
454	!
455	IF(lwp) WRITE(numout,*) ' Thickness category boundaries '
456	IF(lwp) WRITE(numout,*) ' hi_max ', hi_max(0:jpl)
457	!
458	END SUBROUTINE lim_itd_init
459
460
461	SUBROUTINE ice_lim_flx( ptn_ice , palb_ice, pqns_ice , &
462	& pqsr_ice, pdqn_ice, pevap_ice, pdevap_ice, k_limflx )
463	!!---------------------------------------------------------------------
464	!! * ROUTINE ice_lim_flx *
465	!!
466	!! ** Purpose : update the ice surface boundary condition by averaging and / or
467	!! redistributing fluxes on ice categories
468	!!
469	!! ** Method : average then redistribute
470	!!
471	!! ** Action :
472	!!---------------------------------------------------------------------
473	INTEGER , INTENT(in ) :: k_limflx ! =-1 do nothing; =0 average ;
474	! ! =1 average and redistribute ; =2 redistribute
475	REAL(wp), DIMENSION(:,:,:), INTENT(in ) :: ptn_ice ! ice surface temperature
476	REAL(wp), DIMENSION(:,:,:), INTENT(in ) :: palb_ice ! ice albedo
477	REAL(wp), DIMENSION(:,:,:), INTENT(inout) :: pqns_ice ! non solar flux
478	REAL(wp), DIMENSION(:,:,:), INTENT(inout) :: pqsr_ice ! net solar flux
479	REAL(wp), DIMENSION(:,:,:), INTENT(inout) :: pdqn_ice ! non solar flux sensitivity
480	REAL(wp), DIMENSION(:,:,:), INTENT(inout) :: pevap_ice ! sublimation
481	REAL(wp), DIMENSION(:,:,:), INTENT(inout) :: pdevap_ice ! sublimation sensitivity
482	!
483	INTEGER :: jl ! dummy loop index
484	!
485	REAL(wp), POINTER, DIMENSION(:,:) :: zalb_m ! Mean albedo over all categories
486	REAL(wp), POINTER, DIMENSION(:,:) :: ztem_m ! Mean temperature over all categories
487	!
488	REAL(wp), POINTER, DIMENSION(:,:) :: z_qsr_m ! Mean solar heat flux over all categories
489	REAL(wp), POINTER, DIMENSION(:,:) :: z_qns_m ! Mean non solar heat flux over all categories
490	REAL(wp), POINTER, DIMENSION(:,:) :: z_evap_m ! Mean sublimation over all categories
491	REAL(wp), POINTER, DIMENSION(:,:) :: z_dqn_m ! Mean d(qns)/dT over all categories
492	REAL(wp), POINTER, DIMENSION(:,:) :: z_devap_m ! Mean d(evap)/dT over all categories
493	!!----------------------------------------------------------------------
494	!
495	IF( nn_timing == 1 ) CALL timing_start('ice_lim_flx')
496	!
497	SELECT CASE( k_limflx ) !== averaged on all ice categories ==!
498	CASE( 0 , 1 )
499	CALL wrk_alloc( jpi,jpj, z_qsr_m, z_qns_m, z_evap_m, z_dqn_m, z_devap_m)
500	!
501	z_qns_m (:,:) = fice_ice_ave ( pqns_ice (:,:,:) )
502	z_qsr_m (:,:) = fice_ice_ave ( pqsr_ice (:,:,:) )
503	z_dqn_m (:,:) = fice_ice_ave ( pdqn_ice (:,:,:) )
504	z_evap_m (:,:) = fice_ice_ave ( pevap_ice (:,:,:) )
505	z_devap_m(:,:) = fice_ice_ave ( pdevap_ice (:,:,:) )
506	DO jl = 1, jpl
507	pdqn_ice (:,:,jl) = z_dqn_m(:,:)
508	pdevap_ice(:,:,jl) = z_devap_m(:,:)
509	END DO
510	!
511	DO jl = 1, jpl
512	pqns_ice (:,:,jl) = z_qns_m(:,:)
513	pqsr_ice (:,:,jl) = z_qsr_m(:,:)
514	pevap_ice(:,:,jl) = z_evap_m(:,:)
515	END DO
516	!
517	CALL wrk_dealloc( jpi,jpj, z_qsr_m, z_qns_m, z_evap_m, z_dqn_m, z_devap_m)
518	END SELECT
519	!
520	SELECT CASE( k_limflx ) !== redistribution on all ice categories ==!
521	CASE( 1 , 2 )
522	CALL wrk_alloc( jpi,jpj, zalb_m, ztem_m )
523	!
524	zalb_m(:,:) = fice_ice_ave ( palb_ice (:,:,:) )
525	ztem_m(:,:) = fice_ice_ave ( ptn_ice (:,:,:) )
526	DO jl = 1, jpl
527	pqns_ice (:,:,jl) = pqns_ice (:,:,jl) + pdqn_ice (:,:,jl) * ( ptn_ice(:,:,jl) - ztem_m(:,:) )
528	pevap_ice(:,:,jl) = pevap_ice(:,:,jl) + pdevap_ice(:,:,jl) * ( ptn_ice(:,:,jl) - ztem_m(:,:) )
529	pqsr_ice (:,:,jl) = pqsr_ice (:,:,jl) * ( 1._wp - palb_ice(:,:,jl) ) / ( 1._wp - zalb_m(:,:) )
530	END DO
531	!
532	CALL wrk_dealloc( jpi,jpj, zalb_m, ztem_m )
533	END SELECT
534	!
535	IF( nn_timing == 1 ) CALL timing_stop('ice_lim_flx')
536	!
537	END SUBROUTINE ice_lim_flx
538
539
540	SUBROUTINE sbc_lim_bef
541	!!----------------------------------------------------------------------
542	!! * ROUTINE sbc_lim_bef *
543	!!
544	!! ** purpose : store ice variables at "before" time step
545	!!----------------------------------------------------------------------
546	a_i_b (:,:,:) = a_i (:,:,:) ! ice area
547	e_i_b (:,:,:,:) = e_i (:,:,:,:) ! ice thermal energy
548	v_i_b (:,:,:) = v_i (:,:,:) ! ice volume
549	v_s_b (:,:,:) = v_s (:,:,:) ! snow volume
550	e_s_b (:,:,:,:) = e_s (:,:,:,:) ! snow thermal energy
551	smv_i_b(:,:,:) = smv_i(:,:,:) ! salt content
552	oa_i_b (:,:,:) = oa_i (:,:,:) ! areal age content
553	u_ice_b(:,:) = u_ice(:,:)
554	v_ice_b(:,:) = v_ice(:,:)
555	!
556	END SUBROUTINE sbc_lim_bef
557
558
559	SUBROUTINE sbc_lim_diag0
560	!!----------------------------------------------------------------------
561	!! * ROUTINE sbc_lim_diag0 *
562	!!
563	!! ** purpose : set ice-ocean and ice-atm. fluxes to zeros at the beggining
564	!! of the time step
565	!!----------------------------------------------------------------------
566	sfx (:,:) = 0._wp ;
567	sfx_bri(:,:) = 0._wp ;
568	sfx_sni(:,:) = 0._wp ; sfx_opw(:,:) = 0._wp
569	sfx_bog(:,:) = 0._wp ; sfx_dyn(:,:) = 0._wp
570	sfx_bom(:,:) = 0._wp ; sfx_sum(:,:) = 0._wp
571	sfx_res(:,:) = 0._wp ; sfx_sub(:,:) = 0._wp
572	!
573	wfx_snw(:,:) = 0._wp ; wfx_ice(:,:) = 0._wp
574	wfx_sni(:,:) = 0._wp ; wfx_opw(:,:) = 0._wp
575	wfx_bog(:,:) = 0._wp ; wfx_dyn(:,:) = 0._wp
576	wfx_bom(:,:) = 0._wp ; wfx_sum(:,:) = 0._wp
577	wfx_res(:,:) = 0._wp ; wfx_sub(:,:) = 0._wp
578	wfx_spr(:,:) = 0._wp ;
579	!
580	hfx_thd(:,:) = 0._wp ;
581	hfx_snw(:,:) = 0._wp ; hfx_opw(:,:) = 0._wp
582	hfx_bog(:,:) = 0._wp ; hfx_dyn(:,:) = 0._wp
583	hfx_bom(:,:) = 0._wp ; hfx_sum(:,:) = 0._wp
584	hfx_res(:,:) = 0._wp ; hfx_sub(:,:) = 0._wp
585	hfx_spr(:,:) = 0._wp ; hfx_dif(:,:) = 0._wp
586	hfx_err(:,:) = 0._wp ; hfx_err_rem(:,:) = 0._wp
587	hfx_err_dif(:,:) = 0._wp
588	wfx_err_sub(:,:) = 0._wp
589	!
590	afx_tot(:,:) = 0._wp ;
591	afx_dyn(:,:) = 0._wp ; afx_thd(:,:) = 0._wp
592	!
593	diag_heat(:,:) = 0._wp ; diag_smvi(:,:) = 0._wp ;
594	diag_vice(:,:) = 0._wp ; diag_vsnw(:,:) = 0._wp ;
595	!
596	END SUBROUTINE sbc_lim_diag0
597
598
599	FUNCTION fice_cell_ave ( ptab )
600	!!--------------------------------------------------------------------------
601	!! * Compute average over categories, for grid cell (ice covered and free ocean)
602	!!--------------------------------------------------------------------------
603	REAL (wp), DIMENSION (jpi,jpj) :: fice_cell_ave
604	REAL (wp), DIMENSION (jpi,jpj,jpl), INTENT (in) :: ptab
605	INTEGER :: jl ! Dummy loop index
606
607	fice_cell_ave (:,:) = 0.0_wp
608	DO jl = 1, jpl
609	fice_cell_ave (:,:) = fice_cell_ave (:,:) + a_i (:,:,jl) * ptab (:,:,jl)
610	END DO
611
612	END FUNCTION fice_cell_ave
613
614
615	FUNCTION fice_ice_ave ( ptab )
616	!!--------------------------------------------------------------------------
617	!! * Compute average over categories, for ice covered part of grid cell
618	!!--------------------------------------------------------------------------
619	REAL (kind=wp), DIMENSION (jpi,jpj) :: fice_ice_ave
620	REAL (kind=wp), DIMENSION (jpi,jpj,jpl), INTENT(in) :: ptab
621
622	fice_ice_ave (:,:) = 0.0_wp
623	WHERE ( at_i (:,:) > 0.0_wp ) fice_ice_ave (:,:) = fice_cell_ave ( ptab (:,:,:)) / at_i (:,:)
624
625	END FUNCTION fice_ice_ave
626
627	#else
628	!!----------------------------------------------------------------------
629	!! Default option Dummy module NO LIM 3.0 sea-ice model
630	!!----------------------------------------------------------------------
631	CONTAINS
632	SUBROUTINE sbc_ice_lim ( kt, kblk ) ! Dummy routine
633	WRITE(,) 'sbc_ice_lim: You should not have seen this print! error?', kt, kblk
634	END SUBROUTINE sbc_ice_lim
635	SUBROUTINE sbc_lim_init ! Dummy routine
636	END SUBROUTINE sbc_lim_init
637	#endif
638
639	!!======================================================================
640	END MODULE sbcice_lim

Note: See TracBrowser for help on using the repository browser.

Download in other formats: