1 | MODULE dynzdf_exp |
---|
2 | !!============================================================================== |
---|
3 | !! *** MODULE dynzdf_exp *** |
---|
4 | !! Ocean dynamics: vertical component(s) of the momentum mixing trend |
---|
5 | !!============================================================================== |
---|
6 | !! History : OPA ! 1990-10 (B. Blanke) Original code |
---|
7 | !! 8.0 ! 1997-05 (G. Madec) vertical component of isopycnal |
---|
8 | !! NEMO 0.5 ! 2002-08 (G. Madec) F90: Free form and module |
---|
9 | !! 3.3 ! 2010-04 (M. Leclair, G. Madec) Forcing averaged over 2 time steps |
---|
10 | !! 3.7 ! 2015-11 (J. Chanut) output velocities instead of trends |
---|
11 | !!---------------------------------------------------------------------- |
---|
12 | |
---|
13 | !!---------------------------------------------------------------------- |
---|
14 | !! dyn_zdf_exp : update the momentum trend with the vertical diffusion using a split-explicit scheme |
---|
15 | !! and perform the Leap-Frog time integration. |
---|
16 | !!---------------------------------------------------------------------- |
---|
17 | USE oce ! ocean dynamics and tracers |
---|
18 | USE dom_oce ! ocean space and time domain |
---|
19 | USE phycst ! physical constants |
---|
20 | USE zdf_oce ! ocean vertical physics |
---|
21 | USE dynadv , ONLY: ln_dynadv_vec ! Momentum advection form |
---|
22 | USE sbc_oce ! surface boundary condition: ocean |
---|
23 | ! |
---|
24 | USE in_out_manager ! I/O manager |
---|
25 | USE lib_mpp ! MPP library |
---|
26 | USE wrk_nemo ! Memory Allocation |
---|
27 | USE timing ! Timing |
---|
28 | |
---|
29 | IMPLICIT NONE |
---|
30 | PRIVATE |
---|
31 | |
---|
32 | PUBLIC dyn_zdf_exp ! called by step.F90 |
---|
33 | |
---|
34 | !! * Substitutions |
---|
35 | # include "vectopt_loop_substitute.h90" |
---|
36 | !!---------------------------------------------------------------------- |
---|
37 | !! NEMO/OPA 3.7 , NEMO Consortium (2015) |
---|
38 | !! $Id$ |
---|
39 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
---|
40 | !!---------------------------------------------------------------------- |
---|
41 | CONTAINS |
---|
42 | |
---|
43 | SUBROUTINE dyn_zdf_exp( kt, p2dt ) |
---|
44 | !!---------------------------------------------------------------------- |
---|
45 | !! *** ROUTINE dyn_zdf_exp *** |
---|
46 | !! |
---|
47 | !! ** Purpose : Compute the trend due to the vert. momentum diffusion |
---|
48 | !! and perform the Leap-Frog time stepping. |
---|
49 | !! |
---|
50 | !! ** Method : - Split-explicit forward time stepping. |
---|
51 | !! The vertical mixing of momentum is given by: |
---|
52 | !! diffu = dz( avmu dz(u) ) = 1/e3u dk+1( avmu/e3uw dk(ub) ) |
---|
53 | !! Surface boundary conditions: wind stress input (averaged over kt-1/2 & kt+1/2) |
---|
54 | !! Bottom boundary conditions : bottom stress (cf zdfbfr.F90) |
---|
55 | !! Add this trend to the general trend ua : |
---|
56 | !! ua = ua + dz( avmu dz(u) ) |
---|
57 | !! - Leap-Frog time stepping (Asselin filter will be applied in dyn_nxt) |
---|
58 | !! ua = ub + 2*dt * ua vector form or linear free surf. |
---|
59 | !! ua = ( e3u_b*ub + 2*dt * e3u_n*ua ) / e3u_a otherwise |
---|
60 | !! |
---|
61 | !! ** Action : - (ua,va) after velocity |
---|
62 | !!--------------------------------------------------------------------- |
---|
63 | INTEGER , INTENT(in) :: kt ! ocean time-step index |
---|
64 | REAL(wp), INTENT(in) :: p2dt ! time-step |
---|
65 | ! |
---|
66 | INTEGER :: ji, jj, jk, jl ! dummy loop indices |
---|
67 | REAL(wp) :: zlavmr, zua, zva ! local scalars |
---|
68 | REAL(wp), POINTER, DIMENSION(:,:,:) :: zwx, zwy, zwz, zww |
---|
69 | !!---------------------------------------------------------------------- |
---|
70 | ! |
---|
71 | IF( nn_timing == 1 ) CALL timing_start('dyn_zdf_exp') |
---|
72 | ! |
---|
73 | CALL wrk_alloc( jpi,jpj,jpk, zwx, zwy, zwz, zww ) |
---|
74 | ! |
---|
75 | IF( kt == nit000 .AND. lwp ) THEN |
---|
76 | WRITE(numout,*) |
---|
77 | WRITE(numout,*) 'dyn_zdf_exp : vertical momentum diffusion - explicit operator' |
---|
78 | WRITE(numout,*) '~~~~~~~~~~~ ' |
---|
79 | ENDIF |
---|
80 | ! |
---|
81 | ! !== vertical mixing trend ==! |
---|
82 | ! |
---|
83 | zlavmr = 1. / REAL( nn_zdfexp ) |
---|
84 | ! |
---|
85 | DO jj = 2, jpjm1 ! Surface boundary condition |
---|
86 | DO ji = 2, jpim1 |
---|
87 | zwy(ji,jj,1) = ( utau_b(ji,jj) + utau(ji,jj) ) * r1_rau0 |
---|
88 | zww(ji,jj,1) = ( vtau_b(ji,jj) + vtau(ji,jj) ) * r1_rau0 |
---|
89 | END DO |
---|
90 | END DO |
---|
91 | DO jk = 1, jpk ! Initialization of x, z and contingently trends array |
---|
92 | DO jj = 2, jpjm1 |
---|
93 | DO ji = 2, jpim1 |
---|
94 | zwx(ji,jj,jk) = ub(ji,jj,jk) |
---|
95 | zwz(ji,jj,jk) = vb(ji,jj,jk) |
---|
96 | END DO |
---|
97 | END DO |
---|
98 | END DO |
---|
99 | ! |
---|
100 | DO jl = 1, nn_zdfexp ! Time splitting loop |
---|
101 | ! |
---|
102 | DO jk = 2, jpk ! First vertical derivative |
---|
103 | DO jj = 2, jpjm1 |
---|
104 | DO ji = 2, jpim1 |
---|
105 | zwy(ji,jj,jk) = avmu(ji,jj,jk) * ( zwx(ji,jj,jk-1) - zwx(ji,jj,jk) ) / e3uw_n(ji,jj,jk) |
---|
106 | zww(ji,jj,jk) = avmv(ji,jj,jk) * ( zwz(ji,jj,jk-1) - zwz(ji,jj,jk) ) / e3vw_n(ji,jj,jk) |
---|
107 | END DO |
---|
108 | END DO |
---|
109 | END DO |
---|
110 | DO jk = 1, jpkm1 ! Second vertical derivative and trend estimation at kt+l*rdt/nn_zdfexp |
---|
111 | DO jj = 2, jpjm1 |
---|
112 | DO ji = 2, jpim1 |
---|
113 | zua = zlavmr * ( zwy(ji,jj,jk) - zwy(ji,jj,jk+1) ) / e3u_n(ji,jj,jk) |
---|
114 | zva = zlavmr * ( zww(ji,jj,jk) - zww(ji,jj,jk+1) ) / e3v_n(ji,jj,jk) |
---|
115 | ua(ji,jj,jk) = ua(ji,jj,jk) + zua |
---|
116 | va(ji,jj,jk) = va(ji,jj,jk) + zva |
---|
117 | ! |
---|
118 | zwx(ji,jj,jk) = zwx(ji,jj,jk) + p2dt * zua * umask(ji,jj,jk) |
---|
119 | zwz(ji,jj,jk) = zwz(ji,jj,jk) + p2dt * zva * vmask(ji,jj,jk) |
---|
120 | END DO |
---|
121 | END DO |
---|
122 | END DO |
---|
123 | END DO ! End of time splitting |
---|
124 | ! |
---|
125 | ! |
---|
126 | ! !== Leap-Frog time integration ==! |
---|
127 | ! |
---|
128 | IF( ln_dynadv_vec .OR. ln_linssh ) THEN ! applied on velocity |
---|
129 | DO jk = 1, jpkm1 |
---|
130 | ua(:,:,jk) = ( ub(:,:,jk) + p2dt * ua(:,:,jk) ) * umask(:,:,jk) |
---|
131 | va(:,:,jk) = ( vb(:,:,jk) + p2dt * va(:,:,jk) ) * vmask(:,:,jk) |
---|
132 | END DO |
---|
133 | ELSE ! applied on thickness weighted velocity |
---|
134 | DO jk = 1, jpkm1 |
---|
135 | ua(:,:,jk) = ( e3u_b(:,:,jk) * ub(:,:,jk) & |
---|
136 | & + p2dt * e3u_n(:,:,jk) * ua(:,:,jk) ) / e3u_a(:,:,jk) * umask(:,:,jk) |
---|
137 | va(:,:,jk) = ( e3v_b(:,:,jk) * vb(:,:,jk) & |
---|
138 | & + p2dt * e3v_n(:,:,jk) * va(:,:,jk) ) / e3v_a(:,:,jk) * vmask(:,:,jk) |
---|
139 | END DO |
---|
140 | ENDIF |
---|
141 | ! |
---|
142 | CALL wrk_dealloc( jpi,jpj,jpk, zwx, zwy, zwz, zww ) |
---|
143 | ! |
---|
144 | IF( nn_timing == 1 ) CALL timing_stop('dyn_zdf_exp') |
---|
145 | ! |
---|
146 | END SUBROUTINE dyn_zdf_exp |
---|
147 | |
---|
148 | !!============================================================================== |
---|
149 | END MODULE dynzdf_exp |
---|