1 | MODULE p4zsink |
---|
2 | !!====================================================================== |
---|
3 | !! *** MODULE p4zsink *** |
---|
4 | !! TOP : PISCES vertical flux of particulate matter due to gravitational sinking |
---|
5 | !!====================================================================== |
---|
6 | !! History : 1.0 ! 2004 (O. Aumont) Original code |
---|
7 | !! 2.0 ! 2007-12 (C. Ethe, G. Madec) F90 |
---|
8 | !! 3.4 ! 2011-06 (O. Aumont, C. Ethe) Change aggregation formula |
---|
9 | !! 3.5 ! 2012-07 (O. Aumont) Introduce potential time-splitting |
---|
10 | !!---------------------------------------------------------------------- |
---|
11 | #if defined key_pisces |
---|
12 | !!---------------------------------------------------------------------- |
---|
13 | !! p4z_sink : Compute vertical flux of particulate matter due to gravitational sinking |
---|
14 | !! p4z_sink_init : Unitialisation of sinking speed parameters |
---|
15 | !! p4z_sink_alloc : Allocate sinking speed variables |
---|
16 | !!---------------------------------------------------------------------- |
---|
17 | USE oce_trc ! shared variables between ocean and passive tracers |
---|
18 | USE trc ! passive tracers common variables |
---|
19 | USE sms_pisces ! PISCES Source Minus Sink variables |
---|
20 | USE prtctl_trc ! print control for debugging |
---|
21 | USE iom ! I/O manager |
---|
22 | USE lib_mpp |
---|
23 | |
---|
24 | IMPLICIT NONE |
---|
25 | PRIVATE |
---|
26 | |
---|
27 | PUBLIC p4z_sink ! called in p4zbio.F90 |
---|
28 | PUBLIC p4z_sink_init ! called in trcsms_pisces.F90 |
---|
29 | PUBLIC p4z_sink_alloc |
---|
30 | |
---|
31 | REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: wsbio3 !: POC sinking speed |
---|
32 | REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: wsbio4 !: GOC sinking speed |
---|
33 | REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: wscal !: Calcite and BSi sinking speeds |
---|
34 | |
---|
35 | REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: sinking, sinking2 !: POC sinking fluxes |
---|
36 | ! ! (different meanings depending on the parameterization) |
---|
37 | REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: sinkcal, sinksil !: CaCO3 and BSi sinking fluxes |
---|
38 | REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: sinkfer !: Small BFe sinking fluxes |
---|
39 | #if ! defined key_kriest |
---|
40 | REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: sinkfer2 !: Big iron sinking fluxes |
---|
41 | #endif |
---|
42 | |
---|
43 | INTEGER :: iksed = 10 |
---|
44 | |
---|
45 | #if defined key_kriest |
---|
46 | REAL(wp) :: xkr_sfact = 250. !: Sinking factor |
---|
47 | REAL(wp) :: xkr_stick = 0.2 !: Stickiness |
---|
48 | REAL(wp) :: xkr_nnano = 2.337 !: Nbr of cell in nano size class |
---|
49 | REAL(wp) :: xkr_ndiat = 3.718 !: Nbr of cell in diatoms size class |
---|
50 | REAL(wp) :: xkr_nmicro = 3.718 !: Nbr of cell in microzoo size class |
---|
51 | REAL(wp) :: xkr_nmeso = 7.147 !: Nbr of cell in mesozoo size class |
---|
52 | REAL(wp) :: xkr_naggr = 9.877 !: Nbr of cell in aggregates size class |
---|
53 | |
---|
54 | REAL(wp) :: xkr_frac |
---|
55 | |
---|
56 | REAL(wp), PUBLIC :: xkr_dnano !: Size of particles in nano pool |
---|
57 | REAL(wp), PUBLIC :: xkr_ddiat !: Size of particles in diatoms pool |
---|
58 | REAL(wp), PUBLIC :: xkr_dmicro !: Size of particles in microzoo pool |
---|
59 | REAL(wp), PUBLIC :: xkr_dmeso !: Size of particles in mesozoo pool |
---|
60 | REAL(wp), PUBLIC :: xkr_daggr !: Size of particles in aggregates pool |
---|
61 | REAL(wp), PUBLIC :: xkr_wsbio_min !: min vertical particle speed |
---|
62 | REAL(wp), PUBLIC :: xkr_wsbio_max !: max vertical particle speed |
---|
63 | |
---|
64 | REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:) :: xnumm !: maximum number of particles in aggregates |
---|
65 | #endif |
---|
66 | |
---|
67 | !!* Substitution |
---|
68 | # include "top_substitute.h90" |
---|
69 | !!---------------------------------------------------------------------- |
---|
70 | !! NEMO/TOP 3.3 , NEMO Consortium (2010) |
---|
71 | !! $Id: p4zsink.F90 3160 2011-11-20 14:27:18Z cetlod $ |
---|
72 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
---|
73 | !!---------------------------------------------------------------------- |
---|
74 | CONTAINS |
---|
75 | |
---|
76 | #if ! defined key_kriest |
---|
77 | !!---------------------------------------------------------------------- |
---|
78 | !! 'standard sinking parameterisation' ??? |
---|
79 | !!---------------------------------------------------------------------- |
---|
80 | |
---|
81 | SUBROUTINE p4z_sink ( kt, jnt ) |
---|
82 | !!--------------------------------------------------------------------- |
---|
83 | !! *** ROUTINE p4z_sink *** |
---|
84 | !! |
---|
85 | !! ** Purpose : Compute vertical flux of particulate matter due to |
---|
86 | !! gravitational sinking |
---|
87 | !! |
---|
88 | !! ** Method : - ??? |
---|
89 | !!--------------------------------------------------------------------- |
---|
90 | INTEGER, INTENT(in) :: kt, jnt |
---|
91 | INTEGER :: ji, jj, jk, jit |
---|
92 | INTEGER :: iiter1, iiter2 |
---|
93 | REAL(wp) :: zagg1, zagg2, zagg3, zagg4 |
---|
94 | REAL(wp) :: zagg , zaggfe, zaggdoc, zaggdoc2, zaggdoc3 |
---|
95 | REAL(wp) :: zfact, zwsmax, zmax, zstep |
---|
96 | REAL(wp) :: zrfact2 |
---|
97 | INTEGER :: ik1 |
---|
98 | CHARACTER (len=25) :: charout |
---|
99 | !!--------------------------------------------------------------------- |
---|
100 | ! |
---|
101 | IF( nn_timing == 1 ) CALL timing_start('p4z_sink') |
---|
102 | ! |
---|
103 | ! Sinking speeds of detritus is increased with depth as shown |
---|
104 | ! by data and from the coagulation theory |
---|
105 | ! ----------------------------------------------------------- |
---|
106 | DO jk = 1, jpkm1 |
---|
107 | DO jj = 1, jpj |
---|
108 | DO ji = 1,jpi |
---|
109 | zmax = MAX( heup(ji,jj), hmld(ji,jj) ) |
---|
110 | zfact = MAX( 0., fsdepw(ji,jj,jk+1) - zmax ) / 5000._wp |
---|
111 | wsbio4(ji,jj,jk) = wsbio2 + ( 200.- wsbio2 ) * zfact |
---|
112 | END DO |
---|
113 | END DO |
---|
114 | END DO |
---|
115 | |
---|
116 | ! limit the values of the sinking speeds to avoid numerical instabilities |
---|
117 | wsbio3(:,:,:) = wsbio |
---|
118 | wscal (:,:,:) = wsbio4(:,:,:) |
---|
119 | ! |
---|
120 | ! OA This is (I hope) a temporary solution for the problem that may |
---|
121 | ! OA arise in specific situation where the CFL criterion is broken |
---|
122 | ! OA for vertical sedimentation of particles. To avoid this, a time |
---|
123 | ! OA splitting algorithm has been coded. A specific maximum |
---|
124 | ! OA iteration number is provided and may be specified in the namelist |
---|
125 | ! OA This is to avoid very large iteration number when explicit free |
---|
126 | ! OA surface is used (for instance). When niter?max is set to 1, |
---|
127 | ! OA this computation is skipped. The crude old threshold method is |
---|
128 | ! OA then applied. This also happens when niter exceeds nitermax. |
---|
129 | IF( MAX( niter1max, niter2max ) == 1 ) THEN |
---|
130 | iiter1 = 1 |
---|
131 | iiter2 = 1 |
---|
132 | ELSE |
---|
133 | iiter1 = 1 |
---|
134 | iiter2 = 1 |
---|
135 | DO jk = 1, jpkm1 |
---|
136 | DO jj = 1, jpj |
---|
137 | DO ji = 1, jpi |
---|
138 | IF( tmask(ji,jj,jk) == 1) THEN |
---|
139 | zwsmax = 0.8 * fse3t(ji,jj,jk) / xstep |
---|
140 | iiter1 = MAX( iiter1, INT( wsbio3(ji,jj,jk) / zwsmax ) ) |
---|
141 | iiter2 = MAX( iiter2, INT( wsbio4(ji,jj,jk) / zwsmax ) ) |
---|
142 | ENDIF |
---|
143 | END DO |
---|
144 | END DO |
---|
145 | END DO |
---|
146 | IF( lk_mpp ) THEN |
---|
147 | CALL mpp_max( iiter1 ) |
---|
148 | CALL mpp_max( iiter2 ) |
---|
149 | ENDIF |
---|
150 | iiter1 = MIN( iiter1, niter1max ) |
---|
151 | iiter2 = MIN( iiter2, niter2max ) |
---|
152 | ENDIF |
---|
153 | |
---|
154 | DO jk = 1,jpkm1 |
---|
155 | DO jj = 1, jpj |
---|
156 | DO ji = 1, jpi |
---|
157 | IF( tmask(ji,jj,jk) == 1 ) THEN |
---|
158 | zwsmax = 0.8 * fse3t(ji,jj,jk) / xstep |
---|
159 | wsbio3(ji,jj,jk) = MIN( wsbio3(ji,jj,jk), zwsmax * FLOAT( iiter1 ) ) |
---|
160 | wsbio4(ji,jj,jk) = MIN( wsbio4(ji,jj,jk), zwsmax * FLOAT( iiter2 ) ) |
---|
161 | ENDIF |
---|
162 | END DO |
---|
163 | END DO |
---|
164 | END DO |
---|
165 | |
---|
166 | ! Initializa to zero all the sinking arrays |
---|
167 | ! ----------------------------------------- |
---|
168 | sinking (:,:,:) = 0.e0 |
---|
169 | sinking2(:,:,:) = 0.e0 |
---|
170 | sinkcal (:,:,:) = 0.e0 |
---|
171 | sinkfer (:,:,:) = 0.e0 |
---|
172 | sinksil (:,:,:) = 0.e0 |
---|
173 | sinkfer2(:,:,:) = 0.e0 |
---|
174 | |
---|
175 | ! Compute the sedimentation term using p4zsink2 for all the sinking particles |
---|
176 | ! ----------------------------------------------------- |
---|
177 | DO jit = 1, iiter1 |
---|
178 | CALL p4z_sink2( wsbio3, sinking , jppoc, iiter1 ) |
---|
179 | CALL p4z_sink2( wsbio3, sinkfer , jpsfe, iiter1 ) |
---|
180 | END DO |
---|
181 | |
---|
182 | DO jit = 1, iiter2 |
---|
183 | CALL p4z_sink2( wsbio4, sinking2, jpgoc, iiter2 ) |
---|
184 | CALL p4z_sink2( wsbio4, sinkfer2, jpbfe, iiter2 ) |
---|
185 | CALL p4z_sink2( wsbio4, sinksil , jpgsi, iiter2 ) |
---|
186 | CALL p4z_sink2( wscal , sinkcal , jpcal, iiter2 ) |
---|
187 | END DO |
---|
188 | |
---|
189 | ! Exchange between organic matter compartments due to coagulation/disaggregation |
---|
190 | ! --------------------------------------------------- |
---|
191 | DO jk = 1, jpkm1 |
---|
192 | DO jj = 1, jpj |
---|
193 | DO ji = 1, jpi |
---|
194 | ! |
---|
195 | zstep = xstep |
---|
196 | # if defined key_degrad |
---|
197 | zstep = zstep * facvol(ji,jj,jk) |
---|
198 | # endif |
---|
199 | zfact = zstep * xdiss(ji,jj,jk) |
---|
200 | ! Part I : Coagulation dependent on turbulence |
---|
201 | zagg1 = 25.9 * zfact * trn(ji,jj,jk,jppoc) * trn(ji,jj,jk,jppoc) |
---|
202 | zagg2 = 4452. * zfact * trn(ji,jj,jk,jppoc) * trn(ji,jj,jk,jpgoc) |
---|
203 | |
---|
204 | ! Part II : Differential settling |
---|
205 | |
---|
206 | ! Aggregation of small into large particles |
---|
207 | zagg3 = 47.1 * zstep * trn(ji,jj,jk,jppoc) * trn(ji,jj,jk,jpgoc) |
---|
208 | zagg4 = 3.3 * zstep * trn(ji,jj,jk,jppoc) * trn(ji,jj,jk,jppoc) |
---|
209 | |
---|
210 | zagg = zagg1 + zagg2 + zagg3 + zagg4 |
---|
211 | zaggfe = zagg * trn(ji,jj,jk,jpsfe) / ( trn(ji,jj,jk,jppoc) + rtrn ) |
---|
212 | |
---|
213 | ! Aggregation of DOC to POC : |
---|
214 | ! 1st term is shear aggregation of DOC-DOC |
---|
215 | ! 2nd term is shear aggregation of DOC-POC |
---|
216 | ! 3rd term is differential settling of DOC-POC |
---|
217 | zaggdoc = ( ( 0.369 * 0.3 * trn(ji,jj,jk,jpdoc) + 102.4 * trn(ji,jj,jk,jppoc) ) * zfact & |
---|
218 | & + 2.4 * zstep * trn(ji,jj,jk,jppoc) ) * 0.3 * trn(ji,jj,jk,jpdoc) |
---|
219 | ! zaggdoc = ( 0.83 * trn(ji,jj,jk,jpdoc) + 271. * trn(ji,jj,jk,jppoc) ) * zfact * trn(ji,jj,jk,jpdoc) |
---|
220 | ! transfer of DOC to GOC : |
---|
221 | ! 1st term is shear aggregation |
---|
222 | ! 2nd term is differential settling |
---|
223 | zaggdoc2 = ( 3.53E3 * zfact + 0.1 * zstep ) * trn(ji,jj,jk,jpgoc) * 0.3 * trn(ji,jj,jk,jpdoc) |
---|
224 | ! zaggdoc2 = 1.07e4 * zfact * trn(ji,jj,jk,jpgoc) * trn(ji,jj,jk,jpdoc) |
---|
225 | ! tranfer of DOC to POC due to brownian motion |
---|
226 | ! zaggdoc3 = 0.02 * ( 16706. * trn(ji,jj,jk,jppoc) + 231. * trn(ji,jj,jk,jpdoc) ) * zstep * trn(ji,jj,jk,jpdoc) |
---|
227 | zaggdoc3 = ( 5095. * trn(ji,jj,jk,jppoc) + 114. * 0.3 * trn(ji,jj,jk,jpdoc) ) *zstep * 0.3 * trn(ji,jj,jk,jpdoc) |
---|
228 | |
---|
229 | ! Update the trends |
---|
230 | tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) - zagg + zaggdoc + zaggdoc3 |
---|
231 | tra(ji,jj,jk,jpgoc) = tra(ji,jj,jk,jpgoc) + zagg + zaggdoc2 |
---|
232 | tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) - zaggfe |
---|
233 | tra(ji,jj,jk,jpbfe) = tra(ji,jj,jk,jpbfe) + zaggfe |
---|
234 | tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) - zaggdoc - zaggdoc2 - zaggdoc3 |
---|
235 | ! |
---|
236 | END DO |
---|
237 | END DO |
---|
238 | END DO |
---|
239 | |
---|
240 | ! |
---|
241 | IF( ln_diatrc ) THEN |
---|
242 | zrfact2 = 1.e3 * rfact2r |
---|
243 | ik1 = iksed + 1 |
---|
244 | IF( lk_iomput ) THEN |
---|
245 | IF( jnt == nrdttrc ) THEN |
---|
246 | CALL iom_put( "EPC100" , ( sinking(:,:,ik1) + sinking2(:,:,ik1) ) * zrfact2 * tmask(:,:,1) ) ! Export of carbon at 100m |
---|
247 | CALL iom_put( "EPFE100" , ( sinkfer(:,:,ik1) + sinkfer2(:,:,ik1) ) * zrfact2 * tmask(:,:,1) ) ! Export of iron at 100m |
---|
248 | CALL iom_put( "EPCAL100", sinkcal(:,:,ik1) * zrfact2 * tmask(:,:,1) ) ! Export of calcite at 100m |
---|
249 | CALL iom_put( "EPSI100" , sinksil(:,:,ik1) * zrfact2 * tmask(:,:,1) ) ! Export of biogenic silica at 100m |
---|
250 | ENDIF |
---|
251 | ELSE |
---|
252 | trc2d(:,:,jp_pcs0_2d + 4) = sinking (:,:,ik1) * zrfact2 * tmask(:,:,1) |
---|
253 | trc2d(:,:,jp_pcs0_2d + 5) = sinking2(:,:,ik1) * zrfact2 * tmask(:,:,1) |
---|
254 | trc2d(:,:,jp_pcs0_2d + 6) = sinkfer (:,:,ik1) * zrfact2 * tmask(:,:,1) |
---|
255 | trc2d(:,:,jp_pcs0_2d + 7) = sinkfer2(:,:,ik1) * zrfact2 * tmask(:,:,1) |
---|
256 | trc2d(:,:,jp_pcs0_2d + 8) = sinksil (:,:,ik1) * zrfact2 * tmask(:,:,1) |
---|
257 | trc2d(:,:,jp_pcs0_2d + 9) = sinkcal (:,:,ik1) * zrfact2 * tmask(:,:,1) |
---|
258 | ENDIF |
---|
259 | ENDIF |
---|
260 | ! |
---|
261 | IF(ln_ctl) THEN ! print mean trends (used for debugging) |
---|
262 | WRITE(charout, FMT="('sink')") |
---|
263 | CALL prt_ctl_trc_info(charout) |
---|
264 | CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm) |
---|
265 | ENDIF |
---|
266 | ! |
---|
267 | IF( nn_timing == 1 ) CALL timing_stop('p4z_sink') |
---|
268 | ! |
---|
269 | END SUBROUTINE p4z_sink |
---|
270 | |
---|
271 | SUBROUTINE p4z_sink_init |
---|
272 | !!---------------------------------------------------------------------- |
---|
273 | !! *** ROUTINE p4z_sink_init *** |
---|
274 | !!---------------------------------------------------------------------- |
---|
275 | END SUBROUTINE p4z_sink_init |
---|
276 | |
---|
277 | #else |
---|
278 | !!---------------------------------------------------------------------- |
---|
279 | !! 'Kriest sinking parameterisation' key_kriest ??? |
---|
280 | !!---------------------------------------------------------------------- |
---|
281 | |
---|
282 | SUBROUTINE p4z_sink ( kt, jnt ) |
---|
283 | !!--------------------------------------------------------------------- |
---|
284 | !! *** ROUTINE p4z_sink *** |
---|
285 | !! |
---|
286 | !! ** Purpose : Compute vertical flux of particulate matter due to |
---|
287 | !! gravitational sinking - Kriest parameterization |
---|
288 | !! |
---|
289 | !! ** Method : - ??? |
---|
290 | !!--------------------------------------------------------------------- |
---|
291 | ! |
---|
292 | INTEGER, INTENT(in) :: kt, jnt |
---|
293 | ! |
---|
294 | INTEGER :: ji, jj, jk, jit, niter1, niter2 |
---|
295 | REAL(wp) :: zagg1, zagg2, zagg3, zagg4, zagg5, zfract, zaggsi, zaggsh |
---|
296 | REAL(wp) :: zagg , zaggdoc, zaggdoc1, znumdoc |
---|
297 | REAL(wp) :: znum , zeps, zfm, zgm, zsm |
---|
298 | REAL(wp) :: zdiv , zdiv1, zdiv2, zdiv3, zdiv4, zdiv5 |
---|
299 | REAL(wp) :: zval1, zval2, zval3, zval4 |
---|
300 | REAL(wp) :: zrfact2 |
---|
301 | INTEGER :: ik1 |
---|
302 | CHARACTER (len=25) :: charout |
---|
303 | REAL(wp), POINTER, DIMENSION(:,:,:) :: znum3d |
---|
304 | !!--------------------------------------------------------------------- |
---|
305 | ! |
---|
306 | IF( nn_timing == 1 ) CALL timing_start('p4z_sink') |
---|
307 | ! |
---|
308 | CALL wrk_alloc( jpi, jpj, jpk, znum3d ) |
---|
309 | ! |
---|
310 | ! Initialisation of variables used to compute Sinking Speed |
---|
311 | ! --------------------------------------------------------- |
---|
312 | |
---|
313 | znum3d(:,:,:) = 0.e0 |
---|
314 | zval1 = 1. + xkr_zeta |
---|
315 | zval2 = 1. + xkr_zeta + xkr_eta |
---|
316 | zval3 = 1. + xkr_eta |
---|
317 | |
---|
318 | ! Computation of the vertical sinking speed : Kriest et Evans, 2000 |
---|
319 | ! ----------------------------------------------------------------- |
---|
320 | |
---|
321 | DO jk = 1, jpkm1 |
---|
322 | DO jj = 1, jpj |
---|
323 | DO ji = 1, jpi |
---|
324 | IF( tmask(ji,jj,jk) /= 0.e0 ) THEN |
---|
325 | znum = trn(ji,jj,jk,jppoc) / ( trn(ji,jj,jk,jpnum) + rtrn ) / xkr_massp |
---|
326 | ! -------------- To avoid sinking speed over 50 m/day ------- |
---|
327 | znum = MIN( xnumm(jk), znum ) |
---|
328 | znum = MAX( 1.1 , znum ) |
---|
329 | znum3d(ji,jj,jk) = znum |
---|
330 | !------------------------------------------------------------ |
---|
331 | zeps = ( zval1 * znum - 1. )/ ( znum - 1. ) |
---|
332 | zfm = xkr_frac**( 1. - zeps ) |
---|
333 | zgm = xkr_frac**( zval1 - zeps ) |
---|
334 | zdiv = MAX( 1.e-4, ABS( zeps - zval2 ) ) * SIGN( 1., ( zeps - zval2 ) ) |
---|
335 | zdiv1 = zeps - zval3 |
---|
336 | wsbio3(ji,jj,jk) = xkr_wsbio_min * ( zeps - zval1 ) / zdiv & |
---|
337 | & - xkr_wsbio_max * zgm * xkr_eta / zdiv |
---|
338 | wsbio4(ji,jj,jk) = xkr_wsbio_min * ( zeps-1. ) / zdiv1 & |
---|
339 | & - xkr_wsbio_max * zfm * xkr_eta / zdiv1 |
---|
340 | IF( znum == 1.1) wsbio3(ji,jj,jk) = wsbio4(ji,jj,jk) |
---|
341 | ENDIF |
---|
342 | END DO |
---|
343 | END DO |
---|
344 | END DO |
---|
345 | |
---|
346 | wscal(:,:,:) = MAX( wsbio3(:,:,:), 30._wp ) |
---|
347 | |
---|
348 | ! INITIALIZE TO ZERO ALL THE SINKING ARRAYS |
---|
349 | ! ----------------------------------------- |
---|
350 | |
---|
351 | sinking (:,:,:) = 0.e0 |
---|
352 | sinking2(:,:,:) = 0.e0 |
---|
353 | sinkcal (:,:,:) = 0.e0 |
---|
354 | sinkfer (:,:,:) = 0.e0 |
---|
355 | sinksil (:,:,:) = 0.e0 |
---|
356 | |
---|
357 | ! Compute the sedimentation term using p4zsink2 for all the sinking particles |
---|
358 | ! ----------------------------------------------------- |
---|
359 | |
---|
360 | niter1 = niter1max |
---|
361 | niter2 = niter2max |
---|
362 | |
---|
363 | DO jit = 1, niter1 |
---|
364 | CALL p4z_sink2( wsbio3, sinking , jppoc, niter1 ) |
---|
365 | CALL p4z_sink2( wsbio3, sinkfer , jpsfe, niter1 ) |
---|
366 | CALL p4z_sink2( wscal , sinksil , jpgsi, niter1 ) |
---|
367 | CALL p4z_sink2( wscal , sinkcal , jpcal, niter1 ) |
---|
368 | END DO |
---|
369 | |
---|
370 | DO jit = 1, niter2 |
---|
371 | CALL p4z_sink2( wsbio4, sinking2, jpnum, niter2 ) |
---|
372 | END DO |
---|
373 | |
---|
374 | ! Exchange between organic matter compartments due to coagulation/disaggregation |
---|
375 | ! --------------------------------------------------- |
---|
376 | |
---|
377 | zval1 = 1. + xkr_zeta |
---|
378 | zval2 = 1. + xkr_eta |
---|
379 | zval3 = 3. + xkr_eta |
---|
380 | zval4 = 4. + xkr_eta |
---|
381 | |
---|
382 | DO jk = 1,jpkm1 |
---|
383 | DO jj = 1,jpj |
---|
384 | DO ji = 1,jpi |
---|
385 | IF( tmask(ji,jj,jk) /= 0.e0 ) THEN |
---|
386 | |
---|
387 | znum = trn(ji,jj,jk,jppoc)/(trn(ji,jj,jk,jpnum)+rtrn) / xkr_massp |
---|
388 | !-------------- To avoid sinking speed over 50 m/day ------- |
---|
389 | znum = min(xnumm(jk),znum) |
---|
390 | znum = MAX( 1.1,znum) |
---|
391 | !------------------------------------------------------------ |
---|
392 | zeps = ( zval1 * znum - 1.) / ( znum - 1.) |
---|
393 | zdiv = MAX( 1.e-4, ABS( zeps - zval3) ) * SIGN( 1., zeps - zval3 ) |
---|
394 | zdiv1 = MAX( 1.e-4, ABS( zeps - 4. ) ) * SIGN( 1., zeps - 4. ) |
---|
395 | zdiv2 = zeps - 2. |
---|
396 | zdiv3 = zeps - 3. |
---|
397 | zdiv4 = zeps - zval2 |
---|
398 | zdiv5 = 2.* zeps - zval4 |
---|
399 | zfm = xkr_frac**( 1.- zeps ) |
---|
400 | zsm = xkr_frac**xkr_eta |
---|
401 | |
---|
402 | ! Part I : Coagulation dependant on turbulence |
---|
403 | ! ---------------------------------------------- |
---|
404 | |
---|
405 | zagg1 = ( 0.163 * trn(ji,jj,jk,jpnum)**2 & |
---|
406 | & * 2.*( (zfm-1.)*(zfm*xkr_mass_max**3-xkr_mass_min**3) & |
---|
407 | & * (zeps-1)/zdiv1 + 3.*(zfm*xkr_mass_max-xkr_mass_min) & |
---|
408 | & * (zfm*xkr_mass_max**2-xkr_mass_min**2) & |
---|
409 | & * (zeps-1.)**2/(zdiv2*zdiv3)) |
---|
410 | zagg2 = 2*0.163*trn(ji,jj,jk,jpnum)**2*zfm* & |
---|
411 | & ((xkr_mass_max**3+3.*(xkr_mass_max**2 & |
---|
412 | & *xkr_mass_min*(zeps-1.)/zdiv2 & |
---|
413 | & +xkr_mass_max*xkr_mass_min**2*(zeps-1.)/zdiv3) & |
---|
414 | & +xkr_mass_min**3*(zeps-1)/zdiv1) & |
---|
415 | & -zfm*xkr_mass_max**3*(1.+3.*((zeps-1.)/ & |
---|
416 | & (zeps-2.)+(zeps-1.)/zdiv3)+(zeps-1.)/zdiv1)) |
---|
417 | |
---|
418 | zagg3 = 0.163*trn(ji,jj,jk,jpnum)**2*zfm**2*8. * xkr_mass_max**3 |
---|
419 | |
---|
420 | ! Aggregation of small into large particles |
---|
421 | ! Part II : Differential settling |
---|
422 | ! ---------------------------------------------- |
---|
423 | |
---|
424 | zagg4 = 2.*3.141*0.125*trn(ji,jj,jk,jpnum)**2* & |
---|
425 | & xkr_wsbio_min*(zeps-1.)**2 & |
---|
426 | & *(xkr_mass_min**2*((1.-zsm*zfm)/(zdiv3*zdiv4) & |
---|
427 | & -(1.-zfm)/(zdiv*(zeps-1.)))- & |
---|
428 | & ((zfm*zfm*xkr_mass_max**2*zsm-xkr_mass_min**2) & |
---|
429 | & *xkr_eta)/(zdiv*zdiv3*zdiv5) ) |
---|
430 | |
---|
431 | zagg5 = 2.*3.141*0.125*trn(ji,jj,jk,jpnum)**2 & |
---|
432 | & *(zeps-1.)*zfm*xkr_wsbio_min & |
---|
433 | & *(zsm*(xkr_mass_min**2-zfm*xkr_mass_max**2) & |
---|
434 | & /zdiv3-(xkr_mass_min**2-zfm*zsm*xkr_mass_max**2) & |
---|
435 | & /zdiv) |
---|
436 | |
---|
437 | ! |
---|
438 | ! Fractionnation by swimming organisms |
---|
439 | ! ------------------------------------ |
---|
440 | |
---|
441 | zfract = 2.*3.141*0.125*trn(ji,jj,jk,jpmes)*12./0.12/0.06**3*trn(ji,jj,jk,jpnum) & |
---|
442 | & * (0.01/xkr_mass_min)**(1.-zeps)*0.1**2 & |
---|
443 | & * 10000.*xstep |
---|
444 | |
---|
445 | ! Aggregation of DOC to small particles |
---|
446 | ! -------------------------------------- |
---|
447 | |
---|
448 | zaggdoc = 0.83 * trn(ji,jj,jk,jpdoc) * xstep * xdiss(ji,jj,jk) * trn(ji,jj,jk,jpdoc) & |
---|
449 | & + 0.005 * 231. * trn(ji,jj,jk,jpdoc) * xstep * trn(ji,jj,jk,jpdoc) |
---|
450 | zaggdoc1 = 271. * trn(ji,jj,jk,jppoc) * xstep * xdiss(ji,jj,jk) * trn(ji,jj,jk,jpdoc) & |
---|
451 | & + 0.02 * 16706. * trn(ji,jj,jk,jppoc) * xstep * trn(ji,jj,jk,jpdoc) |
---|
452 | |
---|
453 | # if defined key_degrad |
---|
454 | zagg1 = zagg1 * facvol(ji,jj,jk) |
---|
455 | zagg2 = zagg2 * facvol(ji,jj,jk) |
---|
456 | zagg3 = zagg3 * facvol(ji,jj,jk) |
---|
457 | zagg4 = zagg4 * facvol(ji,jj,jk) |
---|
458 | zagg5 = zagg5 * facvol(ji,jj,jk) |
---|
459 | zaggdoc = zaggdoc * facvol(ji,jj,jk) |
---|
460 | zaggdoc1 = zaggdoc1 * facvol(ji,jj,jk) |
---|
461 | # endif |
---|
462 | zaggsh = ( zagg1 + zagg2 + zagg3 ) * rfact2 * xdiss(ji,jj,jk) / 1000. |
---|
463 | zaggsi = ( zagg4 + zagg5 ) * xstep / 10. |
---|
464 | zagg = 0.5 * xkr_stick * ( zaggsh + zaggsi ) |
---|
465 | ! |
---|
466 | znumdoc = trn(ji,jj,jk,jpnum) / ( trn(ji,jj,jk,jppoc) + rtrn ) |
---|
467 | tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) + zaggdoc + zaggdoc1 |
---|
468 | tra(ji,jj,jk,jpnum) = tra(ji,jj,jk,jpnum) + zfract + zaggdoc / xkr_massp - zagg |
---|
469 | tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) - zaggdoc - zaggdoc1 |
---|
470 | |
---|
471 | ENDIF |
---|
472 | END DO |
---|
473 | END DO |
---|
474 | END DO |
---|
475 | |
---|
476 | IF( ln_diatrc ) THEN |
---|
477 | ! |
---|
478 | ik1 = iksed + 1 |
---|
479 | zrfact2 = 1.e3 * rfact2r |
---|
480 | IF( jnt == nrdttrc ) THEN |
---|
481 | CALL iom_put( "POCFlx" , sinking (:,:,:) * zrfact2 * tmask(:,:,:) ) ! POC export |
---|
482 | CALL iom_put( "NumFlx" , sinking2 (:,:,:) * zrfact2 * tmask(:,:,:) ) ! Num export |
---|
483 | CALL iom_put( "SiFlx" , sinksil (:,:,:) * zrfact2 * tmask(:,:,:) ) ! Silica export |
---|
484 | CALL iom_put( "CaCO3Flx", sinkcal (:,:,:) * zrfact2 * tmask(:,:,:) ) ! Calcite export |
---|
485 | CALL iom_put( "xnum" , znum3d (:,:,:) * tmask(:,:,:) ) ! Number of particles in aggregats |
---|
486 | CALL iom_put( "W1" , wsbio3 (:,:,:) * tmask(:,:,:) ) ! sinking speed of POC |
---|
487 | CALL iom_put( "W2" , wsbio4 (:,:,:) * tmask(:,:,:) ) ! sinking speed of aggregats |
---|
488 | CALL iom_put( "PMO" , sinking (:,:,ik1) * zrfact2 * tmask(:,:,1) ) ! POC export at 100m |
---|
489 | CALL iom_put( "PMO2" , sinking2(:,:,ik1) * zrfact2 * tmask(:,:,1) ) ! Num export at 100m |
---|
490 | CALL iom_put( "ExpFe1" , sinkfer (:,:,ik1) * zrfact2 * tmask(:,:,1) ) ! Export of iron at 100m |
---|
491 | CALL iom_put( "ExpSi" , sinksil (:,:,ik1) * zrfact2 * tmask(:,:,1) ) ! export of silica at 100m |
---|
492 | CALL iom_put( "ExpCaCO3", sinkcal (:,:,ik1) * zrfact2 * tmask(:,:,1) ) ! export of calcite at 100m |
---|
493 | ENDIF |
---|
494 | # if ! defined key_iomput |
---|
495 | trc2d(:,: ,jp_pcs0_2d + 4) = sinking (:,:,ik1) * zrfact2 * tmask(:,:,1) |
---|
496 | trc2d(:,: ,jp_pcs0_2d + 5) = sinking2(:,:,ik1) * zrfact2 * tmask(:,:,1) |
---|
497 | trc2d(:,: ,jp_pcs0_2d + 6) = sinkfer (:,:,ik1) * zrfact2 * tmask(:,:,1) |
---|
498 | trc2d(:,: ,jp_pcs0_2d + 7) = sinksil (:,:,ik1) * zrfact2 * tmask(:,:,1) |
---|
499 | trc2d(:,: ,jp_pcs0_2d + 8) = sinkcal (:,:,ik1) * zrfact2 * tmask(:,:,1) |
---|
500 | trc3d(:,:,:,jp_pcs0_3d + 11) = sinking (:,:,:) * zrfact2 * tmask(:,:,:) |
---|
501 | trc3d(:,:,:,jp_pcs0_3d + 12) = sinking2(:,:,:) * zrfact2 * tmask(:,:,:) |
---|
502 | trc3d(:,:,:,jp_pcs0_3d + 13) = sinksil (:,:,:) * zrfact2 * tmask(:,:,:) |
---|
503 | trc3d(:,:,:,jp_pcs0_3d + 14) = sinkcal (:,:,:) * zrfact2 * tmask(:,:,:) |
---|
504 | trc3d(:,:,:,jp_pcs0_3d + 15) = znum3d (:,:,:) * tmask(:,:,:) |
---|
505 | trc3d(:,:,:,jp_pcs0_3d + 16) = wsbio3 (:,:,:) * tmask(:,:,:) |
---|
506 | trc3d(:,:,:,jp_pcs0_3d + 17) = wsbio4 (:,:,:) * tmask(:,:,:) |
---|
507 | # endif |
---|
508 | ! |
---|
509 | ENDIF |
---|
510 | ! |
---|
511 | IF(ln_ctl) THEN ! print mean trends (used for debugging) |
---|
512 | WRITE(charout, FMT="('sink')") |
---|
513 | CALL prt_ctl_trc_info(charout) |
---|
514 | CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm) |
---|
515 | ENDIF |
---|
516 | ! |
---|
517 | CALL wrk_dealloc( jpi, jpj, jpk, znum3d ) |
---|
518 | ! |
---|
519 | IF( nn_timing == 1 ) CALL timing_stop('p4z_sink') |
---|
520 | ! |
---|
521 | END SUBROUTINE p4z_sink |
---|
522 | |
---|
523 | |
---|
524 | SUBROUTINE p4z_sink_init |
---|
525 | !!---------------------------------------------------------------------- |
---|
526 | !! *** ROUTINE p4z_sink_init *** |
---|
527 | !! |
---|
528 | !! ** Purpose : Initialization of sinking parameters |
---|
529 | !! Kriest parameterization only |
---|
530 | !! |
---|
531 | !! ** Method : Read the nampiskrs namelist and check the parameters |
---|
532 | !! called at the first timestep |
---|
533 | !! |
---|
534 | !! ** input : Namelist nampiskrs |
---|
535 | !!---------------------------------------------------------------------- |
---|
536 | INTEGER :: jk, jn, kiter |
---|
537 | REAL(wp) :: znum, zdiv |
---|
538 | REAL(wp) :: zws, zwr, zwl,wmax, znummax |
---|
539 | REAL(wp) :: zmin, zmax, zl, zr, xacc |
---|
540 | ! |
---|
541 | NAMELIST/nampiskrs/ xkr_sfact, xkr_stick , & |
---|
542 | & xkr_nnano, xkr_ndiat, xkr_nmicro, xkr_nmeso, xkr_naggr |
---|
543 | !!---------------------------------------------------------------------- |
---|
544 | ! |
---|
545 | IF( nn_timing == 1 ) CALL timing_start('p4z_sink_init') |
---|
546 | ! |
---|
547 | REWIND( numnatp ) ! read nampiskrs |
---|
548 | READ ( numnatp, nampiskrs ) |
---|
549 | |
---|
550 | IF(lwp) THEN |
---|
551 | WRITE(numout,*) |
---|
552 | WRITE(numout,*) ' Namelist : nampiskrs' |
---|
553 | WRITE(numout,*) ' Sinking factor xkr_sfact = ', xkr_sfact |
---|
554 | WRITE(numout,*) ' Stickiness xkr_stick = ', xkr_stick |
---|
555 | WRITE(numout,*) ' Nbr of cell in nano size class xkr_nnano = ', xkr_nnano |
---|
556 | WRITE(numout,*) ' Nbr of cell in diatoms size class xkr_ndiat = ', xkr_ndiat |
---|
557 | WRITE(numout,*) ' Nbr of cell in microzoo size class xkr_nmicro = ', xkr_nmicro |
---|
558 | WRITE(numout,*) ' Nbr of cell in mesozoo size class xkr_nmeso = ', xkr_nmeso |
---|
559 | WRITE(numout,*) ' Nbr of cell in aggregates size class xkr_naggr = ', xkr_naggr |
---|
560 | ENDIF |
---|
561 | |
---|
562 | |
---|
563 | ! max and min vertical particle speed |
---|
564 | xkr_wsbio_min = xkr_sfact * xkr_mass_min**xkr_eta |
---|
565 | xkr_wsbio_max = xkr_sfact * xkr_mass_max**xkr_eta |
---|
566 | IF (lwp) WRITE(numout,*) ' max and min vertical particle speed ', xkr_wsbio_min, xkr_wsbio_max |
---|
567 | |
---|
568 | ! |
---|
569 | ! effect of the sizes of the different living pools on particle numbers |
---|
570 | ! nano = 2um-20um -> mean size=6.32 um -> ws=2.596 -> xnum=xnnano=2.337 |
---|
571 | ! diat and microzoo = 10um-200um -> 44.7 -> 8.732 -> xnum=xndiat=3.718 |
---|
572 | ! mesozoo = 200um-2mm -> 632.45 -> 45.14 -> xnum=xnmeso=7.147 |
---|
573 | ! aggregates = 200um-10mm -> 1414 -> 74.34 -> xnum=xnaggr=9.877 |
---|
574 | ! doc aggregates = 1um |
---|
575 | ! ---------------------------------------------------------- |
---|
576 | |
---|
577 | xkr_dnano = 1. / ( xkr_massp * xkr_nnano ) |
---|
578 | xkr_ddiat = 1. / ( xkr_massp * xkr_ndiat ) |
---|
579 | xkr_dmicro = 1. / ( xkr_massp * xkr_nmicro ) |
---|
580 | xkr_dmeso = 1. / ( xkr_massp * xkr_nmeso ) |
---|
581 | xkr_daggr = 1. / ( xkr_massp * xkr_naggr ) |
---|
582 | |
---|
583 | !!--------------------------------------------------------------------- |
---|
584 | !! 'key_kriest' ??? |
---|
585 | !!--------------------------------------------------------------------- |
---|
586 | ! COMPUTATION OF THE VERTICAL PROFILE OF MAXIMUM SINKING SPEED |
---|
587 | ! Search of the maximum number of particles in aggregates for each k-level. |
---|
588 | ! Bissection Method |
---|
589 | !-------------------------------------------------------------------- |
---|
590 | IF (lwp) THEN |
---|
591 | WRITE(numout,*) |
---|
592 | WRITE(numout,*)' kriest : Compute maximum number of particles in aggregates' |
---|
593 | ENDIF |
---|
594 | |
---|
595 | xacc = 0.001_wp |
---|
596 | kiter = 50 |
---|
597 | zmin = 1.10_wp |
---|
598 | zmax = xkr_mass_max / xkr_mass_min |
---|
599 | xkr_frac = zmax |
---|
600 | |
---|
601 | DO jk = 1,jpk |
---|
602 | zl = zmin |
---|
603 | zr = zmax |
---|
604 | wmax = 0.5 * fse3t(1,1,jk) * rday * float(niter1max) / rfact2 |
---|
605 | zdiv = xkr_zeta + xkr_eta - xkr_eta * zl |
---|
606 | znum = zl - 1. |
---|
607 | zwl = xkr_wsbio_min * xkr_zeta / zdiv & |
---|
608 | & - ( xkr_wsbio_max * xkr_eta * znum * & |
---|
609 | & xkr_frac**( -xkr_zeta / znum ) / zdiv ) & |
---|
610 | & - wmax |
---|
611 | |
---|
612 | zdiv = xkr_zeta + xkr_eta - xkr_eta * zr |
---|
613 | znum = zr - 1. |
---|
614 | zwr = xkr_wsbio_min * xkr_zeta / zdiv & |
---|
615 | & - ( xkr_wsbio_max * xkr_eta * znum * & |
---|
616 | & xkr_frac**( -xkr_zeta / znum ) / zdiv ) & |
---|
617 | & - wmax |
---|
618 | iflag: DO jn = 1, kiter |
---|
619 | IF ( zwl == 0._wp ) THEN ; znummax = zl |
---|
620 | ELSEIF( zwr == 0._wp ) THEN ; znummax = zr |
---|
621 | ELSE |
---|
622 | znummax = ( zr + zl ) / 2. |
---|
623 | zdiv = xkr_zeta + xkr_eta - xkr_eta * znummax |
---|
624 | znum = znummax - 1. |
---|
625 | zws = xkr_wsbio_min * xkr_zeta / zdiv & |
---|
626 | & - ( xkr_wsbio_max * xkr_eta * znum * & |
---|
627 | & xkr_frac**( -xkr_zeta / znum ) / zdiv ) & |
---|
628 | & - wmax |
---|
629 | IF( zws * zwl < 0. ) THEN ; zr = znummax |
---|
630 | ELSE ; zl = znummax |
---|
631 | ENDIF |
---|
632 | zdiv = xkr_zeta + xkr_eta - xkr_eta * zl |
---|
633 | znum = zl - 1. |
---|
634 | zwl = xkr_wsbio_min * xkr_zeta / zdiv & |
---|
635 | & - ( xkr_wsbio_max * xkr_eta * znum * & |
---|
636 | & xkr_frac**( -xkr_zeta / znum ) / zdiv ) & |
---|
637 | & - wmax |
---|
638 | |
---|
639 | zdiv = xkr_zeta + xkr_eta - xkr_eta * zr |
---|
640 | znum = zr - 1. |
---|
641 | zwr = xkr_wsbio_min * xkr_zeta / zdiv & |
---|
642 | & - ( xkr_wsbio_max * xkr_eta * znum * & |
---|
643 | & xkr_frac**( -xkr_zeta / znum ) / zdiv ) & |
---|
644 | & - wmax |
---|
645 | ! |
---|
646 | IF ( ABS ( zws ) <= xacc ) EXIT iflag |
---|
647 | ! |
---|
648 | ENDIF |
---|
649 | ! |
---|
650 | END DO iflag |
---|
651 | |
---|
652 | xnumm(jk) = znummax |
---|
653 | IF (lwp) WRITE(numout,*) ' jk = ', jk, ' wmax = ', wmax,' xnum max = ', xnumm(jk) |
---|
654 | ! |
---|
655 | END DO |
---|
656 | ! |
---|
657 | IF( nn_timing == 1 ) CALL timing_stop('p4z_sink_init') |
---|
658 | ! |
---|
659 | END SUBROUTINE p4z_sink_init |
---|
660 | |
---|
661 | #endif |
---|
662 | |
---|
663 | SUBROUTINE p4z_sink2( pwsink, psinkflx, jp_tra, kiter ) |
---|
664 | !!--------------------------------------------------------------------- |
---|
665 | !! *** ROUTINE p4z_sink2 *** |
---|
666 | !! |
---|
667 | !! ** Purpose : Compute the sedimentation terms for the various sinking |
---|
668 | !! particles. The scheme used to compute the trends is based |
---|
669 | !! on MUSCL. |
---|
670 | !! |
---|
671 | !! ** Method : - this ROUTINE compute not exactly the advection but the |
---|
672 | !! transport term, i.e. div(u*tra). |
---|
673 | !!--------------------------------------------------------------------- |
---|
674 | ! |
---|
675 | INTEGER , INTENT(in ) :: jp_tra ! tracer index index |
---|
676 | INTEGER , INTENT(in ) :: kiter ! number of iterations for time-splitting |
---|
677 | REAL(wp), INTENT(in ), DIMENSION(jpi,jpj,jpk) :: pwsink ! sinking speed |
---|
678 | REAL(wp), INTENT(inout), DIMENSION(jpi,jpj,jpk) :: psinkflx ! sinking fluxe |
---|
679 | !! |
---|
680 | INTEGER :: ji, jj, jk, jn |
---|
681 | REAL(wp) :: zigma,zew,zign, zflx, zstep |
---|
682 | REAL(wp), POINTER, DIMENSION(:,:,:) :: ztraz, zakz, zwsink2 |
---|
683 | !!--------------------------------------------------------------------- |
---|
684 | ! |
---|
685 | IF( nn_timing == 1 ) CALL timing_start('p4z_sink2') |
---|
686 | ! |
---|
687 | ! Allocate temporary workspace |
---|
688 | CALL wrk_alloc( jpi, jpj, jpk, ztraz, zakz, zwsink2 ) |
---|
689 | |
---|
690 | zstep = rfact2 / FLOAT( kiter ) / 2. |
---|
691 | |
---|
692 | ztraz(:,:,:) = 0.e0 |
---|
693 | zakz (:,:,:) = 0.e0 |
---|
694 | |
---|
695 | DO jk = 1, jpkm1 |
---|
696 | zwsink2(:,:,jk+1) = -pwsink(:,:,jk) / rday * tmask(:,:,jk+1) |
---|
697 | END DO |
---|
698 | zwsink2(:,:,1) = 0.e0 |
---|
699 | IF( lk_degrad ) THEN |
---|
700 | zwsink2(:,:,:) = zwsink2(:,:,:) * facvol(:,:,:) |
---|
701 | ENDIF |
---|
702 | |
---|
703 | |
---|
704 | ! Vertical advective flux |
---|
705 | DO jn = 1, 2 |
---|
706 | ! first guess of the slopes interior values |
---|
707 | DO jk = 2, jpkm1 |
---|
708 | ztraz(:,:,jk) = ( trn(:,:,jk-1,jp_tra) - trn(:,:,jk,jp_tra) ) * tmask(:,:,jk) |
---|
709 | END DO |
---|
710 | ztraz(:,:,1 ) = 0.0 |
---|
711 | ztraz(:,:,jpk) = 0.0 |
---|
712 | |
---|
713 | ! slopes |
---|
714 | DO jk = 2, jpkm1 |
---|
715 | DO jj = 1,jpj |
---|
716 | DO ji = 1, jpi |
---|
717 | zign = 0.25 + SIGN( 0.25, ztraz(ji,jj,jk) * ztraz(ji,jj,jk+1) ) |
---|
718 | zakz(ji,jj,jk) = ( ztraz(ji,jj,jk) + ztraz(ji,jj,jk+1) ) * zign |
---|
719 | END DO |
---|
720 | END DO |
---|
721 | END DO |
---|
722 | |
---|
723 | ! Slopes limitation |
---|
724 | DO jk = 2, jpkm1 |
---|
725 | DO jj = 1, jpj |
---|
726 | DO ji = 1, jpi |
---|
727 | zakz(ji,jj,jk) = SIGN( 1., zakz(ji,jj,jk) ) * & |
---|
728 | & MIN( ABS( zakz(ji,jj,jk) ), 2. * ABS(ztraz(ji,jj,jk+1)), 2. * ABS(ztraz(ji,jj,jk) ) ) |
---|
729 | END DO |
---|
730 | END DO |
---|
731 | END DO |
---|
732 | |
---|
733 | ! vertical advective flux |
---|
734 | DO jk = 1, jpkm1 |
---|
735 | DO jj = 1, jpj |
---|
736 | DO ji = 1, jpi |
---|
737 | zigma = zwsink2(ji,jj,jk+1) * zstep / fse3w(ji,jj,jk+1) |
---|
738 | zew = zwsink2(ji,jj,jk+1) |
---|
739 | psinkflx(ji,jj,jk+1) = -zew * ( trn(ji,jj,jk,jp_tra) - 0.5 * ( 1 + zigma ) * zakz(ji,jj,jk) ) * zstep |
---|
740 | END DO |
---|
741 | END DO |
---|
742 | END DO |
---|
743 | ! |
---|
744 | ! Boundary conditions |
---|
745 | psinkflx(:,:,1 ) = 0.e0 |
---|
746 | psinkflx(:,:,jpk) = 0.e0 |
---|
747 | |
---|
748 | DO jk=1,jpkm1 |
---|
749 | DO jj = 1,jpj |
---|
750 | DO ji = 1, jpi |
---|
751 | zflx = ( psinkflx(ji,jj,jk) - psinkflx(ji,jj,jk+1) ) / fse3t(ji,jj,jk) |
---|
752 | trn(ji,jj,jk,jp_tra) = trn(ji,jj,jk,jp_tra) + zflx |
---|
753 | END DO |
---|
754 | END DO |
---|
755 | END DO |
---|
756 | |
---|
757 | ENDDO |
---|
758 | |
---|
759 | DO jk=1,jpkm1 |
---|
760 | DO jj = 1,jpj |
---|
761 | DO ji = 1, jpi |
---|
762 | zflx = ( psinkflx(ji,jj,jk) - psinkflx(ji,jj,jk+1) ) / fse3t(ji,jj,jk) |
---|
763 | trb(ji,jj,jk,jp_tra) = trb(ji,jj,jk,jp_tra) + 2. * zflx |
---|
764 | END DO |
---|
765 | END DO |
---|
766 | END DO |
---|
767 | |
---|
768 | trn (:,:,:,jp_tra) = trb(:,:,:,jp_tra) |
---|
769 | psinkflx(:,:,:) = 2. * psinkflx(:,:,:) |
---|
770 | ! |
---|
771 | CALL wrk_dealloc( jpi, jpj, jpk, ztraz, zakz, zwsink2 ) |
---|
772 | ! |
---|
773 | IF( nn_timing == 1 ) CALL timing_stop('p4z_sink2') |
---|
774 | ! |
---|
775 | END SUBROUTINE p4z_sink2 |
---|
776 | |
---|
777 | |
---|
778 | INTEGER FUNCTION p4z_sink_alloc() |
---|
779 | !!---------------------------------------------------------------------- |
---|
780 | !! *** ROUTINE p4z_sink_alloc *** |
---|
781 | !!---------------------------------------------------------------------- |
---|
782 | ALLOCATE( wsbio3 (jpi,jpj,jpk) , wsbio4 (jpi,jpj,jpk) , wscal(jpi,jpj,jpk) , & |
---|
783 | & sinking(jpi,jpj,jpk) , sinking2(jpi,jpj,jpk) , & |
---|
784 | & sinkcal(jpi,jpj,jpk) , sinksil (jpi,jpj,jpk) , & |
---|
785 | #if defined key_kriest |
---|
786 | & xnumm(jpk) , & |
---|
787 | #else |
---|
788 | & sinkfer2(jpi,jpj,jpk) , & |
---|
789 | #endif |
---|
790 | & sinkfer(jpi,jpj,jpk) , STAT=p4z_sink_alloc ) |
---|
791 | ! |
---|
792 | IF( p4z_sink_alloc /= 0 ) CALL ctl_warn('p4z_sink_alloc : failed to allocate arrays.') |
---|
793 | ! |
---|
794 | END FUNCTION p4z_sink_alloc |
---|
795 | |
---|
796 | #else |
---|
797 | !!====================================================================== |
---|
798 | !! Dummy module : No PISCES bio-model |
---|
799 | !!====================================================================== |
---|
800 | CONTAINS |
---|
801 | SUBROUTINE p4z_sink ! Empty routine |
---|
802 | END SUBROUTINE p4z_sink |
---|
803 | #endif |
---|
804 | |
---|
805 | !!====================================================================== |
---|
806 | END MODULE p4zsink |
---|