New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
dynspg.F90 in branches/2013/dev_r3858_NOC_ZTC/NEMOGCM/NEMO/OPA_SRC/DYN – NEMO

source: branches/2013/dev_r3858_NOC_ZTC/NEMOGCM/NEMO/OPA_SRC/DYN/dynspg.F90 @ 4263

Last change on this file since 4263 was 4178, checked in by acc, 11 years ago

Branch 2013/dev_r3858_NOC_ZTC, #863. Merge of Mercator time-stepping changes with z-tilde structure. Not yet fully operational with key_dynspg_ts but main structural changes are all in place.
  • Property svn:keywords set to Id
File size: 13.8 KB
Line 
1MODULE dynspg
2   !!======================================================================
3   !!                       ***  MODULE  dynspg  ***
4   !! Ocean dynamics:  surface pressure gradient control
5   !!======================================================================
6   !! History :  1.0  ! 2005-12  (C. Talandier, G. Madec, V. Garnier)  Original code
7   !!            3.2  ! 2009-07  (R. Benshila)  Suppression of rigid-lid option
8   !!----------------------------------------------------------------------
9
10   !!----------------------------------------------------------------------
11   !!   dyn_spg     : update the dynamics trend with the lateral diffusion
12   !!   dyn_spg_ctl : initialization, namelist read, and parameters control
13   !!----------------------------------------------------------------------
14   USE oce            ! ocean dynamics and tracers variables
15   USE dom_oce        ! ocean space and time domain variables
16   USE phycst         ! physical constants
17   USE sbc_oce        ! surface boundary condition: ocean
18   USE sbcapr         ! surface boundary condition: atmospheric pressure
19   USE dynspg_oce     ! surface pressure gradient variables
20   USE dynspg_exp     ! surface pressure gradient     (dyn_spg_exp routine)
21   USE dynspg_ts      ! surface pressure gradient     (dyn_spg_ts  routine)
22   USE dynspg_flt     ! surface pressure gradient     (dyn_spg_flt routine)
23   USE dynadv         ! dynamics: vector invariant versus flux form
24   USE dynhpg, ONLY: ln_dynhpg_imp
25   USE sbctide
26   USE updtide
27   USE trdmod         ! ocean dynamics trends
28   USE trdmod_oce     ! ocean variables trends
29   USE prtctl         ! Print control                     (prt_ctl routine)
30   USE in_out_manager ! I/O manager
31   USE lib_mpp        ! MPP library
32   USE solver          ! solver initialization
33   USE wrk_nemo        ! Memory Allocation
34   USE timing          ! Timing
35
36
37   IMPLICIT NONE
38   PRIVATE
39
40   PUBLIC   dyn_spg        ! routine called by step module
41   PUBLIC   dyn_spg_init   ! routine called by opa module
42
43   INTEGER ::   nspg = 0   ! type of surface pressure gradient scheme defined from lk_dynspg_...
44
45   !! * Substitutions
46#  include "domzgr_substitute.h90"
47#  include "vectopt_loop_substitute.h90"
48   !!----------------------------------------------------------------------
49   !! NEMO/OPA 3.2 , LODYC-IPSL  (2009)
50   !! $Id$
51   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
52   !!----------------------------------------------------------------------
53CONTAINS
54
55   SUBROUTINE dyn_spg( kt, kindic )
56      !!----------------------------------------------------------------------
57      !!                  ***  ROUTINE dyn_spg  ***
58      !!
59      !! ** Purpose :   achieve the momentum time stepping by computing the
60      !!              last trend, the surface pressure gradient including the
61      !!              atmospheric pressure forcing (ln_apr_dyn=T), and performing
62      !!              the Leap-Frog integration.
63      !!gm              In the current version only the filtered solution provide
64      !!gm            the after velocity, in the 2 other (ua,va) are still the trends
65      !!
66      !! ** Method  :   Three schemes:
67      !!              - explicit computation      : the spg is evaluated at now
68      !!              - filtered computation      : the Roulet & madec (2000) technique is used
69      !!              - split-explicit computation: a time splitting technique is used
70      !!
71      !!              ln_apr_dyn=T : the atmospheric pressure forcing is applied
72      !!             as the gradient of the inverse barometer ssh:
73      !!                apgu = - 1/rau0 di[apr] = 0.5*grav di[ssh_ib+ssh_ibb]
74      !!                apgv = - 1/rau0 dj[apr] = 0.5*grav dj[ssh_ib+ssh_ibb]
75      !!             Note that as all external forcing a time averaging over a two rdt
76      !!             period is used to prevent the divergence of odd and even time step.
77      !!
78      !! N.B. : When key_esopa is used all the scheme are tested, regardless
79      !!        of the physical meaning of the results.
80      !!----------------------------------------------------------------------
81      !
82      INTEGER, INTENT(in   ) ::   kt       ! ocean time-step index
83      INTEGER, INTENT(  out) ::   kindic   ! solver flag
84      !
85      INTEGER  ::   ji, jj, jk                             ! dummy loop indices
86      REAL(wp) ::   z2dt, zg_2, zintp, zgrau0r             ! temporary scalar
87      REAL(wp), POINTER, DIMENSION(:,:,:) ::  ztrdu, ztrdv
88      REAL(wp), POINTER, DIMENSION(:,:)   ::  zpice
89      !!----------------------------------------------------------------------
90      !
91      IF( nn_timing == 1 )  CALL timing_start('dyn_spg')
92      !
93
94!!gm NOTA BENE : the dynspg_exp and dynspg_ts should be modified so that
95!!gm             they return the after velocity, not the trends (as in trazdf_imp...)
96!!gm             In this case, change/simplify dynnxt
97
98
99      IF( l_trddyn )   THEN                      ! temporary save of ta and sa trends
100         CALL wrk_alloc( jpi, jpj, jpk, ztrdu, ztrdv ) 
101         ztrdu(:,:,:) = ua(:,:,:)
102         ztrdv(:,:,:) = va(:,:,:)
103      ENDIF
104
105      IF(      ln_apr_dyn                                                &   ! atmos. pressure
106         .OR.  ( .NOT.lk_dynspg_ts .AND. (ln_tide_pot .AND. lk_tide) )   &   ! tide potential (no time slitting)
107         .OR.  nn_ice_embd == 2  ) THEN                                      ! embedded sea-ice
108         !
109         DO jj = 2, jpjm1
110            DO ji = fs_2, fs_jpim1   ! vector opt.
111               spgu(ji,jj) = 0._wp
112               spgv(ji,jj) = 0._wp
113            END DO
114         END DO         
115         !
116         IF( ln_apr_dyn .AND. (.NOT. lk_dynspg_ts) ) THEN                    !==  Atmospheric pressure gradient (added later in time-split case) ==!
117            zg_2 = grav * 0.5
118            DO jj = 2, jpjm1                          ! gradient of Patm using inverse barometer ssh
119               DO ji = fs_2, fs_jpim1   ! vector opt.
120                  spgu(ji,jj) = spgu(ji,jj) + zg_2 * (  ssh_ib (ji+1,jj) - ssh_ib (ji,jj)    &
121                     &                      + ssh_ibb(ji+1,jj) - ssh_ibb(ji,jj)  ) /e1u(ji,jj)
122                  spgv(ji,jj) = spgv(ji,jj) + zg_2 * (  ssh_ib (ji,jj+1) - ssh_ib (ji,jj)    &
123                     &                      + ssh_ibb(ji,jj+1) - ssh_ibb(ji,jj)  ) /e2v(ji,jj)
124               END DO
125            END DO
126         ENDIF
127         !
128         !                                    !==  tide potential forcing term  ==!
129         IF( .NOT.lk_dynspg_ts .AND. ( ln_tide_pot .AND. lk_tide )  ) THEN   ! N.B. added directly at sub-time-step in ts-case
130            !
131            CALL upd_tide( kt )                      ! update tide potential
132            !
133            DO jj = 2, jpjm1                         ! add tide potential forcing
134               DO ji = fs_2, fs_jpim1   ! vector opt.
135                  spgv(ji,jj) = spgu(ji,jj) + grav * ( pot_astro(ji+1,jj) - pot_astro(ji,jj) ) / e1u(ji,jj)
136                  spgv(ji,jj) = spgv(ji,jj) + grav * ( pot_astro(ji,jj+1) - pot_astro(ji,jj) ) / e2v(ji,jj)
137               END DO
138            END DO
139         ENDIF
140         !
141         IF( nn_ice_embd == 2 ) THEN          !== embedded sea ice: Pressure gradient due to snow-ice mass ==!
142            CALL wrk_alloc( jpi, jpj, zpice )
143            !                                           
144            zintp = REAL( MOD( kt-1, nn_fsbc ) ) / REAL( nn_fsbc )
145            zgrau0r     = - grav * r1_rau0
146            zpice(:,:) = (  zintp * snwice_mass(:,:) + ( 1.- zintp ) * snwice_mass_b(:,:)  ) * zgrau0r
147            DO jj = 2, jpjm1
148               DO ji = fs_2, fs_jpim1   ! vector opt.
149                  spgu(ji,jj) = spgu(ji,jj) + ( zpice(ji+1,jj) - zpice(ji,jj) ) / e1u(ji,jj)
150                  spgv(ji,jj) = spgv(ji,jj) + ( zpice(ji,jj+1) - zpice(ji,jj) ) / e2v(ji,jj)
151               END DO
152            END DO
153            !
154            CALL wrk_dealloc( jpi, jpj, zpice )         
155         ENDIF
156         !
157         DO jk = 1, jpkm1                     !== Add all terms to the general trend
158            DO jj = 2, jpjm1
159               DO ji = fs_2, fs_jpim1   ! vector opt.
160                  ua(ji,jj,jk) = ua(ji,jj,jk) + spgu(ji,jj)
161                  va(ji,jj,jk) = va(ji,jj,jk) + spgv(ji,jj)
162               END DO
163            END DO
164         END DO         
165      ENDIF
166
167      SELECT CASE ( nspg )                       ! compute surf. pressure gradient trend and add it to the general trend
168      !                                                     
169      CASE (  0 )   ;   CALL dyn_spg_exp( kt )              ! explicit
170      CASE (  1 )   ;   CALL dyn_spg_ts ( kt )              ! time-splitting
171      CASE (  2 )   ;   CALL dyn_spg_flt( kt, kindic )      ! filtered
172      !                                                   
173      CASE ( -1 )                                ! esopa: test all possibility with control print
174                        CALL dyn_spg_exp( kt )
175                        CALL prt_ctl( tab3d_1=ua, clinfo1=' spg0 - Ua: ', mask1=umask, &
176         &                            tab3d_2=va, clinfo2=       ' Va: ', mask2=vmask, clinfo3='dyn' )
177                        CALL dyn_spg_ts ( kt )
178                        CALL prt_ctl( tab3d_1=ua, clinfo1=' spg1 - Ua: ', mask1=umask, &
179         &                           tab3d_2=va, clinfo2=       ' Va: ', mask2=vmask, clinfo3='dyn' )
180                        CALL dyn_spg_flt( kt, kindic )
181                        CALL prt_ctl( tab3d_1=ua, clinfo1=' spg2 - Ua: ', mask1=umask, &
182         &                            tab3d_2=va, clinfo2=       ' Va: ', mask2=vmask, clinfo3='dyn' )
183      END SELECT
184      !                   
185      IF( l_trddyn )   THEN                      ! save the surface pressure gradient trends for further diagnostics
186         SELECT CASE ( nspg )
187         CASE ( 0, 1 )
188            ztrdu(:,:,:) = ua(:,:,:) - ztrdu(:,:,:)
189            ztrdv(:,:,:) = va(:,:,:) - ztrdv(:,:,:)
190         CASE( 2 )
191            z2dt = 2. * rdt
192            IF( neuler == 0 .AND. kt == nit000 ) z2dt = rdt
193            ztrdu(:,:,:) = ( ua(:,:,:) - ub(:,:,:) ) / z2dt - ztrdu(:,:,:)
194            ztrdv(:,:,:) = ( va(:,:,:) - vb(:,:,:) ) / z2dt - ztrdv(:,:,:)
195         END SELECT
196         CALL trd_mod( ztrdu, ztrdv, jpdyn_trd_spg, 'DYN', kt )
197         !
198         CALL wrk_dealloc( jpi, jpj, jpk, ztrdu, ztrdv ) 
199      ENDIF
200      !                                          ! print mean trends (used for debugging)
201      IF(ln_ctl)   CALL prt_ctl( tab3d_1=ua, clinfo1=' spg  - Ua: ', mask1=umask, &
202         &                       tab3d_2=va, clinfo2=       ' Va: ', mask2=vmask, clinfo3='dyn' )
203      !
204      IF( nn_timing == 1 )  CALL timing_stop('dyn_spg')
205      !
206   END SUBROUTINE dyn_spg
207
208
209   SUBROUTINE dyn_spg_init
210      !!---------------------------------------------------------------------
211      !!                  ***  ROUTINE dyn_spg_init  ***
212      !!               
213      !! ** Purpose :   Control the consistency between cpp options for
214      !!              surface pressure gradient schemes
215      !!----------------------------------------------------------------------
216      INTEGER ::   ioptio
217      !!----------------------------------------------------------------------
218      !
219      IF( nn_timing == 1 )  CALL timing_start('dyn_spg_init')
220      !
221      IF(lwp) THEN             ! Control print
222         WRITE(numout,*)
223         WRITE(numout,*) 'dyn_spg_init : choice of the surface pressure gradient scheme'
224         WRITE(numout,*) '~~~~~~~~~~~'
225         WRITE(numout,*) '     Explicit free surface                  lk_dynspg_exp = ', lk_dynspg_exp
226         WRITE(numout,*) '     Free surface with time splitting       lk_dynspg_ts  = ', lk_dynspg_ts
227         WRITE(numout,*) '     Filtered free surface cst volume       lk_dynspg_flt = ', lk_dynspg_flt
228      ENDIF
229
230      IF( lk_dynspg_ts ) CALL dyn_spg_ts_init( nit000 )
231      ! (do it now, to set nn_baro, used to allocate some arrays later on)
232      !                        ! allocate dyn_spg arrays
233      IF( lk_dynspg_ts ) THEN
234         IF( dynspg_oce_alloc() /= 0 )   CALL ctl_stop('STOP', 'dyn_spg_init: failed to allocate dynspg_oce arrays')
235         IF( dyn_spg_ts_alloc() /= 0 )   CALL ctl_stop('STOP', 'dyn_spg_init: failed to allocate dynspg_ts  arrays')
236      ENDIF
237
238      !                        ! Control of surface pressure gradient scheme options
239      ioptio = 0
240      IF(lk_dynspg_exp)   ioptio = ioptio + 1
241      IF(lk_dynspg_ts )   ioptio = ioptio + 1
242      IF(lk_dynspg_flt)   ioptio = ioptio + 1
243      !
244      IF( ( ioptio > 1 .AND. .NOT. lk_esopa ) .OR. ioptio == 0 )   &
245           &   CALL ctl_stop( ' Choose only one surface pressure gradient scheme with a key cpp' )
246      !
247      IF( lk_esopa     )   nspg = -1
248      IF( lk_dynspg_exp)   nspg =  0
249      IF( lk_dynspg_ts )   nspg =  1
250      IF( lk_dynspg_flt)   nspg =  2
251      !
252      IF( lk_esopa     )   nspg = -1
253      !
254      IF(lwp) THEN
255         WRITE(numout,*)
256         IF( nspg == -1 )   WRITE(numout,*) '     ESOPA test All scheme used'
257         IF( nspg ==  0 )   WRITE(numout,*) '     explicit free surface'
258         IF( nspg ==  1 )   WRITE(numout,*) '     free surface with time splitting scheme'
259         IF( nspg ==  2 )   WRITE(numout,*) '     filtered free surface'
260      ENDIF
261
262#if defined key_dynspg_flt || defined key_esopa
263      CALL solver_init( nit000 )   ! Elliptic solver initialisation
264#endif
265
266      !                        ! Control of timestep choice
267      IF( lk_dynspg_ts .OR. lk_dynspg_exp ) THEN
268         IF( nn_cla == 1 )   CALL ctl_stop( 'Crossland advection not implemented for this free surface formulation' )
269      ENDIF
270
271      !               ! Control of hydrostatic pressure choice
272      IF( lk_dynspg_ts .AND. ln_dynhpg_imp ) THEN
273         CALL ctl_stop( 'Semi-implicit hpg not compatible with time splitting' )
274      ENDIF
275      !
276      IF( nn_timing == 1 )  CALL timing_stop('dyn_spg_init')
277      !
278   END SUBROUTINE dyn_spg_init
279
280  !!======================================================================
281END MODULE dynspg
Note: See TracBrowser for help on using the repository browser.