1 | MODULE step |
---|
2 | !!====================================================================== |
---|
3 | !! *** MODULE step *** |
---|
4 | !! Time-stepping : manager of the ocean, tracer and ice time stepping |
---|
5 | !!====================================================================== |
---|
6 | !! History : OPA ! 1991-03 (G. Madec) Original code |
---|
7 | !! - ! 1991-11 (G. Madec) |
---|
8 | !! - ! 1992-06 (M. Imbard) add a first output record |
---|
9 | !! - ! 1996-04 (G. Madec) introduction of dynspg |
---|
10 | !! - ! 1996-04 (M.A. Foujols) introduction of passive tracer |
---|
11 | !! 8.0 ! 1997-06 (G. Madec) new architecture of call |
---|
12 | !! 8.2 ! 1997-06 (G. Madec, M. Imbard, G. Roullet) free surface |
---|
13 | !! - ! 1999-02 (G. Madec, N. Grima) hpg implicit |
---|
14 | !! - ! 2000-07 (J-M Molines, M. Imbard) Open Bondary Conditions |
---|
15 | !! NEMO 1.0 ! 2002-06 (G. Madec) free form, suppress macro-tasking |
---|
16 | !! - ! 2004-08 (C. Talandier) New trends organization |
---|
17 | !! - ! 2005-01 (C. Ethe) Add the KPP closure scheme |
---|
18 | !! - ! 2005-11 (G. Madec) Reorganisation of tra and dyn calls |
---|
19 | !! - ! 2006-01 (L. Debreu, C. Mazauric) Agrif implementation |
---|
20 | !! - ! 2006-07 (S. Masson) restart using iom |
---|
21 | !! 3.2 ! 2009-02 (G. Madec, R. Benshila) reintroduicing z*-coordinate |
---|
22 | !! - ! 2009-06 (S. Masson, G. Madec) TKE restart compatible with key_cpl |
---|
23 | !! 3.3 ! 2010-05 (K. Mogensen, A. Weaver, M. Martin, D. Lea) Assimilation interface |
---|
24 | !! - ! 2010-10 (C. Ethe, G. Madec) reorganisation of initialisation phase + merge TRC-TRA |
---|
25 | !! 3.4 ! 2011-04 (G. Madec, C. Ethe) Merge of dtatem and dtasal |
---|
26 | !! 3.6 ! 2012-07 (J. Simeon, G. Madec. C. Ethe) Online coarsening of outputs |
---|
27 | !! 3.6 ! 2014-04 (F. Roquet, G. Madec) New equations of state |
---|
28 | !! 3.6 ! 2014-10 (E. Clementi, P. Oddo) Add Qiao vertical mixing in case of waves |
---|
29 | !! 3.7 ! 2014-10 (G. Madec) LDF simplication |
---|
30 | !! - ! 2014-12 (G. Madec) remove KPP scheme |
---|
31 | !! - ! 2015-11 (J. Chanut) free surface simplification (remove filtered free surface) |
---|
32 | !! 4.0 ! 2017-05 (G. Madec) introduction of the vertical physics manager (zdfphy) |
---|
33 | !! 4.1 ! 2019-08 (A. Coward, D. Storkey) rewrite in preparation for new timestepping scheme |
---|
34 | !!---------------------------------------------------------------------- |
---|
35 | |
---|
36 | #if defined key_qco || defined key_linssh |
---|
37 | !!---------------------------------------------------------------------- |
---|
38 | !! 'key_qco' EMPTY MODULE Quasi-Eulerian vertical coordinate |
---|
39 | !! OR |
---|
40 | !! 'key_linssh EMPTY MODULE Fixed in time vertical coordinate |
---|
41 | !!---------------------------------------------------------------------- |
---|
42 | #else |
---|
43 | !!---------------------------------------------------------------------- |
---|
44 | !! stp : OCE system time-stepping |
---|
45 | !!---------------------------------------------------------------------- |
---|
46 | USE step_oce ! time stepping definition modules |
---|
47 | |
---|
48 | IMPLICIT NONE |
---|
49 | PRIVATE |
---|
50 | |
---|
51 | PUBLIC stp ! called by nemogcm.F90 |
---|
52 | |
---|
53 | ! !** time level indices **! |
---|
54 | INTEGER, PUBLIC :: Nbb, Nnn, Naa, Nrhs !: used by nemo_init |
---|
55 | |
---|
56 | !! * Substitutions |
---|
57 | # include "do_loop_substitute.h90" |
---|
58 | !!---------------------------------------------------------------------- |
---|
59 | !! NEMO/OCE 4.0 , NEMO Consortium (2018) |
---|
60 | !! $Id$ |
---|
61 | !! Software governed by the CeCILL license (see ./LICENSE) |
---|
62 | !!---------------------------------------------------------------------- |
---|
63 | CONTAINS |
---|
64 | |
---|
65 | #if defined key_agrif |
---|
66 | RECURSIVE SUBROUTINE stp( ) |
---|
67 | INTEGER :: kstp ! ocean time-step index |
---|
68 | #else |
---|
69 | SUBROUTINE stp( kstp ) |
---|
70 | INTEGER, INTENT(in) :: kstp ! ocean time-step index |
---|
71 | #endif |
---|
72 | !!---------------------------------------------------------------------- |
---|
73 | !! *** ROUTINE stp *** |
---|
74 | !! |
---|
75 | !! ** Purpose : - Time stepping of OCE (momentum and active tracer eqs.) |
---|
76 | !! - Time stepping of SI3 (dynamic and thermodynamic eqs.) |
---|
77 | !! - Time stepping of TRC (passive tracer eqs.) |
---|
78 | !! |
---|
79 | !! ** Method : -1- Update forcings and data |
---|
80 | !! -2- Update ocean physics |
---|
81 | !! -3- Compute the t and s trends |
---|
82 | !! -4- Update t and s |
---|
83 | !! -5- Compute the momentum trends |
---|
84 | !! -6- Update the horizontal velocity |
---|
85 | !! -7- Compute the diagnostics variables (rd,N2, hdiv,w) |
---|
86 | !! -8- Outputs and diagnostics |
---|
87 | !!---------------------------------------------------------------------- |
---|
88 | INTEGER :: ji, jj, jk, jtile ! dummy loop indice |
---|
89 | !! --------------------------------------------------------------------- |
---|
90 | #if defined key_agrif |
---|
91 | IF( nstop > 0 ) RETURN ! avoid to go further if an error was detected during previous time step (child grid) |
---|
92 | kstp = nit000 + Agrif_Nb_Step() |
---|
93 | Kbb_a = Nbb; Kmm_a = Nnn; Krhs_a = Nrhs ! agrif_oce module copies of time level indices |
---|
94 | IF( lk_agrif_debug ) THEN |
---|
95 | IF( Agrif_Root() .and. lwp) WRITE(*,*) '---' |
---|
96 | IF(lwp) WRITE(*,*) 'Grid Number', Agrif_Fixed(),' time step ', kstp, 'int tstep', Agrif_NbStepint() |
---|
97 | ENDIF |
---|
98 | IF( kstp == nit000 + 1 ) lk_agrif_fstep = .FALSE. |
---|
99 | # if defined key_xios |
---|
100 | IF( Agrif_Nbstepint() == 0 ) CALL iom_swap( cxios_context ) |
---|
101 | # endif |
---|
102 | #endif |
---|
103 | ! |
---|
104 | IF( ln_timing ) CALL timing_start('stp') |
---|
105 | ! |
---|
106 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
---|
107 | ! model timestep |
---|
108 | !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< |
---|
109 | ! |
---|
110 | IF( l_1st_euler ) THEN ! start or restart with Euler 1st time-step |
---|
111 | rDt = rn_Dt |
---|
112 | r1_Dt = 1._wp / rDt |
---|
113 | ENDIF |
---|
114 | ! |
---|
115 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
---|
116 | ! update I/O and calendar |
---|
117 | !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< |
---|
118 | ! |
---|
119 | IF( kstp == nit000 ) THEN ! initialize IOM context (must be done after nemo_init for AGRIF+XIOS+OASIS) |
---|
120 | CALL iom_init( cxios_context, ld_closedef=.FALSE. ) ! for model grid (including possible AGRIF zoom) |
---|
121 | IF( lk_diamlr ) CALL dia_mlr_iom_init ! with additional setup for multiple-linear-regression analysis |
---|
122 | CALL iom_init_closedef |
---|
123 | IF( ln_crs ) CALL iom_init( TRIM(cxios_context)//"_crs" ) ! for coarse grid |
---|
124 | ENDIF |
---|
125 | IF( kstp == nitrst .AND. lwxios ) THEN |
---|
126 | CALL iom_swap( cw_ocerst_cxt ) |
---|
127 | CALL iom_init_closedef( cw_ocerst_cxt ) |
---|
128 | CALL iom_setkt( kstp - nit000 + 1, cw_ocerst_cxt ) |
---|
129 | #if defined key_top |
---|
130 | CALL iom_swap( cw_toprst_cxt ) |
---|
131 | CALL iom_init_closedef( cw_toprst_cxt ) |
---|
132 | CALL iom_setkt( kstp - nit000 + 1, cw_toprst_cxt ) |
---|
133 | #endif |
---|
134 | ENDIF |
---|
135 | IF( kstp + nn_fsbc - 1 == nitrst .AND. lwxios ) THEN |
---|
136 | #if defined key_si3 |
---|
137 | CALL iom_swap( cw_icerst_cxt ) |
---|
138 | CALL iom_init_closedef( cw_icerst_cxt ) |
---|
139 | CALL iom_setkt( kstp - nit000 + 1, cw_icerst_cxt ) |
---|
140 | #endif |
---|
141 | IF( ln_abl ) THEN |
---|
142 | CALL iom_swap( cw_ablrst_cxt ) |
---|
143 | CALL iom_init_closedef( cw_ablrst_cxt ) |
---|
144 | CALL iom_setkt( kstp - nit000 + 1, cw_ablrst_cxt ) |
---|
145 | ENDIF |
---|
146 | ENDIF |
---|
147 | IF( kstp /= nit000 ) CALL day( kstp ) ! Calendar (day was already called at nit000 in day_init) |
---|
148 | CALL iom_setkt( kstp - nit000 + 1, cxios_context ) ! tell IOM we are at time step kstp |
---|
149 | IF( ln_crs ) CALL iom_setkt( kstp - nit000 + 1, TRIM(cxios_context)//"_crs" ) ! tell IOM we are at time step kstp |
---|
150 | |
---|
151 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
---|
152 | ! Update external forcing (tides, open boundaries, ice shelf interaction and surface boundary condition (including sea-ice) |
---|
153 | !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< |
---|
154 | IF( ln_tide ) CALL tide_update( kstp ) ! update tide potential |
---|
155 | IF( ln_apr_dyn ) CALL sbc_apr ( kstp ) ! atmospheric pressure (NB: call before bdy_dta which needs ssh_ib) |
---|
156 | IF( ln_bdy ) CALL bdy_dta ( kstp, Nnn ) ! update dynamic & tracer data at open boundaries |
---|
157 | IF( ln_isf ) CALL isf_stp ( kstp, Nnn ) |
---|
158 | CALL sbc ( kstp, Nbb, Nnn ) ! Sea Boundary Condition (including sea-ice) |
---|
159 | |
---|
160 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
---|
161 | ! Update stochastic parameters and random T/S fluctuations |
---|
162 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
---|
163 | IF( ln_sto_eos ) CALL sto_par( kstp ) ! Stochastic parameters |
---|
164 | IF( ln_sto_eos ) CALL sto_pts( ts(:,:,:,:,Nnn) ) ! Random T/S fluctuations |
---|
165 | |
---|
166 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
---|
167 | ! Ocean physics update |
---|
168 | !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< |
---|
169 | ! THERMODYNAMICS |
---|
170 | CALL eos_rab( ts(:,:,:,:,Nbb), rab_b, Nnn ) ! before local thermal/haline expension ratio at T-points |
---|
171 | CALL eos_rab( ts(:,:,:,:,Nnn), rab_n, Nnn ) ! now local thermal/haline expension ratio at T-points |
---|
172 | CALL bn2 ( ts(:,:,:,:,Nbb), rab_b, rn2b, Nnn ) ! before Brunt-Vaisala frequency |
---|
173 | CALL bn2 ( ts(:,:,:,:,Nnn), rab_n, rn2, Nnn ) ! now Brunt-Vaisala frequency |
---|
174 | |
---|
175 | ! VERTICAL PHYSICS |
---|
176 | CALL zdf_phy( kstp, Nbb, Nnn, Nrhs ) ! vertical physics update (top/bot drag, avt, avs, avm + MLD) |
---|
177 | |
---|
178 | ! LATERAL PHYSICS |
---|
179 | ! |
---|
180 | IF( l_ldfslp ) THEN ! slope of lateral mixing |
---|
181 | CALL eos( ts(:,:,:,:,Nbb), rhd, gdept_0(:,:,:) ) ! before in situ density |
---|
182 | |
---|
183 | IF( ln_zps .AND. .NOT. ln_isfcav) & |
---|
184 | & CALL zps_hde ( kstp, Nnn, jpts, ts(:,:,:,:,Nbb), gtsu, gtsv, & ! Partial steps: before horizontal gradient |
---|
185 | & rhd, gru , grv ) ! of t, s, rd at the last ocean level |
---|
186 | |
---|
187 | IF( ln_zps .AND. ln_isfcav) & |
---|
188 | & CALL zps_hde_isf( kstp, Nnn, jpts, ts(:,:,:,:,Nbb), gtsu, gtsv, gtui, gtvi, & ! Partial steps for top cell (ISF) |
---|
189 | & rhd, gru , grv , grui, grvi ) ! of t, s, rd at the first ocean level |
---|
190 | IF( ln_traldf_triad ) THEN |
---|
191 | CALL ldf_slp_triad( kstp, Nbb, Nnn ) ! before slope for triad operator |
---|
192 | ELSE |
---|
193 | CALL ldf_slp ( kstp, rhd, rn2b, Nbb, Nnn ) ! before slope for standard operator |
---|
194 | ENDIF |
---|
195 | ENDIF |
---|
196 | ! ! eddy diffusivity coeff. |
---|
197 | IF( l_ldftra_time .OR. l_ldfeiv_time ) CALL ldf_tra( kstp, Nbb, Nnn ) ! and/or eiv coeff. |
---|
198 | IF( l_ldfdyn_time ) CALL ldf_dyn( kstp, Nbb ) ! eddy viscosity coeff. |
---|
199 | |
---|
200 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
---|
201 | ! Ocean dynamics : hdiv, ssh, e3, u, v, w |
---|
202 | !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< |
---|
203 | |
---|
204 | CALL ssh_nxt ( kstp, Nbb, Nnn, ssh, Naa ) ! after ssh (includes call to div_hor) |
---|
205 | IF( .NOT.ln_linssh ) & |
---|
206 | & CALL dom_vvl_sf_nxt( kstp, Nbb, Nnn, Naa ) ! after vertical scale factors |
---|
207 | CALL wzv ( kstp, Nbb, Nnn, Naa, ww ) ! now cross-level velocity |
---|
208 | IF( ln_zad_Aimp ) CALL wAimp ( kstp, Nnn ) ! Adaptive-implicit vertical advection partitioning |
---|
209 | CALL eos ( ts(:,:,:,:,Nnn), rhd, rhop, gdept(:,:,:,Nnn) ) ! now in situ density for hpg computation |
---|
210 | |
---|
211 | |
---|
212 | uu(:,:,:,Nrhs) = 0._wp ! set dynamics trends to zero |
---|
213 | vv(:,:,:,Nrhs) = 0._wp |
---|
214 | |
---|
215 | IF( lk_asminc .AND. ln_asmiau .AND. ln_dyninc ) & |
---|
216 | & CALL dyn_asm_inc ( kstp, Nbb, Nnn, uu, vv, Nrhs ) ! apply dynamics assimilation increment |
---|
217 | IF( ln_bdy ) CALL bdy_dyn3d_dmp ( kstp, Nbb, uu, vv, Nrhs ) ! bdy damping trends |
---|
218 | #if defined key_agrif |
---|
219 | IF(.NOT. Agrif_Root()) & |
---|
220 | & CALL Agrif_Sponge_dyn ! momentum sponge |
---|
221 | #endif |
---|
222 | CALL dyn_adv( kstp, Nbb, Nnn , uu, vv, Nrhs ) ! advection (VF or FF) ==> RHS |
---|
223 | CALL dyn_vor( kstp, Nnn , uu, vv, Nrhs ) ! vorticity ==> RHS |
---|
224 | CALL dyn_ldf( kstp, Nbb, Nnn , uu, vv, Nrhs ) ! lateral mixing |
---|
225 | IF( ln_zdfosm ) CALL dyn_osm( kstp, Nnn , uu, vv, Nrhs ) ! OSMOSIS non-local velocity fluxes ==> RHS |
---|
226 | CALL dyn_hpg( kstp, Nnn , uu, vv, Nrhs ) ! horizontal gradient of Hydrostatic pressure |
---|
227 | CALL dyn_spg( kstp, Nbb, Nnn, Nrhs, uu, vv, ssh, uu_b, vv_b, Naa ) ! surface pressure gradient |
---|
228 | |
---|
229 | ! With split-explicit free surface, since now transports have been updated and ssh(:,:,Nrhs) as well |
---|
230 | IF( ln_dynspg_ts ) THEN ! vertical scale factors and vertical velocity need to be updated |
---|
231 | CALL div_hor ( kstp, Nbb, Nnn ) ! Horizontal divergence (2nd call in time-split case) |
---|
232 | IF(.NOT.ln_linssh) CALL dom_vvl_sf_nxt( kstp, Nbb, Nnn, Naa, kcall=2 ) ! after vertical scale factors (update depth average component) |
---|
233 | ENDIF |
---|
234 | CALL dyn_zdf ( kstp, Nbb, Nnn, Nrhs, uu, vv, Naa ) ! vertical diffusion |
---|
235 | IF( ln_dynspg_ts ) THEN ! vertical scale factors and vertical velocity need to be updated |
---|
236 | CALL wzv ( kstp, Nbb, Nnn, Naa, ww ) ! Nnn cross-level velocity |
---|
237 | IF( ln_zad_Aimp ) CALL wAimp ( kstp, Nnn ) ! Adaptive-implicit vertical advection partitioning |
---|
238 | ENDIF |
---|
239 | |
---|
240 | |
---|
241 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
---|
242 | ! cool skin |
---|
243 | !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< |
---|
244 | IF ( ln_diurnal ) CALL diurnal_layers( kstp ) |
---|
245 | |
---|
246 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
---|
247 | ! diagnostics and outputs |
---|
248 | !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< |
---|
249 | IF( ln_floats ) CALL flo_stp ( kstp, Nbb, Nnn ) ! drifting Floats |
---|
250 | IF( ln_diacfl ) CALL dia_cfl ( kstp, Nnn ) ! Courant number diagnostics |
---|
251 | CALL dia_hth ( kstp, Nnn ) ! Thermocline depth (20 degres isotherm depth) |
---|
252 | IF( ln_diadct ) CALL dia_dct ( kstp, Nnn ) ! Transports |
---|
253 | CALL dia_ar5 ( kstp, Nnn ) ! ar5 diag |
---|
254 | CALL dia_ptr ( kstp, Nnn ) ! Poleward adv/ldf TRansports diagnostics |
---|
255 | CALL dia_wri ( kstp, Nnn ) ! ocean model: outputs |
---|
256 | IF( ln_crs ) CALL crs_fld ( kstp, Nnn ) ! ocean model: online field coarsening & output |
---|
257 | IF( lk_diadetide ) CALL dia_detide( kstp ) ! Weights computation for daily detiding of model diagnostics |
---|
258 | IF( lk_diamlr ) CALL dia_mlr ! Update time used in multiple-linear-regression analysis |
---|
259 | |
---|
260 | #if defined key_top |
---|
261 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
---|
262 | ! Passive Tracer Model |
---|
263 | !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< |
---|
264 | CALL trc_stp ( kstp, Nbb, Nnn, Nrhs, Naa ) ! time-stepping |
---|
265 | #endif |
---|
266 | |
---|
267 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
---|
268 | ! Active tracers |
---|
269 | !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< |
---|
270 | ! Loop over tile domains |
---|
271 | DO jtile = 1, nijtile |
---|
272 | IF( ln_tile ) CALL dom_tile( ntsi, ntsj, ntei, ntej, ktile = jtile ) |
---|
273 | |
---|
274 | DO_3D( 0, 0, 0, 0, 1, jpk ) |
---|
275 | ts(ji,jj,jk,:,Nrhs) = 0._wp ! set tracer trends to zero |
---|
276 | END_3D |
---|
277 | |
---|
278 | IF( lk_asminc .AND. ln_asmiau .AND. & |
---|
279 | & ln_trainc ) CALL tra_asm_inc( kstp, Nbb, Nnn, ts, Nrhs ) ! apply tracer assimilation increment |
---|
280 | CALL tra_sbc ( kstp, Nnn, ts, Nrhs ) ! surface boundary condition |
---|
281 | IF( ln_traqsr ) CALL tra_qsr ( kstp, Nnn, ts, Nrhs ) ! penetrative solar radiation qsr |
---|
282 | IF( ln_isf ) CALL tra_isf ( kstp, Nnn, ts, Nrhs ) ! ice shelf heat flux |
---|
283 | IF( ln_trabbc ) CALL tra_bbc ( kstp, Nnn, ts, Nrhs ) ! bottom heat flux |
---|
284 | IF( ln_trabbl ) CALL tra_bbl ( kstp, Nbb, Nnn, ts, Nrhs ) ! advective (and/or diffusive) bottom boundary layer scheme |
---|
285 | IF( ln_tradmp ) CALL tra_dmp ( kstp, Nbb, Nnn, ts, Nrhs ) ! internal damping trends |
---|
286 | IF( ln_bdy ) CALL bdy_tra_dmp( kstp, Nbb, ts, Nrhs ) ! bdy damping trends |
---|
287 | END DO |
---|
288 | |
---|
289 | #if defined key_agrif |
---|
290 | IF(.NOT. Agrif_Root() ) THEN |
---|
291 | IF( ln_tile ) CALL dom_tile( ntsi, ntsj, ntei, ntej, ktile = 0 ) |
---|
292 | CALL Agrif_Sponge_tra ! tracers sponge |
---|
293 | ENDIF |
---|
294 | #endif |
---|
295 | |
---|
296 | ! TEMP: [tiling] Separate loop over tile domains (due to tra_adv workarounds for tiling) |
---|
297 | DO jtile = 1, nijtile |
---|
298 | IF( ln_tile ) CALL dom_tile( ntsi, ntsj, ntei, ntej, ktile = jtile ) |
---|
299 | |
---|
300 | CALL tra_adv ( kstp, Nbb, Nnn, ts, Nrhs ) ! hor. + vert. advection ==> RHS |
---|
301 | IF( ln_zdfmfc ) CALL tra_mfc ( kstp, Nbb, ts, Nrhs ) ! Mass Flux Convection |
---|
302 | IF( ln_zdfosm ) THEN |
---|
303 | CALL tra_osm ( kstp, Nnn, ts, Nrhs ) ! OSMOSIS non-local tracer fluxes ==> RHS |
---|
304 | IF( lrst_oce ) CALL osm_rst ( kstp, Nnn, 'WRITE' ) ! write OSMOSIS outputs + ww (so must do here) to restarts |
---|
305 | ENDIF |
---|
306 | CALL tra_ldf ( kstp, Nbb, Nnn, ts, Nrhs ) ! lateral mixing |
---|
307 | |
---|
308 | CALL tra_zdf ( kstp, Nbb, Nnn, Nrhs, ts, Naa ) ! vertical mixing and after tracer fields |
---|
309 | IF( ln_zdfnpc ) CALL tra_npc ( kstp, Nnn, Nrhs, ts, Naa ) ! update after fields by non-penetrative convection |
---|
310 | END DO |
---|
311 | |
---|
312 | IF( ln_tile ) CALL dom_tile( ntsi, ntsj, ntei, ntej, ktile = 0 ) ! Revert to tile over full domain |
---|
313 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
---|
314 | ! Set boundary conditions, time filter and swap time levels |
---|
315 | !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< |
---|
316 | !!jc1: For agrif, it would be much better to finalize tracers/momentum here (e.g. bdy conditions) and move the swap |
---|
317 | !! (and time filtering) after Agrif update. Then restart would be done after and would contain updated fields. |
---|
318 | !! If so: |
---|
319 | !! (i) no need to call agrif update at initialization time |
---|
320 | !! (ii) no need to update "before" fields |
---|
321 | !! |
---|
322 | !! Apart from creating new tra_swp/dyn_swp routines, this however: |
---|
323 | !! (i) makes boundary conditions at initialization time computed from updated fields which is not the case between |
---|
324 | !! two restarts => restartability issue. One can circumvent this, maybe, by assuming "interface separation", |
---|
325 | !! e.g. a shift of the feedback interface inside child domain. |
---|
326 | !! (ii) requires that all restart outputs of updated variables by agrif (e.g. passive tracers/tke/barotropic arrays) are done at the same |
---|
327 | !! place. |
---|
328 | !! |
---|
329 | !!jc2: dynnxt must be the latest call. e3t(:,:,:,Nbb) are indeed updated in that routine |
---|
330 | CALL tra_atf ( kstp, Nbb, Nnn, Naa, ts ) ! time filtering of "now" tracer arrays |
---|
331 | CALL dyn_atf ( kstp, Nbb, Nnn, Naa, uu, vv, e3t, e3u, e3v ) ! time filtering of "now" velocities and scale factors |
---|
332 | CALL ssh_atf ( kstp, Nbb, Nnn, Naa, ssh ) ! time filtering of "now" sea surface height |
---|
333 | ! |
---|
334 | ! Swap time levels |
---|
335 | Nrhs = Nbb |
---|
336 | Nbb = Nnn |
---|
337 | Nnn = Naa |
---|
338 | Naa = Nrhs |
---|
339 | ! |
---|
340 | IF(.NOT.ln_linssh) CALL dom_vvl_sf_update( kstp, Nbb, Nnn, Naa ) ! recompute vertical scale factors |
---|
341 | ! |
---|
342 | IF( ln_diahsb ) CALL dia_hsb ( kstp, Nbb, Nnn ) ! - ML - global conservation diagnostics |
---|
343 | |
---|
344 | !!gm : This does not only concern the dynamics ==>>> add a new title |
---|
345 | !!gm2: why ouput restart before AGRIF update? |
---|
346 | !! |
---|
347 | !!jc: That would be better, but see comment above |
---|
348 | !! |
---|
349 | IF( lrst_oce ) CALL rst_write ( kstp, Nbb, Nnn ) ! write output ocean restart file |
---|
350 | IF( ln_sto_eos ) CALL sto_rst_write( kstp ) ! write restart file for stochastic parameters |
---|
351 | |
---|
352 | #if defined key_agrif |
---|
353 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
---|
354 | ! AGRIF recursive integration |
---|
355 | !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< |
---|
356 | Kbb_a = Nbb; Kmm_a = Nnn; Krhs_a = Nrhs ! agrif_oce module copies of time level indices |
---|
357 | CALL Agrif_Integrate_ChildGrids( stp ) ! allows to finish all the Child Grids before updating |
---|
358 | |
---|
359 | #endif |
---|
360 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
---|
361 | ! Control |
---|
362 | !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< |
---|
363 | CALL stp_ctl ( kstp, Nnn ) |
---|
364 | |
---|
365 | #if defined key_agrif |
---|
366 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
---|
367 | ! AGRIF update |
---|
368 | !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< |
---|
369 | IF( Agrif_NbStepint() == 0 .AND. nstop == 0 ) & |
---|
370 | & CALL Agrif_update_all( ) ! Update all components |
---|
371 | |
---|
372 | #endif |
---|
373 | IF( ln_diaobs .AND. nstop == 0 ) & |
---|
374 | & CALL dia_obs( kstp, Nnn ) ! obs-minus-model (assimilation) diags (after dynamics update) |
---|
375 | |
---|
376 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
---|
377 | ! File manipulation at the end of the first time step |
---|
378 | !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< |
---|
379 | IF( kstp == nit000 ) THEN ! 1st time step only |
---|
380 | CALL iom_close( numror ) ! close input ocean restart file |
---|
381 | IF( lrxios ) CALL iom_context_finalize( cr_ocerst_cxt ) |
---|
382 | IF(lwm) CALL FLUSH ( numond ) ! flush output namelist oce |
---|
383 | IF(lwm .AND. numoni /= -1 ) CALL FLUSH ( numoni ) ! flush output namelist ice (if exist) |
---|
384 | ENDIF |
---|
385 | |
---|
386 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
---|
387 | ! Coupled mode |
---|
388 | !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< |
---|
389 | IF( lk_oasis .AND. nstop == 0 ) CALL sbc_cpl_snd( kstp, Nbb, Nnn ) ! coupled mode : field exchanges |
---|
390 | ! |
---|
391 | #if defined key_xios |
---|
392 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
---|
393 | ! Finalize contextes if end of simulation or error detected |
---|
394 | !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< |
---|
395 | IF( kstp == nitend .OR. nstop > 0 ) THEN |
---|
396 | CALL iom_context_finalize( cxios_context ) ! needed for XIOS+AGRIF |
---|
397 | IF( ln_crs ) CALL iom_context_finalize( trim(cxios_context)//"_crs" ) ! |
---|
398 | ENDIF |
---|
399 | #endif |
---|
400 | ! |
---|
401 | IF( l_1st_euler ) THEN ! recover Leap-frog timestep |
---|
402 | rDt = 2._wp * rn_Dt |
---|
403 | r1_Dt = 1._wp / rDt |
---|
404 | l_1st_euler = .FALSE. |
---|
405 | ENDIF |
---|
406 | ! |
---|
407 | IF( ln_timing ) CALL timing_stop('stp') |
---|
408 | ! |
---|
409 | END SUBROUTINE stp |
---|
410 | ! |
---|
411 | #endif |
---|
412 | !!====================================================================== |
---|
413 | END MODULE step |
---|