| 1 | MODULE p4zflx |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE p4zflx *** |
|---|
| 4 | !! TOP : PISCES CALCULATES GAS EXCHANGE AND CHEMISTRY AT SEA SURFACE |
|---|
| 5 | !!====================================================================== |
|---|
| 6 | !! History : - ! 1988-07 (E. MAIER-REIMER) Original code |
|---|
| 7 | !! - ! 1998 (O. Aumont) additions |
|---|
| 8 | !! - ! 1999 (C. Le Quere) modifications |
|---|
| 9 | !! 1.0 ! 2004 (O. Aumont) modifications |
|---|
| 10 | !! 2.0 ! 2007-12 (C. Ethe, G. Madec) F90 |
|---|
| 11 | !! ! 2011-02 (J. Simeon, J. Orr) Include total atm P correction |
|---|
| 12 | !!---------------------------------------------------------------------- |
|---|
| 13 | #if defined key_pisces |
|---|
| 14 | !!---------------------------------------------------------------------- |
|---|
| 15 | !! 'key_pisces' PISCES bio-model |
|---|
| 16 | !!---------------------------------------------------------------------- |
|---|
| 17 | !! p4z_flx : CALCULATES GAS EXCHANGE AND CHEMISTRY AT SEA SURFACE |
|---|
| 18 | !! p4z_flx_init : Read the namelist |
|---|
| 19 | !! p4z_patm : Read sfc atm pressure [atm] for each grid cell |
|---|
| 20 | !!---------------------------------------------------------------------- |
|---|
| 21 | USE oce_trc ! shared variables between ocean and passive tracers |
|---|
| 22 | USE trc ! passive tracers common variables |
|---|
| 23 | USE sms_pisces ! PISCES Source Minus Sink variables |
|---|
| 24 | USE p4zche ! Chemical model |
|---|
| 25 | USE prtctl_trc ! print control for debugging |
|---|
| 26 | USE iom ! I/O manager |
|---|
| 27 | USE fldread ! read input fields |
|---|
| 28 | #if defined key_cpl_carbon_cycle |
|---|
| 29 | USE sbc_oce, ONLY : atm_co2 ! atmospheric pCO2 |
|---|
| 30 | #endif |
|---|
| 31 | |
|---|
| 32 | IMPLICIT NONE |
|---|
| 33 | PRIVATE |
|---|
| 34 | |
|---|
| 35 | PUBLIC p4z_flx |
|---|
| 36 | PUBLIC p4z_flx_init |
|---|
| 37 | PUBLIC p4z_flx_alloc |
|---|
| 38 | |
|---|
| 39 | ! !!** Namelist nampisext ** |
|---|
| 40 | REAL(wp) :: atcco2 = 278._wp !: pre-industrial atmospheric [co2] (ppm) |
|---|
| 41 | LOGICAL :: ln_co2int = .FALSE. !: flag to read in a file and interpolate atmospheric pco2 or not |
|---|
| 42 | CHARACTER(len=34) :: clname = 'atcco2.txt' !: filename of pco2 values |
|---|
| 43 | INTEGER :: nn_offset = 0 !: Offset model-data start year (default = 0) |
|---|
| 44 | |
|---|
| 45 | !! Variables related to reading atmospheric CO2 time history |
|---|
| 46 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:) :: atcco2h, years |
|---|
| 47 | INTEGER :: nmaxrec, numco2 |
|---|
| 48 | |
|---|
| 49 | REAL(wp) , ALLOCATABLE, SAVE, DIMENSION(:,:) :: patm ! atmospheric pressure at kt [N/m2] |
|---|
| 50 | TYPE(FLD), ALLOCATABLE, DIMENSION(:) :: sf_patm ! structure of input fields (file informations, fields read) |
|---|
| 51 | |
|---|
| 52 | |
|---|
| 53 | REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) :: oce_co2 !: ocean carbon flux |
|---|
| 54 | REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:) :: satmco2 !: atmospheric pco2 |
|---|
| 55 | |
|---|
| 56 | REAL(wp) :: t_oce_co2_flx !: Total ocean carbon flux |
|---|
| 57 | REAL(wp) :: t_atm_co2_flx !: global mean of atmospheric pco2 |
|---|
| 58 | REAL(wp) :: area !: ocean surface |
|---|
| 59 | REAL(wp) :: xconv = 0.01_wp / 3600._wp !: coefficients for conversion |
|---|
| 60 | |
|---|
| 61 | !!* Substitution |
|---|
| 62 | # include "top_substitute.h90" |
|---|
| 63 | !!---------------------------------------------------------------------- |
|---|
| 64 | !! NEMO/TOP 3.3 , NEMO Consortium (2010) |
|---|
| 65 | !! $Id$ |
|---|
| 66 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
|---|
| 67 | !!---------------------------------------------------------------------- |
|---|
| 68 | CONTAINS |
|---|
| 69 | |
|---|
| 70 | SUBROUTINE p4z_flx ( kt ) |
|---|
| 71 | !!--------------------------------------------------------------------- |
|---|
| 72 | !! *** ROUTINE p4z_flx *** |
|---|
| 73 | !! |
|---|
| 74 | !! ** Purpose : CALCULATES GAS EXCHANGE AND CHEMISTRY AT SEA SURFACE |
|---|
| 75 | !! |
|---|
| 76 | !! ** Method : |
|---|
| 77 | !! - Include total atm P correction via Esbensen & Kushnir (1981) |
|---|
| 78 | !! - Pressure correction NOT done for key_cpl_carbon_cycle |
|---|
| 79 | !! - Remove Wanninkhof chemical enhancement; |
|---|
| 80 | !! - Add option for time-interpolation of atcco2.txt |
|---|
| 81 | !!--------------------------------------------------------------------- |
|---|
| 82 | USE wrk_nemo, ONLY: wrk_in_use, wrk_not_released |
|---|
| 83 | USE wrk_nemo, ONLY: zkgco2 => wrk_2d_11 , zkgo2 => wrk_2d_12 , zh2co3 => wrk_2d_13 |
|---|
| 84 | USE wrk_nemo, ONLY: zoflx => wrk_2d_14 , zkg => wrk_2d_15 |
|---|
| 85 | USE wrk_nemo, ONLY: zdpco2 => wrk_2d_16 , zdpo2 => wrk_2d_17 |
|---|
| 86 | ! |
|---|
| 87 | INTEGER, INTENT(in) :: kt ! |
|---|
| 88 | ! |
|---|
| 89 | INTEGER :: ji, jj, jm, iind, iindm1 |
|---|
| 90 | REAL(wp) :: ztc, ztc2, ztc3, zws, zkgwan |
|---|
| 91 | REAL(wp) :: zfld, zflu, zfld16, zflu16, zfact |
|---|
| 92 | REAL(wp) :: zph, zah2, zbot, zdic, zalk, zsch_o2, zalka, zsch_co2 |
|---|
| 93 | REAL(wp) :: zyr_dec, zdco2dt |
|---|
| 94 | CHARACTER (len=25) :: charout |
|---|
| 95 | !!--------------------------------------------------------------------- |
|---|
| 96 | |
|---|
| 97 | IF( wrk_in_use(2, 11,12,13,14,15,16,17) ) THEN |
|---|
| 98 | CALL ctl_stop('p4z_flx: requested workspace arrays unavailable') ; RETURN |
|---|
| 99 | ENDIF |
|---|
| 100 | |
|---|
| 101 | ! SURFACE CHEMISTRY (PCO2 AND [H+] IN |
|---|
| 102 | ! SURFACE LAYER); THE RESULT OF THIS CALCULATION |
|---|
| 103 | ! IS USED TO COMPUTE AIR-SEA FLUX OF CO2 |
|---|
| 104 | |
|---|
| 105 | CALL p4z_patm( kt ) ! Get sea-level pressure (E&K [1981] climatology) for use in flux calcs |
|---|
| 106 | |
|---|
| 107 | IF( ln_co2int ) THEN |
|---|
| 108 | ! Linear temporal interpolation of atmospheric pco2. atcco2.txt has annual values. |
|---|
| 109 | ! Caveats: First column of .txt must be in years, decimal years preferably. |
|---|
| 110 | ! For nn_offset, if your model year is iyy, nn_offset=(years(1)-iyy) |
|---|
| 111 | ! then the first atmospheric CO2 record read is at years(1) |
|---|
| 112 | zyr_dec = REAL( nyear + nn_offset, wp ) + REAL( nday_year, wp ) / REAL( nyear_len(1), wp ) |
|---|
| 113 | jm = 2 |
|---|
| 114 | DO WHILE( jm <= nmaxrec .AND. years(jm-1) < zyr_dec .AND. years(jm) >= zyr_dec ) ; jm = jm + 1 ; END DO |
|---|
| 115 | iind = jm ; iindm1 = jm - 1 |
|---|
| 116 | zdco2dt = ( atcco2h(iind) - atcco2h(iindm1) ) / ( years(iind) - years(iindm1) + rtrn ) |
|---|
| 117 | atcco2 = zdco2dt * ( zyr_dec - years(iindm1) ) + atcco2h(iindm1) |
|---|
| 118 | satmco2(:,:) = atcco2 |
|---|
| 119 | ENDIF |
|---|
| 120 | |
|---|
| 121 | #if defined key_cpl_carbon_cycle |
|---|
| 122 | satmco2(:,:) = atm_co2(:,:) |
|---|
| 123 | #endif |
|---|
| 124 | |
|---|
| 125 | DO jm = 1, 10 |
|---|
| 126 | !CDIR NOVERRCHK |
|---|
| 127 | DO jj = 1, jpj |
|---|
| 128 | !CDIR NOVERRCHK |
|---|
| 129 | DO ji = 1, jpi |
|---|
| 130 | |
|---|
| 131 | ! DUMMY VARIABLES FOR DIC, H+, AND BORATE |
|---|
| 132 | zbot = borat(ji,jj,1) |
|---|
| 133 | zfact = rhop(ji,jj,1) / 1000. + rtrn |
|---|
| 134 | zdic = trn(ji,jj,1,jpdic) / zfact |
|---|
| 135 | zph = MAX( hi(ji,jj,1), 1.e-10 ) / zfact |
|---|
| 136 | zalka = trn(ji,jj,1,jptal) / zfact |
|---|
| 137 | |
|---|
| 138 | ! CALCULATE [ALK]([CO3--], [HCO3-]) |
|---|
| 139 | zalk = zalka - ( akw3(ji,jj,1) / zph - zph + zbot / ( 1.+ zph / akb3(ji,jj,1) ) ) |
|---|
| 140 | |
|---|
| 141 | ! CALCULATE [H+] AND [H2CO3] |
|---|
| 142 | zah2 = SQRT( (zdic-zalk)**2 + 4.* ( zalk * ak23(ji,jj,1) & |
|---|
| 143 | & / ak13(ji,jj,1) ) * ( 2.* zdic - zalk ) ) |
|---|
| 144 | zah2 = 0.5 * ak13(ji,jj,1) / zalk * ( ( zdic - zalk ) + zah2 ) |
|---|
| 145 | zh2co3(ji,jj) = ( 2.* zdic - zalk ) / ( 2.+ ak13(ji,jj,1) / zah2 ) * zfact |
|---|
| 146 | hi(ji,jj,1) = zah2 * zfact |
|---|
| 147 | END DO |
|---|
| 148 | END DO |
|---|
| 149 | END DO |
|---|
| 150 | |
|---|
| 151 | |
|---|
| 152 | ! -------------- |
|---|
| 153 | ! COMPUTE FLUXES |
|---|
| 154 | ! -------------- |
|---|
| 155 | |
|---|
| 156 | ! FIRST COMPUTE GAS EXCHANGE COEFFICIENTS |
|---|
| 157 | ! ------------------------------------------- |
|---|
| 158 | |
|---|
| 159 | !CDIR NOVERRCHK |
|---|
| 160 | DO jj = 1, jpj |
|---|
| 161 | !CDIR NOVERRCHK |
|---|
| 162 | DO ji = 1, jpi |
|---|
| 163 | ztc = MIN( 35., tsn(ji,jj,1,jp_tem) ) |
|---|
| 164 | ztc2 = ztc * ztc |
|---|
| 165 | ztc3 = ztc * ztc2 |
|---|
| 166 | ! Compute the schmidt Number both O2 and CO2 |
|---|
| 167 | zsch_co2 = 2073.1 - 125.62 * ztc + 3.6276 * ztc2 - 0.043126 * ztc3 |
|---|
| 168 | zsch_o2 = 1953.4 - 128.0 * ztc + 3.9918 * ztc2 - 0.050091 * ztc3 |
|---|
| 169 | ! wind speed |
|---|
| 170 | zws = wndm(ji,jj) * wndm(ji,jj) |
|---|
| 171 | ! Compute the piston velocity for O2 and CO2 |
|---|
| 172 | zkgwan = 0.3 * zws + 2.5 * ( 0.5246 + 0.016256 * ztc + 0.00049946 * ztc2 ) |
|---|
| 173 | zkgwan = zkgwan * xconv * ( 1.- fr_i(ji,jj) ) * tmask(ji,jj,1) |
|---|
| 174 | # if defined key_degrad |
|---|
| 175 | zkgwan = zkgwan * facvol(ji,jj,1) |
|---|
| 176 | #endif |
|---|
| 177 | ! compute gas exchange for CO2 and O2 |
|---|
| 178 | zkgco2(ji,jj) = zkgwan * SQRT( 660./ zsch_co2 ) |
|---|
| 179 | zkgo2 (ji,jj) = zkgwan * SQRT( 660./ zsch_o2 ) |
|---|
| 180 | END DO |
|---|
| 181 | END DO |
|---|
| 182 | |
|---|
| 183 | DO jj = 1, jpj |
|---|
| 184 | DO ji = 1, jpi |
|---|
| 185 | ! Compute CO2 flux for the sea and air |
|---|
| 186 | zfld = satmco2(ji,jj) * patm(ji,jj) * tmask(ji,jj,1) * chemc(ji,jj,1) * zkgco2(ji,jj) ! (mol/L) * (m/s) |
|---|
| 187 | zflu = zh2co3(ji,jj) * tmask(ji,jj,1) * zkgco2(ji,jj) ! (mol/L) (m/s) ? |
|---|
| 188 | oce_co2(ji,jj) = ( zfld - zflu ) * rfact * e1e2t(ji,jj) * tmask(ji,jj,1) * 1000. |
|---|
| 189 | ! compute the trend |
|---|
| 190 | tra(ji,jj,1,jpdic) = tra(ji,jj,1,jpdic) + ( zfld - zflu ) / fse3t(ji,jj,1) |
|---|
| 191 | |
|---|
| 192 | ! Compute O2 flux |
|---|
| 193 | zfld16 = atcox * patm(ji,jj) * chemc(ji,jj,2) * tmask(ji,jj,1) * zkgo2(ji,jj) ! (mol/L) * (m/s) |
|---|
| 194 | zflu16 = trn(ji,jj,1,jpoxy) * tmask(ji,jj,1) * zkgo2(ji,jj) |
|---|
| 195 | tra(ji,jj,1,jpoxy) = tra(ji,jj,1,jpoxy) + ( zfld16 - zflu16 ) / fse3t(ji,jj,1) |
|---|
| 196 | |
|---|
| 197 | IF( ln_diatrc ) THEN ! Save diagnostics |
|---|
| 198 | IF( lk_iomput ) THEN |
|---|
| 199 | zoflx(ji,jj) = ( zfld16 - zflu16 ) * 1000. * tmask(ji,jj,1) |
|---|
| 200 | zkg (ji,jj) = zkgco2(ji,jj) * tmask(ji,jj,1) |
|---|
| 201 | zdpco2(ji,jj) = ( satmco2(ji,jj) * patm(ji,jj) - zh2co3(ji,jj) / ( chemc(ji,jj,1) + rtrn ) ) * tmask(ji,jj,1) |
|---|
| 202 | zdpo2 (ji,jj) = ( atcox * patm(ji,jj) - trn(ji,jj,1,jpoxy) / ( chemc(ji,jj,2) + rtrn ) ) * tmask(ji,jj,1) |
|---|
| 203 | ELSE |
|---|
| 204 | zfact = 1. / e1e2t(ji,jj) / rfact |
|---|
| 205 | trc2d(ji,jj,jp_pcs0_2d ) = oce_co2(ji,jj) * zfact |
|---|
| 206 | trc2d(ji,jj,jp_pcs0_2d + 1) = ( zfld16 - zflu16 ) * 1000. * tmask(ji,jj,1) |
|---|
| 207 | trc2d(ji,jj,jp_pcs0_2d + 2) = zkgco2(ji,jj) * tmask(ji,jj,1) |
|---|
| 208 | trc2d(ji,jj,jp_pcs0_2d + 3) = ( satmco2(ji,jj) * patm(ji,jj) - zh2co3(ji,jj) / ( chemc(ji,jj,1) + rtrn ) ) & |
|---|
| 209 | & * tmask(ji,jj,1) |
|---|
| 210 | ENDIF |
|---|
| 211 | ENDIF |
|---|
| 212 | END DO |
|---|
| 213 | END DO |
|---|
| 214 | |
|---|
| 215 | t_oce_co2_flx = t_oce_co2_flx + glob_sum( oce_co2(:,:) ) ! Cumulative Total Flux of Carbon |
|---|
| 216 | IF( kt == nitend ) THEN |
|---|
| 217 | t_atm_co2_flx = glob_sum( satmco2(:,:) * patm(:,:) * e1e2t(:,:) ) ! Total atmospheric pCO2 |
|---|
| 218 | ! |
|---|
| 219 | t_oce_co2_flx = (-1.) * t_oce_co2_flx * 12. / 1.e15 ! Conversion in PgC ; negative for out of the ocean |
|---|
| 220 | t_atm_co2_flx = t_atm_co2_flx / area ! global mean of atmospheric pCO2 |
|---|
| 221 | ! |
|---|
| 222 | IF( lwp) THEN |
|---|
| 223 | WRITE(numout,*) |
|---|
| 224 | WRITE(numout,*) ' Global mean of atmospheric pCO2 (ppm) at it= ', kt, ' date= ', ndastp |
|---|
| 225 | WRITE(numout,*) '------------------------------------------------------- : ',t_atm_co2_flx |
|---|
| 226 | WRITE(numout,*) |
|---|
| 227 | WRITE(numout,*) ' Cumulative total Flux of Carbon out of the ocean (PgC) :' |
|---|
| 228 | WRITE(numout,*) '------------------------------------------------------- ',t_oce_co2_flx |
|---|
| 229 | ENDIF |
|---|
| 230 | ! |
|---|
| 231 | ENDIF |
|---|
| 232 | |
|---|
| 233 | IF(ln_ctl) THEN ! print mean trends (used for debugging) |
|---|
| 234 | WRITE(charout, FMT="('flx ')") |
|---|
| 235 | CALL prt_ctl_trc_info(charout) |
|---|
| 236 | CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm) |
|---|
| 237 | ENDIF |
|---|
| 238 | |
|---|
| 239 | IF( ln_diatrc ) THEN |
|---|
| 240 | CALL iom_put( "Cflx" , oce_co2(:,:) / e1e2t(:,:) / rfact ) |
|---|
| 241 | CALL iom_put( "Oflx" , zoflx ) |
|---|
| 242 | CALL iom_put( "Kg" , zkg ) |
|---|
| 243 | CALL iom_put( "Dpco2", zdpco2 ) |
|---|
| 244 | CALL iom_put( "Dpo2" , zdpo2 ) |
|---|
| 245 | ENDIF |
|---|
| 246 | ! |
|---|
| 247 | IF( wrk_not_released(2, 11,12,13,14,15,16,17) ) & |
|---|
| 248 | & CALL ctl_stop('p4z_flx: failed to release workspace arrays') |
|---|
| 249 | ! |
|---|
| 250 | END SUBROUTINE p4z_flx |
|---|
| 251 | |
|---|
| 252 | |
|---|
| 253 | SUBROUTINE p4z_flx_init |
|---|
| 254 | !!---------------------------------------------------------------------- |
|---|
| 255 | !! *** ROUTINE p4z_flx_init *** |
|---|
| 256 | !! |
|---|
| 257 | !! ** Purpose : Initialization of atmospheric conditions |
|---|
| 258 | !! |
|---|
| 259 | !! ** Method : Read the nampisext namelist and check the parameters |
|---|
| 260 | !! called at the first timestep (nit000) |
|---|
| 261 | !! ** input : Namelist nampisext |
|---|
| 262 | !!---------------------------------------------------------------------- |
|---|
| 263 | NAMELIST/nampisext/ln_co2int, atcco2, clname, nn_offset |
|---|
| 264 | INTEGER :: jm |
|---|
| 265 | !!---------------------------------------------------------------------- |
|---|
| 266 | ! |
|---|
| 267 | REWIND( numnatp ) ! read numnatp |
|---|
| 268 | READ ( numnatp, nampisext ) |
|---|
| 269 | ! |
|---|
| 270 | IF(lwp) THEN ! control print |
|---|
| 271 | WRITE(numout,*) ' ' |
|---|
| 272 | WRITE(numout,*) ' Namelist parameters for air-sea exchange, nampisext' |
|---|
| 273 | WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~' |
|---|
| 274 | WRITE(numout,*) ' Choice for reading in the atm pCO2 file or constant value, ln_co2int =', ln_co2int |
|---|
| 275 | WRITE(numout,*) ' ' |
|---|
| 276 | ENDIF |
|---|
| 277 | IF( .NOT.ln_co2int ) THEN |
|---|
| 278 | IF(lwp) THEN ! control print |
|---|
| 279 | WRITE(numout,*) ' Constant Atmospheric pCO2 value atcco2 =', atcco2 |
|---|
| 280 | WRITE(numout,*) ' ' |
|---|
| 281 | ENDIF |
|---|
| 282 | satmco2(:,:) = atcco2 ! Initialisation of atmospheric pco2 |
|---|
| 283 | ELSE |
|---|
| 284 | IF(lwp) THEN |
|---|
| 285 | WRITE(numout,*) ' Atmospheric pCO2 value from file clname =', TRIM( clname ) |
|---|
| 286 | WRITE(numout,*) ' Offset model-data start year nn_offset =', nn_offset |
|---|
| 287 | WRITE(numout,*) ' ' |
|---|
| 288 | ENDIF |
|---|
| 289 | CALL ctl_opn( numco2, TRIM( clname) , 'OLD', 'FORMATTED', 'SEQUENTIAL', -1 , numout, lwp ) |
|---|
| 290 | jm = 0 ! Count the number of record in co2 file |
|---|
| 291 | DO |
|---|
| 292 | READ(numco2,*,END=100) |
|---|
| 293 | jm = jm + 1 |
|---|
| 294 | END DO |
|---|
| 295 | 100 nmaxrec = jm - 1 |
|---|
| 296 | ALLOCATE( years (nmaxrec) ) ; years (:) = 0._wp |
|---|
| 297 | ALLOCATE( atcco2h(nmaxrec) ) ; atcco2h(:) = 0._wp |
|---|
| 298 | |
|---|
| 299 | REWIND(numco2) |
|---|
| 300 | DO jm = 1, nmaxrec ! get xCO2 data |
|---|
| 301 | READ(numco2, *) years(jm), atcco2h(jm) |
|---|
| 302 | IF(lwp) WRITE(numout, '(f6.0,f7.2)') years(jm), atcco2h(jm) |
|---|
| 303 | END DO |
|---|
| 304 | CLOSE(numco2) |
|---|
| 305 | ENDIF |
|---|
| 306 | ! |
|---|
| 307 | area = glob_sum( e1e2t(:,:) ) ! interior global domain surface |
|---|
| 308 | ! |
|---|
| 309 | oce_co2(:,:) = 0._wp ! Initialization of Flux of Carbon |
|---|
| 310 | t_atm_co2_flx = 0._wp |
|---|
| 311 | t_oce_co2_flx = 0._wp |
|---|
| 312 | ! |
|---|
| 313 | END SUBROUTINE p4z_flx_init |
|---|
| 314 | |
|---|
| 315 | SUBROUTINE p4z_patm( kt ) |
|---|
| 316 | |
|---|
| 317 | !!---------------------------------------------------------------------- |
|---|
| 318 | !! *** ROUTINE p4z_atm *** |
|---|
| 319 | !! |
|---|
| 320 | !! ** Purpose : Read and interpolate the external atmospheric sea-levl pressure |
|---|
| 321 | !! ** Method : Read the files and interpolate the appropriate variables |
|---|
| 322 | !! |
|---|
| 323 | !!---------------------------------------------------------------------- |
|---|
| 324 | !! * arguments |
|---|
| 325 | INTEGER, INTENT( in ) :: kt ! ocean time step |
|---|
| 326 | ! |
|---|
| 327 | INTEGER :: ierr |
|---|
| 328 | CHARACTER(len=100) :: cn_dir ! Root directory for location of ssr files |
|---|
| 329 | TYPE(FLD_N) :: sn_patm ! informations about the fields to be read |
|---|
| 330 | !! |
|---|
| 331 | NAMELIST/nampisatm/ sn_patm, cn_dir |
|---|
| 332 | |
|---|
| 333 | ! ! -------------------- ! |
|---|
| 334 | IF( kt == nit000 ) THEN ! First call kt=nit000 ! |
|---|
| 335 | ! ! -------------------- ! |
|---|
| 336 | ! !* set file information (default values) |
|---|
| 337 | ! ... default values (NB: frequency positive => hours, negative => months) |
|---|
| 338 | ! ! file ! frequency ! variable ! time intep ! clim ! 'yearly' or ! weights ! rotation ! |
|---|
| 339 | ! ! name ! (hours) ! name ! (T/F) ! (T/F) ! 'monthly' ! filename ! pairs ! |
|---|
| 340 | sn_patm = FLD_N( 'pres' , 24 , 'patm' , .false. , .true. , 'yearly' , '' , '' ) |
|---|
| 341 | cn_dir = './' ! directory in which the Patm data are |
|---|
| 342 | |
|---|
| 343 | REWIND( numnatp ) !* read in namlist nampisatm |
|---|
| 344 | READ ( numnatp, nampisatm ) |
|---|
| 345 | ! |
|---|
| 346 | ALLOCATE( sf_patm(1), STAT=ierr ) !* allocate and fill sf_patm (forcing structure) with sn_patm |
|---|
| 347 | IF( ierr > 0 ) CALL ctl_stop( 'STOP', 'p4z_flx: unable to allocate sf_patm structure' ) |
|---|
| 348 | ! |
|---|
| 349 | CALL fld_fill( sf_patm, (/ sn_patm /), cn_dir, 'p4z_flx', 'Atmospheric pressure ', 'nampisatm' ) |
|---|
| 350 | ALLOCATE( sf_patm(1)%fnow(jpi,jpj,1) ) |
|---|
| 351 | IF( sn_patm%ln_tint ) ALLOCATE( sf_patm(1)%fdta(jpi,jpj,1,2) ) |
|---|
| 352 | ! |
|---|
| 353 | ENDIF |
|---|
| 354 | ! |
|---|
| 355 | CALL fld_read( kt, 1, sf_patm ) !* input Patm provided at kt + 1/2 |
|---|
| 356 | patm(:,:) = sf_patm(1)%fnow(:,:,1) ! atmospheric pressure |
|---|
| 357 | |
|---|
| 358 | END SUBROUTINE p4z_patm |
|---|
| 359 | |
|---|
| 360 | INTEGER FUNCTION p4z_flx_alloc() |
|---|
| 361 | !!---------------------------------------------------------------------- |
|---|
| 362 | !! *** ROUTINE p4z_flx_alloc *** |
|---|
| 363 | !!---------------------------------------------------------------------- |
|---|
| 364 | ALLOCATE( oce_co2(jpi,jpj), satmco2(jpi,jpj), patm(jpi,jpj), STAT=p4z_flx_alloc ) |
|---|
| 365 | ! |
|---|
| 366 | IF( p4z_flx_alloc /= 0 ) CALL ctl_warn('p4z_flx_alloc : failed to allocate arrays') |
|---|
| 367 | ! |
|---|
| 368 | END FUNCTION p4z_flx_alloc |
|---|
| 369 | |
|---|
| 370 | #else |
|---|
| 371 | !!====================================================================== |
|---|
| 372 | !! Dummy module : No PISCES bio-model |
|---|
| 373 | !!====================================================================== |
|---|
| 374 | CONTAINS |
|---|
| 375 | SUBROUTINE p4z_flx( kt ) ! Empty routine |
|---|
| 376 | INTEGER, INTENT( in ) :: kt |
|---|
| 377 | WRITE(*,*) 'p4z_flx: You should not have seen this print! error?', kt |
|---|
| 378 | END SUBROUTINE p4z_flx |
|---|
| 379 | #endif |
|---|
| 380 | |
|---|
| 381 | !!====================================================================== |
|---|
| 382 | END MODULE p4zflx |
|---|
