source: branches/2013/dev_r3867_MERCATOR1_DYN/NEMOGCM/NEMO/OPA_SRC/SBC/updtide.F90 @ 3970

MODULE updtide
  !!=================================================================================
  !!                       ***  MODULE  updtide  ***
  !! Initialization of tidal forcing
  !! History :  9.0  !  07  (O. Le Galloudec)  Original code
  !!            3.5  !  2013-07   (J. Chanut) Compliant with time splitting changes
  !!=================================================================================
#if defined key_tide
  !! * Modules used
  USE oce             ! ocean dynamics and tracers variables
  USE dom_oce         ! ocean space and time domain
  USE in_out_manager  ! I/O units
  USE phycst
  USE sbctide
  USE dynspg_oce
  USE tideini, ONLY: ln_tide_ramp, rdttideramp

  IMPLICIT NONE
  PUBLIC

  !! * Routine accessibility
  PUBLIC upd_tide
  !!---------------------------------------------------------------------------------
  !!   OPA 9.0 , LODYC-IPSL  (2003)
  !!---------------------------------------------------------------------------------

CONTAINS

  SUBROUTINE upd_tide (kt, kit, time_offset)
    !!----------------------------------------------------------------------
    !!                 ***  ROUTINE upd_tide  ***
    !!----------------------------------------------------------------------      
    !! * Local declarations

    INTEGER, INTENT( in ) ::   kt            ! ocean time-step index
    INTEGER, INTENT( in ), OPTIONAL  :: kit  ! Barotropic timestep counter (ts option)
    INTEGER, INTENT( in ), OPTIONAL  :: time_offset ! time offset in units of timesteps
    INTEGER                          :: time_add    ! time offset in units of timesteps
    INTEGER  :: ji, jj, jk                   
    REAL (wp) :: zramp, z_arg, z_t
    !...............................................................................

    pot_astro(:,:)=0.e0
    zramp = 1.e0
    time_add = 0

    IF( PRESENT(time_offset) ) THEN
       time_add = time_offset
    ENDIF
         
    IF( PRESENT(kit) ) THEN  
       z_arg = ((kt-kt_tide) * rdt + (kit+0.5*(time_add-1)) * rdt / REAL(nn_baro,wp) )
    ELSE                              
       z_arg = ((kt-kt_tide)+time_add) * rdt
    ENDIF

    IF (ln_tide_ramp) zramp = MIN(MAX( (z_arg + (kt_tide-nit000)*rdt)/(rdttideramp*rday),0.),1.)

    DO jk=1,nb_harmo
       z_t = z_arg * omega_tide(jk)
       DO ji=1,jpi
          DO jj=1,jpj
             pot_astro(ji,jj)=pot_astro(ji,jj) + zramp * amp_pot(ji,jj,jk)*COS(z_t + phi_pot(ji,jj,jk))      
          END DO
       END DO
    END DO

  END SUBROUTINE upd_tide

#else
  !!----------------------------------------------------------------------
  !!   Dummy module :                                        NO TIDE
  !!----------------------------------------------------------------------
CONTAINS
  SUBROUTINE upd_tide( kt)          ! Empty routine
    INTEGER,INTENT (IN) :: kt
    WRITE(*,*) 'upd_tide: You should not have seen this print! error?', kt
  END SUBROUTINE upd_tide

#endif

  !!======================================================================

END MODULE updtide