1 | MODULE traadv_muscl |
---|
2 | !!====================================================================== |
---|
3 | !! *** MODULE traadv_muscl *** |
---|
4 | !! Ocean tracers: horizontal & vertical advective trend |
---|
5 | !!====================================================================== |
---|
6 | !! History : ! 2000-06 (A.Estublier) for passive tracers |
---|
7 | !! ! 2001-08 (E.Durand, G.Madec) adapted for T & S |
---|
8 | !! NEMO 1.0 ! 2002-06 (G. Madec) F90: Free form and module |
---|
9 | !! 3.2 ! 2010-05 (C. Ethe, G. Madec) merge TRC-TRA + switch from velocity to transport |
---|
10 | !! 3.4 ! 2012-06 (P. Oddo, M. Vichi) include the upstream where needed |
---|
11 | !!---------------------------------------------------------------------- |
---|
12 | |
---|
13 | !!---------------------------------------------------------------------- |
---|
14 | !! tra_adv_muscl : update the tracer trend with the horizontal |
---|
15 | !! and vertical advection trends using MUSCL scheme |
---|
16 | !!---------------------------------------------------------------------- |
---|
17 | USE oce ! ocean dynamics and active tracers |
---|
18 | USE dom_oce ! ocean space and time domain |
---|
19 | USE trdmod_oce ! tracers trends |
---|
20 | USE trdtra ! tracers trends |
---|
21 | USE in_out_manager ! I/O manager |
---|
22 | USE dynspg_oce ! choice/control of key cpp for surface pressure gradient |
---|
23 | USE trabbl ! tracers: bottom boundary layer |
---|
24 | USE lib_mpp ! distribued memory computing |
---|
25 | USE lbclnk ! ocean lateral boundary condition (or mpp link) |
---|
26 | USE diaptr ! poleward transport diagnostics |
---|
27 | USE trc_oce ! share passive tracers/Ocean variables |
---|
28 | USE wrk_nemo ! Memory Allocation |
---|
29 | USE timing ! Timing |
---|
30 | USE lib_fortran ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) |
---|
31 | USE eosbn2 ! equation of state |
---|
32 | USE sbcrnf ! river runoffs |
---|
33 | |
---|
34 | IMPLICIT NONE |
---|
35 | PRIVATE |
---|
36 | |
---|
37 | PUBLIC tra_adv_muscl ! routine called by step.F90 |
---|
38 | |
---|
39 | LOGICAL :: l_trd ! flag to compute trends |
---|
40 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: upsmsk !: mixed upstream/centered scheme near some straits |
---|
41 | ! ! and in closed seas (orca 2 and 4 configurations) |
---|
42 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: xind !: mixed upstream/centered index |
---|
43 | !! * Substitutions |
---|
44 | # include "domzgr_substitute.h90" |
---|
45 | # include "vectopt_loop_substitute.h90" |
---|
46 | !!---------------------------------------------------------------------- |
---|
47 | !! NEMO/OPA 3.3 , NEMO Consortium (2010) |
---|
48 | !! $Id$ |
---|
49 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
---|
50 | !!---------------------------------------------------------------------- |
---|
51 | CONTAINS |
---|
52 | |
---|
53 | SUBROUTINE tra_adv_muscl( kt, kit000, cdtype, p2dt, pun, pvn, pwn, & |
---|
54 | & ptb, pta, kjpt, ld_msc_ups ) |
---|
55 | !!---------------------------------------------------------------------- |
---|
56 | !! *** ROUTINE tra_adv_muscl *** |
---|
57 | !! |
---|
58 | !! ** Purpose : Compute the now trend due to total advection of T and |
---|
59 | !! S using a MUSCL scheme (Monotone Upstream-centered Scheme for |
---|
60 | !! Conservation Laws) and add it to the general tracer trend. |
---|
61 | !! |
---|
62 | !! ** Method : MUSCL scheme plus centered scheme at ocean boundaries |
---|
63 | !! |
---|
64 | !! ** Action : - update (ta,sa) with the now advective tracer trends |
---|
65 | !! - save trends |
---|
66 | !! |
---|
67 | !! References : Estubier, A., and M. Levy, Notes Techn. Pole de Modelisation |
---|
68 | !! IPSL, Sept. 2000 (http://www.lodyc.jussieu.fr/opa) |
---|
69 | !!---------------------------------------------------------------------- |
---|
70 | USE oce , ONLY: zwx => ua , zwy => va ! (ua,va) used as workspace |
---|
71 | ! |
---|
72 | INTEGER , INTENT(in ) :: kt ! ocean time-step index |
---|
73 | INTEGER , INTENT(in ) :: kit000 ! first time step index |
---|
74 | CHARACTER(len=3) , INTENT(in ) :: cdtype ! =TRA or TRC (tracer indicator) |
---|
75 | INTEGER , INTENT(in ) :: kjpt ! number of tracers |
---|
76 | LOGICAL , INTENT(in ) :: ld_msc_ups ! use upstream scheme within muscl |
---|
77 | REAL(wp), DIMENSION( jpk ), INTENT(in ) :: p2dt ! vertical profile of tracer time-step |
---|
78 | REAL(wp), DIMENSION(jpi,jpj,jpk ), INTENT(in ) :: pun, pvn, pwn ! 3 ocean velocity components |
---|
79 | REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in ) :: ptb ! before tracer field |
---|
80 | REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) :: pta ! tracer trend |
---|
81 | |
---|
82 | ! |
---|
83 | INTEGER :: ji, jj, jk, jn ! dummy loop indices |
---|
84 | REAL(wp) :: zu, z0u, zzwx, zw ! local scalars |
---|
85 | REAL(wp) :: zv, z0v, zzwy, z0w ! - - |
---|
86 | REAL(wp) :: ztra, zbtr, zdt, zalpha ! - - |
---|
87 | REAL(wp), POINTER, DIMENSION(:,:,:) :: zslpx, zslpy |
---|
88 | INTEGER :: ierr |
---|
89 | !!---------------------------------------------------------------------- |
---|
90 | ! |
---|
91 | IF( nn_timing == 1 ) CALL timing_start('tra_adv_muscl') |
---|
92 | ! |
---|
93 | CALL wrk_alloc( jpi, jpj, jpk, zslpx, zslpy ) |
---|
94 | ! |
---|
95 | |
---|
96 | IF( kt == kit000 ) THEN |
---|
97 | IF(lwp) WRITE(numout,*) |
---|
98 | IF(lwp) WRITE(numout,*) 'tra_adv : MUSCL advection scheme on ', cdtype |
---|
99 | IF(lwp) WRITE(numout,*) ' : mixed up-stream ', ld_msc_ups |
---|
100 | IF(lwp) WRITE(numout,*) '~~~~~~~' |
---|
101 | IF(lwp) WRITE(numout,*) |
---|
102 | ! |
---|
103 | ! |
---|
104 | IF( ld_msc_ups ) THEN |
---|
105 | IF( .NOT. ALLOCATED( upsmsk ) ) THEN |
---|
106 | ALLOCATE( upsmsk(jpi,jpj), STAT=ierr ) |
---|
107 | IF( ierr /= 0 ) CALL ctl_stop('STOP', 'tra_adv_muscl: unable to allocate upsmsk array') |
---|
108 | ENDIF |
---|
109 | upsmsk(:,:) = 0._wp ! not upstream by default |
---|
110 | ENDIF |
---|
111 | |
---|
112 | IF( .NOT. ALLOCATED( xind ) ) THEN |
---|
113 | ALLOCATE( xind(jpi,jpj,jpk), STAT=ierr ) |
---|
114 | IF( ierr /= 0 ) CALL ctl_stop('STOP', 'tra_adv_muscl: unable to allocate zind array') |
---|
115 | ENDIF |
---|
116 | ! |
---|
117 | ! |
---|
118 | l_trd = .FALSE. |
---|
119 | IF( ( cdtype == 'TRA' .AND. l_trdtra ) .OR. ( cdtype == 'TRC' .AND. l_trdtrc ) ) l_trd = .TRUE. |
---|
120 | |
---|
121 | ! |
---|
122 | ! Upstream / centered scheme indicator |
---|
123 | ! ------------------------------------ |
---|
124 | xind(:,:,:) = 1._wp ! set equal to 1 where up-stream is not needed |
---|
125 | ! |
---|
126 | IF( ld_msc_ups ) THEN |
---|
127 | DO jk = 1, jpk |
---|
128 | DO jj = 1, jpj |
---|
129 | DO ji = 1, jpi |
---|
130 | xind(ji,jj,jk) = 1 - MAX ( & |
---|
131 | rnfmsk(ji,jj) * rnfmsk_z(jk), & ! near runoff mouths (& closed sea outflows) |
---|
132 | upsmsk(ji,jj) ) * tmask(ji,jj,jk) ! some of some straits |
---|
133 | END DO |
---|
134 | END DO |
---|
135 | END DO |
---|
136 | ENDIF |
---|
137 | ! |
---|
138 | ENDIF |
---|
139 | ! ! =========== |
---|
140 | DO jn = 1, kjpt ! tracer loop |
---|
141 | ! ! =========== |
---|
142 | ! I. Horizontal advective fluxes |
---|
143 | ! ------------------------------ |
---|
144 | ! first guess of the slopes |
---|
145 | zwx(:,:,jpk) = 0.e0 ; zwy(:,:,jpk) = 0.e0 ! bottom values |
---|
146 | ! interior values |
---|
147 | DO jk = 1, jpkm1 |
---|
148 | DO jj = 1, jpjm1 |
---|
149 | DO ji = 1, fs_jpim1 ! vector opt. |
---|
150 | zwx(ji,jj,jk) = umask(ji,jj,jk) * ( ptb(ji+1,jj,jk,jn) - ptb(ji,jj,jk,jn) ) |
---|
151 | zwy(ji,jj,jk) = vmask(ji,jj,jk) * ( ptb(ji,jj+1,jk,jn) - ptb(ji,jj,jk,jn) ) |
---|
152 | END DO |
---|
153 | END DO |
---|
154 | END DO |
---|
155 | ! |
---|
156 | CALL lbc_lnk( zwx, 'U', -1. ) ! lateral boundary conditions on zwx, zwy (changed sign) |
---|
157 | CALL lbc_lnk( zwy, 'V', -1. ) |
---|
158 | ! !-- Slopes of tracer |
---|
159 | zslpx(:,:,jpk) = 0.e0 ; zslpy(:,:,jpk) = 0.e0 ! bottom values |
---|
160 | DO jk = 1, jpkm1 ! interior values |
---|
161 | DO jj = 2, jpj |
---|
162 | DO ji = fs_2, jpi ! vector opt. |
---|
163 | zslpx(ji,jj,jk) = ( zwx(ji,jj,jk) + zwx(ji-1,jj ,jk) ) & |
---|
164 | & * ( 0.25 + SIGN( 0.25, zwx(ji,jj,jk) * zwx(ji-1,jj ,jk) ) ) |
---|
165 | zslpy(ji,jj,jk) = ( zwy(ji,jj,jk) + zwy(ji ,jj-1,jk) ) & |
---|
166 | & * ( 0.25 + SIGN( 0.25, zwy(ji,jj,jk) * zwy(ji ,jj-1,jk) ) ) |
---|
167 | END DO |
---|
168 | END DO |
---|
169 | END DO |
---|
170 | ! |
---|
171 | DO jk = 1, jpkm1 ! Slopes limitation |
---|
172 | DO jj = 2, jpj |
---|
173 | DO ji = fs_2, jpi ! vector opt. |
---|
174 | zslpx(ji,jj,jk) = SIGN( 1., zslpx(ji,jj,jk) ) * MIN( ABS( zslpx(ji ,jj,jk) ), & |
---|
175 | & 2.*ABS( zwx (ji-1,jj,jk) ), & |
---|
176 | & 2.*ABS( zwx (ji ,jj,jk) ) ) |
---|
177 | zslpy(ji,jj,jk) = SIGN( 1., zslpy(ji,jj,jk) ) * MIN( ABS( zslpy(ji,jj ,jk) ), & |
---|
178 | & 2.*ABS( zwy (ji,jj-1,jk) ), & |
---|
179 | & 2.*ABS( zwy (ji,jj ,jk) ) ) |
---|
180 | END DO |
---|
181 | END DO |
---|
182 | END DO ! interior values |
---|
183 | |
---|
184 | ! !-- MUSCL horizontal advective fluxes |
---|
185 | DO jk = 1, jpkm1 ! interior values |
---|
186 | zdt = p2dt(jk) |
---|
187 | DO jj = 2, jpjm1 |
---|
188 | DO ji = fs_2, fs_jpim1 ! vector opt. |
---|
189 | ! MUSCL fluxes |
---|
190 | z0u = SIGN( 0.5, pun(ji,jj,jk) ) |
---|
191 | zalpha = 0.5 - z0u |
---|
192 | zu = z0u - 0.5 * pun(ji,jj,jk) * zdt / ( e1u(ji,jj) * e2u(ji,jj) * fse3u(ji,jj,jk) ) |
---|
193 | zzwx = ptb(ji+1,jj,jk,jn) + xind(ji,jj,jk) * (zu * zslpx(ji+1,jj,jk)) |
---|
194 | zzwy = ptb(ji ,jj,jk,jn) + xind(ji,jj,jk) * (zu * zslpx(ji ,jj,jk)) |
---|
195 | zwx(ji,jj,jk) = pun(ji,jj,jk) * ( zalpha * zzwx + (1.-zalpha) * zzwy ) |
---|
196 | ! |
---|
197 | z0v = SIGN( 0.5, pvn(ji,jj,jk) ) |
---|
198 | zalpha = 0.5 - z0v |
---|
199 | zv = z0v - 0.5 * pvn(ji,jj,jk) * zdt / ( e1v(ji,jj) * e2v(ji,jj) * fse3v(ji,jj,jk) ) |
---|
200 | zzwx = ptb(ji,jj+1,jk,jn) + xind(ji,jj,jk) * (zv * zslpy(ji,jj+1,jk)) |
---|
201 | zzwy = ptb(ji,jj ,jk,jn) + xind(ji,jj,jk) * (zv * zslpy(ji,jj ,jk)) |
---|
202 | zwy(ji,jj,jk) = pvn(ji,jj,jk) * ( zalpha * zzwx + (1.-zalpha) * zzwy ) |
---|
203 | END DO |
---|
204 | END DO |
---|
205 | END DO |
---|
206 | ! ! lateral boundary conditions on zwx, zwy (changed sign) |
---|
207 | CALL lbc_lnk( zwx, 'U', -1. ) ; CALL lbc_lnk( zwy, 'V', -1. ) |
---|
208 | ! |
---|
209 | ! Tracer flux divergence at t-point added to the general trend |
---|
210 | DO jk = 1, jpkm1 |
---|
211 | DO jj = 2, jpjm1 |
---|
212 | DO ji = fs_2, fs_jpim1 ! vector opt. |
---|
213 | zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) ) |
---|
214 | ! horizontal advective trends |
---|
215 | ztra = - zbtr * ( zwx(ji,jj,jk) - zwx(ji-1,jj ,jk ) & |
---|
216 | & + zwy(ji,jj,jk) - zwy(ji ,jj-1,jk ) ) |
---|
217 | ! add it to the general tracer trends |
---|
218 | pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + ztra |
---|
219 | END DO |
---|
220 | END DO |
---|
221 | END DO |
---|
222 | ! ! trend diagnostics (contribution of upstream fluxes) |
---|
223 | IF( l_trd ) THEN |
---|
224 | CALL trd_tra( kt, cdtype, jn, jptra_trd_xad, zwx, pun, ptb(:,:,:,jn) ) |
---|
225 | CALL trd_tra( kt, cdtype, jn, jptra_trd_yad, zwy, pvn, ptb(:,:,:,jn) ) |
---|
226 | END IF |
---|
227 | ! ! "Poleward" heat and salt transports (contribution of upstream fluxes) |
---|
228 | IF( cdtype == 'TRA' .AND. ln_diaptr .AND. ( MOD( kt, nn_fptr ) == 0 ) ) THEN |
---|
229 | IF( jn == jp_tem ) htr_adv(:) = ptr_vj( zwy(:,:,:) ) |
---|
230 | IF( jn == jp_sal ) str_adv(:) = ptr_vj( zwy(:,:,:) ) |
---|
231 | ENDIF |
---|
232 | |
---|
233 | ! II. Vertical advective fluxes |
---|
234 | ! ----------------------------- |
---|
235 | ! !-- first guess of the slopes |
---|
236 | zwx (:,:, 1 ) = 0.e0 ; zwx (:,:,jpk) = 0.e0 ! surface & bottom boundary conditions |
---|
237 | DO jk = 2, jpkm1 ! interior values |
---|
238 | zwx(:,:,jk) = tmask(:,:,jk) * ( ptb(:,:,jk-1,jn) - ptb(:,:,jk,jn) ) |
---|
239 | END DO |
---|
240 | |
---|
241 | ! !-- Slopes of tracer |
---|
242 | zslpx(:,:,1) = 0.e0 ! surface values |
---|
243 | DO jk = 2, jpkm1 ! interior value |
---|
244 | DO jj = 1, jpj |
---|
245 | DO ji = 1, jpi |
---|
246 | zslpx(ji,jj,jk) = ( zwx(ji,jj,jk) + zwx(ji,jj,jk+1) ) & |
---|
247 | & * ( 0.25 + SIGN( 0.25, zwx(ji,jj,jk) * zwx(ji,jj,jk+1) ) ) |
---|
248 | END DO |
---|
249 | END DO |
---|
250 | END DO |
---|
251 | ! !-- Slopes limitation |
---|
252 | DO jk = 2, jpkm1 ! interior values |
---|
253 | DO jj = 1, jpj |
---|
254 | DO ji = 1, jpi |
---|
255 | zslpx(ji,jj,jk) = SIGN( 1., zslpx(ji,jj,jk) ) * MIN( ABS( zslpx(ji,jj,jk ) ), & |
---|
256 | & 2.*ABS( zwx (ji,jj,jk+1) ), & |
---|
257 | & 2.*ABS( zwx (ji,jj,jk ) ) ) |
---|
258 | END DO |
---|
259 | END DO |
---|
260 | END DO |
---|
261 | ! !-- vertical advective flux |
---|
262 | ! ! surface values (bottom already set to zero) |
---|
263 | IF( lk_vvl ) THEN ; zwx(:,:, 1 ) = 0.e0 ! variable volume |
---|
264 | ELSE ; zwx(:,:, 1 ) = pwn(:,:,1) * ptb(:,:,1,jn) ! linear free surface |
---|
265 | ENDIF |
---|
266 | ! |
---|
267 | DO jk = 1, jpkm1 ! interior values |
---|
268 | zdt = p2dt(jk) |
---|
269 | DO jj = 2, jpjm1 |
---|
270 | DO ji = fs_2, fs_jpim1 ! vector opt. |
---|
271 | zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3w(ji,jj,jk+1) ) |
---|
272 | z0w = SIGN( 0.5, pwn(ji,jj,jk+1) ) |
---|
273 | zalpha = 0.5 + z0w |
---|
274 | zw = z0w - 0.5 * pwn(ji,jj,jk+1) * zdt * zbtr |
---|
275 | zzwx = ptb(ji,jj,jk+1,jn) + xind(ji,jj,jk) * (zw * zslpx(ji,jj,jk+1)) |
---|
276 | zzwy = ptb(ji,jj,jk ,jn) + xind(ji,jj,jk) * (zw * zslpx(ji,jj,jk )) |
---|
277 | zwx(ji,jj,jk+1) = pwn(ji,jj,jk+1) * ( zalpha * zzwx + (1.-zalpha) * zzwy ) |
---|
278 | END DO |
---|
279 | END DO |
---|
280 | END DO |
---|
281 | |
---|
282 | ! Compute & add the vertical advective trend |
---|
283 | DO jk = 1, jpkm1 |
---|
284 | DO jj = 2, jpjm1 |
---|
285 | DO ji = fs_2, fs_jpim1 ! vector opt. |
---|
286 | zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) ) |
---|
287 | ! vertical advective trends |
---|
288 | ztra = - zbtr * ( zwx(ji,jj,jk) - zwx(ji,jj,jk+1) ) |
---|
289 | ! add it to the general tracer trends |
---|
290 | pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + ztra |
---|
291 | END DO |
---|
292 | END DO |
---|
293 | END DO |
---|
294 | ! ! Save the vertical advective trends for diagnostic |
---|
295 | IF( l_trd ) CALL trd_tra( kt, cdtype, jn, jptra_trd_zad, zwx, pwn, ptb(:,:,:,jn) ) |
---|
296 | ! |
---|
297 | ENDDO |
---|
298 | ! |
---|
299 | CALL wrk_dealloc( jpi, jpj, jpk, zslpx, zslpy ) |
---|
300 | ! |
---|
301 | IF( nn_timing == 1 ) CALL timing_stop('tra_adv_muscl') |
---|
302 | ! |
---|
303 | END SUBROUTINE tra_adv_muscl |
---|
304 | |
---|
305 | !!====================================================================== |
---|
306 | END MODULE traadv_muscl |
---|