1 | MODULE p4zmeso |
---|
2 | !!====================================================================== |
---|
3 | !! *** MODULE p4zmeso *** |
---|
4 | !! TOP : PISCES Compute the sources/sinks for mesozooplankton |
---|
5 | !!====================================================================== |
---|
6 | !! History : 1.0 ! 2002 (O. Aumont) Original code |
---|
7 | !! 2.0 ! 2007-12 (C. Ethe, G. Madec) F90 |
---|
8 | !! 3.4 ! 2011-06 (O. Aumont, C. Ethe) Quota model for iron |
---|
9 | !!---------------------------------------------------------------------- |
---|
10 | #if defined key_pisces |
---|
11 | !!---------------------------------------------------------------------- |
---|
12 | !! 'key_pisces' PISCES bio-model |
---|
13 | !!---------------------------------------------------------------------- |
---|
14 | !! p4z_meso : Compute the sources/sinks for mesozooplankton |
---|
15 | !! p4z_meso_init : Initialization of the parameters for mesozooplankton |
---|
16 | !!---------------------------------------------------------------------- |
---|
17 | USE oce_trc ! shared variables between ocean and passive tracers |
---|
18 | USE trc ! passive tracers common variables |
---|
19 | USE sms_pisces ! PISCES Source Minus Sink variables |
---|
20 | USE p4zsink ! vertical flux of particulate matter due to sinking |
---|
21 | USE p4zint ! interpolation and computation of various fields |
---|
22 | USE p4zprod ! production |
---|
23 | USE prtctl_trc ! print control for debugging |
---|
24 | USE iom ! I/O manager |
---|
25 | |
---|
26 | IMPLICIT NONE |
---|
27 | PRIVATE |
---|
28 | |
---|
29 | PUBLIC p4z_meso ! called in p4zbio.F90 |
---|
30 | PUBLIC p4z_meso_init ! called in trcsms_pisces.F90 |
---|
31 | |
---|
32 | !! * Shared module variables |
---|
33 | REAL(wp), PUBLIC :: part2 = 0.5_wp !: part of calcite not dissolved in mesozoo guts |
---|
34 | REAL(wp), PUBLIC :: xprefc = 1.0_wp !: mesozoo preference for POC |
---|
35 | REAL(wp), PUBLIC :: xprefp = 0.3_wp !: mesozoo preference for nanophyto |
---|
36 | REAL(wp), PUBLIC :: xprefz = 1.0_wp !: mesozoo preference for diatoms |
---|
37 | REAL(wp), PUBLIC :: xprefpoc = 0.3_wp !: mesozoo preference for POC |
---|
38 | REAL(wp), PUBLIC :: xthresh2zoo = 1E-8_wp !: zoo feeding threshold for mesozooplankton |
---|
39 | REAL(wp), PUBLIC :: xthresh2dia = 1E-8_wp !: diatoms feeding threshold for mesozooplankton |
---|
40 | REAL(wp), PUBLIC :: xthresh2phy = 2E-7_wp !: nanophyto feeding threshold for mesozooplankton |
---|
41 | REAL(wp), PUBLIC :: xthresh2poc = 1E-8_wp !: poc feeding threshold for mesozooplankton |
---|
42 | REAL(wp), PUBLIC :: xthresh2 = 0._wp !: feeding threshold for mesozooplankton |
---|
43 | REAL(wp), PUBLIC :: resrat2 = 0.005_wp !: exsudation rate of mesozooplankton |
---|
44 | REAL(wp), PUBLIC :: mzrat2 = 0.04_wp !: microzooplankton mortality rate |
---|
45 | REAL(wp), PUBLIC :: grazrat2 = 0.9_wp !: maximal mesozoo grazing rate |
---|
46 | REAL(wp), PUBLIC :: xkgraz2 = 20E-6_wp !: non assimilated fraction of P by mesozoo |
---|
47 | REAL(wp), PUBLIC :: unass2 = 0.3_wp !: Efficicency of mesozoo growth |
---|
48 | REAL(wp), PUBLIC :: sigma2 = 0.6_wp !: Fraction of mesozoo excretion as DOM |
---|
49 | REAL(wp), PUBLIC :: epsher2 = 0.3_wp !: half sturation constant for grazing 2 |
---|
50 | REAL(wp), PUBLIC :: grazflux = 3.E3_wp !: mesozoo flux feeding rate |
---|
51 | |
---|
52 | !!* Substitution |
---|
53 | # include "top_substitute.h90" |
---|
54 | !!---------------------------------------------------------------------- |
---|
55 | !! NEMO/TOP 3.3 , NEMO Consortium (2010) |
---|
56 | !! $Id: p4zmeso.F90 3295 2012-01-30 15:49:07Z cetlod $ |
---|
57 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
---|
58 | !!---------------------------------------------------------------------- |
---|
59 | |
---|
60 | CONTAINS |
---|
61 | |
---|
62 | SUBROUTINE p4z_meso( kt, jnt ) |
---|
63 | !!--------------------------------------------------------------------- |
---|
64 | !! *** ROUTINE p4z_meso *** |
---|
65 | !! |
---|
66 | !! ** Purpose : Compute the sources/sinks for mesozooplankton |
---|
67 | !! |
---|
68 | !! ** Method : - ??? |
---|
69 | !!--------------------------------------------------------------------- |
---|
70 | INTEGER, INTENT(in) :: kt, jnt ! ocean time step |
---|
71 | INTEGER :: ji, jj, jk |
---|
72 | REAL(wp) :: zcompadi, zcompaph, zcompapoc, zcompaz, zcompam |
---|
73 | REAL(wp) :: zgraze2 , zdenom, zdenom2, zncratio |
---|
74 | REAL(wp) :: zfact , zstep, zfood, zfoodlim |
---|
75 | REAL(wp) :: zepshert, zepsherv, zgrarsig, zgraztot, zgraztotf |
---|
76 | REAL(wp) :: zgrarem2, zgrafer2, zgrapoc2, zprcaca, zmortz2, zgrasrat |
---|
77 | #if defined key_kriest |
---|
78 | REAL znumpoc |
---|
79 | #endif |
---|
80 | REAL(wp) :: zrespz2, ztortz2, zgrazd, zgrazz, zgrazpof |
---|
81 | REAL(wp) :: zgrazn, zgrazpoc, zgraznf, zgrazf |
---|
82 | REAL(wp) :: zgrazfff, zgrazffe |
---|
83 | REAL(wp) :: zrfact2 |
---|
84 | REAL(wp), POINTER, DIMENSION(:,:,:) :: zgrazing |
---|
85 | CHARACTER (len=25) :: charout |
---|
86 | !!--------------------------------------------------------------------- |
---|
87 | ! |
---|
88 | IF( nn_timing == 1 ) CALL timing_start('p4z_meso') |
---|
89 | ! |
---|
90 | IF( ln_diatrc .AND. lk_iomput ) CALL wrk_alloc( jpi, jpj, jpk, zgrazing ) |
---|
91 | ! |
---|
92 | DO jk = 1, jpkm1 |
---|
93 | DO jj = 1, jpj |
---|
94 | DO ji = 1, jpi |
---|
95 | zcompam = MAX( ( trn(ji,jj,jk,jpmes) - 1.e-8 ), 0.e0 ) |
---|
96 | # if defined key_degrad |
---|
97 | zstep = xstep * facvol(ji,jj,jk) |
---|
98 | # else |
---|
99 | zstep = xstep |
---|
100 | # endif |
---|
101 | zfact = zstep * tgfunc(ji,jj,jk) * zcompam |
---|
102 | |
---|
103 | ! Respiration rates of both zooplankton |
---|
104 | ! ------------------------------------- |
---|
105 | zrespz2 = resrat2 * zfact * trn(ji,jj,jk,jpmes) / ( xkmort + trn(ji,jj,jk,jpmes) ) & |
---|
106 | & + resrat2 * zfact * 3. * nitrfac(ji,jj,jk) |
---|
107 | |
---|
108 | ! Zooplankton mortality. A square function has been selected with |
---|
109 | ! no real reason except that it seems to be more stable and may mimic predation |
---|
110 | ! --------------------------------------------------------------- |
---|
111 | ztortz2 = mzrat2 * 1.e6 * zfact * trn(ji,jj,jk,jpmes) |
---|
112 | ! |
---|
113 | |
---|
114 | zcompadi = MAX( ( trn(ji,jj,jk,jpdia) - xthresh2dia ), 0.e0 ) |
---|
115 | zcompaz = MAX( ( trn(ji,jj,jk,jpzoo) - xthresh2zoo ), 0.e0 ) |
---|
116 | zcompaph = MAX( ( trn(ji,jj,jk,jpphy) - xthresh2phy ), 0.e0 ) |
---|
117 | zcompapoc = MAX( ( trn(ji,jj,jk,jppoc) - xthresh2poc ), 0.e0 ) |
---|
118 | |
---|
119 | zfood = xprefc * zcompadi + xprefz * zcompaz + xprefp * zcompaph + xprefpoc * zcompapoc |
---|
120 | zfoodlim = MAX( 0., zfood - MIN( 0.5 * zfood , xthresh2 ) ) |
---|
121 | zdenom = zfoodlim / ( xkgraz2 + zfoodlim ) |
---|
122 | zdenom2 = zdenom / ( zfood + rtrn ) |
---|
123 | zgraze2 = grazrat2 * zstep * tgfunc2(ji,jj,jk) * trn(ji,jj,jk,jpmes) |
---|
124 | |
---|
125 | zgrazd = zgraze2 * xprefc * zcompadi * zdenom2 |
---|
126 | zgrazz = zgraze2 * xprefz * zcompaz * zdenom2 |
---|
127 | zgrazn = zgraze2 * xprefp * zcompaph * zdenom2 |
---|
128 | zgrazpoc = zgraze2 * xprefpoc * zcompapoc * zdenom2 |
---|
129 | |
---|
130 | zgraznf = zgrazn * trn(ji,jj,jk,jpnfe) / ( trn(ji,jj,jk,jpphy) + rtrn) |
---|
131 | zgrazf = zgrazd * trn(ji,jj,jk,jpdfe) / ( trn(ji,jj,jk,jpdia) + rtrn) |
---|
132 | zgrazpof = zgrazpoc * trn(ji,jj,jk,jpsfe) / ( trn(ji,jj,jk,jppoc) + rtrn) |
---|
133 | |
---|
134 | ! Mesozooplankton flux feeding on GOC |
---|
135 | ! ---------------------------------- |
---|
136 | # if ! defined key_kriest |
---|
137 | zgrazffe = grazflux * zstep * wsbio4(ji,jj,jk) & |
---|
138 | & * tgfunc2(ji,jj,jk) * trn(ji,jj,jk,jpgoc) * trn(ji,jj,jk,jpmes) |
---|
139 | zgrazfff = zgrazffe * trn(ji,jj,jk,jpbfe) / (trn(ji,jj,jk,jpgoc) + rtrn) |
---|
140 | # else |
---|
141 | zgrazffe = grazflux * zstep * wsbio3(ji,jj,jk) & |
---|
142 | zgrazfff = zgrazffe * trn(ji,jj,jk,jpsfe) / (trn(ji,jj,jk,jppoc) + rtrn) |
---|
143 | # endif |
---|
144 | ! |
---|
145 | zgraztot = zgrazd + zgrazz + zgrazn + zgrazpoc + zgrazffe |
---|
146 | zgraztotf = zgrazf + zgraznf + zgrazz * ferat3 + zgrazpof + zgrazfff |
---|
147 | |
---|
148 | ! Total grazing ( grazing by microzoo is already computed in p4zmicro ) |
---|
149 | IF( ln_diatrc .AND. lk_iomput ) zgrazing(ji,jj,jk) = zgraztot |
---|
150 | |
---|
151 | ! Mesozooplankton efficiency |
---|
152 | ! -------------------------- |
---|
153 | zgrasrat = zgraztotf / ( zgraztot + rtrn ) |
---|
154 | zncratio = ( xprefc * zcompadi * quotad(ji,jj,jk) & |
---|
155 | & + xprefp * zcompaph * quotan(ji,jj,jk) & |
---|
156 | & + xprefz * zcompaz & |
---|
157 | & + xprefpoc * zcompapoc ) / ( zfood + rtrn ) |
---|
158 | zepshert = epsher2 * MIN( 1., zncratio ) |
---|
159 | zepsherv = zepshert * MIN( 1., zgrasrat / ferat3 ) |
---|
160 | zgrarem2 = zgraztot * ( 1. - zepsherv - unass2 ) |
---|
161 | zgrafer2 = zgraztot * MAX( 0. , ( 1. - unass2 ) * zgrasrat - ferat3 * zepshert ) |
---|
162 | zgrapoc2 = zgraztot * unass2 |
---|
163 | |
---|
164 | ! Update the arrays TRA which contain the biological sources and sinks |
---|
165 | zgrarsig = zgrarem2 * sigma2 |
---|
166 | tra(ji,jj,jk,jppo4) = tra(ji,jj,jk,jppo4) + zgrarsig |
---|
167 | tra(ji,jj,jk,jpnh4) = tra(ji,jj,jk,jpnh4) + zgrarsig |
---|
168 | tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) + zgrarem2 - zgrarsig |
---|
169 | tra(ji,jj,jk,jpoxy) = tra(ji,jj,jk,jpoxy) - o2ut * zgrarsig |
---|
170 | tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) + zgrafer2 |
---|
171 | tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) + zgrarsig |
---|
172 | tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) + rno3 * zgrarsig |
---|
173 | #if defined key_kriest |
---|
174 | tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) + zgrapoc2 |
---|
175 | tra(ji,jj,jk,jpnum) = tra(ji,jj,jk,jpnum) + zgrapoc2 * xkr_dmeso |
---|
176 | tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) + zgraztotf * unass2 |
---|
177 | #else |
---|
178 | tra(ji,jj,jk,jpgoc) = tra(ji,jj,jk,jpgoc) + zgrapoc2 |
---|
179 | tra(ji,jj,jk,jpbfe) = tra(ji,jj,jk,jpbfe) + zgraztotf * unass2 |
---|
180 | #endif |
---|
181 | zmortz2 = ztortz2 + zrespz2 |
---|
182 | tra(ji,jj,jk,jpmes) = tra(ji,jj,jk,jpmes) - zmortz2 + zepsherv * zgraztot |
---|
183 | tra(ji,jj,jk,jpdia) = tra(ji,jj,jk,jpdia) - zgrazd |
---|
184 | tra(ji,jj,jk,jpzoo) = tra(ji,jj,jk,jpzoo) - zgrazz |
---|
185 | tra(ji,jj,jk,jpphy) = tra(ji,jj,jk,jpphy) - zgrazn |
---|
186 | tra(ji,jj,jk,jpnch) = tra(ji,jj,jk,jpnch) - zgrazn * trn(ji,jj,jk,jpnch) / ( trn(ji,jj,jk,jpphy) + rtrn ) |
---|
187 | tra(ji,jj,jk,jpdch) = tra(ji,jj,jk,jpdch) - zgrazd * trn(ji,jj,jk,jpdch) / ( trn(ji,jj,jk,jpdia) + rtrn ) |
---|
188 | tra(ji,jj,jk,jpdsi) = tra(ji,jj,jk,jpdsi) - zgrazd * trn(ji,jj,jk,jpdsi) / ( trn(ji,jj,jk,jpdia) + rtrn ) |
---|
189 | tra(ji,jj,jk,jpgsi) = tra(ji,jj,jk,jpgsi) + zgrazd * trn(ji,jj,jk,jpdsi) / ( trn(ji,jj,jk,jpdia) + rtrn ) |
---|
190 | tra(ji,jj,jk,jpnfe) = tra(ji,jj,jk,jpnfe) - zgraznf |
---|
191 | tra(ji,jj,jk,jpdfe) = tra(ji,jj,jk,jpdfe) - zgrazf |
---|
192 | |
---|
193 | zprcaca = xfracal(ji,jj,jk) * zgrazn |
---|
194 | ! calcite production |
---|
195 | prodcal(ji,jj,jk) = prodcal(ji,jj,jk) + zprcaca ! prodcal=prodcal(nanophy)+prodcal(microzoo)+prodcal(mesozoo) |
---|
196 | ! |
---|
197 | zprcaca = part2 * zprcaca |
---|
198 | tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) - zprcaca |
---|
199 | tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) - 2. * zprcaca |
---|
200 | tra(ji,jj,jk,jpcal) = tra(ji,jj,jk,jpcal) + zprcaca |
---|
201 | #if defined key_kriest |
---|
202 | znumpoc = trn(ji,jj,jk,jpnum) / ( trn(ji,jj,jk,jppoc) + rtrn ) |
---|
203 | tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) + zmortz2 - zgrazpoc - zgrazffe |
---|
204 | tra(ji,jj,jk,jpnum) = tra(ji,jj,jk,jpnum) - zgrazpoc * znumpoc & |
---|
205 | & + zmortz2 * xkr_dmeso - zgrazffe * znumpoc * wsbio4(ji,jj,jk) / ( wsbio3(ji,jj,jk) + rtrn ) |
---|
206 | tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) + ferat3 * zmortz2 - zgrazfff - zgrazpof |
---|
207 | #else |
---|
208 | tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) - zgrazpoc |
---|
209 | tra(ji,jj,jk,jpgoc) = tra(ji,jj,jk,jpgoc) + zmortz2 - zgrazffe |
---|
210 | tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) - zgrazpof |
---|
211 | tra(ji,jj,jk,jpbfe) = tra(ji,jj,jk,jpbfe) + ferat3 * zmortz2 - zgrazfff |
---|
212 | #endif |
---|
213 | |
---|
214 | END DO |
---|
215 | END DO |
---|
216 | END DO |
---|
217 | ! |
---|
218 | IF( ln_diatrc .AND. lk_iomput .AND. jnt == nrdttrc ) THEN |
---|
219 | zrfact2 = 1.e3 * rfact2r |
---|
220 | CALL iom_put( "GRAZ2", zgrazing(:,:,:) * zrfact2 * tmask(:,:,:) ) ! Total grazing of phyto by zooplankton |
---|
221 | CALL iom_put( "PCAL" , prodcal(:,:,:) * zrfact2 * tmask(:,:,:) ) ! Calcite production |
---|
222 | ENDIF |
---|
223 | ! |
---|
224 | IF(ln_ctl) THEN ! print mean trends (used for debugging) |
---|
225 | WRITE(charout, FMT="('meso')") |
---|
226 | CALL prt_ctl_trc_info(charout) |
---|
227 | CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm) |
---|
228 | ENDIF |
---|
229 | ! |
---|
230 | IF( ln_diatrc .AND. lk_iomput ) CALL wrk_dealloc( jpi, jpj, jpk, zgrazing ) |
---|
231 | ! |
---|
232 | IF( nn_timing == 1 ) CALL timing_stop('p4z_meso') |
---|
233 | ! |
---|
234 | END SUBROUTINE p4z_meso |
---|
235 | |
---|
236 | SUBROUTINE p4z_meso_init |
---|
237 | |
---|
238 | !!---------------------------------------------------------------------- |
---|
239 | !! *** ROUTINE p4z_meso_init *** |
---|
240 | !! |
---|
241 | !! ** Purpose : Initialization of mesozooplankton parameters |
---|
242 | !! |
---|
243 | !! ** Method : Read the nampismes namelist and check the parameters |
---|
244 | !! called at the first timestep (nittrc000) |
---|
245 | !! |
---|
246 | !! ** input : Namelist nampismes |
---|
247 | !! |
---|
248 | !!---------------------------------------------------------------------- |
---|
249 | |
---|
250 | NAMELIST/nampismes/ part2, grazrat2, resrat2, mzrat2, xprefc, xprefp, xprefz, & |
---|
251 | & xprefpoc, xthresh2dia, xthresh2phy, xthresh2zoo, xthresh2poc, & |
---|
252 | & xthresh2, xkgraz2, epsher2, sigma2, unass2, grazflux |
---|
253 | |
---|
254 | REWIND( numnatp ) ! read numnatp |
---|
255 | READ ( numnatp, nampismes ) |
---|
256 | |
---|
257 | |
---|
258 | IF(lwp) THEN ! control print |
---|
259 | WRITE(numout,*) ' ' |
---|
260 | WRITE(numout,*) ' Namelist parameters for mesozooplankton, nampismes' |
---|
261 | WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~' |
---|
262 | WRITE(numout,*) ' part of calcite not dissolved in mesozoo guts part2 =', part2 |
---|
263 | WRITE(numout,*) ' mesozoo preference for phyto xprefc =', xprefc |
---|
264 | WRITE(numout,*) ' mesozoo preference for POC xprefp =', xprefp |
---|
265 | WRITE(numout,*) ' mesozoo preference for zoo xprefz =', xprefz |
---|
266 | WRITE(numout,*) ' mesozoo preference for poc xprefpoc =', xprefpoc |
---|
267 | WRITE(numout,*) ' microzoo feeding threshold for mesozoo xthresh2zoo =', xthresh2zoo |
---|
268 | WRITE(numout,*) ' diatoms feeding threshold for mesozoo xthresh2dia =', xthresh2dia |
---|
269 | WRITE(numout,*) ' nanophyto feeding threshold for mesozoo xthresh2phy =', xthresh2phy |
---|
270 | WRITE(numout,*) ' poc feeding threshold for mesozoo xthresh2poc =', xthresh2poc |
---|
271 | WRITE(numout,*) ' feeding threshold for mesozooplankton xthresh2 =', xthresh2 |
---|
272 | WRITE(numout,*) ' exsudation rate of mesozooplankton resrat2 =', resrat2 |
---|
273 | WRITE(numout,*) ' mesozooplankton mortality rate mzrat2 =', mzrat2 |
---|
274 | WRITE(numout,*) ' maximal mesozoo grazing rate grazrat2 =', grazrat2 |
---|
275 | WRITE(numout,*) ' mesozoo flux feeding rate grazflux =', grazflux |
---|
276 | WRITE(numout,*) ' non assimilated fraction of P by mesozoo unass2 =', unass2 |
---|
277 | WRITE(numout,*) ' Efficicency of Mesozoo growth epsher2 =', epsher2 |
---|
278 | WRITE(numout,*) ' Fraction of mesozoo excretion as DOM sigma2 =', sigma2 |
---|
279 | WRITE(numout,*) ' half sturation constant for grazing 2 xkgraz2 =', xkgraz2 |
---|
280 | ENDIF |
---|
281 | |
---|
282 | |
---|
283 | END SUBROUTINE p4z_meso_init |
---|
284 | |
---|
285 | |
---|
286 | #else |
---|
287 | !!====================================================================== |
---|
288 | !! Dummy module : No PISCES bio-model |
---|
289 | !!====================================================================== |
---|
290 | CONTAINS |
---|
291 | SUBROUTINE p4z_meso ! Empty routine |
---|
292 | END SUBROUTINE p4z_meso |
---|
293 | #endif |
---|
294 | |
---|
295 | !!====================================================================== |
---|
296 | END MODULE p4zmeso |
---|