New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
trcini.F90 in branches/2011/dev_NEMO_MERGE_2011/NEMOGCM/NEMO/TOP_SRC – NEMO

source: branches/2011/dev_NEMO_MERGE_2011/NEMOGCM/NEMO/TOP_SRC/trcini.F90 @ 3169

Last change on this file since 3169 was 3169, checked in by cetlod, 13 years ago

New memory allocation for some forgotten TOP routines
  • Property svn:keywords set to Id
File size: 9.6 KB
Line 
1MODULE trcini
2   !!======================================================================
3   !!                         ***  MODULE trcini  ***
4   !! TOP :   Manage the passive tracer initialization
5   !!======================================================================
6   !! History :   -   ! 1991-03 (O. Marti)  original code
7   !!            1.0  ! 2005-03 (O. Aumont, A. El Moussaoui) F90
8   !!            2.0  ! 2005-10 (C. Ethe, G. Madec) revised architecture
9   !!            4.0  ! 2011-01 (A. R. Porter, STFC Daresbury) dynamical allocation
10   !!----------------------------------------------------------------------
11#if defined key_top
12   !!----------------------------------------------------------------------
13   !!   'key_top'                                                TOP models
14   !!----------------------------------------------------------------------
15   !!   trc_init  :   Initialization for passive tracer
16   !!   top_alloc :   allocate the TOP arrays
17   !!----------------------------------------------------------------------
18   USE oce_trc         ! shared variables between ocean and passive tracers
19   USE trc             ! passive tracers common variables
20   USE trcrst          ! passive tracers restart
21   USE trcnam          ! Namelist read
22   USE trcini_cfc      ! CFC      initialisation
23   USE trcini_lobster  ! LOBSTER  initialisation
24   USE trcini_pisces   ! PISCES   initialisation
25   USE trcini_c14b     ! C14 bomb initialisation
26   USE trcini_my_trc   ! MY_TRC   initialisation
27   USE trcdta          ! initialisation form files
28   USE daymod          ! calendar manager
29   USE zpshde          ! partial step: hor. derivative   (zps_hde routine)
30   USE prtctl_trc      ! Print control passive tracers (prt_ctl_trc_init routine)
31   USE trcsub       ! variables to substep passive tracers
32   
33   IMPLICIT NONE
34   PRIVATE
35   
36   PUBLIC   trc_init   ! called by opa
37
38    !! * Substitutions
39#  include "domzgr_substitute.h90"
40   !!----------------------------------------------------------------------
41   !! NEMO/TOP 4.0 , NEMO Consortium (2011)
42   !! $Id$
43   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
44   !!----------------------------------------------------------------------
45CONTAINS
46   
47   SUBROUTINE trc_init
48      !!---------------------------------------------------------------------
49      !!                     ***  ROUTINE trc_init  ***
50      !!
51      !! ** Purpose :   Initialization of the passive tracer fields
52      !!
53      !! ** Method  : - read namelist
54      !!              - control the consistancy
55      !!              - compute specific initialisations
56      !!              - set initial tracer fields (either read restart
57      !!                or read data or analytical formulation
58      !!---------------------------------------------------------------------
59      INTEGER ::   jk, jn, jl    ! dummy loop indices
60      INTEGER ::   ierr          ! local integer
61      CHARACTER (len=25) :: charout
62      REAL(wp), POINTER, DIMENSION(:,:,:,:) ::  ztrcdta   ! 4D  workspace
63      !!---------------------------------------------------------------------
64      !
65      IF( nn_timing == 1 )   CALL timing_start('trc_init')
66      !
67      IF(lwp) WRITE(numout,*)
68      IF(lwp) WRITE(numout,*) 'trc_init : initial set up of the passive tracers'
69      IF(lwp) WRITE(numout,*) '~~~~~~~'
70
71      CALL top_alloc()              ! allocate TOP arrays
72
73      IF( ln_dm2dc .AND. ( lk_pisces .OR. lk_lobster ) )    &
74         &  CALL ctl_stop( ' The diurnal cycle is not compatible with PISCES or LOBSTER  ' )
75
76      IF( nn_cla == 1 )   &
77         &  CALL ctl_stop( ' Cross Land Advection not yet implemented with passive tracer ; nn_cla must be 0' )
78
79      CALL trc_nam                  ! read passive tracers namelists
80
81      IF( lk_lobster ) THEN   ;   CALL trc_ini_lobster      ! LOBSTER bio-model
82      ELSE                    ;   IF(lwp) WRITE(numout,*) '          LOBSTER not used'
83      ENDIF
84     
85      IF( lk_pisces  ) THEN   ;   CALL trc_ini_pisces       ! PISCES  bio-model
86      ELSE                    ;   IF(lwp) WRITE(numout,*) '          PISCES not used'
87      ENDIF
88     
89      IF( lk_cfc     ) THEN   ;   CALL trc_ini_cfc          ! CFC     tracers
90      ELSE                    ;   IF(lwp) WRITE(numout,*) '          CFC not used'
91      ENDIF
92
93      IF( lk_c14b    ) THEN   ;   CALL trc_ini_c14b         ! C14 bomb  tracer
94      ELSE                    ;   IF(lwp) WRITE(numout,*) '          C14 not used'
95      ENDIF
96     
97      IF( lk_my_trc  ) THEN   ;   CALL trc_ini_my_trc       ! MY_TRC  tracers
98      ELSE                    ;   IF(lwp) WRITE(numout,*) '          MY_TRC not used'
99      ENDIF
100
101      IF( lwp ) THEN
102         !
103         CALL ctl_opn( numstr, 'tracer.stat', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE., narea )
104         !
105      ENDIF
106
107      IF( ln_trcdta )             CALL trc_dta_init
108
109      IF( ln_rsttr ) THEN
110        !
111        IF( lk_offline )  neuler = 1   ! Set time-step indicator at nit000 (leap-frog)
112        CALL trc_rst_read              ! restart from a file
113        !
114      ELSE
115        IF( lk_offline )  THEN
116           neuler = 0                  ! Set time-step indicator at nit000 (euler)
117           CALL day_init               ! set calendar
118        ENDIF
119        IF( ln_trcdta .AND. nb_trcdta > 0 ) THEN  ! Initialisation of tracer from a file that may also be used for damping
120            !
121            CALL wrk_alloc( jpi, jpj, jpk, nb_trcdta, ztrcdta )    ! Memory allocation
122            !
123            CALL trc_dta( nit000, ztrcdta )   ! read tracer data at nit000
124            !
125            DO jn = 1, jptra
126               IF( ln_trc_ini(jn) ) THEN      ! update passive tracers arrays with input data read from file
127                  jl = n_trc_index(jn) 
128                  trn(:,:,:,jn) = ztrcdta(:,:,:,jl) * tmask(:,:,:) 
129               ENDIF
130            ENDDO
131            CALL wrk_dealloc( jpi, jpj, jpk, nb_trcdta, ztrcdta )
132        ENDIF
133        !
134        trb(:,:,:,:) = trn(:,:,:,:)
135        !
136      ENDIF
137 
138      tra(:,:,:,:) = 0._wp
139     
140      IF( ln_zps .AND. .NOT. lk_c1d )   &              ! Partial steps: before horizontal gradient of passive
141        &    CALL zps_hde( nit000, jptra, trn, gtru, gtrv )       ! tracers at the bottom ocean level
142      !                                                              ! masked grid volume
143      DO jk = 1, jpk
144         cvol(:,:,jk) = e1e2t(:,:) * fse3t(:,:,jk) * tmask(:,:,jk)
145      END DO
146      IF( lk_degrad ) cvol(:,:,:) = cvol(:,:,:) * facvol(:,:,:)      ! degrad option: reduction by facvol
147      !                                                              ! total volume of the ocean
148      areatot = glob_sum( cvol(:,:,:) )
149
150      !
151      IF( nn_dttrc /= 1 )        CALL trc_sub_ini      ! Initialize variables for substepping passive tracers
152      !
153
154      trai(:) = 0._wp                                                   ! initial content of all tracers
155      DO jn = 1, jptra
156         trai(jn) = trai(jn) + glob_sum( trn(:,:,:,jn) * cvol(:,:,:)   )
157      END DO
158
159      IF(lwp) THEN               ! control print
160         WRITE(numout,*)
161         WRITE(numout,*)
162         WRITE(numout,*) '          *** Total number of passive tracer jptra = ', jptra
163         WRITE(numout,*) '          *** Total volume of ocean                = ', areatot
164         WRITE(numout,*) '          *** Total inital content of all tracers '
165         WRITE(numout,*)
166         DO jn = 1, jptra
167            WRITE(numout,9000) jn, TRIM( ctrcnm(jn) ), trai(jn)
168         ENDDO
169         WRITE(numout,*)
170      ENDIF
171      WRITE(numout,*)
172      IF(ln_ctl) THEN            ! print mean trends (used for debugging)
173         CALL prt_ctl_trc_init
174         WRITE(charout, FMT="('ini ')")
175         CALL prt_ctl_trc_info( charout )
176         CALL prt_ctl_trc( tab4d=trn, mask=tmask, clinfo=ctrcnm )
177      ENDIF
1789000  FORMAT(' tracer nb : ',i2,'      name :',a10,'      initial content :',e18.10)
179      !
180      IF( nn_timing == 1 )   CALL timing_stop('trc_init')
181      !
182   END SUBROUTINE trc_init
183
184
185   SUBROUTINE top_alloc
186      !!----------------------------------------------------------------------
187      !!                     ***  ROUTINE top_alloc  ***
188      !!
189      !! ** Purpose :   Allocate all the dynamic arrays of the OPA modules
190      !!----------------------------------------------------------------------
191      USE trcadv        , ONLY:   trc_adv_alloc          ! TOP-related alloc routines...
192      USE trc           , ONLY:   trc_alloc
193      USE trcnxt        , ONLY:   trc_nxt_alloc
194      USE trczdf        , ONLY:   trc_zdf_alloc
195      USE trdmod_trc_oce, ONLY:   trd_mod_trc_oce_alloc
196#if defined key_trdmld_trc 
197      USE trdmld_trc    , ONLY:   trd_mld_trc_alloc
198#endif
199      !
200      INTEGER :: ierr
201      !!----------------------------------------------------------------------
202      !
203      ierr =        trc_adv_alloc()          ! Start of TOP-related alloc routines...
204      ierr = ierr + trc_alloc    ()
205      ierr = ierr + trc_nxt_alloc()
206      ierr = ierr + trc_zdf_alloc()
207      ierr = ierr + trd_mod_trc_oce_alloc()
208#if defined key_trdmld_trc 
209      ierr = ierr + trd_mld_trc_alloc()
210#endif
211      !
212      IF( lk_mpp    )   CALL mpp_sum( ierr )
213      IF( ierr /= 0 )   CALL ctl_stop( 'STOP', 'top_alloc : unable to allocate standard ocean arrays' )
214      !
215   END SUBROUTINE top_alloc
216
217#else
218   !!----------------------------------------------------------------------
219   !!  Empty module :                                     No passive tracer
220   !!----------------------------------------------------------------------
221CONTAINS
222   SUBROUTINE trc_init                      ! Dummy routine   
223   END SUBROUTINE trc_init
224#endif
225
226   !!======================================================================
227END MODULE trcini
Note: See TracBrowser for help on using the repository browser.