[3] | 1 | MODULE traldf_lap |
---|
| 2 | !!============================================================================== |
---|
| 3 | !! *** MODULE traldf_lap *** |
---|
[2528] | 4 | !! Ocean tracers: horizontal component of the lateral tracer mixing trend |
---|
[3] | 5 | !!============================================================================== |
---|
[2528] | 6 | !! History : OPA ! 87-06 (P. Andrich, D. L Hostis) Original code |
---|
| 7 | !! ! 91-11 (G. Madec) |
---|
| 8 | !! ! 95-11 (G. Madec) suppress volumetric scale factors |
---|
| 9 | !! ! 96-01 (G. Madec) statement function for e3 |
---|
| 10 | !! NEMO ! 02-06 (G. Madec) F90: Free form and module |
---|
| 11 | !! 1.0 ! 04-08 (C. Talandier) New trends organization |
---|
| 12 | !! ! 05-11 (G. Madec) add zps case |
---|
| 13 | !! 3.0 ! 10-06 (C. Ethe, G. Madec) Merge TRA-TRC |
---|
| 14 | !!---------------------------------------------------------------------- |
---|
[3] | 15 | |
---|
| 16 | !!---------------------------------------------------------------------- |
---|
| 17 | !! tra_ldf_lap : update the tracer trend with the horizontal diffusion |
---|
| 18 | !! using a iso-level harmonic (laplacien) operator. |
---|
| 19 | !!---------------------------------------------------------------------- |
---|
| 20 | USE oce ! ocean dynamics and active tracers |
---|
| 21 | USE dom_oce ! ocean space and time domain |
---|
[74] | 22 | USE ldftra_oce ! ocean active tracers: lateral physics |
---|
[3] | 23 | USE in_out_manager ! I/O manager |
---|
[132] | 24 | USE diaptr ! poleward transport diagnostics |
---|
[2528] | 25 | USE trc_oce ! share passive tracers/Ocean variables |
---|
[2715] | 26 | USE lib_mpp ! MPP library |
---|
[3294] | 27 | USE timing ! Timing |
---|
[3] | 28 | |
---|
| 29 | IMPLICIT NONE |
---|
| 30 | PRIVATE |
---|
| 31 | |
---|
[2528] | 32 | PUBLIC tra_ldf_lap ! routine called by step.F90 |
---|
[3] | 33 | |
---|
| 34 | !! * Substitutions |
---|
| 35 | # include "domzgr_substitute.h90" |
---|
| 36 | # include "ldftra_substitute.h90" |
---|
| 37 | # include "vectopt_loop_substitute.h90" |
---|
| 38 | !!---------------------------------------------------------------------- |
---|
[2528] | 39 | !! NEMO/OPA 3.3 , NEMO Consortium (2010) |
---|
| 40 | !! $Id$ |
---|
| 41 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
---|
[3] | 42 | !!---------------------------------------------------------------------- |
---|
| 43 | CONTAINS |
---|
| 44 | |
---|
[5260] | 45 | SUBROUTINE tra_ldf_lap( kt, kit000, cdtype, pgu , pgv , & |
---|
| 46 | & pgui, pgvi, & |
---|
[2528] | 47 | & ptb, pta, kjpt ) |
---|
[3] | 48 | !!---------------------------------------------------------------------- |
---|
| 49 | !! *** ROUTINE tra_ldf_lap *** |
---|
| 50 | !! |
---|
| 51 | !! ** Purpose : Compute the before horizontal tracer (t & s) diffusive |
---|
| 52 | !! trend and add it to the general trend of tracer equation. |
---|
| 53 | !! |
---|
| 54 | !! ** Method : Second order diffusive operator evaluated using before |
---|
| 55 | !! fields (forward time scheme). The horizontal diffusive trends of |
---|
[2528] | 56 | !! the tracer is given by: |
---|
[3] | 57 | !! difft = 1/(e1t*e2t*e3t) { di-1[ aht e2u*e3u/e1u di(tb) ] |
---|
| 58 | !! + dj-1[ aht e1v*e3v/e2v dj(tb) ] } |
---|
[2528] | 59 | !! Add this trend to the general tracer trend pta : |
---|
| 60 | !! pta = pta + difft |
---|
[3] | 61 | !! |
---|
[2528] | 62 | !! ** Action : - Update pta arrays with the before iso-level |
---|
[3] | 63 | !! harmonic mixing trend. |
---|
[2528] | 64 | !!---------------------------------------------------------------------- |
---|
[2715] | 65 | USE oce, ONLY: ztu => ua , ztv => va ! (ua,va) used as workspace |
---|
| 66 | ! |
---|
[2528] | 67 | INTEGER , INTENT(in ) :: kt ! ocean time-step index |
---|
[3294] | 68 | INTEGER , INTENT(in ) :: kit000 ! first time step index |
---|
[2528] | 69 | CHARACTER(len=3) , INTENT(in ) :: cdtype ! =TRA or TRC (tracer indicator) |
---|
| 70 | INTEGER , INTENT(in ) :: kjpt ! number of tracers |
---|
| 71 | REAL(wp), DIMENSION(jpi,jpj ,kjpt), INTENT(in ) :: pgu, pgv ! tracer gradient at pstep levels |
---|
[5260] | 72 | REAL(wp), DIMENSION(jpi,jpj, kjpt), INTENT(in ) :: pgui, pgvi ! tracer gradient at top levels |
---|
[2528] | 73 | REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in ) :: ptb ! before and now tracer fields |
---|
| 74 | REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) :: pta ! tracer trend |
---|
[2715] | 75 | ! |
---|
[2528] | 76 | INTEGER :: ji, jj, jk, jn ! dummy loop indices |
---|
[2715] | 77 | INTEGER :: iku, ikv, ierr ! local integers |
---|
[2528] | 78 | REAL(wp) :: zabe1, zabe2, zbtr ! local scalars |
---|
[3] | 79 | !!---------------------------------------------------------------------- |
---|
[3294] | 80 | ! |
---|
[4364] | 81 | IF( nn_timing == 1 ) CALL timing_start('tra_ldf_lap') |
---|
[3294] | 82 | ! |
---|
| 83 | IF( kt == kit000 ) THEN |
---|
[3] | 84 | IF(lwp) WRITE(numout,*) |
---|
[2528] | 85 | IF(lwp) WRITE(numout,*) 'tra_ldf_lap : iso-level laplacian diffusion on ', cdtype |
---|
[3] | 86 | IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ ' |
---|
| 87 | ENDIF |
---|
[2528] | 88 | |
---|
| 89 | ! ! =========== ! |
---|
| 90 | DO jn = 1, kjpt ! tracer loop ! |
---|
| 91 | ! ! =========== ! |
---|
| 92 | DO jk = 1, jpkm1 ! slab loop |
---|
| 93 | ! |
---|
| 94 | ! 1. First derivative (gradient) |
---|
| 95 | ! ------------------- |
---|
[457] | 96 | DO jj = 1, jpjm1 |
---|
| 97 | DO ji = 1, fs_jpim1 ! vector opt. |
---|
[4292] | 98 | zabe1 = fsahtu(ji,jj,jk) * umask(ji,jj,jk) * re2u_e1u(ji,jj) * fse3u_n(ji,jj,jk) |
---|
| 99 | zabe2 = fsahtv(ji,jj,jk) * vmask(ji,jj,jk) * re1v_e2v(ji,jj) * fse3v_n(ji,jj,jk) |
---|
[2528] | 100 | ztu(ji,jj,jk) = zabe1 * ( ptb(ji+1,jj ,jk,jn) - ptb(ji,jj,jk,jn) ) |
---|
| 101 | ztv(ji,jj,jk) = zabe2 * ( ptb(ji ,jj+1,jk,jn) - ptb(ji,jj,jk,jn) ) |
---|
[457] | 102 | END DO |
---|
| 103 | END DO |
---|
[5260] | 104 | IF( ln_zps ) THEN ! set gradient at partial step level for the last ocean cell |
---|
[2528] | 105 | DO jj = 1, jpjm1 |
---|
| 106 | DO ji = 1, fs_jpim1 ! vector opt. |
---|
| 107 | ! last level |
---|
| 108 | iku = mbku(ji,jj) |
---|
| 109 | ikv = mbkv(ji,jj) |
---|
| 110 | IF( iku == jk ) THEN |
---|
[4292] | 111 | zabe1 = fsahtu(ji,jj,iku) * umask(ji,jj,iku) * re2u_e1u(ji,jj) * fse3u_n(ji,jj,iku) |
---|
[2528] | 112 | ztu(ji,jj,jk) = zabe1 * pgu(ji,jj,jn) |
---|
| 113 | ENDIF |
---|
| 114 | IF( ikv == jk ) THEN |
---|
[4292] | 115 | zabe2 = fsahtv(ji,jj,ikv) * vmask(ji,jj,ikv) * re1v_e2v(ji,jj) * fse3v_n(ji,jj,ikv) |
---|
[2528] | 116 | ztv(ji,jj,jk) = zabe2 * pgv(ji,jj,jn) |
---|
| 117 | ENDIF |
---|
| 118 | END DO |
---|
| 119 | END DO |
---|
| 120 | ENDIF |
---|
[5260] | 121 | ! (ISH) |
---|
| 122 | IF( ln_zps .AND. ln_isfcav ) THEN ! set gradient at partial step level for the first ocean cell |
---|
| 123 | ! into a cavity |
---|
| 124 | DO jj = 1, jpjm1 |
---|
| 125 | DO ji = 1, fs_jpim1 ! vector opt. |
---|
| 126 | ! ice shelf level level MAX(2,jk) => only where ice shelf |
---|
| 127 | iku = miku(ji,jj) |
---|
| 128 | ikv = mikv(ji,jj) |
---|
| 129 | IF( iku == MAX(2,jk) ) THEN |
---|
| 130 | zabe1 = fsahtu(ji,jj,iku) * umask(ji,jj,iku) * re2u_e1u(ji,jj) * fse3u_n(ji,jj,iku) |
---|
| 131 | ztu(ji,jj,jk) = zabe1 * pgui(ji,jj,jn) |
---|
| 132 | ENDIF |
---|
| 133 | IF( ikv == MAX(2,jk) ) THEN |
---|
| 134 | zabe2 = fsahtv(ji,jj,ikv) * vmask(ji,jj,ikv) * re1v_e2v(ji,jj) * fse3v_n(ji,jj,ikv) |
---|
| 135 | ztv(ji,jj,jk) = zabe2 * pgvi(ji,jj,jn) |
---|
| 136 | END IF |
---|
| 137 | END DO |
---|
| 138 | END DO |
---|
| 139 | ENDIF |
---|
[3] | 140 | |
---|
| 141 | |
---|
[2528] | 142 | ! 2. Second derivative (divergence) added to the general tracer trends |
---|
| 143 | ! --------------------------------------------------------------------- |
---|
| 144 | DO jj = 2, jpjm1 |
---|
| 145 | DO ji = fs_2, fs_jpim1 ! vector opt. |
---|
[4292] | 146 | zbtr = 1._wp / ( e12t(ji,jj) * fse3t_n(ji,jj,jk) ) |
---|
[2528] | 147 | ! horizontal diffusive trends added to the general tracer trends |
---|
| 148 | pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + zbtr * ( ztu(ji,jj,jk) - ztu(ji-1,jj,jk) & |
---|
| 149 | & + ztv(ji,jj,jk) - ztv(ji,jj-1,jk) ) |
---|
[3] | 150 | END DO |
---|
| 151 | END DO |
---|
[2528] | 152 | ! |
---|
| 153 | END DO ! End of slab |
---|
| 154 | ! |
---|
| 155 | ! "Poleward" diffusive heat or salt transports |
---|
[5260] | 156 | IF( cdtype == 'TRA' .AND. ln_diaptr ) THEN |
---|
| 157 | IF( jn == jp_tem) htr_ldf(:) = ptr_sj( ztv(:,:,:) ) |
---|
| 158 | IF( jn == jp_sal) str_ldf(:) = ptr_sj( ztv(:,:,:) ) |
---|
[457] | 159 | ENDIF |
---|
[2528] | 160 | ! ! ================== |
---|
| 161 | END DO ! end of tracer loop |
---|
| 162 | ! ! ================== |
---|
[4364] | 163 | IF( nn_timing == 1 ) CALL timing_stop('tra_ldf_lap') |
---|
[3294] | 164 | ! |
---|
[3] | 165 | END SUBROUTINE tra_ldf_lap |
---|
| 166 | |
---|
| 167 | !!============================================================================== |
---|
| 168 | END MODULE traldf_lap |
---|