New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traadv_muscl2.F90 in branches/2011/dev_r2802_TOP_substepping/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: branches/2011/dev_r2802_TOP_substepping/NEMOGCM/NEMO/OPA_SRC/TRA/traadv_muscl2.F90 @ 2910

Last change on this file since 2910 was 2910, checked in by kpedwards, 13 years ago

Updates from Christian - use kit000 in local TRA code; plus a few style corrections in TRC code.
  • Property svn:keywords set to Id
File size: 15.1 KB
Line 
1MODULE traadv_muscl2
2   !!======================================================================
3   !!                       ***  MODULE  traadv_muscl2  ***
4   !! Ocean  tracers:  horizontal & vertical advective trend
5   !!======================================================================
6   !! History :  1.0  !  2002-06  (G. Madec) from traadv_muscl
7   !!            3.2  !  2010-05  (C. Ethe, G. Madec)  merge TRC-TRA + switch from velocity to transport
8   !!----------------------------------------------------------------------
9
10   !!----------------------------------------------------------------------
11   !!   tra_adv_muscl2 : update the tracer trend with the horizontal
12   !!                    and vertical advection trends using MUSCL2 scheme
13   !!----------------------------------------------------------------------
14   USE oce             ! ocean dynamics and active tracers
15   USE dom_oce         ! ocean space and time domain
16   USE trdmod_oce      ! tracers trends
17   USE trdtra          ! tracers trends
18   USE in_out_manager  ! I/O manager
19   USE dynspg_oce      ! choice/control of key cpp for surface pressure gradient
20   USE trabbl          ! tracers: bottom boundary layer
21   USE lib_mpp         ! distribued memory computing
22   USE lbclnk          ! ocean lateral boundary condition (or mpp link)
23   USE diaptr          ! poleward transport diagnostics
24   USE trc_oce         ! share passive tracers/Ocean variables
25
26
27   IMPLICIT NONE
28   PRIVATE
29
30   PUBLIC   tra_adv_muscl2        ! routine called by step.F90
31
32   LOGICAL  :: l_trd       ! flag to compute trends
33
34   !! * Substitutions
35#  include "domzgr_substitute.h90"
36#  include "vectopt_loop_substitute.h90"
37   !!----------------------------------------------------------------------
38   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
39   !! $Id$
40   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
41   !!----------------------------------------------------------------------
42CONTAINS
43
44   SUBROUTINE tra_adv_muscl2( kt, kit000, cdtype, p2dt, pun, pvn, pwn,      &
45      &                                         ptb, ptn, pta, kjpt )
46      !!----------------------------------------------------------------------
47      !!                   ***  ROUTINE tra_adv_muscl2  ***
48      !!
49      !! ** Purpose :   Compute the now trend due to total advection of T and
50      !!      S using a MUSCL scheme (Monotone Upstream-centered Scheme for
51      !!      Conservation Laws) and add it to the general tracer trend.
52      !!
53      !! ** Method  : MUSCL scheme plus centered scheme at ocean boundaries
54      !!
55      !! ** Action  : - update (pta) with the now advective tracer trends
56      !!              - save trends
57      !!
58      !! References : Estubier, A., and M. Levy, Notes Techn. Pole de Modelisation
59      !!              IPSL, Sept. 2000 (http://www.lodyc.jussieu.fr/opa)
60      !!----------------------------------------------------------------------
61      USE wrk_nemo, ONLY:   wrk_in_use, wrk_not_released
62      USE oce     , ONLY:   zwx   => ua       , zwy   => va         ! (ua,va) used as 3D workspace
63      USE wrk_nemo, ONLY:   zslpx => wrk_3d_1 , zslpy => wrk_3d_2   ! 3D workspace
64      !!
65      INTEGER                              , INTENT(in   ) ::   kt              ! ocean time-step index
66      INTEGER                              , INTENT(in   ) ::   kit000          ! first time step index
67      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype          ! =TRA or TRC (tracer indicator)
68      INTEGER                              , INTENT(in   ) ::   kjpt            ! number of tracers
69      REAL(wp), DIMENSION(        jpk     ), INTENT(in   ) ::   p2dt            ! vertical profile of tracer time-step
70      REAL(wp), DIMENSION(jpi,jpj,jpk     ), INTENT(in   ) ::   pun, pvn, pwn   ! 3 ocean velocity components
71      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptb, ptn        ! before & now tracer fields
72      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pta             ! tracer trend
73      !!
74      INTEGER  ::   ji, jj, jk, jn   ! dummy loop indices
75      REAL(wp) ::   zu, z0u, zzwx, zw         ! local scalars
76      REAL(wp) ::   zv, z0v, zzwy, z0w        !   -      -
77      REAL(wp) ::   ztra, zbtr, zdt, zalpha   !   -      -
78      !!----------------------------------------------------------------------
79
80      IF( wrk_in_use(3, 1,2) ) THEN
81         CALL ctl_stop('tra_adv_muscl2: requested workspace arrays are unavailable')   ;   RETURN
82      ENDIF
83
84      IF( kt == kit000 )  THEN
85         IF(lwp) WRITE(numout,*)
86         IF(lwp) WRITE(numout,*) 'tra_adv_muscl2 : MUSCL2 advection scheme on ', cdtype
87         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~~~~'
88         !
89         l_trd = .FALSE.
90         IF( ( cdtype == 'TRA' .AND. l_trdtra ) .OR. ( cdtype == 'TRC' .AND. l_trdtrc ) )   l_trd = .TRUE.
91      ENDIF
92
93      !                                                          ! ===========
94      DO jn = 1, kjpt                                            ! tracer loop
95         !                                                       ! ===========
96         ! I. Horizontal advective fluxes
97         ! ------------------------------
98         ! first guess of the slopes
99         zwx(:,:,jpk) = 0.e0   ;   zwy(:,:,jpk) = 0.e0        ! bottom values
100         ! interior values
101         DO jk = 1, jpkm1
102            DO jj = 1, jpjm1     
103               DO ji = 1, fs_jpim1   ! vector opt.
104                  zwx(ji,jj,jk) = umask(ji,jj,jk) * ( ptb(ji+1,jj,jk,jn) - ptb(ji,jj,jk,jn) )
105                  zwy(ji,jj,jk) = vmask(ji,jj,jk) * ( ptb(ji,jj+1,jk,jn) - ptb(ji,jj,jk,jn) )
106               END DO
107           END DO
108         END DO
109         !
110         CALL lbc_lnk( zwx, 'U', -1. )                        ! lateral boundary conditions on zwx, zwy   (changed sign)
111         CALL lbc_lnk( zwy, 'V', -1. )
112         !                                             !-- Slopes of tracer
113         zslpx(:,:,jpk) = 0.e0   ;   zslpy(:,:,jpk) = 0.e0    ! bottom values
114         DO jk = 1, jpkm1                                     ! interior values
115            DO jj = 2, jpj
116               DO ji = fs_2, jpi   ! vector opt.
117                  zslpx(ji,jj,jk) =                    ( zwx(ji,jj,jk) + zwx(ji-1,jj  ,jk) )   &
118                     &            * ( 0.25 + SIGN( 0.25, zwx(ji,jj,jk) * zwx(ji-1,jj  ,jk) ) )
119                  zslpy(ji,jj,jk) =                    ( zwy(ji,jj,jk) + zwy(ji  ,jj-1,jk) )   &
120                     &            * ( 0.25 + SIGN( 0.25, zwy(ji,jj,jk) * zwy(ji  ,jj-1,jk) ) )
121               END DO
122            END DO
123         END DO
124         !
125         DO jk = 1, jpkm1                                     ! Slopes limitation
126            DO jj = 2, jpj
127               DO ji = fs_2, jpi   ! vector opt.
128                  zslpx(ji,jj,jk) = SIGN( 1., zslpx(ji,jj,jk) ) * MIN(    ABS( zslpx(ji  ,jj,jk) ),   &
129                     &                                                 2.*ABS( zwx  (ji-1,jj,jk) ),   &
130                     &                                                 2.*ABS( zwx  (ji  ,jj,jk) ) )
131                  zslpy(ji,jj,jk) = SIGN( 1., zslpy(ji,jj,jk) ) * MIN(    ABS( zslpy(ji,jj  ,jk) ),   &
132                     &                                                 2.*ABS( zwy  (ji,jj-1,jk) ),   &
133                     &                                                 2.*ABS( zwy  (ji,jj  ,jk) ) )
134               END DO
135           END DO
136         END DO             ! interior values
137
138        !                                             !-- MUSCL horizontal advective fluxes
139         DO jk = 1, jpkm1                                     ! interior values
140            zdt  = p2dt(jk)
141            DO jj = 2, jpjm1
142               DO ji = fs_2, fs_jpim1   ! vector opt.
143                  ! MUSCL fluxes
144                  z0u = SIGN( 0.5, pun(ji,jj,jk) )
145                  zalpha = 0.5 - z0u
146                  zu  = z0u - 0.5 * pun(ji,jj,jk) * zdt / ( e1u(ji,jj) * e2u(ji,jj) * fse3u(ji,jj,jk) )
147                  zzwx = ptb(ji+1,jj,jk,jn) + zu * zslpx(ji+1,jj,jk)
148                  zzwy = ptb(ji  ,jj,jk,jn) + zu * zslpx(ji  ,jj,jk)
149                  zwx(ji,jj,jk) = pun(ji,jj,jk) * ( zalpha * zzwx + (1.-zalpha) * zzwy )
150                  !
151                  z0v = SIGN( 0.5, pvn(ji,jj,jk) )
152                  zalpha = 0.5 - z0v
153                  zv  = z0v - 0.5 * pvn(ji,jj,jk) * zdt / ( e1v(ji,jj) * e2v(ji,jj) * fse3v(ji,jj,jk) )
154                  zzwx = ptb(ji,jj+1,jk,jn) + zv * zslpy(ji,jj+1,jk)
155                  zzwy = ptb(ji,jj  ,jk,jn) + zv * zslpy(ji,jj  ,jk)
156                  zwy(ji,jj,jk) = pvn(ji,jj,jk) * ( zalpha * zzwx + (1.-zalpha) * zzwy )
157               END DO
158            END DO
159         END DO
160
161         !!  centered scheme at lateral b.C. if off-shore velocity
162         DO jk = 1, jpkm1
163            DO jj = 2, jpjm1
164               DO ji = fs_2, fs_jpim1   ! vector opt.
165                  IF( umask(ji,jj,jk) == 0. ) THEN
166                     IF( pun(ji+1,jj,jk) > 0. .AND. ji /= jpi ) THEN
167                        zwx(ji+1,jj,jk) = 0.5 * pun(ji+1,jj,jk) * ( ptn(ji+1,jj,jk,jn) + ptn(ji+2,jj,jk,jn) )
168                     ENDIF
169                     IF( pun(ji-1,jj,jk) < 0. ) THEN
170                        zwx(ji-1,jj,jk) = 0.5 * pun(ji-1,jj,jk) * ( ptn(ji-1,jj,jk,jn) + ptn(ji,jj,jk,jn) ) 
171                     ENDIF
172                  ENDIF
173                  IF( vmask(ji,jj,jk) == 0. ) THEN
174                     IF( pvn(ji,jj+1,jk) > 0. .AND. jj /= jpj ) THEN
175                        zwy(ji,jj+1,jk) = 0.5 * pvn(ji,jj+1,jk) * ( ptn(ji,jj+1,jk,jn) + ptn(ji,jj+2,jk,jn) )
176                     ENDIF
177                     IF( pvn(ji,jj-1,jk) < 0. ) THEN
178                        zwy(ji,jj-1,jk) = 0.5 * pvn(ji,jj-1,jk) * ( ptn(ji,jj-1,jk,jn) + ptn(ji,jj,jk,jn) ) 
179                     ENDIF
180                  ENDIF
181               END DO
182            END DO
183         END DO
184         CALL lbc_lnk( zwx, 'U', -1. )   ;   CALL lbc_lnk( zwy, 'V', -1. )   ! lateral boundary condition (changed sign)
185
186         ! Tracer flux divergence at t-point added to the general trend
187         DO jk = 1, jpkm1
188            DO jj = 2, jpjm1
189               DO ji = fs_2, fs_jpim1   ! vector opt.
190                  zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
191                  ! horizontal advective trends
192                  ztra = - zbtr * ( zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
193                  &               + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  ) )
194                  ! added to the general tracer trends
195                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + ztra
196               END DO
197           END DO
198         END DO
199         !                                 ! trend diagnostics (contribution of upstream fluxes)
200         IF( l_trd ) THEN
201            CALL trd_tra( kt, cdtype, jn, jptra_trd_xad, zwx, pun, ptb(:,:,:,jn) )
202            CALL trd_tra( kt, cdtype, jn, jptra_trd_yad, zwy, pvn, ptb(:,:,:,jn) )
203         END IF
204
205         !                                 ! "Poleward" heat and salt transports (contribution of upstream fluxes)
206         IF( cdtype == 'TRA' .AND. ln_diaptr .AND. ( MOD( kt, nn_fptr ) == 0 ) ) THEN
207            IF( jn == jp_tem )  htr_adv(:) = ptr_vj( zwy(:,:,:) )
208            IF( jn == jp_sal )  str_adv(:) = ptr_vj( zwy(:,:,:) )
209         ENDIF
210
211         ! II. Vertical advective fluxes
212         ! -----------------------------
213         !                                             !-- first guess of the slopes
214         zwx (:,:, 1 ) = 0.e0    ;    zwx (:,:,jpk) = 0.e0    ! surface & bottom boundary conditions
215         DO jk = 2, jpkm1                                     ! interior values
216            zwx(:,:,jk) = tmask(:,:,jk) * ( ptb(:,:,jk-1,jn) - ptb(:,:,jk,jn) )
217         END DO
218
219         !                                             !-- Slopes of tracer
220         zslpx(:,:,1) = 0.e0                                  ! surface values
221         DO jk = 2, jpkm1                                     ! interior value
222            DO jj = 1, jpj
223               DO ji = 1, jpi
224                  zslpx(ji,jj,jk) =                    ( zwx(ji,jj,jk) + zwx(ji,jj,jk+1) )   &
225                     &            * ( 0.25 + SIGN( 0.25, zwx(ji,jj,jk) * zwx(ji,jj,jk+1) ) )
226               END DO
227            END DO
228         END DO
229         !                                             !-- Slopes limitation
230         DO jk = 2, jpkm1                                     ! interior values
231            DO jj = 1, jpj
232               DO ji = 1, jpi
233                  zslpx(ji,jj,jk) = SIGN( 1., zslpx(ji,jj,jk) ) * MIN(    ABS( zslpx(ji,jj,jk  ) ),   &
234                     &                                                 2.*ABS( zwx  (ji,jj,jk+1) ),   &
235                     &                                                 2.*ABS( zwx  (ji,jj,jk  ) )  )
236               END DO
237            END DO
238         END DO
239         !                                             !-- vertical advective flux
240         !                                                    ! surface values  (bottom already set to zero)
241         IF( lk_vvl ) THEN    ;   zwx(:,:, 1 ) = 0.e0                      !  variable volume
242         ELSE                 ;   zwx(:,:, 1 ) = pwn(:,:,1) * ptb(:,:,1,jn)   ! linear free surface
243         ENDIF
244         !
245         DO jk = 1, jpkm1                                     ! interior values
246            zdt  = p2dt(jk)
247            DO jj = 2, jpjm1
248               DO ji = fs_2, fs_jpim1   ! vector opt.
249                  zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3w(ji,jj,jk+1) )
250                  z0w = SIGN( 0.5, pwn(ji,jj,jk+1) )
251                  zalpha = 0.5 + z0w
252                  zw  = z0w - 0.5 * pwn(ji,jj,jk+1) * zdt * zbtr
253                  zzwx = ptb(ji,jj,jk+1,jn) + zw * zslpx(ji,jj,jk+1)
254                  zzwy = ptb(ji,jj,jk  ,jn) + zw * zslpx(ji,jj,jk  )
255                  zwx(ji,jj,jk+1) = pwn(ji,jj,jk+1) * ( zalpha * zzwx + (1.-zalpha) * zzwy )
256               END DO
257            END DO
258         END DO
259         !
260         DO jk = 2, jpkm1        ! centered near the bottom
261            DO jj = 2, jpjm1
262               DO ji = fs_2, fs_jpim1   ! vector opt.
263                  IF( tmask(ji,jj,jk+1) == 0. ) THEN
264                     IF( pwn(ji,jj,jk) > 0. ) THEN
265                        zwx(ji,jj,jk) = 0.5 * pwn(ji,jj,jk) * ( ptn(ji,jj,jk-1,jn) + ptn(ji,jj,jk,jn) ) 
266                     ENDIF
267                  ENDIF
268               END DO
269            END DO
270         END DO
271         !
272         DO jk = 1, jpkm1        ! Compute & add the vertical advective trend
273            DO jj = 2, jpjm1     
274               DO ji = fs_2, fs_jpim1   ! vector opt.
275                  zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
276                  ! vertical advective trends
277                  ztra = - zbtr * ( zwx(ji,jj,jk) - zwx(ji,jj,jk+1) )
278                  ! added to the general tracer trends
279                  pta(ji,jj,jk,jn) =  pta(ji,jj,jk,jn) + ztra
280               END DO
281            END DO
282         END DO
283         !                       ! trend diagnostics (contribution of upstream fluxes)
284         IF( l_trd )  CALL trd_tra( kt, cdtype, jn, jptra_trd_zad, zwx, pwn, ptb(:,:,:,jn) )
285         !
286      END DO
287      !
288      IF( wrk_not_released(3, 1,2) )   CALL ctl_stop('tra_adv_muscl2: failed to release workspace arrays')
289      !
290   END SUBROUTINE tra_adv_muscl2
291
292   !!======================================================================
293END MODULE traadv_muscl2
Note: See TracBrowser for help on using the repository browser.