1 | MODULE icbini |
---|
2 | |
---|
3 | !!====================================================================== |
---|
4 | !! *** MODULE icbini *** |
---|
5 | !! Icebergs: initialise variables for iceberg tracking |
---|
6 | !!====================================================================== |
---|
7 | !! History : - ! 2010-01 (T. Martin & A. Adcroft) Original code |
---|
8 | !! 3.3 ! 2011-03 (G. Madec) Part conversion to NEMO form ; Removal of mapping from another grid |
---|
9 | !! - ! 2011-04 (S. Alderson) Split into separate modules ; Restore restart routines |
---|
10 | !! - ! 2011-05 (S. Alderson) generate_test_icebergs restored ; new forcing arrays with extra halo ; |
---|
11 | !! - ! north fold exchange arrays added |
---|
12 | !!---------------------------------------------------------------------- |
---|
13 | !!---------------------------------------------------------------------- |
---|
14 | !! icb_init : initialise icebergs |
---|
15 | !! icb_ini_gen : generate test icebergs |
---|
16 | !! icb_nam : read iceberg namelist |
---|
17 | !!---------------------------------------------------------------------- |
---|
18 | USE dom_oce ! ocean domain |
---|
19 | USE in_out_manager ! IO routines and numout in particular |
---|
20 | USE lib_mpp ! mpi library and lk_mpp in particular |
---|
21 | USE sbc_oce ! ocean: surface boundary condition |
---|
22 | USE iom ! IOM library |
---|
23 | USE fldread ! field read |
---|
24 | USE lbclnk ! lateral boundary condition - MPP link |
---|
25 | ! |
---|
26 | USE icb_oce ! define iceberg arrays |
---|
27 | USE icbutl ! iceberg utility routines |
---|
28 | USE icbrst ! iceberg restart routines |
---|
29 | USE icbtrj ! iceberg trajectory I/O routines |
---|
30 | USE icbdia ! iceberg budget routines |
---|
31 | |
---|
32 | IMPLICIT NONE |
---|
33 | PRIVATE |
---|
34 | |
---|
35 | PUBLIC icb_init ! routine called in nemogcm.F90 module |
---|
36 | |
---|
37 | CHARACTER(len=100) :: cn_dir = './' ! Root directory for location of icb files |
---|
38 | TYPE(FLD_N) :: sn_icb ! information about the calving file to be read |
---|
39 | |
---|
40 | !!---------------------------------------------------------------------- |
---|
41 | !! NEMO/OPA 3.3 , NEMO Consortium (2011) |
---|
42 | !! $Id:$ |
---|
43 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
---|
44 | !!---------------------------------------------------------------------- |
---|
45 | CONTAINS |
---|
46 | |
---|
47 | SUBROUTINE icb_init( pdt, kt ) |
---|
48 | !!---------------------------------------------------------------------- |
---|
49 | !! *** ROUTINE dom_init *** |
---|
50 | !! |
---|
51 | !! ** Purpose : iceberg initialization. |
---|
52 | !! |
---|
53 | !! ** Method : - blah blah |
---|
54 | !!---------------------------------------------------------------------- |
---|
55 | REAL(wp), INTENT(in) :: pdt ! iceberg time-step (rdt*nn_fsbc) |
---|
56 | INTEGER , INTENT(in) :: kt ! time step number |
---|
57 | ! |
---|
58 | INTEGER :: ji, jj, jn ! dummy loop indices |
---|
59 | INTEGER :: i1, i2, i3 ! local integers |
---|
60 | INTEGER :: ii, inum, ivar ! - - |
---|
61 | INTEGER :: istat1, istat2, istat3 ! - - |
---|
62 | CHARACTER(len=300) :: cl_sdist ! local character |
---|
63 | !!---------------------------------------------------------------------- |
---|
64 | ! |
---|
65 | CALL icb_nam ! Read and print namelist parameters |
---|
66 | ! |
---|
67 | IF( .NOT. ln_icebergs ) RETURN |
---|
68 | |
---|
69 | ! ! allocate gridded fields |
---|
70 | IF( icb_alloc() /= 0 ) CALL ctl_stop( 'STOP', 'icb_alloc : unable to allocate arrays' ) |
---|
71 | |
---|
72 | ! ! open ascii output file or files for iceberg status information |
---|
73 | ! ! note that we choose to do this on all processors since we cannot |
---|
74 | ! ! predict where icebergs will be ahead of time |
---|
75 | CALL ctl_opn( numicb, 'icebergs.stat', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, numout, lwp, narea ) |
---|
76 | |
---|
77 | ! set parameters (mostly from namelist) |
---|
78 | ! |
---|
79 | berg_dt = pdt |
---|
80 | first_width (:) = SQRT( rn_initial_mass(:) / ( rn_LoW_ratio * rn_rho_bergs * rn_initial_thickness(:) ) ) |
---|
81 | first_length(:) = rn_LoW_ratio * first_width(:) |
---|
82 | |
---|
83 | berg_grid%calving (:,:) = 0._wp |
---|
84 | berg_grid%calving_hflx (:,:) = 0._wp |
---|
85 | berg_grid%stored_heat (:,:) = 0._wp |
---|
86 | berg_grid%floating_melt(:,:) = 0._wp |
---|
87 | berg_grid%maxclass (:,:) = nclasses |
---|
88 | berg_grid%stored_ice (:,:,:) = 0._wp |
---|
89 | berg_grid%tmp (:,:) = 0._wp |
---|
90 | src_calving (:,:) = 0._wp |
---|
91 | src_calving_hflx (:,:) = 0._wp |
---|
92 | |
---|
93 | ! ! domain for icebergs |
---|
94 | IF( lk_mpp .AND. jpni == 1 ) CALL ctl_stop( 'icbinit: having ONE processor in x currently does not work' ) |
---|
95 | ! NB: the issue here is simply that cyclic east-west boundary condition have not been coded in mpp case |
---|
96 | ! for the north fold we work out which points communicate by asking |
---|
97 | ! lbc_lnk to pass processor number (valid even in single processor case) |
---|
98 | ! borrow src_calving arrays for this |
---|
99 | ! |
---|
100 | ! pack i and j together using a scaling of a power of 10 |
---|
101 | nicbpack = 10000 |
---|
102 | IF( jpiglo >= nicbpack ) CALL ctl_stop( 'icbini: processor index packing failure' ) |
---|
103 | nicbfldproc(:) = -1 |
---|
104 | |
---|
105 | DO jj = 1, jpj |
---|
106 | DO ji = 1, jpi |
---|
107 | src_calving_hflx(ji,jj) = narea |
---|
108 | src_calving (ji,jj) = nicbpack * mjg(jj) + mig(ji) |
---|
109 | END DO |
---|
110 | END DO |
---|
111 | CALL lbc_lnk( src_calving_hflx, 'T', 1._wp ) |
---|
112 | CALL lbc_lnk( src_calving , 'T', 1._wp ) |
---|
113 | |
---|
114 | ! work out interior of processor from exchange array |
---|
115 | ! first entry with narea for this processor is left hand interior index |
---|
116 | ! last entry is right hand interior index |
---|
117 | jj = jpj/2 |
---|
118 | nicbdi = -1 |
---|
119 | nicbei = -1 |
---|
120 | DO ji = 1, jpi |
---|
121 | i3 = INT( src_calving(ji,jj) ) |
---|
122 | i2 = INT( i3/nicbpack ) |
---|
123 | i1 = i3 - i2*nicbpack |
---|
124 | i3 = INT( src_calving_hflx(ji,jj) ) |
---|
125 | IF( i1 == mig(ji) .AND. i3 == narea ) THEN |
---|
126 | IF( nicbdi < 0 ) THEN ; nicbdi = ji |
---|
127 | ELSE ; nicbei = ji |
---|
128 | ENDIF |
---|
129 | ENDIF |
---|
130 | END DO |
---|
131 | ! |
---|
132 | ! repeat for j direction |
---|
133 | ji = jpi/2 |
---|
134 | nicbdj = -1 |
---|
135 | nicbej = -1 |
---|
136 | DO jj = 1, jpj |
---|
137 | i3 = INT( src_calving(ji,jj) ) |
---|
138 | i2 = INT( i3/nicbpack ) |
---|
139 | i1 = i3 - i2*nicbpack |
---|
140 | i3 = INT( src_calving_hflx(ji,jj) ) |
---|
141 | IF( i2 == mjg(jj) .AND. i3 == narea ) THEN |
---|
142 | IF( nicbdj < 0 ) THEN ; nicbdj = jj |
---|
143 | ELSE ; nicbej = jj |
---|
144 | ENDIF |
---|
145 | ENDIF |
---|
146 | END DO |
---|
147 | ! |
---|
148 | ! special for east-west boundary exchange we save the destination index |
---|
149 | i1 = MAX( nicbdi-1, 1) |
---|
150 | i3 = INT( src_calving(i1,jpj/2) ) |
---|
151 | jj = INT( i3/nicbpack ) |
---|
152 | ricb_left = REAL( i3 - nicbpack*jj, wp ) |
---|
153 | i1 = MIN( nicbei+1, jpi ) |
---|
154 | i3 = INT( src_calving(i1,jpj/2) ) |
---|
155 | jj = INT( i3/nicbpack ) |
---|
156 | ricb_right = REAL( i3 - nicbpack*jj, wp ) |
---|
157 | |
---|
158 | ! north fold |
---|
159 | IF( npolj > 0 ) THEN |
---|
160 | ! |
---|
161 | ! icebergs in row nicbej+1 get passed across fold |
---|
162 | nicbfldpts(:) = INT( src_calving(:,nicbej+1) ) |
---|
163 | nicbflddest(:) = INT( src_calving_hflx(:,nicbej+1) ) |
---|
164 | ! |
---|
165 | ! work out list of unique processors to talk to |
---|
166 | ! pack them into a fixed size array where empty slots are marked by a -1 |
---|
167 | DO ji = nicbdi, nicbei |
---|
168 | ii = nicbflddest(ji) |
---|
169 | DO jn = 1, jpni |
---|
170 | ! work along array until we find an empty slot |
---|
171 | IF( nicbfldproc(jn) == -1 ) THEN |
---|
172 | nicbfldproc(jn) = ii |
---|
173 | EXIT !!gm EXIT should be avoided: use DO WHILE expression instead |
---|
174 | ENDIF |
---|
175 | ! before we find an empty slot, we may find processor number is already here so we exit |
---|
176 | IF( nicbfldproc(jn) == ii ) EXIT |
---|
177 | END DO |
---|
178 | END DO |
---|
179 | ENDIF |
---|
180 | ! |
---|
181 | IF( nn_verbose_level > 0) THEN |
---|
182 | WRITE(numicb,*) 'processor ', narea |
---|
183 | WRITE(numicb,*) 'jpi, jpj ', jpi, jpj |
---|
184 | WRITE(numicb,*) 'nldi, nlei ', nldi, nlei |
---|
185 | WRITE(numicb,*) 'nldj, nlej ', nldj, nlej |
---|
186 | WRITE(numicb,*) 'berg i interior ', nicbdi, nicbei |
---|
187 | WRITE(numicb,*) 'berg j interior ', nicbdj, nicbej |
---|
188 | WRITE(numicb,*) 'berg left ', ricb_left |
---|
189 | WRITE(numicb,*) 'berg right ', ricb_right |
---|
190 | jj = jpj/2 |
---|
191 | WRITE(numicb,*) "central j line:" |
---|
192 | WRITE(numicb,*) "i processor" |
---|
193 | WRITE(numicb,*) (INT(src_calving_hflx(ji,jj)), ji=1,jpi) |
---|
194 | WRITE(numicb,*) "i point" |
---|
195 | WRITE(numicb,*) (INT(src_calving(ji,jj)), ji=1,jpi) |
---|
196 | ji = jpi/2 |
---|
197 | WRITE(numicb,*) "central i line:" |
---|
198 | WRITE(numicb,*) "j processor" |
---|
199 | WRITE(numicb,*) (INT(src_calving_hflx(ji,jj)), jj=1,jpj) |
---|
200 | WRITE(numicb,*) "j point" |
---|
201 | WRITE(numicb,*) (INT(src_calving(ji,jj)), jj=1,jpj) |
---|
202 | IF( npolj > 0 ) THEN |
---|
203 | WRITE(numicb,*) 'north fold destination points ' |
---|
204 | WRITE(numicb,*) nicbfldpts |
---|
205 | WRITE(numicb,*) 'north fold destination procs ' |
---|
206 | WRITE(numicb,*) nicbflddest |
---|
207 | ENDIF |
---|
208 | CALL flush(numicb) |
---|
209 | ENDIF |
---|
210 | |
---|
211 | src_calving (:,:) = 0._wp |
---|
212 | src_calving_hflx(:,:) = 0._wp |
---|
213 | |
---|
214 | ! assign each new iceberg with a unique number constructed from the processor number |
---|
215 | ! and incremented by the total number of processors |
---|
216 | num_bergs(:) = 0 |
---|
217 | num_bergs(1) = narea - jpnij |
---|
218 | |
---|
219 | ! when not generating test icebergs we need to setup calving file |
---|
220 | IF( nn_test_icebergs < 0 ) THEN |
---|
221 | ! |
---|
222 | ! maximum distribution class array does not change in time so read it once |
---|
223 | cl_sdist = TRIM( cn_dir )//TRIM( sn_icb%clname ) |
---|
224 | CALL iom_open ( cl_sdist, inum ) ! open file |
---|
225 | ivar = iom_varid( inum, 'maxclass', ldstop=.FALSE. ) |
---|
226 | IF( ivar > 0 ) THEN |
---|
227 | CALL iom_get ( inum, jpdom_data, 'maxclass', src_calving ) ! read the max distribution array |
---|
228 | berg_grid%maxclass(:,:) = INT( src_calving ) |
---|
229 | src_calving(:,:) = 0._wp |
---|
230 | ENDIF |
---|
231 | CALL iom_close( inum ) ! close file |
---|
232 | ! |
---|
233 | WRITE(numicb,*) |
---|
234 | WRITE(numicb,*) ' calving read in a file' |
---|
235 | ALLOCATE( sf_icb(1), STAT=istat1 ) ! Create sf_icb structure (calving) |
---|
236 | ALLOCATE( sf_icb(1)%fnow(jpi,jpj,1), STAT=istat2 ) |
---|
237 | ALLOCATE( sf_icb(1)%fdta(jpi,jpj,1,2), STAT=istat3 ) |
---|
238 | IF( istat1+istat2+istat3 > 0 ) THEN |
---|
239 | CALL ctl_stop( 'sbc_icb: unable to allocate sf_icb structure' ) ; RETURN |
---|
240 | ENDIF |
---|
241 | ! ! fill sf_icb with the namelist (sn_icb) and control print |
---|
242 | CALL fld_fill( sf_icb, (/ sn_icb /), cn_dir, 'icb_init', 'read calving data', 'namicb' ) |
---|
243 | ! |
---|
244 | ENDIF |
---|
245 | |
---|
246 | IF( .NOT.ln_rstart ) THEN |
---|
247 | IF( nn_test_icebergs > 0 ) CALL icb_ini_gen() |
---|
248 | ELSE |
---|
249 | IF( nn_test_icebergs > 0 ) THEN |
---|
250 | CALL icb_ini_gen() |
---|
251 | ELSE |
---|
252 | CALL icb_rst_read() |
---|
253 | l_restarted_bergs = .TRUE. |
---|
254 | ENDIF |
---|
255 | ENDIF |
---|
256 | ! |
---|
257 | IF( nn_sample_rate .GT. 0 ) CALL icb_trj_init( nitend ) |
---|
258 | ! |
---|
259 | CALL icb_dia_init() |
---|
260 | ! |
---|
261 | IF( nn_verbose_level >= 2 ) CALL icb_utl_print('icb_init, initial status', nit000-1) |
---|
262 | ! |
---|
263 | END SUBROUTINE icb_init |
---|
264 | |
---|
265 | SUBROUTINE icb_ini_gen() |
---|
266 | !!---------------------------------------------------------------------- |
---|
267 | !! *** ROUTINE icb_ini_gen *** |
---|
268 | !! |
---|
269 | !! ** Purpose : iceberg generation |
---|
270 | !! |
---|
271 | !! ** Method : - at each grid point of the test box supplied in the namelist |
---|
272 | !! generate an iceberg in one class determined by the value of |
---|
273 | !! parameter nn_test_icebergs |
---|
274 | !!---------------------------------------------------------------------- |
---|
275 | INTEGER :: ji, jj, ibergs |
---|
276 | TYPE(iceberg) :: localberg ! NOT a pointer but an actual local variable |
---|
277 | TYPE(point) :: localpt |
---|
278 | INTEGER :: iyr, imon, iday, ihr, imin, isec |
---|
279 | INTEGER :: iberg |
---|
280 | !!---------------------------------------------------------------------- |
---|
281 | |
---|
282 | ! For convenience |
---|
283 | iberg = nn_test_icebergs |
---|
284 | |
---|
285 | ! call get_date(Time, iyr, imon, iday, ihr, imin, isec) |
---|
286 | ! Convert nemo time variables from dom_oce into local versions |
---|
287 | iyr = nyear |
---|
288 | imon = nmonth |
---|
289 | iday = nday |
---|
290 | ihr = INT(nsec_day/3600) |
---|
291 | imin = INT((nsec_day-ihr*3600)/60) |
---|
292 | isec = nsec_day - ihr*3600 - imin*60 |
---|
293 | |
---|
294 | ! no overlap for icebergs since we want only one instance of each across the whole domain |
---|
295 | ! so restrict area of interest |
---|
296 | ! use tmask here because tmask_i has been doctored on one side of the north fold line |
---|
297 | |
---|
298 | DO jj = nicbdj, nicbej |
---|
299 | DO ji = nicbdi, nicbei |
---|
300 | IF( tmask(ji,jj,1) > 0._wp .AND. & |
---|
301 | rn_test_box(1) < glamt(ji,jj) .AND. glamt(ji,jj) < rn_test_box(2) .AND. & |
---|
302 | rn_test_box(3) < gphit(ji,jj) .AND. gphit(ji,jj) < rn_test_box(4) ) THEN |
---|
303 | localberg%mass_scaling = rn_mass_scaling(iberg) |
---|
304 | localpt%xi = REAL( mig(ji), wp ) |
---|
305 | localpt%yj = REAL( mjg(jj), wp ) |
---|
306 | localpt%lon = icb_utl_bilin(glamt, localpt%xi, localpt%yj, 'T', 0, 0 ) |
---|
307 | localpt%lat = icb_utl_bilin(gphit, localpt%xi, localpt%yj, 'T', 0, 0 ) |
---|
308 | localpt%mass = rn_initial_mass (iberg) |
---|
309 | localpt%thickness = rn_initial_thickness(iberg) |
---|
310 | localpt%width = first_width (iberg) |
---|
311 | localpt%length = first_length(iberg) |
---|
312 | localpt%year = iyr |
---|
313 | localpt%day = FLOAT(iday)+(FLOAT(ihr)+FLOAT(imin)/60._wp)/24._wp |
---|
314 | localpt%mass_of_bits = 0._wp |
---|
315 | localpt%heat_density = 0._wp |
---|
316 | localpt%uvel = 0._wp |
---|
317 | localpt%vvel = 0._wp |
---|
318 | CALL icb_utl_incr() |
---|
319 | localberg%number(:) = num_bergs(:) |
---|
320 | call icb_utl_add(localberg, localpt) |
---|
321 | ENDIF |
---|
322 | END DO |
---|
323 | END DO |
---|
324 | ! |
---|
325 | ibergs = icb_utl_count() |
---|
326 | IF( lk_mpp ) CALL mpp_sum(ibergs) |
---|
327 | WRITE(numicb,'(a,i6,a)') 'diamonds, icb_ini_gen: ',ibergs,' were generated' |
---|
328 | ! |
---|
329 | END SUBROUTINE icb_ini_gen |
---|
330 | |
---|
331 | SUBROUTINE icb_nam |
---|
332 | !!---------------------------------------------------------------------- |
---|
333 | !! *** ROUTINE icb_nam *** |
---|
334 | !! |
---|
335 | !! ** Purpose : read iceberg namelist and print the variables. |
---|
336 | !! |
---|
337 | !! ** input : - namberg namelist |
---|
338 | !!---------------------------------------------------------------------- |
---|
339 | INTEGER :: jn ! dummy loop indices |
---|
340 | REAL(wp) :: zfact ! local scalar |
---|
341 | ! |
---|
342 | NAMELIST/namberg/ ln_icebergs , ln_bergdia , nn_sample_rate , rn_initial_mass , & |
---|
343 | & rn_distribution, rn_mass_scaling, rn_initial_thickness, nn_verbose_write , & |
---|
344 | & rn_rho_bergs , rn_LoW_ratio , nn_verbose_level , ln_operator_splitting, & |
---|
345 | & rn_bits_erosion_fraction , rn_sicn_shift , ln_passive_mode , & |
---|
346 | & ln_time_average_weight , nn_test_icebergs , rn_test_box , & |
---|
347 | & rn_speed_limit , cn_dir, sn_icb |
---|
348 | !!---------------------------------------------------------------------- |
---|
349 | |
---|
350 | ! (NB: frequency positive => hours, negative => months) |
---|
351 | ! ! file ! frequency ! variable ! time intep ! clim ! 'yearly' or ! weights ! rotation ! |
---|
352 | ! ! name ! (hours) ! name ! (T/F) ! (T/F) ! 'monthly' ! filename ! pairs ! |
---|
353 | sn_icb = FLD_N( 'calving' , -1 , 'calving' , .TRUE. , .TRUE. , 'yearly' , '' , '' ) |
---|
354 | |
---|
355 | REWIND( numnam ) ! Namelist namrun : iceberg parameters |
---|
356 | READ ( numnam, namberg ) |
---|
357 | |
---|
358 | !!gm bug here in mpp : the return instruction will be done only on the 1st processor (lwp=True) |
---|
359 | ! IF( .NOT. ln_icebergs .AND. lwp ) THEN |
---|
360 | ! WRITE(numout,*) |
---|
361 | ! WRITE(numout,*) 'icb_nam : iceberg initialization through namberg namelist read' |
---|
362 | ! WRITE(numout,*) '~~~~~~~~ ' |
---|
363 | ! WRITE(numout,*) 'NO icebergs used' |
---|
364 | ! RETURN |
---|
365 | ! ENDIF |
---|
366 | !!gm solution: |
---|
367 | |
---|
368 | IF( .NOT. ln_icebergs ) THEN ! no icebergs |
---|
369 | IF(lwp) THEN |
---|
370 | WRITE(numout,*) |
---|
371 | WRITE(numout,*) 'icb_nam : ln_icebergs = F , NO icebergs used' |
---|
372 | WRITE(numout,*) '~~~~~~~~ ' |
---|
373 | ENDIF |
---|
374 | RETURN |
---|
375 | ENDIF |
---|
376 | !!gm end |
---|
377 | |
---|
378 | IF( nn_test_icebergs > nclasses ) THEN |
---|
379 | IF(lwp) WRITE(numout,*) 'Resetting nn_test_icebergs to ', nclasses |
---|
380 | nn_test_icebergs = nclasses |
---|
381 | ENDIF |
---|
382 | |
---|
383 | zfact = SUM( rn_distribution ) |
---|
384 | IF( zfact < 1._wp ) THEN |
---|
385 | IF( zfact <= 0._wp ) THEN |
---|
386 | CALL ctl_stop( 'icb_nam: sum of berg distribution equal to zero' ) |
---|
387 | ELSE |
---|
388 | rn_distribution(:) = rn_distribution(:) / zfact |
---|
389 | CALL ctl_warn( 'icb_nam: sum of berg input distribution not equal to one and so RESCALED' ) |
---|
390 | ENDIF |
---|
391 | ENDIF |
---|
392 | |
---|
393 | IF(lwp) THEN ! control print |
---|
394 | WRITE(numout,*) |
---|
395 | WRITE(numout,*) 'icb_nam : iceberg initialization through namberg namelist read' |
---|
396 | WRITE(numout,*) '~~~~~~~~ ' |
---|
397 | WRITE(numout,*) ' Calculate budgets ln_bergdia = ', ln_bergdia |
---|
398 | WRITE(numout,*) ' Period between sampling of position for trajectory storage nn_sample_rate = ', nn_sample_rate |
---|
399 | WRITE(numout,*) ' Mass thresholds between iceberg classes (kg) rn_initial_mass =' |
---|
400 | DO jn=1,nclasses |
---|
401 | WRITE(numout,'(a,f15.2)') ' ',rn_initial_mass(jn) |
---|
402 | ENDDO |
---|
403 | WRITE(numout,*) ' Fraction of calving to apply to this class (non-dim) rn_distribution =' |
---|
404 | DO jn = 1, nclasses |
---|
405 | WRITE(numout,'(a,f10.2)') ' ',rn_distribution(jn) |
---|
406 | END DO |
---|
407 | WRITE(numout,*) ' Ratio between effective and real iceberg mass (non-dim) rn_mass_scaling = ' |
---|
408 | DO jn = 1, nclasses |
---|
409 | WRITE(numout,'(a,f10.2)') ' ',rn_mass_scaling(jn) |
---|
410 | END DO |
---|
411 | WRITE(numout,*) ' Total thickness of newly calved bergs (m) rn_initial_thickness = ' |
---|
412 | DO jn = 1, nclasses |
---|
413 | WRITE(numout,'(a,f10.2)') ' ',rn_initial_thickness(jn) |
---|
414 | END DO |
---|
415 | WRITE(numout,*) ' Timesteps between verbose messages nn_verbose_write = ', nn_verbose_write |
---|
416 | |
---|
417 | WRITE(numout,*) ' Density of icebergs rn_rho_bergs = ', rn_rho_bergs |
---|
418 | WRITE(numout,*) ' Initial ratio L/W for newly calved icebergs rn_LoW_ratio = ', rn_LoW_ratio |
---|
419 | WRITE(numout,*) ' Turn on more verbose output level = ', nn_verbose_level |
---|
420 | WRITE(numout,*) ' Use first order operator splitting for thermodynamics ', & |
---|
421 | & 'use_operator_splitting = ', ln_operator_splitting |
---|
422 | WRITE(numout,*) ' Fraction of erosion melt flux to divert to bergy bits ', & |
---|
423 | & 'bits_erosion_fraction = ', rn_bits_erosion_fraction |
---|
424 | |
---|
425 | WRITE(numout,*) ' Shift of sea-ice concentration in erosion flux modulation ', & |
---|
426 | & '(0<sicn_shift<1) rn_sicn_shift = ', rn_sicn_shift |
---|
427 | WRITE(numout,*) ' Do not add freshwater flux from icebergs to ocean ', & |
---|
428 | & ' passive_mode = ', ln_passive_mode |
---|
429 | WRITE(numout,*) ' Time average the weight on the ocean time_average_weight = ', ln_time_average_weight |
---|
430 | WRITE(numout,*) ' Create icebergs in absence of a restart file nn_test_icebergs = ', nn_test_icebergs |
---|
431 | WRITE(numout,*) ' in lon/lat box = ', rn_test_box |
---|
432 | WRITE(numout,*) ' CFL speed limit for a berg speed_limit = ', rn_speed_limit |
---|
433 | WRITE(numout,*) ' Writing Iceberg status information to icebergs.stat file ' |
---|
434 | ENDIF |
---|
435 | ! |
---|
436 | END SUBROUTINE icb_nam |
---|
437 | |
---|
438 | !!====================================================================== |
---|
439 | |
---|
440 | END MODULE icbini |
---|