1 | MODULE sbcblk_core |
---|
2 | !!====================================================================== |
---|
3 | !! *** MODULE sbcblk_core *** |
---|
4 | !! Ocean forcing: momentum, heat and freshwater flux formulation |
---|
5 | !!===================================================================== |
---|
6 | !! History : 1.0 ! 2004-08 (U. Schweckendiek) Original code |
---|
7 | !! 2.0 ! 2005-04 (L. Brodeau, A.M. Treguier) additions: |
---|
8 | !! - new bulk routine for efficiency |
---|
9 | !! - WINDS ARE NOW ASSUMED TO BE AT T POINTS in input files !!!! |
---|
10 | !! - file names and file characteristics in namelist |
---|
11 | !! - Implement reading of 6-hourly fields |
---|
12 | !! 3.0 ! 2006-06 (G. Madec) sbc rewritting |
---|
13 | !! - ! 2006-12 (L. Brodeau) Original code for turb_core_2z |
---|
14 | !! 3.2 ! 2009-04 (B. Lemaire) Introduce iom_put |
---|
15 | !! 3.3 ! 2010-10 (S. Masson) add diurnal cycle |
---|
16 | !! 3.4 ! 2011-11 (C. Harris) Fill arrays required by CICE |
---|
17 | !! 3.7 ! 2014-06 (L. Brodeau) simplification and optimization of CORE bulk |
---|
18 | !!---------------------------------------------------------------------- |
---|
19 | |
---|
20 | !!---------------------------------------------------------------------- |
---|
21 | !! sbc_blk_core : bulk formulation as ocean surface boundary condition (forced mode, CORE bulk formulea) |
---|
22 | !! blk_oce_core : computes momentum, heat and freshwater fluxes over ocean |
---|
23 | !! blk_ice_core : computes momentum, heat and freshwater fluxes over ice |
---|
24 | !! turb_core_2z : Computes turbulent transfert coefficients |
---|
25 | !! cd_neutral_10m : Estimate of the neutral drag coefficient at 10m |
---|
26 | !! psi_m : universal profile stability function for momentum |
---|
27 | !! psi_h : universal profile stability function for temperature and humidity |
---|
28 | !!---------------------------------------------------------------------- |
---|
29 | USE oce ! ocean dynamics and tracers |
---|
30 | USE dom_oce ! ocean space and time domain |
---|
31 | USE phycst ! physical constants |
---|
32 | USE fldread ! read input fields |
---|
33 | USE sbc_oce ! Surface boundary condition: ocean fields |
---|
34 | USE cyclone ! Cyclone 10m wind form trac of cyclone centres |
---|
35 | USE sbcdcy ! surface boundary condition: diurnal cycle |
---|
36 | USE iom ! I/O manager library |
---|
37 | USE in_out_manager ! I/O manager |
---|
38 | USE lib_mpp ! distribued memory computing library |
---|
39 | USE wrk_nemo ! work arrays |
---|
40 | USE timing ! Timing |
---|
41 | USE lbclnk ! ocean lateral boundary conditions (or mpp link) |
---|
42 | USE prtctl ! Print control |
---|
43 | USE sbcwave, ONLY : cdn_wave ! wave module |
---|
44 | USE sbc_ice ! Surface boundary condition: ice fields |
---|
45 | USE lib_fortran ! to use key_nosignedzero |
---|
46 | |
---|
47 | IMPLICIT NONE |
---|
48 | PRIVATE |
---|
49 | |
---|
50 | PUBLIC sbc_blk_core ! routine called in sbcmod module |
---|
51 | PUBLIC blk_ice_core ! routine called in sbc_ice_lim module |
---|
52 | PUBLIC turb_core_2z ! routine calles in sbcblk_mfs module |
---|
53 | |
---|
54 | INTEGER , PARAMETER :: jpfld = 9 ! maximum number of files to read |
---|
55 | INTEGER , PARAMETER :: jp_wndi = 1 ! index of 10m wind velocity (i-component) (m/s) at T-point |
---|
56 | INTEGER , PARAMETER :: jp_wndj = 2 ! index of 10m wind velocity (j-component) (m/s) at T-point |
---|
57 | INTEGER , PARAMETER :: jp_humi = 3 ! index of specific humidity ( % ) |
---|
58 | INTEGER , PARAMETER :: jp_qsr = 4 ! index of solar heat (W/m2) |
---|
59 | INTEGER , PARAMETER :: jp_qlw = 5 ! index of Long wave (W/m2) |
---|
60 | INTEGER , PARAMETER :: jp_tair = 6 ! index of 10m air temperature (Kelvin) |
---|
61 | INTEGER , PARAMETER :: jp_prec = 7 ! index of total precipitation (rain+snow) (Kg/m2/s) |
---|
62 | INTEGER , PARAMETER :: jp_snow = 8 ! index of snow (solid prcipitation) (kg/m2/s) |
---|
63 | INTEGER , PARAMETER :: jp_tdif = 9 ! index of tau diff associated to HF tau (N/m2) at T-point |
---|
64 | |
---|
65 | TYPE(FLD), ALLOCATABLE, DIMENSION(:) :: sf ! structure of input fields (file informations, fields read) |
---|
66 | |
---|
67 | ! !!! CORE bulk parameters |
---|
68 | REAL(wp), PARAMETER :: rhoa = 1.22 ! air density |
---|
69 | REAL(wp), PARAMETER :: cpa = 1000.5 ! specific heat of air |
---|
70 | REAL(wp), PARAMETER :: Lv = 2.5e6 ! latent heat of vaporization |
---|
71 | REAL(wp), PARAMETER :: Ls = 2.839e6 ! latent heat of sublimation |
---|
72 | REAL(wp), PARAMETER :: Stef = 5.67e-8 ! Stefan Boltzmann constant |
---|
73 | REAL(wp), PARAMETER :: Cice = 1.4e-3 ! iovi 1.63e-3 ! transfer coefficient over ice |
---|
74 | REAL(wp), PARAMETER :: albo = 0.066 ! ocean albedo assumed to be constant |
---|
75 | |
---|
76 | ! !!* Namelist namsbc_core : CORE bulk parameters |
---|
77 | LOGICAL :: ln_taudif ! logical flag to use the "mean of stress module - module of mean stress" data |
---|
78 | REAL(wp) :: rn_pfac ! multiplication factor for precipitation |
---|
79 | REAL(wp) :: rn_efac ! multiplication factor for evaporation (clem) |
---|
80 | REAL(wp) :: rn_vfac ! multiplication factor for ice/ocean velocity in the calculation of wind stress (clem) |
---|
81 | REAL(wp) :: rn_zqt ! z(q,t) : height of humidity and temperature measurements |
---|
82 | REAL(wp) :: rn_zu ! z(u) : height of wind measurements |
---|
83 | |
---|
84 | !! * Substitutions |
---|
85 | # include "domzgr_substitute.h90" |
---|
86 | # include "vectopt_loop_substitute.h90" |
---|
87 | !!---------------------------------------------------------------------- |
---|
88 | !! NEMO/OPA 3.7 , NEMO-consortium (2014) |
---|
89 | !! $Id$ |
---|
90 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
---|
91 | !!---------------------------------------------------------------------- |
---|
92 | CONTAINS |
---|
93 | |
---|
94 | SUBROUTINE sbc_blk_core( kt ) |
---|
95 | !!--------------------------------------------------------------------- |
---|
96 | !! *** ROUTINE sbc_blk_core *** |
---|
97 | !! |
---|
98 | !! ** Purpose : provide at each time step the surface ocean fluxes |
---|
99 | !! (momentum, heat, freshwater and runoff) |
---|
100 | !! |
---|
101 | !! ** Method : (1) READ each fluxes in NetCDF files: |
---|
102 | !! the 10m wind velocity (i-component) (m/s) at T-point |
---|
103 | !! the 10m wind velocity (j-component) (m/s) at T-point |
---|
104 | !! the 10m or 2m specific humidity ( % ) |
---|
105 | !! the solar heat (W/m2) |
---|
106 | !! the Long wave (W/m2) |
---|
107 | !! the 10m or 2m air temperature (Kelvin) |
---|
108 | !! the total precipitation (rain+snow) (Kg/m2/s) |
---|
109 | !! the snow (solid prcipitation) (kg/m2/s) |
---|
110 | !! the tau diff associated to HF tau (N/m2) at T-point (ln_taudif=T) |
---|
111 | !! (2) CALL blk_oce_core |
---|
112 | !! |
---|
113 | !! C A U T I O N : never mask the surface stress fields |
---|
114 | !! the stress is assumed to be in the (i,j) mesh referential |
---|
115 | !! |
---|
116 | !! ** Action : defined at each time-step at the air-sea interface |
---|
117 | !! - utau, vtau i- and j-component of the wind stress |
---|
118 | !! - taum wind stress module at T-point |
---|
119 | !! - wndm wind speed module at T-point over free ocean or leads in presence of sea-ice |
---|
120 | !! - qns, qsr non-solar and solar heat fluxes |
---|
121 | !! - emp upward mass flux (evapo. - precip.) |
---|
122 | !! - sfx salt flux due to freezing/melting (non-zero only if ice is present) |
---|
123 | !! (set in limsbc(_2).F90) |
---|
124 | !! |
---|
125 | !! ** References : Large & Yeager, 2004 / Large & Yeager, 2008 |
---|
126 | !! Brodeau et al. Ocean Modelling 2010 |
---|
127 | !!---------------------------------------------------------------------- |
---|
128 | INTEGER, INTENT(in) :: kt ! ocean time step |
---|
129 | ! |
---|
130 | INTEGER :: ierror ! return error code |
---|
131 | INTEGER :: ifpr ! dummy loop indice |
---|
132 | INTEGER :: jfld ! dummy loop arguments |
---|
133 | INTEGER :: ios ! Local integer output status for namelist read |
---|
134 | ! |
---|
135 | CHARACTER(len=100) :: cn_dir ! Root directory for location of core files |
---|
136 | TYPE(FLD_N), DIMENSION(jpfld) :: slf_i ! array of namelist informations on the fields to read |
---|
137 | TYPE(FLD_N) :: sn_wndi, sn_wndj, sn_humi, sn_qsr ! informations about the fields to be read |
---|
138 | TYPE(FLD_N) :: sn_qlw , sn_tair, sn_prec, sn_snow ! " " |
---|
139 | TYPE(FLD_N) :: sn_tdif ! " " |
---|
140 | NAMELIST/namsbc_core/ cn_dir , ln_taudif, rn_pfac, rn_efac, rn_vfac, & |
---|
141 | & sn_wndi, sn_wndj, sn_humi , sn_qsr , & |
---|
142 | & sn_qlw , sn_tair, sn_prec , sn_snow, & |
---|
143 | & sn_tdif, rn_zqt, rn_zu |
---|
144 | !!--------------------------------------------------------------------- |
---|
145 | ! |
---|
146 | ! ! ====================== ! |
---|
147 | IF( kt == nit000 ) THEN ! First call kt=nit000 ! |
---|
148 | ! ! ====================== ! |
---|
149 | ! |
---|
150 | REWIND( numnam_ref ) ! Namelist namsbc_core in reference namelist : CORE bulk parameters |
---|
151 | READ ( numnam_ref, namsbc_core, IOSTAT = ios, ERR = 901) |
---|
152 | 901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc_core in reference namelist', lwp ) |
---|
153 | ! |
---|
154 | REWIND( numnam_cfg ) ! Namelist namsbc_core in configuration namelist : CORE bulk parameters |
---|
155 | READ ( numnam_cfg, namsbc_core, IOSTAT = ios, ERR = 902 ) |
---|
156 | 902 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc_core in configuration namelist', lwp ) |
---|
157 | |
---|
158 | IF(lwm) WRITE( numond, namsbc_core ) |
---|
159 | ! ! check: do we plan to use ln_dm2dc with non-daily forcing? |
---|
160 | IF( ln_dm2dc .AND. sn_qsr%nfreqh /= 24 ) & |
---|
161 | & CALL ctl_stop( 'sbc_blk_core: ln_dm2dc can be activated only with daily short-wave forcing' ) |
---|
162 | IF( ln_dm2dc .AND. sn_qsr%ln_tint ) THEN |
---|
163 | CALL ctl_warn( 'sbc_blk_core: ln_dm2dc is taking care of the temporal interpolation of daily qsr', & |
---|
164 | & ' ==> We force time interpolation = .false. for qsr' ) |
---|
165 | sn_qsr%ln_tint = .false. |
---|
166 | ENDIF |
---|
167 | ! ! store namelist information in an array |
---|
168 | slf_i(jp_wndi) = sn_wndi ; slf_i(jp_wndj) = sn_wndj |
---|
169 | slf_i(jp_qsr ) = sn_qsr ; slf_i(jp_qlw ) = sn_qlw |
---|
170 | slf_i(jp_tair) = sn_tair ; slf_i(jp_humi) = sn_humi |
---|
171 | slf_i(jp_prec) = sn_prec ; slf_i(jp_snow) = sn_snow |
---|
172 | slf_i(jp_tdif) = sn_tdif |
---|
173 | ! |
---|
174 | lhftau = ln_taudif ! do we use HF tau information? |
---|
175 | jfld = jpfld - COUNT( (/.NOT. lhftau/) ) |
---|
176 | ! |
---|
177 | ALLOCATE( sf(jfld), STAT=ierror ) ! set sf structure |
---|
178 | IF( ierror > 0 ) CALL ctl_stop( 'STOP', 'sbc_blk_core: unable to allocate sf structure' ) |
---|
179 | DO ifpr= 1, jfld |
---|
180 | ALLOCATE( sf(ifpr)%fnow(jpi,jpj,1) ) |
---|
181 | IF( slf_i(ifpr)%ln_tint ) ALLOCATE( sf(ifpr)%fdta(jpi,jpj,1,2) ) |
---|
182 | END DO |
---|
183 | ! ! fill sf with slf_i and control print |
---|
184 | CALL fld_fill( sf, slf_i, cn_dir, 'sbc_blk_core', 'flux formulation for ocean surface boundary condition', 'namsbc_core' ) |
---|
185 | ! |
---|
186 | sfx(:,:) = 0._wp ! salt flux; zero unless ice is present (computed in limsbc(_2).F90) |
---|
187 | ! |
---|
188 | ENDIF |
---|
189 | |
---|
190 | CALL fld_read( kt, nn_fsbc, sf ) ! input fields provided at the current time-step |
---|
191 | |
---|
192 | ! ! compute the surface ocean fluxes using CORE bulk formulea |
---|
193 | IF( MOD( kt - 1, nn_fsbc ) == 0 ) CALL blk_oce_core( kt, sf, sst_m, ssu_m, ssv_m ) |
---|
194 | |
---|
195 | #if defined key_cice |
---|
196 | IF( MOD( kt - 1, nn_fsbc ) == 0 ) THEN |
---|
197 | qlw_ice(:,:,1) = sf(jp_qlw)%fnow(:,:,1) |
---|
198 | qsr_ice(:,:,1) = sf(jp_qsr)%fnow(:,:,1) |
---|
199 | tatm_ice(:,:) = sf(jp_tair)%fnow(:,:,1) |
---|
200 | qatm_ice(:,:) = sf(jp_humi)%fnow(:,:,1) |
---|
201 | tprecip(:,:) = sf(jp_prec)%fnow(:,:,1) * rn_pfac |
---|
202 | sprecip(:,:) = sf(jp_snow)%fnow(:,:,1) * rn_pfac |
---|
203 | wndi_ice(:,:) = sf(jp_wndi)%fnow(:,:,1) |
---|
204 | wndj_ice(:,:) = sf(jp_wndj)%fnow(:,:,1) |
---|
205 | ENDIF |
---|
206 | #endif |
---|
207 | ! |
---|
208 | END SUBROUTINE sbc_blk_core |
---|
209 | |
---|
210 | |
---|
211 | SUBROUTINE blk_oce_core( kt, sf, pst, pu, pv ) |
---|
212 | !!--------------------------------------------------------------------- |
---|
213 | !! *** ROUTINE blk_core *** |
---|
214 | !! |
---|
215 | !! ** Purpose : provide the momentum, heat and freshwater fluxes at |
---|
216 | !! the ocean surface at each time step |
---|
217 | !! |
---|
218 | !! ** Method : CORE bulk formulea for the ocean using atmospheric |
---|
219 | !! fields read in sbc_read |
---|
220 | !! |
---|
221 | !! ** Outputs : - utau : i-component of the stress at U-point (N/m2) |
---|
222 | !! - vtau : j-component of the stress at V-point (N/m2) |
---|
223 | !! - taum : Wind stress module at T-point (N/m2) |
---|
224 | !! - wndm : Wind speed module at T-point (m/s) |
---|
225 | !! - qsr : Solar heat flux over the ocean (W/m2) |
---|
226 | !! - qns : Non Solar heat flux over the ocean (W/m2) |
---|
227 | !! - emp : evaporation minus precipitation (kg/m2/s) |
---|
228 | !! |
---|
229 | !! ** Nota : sf has to be a dummy argument for AGRIF on NEC |
---|
230 | !!--------------------------------------------------------------------- |
---|
231 | INTEGER , INTENT(in ) :: kt ! time step index |
---|
232 | TYPE(fld), INTENT(inout), DIMENSION(:) :: sf ! input data |
---|
233 | REAL(wp) , INTENT(in) , DIMENSION(:,:) :: pst ! surface temperature [Celcius] |
---|
234 | REAL(wp) , INTENT(in) , DIMENSION(:,:) :: pu ! surface current at U-point (i-component) [m/s] |
---|
235 | REAL(wp) , INTENT(in) , DIMENSION(:,:) :: pv ! surface current at V-point (j-component) [m/s] |
---|
236 | ! |
---|
237 | INTEGER :: ji, jj ! dummy loop indices |
---|
238 | REAL(wp) :: zcoef_qsatw, zztmp ! local variable |
---|
239 | REAL(wp), DIMENSION(:,:), POINTER :: zwnd_i, zwnd_j ! wind speed components at T-point |
---|
240 | REAL(wp), DIMENSION(:,:), POINTER :: zqsatw ! specific humidity at pst |
---|
241 | REAL(wp), DIMENSION(:,:), POINTER :: zqlw, zqsb ! long wave and sensible heat fluxes |
---|
242 | REAL(wp), DIMENSION(:,:), POINTER :: zqla, zevap ! latent heat fluxes and evaporation |
---|
243 | REAL(wp), DIMENSION(:,:), POINTER :: Cd ! transfer coefficient for momentum (tau) |
---|
244 | REAL(wp), DIMENSION(:,:), POINTER :: Ch ! transfer coefficient for sensible heat (Q_sens) |
---|
245 | REAL(wp), DIMENSION(:,:), POINTER :: Ce ! tansfert coefficient for evaporation (Q_lat) |
---|
246 | REAL(wp), DIMENSION(:,:), POINTER :: zst ! surface temperature in Kelvin |
---|
247 | REAL(wp), DIMENSION(:,:), POINTER :: zt_zu ! air temperature at wind speed height |
---|
248 | REAL(wp), DIMENSION(:,:), POINTER :: zq_zu ! air spec. hum. at wind speed height |
---|
249 | !!--------------------------------------------------------------------- |
---|
250 | ! |
---|
251 | IF( nn_timing == 1 ) CALL timing_start('blk_oce_core') |
---|
252 | ! |
---|
253 | CALL wrk_alloc( jpi,jpj, zwnd_i, zwnd_j, zqsatw, zqlw, zqsb, zqla, zevap ) |
---|
254 | CALL wrk_alloc( jpi,jpj, Cd, Ch, Ce, zst, zt_zu, zq_zu ) |
---|
255 | ! |
---|
256 | ! local scalars ( place there for vector optimisation purposes) |
---|
257 | zcoef_qsatw = 0.98 * 640380. / rhoa |
---|
258 | |
---|
259 | zst(:,:) = pst(:,:) + rt0 ! convert SST from Celcius to Kelvin (and set minimum value far above 0 K) |
---|
260 | |
---|
261 | ! ----------------------------------------------------------------------------- ! |
---|
262 | ! 0 Wind components and module at T-point relative to the moving ocean ! |
---|
263 | ! ----------------------------------------------------------------------------- ! |
---|
264 | |
---|
265 | ! ... components ( U10m - U_oce ) at T-point (unmasked) |
---|
266 | zwnd_i(:,:) = 0.e0 |
---|
267 | zwnd_j(:,:) = 0.e0 |
---|
268 | #if defined key_cyclone |
---|
269 | CALL wnd_cyc( kt, zwnd_i, zwnd_j ) ! add analytical tropical cyclone (Vincent et al. JGR 2012) |
---|
270 | DO jj = 2, jpjm1 |
---|
271 | DO ji = fs_2, fs_jpim1 ! vect. opt. |
---|
272 | sf(jp_wndi)%fnow(ji,jj,1) = sf(jp_wndi)%fnow(ji,jj,1) + zwnd_i(ji,jj) |
---|
273 | sf(jp_wndj)%fnow(ji,jj,1) = sf(jp_wndj)%fnow(ji,jj,1) + zwnd_j(ji,jj) |
---|
274 | END DO |
---|
275 | END DO |
---|
276 | #endif |
---|
277 | DO jj = 2, jpjm1 |
---|
278 | DO ji = fs_2, fs_jpim1 ! vect. opt. |
---|
279 | zwnd_i(ji,jj) = ( sf(jp_wndi)%fnow(ji,jj,1) - rn_vfac * 0.5 * ( pu(ji-1,jj ) + pu(ji,jj) ) ) |
---|
280 | zwnd_j(ji,jj) = ( sf(jp_wndj)%fnow(ji,jj,1) - rn_vfac * 0.5 * ( pv(ji ,jj-1) + pv(ji,jj) ) ) |
---|
281 | END DO |
---|
282 | END DO |
---|
283 | CALL lbc_lnk( zwnd_i(:,:) , 'T', -1. ) |
---|
284 | CALL lbc_lnk( zwnd_j(:,:) , 'T', -1. ) |
---|
285 | ! ... scalar wind ( = | U10m - U_oce | ) at T-point (masked) |
---|
286 | wndm(:,:) = SQRT( zwnd_i(:,:) * zwnd_i(:,:) & |
---|
287 | & + zwnd_j(:,:) * zwnd_j(:,:) ) * tmask(:,:,1) |
---|
288 | |
---|
289 | ! ----------------------------------------------------------------------------- ! |
---|
290 | ! I Radiative FLUXES ! |
---|
291 | ! ----------------------------------------------------------------------------- ! |
---|
292 | |
---|
293 | ! ocean albedo assumed to be constant + modify now Qsr to include the diurnal cycle ! Short Wave |
---|
294 | zztmp = 1. - albo |
---|
295 | IF( ln_dm2dc ) THEN ; qsr(:,:) = zztmp * sbc_dcy( sf(jp_qsr)%fnow(:,:,1) ) * tmask(:,:,1) |
---|
296 | ELSE ; qsr(:,:) = zztmp * sf(jp_qsr)%fnow(:,:,1) * tmask(:,:,1) |
---|
297 | ENDIF |
---|
298 | |
---|
299 | zqlw(:,:) = ( sf(jp_qlw)%fnow(:,:,1) - Stef * zst(:,:)*zst(:,:)*zst(:,:)*zst(:,:) ) * tmask(:,:,1) ! Long Wave |
---|
300 | ! ----------------------------------------------------------------------------- ! |
---|
301 | ! II Turbulent FLUXES ! |
---|
302 | ! ----------------------------------------------------------------------------- ! |
---|
303 | |
---|
304 | ! ... specific humidity at SST and IST |
---|
305 | zqsatw(:,:) = zcoef_qsatw * EXP( -5107.4 / zst(:,:) ) |
---|
306 | |
---|
307 | ! ... NCAR Bulk formulae, computation of Cd, Ch, Ce at T-point : |
---|
308 | CALL turb_core_2z( rn_zqt, rn_zu, zst, sf(jp_tair)%fnow, zqsatw, sf(jp_humi)%fnow, wndm, & |
---|
309 | & Cd, Ch, Ce, zt_zu, zq_zu ) |
---|
310 | |
---|
311 | ! ... tau module, i and j component |
---|
312 | DO jj = 1, jpj |
---|
313 | DO ji = 1, jpi |
---|
314 | zztmp = rhoa * wndm(ji,jj) * Cd(ji,jj) |
---|
315 | taum (ji,jj) = zztmp * wndm (ji,jj) |
---|
316 | zwnd_i(ji,jj) = zztmp * zwnd_i(ji,jj) |
---|
317 | zwnd_j(ji,jj) = zztmp * zwnd_j(ji,jj) |
---|
318 | END DO |
---|
319 | END DO |
---|
320 | |
---|
321 | ! ... add the HF tau contribution to the wind stress module? |
---|
322 | IF( lhftau ) THEN |
---|
323 | taum(:,:) = taum(:,:) + sf(jp_tdif)%fnow(:,:,1) |
---|
324 | ENDIF |
---|
325 | CALL iom_put( "taum_oce", taum ) ! output wind stress module |
---|
326 | |
---|
327 | ! ... utau, vtau at U- and V_points, resp. |
---|
328 | ! Note the use of 0.5*(2-umask) in order to unmask the stress along coastlines |
---|
329 | ! Note the use of MAX(tmask(i,j),tmask(i+1,j) is to mask tau over ice shelves |
---|
330 | DO jj = 1, jpjm1 |
---|
331 | DO ji = 1, fs_jpim1 |
---|
332 | utau(ji,jj) = 0.5 * ( 2. - umask(ji,jj,1) ) * ( zwnd_i(ji,jj) + zwnd_i(ji+1,jj ) ) & |
---|
333 | & * MAX(tmask(ji,jj,1),tmask(ji+1,jj,1)) |
---|
334 | vtau(ji,jj) = 0.5 * ( 2. - vmask(ji,jj,1) ) * ( zwnd_j(ji,jj) + zwnd_j(ji ,jj+1) ) & |
---|
335 | & * MAX(tmask(ji,jj,1),tmask(ji,jj+1,1)) |
---|
336 | END DO |
---|
337 | END DO |
---|
338 | CALL lbc_lnk( utau(:,:), 'U', -1. ) |
---|
339 | CALL lbc_lnk( vtau(:,:), 'V', -1. ) |
---|
340 | |
---|
341 | |
---|
342 | ! Turbulent fluxes over ocean |
---|
343 | ! ----------------------------- |
---|
344 | IF( ABS( rn_zu - rn_zqt) < 0.01_wp ) THEN |
---|
345 | !! q_air and t_air are (or "are almost") given at 10m (wind reference height) |
---|
346 | zevap(:,:) = rn_efac*MAX( 0._wp, rhoa*Ce(:,:)*( zqsatw(:,:) - sf(jp_humi)%fnow(:,:,1) )*wndm(:,:) ) ! Evaporation |
---|
347 | zqsb (:,:) = cpa*rhoa*Ch(:,:)*( zst (:,:) - sf(jp_tair)%fnow(:,:,1) )*wndm(:,:) ! Sensible Heat |
---|
348 | ELSE |
---|
349 | !! q_air and t_air are not given at 10m (wind reference height) |
---|
350 | ! Values of temp. and hum. adjusted to height of wind during bulk algorithm iteration must be used!!! |
---|
351 | zevap(:,:) = rn_efac*MAX( 0._wp, rhoa*Ce(:,:)*( zqsatw(:,:) - zq_zu(:,:) )*wndm(:,:) ) ! Evaporation |
---|
352 | zqsb (:,:) = cpa*rhoa*Ch(:,:)*( zst (:,:) - zt_zu(:,:) )*wndm(:,:) ! Sensible Heat |
---|
353 | ENDIF |
---|
354 | zqla (:,:) = Lv * zevap(:,:) ! Latent Heat |
---|
355 | |
---|
356 | IF(ln_ctl) THEN |
---|
357 | CALL prt_ctl( tab2d_1=zqla , clinfo1=' blk_oce_core: zqla : ', tab2d_2=Ce , clinfo2=' Ce : ' ) |
---|
358 | CALL prt_ctl( tab2d_1=zqsb , clinfo1=' blk_oce_core: zqsb : ', tab2d_2=Ch , clinfo2=' Ch : ' ) |
---|
359 | CALL prt_ctl( tab2d_1=zqlw , clinfo1=' blk_oce_core: zqlw : ', tab2d_2=qsr, clinfo2=' qsr : ' ) |
---|
360 | CALL prt_ctl( tab2d_1=zqsatw, clinfo1=' blk_oce_core: zqsatw : ', tab2d_2=zst, clinfo2=' zst : ' ) |
---|
361 | CALL prt_ctl( tab2d_1=utau , clinfo1=' blk_oce_core: utau : ', mask1=umask, & |
---|
362 | & tab2d_2=vtau , clinfo2= ' vtau : ' , mask2=vmask ) |
---|
363 | CALL prt_ctl( tab2d_1=wndm , clinfo1=' blk_oce_core: wndm : ') |
---|
364 | CALL prt_ctl( tab2d_1=zst , clinfo1=' blk_oce_core: zst : ') |
---|
365 | ENDIF |
---|
366 | |
---|
367 | ! ----------------------------------------------------------------------------- ! |
---|
368 | ! III Total FLUXES ! |
---|
369 | ! ----------------------------------------------------------------------------- ! |
---|
370 | ! |
---|
371 | emp (:,:) = ( zevap(:,:) & ! mass flux (evap. - precip.) |
---|
372 | & - sf(jp_prec)%fnow(:,:,1) * rn_pfac ) * tmask(:,:,1) |
---|
373 | qns(:,:) = zqlw(:,:) - zqsb(:,:) - zqla(:,:) & ! Downward Non Solar flux |
---|
374 | & - sf(jp_snow)%fnow(:,:,1) * rn_pfac * lfus & ! remove latent melting heat for solid precip |
---|
375 | & - zevap(:,:) * pst(:,:) * rcp & ! remove evap heat content at SST |
---|
376 | & + ( sf(jp_prec)%fnow(:,:,1) - sf(jp_snow)%fnow(:,:,1) ) * rn_pfac & ! add liquid precip heat content at Tair |
---|
377 | & * ( sf(jp_tair)%fnow(:,:,1) - rt0 ) * rcp & |
---|
378 | & + sf(jp_snow)%fnow(:,:,1) * rn_pfac & ! add solid precip heat content at min(Tair,Tsnow) |
---|
379 | & * ( MIN( sf(jp_tair)%fnow(:,:,1), rt0_snow ) - rt0 ) * cpic * tmask(:,:,1) |
---|
380 | ! |
---|
381 | CALL iom_put( "qlw_oce", zqlw ) ! output downward longwave heat over the ocean |
---|
382 | CALL iom_put( "qsb_oce", - zqsb ) ! output downward sensible heat over the ocean |
---|
383 | CALL iom_put( "qla_oce", - zqla ) ! output downward latent heat over the ocean |
---|
384 | CALL iom_put( "qhc_oce", qns-zqlw+zqsb+zqla ) ! output downward heat content of E-P over the ocean |
---|
385 | CALL iom_put( "qns_oce", qns ) ! output downward non solar heat over the ocean |
---|
386 | ! |
---|
387 | IF(ln_ctl) THEN |
---|
388 | CALL prt_ctl(tab2d_1=zqsb , clinfo1=' blk_oce_core: zqsb : ', tab2d_2=zqlw , clinfo2=' zqlw : ') |
---|
389 | CALL prt_ctl(tab2d_1=zqla , clinfo1=' blk_oce_core: zqla : ', tab2d_2=qsr , clinfo2=' qsr : ') |
---|
390 | CALL prt_ctl(tab2d_1=pst , clinfo1=' blk_oce_core: pst : ', tab2d_2=emp , clinfo2=' emp : ') |
---|
391 | CALL prt_ctl(tab2d_1=utau , clinfo1=' blk_oce_core: utau : ', mask1=umask, & |
---|
392 | & tab2d_2=vtau , clinfo2= ' vtau : ' , mask2=vmask ) |
---|
393 | ENDIF |
---|
394 | ! |
---|
395 | CALL wrk_dealloc( jpi,jpj, zwnd_i, zwnd_j, zqsatw, zqlw, zqsb, zqla, zevap ) |
---|
396 | CALL wrk_dealloc( jpi,jpj, Cd, Ch, Ce, zst, zt_zu, zq_zu ) |
---|
397 | ! |
---|
398 | IF( nn_timing == 1 ) CALL timing_stop('blk_oce_core') |
---|
399 | ! |
---|
400 | END SUBROUTINE blk_oce_core |
---|
401 | |
---|
402 | |
---|
403 | SUBROUTINE blk_ice_core( pst , pui , pvi , palb , & |
---|
404 | & p_taui, p_tauj, p_qns , p_qsr, & |
---|
405 | & p_qla , p_dqns, p_dqla, & |
---|
406 | & p_tpr , p_spr , & |
---|
407 | & p_fr1 , p_fr2 , cd_grid, pdim ) |
---|
408 | !!--------------------------------------------------------------------- |
---|
409 | !! *** ROUTINE blk_ice_core *** |
---|
410 | !! |
---|
411 | !! ** Purpose : provide the surface boundary condition over sea-ice |
---|
412 | !! |
---|
413 | !! ** Method : compute momentum, heat and freshwater exchanged |
---|
414 | !! between atmosphere and sea-ice using CORE bulk |
---|
415 | !! formulea, ice variables and read atmmospheric fields. |
---|
416 | !! NB: ice drag coefficient is assumed to be a constant |
---|
417 | !! |
---|
418 | !! caution : the net upward water flux has with mm/day unit |
---|
419 | !!--------------------------------------------------------------------- |
---|
420 | REAL(wp), DIMENSION(:,:,:), INTENT(in ) :: pst ! ice surface temperature (>0, =rt0 over land) [Kelvin] |
---|
421 | REAL(wp), DIMENSION(:,:) , INTENT(in ) :: pui ! ice surface velocity (i- and i- components [m/s] |
---|
422 | REAL(wp), DIMENSION(:,:) , INTENT(in ) :: pvi ! at I-point (B-grid) or U & V-point (C-grid) |
---|
423 | REAL(wp), DIMENSION(:,:,:), INTENT(in ) :: palb ! ice albedo (all skies) [%] |
---|
424 | REAL(wp), DIMENSION(:,:) , INTENT( out) :: p_taui ! i- & j-components of surface ice stress [N/m2] |
---|
425 | REAL(wp), DIMENSION(:,:) , INTENT( out) :: p_tauj ! at I-point (B-grid) or U & V-point (C-grid) |
---|
426 | REAL(wp), DIMENSION(:,:,:), INTENT( out) :: p_qns ! non solar heat flux over ice (T-point) [W/m2] |
---|
427 | REAL(wp), DIMENSION(:,:,:), INTENT( out) :: p_qsr ! solar heat flux over ice (T-point) [W/m2] |
---|
428 | REAL(wp), DIMENSION(:,:,:), INTENT( out) :: p_qla ! latent heat flux over ice (T-point) [W/m2] |
---|
429 | REAL(wp), DIMENSION(:,:,:), INTENT( out) :: p_dqns ! non solar heat sensistivity (T-point) [W/m2] |
---|
430 | REAL(wp), DIMENSION(:,:,:), INTENT( out) :: p_dqla ! latent heat sensistivity (T-point) [W/m2] |
---|
431 | REAL(wp), DIMENSION(:,:) , INTENT( out) :: p_tpr ! total precipitation (T-point) [Kg/m2/s] |
---|
432 | REAL(wp), DIMENSION(:,:) , INTENT( out) :: p_spr ! solid precipitation (T-point) [Kg/m2/s] |
---|
433 | REAL(wp), DIMENSION(:,:) , INTENT( out) :: p_fr1 ! 1sr fraction of qsr penetration in ice (T-point) [%] |
---|
434 | REAL(wp), DIMENSION(:,:) , INTENT( out) :: p_fr2 ! 2nd fraction of qsr penetration in ice (T-point) [%] |
---|
435 | CHARACTER(len=1) , INTENT(in ) :: cd_grid ! ice grid ( C or B-grid) |
---|
436 | INTEGER , INTENT(in ) :: pdim ! number of ice categories |
---|
437 | !! |
---|
438 | INTEGER :: ji, jj, jl ! dummy loop indices |
---|
439 | INTEGER :: ijpl ! number of ice categories (size of 3rd dim of input arrays) |
---|
440 | REAL(wp) :: zst2, zst3 |
---|
441 | REAL(wp) :: zcoef_wnorm, zcoef_wnorm2, zcoef_dqlw, zcoef_dqla, zcoef_dqsb |
---|
442 | REAL(wp) :: zztmp ! temporary variable |
---|
443 | REAL(wp) :: zwnorm_f, zwndi_f , zwndj_f ! relative wind module and components at F-point |
---|
444 | REAL(wp) :: zwndi_t , zwndj_t ! relative wind components at T-point |
---|
445 | !! |
---|
446 | REAL(wp), DIMENSION(:,:) , POINTER :: z_wnds_t ! wind speed ( = | U10m - U_ice | ) at T-point |
---|
447 | REAL(wp), DIMENSION(:,:,:), POINTER :: z_qlw ! long wave heat flux over ice |
---|
448 | REAL(wp), DIMENSION(:,:,:), POINTER :: z_qsb ! sensible heat flux over ice |
---|
449 | REAL(wp), DIMENSION(:,:,:), POINTER :: z_dqlw ! long wave heat sensitivity over ice |
---|
450 | REAL(wp), DIMENSION(:,:,:), POINTER :: z_dqsb ! sensible heat sensitivity over ice |
---|
451 | !!--------------------------------------------------------------------- |
---|
452 | ! |
---|
453 | IF( nn_timing == 1 ) CALL timing_start('blk_ice_core') |
---|
454 | ! |
---|
455 | CALL wrk_alloc( jpi,jpj, z_wnds_t ) |
---|
456 | CALL wrk_alloc( jpi,jpj,pdim, z_qlw, z_qsb, z_dqlw, z_dqsb ) |
---|
457 | |
---|
458 | ijpl = pdim ! number of ice categories |
---|
459 | |
---|
460 | ! local scalars ( place there for vector optimisation purposes) |
---|
461 | zcoef_wnorm = rhoa * Cice |
---|
462 | zcoef_wnorm2 = rhoa * Cice * 0.5 |
---|
463 | zcoef_dqlw = 4.0 * 0.95 * Stef |
---|
464 | zcoef_dqla = -Ls * Cice * 11637800. * (-5897.8) |
---|
465 | zcoef_dqsb = rhoa * cpa * Cice |
---|
466 | |
---|
467 | !!gm brutal.... |
---|
468 | z_wnds_t(:,:) = 0.e0 |
---|
469 | p_taui (:,:) = 0.e0 |
---|
470 | p_tauj (:,:) = 0.e0 |
---|
471 | !!gm end |
---|
472 | |
---|
473 | #if defined key_lim3 |
---|
474 | tatm_ice(:,:) = sf(jp_tair)%fnow(:,:,1) ! LIM3: make Tair available in sea-ice. WARNING allocated after call to ice_init |
---|
475 | #endif |
---|
476 | ! ----------------------------------------------------------------------------- ! |
---|
477 | ! Wind components and module relative to the moving ocean ( U10m - U_ice ) ! |
---|
478 | ! ----------------------------------------------------------------------------- ! |
---|
479 | SELECT CASE( cd_grid ) |
---|
480 | CASE( 'I' ) ! B-grid ice dynamics : I-point (i.e. F-point with sea-ice indexation) |
---|
481 | ! and scalar wind at T-point ( = | U10m - U_ice | ) (masked) |
---|
482 | DO jj = 2, jpjm1 |
---|
483 | DO ji = 2, jpim1 ! B grid : NO vector opt |
---|
484 | ! ... scalar wind at I-point (fld being at T-point) |
---|
485 | zwndi_f = 0.25 * ( sf(jp_wndi)%fnow(ji-1,jj ,1) + sf(jp_wndi)%fnow(ji ,jj ,1) & |
---|
486 | & + sf(jp_wndi)%fnow(ji-1,jj-1,1) + sf(jp_wndi)%fnow(ji ,jj-1,1) ) - rn_vfac * pui(ji,jj) |
---|
487 | zwndj_f = 0.25 * ( sf(jp_wndj)%fnow(ji-1,jj ,1) + sf(jp_wndj)%fnow(ji ,jj ,1) & |
---|
488 | & + sf(jp_wndj)%fnow(ji-1,jj-1,1) + sf(jp_wndj)%fnow(ji ,jj-1,1) ) - rn_vfac * pvi(ji,jj) |
---|
489 | zwnorm_f = zcoef_wnorm * SQRT( zwndi_f * zwndi_f + zwndj_f * zwndj_f ) |
---|
490 | ! ... ice stress at I-point |
---|
491 | p_taui(ji,jj) = zwnorm_f * zwndi_f |
---|
492 | p_tauj(ji,jj) = zwnorm_f * zwndj_f |
---|
493 | ! ... scalar wind at T-point (fld being at T-point) |
---|
494 | zwndi_t = sf(jp_wndi)%fnow(ji,jj,1) - rn_vfac * 0.25 * ( pui(ji,jj+1) + pui(ji+1,jj+1) & |
---|
495 | & + pui(ji,jj ) + pui(ji+1,jj ) ) |
---|
496 | zwndj_t = sf(jp_wndj)%fnow(ji,jj,1) - rn_vfac * 0.25 * ( pvi(ji,jj+1) + pvi(ji+1,jj+1) & |
---|
497 | & + pvi(ji,jj ) + pvi(ji+1,jj ) ) |
---|
498 | z_wnds_t(ji,jj) = SQRT( zwndi_t * zwndi_t + zwndj_t * zwndj_t ) * tmask(ji,jj,1) |
---|
499 | END DO |
---|
500 | END DO |
---|
501 | CALL lbc_lnk( p_taui , 'I', -1. ) |
---|
502 | CALL lbc_lnk( p_tauj , 'I', -1. ) |
---|
503 | CALL lbc_lnk( z_wnds_t, 'T', 1. ) |
---|
504 | ! |
---|
505 | CASE( 'C' ) ! C-grid ice dynamics : U & V-points (same as ocean) |
---|
506 | DO jj = 2, jpj |
---|
507 | DO ji = fs_2, jpi ! vect. opt. |
---|
508 | zwndi_t = ( sf(jp_wndi)%fnow(ji,jj,1) - rn_vfac * 0.5 * ( pui(ji-1,jj ) + pui(ji,jj) ) ) |
---|
509 | zwndj_t = ( sf(jp_wndj)%fnow(ji,jj,1) - rn_vfac * 0.5 * ( pvi(ji ,jj-1) + pvi(ji,jj) ) ) |
---|
510 | z_wnds_t(ji,jj) = SQRT( zwndi_t * zwndi_t + zwndj_t * zwndj_t ) * tmask(ji,jj,1) |
---|
511 | END DO |
---|
512 | END DO |
---|
513 | DO jj = 2, jpjm1 |
---|
514 | DO ji = fs_2, fs_jpim1 ! vect. opt. |
---|
515 | p_taui(ji,jj) = zcoef_wnorm2 * ( z_wnds_t(ji+1,jj ) + z_wnds_t(ji,jj) ) & |
---|
516 | & * ( 0.5 * (sf(jp_wndi)%fnow(ji+1,jj,1) + sf(jp_wndi)%fnow(ji,jj,1) ) - rn_vfac * pui(ji,jj) ) |
---|
517 | p_tauj(ji,jj) = zcoef_wnorm2 * ( z_wnds_t(ji,jj+1 ) + z_wnds_t(ji,jj) ) & |
---|
518 | & * ( 0.5 * (sf(jp_wndj)%fnow(ji,jj+1,1) + sf(jp_wndj)%fnow(ji,jj,1) ) - rn_vfac * pvi(ji,jj) ) |
---|
519 | END DO |
---|
520 | END DO |
---|
521 | CALL lbc_lnk( p_taui , 'U', -1. ) |
---|
522 | CALL lbc_lnk( p_tauj , 'V', -1. ) |
---|
523 | CALL lbc_lnk( z_wnds_t, 'T', 1. ) |
---|
524 | ! |
---|
525 | END SELECT |
---|
526 | |
---|
527 | zztmp = 1. / ( 1. - albo ) |
---|
528 | ! ! ========================== ! |
---|
529 | DO jl = 1, ijpl ! Loop over ice categories ! |
---|
530 | ! ! ========================== ! |
---|
531 | DO jj = 1 , jpj |
---|
532 | DO ji = 1, jpi |
---|
533 | ! ----------------------------! |
---|
534 | ! I Radiative FLUXES ! |
---|
535 | ! ----------------------------! |
---|
536 | zst2 = pst(ji,jj,jl) * pst(ji,jj,jl) |
---|
537 | zst3 = pst(ji,jj,jl) * zst2 |
---|
538 | ! Short Wave (sw) |
---|
539 | p_qsr(ji,jj,jl) = zztmp * ( 1. - palb(ji,jj,jl) ) * qsr(ji,jj) |
---|
540 | ! Long Wave (lw) |
---|
541 | z_qlw(ji,jj,jl) = 0.95 * ( sf(jp_qlw)%fnow(ji,jj,1) - Stef * pst(ji,jj,jl) * zst3 ) * tmask(ji,jj,1) |
---|
542 | ! lw sensitivity |
---|
543 | z_dqlw(ji,jj,jl) = zcoef_dqlw * zst3 |
---|
544 | |
---|
545 | ! ----------------------------! |
---|
546 | ! II Turbulent FLUXES ! |
---|
547 | ! ----------------------------! |
---|
548 | |
---|
549 | ! ... turbulent heat fluxes |
---|
550 | ! Sensible Heat |
---|
551 | z_qsb(ji,jj,jl) = rhoa * cpa * Cice * z_wnds_t(ji,jj) * ( pst(ji,jj,jl) - sf(jp_tair)%fnow(ji,jj,1) ) |
---|
552 | ! Latent Heat |
---|
553 | p_qla(ji,jj,jl) = rn_efac * MAX( 0.e0, rhoa * Ls * Cice * z_wnds_t(ji,jj) & |
---|
554 | & * ( 11637800. * EXP( -5897.8 / pst(ji,jj,jl) ) / rhoa - sf(jp_humi)%fnow(ji,jj,1) ) ) |
---|
555 | ! Latent heat sensitivity for ice (Dqla/Dt) |
---|
556 | IF( p_qla(ji,jj,jl) > 0._wp ) THEN |
---|
557 | p_dqla(ji,jj,jl) = rn_efac * zcoef_dqla * z_wnds_t(ji,jj) / ( zst2 ) * EXP( -5897.8 / pst(ji,jj,jl) ) |
---|
558 | ELSE |
---|
559 | p_dqla(ji,jj,jl) = 0._wp |
---|
560 | ENDIF |
---|
561 | |
---|
562 | ! Sensible heat sensitivity (Dqsb_ice/Dtn_ice) |
---|
563 | z_dqsb(ji,jj,jl) = zcoef_dqsb * z_wnds_t(ji,jj) |
---|
564 | |
---|
565 | ! ----------------------------! |
---|
566 | ! III Total FLUXES ! |
---|
567 | ! ----------------------------! |
---|
568 | ! Downward Non Solar flux |
---|
569 | p_qns (ji,jj,jl) = z_qlw (ji,jj,jl) - z_qsb (ji,jj,jl) - p_qla (ji,jj,jl) |
---|
570 | ! Total non solar heat flux sensitivity for ice |
---|
571 | p_dqns(ji,jj,jl) = - ( z_dqlw(ji,jj,jl) + z_dqsb(ji,jj,jl) + p_dqla(ji,jj,jl) ) |
---|
572 | END DO |
---|
573 | ! |
---|
574 | END DO |
---|
575 | ! |
---|
576 | END DO |
---|
577 | ! |
---|
578 | !-------------------------------------------------------------------- |
---|
579 | ! FRACTIONs of net shortwave radiation which is not absorbed in the |
---|
580 | ! thin surface layer and penetrates inside the ice cover |
---|
581 | ! ( Maykut and Untersteiner, 1971 ; Ebert and Curry, 1993 ) |
---|
582 | ! |
---|
583 | p_fr1(:,:) = ( 0.18 * ( 1.0 - cldf_ice ) + 0.35 * cldf_ice ) |
---|
584 | p_fr2(:,:) = ( 0.82 * ( 1.0 - cldf_ice ) + 0.65 * cldf_ice ) |
---|
585 | ! |
---|
586 | p_tpr(:,:) = sf(jp_prec)%fnow(:,:,1) * rn_pfac ! total precipitation [kg/m2/s] |
---|
587 | p_spr(:,:) = sf(jp_snow)%fnow(:,:,1) * rn_pfac ! solid precipitation [kg/m2/s] |
---|
588 | CALL iom_put( 'snowpre', p_spr * 86400. ) ! Snow precipitation |
---|
589 | CALL iom_put( 'precip' , p_tpr * 86400. ) ! Total precipitation |
---|
590 | ! |
---|
591 | IF(ln_ctl) THEN |
---|
592 | CALL prt_ctl(tab3d_1=p_qla , clinfo1=' blk_ice_core: p_qla : ', tab3d_2=z_qsb , clinfo2=' z_qsb : ', kdim=ijpl) |
---|
593 | CALL prt_ctl(tab3d_1=z_qlw , clinfo1=' blk_ice_core: z_qlw : ', tab3d_2=p_dqla , clinfo2=' p_dqla : ', kdim=ijpl) |
---|
594 | CALL prt_ctl(tab3d_1=z_dqsb , clinfo1=' blk_ice_core: z_dqsb : ', tab3d_2=z_dqlw , clinfo2=' z_dqlw : ', kdim=ijpl) |
---|
595 | CALL prt_ctl(tab3d_1=p_dqns , clinfo1=' blk_ice_core: p_dqns : ', tab3d_2=p_qsr , clinfo2=' p_qsr : ', kdim=ijpl) |
---|
596 | CALL prt_ctl(tab3d_1=pst , clinfo1=' blk_ice_core: pst : ', tab3d_2=p_qns , clinfo2=' p_qns : ', kdim=ijpl) |
---|
597 | CALL prt_ctl(tab2d_1=p_tpr , clinfo1=' blk_ice_core: p_tpr : ', tab2d_2=p_spr , clinfo2=' p_spr : ') |
---|
598 | CALL prt_ctl(tab2d_1=p_taui , clinfo1=' blk_ice_core: p_taui : ', tab2d_2=p_tauj , clinfo2=' p_tauj : ') |
---|
599 | CALL prt_ctl(tab2d_1=z_wnds_t, clinfo1=' blk_ice_core: z_wnds_t : ') |
---|
600 | ENDIF |
---|
601 | |
---|
602 | CALL wrk_dealloc( jpi,jpj, z_wnds_t ) |
---|
603 | CALL wrk_dealloc( jpi,jpj, pdim, z_qlw, z_qsb, z_dqlw, z_dqsb ) |
---|
604 | ! |
---|
605 | IF( nn_timing == 1 ) CALL timing_stop('blk_ice_core') |
---|
606 | ! |
---|
607 | END SUBROUTINE blk_ice_core |
---|
608 | |
---|
609 | SUBROUTINE turb_core_2z( zt, zu, sst, T_zt, q_sat, q_zt, dU, & |
---|
610 | & Cd, Ch, Ce , T_zu, q_zu ) |
---|
611 | !!---------------------------------------------------------------------- |
---|
612 | !! *** ROUTINE turb_core *** |
---|
613 | !! |
---|
614 | !! ** Purpose : Computes turbulent transfert coefficients of surface |
---|
615 | !! fluxes according to Large & Yeager (2004) and Large & Yeager (2008) |
---|
616 | !! If relevant (zt /= zu), adjust temperature and humidity from height zt to zu |
---|
617 | !! |
---|
618 | !! ** Method : Monin Obukhov Similarity Theory |
---|
619 | !! + Large & Yeager (2004,2008) closure: CD_n10 = f(U_n10) |
---|
620 | !! |
---|
621 | !! ** References : Large & Yeager, 2004 / Large & Yeager, 2008 |
---|
622 | !! |
---|
623 | !! ** Last update: Laurent Brodeau, June 2014: |
---|
624 | !! - handles both cases zt=zu and zt/=zu |
---|
625 | !! - optimized: less 2D arrays allocated and less operations |
---|
626 | !! - better first guess of stability by checking air-sea difference of virtual temperature |
---|
627 | !! rather than temperature difference only... |
---|
628 | !! - added function "cd_neutral_10m" that uses the improved parametrization of |
---|
629 | !! Large & Yeager 2008. Drag-coefficient reduction for Cyclone conditions! |
---|
630 | !! - using code-wide physical constants defined into "phycst.mod" rather than redifining them |
---|
631 | !! => 'vkarmn' and 'grav' |
---|
632 | !!---------------------------------------------------------------------- |
---|
633 | REAL(wp), INTENT(in ) :: zt ! height for T_zt and q_zt [m] |
---|
634 | REAL(wp), INTENT(in ) :: zu ! height for dU [m] |
---|
635 | REAL(wp), INTENT(in ), DIMENSION(jpi,jpj) :: sst ! sea surface temperature [Kelvin] |
---|
636 | REAL(wp), INTENT(in ), DIMENSION(jpi,jpj) :: T_zt ! potential air temperature [Kelvin] |
---|
637 | REAL(wp), INTENT(in ), DIMENSION(jpi,jpj) :: q_sat ! sea surface specific humidity [kg/kg] |
---|
638 | REAL(wp), INTENT(in ), DIMENSION(jpi,jpj) :: q_zt ! specific air humidity [kg/kg] |
---|
639 | REAL(wp), INTENT(in ), DIMENSION(jpi,jpj) :: dU ! relative wind module at zu [m/s] |
---|
640 | REAL(wp), INTENT( out), DIMENSION(jpi,jpj) :: Cd ! transfer coefficient for momentum (tau) |
---|
641 | REAL(wp), INTENT( out), DIMENSION(jpi,jpj) :: Ch ! transfer coefficient for sensible heat (Q_sens) |
---|
642 | REAL(wp), INTENT( out), DIMENSION(jpi,jpj) :: Ce ! transfert coefficient for evaporation (Q_lat) |
---|
643 | REAL(wp), INTENT( out), DIMENSION(jpi,jpj) :: T_zu ! air temp. shifted at zu [K] |
---|
644 | REAL(wp), INTENT( out), DIMENSION(jpi,jpj) :: q_zu ! spec. hum. shifted at zu [kg/kg] |
---|
645 | ! |
---|
646 | INTEGER :: j_itt |
---|
647 | INTEGER , PARAMETER :: nb_itt = 5 ! number of itterations |
---|
648 | LOGICAL :: l_zt_equal_zu = .FALSE. ! if q and t are given at different height than U |
---|
649 | ! |
---|
650 | REAL(wp), DIMENSION(:,:), POINTER :: U_zu ! relative wind at zu [m/s] |
---|
651 | REAL(wp), DIMENSION(:,:), POINTER :: Ce_n10 ! 10m neutral latent coefficient |
---|
652 | REAL(wp), DIMENSION(:,:), POINTER :: Ch_n10 ! 10m neutral sensible coefficient |
---|
653 | REAL(wp), DIMENSION(:,:), POINTER :: sqrt_Cd_n10 ! root square of Cd_n10 |
---|
654 | REAL(wp), DIMENSION(:,:), POINTER :: sqrt_Cd ! root square of Cd |
---|
655 | REAL(wp), DIMENSION(:,:), POINTER :: zeta_u ! stability parameter at height zu |
---|
656 | REAL(wp), DIMENSION(:,:), POINTER :: zeta_t ! stability parameter at height zt |
---|
657 | REAL(wp), DIMENSION(:,:), POINTER :: zpsi_h_u, zpsi_m_u |
---|
658 | REAL(wp), DIMENSION(:,:), POINTER :: ztmp0, ztmp1, ztmp2 |
---|
659 | REAL(wp), DIMENSION(:,:), POINTER :: stab ! 1st stability test integer |
---|
660 | !!---------------------------------------------------------------------- |
---|
661 | |
---|
662 | IF( nn_timing == 1 ) CALL timing_start('turb_core_2z') |
---|
663 | |
---|
664 | CALL wrk_alloc( jpi,jpj, U_zu, Ce_n10, Ch_n10, sqrt_Cd_n10, sqrt_Cd ) |
---|
665 | CALL wrk_alloc( jpi,jpj, zeta_u, stab ) |
---|
666 | CALL wrk_alloc( jpi,jpj, zpsi_h_u, zpsi_m_u, ztmp0, ztmp1, ztmp2 ) |
---|
667 | |
---|
668 | l_zt_equal_zu = .FALSE. |
---|
669 | IF( ABS(zu - zt) < 0.01 ) l_zt_equal_zu = .TRUE. ! testing "zu == zt" is risky with double precision |
---|
670 | |
---|
671 | IF( .NOT. l_zt_equal_zu ) CALL wrk_alloc( jpi,jpj, zeta_t ) |
---|
672 | |
---|
673 | U_zu = MAX( 0.5 , dU ) ! relative wind speed at zu (normally 10m), we don't want to fall under 0.5 m/s |
---|
674 | |
---|
675 | !! First guess of stability: |
---|
676 | ztmp0 = T_zt*(1. + 0.608*q_zt) - sst*(1. + 0.608*q_sat) ! air-sea difference of virtual pot. temp. at zt |
---|
677 | stab = 0.5 + sign(0.5,ztmp0) ! stab = 1 if dTv > 0 => STABLE, 0 if unstable |
---|
678 | |
---|
679 | !! Neutral coefficients at 10m: |
---|
680 | IF( ln_cdgw ) THEN ! wave drag case |
---|
681 | cdn_wave(:,:) = cdn_wave(:,:) + rsmall * ( 1._wp - tmask(:,:,1) ) |
---|
682 | ztmp0 (:,:) = cdn_wave(:,:) |
---|
683 | ELSE |
---|
684 | ztmp0 = cd_neutral_10m( U_zu ) |
---|
685 | ENDIF |
---|
686 | sqrt_Cd_n10 = SQRT( ztmp0 ) |
---|
687 | Ce_n10 = 1.e-3*( 34.6 * sqrt_Cd_n10 ) |
---|
688 | Ch_n10 = 1.e-3*sqrt_Cd_n10*(18.*stab + 32.7*(1. - stab)) |
---|
689 | |
---|
690 | !! Initializing transf. coeff. with their first guess neutral equivalents : |
---|
691 | Cd = ztmp0 ; Ce = Ce_n10 ; Ch = Ch_n10 ; sqrt_Cd = sqrt_Cd_n10 |
---|
692 | |
---|
693 | !! Initializing values at z_u with z_t values: |
---|
694 | T_zu = T_zt ; q_zu = q_zt |
---|
695 | |
---|
696 | !! * Now starting iteration loop |
---|
697 | DO j_itt=1, nb_itt |
---|
698 | ! |
---|
699 | ztmp1 = T_zu - sst ! Updating air/sea differences |
---|
700 | ztmp2 = q_zu - q_sat |
---|
701 | |
---|
702 | ! Updating turbulent scales : (L&Y 2004 eq. (7)) |
---|
703 | ztmp1 = Ch/sqrt_Cd*ztmp1 ! theta* |
---|
704 | ztmp2 = Ce/sqrt_Cd*ztmp2 ! q* |
---|
705 | |
---|
706 | ztmp0 = T_zu*(1. + 0.608*q_zu) ! virtual potential temperature at zu |
---|
707 | |
---|
708 | ! Estimate the inverse of Monin-Obukov length (1/L) at height zu: |
---|
709 | ztmp0 = (vkarmn*grav/ztmp0*(ztmp1*(1.+0.608*q_zu) + 0.608*T_zu*ztmp2)) / (Cd*U_zu*U_zu) |
---|
710 | ! ( Cd*U_zu*U_zu is U*^2 at zu) |
---|
711 | |
---|
712 | !! Stability parameters : |
---|
713 | zeta_u = zu*ztmp0 ; zeta_u = sign( min(abs(zeta_u),10.0), zeta_u ) |
---|
714 | zpsi_h_u = psi_h( zeta_u ) |
---|
715 | zpsi_m_u = psi_m( zeta_u ) |
---|
716 | |
---|
717 | !! Shifting temperature and humidity at zu (L&Y 2004 eq. (9b-9c)) |
---|
718 | IF ( .NOT. l_zt_equal_zu ) THEN |
---|
719 | zeta_t = zt*ztmp0 ; zeta_t = sign( min(abs(zeta_t),10.0), zeta_t ) |
---|
720 | stab = LOG(zu/zt) - zpsi_h_u + psi_h(zeta_t) ! stab just used as temp array!!! |
---|
721 | T_zu = T_zt + ztmp1/vkarmn*stab ! ztmp1 is still theta* |
---|
722 | q_zu = q_zt + ztmp2/vkarmn*stab ! ztmp2 is still q* |
---|
723 | q_zu = max(0., q_zu) |
---|
724 | END IF |
---|
725 | |
---|
726 | IF( ln_cdgw ) THEN ! surface wave case |
---|
727 | sqrt_Cd = vkarmn / ( vkarmn / sqrt_Cd_n10 - zpsi_m_u ) |
---|
728 | Cd = sqrt_Cd * sqrt_Cd |
---|
729 | ELSE |
---|
730 | ! Update neutral wind speed at 10m and neutral Cd at 10m (L&Y 2004 eq. 9a)... |
---|
731 | ! In very rare low-wind conditions, the old way of estimating the |
---|
732 | ! neutral wind speed at 10m leads to a negative value that causes the code |
---|
733 | ! to crash. To prevent this a threshold of 0.25m/s is imposed. |
---|
734 | ztmp0 = MAX( 0.25 , U_zu/(1. + sqrt_Cd_n10/vkarmn*(LOG(zu/10.) - zpsi_m_u)) ) ! U_n10 |
---|
735 | ztmp0 = cd_neutral_10m(ztmp0) ! Cd_n10 |
---|
736 | sqrt_Cd_n10 = sqrt(ztmp0) |
---|
737 | |
---|
738 | Ce_n10 = 1.e-3 * (34.6 * sqrt_Cd_n10) ! L&Y 2004 eq. (6b) |
---|
739 | stab = 0.5 + sign(0.5,zeta_u) ! update stability |
---|
740 | Ch_n10 = 1.e-3*sqrt_Cd_n10*(18.*stab + 32.7*(1. - stab)) ! L&Y 2004 eq. (6c-6d) |
---|
741 | |
---|
742 | !! Update of transfer coefficients: |
---|
743 | ztmp1 = 1. + sqrt_Cd_n10/vkarmn*(LOG(zu/10.) - zpsi_m_u) ! L&Y 2004 eq. (10a) |
---|
744 | Cd = ztmp0 / ( ztmp1*ztmp1 ) |
---|
745 | sqrt_Cd = SQRT( Cd ) |
---|
746 | ENDIF |
---|
747 | ! |
---|
748 | ztmp0 = (LOG(zu/10.) - zpsi_h_u) / vkarmn / sqrt_Cd_n10 |
---|
749 | ztmp2 = sqrt_Cd / sqrt_Cd_n10 |
---|
750 | ztmp1 = 1. + Ch_n10*ztmp0 |
---|
751 | Ch = Ch_n10*ztmp2 / ztmp1 ! L&Y 2004 eq. (10b) |
---|
752 | ! |
---|
753 | ztmp1 = 1. + Ce_n10*ztmp0 |
---|
754 | Ce = Ce_n10*ztmp2 / ztmp1 ! L&Y 2004 eq. (10c) |
---|
755 | ! |
---|
756 | END DO |
---|
757 | |
---|
758 | CALL wrk_dealloc( jpi,jpj, U_zu, Ce_n10, Ch_n10, sqrt_Cd_n10, sqrt_Cd ) |
---|
759 | CALL wrk_dealloc( jpi,jpj, zeta_u, stab ) |
---|
760 | CALL wrk_dealloc( jpi,jpj, zpsi_h_u, zpsi_m_u, ztmp0, ztmp1, ztmp2 ) |
---|
761 | |
---|
762 | IF( .NOT. l_zt_equal_zu ) CALL wrk_dealloc( jpi,jpj, zeta_t ) |
---|
763 | |
---|
764 | IF( nn_timing == 1 ) CALL timing_stop('turb_core_2z') |
---|
765 | ! |
---|
766 | END SUBROUTINE turb_core_2z |
---|
767 | |
---|
768 | |
---|
769 | FUNCTION cd_neutral_10m( zw10 ) |
---|
770 | !!---------------------------------------------------------------------- |
---|
771 | !! Estimate of the neutral drag coefficient at 10m as a function |
---|
772 | !! of neutral wind speed at 10m |
---|
773 | !! |
---|
774 | !! Origin: Large & Yeager 2008 eq.(11a) and eq.(11b) |
---|
775 | !! |
---|
776 | !! Author: L. Brodeau, june 2014 |
---|
777 | !!---------------------------------------------------------------------- |
---|
778 | REAL(wp), DIMENSION(jpi,jpj), INTENT(in) :: zw10 ! scalar wind speed at 10m (m/s) |
---|
779 | REAL(wp), DIMENSION(jpi,jpj) :: cd_neutral_10m |
---|
780 | ! |
---|
781 | REAL(wp), DIMENSION(:,:), POINTER :: rgt33 |
---|
782 | !!---------------------------------------------------------------------- |
---|
783 | ! |
---|
784 | CALL wrk_alloc( jpi,jpj, rgt33 ) |
---|
785 | ! |
---|
786 | !! When wind speed > 33 m/s => Cyclone conditions => special treatment |
---|
787 | rgt33 = 0.5_wp + SIGN( 0.5_wp, (zw10 - 33._wp) ) ! If zw10 < 33. => 0, else => 1 |
---|
788 | cd_neutral_10m = 1.e-3 * ( & |
---|
789 | & (1._wp - rgt33)*( 2.7_wp/zw10 + 0.142_wp + zw10/13.09_wp - 3.14807E-10*zw10**6) & ! zw10< 33. |
---|
790 | & + rgt33 * 2.34 ) ! zw10 >= 33. |
---|
791 | ! |
---|
792 | CALL wrk_dealloc( jpi,jpj, rgt33) |
---|
793 | ! |
---|
794 | END FUNCTION cd_neutral_10m |
---|
795 | |
---|
796 | |
---|
797 | FUNCTION psi_m(pta) !! Psis, L&Y 2004 eq. (8c), (8d), (8e) |
---|
798 | !------------------------------------------------------------------------------- |
---|
799 | ! universal profile stability function for momentum |
---|
800 | !------------------------------------------------------------------------------- |
---|
801 | REAL(wp), DIMENSION(jpi,jpj), INTENT(in) :: pta |
---|
802 | ! |
---|
803 | REAL(wp), DIMENSION(jpi,jpj) :: psi_m |
---|
804 | REAL(wp), DIMENSION(:,:), POINTER :: X2, X, stabit |
---|
805 | !------------------------------------------------------------------------------- |
---|
806 | ! |
---|
807 | CALL wrk_alloc( jpi,jpj, X2, X, stabit ) |
---|
808 | ! |
---|
809 | X2 = SQRT( ABS( 1. - 16.*pta ) ) ; X2 = MAX( X2 , 1. ) ; X = SQRT( X2 ) |
---|
810 | stabit = 0.5 + SIGN( 0.5 , pta ) |
---|
811 | psi_m = -5.*pta*stabit & ! Stable |
---|
812 | & + (1. - stabit)*(2.*LOG((1. + X)*0.5) + LOG((1. + X2)*0.5) - 2.*ATAN(X) + rpi*0.5) ! Unstable |
---|
813 | ! |
---|
814 | CALL wrk_dealloc( jpi,jpj, X2, X, stabit ) |
---|
815 | ! |
---|
816 | END FUNCTION psi_m |
---|
817 | |
---|
818 | |
---|
819 | FUNCTION psi_h( pta ) !! Psis, L&Y 2004 eq. (8c), (8d), (8e) |
---|
820 | !------------------------------------------------------------------------------- |
---|
821 | ! universal profile stability function for temperature and humidity |
---|
822 | !------------------------------------------------------------------------------- |
---|
823 | REAL(wp), DIMENSION(jpi,jpj), INTENT(in) :: pta |
---|
824 | ! |
---|
825 | REAL(wp), DIMENSION(jpi,jpj) :: psi_h |
---|
826 | REAL(wp), DIMENSION(:,:), POINTER :: X2, X, stabit |
---|
827 | !------------------------------------------------------------------------------- |
---|
828 | ! |
---|
829 | CALL wrk_alloc( jpi,jpj, X2, X, stabit ) |
---|
830 | ! |
---|
831 | X2 = SQRT( ABS( 1. - 16.*pta ) ) ; X2 = MAX( X2 , 1. ) ; X = SQRT( X2 ) |
---|
832 | stabit = 0.5 + SIGN( 0.5 , pta ) |
---|
833 | psi_h = -5.*pta*stabit & ! Stable |
---|
834 | & + (1. - stabit)*(2.*LOG( (1. + X2)*0.5 )) ! Unstable |
---|
835 | ! |
---|
836 | CALL wrk_dealloc( jpi,jpj, X2, X, stabit ) |
---|
837 | ! |
---|
838 | END FUNCTION psi_h |
---|
839 | |
---|
840 | !!====================================================================== |
---|
841 | END MODULE sbcblk_core |
---|