1 | MODULE p4zsms |
---|
2 | !!====================================================================== |
---|
3 | !! *** MODULE p4zsms *** |
---|
4 | !! TOP : PISCES Source Minus Sink manager |
---|
5 | !!====================================================================== |
---|
6 | !! History : 1.0 ! 2004-03 (O. Aumont) Original code |
---|
7 | !! 2.0 ! 2007-12 (C. Ethe, G. Madec) F90 |
---|
8 | !!---------------------------------------------------------------------- |
---|
9 | #if defined key_pisces |
---|
10 | !!---------------------------------------------------------------------- |
---|
11 | !! 'key_pisces' PISCES bio-model |
---|
12 | !!---------------------------------------------------------------------- |
---|
13 | !! p4zsms : Time loop of passive tracers sms |
---|
14 | !!---------------------------------------------------------------------- |
---|
15 | USE oce_trc ! shared variables between ocean and passive tracers |
---|
16 | USE trc ! passive tracers common variables |
---|
17 | USE trcdta |
---|
18 | USE sms_pisces ! PISCES Source Minus Sink variables |
---|
19 | USE p4zbio ! Biological model |
---|
20 | USE p4zche ! Chemical model |
---|
21 | USE p4zlys ! Calcite saturation |
---|
22 | USE p4zflx ! Gas exchange |
---|
23 | USE p4zsbc ! External source of nutrients |
---|
24 | USE p4zsed ! Sedimentation |
---|
25 | USE p4zint ! time interpolation |
---|
26 | USE iom ! I/O manager |
---|
27 | USE trdmod_oce ! Ocean trends variables |
---|
28 | USE trdmod_trc ! TOP trends variables |
---|
29 | USE sedmodel ! Sediment model |
---|
30 | USE prtctl_trc ! print control for debugging |
---|
31 | |
---|
32 | IMPLICIT NONE |
---|
33 | PRIVATE |
---|
34 | |
---|
35 | PUBLIC p4z_sms_init ! called in p4zsms.F90 |
---|
36 | PUBLIC p4z_sms ! called in p4zsms.F90 |
---|
37 | |
---|
38 | LOGICAL :: ln_check_mass = .false. !: Flag to check mass conservation |
---|
39 | |
---|
40 | INTEGER :: numno3 !: logical unit for NO3 budget |
---|
41 | INTEGER :: numalk !: logical unit for talk budget |
---|
42 | INTEGER :: numsil !: logical unit for Si budget |
---|
43 | INTEGER :: numfer !: logical unit for Fer budget |
---|
44 | |
---|
45 | !!---------------------------------------------------------------------- |
---|
46 | !! NEMO/TOP 3.3 , NEMO Consortium (2010) |
---|
47 | !! $Id: p4zsms.F90 3320 2012-03-05 16:37:52Z cetlod $ |
---|
48 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
---|
49 | !!---------------------------------------------------------------------- |
---|
50 | |
---|
51 | CONTAINS |
---|
52 | |
---|
53 | SUBROUTINE p4z_sms( kt ) |
---|
54 | !!--------------------------------------------------------------------- |
---|
55 | !! *** ROUTINE p4z_sms *** |
---|
56 | !! |
---|
57 | !! ** Purpose : Managment of the call to Biological sources and sinks |
---|
58 | !! routines of PISCES bio-model |
---|
59 | !! |
---|
60 | !! ** Method : - at each new day ... |
---|
61 | !! - several calls of bio and sed ??? |
---|
62 | !! - ... |
---|
63 | !!--------------------------------------------------------------------- |
---|
64 | ! |
---|
65 | INTEGER, INTENT( in ) :: kt ! ocean time-step index |
---|
66 | !! |
---|
67 | INTEGER :: jnt, jn, jl |
---|
68 | CHARACTER (len=25) :: charout |
---|
69 | REAL(wp), POINTER, DIMENSION(:,:,:,:) :: ztrdpis |
---|
70 | !!--------------------------------------------------------------------- |
---|
71 | ! |
---|
72 | IF( nn_timing == 1 ) CALL timing_start('p4z_sms') |
---|
73 | ! |
---|
74 | IF( l_trdtrc ) THEN |
---|
75 | CALL wrk_alloc( jpi, jpj, jpk, jp_pisces, ztrdpis ) |
---|
76 | DO jn = 1, jp_pisces |
---|
77 | jl = jn + jp_pcs0 - 1 |
---|
78 | ztrdpis(:,:,:,jn) = trn(:,:,:,jl) |
---|
79 | ENDDO |
---|
80 | ENDIF |
---|
81 | ! |
---|
82 | IF( ln_rsttr .AND. kt == nittrc000 ) CALL p4z_rst( nittrc000, 'READ' ) !* read or initialize all required fields |
---|
83 | IF( ln_rsttr .AND. ln_pisclo ) CALL p4z_clo ! damping on closed seas |
---|
84 | IF( ln_pisdmp .AND. MOD( kt - nn_dttrc, nn_pisdmp ) == 0 ) CALL p4z_dmp( kt ) ! Relaxation of some tracers |
---|
85 | CALL p4z_chk_mass( kt ) ! Mass conservation checking |
---|
86 | IF( ndayflxtr /= nday_year ) THEN ! New days |
---|
87 | ! |
---|
88 | ndayflxtr = nday_year |
---|
89 | |
---|
90 | IF(lwp) write(numout,*) |
---|
91 | IF(lwp) write(numout,*) ' New chemical constants and various rates for biogeochemistry at new day : ', nday_year |
---|
92 | IF(lwp) write(numout,*) '~~~~~~' |
---|
93 | |
---|
94 | CALL p4z_che ! computation of chemical constants |
---|
95 | CALL p4z_int( kt ) ! computation of various rates for biogeochemistry |
---|
96 | ! |
---|
97 | ENDIF |
---|
98 | |
---|
99 | IF( ll_sbc ) CALL p4z_sbc( kt ) ! external sources of nutrients |
---|
100 | |
---|
101 | DO jnt = 1, nrdttrc ! Potential time splitting if requested |
---|
102 | ! |
---|
103 | CALL p4z_bio (kt, jnt) ! Biology |
---|
104 | CALL p4z_sed (kt, jnt) ! Sedimentation |
---|
105 | ! |
---|
106 | DO jn = jp_pcs0, jp_pcs1 |
---|
107 | trb(:,:,:,jn) = trn(:,:,:,jn) |
---|
108 | ENDDO |
---|
109 | ! |
---|
110 | END DO |
---|
111 | |
---|
112 | IF( l_trdtrc ) THEN |
---|
113 | DO jn = 1, jp_pisces |
---|
114 | jl = jn + jp_pcs0 - 1 |
---|
115 | ztrdpis(:,:,:,jn) = ( ztrdpis(:,:,:,jn) - trn(:,:,:,jl) ) * rfact2r |
---|
116 | ENDDO |
---|
117 | ENDIF |
---|
118 | |
---|
119 | CALL p4z_lys( kt ) ! Compute CaCO3 saturation |
---|
120 | CALL p4z_flx( kt ) ! Compute surface fluxes |
---|
121 | |
---|
122 | DO jn = jp_pcs0, jp_pcs1 |
---|
123 | CALL lbc_lnk( trn(:,:,:,jn), 'T', 1. ) |
---|
124 | CALL lbc_lnk( trb(:,:,:,jn), 'T', 1. ) |
---|
125 | CALL lbc_lnk( tra(:,:,:,jn), 'T', 1. ) |
---|
126 | END DO |
---|
127 | ! |
---|
128 | IF( lk_sed ) THEN |
---|
129 | ! |
---|
130 | CALL sed_model( kt ) ! Main program of Sediment model |
---|
131 | ! |
---|
132 | DO jn = jp_pcs0, jp_pcs1 |
---|
133 | CALL lbc_lnk( trn(:,:,:,jn), 'T', 1. ) |
---|
134 | END DO |
---|
135 | ! |
---|
136 | ENDIF |
---|
137 | ! |
---|
138 | IF( lrst_trc ) CALL p4z_rst( kt, 'WRITE' ) !* Write PISCES informations in restart file |
---|
139 | ! |
---|
140 | IF( l_trdtrc ) THEN |
---|
141 | DO jn = 1, jp_pisces |
---|
142 | jl = jn + jp_pcs0 - 1 |
---|
143 | ztrdpis(:,:,:,jn) = ztrdpis(:,:,:,jn) + tra(:,:,:,jl) |
---|
144 | CALL trd_mod_trc( ztrdpis(:,:,:,jn), jn, jptra_trd_sms, kt ) ! save trends |
---|
145 | END DO |
---|
146 | CALL wrk_dealloc( jpi, jpj, jpk, jp_pisces, ztrdpis ) |
---|
147 | END IF |
---|
148 | ! |
---|
149 | IF( nn_timing == 1 ) CALL timing_stop('p4z_sms') |
---|
150 | ! |
---|
151 | END SUBROUTINE p4z_sms |
---|
152 | |
---|
153 | SUBROUTINE p4z_sms_init |
---|
154 | !!---------------------------------------------------------------------- |
---|
155 | !! *** p4z_sms_init *** |
---|
156 | !! |
---|
157 | !! ** Purpose : read PISCES namelist |
---|
158 | !! |
---|
159 | !! ** input : file 'namelist.trc.s' containing the following |
---|
160 | !! namelist: natext, natbio, natsms |
---|
161 | !! natkriest ("key_kriest") |
---|
162 | !!---------------------------------------------------------------------- |
---|
163 | NAMELIST/nampisbio/ nrdttrc, wsbio, xkmort, ferat3, wsbio2, niter1max, niter2max |
---|
164 | #if defined key_kriest |
---|
165 | NAMELIST/nampiskrp/ xkr_eta, xkr_zeta, xkr_ncontent, xkr_mass_min, xkr_mass_max |
---|
166 | #endif |
---|
167 | NAMELIST/nampisdmp/ ln_pisdmp, nn_pisdmp, ln_pisclo |
---|
168 | |
---|
169 | REWIND( numnatp ) |
---|
170 | READ ( numnatp, nampisbio ) |
---|
171 | |
---|
172 | IF(lwp) THEN ! control print |
---|
173 | WRITE(numout,*) ' Namelist : nampisbio' |
---|
174 | WRITE(numout,*) ' frequence pour la biologie nrdttrc =', nrdttrc |
---|
175 | WRITE(numout,*) ' POC sinking speed wsbio =', wsbio |
---|
176 | WRITE(numout,*) ' half saturation constant for mortality xkmort =', xkmort |
---|
177 | WRITE(numout,*) ' Fe/C in zooplankton ferat3 =', ferat3 |
---|
178 | WRITE(numout,*) ' Big particles sinking speed wsbio2 =', wsbio2 |
---|
179 | WRITE(numout,*) ' Maximum number of iterations for POC niter1max =', niter1max |
---|
180 | WRITE(numout,*) ' Maximum number of iterations for GOC niter2max =', niter2max |
---|
181 | ENDIF |
---|
182 | |
---|
183 | #if defined key_kriest |
---|
184 | |
---|
185 | ! ! nampiskrp : kriest parameters |
---|
186 | ! ! ----------------------------- |
---|
187 | xkr_eta = 0.62 |
---|
188 | xkr_zeta = 1.62 |
---|
189 | xkr_ncontent = 5.7E-6 |
---|
190 | xkr_mass_min = 0.0002 |
---|
191 | xkr_mass_max = 1. |
---|
192 | |
---|
193 | REWIND( numnatp ) ! read natkriest |
---|
194 | READ ( numnatp, nampiskrp ) |
---|
195 | |
---|
196 | IF(lwp) THEN |
---|
197 | WRITE(numout,*) |
---|
198 | WRITE(numout,*) ' Namelist : nampiskrp' |
---|
199 | WRITE(numout,*) ' Sinking exponent xkr_eta = ', xkr_eta |
---|
200 | WRITE(numout,*) ' N content exponent xkr_zeta = ', xkr_zeta |
---|
201 | WRITE(numout,*) ' N content factor xkr_ncontent = ', xkr_ncontent |
---|
202 | WRITE(numout,*) ' Minimum mass for Aggregates xkr_mass_min = ', xkr_mass_min |
---|
203 | WRITE(numout,*) ' Maximum mass for Aggregates xkr_mass_max = ', xkr_mass_max |
---|
204 | WRITE(numout,*) |
---|
205 | ENDIF |
---|
206 | |
---|
207 | |
---|
208 | ! Computation of some variables |
---|
209 | xkr_massp = xkr_ncontent * 7.625 * xkr_mass_min**xkr_zeta |
---|
210 | |
---|
211 | #endif |
---|
212 | |
---|
213 | REWIND( numnatp ) |
---|
214 | READ ( numnatp, nampisdmp ) |
---|
215 | |
---|
216 | IF(lwp) THEN ! control print |
---|
217 | WRITE(numout,*) |
---|
218 | WRITE(numout,*) ' Namelist : nampisdmp' |
---|
219 | WRITE(numout,*) ' Relaxation of tracer to glodap mean value ln_pisdmp =', ln_pisdmp |
---|
220 | WRITE(numout,*) ' Frequency of Relaxation nn_pisdmp =', nn_pisdmp |
---|
221 | WRITE(numout,*) ' Restoring of tracer to initial value on closed seas ln_pisclo =', ln_pisclo |
---|
222 | WRITE(numout,*) ' ' |
---|
223 | ENDIF |
---|
224 | |
---|
225 | END SUBROUTINE p4z_sms_init |
---|
226 | |
---|
227 | SUBROUTINE p4z_rst( kt, cdrw ) |
---|
228 | !!--------------------------------------------------------------------- |
---|
229 | !! *** ROUTINE p4z_rst *** |
---|
230 | !! |
---|
231 | !! ** Purpose : Read or write variables in restart file: |
---|
232 | !! |
---|
233 | !! WRITE(READ) mode: |
---|
234 | !! kt : number of time step since the begining of the experiment at the |
---|
235 | !! end of the current(previous) run |
---|
236 | !!--------------------------------------------------------------------- |
---|
237 | INTEGER , INTENT(in) :: kt ! ocean time-step |
---|
238 | CHARACTER(len=*), INTENT(in) :: cdrw ! "READ"/"WRITE" flag |
---|
239 | ! |
---|
240 | INTEGER :: ji, jj, jk |
---|
241 | REAL(wp) :: zcaralk, zbicarb, zco3 |
---|
242 | REAL(wp) :: ztmas, ztmas1 |
---|
243 | !!--------------------------------------------------------------------- |
---|
244 | |
---|
245 | IF( TRIM(cdrw) == 'READ' ) THEN |
---|
246 | ! |
---|
247 | IF(lwp) WRITE(numout,*) |
---|
248 | IF(lwp) WRITE(numout,*) ' p4z_rst : Read specific variables from pisces model ' |
---|
249 | IF(lwp) WRITE(numout,*) ' ~~~~~~~~~~~~~~' |
---|
250 | ! |
---|
251 | IF( iom_varid( numrtr, 'PH', ldstop = .FALSE. ) > 0 ) THEN |
---|
252 | CALL iom_get( numrtr, jpdom_autoglo, 'PH' , hi(:,:,:) ) |
---|
253 | ELSE |
---|
254 | ! hi(:,:,:) = 1.e-9 |
---|
255 | ! Set PH from total alkalinity, borat (???), akb3 (???) and ak23 (???) |
---|
256 | ! -------------------------------------------------------- |
---|
257 | DO jk = 1, jpk |
---|
258 | DO jj = 1, jpj |
---|
259 | DO ji = 1, jpi |
---|
260 | ztmas = tmask(ji,jj,jk) |
---|
261 | ztmas1 = 1. - tmask(ji,jj,jk) |
---|
262 | zcaralk = trn(ji,jj,jk,jptal) - borat(ji,jj,jk) / ( 1. + 1.E-8 / ( rtrn + akb3(ji,jj,jk) ) ) |
---|
263 | zco3 = ( zcaralk - trn(ji,jj,jk,jpdic) ) * ztmas + 0.5e-3 * ztmas1 |
---|
264 | zbicarb = ( 2. * trn(ji,jj,jk,jpdic) - zcaralk ) |
---|
265 | hi(ji,jj,jk) = ( ak23(ji,jj,jk) * zbicarb / zco3 ) * ztmas + 1.e-9 * ztmas1 |
---|
266 | END DO |
---|
267 | END DO |
---|
268 | END DO |
---|
269 | ENDIF |
---|
270 | CALL iom_get( numrtr, jpdom_autoglo, 'Silicalim', xksi(:,:) ) |
---|
271 | IF( iom_varid( numrtr, 'Silicamax', ldstop = .FALSE. ) > 0 ) THEN |
---|
272 | CALL iom_get( numrtr, jpdom_autoglo, 'Silicamax' , xksimax(:,:) ) |
---|
273 | ELSE |
---|
274 | xksimax(:,:) = xksi(:,:) |
---|
275 | ENDIF |
---|
276 | ! |
---|
277 | ELSEIF( TRIM(cdrw) == 'WRITE' ) THEN |
---|
278 | IF( kt == nitrst ) THEN |
---|
279 | IF(lwp) WRITE(numout,*) |
---|
280 | IF(lwp) WRITE(numout,*) 'p4z_rst : write pisces restart file kt =', kt |
---|
281 | IF(lwp) WRITE(numout,*) '~~~~~~~' |
---|
282 | ENDIF |
---|
283 | CALL iom_rstput( kt, nitrst, numrtw, 'PH', hi(:,:,:) ) |
---|
284 | CALL iom_rstput( kt, nitrst, numrtw, 'Silicalim', xksi(:,:) ) |
---|
285 | CALL iom_rstput( kt, nitrst, numrtw, 'Silicamax', xksimax(:,:) ) |
---|
286 | ENDIF |
---|
287 | ! |
---|
288 | END SUBROUTINE p4z_rst |
---|
289 | |
---|
290 | SUBROUTINE p4z_dmp( kt ) |
---|
291 | !!---------------------------------------------------------------------- |
---|
292 | !! *** p4z_dmp *** |
---|
293 | !! |
---|
294 | !! ** purpose : Relaxation of some tracers |
---|
295 | !!---------------------------------------------------------------------- |
---|
296 | ! |
---|
297 | INTEGER, INTENT( in ) :: kt ! time step |
---|
298 | ! |
---|
299 | REAL(wp) :: alkmean = 2426. ! mean value of alkalinity ( Glodap ; for Goyet 2391. ) |
---|
300 | REAL(wp) :: po4mean = 2.165 ! mean value of phosphates |
---|
301 | REAL(wp) :: no3mean = 30.90 ! mean value of nitrate |
---|
302 | REAL(wp) :: silmean = 91.51 ! mean value of silicate |
---|
303 | ! |
---|
304 | REAL(wp) :: zarea, zalksum, zpo4sum, zno3sum, zsilsum |
---|
305 | !!--------------------------------------------------------------------- |
---|
306 | |
---|
307 | |
---|
308 | IF(lwp) WRITE(numout,*) |
---|
309 | IF(lwp) WRITE(numout,*) ' p4z_dmp : Relaxation of nutrients at time-step kt = ', kt |
---|
310 | IF(lwp) WRITE(numout,*) |
---|
311 | |
---|
312 | IF( cp_cfg == "orca" .AND. .NOT. lk_c1d ) THEN ! ORCA condiguration (not 1D) ! |
---|
313 | ! ! --------------------------- ! |
---|
314 | ! set total alkalinity, phosphate, nitrate & silicate |
---|
315 | zarea = 1._wp / glob_sum( cvol(:,:,:) ) * 1e6 |
---|
316 | |
---|
317 | zalksum = glob_sum( trn(:,:,:,jptal) * cvol(:,:,:) ) * zarea |
---|
318 | zpo4sum = glob_sum( trn(:,:,:,jppo4) * cvol(:,:,:) ) * zarea * po4r |
---|
319 | zno3sum = glob_sum( trn(:,:,:,jpno3) * cvol(:,:,:) ) * zarea * rno3 |
---|
320 | zsilsum = glob_sum( trn(:,:,:,jpsil) * cvol(:,:,:) ) * zarea |
---|
321 | |
---|
322 | IF(lwp) WRITE(numout,*) ' TALK mean : ', zalksum |
---|
323 | trn(:,:,:,jptal) = trn(:,:,:,jptal) * alkmean / zalksum |
---|
324 | |
---|
325 | IF(lwp) WRITE(numout,*) ' PO4 mean : ', zpo4sum |
---|
326 | trn(:,:,:,jppo4) = trn(:,:,:,jppo4) * po4mean / zpo4sum |
---|
327 | |
---|
328 | IF(lwp) WRITE(numout,*) ' NO3 mean : ', zno3sum |
---|
329 | trn(:,:,:,jpno3) = trn(:,:,:,jpno3) * no3mean / zno3sum |
---|
330 | |
---|
331 | IF(lwp) WRITE(numout,*) ' SiO3 mean : ', zsilsum |
---|
332 | trn(:,:,:,jpsil) = MIN( 400.e-6,trn(:,:,:,jpsil) * silmean / zsilsum ) |
---|
333 | ! |
---|
334 | ENDIF |
---|
335 | |
---|
336 | END SUBROUTINE p4z_dmp |
---|
337 | |
---|
338 | |
---|
339 | SUBROUTINE p4z_chk_mass( kt ) |
---|
340 | !!---------------------------------------------------------------------- |
---|
341 | !! *** ROUTINE p4z_chk_mass *** |
---|
342 | !! |
---|
343 | !! ** Purpose : Mass conservation check |
---|
344 | !! |
---|
345 | !!--------------------------------------------------------------------- |
---|
346 | ! |
---|
347 | INTEGER, INTENT( in ) :: kt ! ocean time-step index |
---|
348 | !! |
---|
349 | REAL(wp) :: zalkbudget, zno3budget, zsilbudget, zferbudget |
---|
350 | ! |
---|
351 | NAMELIST/nampismass/ ln_check_mass |
---|
352 | !!--------------------------------------------------------------------- |
---|
353 | |
---|
354 | IF( kt == nittrc000 ) THEN |
---|
355 | REWIND( numnatp ) |
---|
356 | READ ( numnatp, nampismass ) |
---|
357 | IF(lwp) THEN ! control print |
---|
358 | WRITE(numout,*) ' ' |
---|
359 | WRITE(numout,*) ' Namelist parameter for mass conservation checking' |
---|
360 | WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~' |
---|
361 | WRITE(numout,*) ' Flag to check mass conservation of NO3/Si/TALK ln_check_mass = ', ln_check_mass |
---|
362 | ENDIF |
---|
363 | |
---|
364 | IF( ln_check_mass .AND. lwp) THEN ! Open budget file of NO3, ALK, Si, Fer |
---|
365 | CALL ctl_opn( numno3, 'no3.budget' , 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE., narea ) |
---|
366 | CALL ctl_opn( numsil, 'sil.budget' , 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE., narea ) |
---|
367 | CALL ctl_opn( numalk, 'talk.budget', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE., narea ) |
---|
368 | CALL ctl_opn( numfer, 'iron.budget', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE., narea ) |
---|
369 | ENDIF |
---|
370 | ENDIF |
---|
371 | |
---|
372 | IF( ln_check_mass ) THEN ! Compute the budget of NO3, ALK, Si, Fer |
---|
373 | zno3budget = glob_sum( ( trn(:,:,:,jpno3) + trn(:,:,:,jpnh4) & |
---|
374 | & + trn(:,:,:,jpphy) + trn(:,:,:,jpdia) & |
---|
375 | & + trn(:,:,:,jpzoo) + trn(:,:,:,jpmes) & |
---|
376 | & + trn(:,:,:,jppoc) + trn(:,:,:,jpgoc) & |
---|
377 | & + trn(:,:,:,jpdoc) ) * cvol(:,:,:) ) |
---|
378 | ! |
---|
379 | zsilbudget = glob_sum( ( trn(:,:,:,jpsil) + trn(:,:,:,jpgsi) & |
---|
380 | & + trn(:,:,:,jpdsi) ) * cvol(:,:,:) ) |
---|
381 | ! |
---|
382 | zalkbudget = glob_sum( ( trn(:,:,:,jpno3) * rno3 & |
---|
383 | & + trn(:,:,:,jptal) & |
---|
384 | & + trn(:,:,:,jpcal) * 2. ) * cvol(:,:,:) ) |
---|
385 | ! |
---|
386 | zferbudget = glob_sum( ( trn(:,:,:,jpfer) + trn(:,:,:,jpnfe) & |
---|
387 | & + trn(:,:,:,jpdfe) + trn(:,:,:,jpbfe) & |
---|
388 | & + trn(:,:,:,jpsfe) + & |
---|
389 | & + trn(:,:,:,jpzoo) & |
---|
390 | & + trn(:,:,:,jpmes) * ferat3 ) * cvol(:,:,:) ) |
---|
391 | |
---|
392 | IF( lwp ) THEN |
---|
393 | WRITE(numno3,9500) kt, zno3budget / areatot |
---|
394 | WRITE(numsil,9500) kt, zsilbudget / areatot |
---|
395 | WRITE(numalk,9500) kt, zalkbudget / areatot |
---|
396 | WRITE(numfer,9500) kt, zferbudget / areatot |
---|
397 | ENDIF |
---|
398 | ENDIF |
---|
399 | 9500 FORMAT(i10,e18.10) |
---|
400 | ! |
---|
401 | END SUBROUTINE p4z_chk_mass |
---|
402 | |
---|
403 | SUBROUTINE p4z_clo |
---|
404 | !!--------------------------------------------------------------------- |
---|
405 | !! *** ROUTINE p4z_clo *** |
---|
406 | !! |
---|
407 | !! ** Purpose : Closed sea domain initialization |
---|
408 | !! |
---|
409 | !! ** Method : if a closed sea is located only in a model grid point |
---|
410 | !! we restore to initial data |
---|
411 | !! |
---|
412 | !! ** Action : ictsi1(), ictsj1() : south-west closed sea limits (i,j) |
---|
413 | !! ictsi2(), ictsj2() : north-east Closed sea limits (i,j) |
---|
414 | !!---------------------------------------------------------------------- |
---|
415 | INTEGER, PARAMETER :: npicts = 4 ! number of closed sea |
---|
416 | INTEGER, DIMENSION(npicts) :: ictsi1, ictsj1 ! south-west closed sea limits (i,j) |
---|
417 | INTEGER, DIMENSION(npicts) :: ictsi2, ictsj2 ! north-east closed sea limits (i,j) |
---|
418 | INTEGER :: ji, jj, jk, jn, jl, jc ! dummy loop indices |
---|
419 | INTEGER :: ierr ! local integer |
---|
420 | REAL(wp), POINTER, DIMENSION(:,:,:,:) :: ztrcdta ! 4D workspace |
---|
421 | !!---------------------------------------------------------------------- |
---|
422 | |
---|
423 | IF(lwp) WRITE(numout,*) |
---|
424 | IF(lwp) WRITE(numout,*)' p4z_clo : closed seas ' |
---|
425 | IF(lwp) WRITE(numout,*)'~~~~~~~' |
---|
426 | |
---|
427 | ! initial values |
---|
428 | ictsi1(:) = 1 ; ictsi2(:) = 1 |
---|
429 | ictsj1(:) = 1 ; ictsj2(:) = 1 |
---|
430 | |
---|
431 | ! set the closed seas (in data domain indices) |
---|
432 | ! ------------------- |
---|
433 | |
---|
434 | IF( cp_cfg == "orca" ) THEN |
---|
435 | ! |
---|
436 | SELECT CASE ( jp_cfg ) |
---|
437 | ! ! ======================= |
---|
438 | CASE ( 2 ) ! ORCA_R2 configuration |
---|
439 | ! ! ======================= |
---|
440 | ! ! Caspian Sea |
---|
441 | ictsi1(1) = 11 ; ictsj1(1) = 103 |
---|
442 | ictsi2(1) = 17 ; ictsj2(1) = 112 |
---|
443 | ! ! Great North American Lakes |
---|
444 | ictsi1(2) = 97 ; ictsj1(2) = 107 |
---|
445 | ictsi2(2) = 103 ; ictsj2(2) = 111 |
---|
446 | ! ! Black Sea 1 : west part of the Black Sea |
---|
447 | ictsi1(3) = 174 ; ictsj1(3) = 107 |
---|
448 | ictsi2(3) = 181 ; ictsj2(3) = 112 |
---|
449 | ! ! Black Sea 2 : est part of the Black Sea |
---|
450 | ictsi1(4) = 2 ; ictsj1(4) = 107 |
---|
451 | ictsi2(4) = 6 ; ictsj2(4) = 112 |
---|
452 | ! ! ======================= |
---|
453 | CASE ( 4 ) ! ORCA_R4 configuration |
---|
454 | ! ! ======================= |
---|
455 | ! ! Caspian Sea |
---|
456 | ictsi1(1) = 4 ; ictsj1(1) = 53 |
---|
457 | ictsi2(1) = 4 ; ictsj2(1) = 56 |
---|
458 | ! ! Great North American Lakes |
---|
459 | ictsi1(2) = 49 ; ictsj1(2) = 55 |
---|
460 | ictsi2(2) = 51 ; ictsj2(2) = 56 |
---|
461 | ! ! Black Sea |
---|
462 | ictsi1(3) = 88 ; ictsj1(3) = 55 |
---|
463 | ictsi2(3) = 91 ; ictsj2(3) = 56 |
---|
464 | ! ! Baltic Sea |
---|
465 | ictsi1(4) = 75 ; ictsj1(4) = 59 |
---|
466 | ictsi2(4) = 76 ; ictsj2(4) = 61 |
---|
467 | ! ! ======================= |
---|
468 | ! ! ======================= |
---|
469 | CASE ( 025 ) ! ORCA_R025 configuration |
---|
470 | ! ! ======================= |
---|
471 | ! Caspian + Aral sea |
---|
472 | ictsi1(1) = 1330 ; ictsj1(1) = 645 |
---|
473 | ictsi2(1) = 1400 ; ictsj2(1) = 795 |
---|
474 | ! ! Azov Sea |
---|
475 | ictsi1(2) = 1284 ; ictsj1(2) = 722 |
---|
476 | ictsi2(2) = 1304 ; ictsj2(2) = 747 |
---|
477 | ! |
---|
478 | END SELECT |
---|
479 | ! |
---|
480 | ENDIF |
---|
481 | |
---|
482 | ! convert the position in local domain indices |
---|
483 | ! -------------------------------------------- |
---|
484 | DO jc = 1, npicts |
---|
485 | ictsi1(jc) = mi0( ictsi1(jc) ) |
---|
486 | ictsj1(jc) = mj0( ictsj1(jc) ) |
---|
487 | |
---|
488 | ictsi2(jc) = mi1( ictsi2(jc) ) |
---|
489 | ictsj2(jc) = mj1( ictsj2(jc) ) |
---|
490 | END DO |
---|
491 | |
---|
492 | ! Restore close seas values to initial data |
---|
493 | IF( ln_trcdta .AND. nb_trcdta > 0 ) THEN ! Initialisation of tracer from a file that may also be used for damping |
---|
494 | ! |
---|
495 | CALL wrk_alloc( jpi, jpj, jpk, nb_trcdta, ztrcdta ) ! Memory allocation |
---|
496 | ! |
---|
497 | CALL trc_dta( nittrc000, ztrcdta ) ! read tracer data at nittrc000 |
---|
498 | ! |
---|
499 | DO jn = 1, jptra |
---|
500 | IF( ln_trc_ini(jn) ) THEN ! update passive tracers arrays with input data read from file |
---|
501 | jl = n_trc_index(jn) |
---|
502 | DO jc = 1, npicts |
---|
503 | DO jk = 1, jpkm1 |
---|
504 | DO jj = ictsj1(jc), ictsj2(jc) |
---|
505 | DO ji = ictsi1(jc), ictsi2(jc) |
---|
506 | trn(ji,jj,jk,jn) = ztrcdta(ji,jj,jk,jl) * tmask(ji,jj,jk) |
---|
507 | trb(ji,jj,jk,jn) = trn(ji,jj,jk,jn) |
---|
508 | ENDDO |
---|
509 | ENDDO |
---|
510 | ENDDO |
---|
511 | ENDDO |
---|
512 | ENDIF |
---|
513 | ENDDO |
---|
514 | CALL wrk_dealloc( jpi, jpj, jpk, nb_trcdta, ztrcdta ) |
---|
515 | ENDIF |
---|
516 | ! |
---|
517 | END SUBROUTINE p4z_clo |
---|
518 | #else |
---|
519 | !!====================================================================== |
---|
520 | !! Dummy module : No PISCES bio-model |
---|
521 | !!====================================================================== |
---|
522 | CONTAINS |
---|
523 | SUBROUTINE p4z_sms( kt ) ! Empty routine |
---|
524 | INTEGER, INTENT( in ) :: kt |
---|
525 | WRITE(*,*) 'p4z_sms: You should not have seen this print! error?', kt |
---|
526 | END SUBROUTINE p4z_sms |
---|
527 | #endif |
---|
528 | |
---|
529 | !!====================================================================== |
---|
530 | END MODULE p4zsms |
---|