1 | MODULE sbcblk_algo_ecmwf |
---|
2 | !!====================================================================== |
---|
3 | !! *** MODULE sbcblk_algo_ecmwf *** |
---|
4 | !! Computes turbulent components of surface fluxes |
---|
5 | !! according to the method in IFS of the ECMWF model |
---|
6 | !! |
---|
7 | !! * bulk transfer coefficients C_D, C_E and C_H |
---|
8 | !! * air temp. and spec. hum. adjusted from zt (2m) to zu (10m) if needed |
---|
9 | !! * the effective bulk wind speed at 10m U_blk |
---|
10 | !! => all these are used in bulk formulas in sbcblk.F90 |
---|
11 | !! |
---|
12 | !! Using the bulk formulation/param. of IFS of ECMWF (cycle 31r2) |
---|
13 | !! based on IFS doc (avaible online on the ECMWF's website) |
---|
14 | !! |
---|
15 | !! |
---|
16 | !! Routine turb_ecmwf maintained and developed in AeroBulk |
---|
17 | !! (http://aerobulk.sourceforge.net/) |
---|
18 | !! |
---|
19 | !! ** Author: L. Brodeau, june 2016 / AeroBulk (https://sourceforge.net/p/aerobulk) |
---|
20 | !!---------------------------------------------------------------------- |
---|
21 | !! History : 4.0 ! 2016-02 (L.Brodeau) Original code |
---|
22 | !!---------------------------------------------------------------------- |
---|
23 | |
---|
24 | !!---------------------------------------------------------------------- |
---|
25 | !! turb_ecmwf : computes the bulk turbulent transfer coefficients |
---|
26 | !! adjusts t_air and q_air from zt to zu m |
---|
27 | !! returns the effective bulk wind speed at 10m |
---|
28 | !!---------------------------------------------------------------------- |
---|
29 | USE oce ! ocean dynamics and tracers |
---|
30 | USE dom_oce ! ocean space and time domain |
---|
31 | USE phycst ! physical constants |
---|
32 | USE iom ! I/O manager library |
---|
33 | USE lib_mpp ! distribued memory computing library |
---|
34 | USE in_out_manager ! I/O manager |
---|
35 | USE prtctl ! Print control |
---|
36 | USE sbcwave, ONLY : cdn_wave ! wave module |
---|
37 | #if defined key_si3 || defined key_cice |
---|
38 | USE sbc_ice ! Surface boundary condition: ice fields |
---|
39 | #endif |
---|
40 | USE lib_fortran ! to use key_nosignedzero |
---|
41 | |
---|
42 | USE sbc_oce ! Surface boundary condition: ocean fields |
---|
43 | |
---|
44 | IMPLICIT NONE |
---|
45 | PRIVATE |
---|
46 | |
---|
47 | PUBLIC :: TURB_ECMWF ! called by sbcblk.F90 |
---|
48 | |
---|
49 | ! !! ECMWF own values for given constants, taken form IFS documentation... |
---|
50 | REAL(wp), PARAMETER :: charn0 = 0.018 ! Charnock constant (pretty high value here !!! |
---|
51 | ! ! => Usually 0.011 for moderate winds) |
---|
52 | REAL(wp), PARAMETER :: zi0 = 1000. ! scale height of the atmospheric boundary layer...1 |
---|
53 | REAL(wp), PARAMETER :: Beta0 = 1. ! gustiness parameter ( = 1.25 in COAREv3) |
---|
54 | REAL(wp), PARAMETER :: rctv0 = 0.608 ! constant to obtain virtual temperature... |
---|
55 | REAL(wp), PARAMETER :: Cp_dry = 1005.0 ! Specic heat of dry air, constant pressure [J/K/kg] |
---|
56 | REAL(wp), PARAMETER :: Cp_vap = 1860.0 ! Specic heat of water vapor, constant pressure [J/K/kg] |
---|
57 | REAL(wp), PARAMETER :: alpha_M = 0.11 ! For roughness length (smooth surface term) |
---|
58 | REAL(wp), PARAMETER :: alpha_H = 0.40 ! (Chapter 3, p.34, IFS doc Cy31r1) |
---|
59 | REAL(wp), PARAMETER :: alpha_Q = 0.62 ! |
---|
60 | !!---------------------------------------------------------------------- |
---|
61 | CONTAINS |
---|
62 | |
---|
63 | SUBROUTINE TURB_ECMWF( zt, zu, sst, t_zt, ssq , q_zt , U_zu, & |
---|
64 | & Cd, Ch, Ce , t_zu, q_zu, U_blk, & |
---|
65 | & Cdn, Chn, Cen ) |
---|
66 | !!---------------------------------------------------------------------------------- |
---|
67 | !! *** ROUTINE turb_ecmwf *** |
---|
68 | !! |
---|
69 | !! 2015: L. Brodeau (brodeau@gmail.com) |
---|
70 | !! |
---|
71 | !! ** Purpose : Computes turbulent transfert coefficients of surface |
---|
72 | !! fluxes according to IFS doc. (cycle 31) |
---|
73 | !! If relevant (zt /= zu), adjust temperature and humidity from height zt to zu |
---|
74 | !! |
---|
75 | !! ** Method : Monin Obukhov Similarity Theory |
---|
76 | !! |
---|
77 | !! INPUT : |
---|
78 | !! ------- |
---|
79 | !! * zt : height for temperature and spec. hum. of air [m] |
---|
80 | !! * zu : height for wind speed (generally 10m) [m] |
---|
81 | !! * U_zu : scalar wind speed at 10m [m/s] |
---|
82 | !! * sst : SST [K] |
---|
83 | !! * t_zt : potential air temperature at zt [K] |
---|
84 | !! * ssq : specific humidity at saturation at SST [kg/kg] |
---|
85 | !! * q_zt : specific humidity of air at zt [kg/kg] |
---|
86 | !! |
---|
87 | !! |
---|
88 | !! OUTPUT : |
---|
89 | !! -------- |
---|
90 | !! * Cd : drag coefficient |
---|
91 | !! * Ch : sensible heat coefficient |
---|
92 | !! * Ce : evaporation coefficient |
---|
93 | !! * t_zu : pot. air temperature adjusted at wind height zu [K] |
---|
94 | !! * q_zu : specific humidity of air // [kg/kg] |
---|
95 | !! * U_blk : bulk wind at 10m [m/s] |
---|
96 | !! |
---|
97 | !! |
---|
98 | !! ** Author: L. Brodeau, june 2016 / AeroBulk (https://sourceforge.net/p/aerobulk) |
---|
99 | !!---------------------------------------------------------------------------------- |
---|
100 | REAL(wp), INTENT(in ) :: zt ! height for t_zt and q_zt [m] |
---|
101 | REAL(wp), INTENT(in ) :: zu ! height for U_zu [m] |
---|
102 | REAL(wp), INTENT(in ), DIMENSION(jpi,jpj) :: sst ! sea surface temperature [Kelvin] |
---|
103 | REAL(wp), INTENT(in ), DIMENSION(jpi,jpj) :: t_zt ! potential air temperature [Kelvin] |
---|
104 | REAL(wp), INTENT(in ), DIMENSION(jpi,jpj) :: ssq ! sea surface specific humidity [kg/kg] |
---|
105 | REAL(wp), INTENT(in ), DIMENSION(jpi,jpj) :: q_zt ! specific air humidity [kg/kg] |
---|
106 | REAL(wp), INTENT(in ), DIMENSION(jpi,jpj) :: U_zu ! relative wind module at zu [m/s] |
---|
107 | REAL(wp), INTENT( out), DIMENSION(jpi,jpj) :: Cd ! transfer coefficient for momentum (tau) |
---|
108 | REAL(wp), INTENT( out), DIMENSION(jpi,jpj) :: Ch ! transfer coefficient for sensible heat (Q_sens) |
---|
109 | REAL(wp), INTENT( out), DIMENSION(jpi,jpj) :: Ce ! transfert coefficient for evaporation (Q_lat) |
---|
110 | REAL(wp), INTENT( out), DIMENSION(jpi,jpj) :: t_zu ! pot. air temp. adjusted at zu [K] |
---|
111 | REAL(wp), INTENT( out), DIMENSION(jpi,jpj) :: q_zu ! spec. humidity adjusted at zu [kg/kg] |
---|
112 | REAL(wp), INTENT( out), DIMENSION(jpi,jpj) :: U_blk ! bulk wind at 10m [m/s] |
---|
113 | REAL(wp), INTENT( out), DIMENSION(jpi,jpj) :: Cdn, Chn, Cen ! neutral transfer coefficients |
---|
114 | ! |
---|
115 | INTEGER :: j_itt |
---|
116 | LOGICAL :: l_zt_equal_zu = .FALSE. ! if q and t are given at same height as U |
---|
117 | INTEGER , PARAMETER :: nb_itt = 4 ! number of itterations |
---|
118 | ! |
---|
119 | REAL(wp), DIMENSION(jpi,jpj) :: u_star, t_star, q_star, & |
---|
120 | & dt_zu, dq_zu, & |
---|
121 | & znu_a, & !: Nu_air, Viscosity of air |
---|
122 | & Linv, & !: 1/L (inverse of Monin Obukhov length... |
---|
123 | & z0, z0t, z0q |
---|
124 | REAL(wp), DIMENSION(jpi,jpj) :: func_m, func_h |
---|
125 | REAL(wp), DIMENSION(jpi,jpj) :: ztmp0, ztmp1, ztmp2 |
---|
126 | !!---------------------------------------------------------------------------------- |
---|
127 | ! |
---|
128 | ! Identical first gess as in COARE, with IFS parameter values though |
---|
129 | ! |
---|
130 | l_zt_equal_zu = .FALSE. |
---|
131 | IF( ABS(zu - zt) < 0.01 ) l_zt_equal_zu = .TRUE. ! testing "zu == zt" is risky with double precision |
---|
132 | |
---|
133 | |
---|
134 | !! First guess of temperature and humidity at height zu: |
---|
135 | t_zu = MAX( t_zt , 0.0 ) ! who knows what's given on masked-continental regions... |
---|
136 | q_zu = MAX( q_zt , 1.e-6) ! " |
---|
137 | |
---|
138 | !! Pot. temp. difference (and we don't want it to be 0!) |
---|
139 | dt_zu = t_zu - sst ; dt_zu = SIGN( MAX(ABS(dt_zu),1.e-6), dt_zu ) |
---|
140 | dq_zu = q_zu - ssq ; dq_zu = SIGN( MAX(ABS(dq_zu),1.e-9), dq_zu ) |
---|
141 | |
---|
142 | znu_a = visc_air(t_zt) ! Air viscosity (m^2/s) at zt given from temperature in (K) |
---|
143 | |
---|
144 | ztmp2 = 0.5 * 0.5 ! initial guess for wind gustiness contribution |
---|
145 | U_blk = SQRT(U_zu*U_zu + ztmp2) |
---|
146 | |
---|
147 | ! z0 = 0.0001 |
---|
148 | ztmp2 = 10000. ! optimization: ztmp2 == 1/z0 |
---|
149 | ztmp0 = LOG(zu*ztmp2) |
---|
150 | ztmp1 = LOG(10.*ztmp2) |
---|
151 | u_star = 0.035*U_blk*ztmp1/ztmp0 ! (u* = 0.035*Un10) |
---|
152 | |
---|
153 | z0 = charn0*u_star*u_star/grav + 0.11*znu_a/u_star |
---|
154 | z0t = 0.1*EXP(vkarmn/(0.00115/(vkarmn/ztmp1))) ! WARNING: 1/z0t ! |
---|
155 | |
---|
156 | Cd = (vkarmn/ztmp0)**2 ! first guess of Cd |
---|
157 | |
---|
158 | ztmp0 = vkarmn*vkarmn/LOG(zt*z0t)/Cd |
---|
159 | |
---|
160 | ztmp2 = Ri_bulk( zu, t_zu, dt_zu, q_zu, dq_zu, U_blk ) ! Ribu = Bulk Richardson number |
---|
161 | |
---|
162 | !! First estimate of zeta_u, depending on the stability, ie sign of Ribu (ztmp2): |
---|
163 | ztmp1 = 0.5 + SIGN( 0.5 , ztmp2 ) |
---|
164 | func_m = ztmp0*ztmp2 ! temporary array !! |
---|
165 | !! Ribu < 0 Ribu > 0 Beta = 1.25 |
---|
166 | func_h = (1.-ztmp1)*(func_m/(1.+ztmp2/(-zu/(zi0*0.004*Beta0**3)))) & ! temporary array !!! func_h == zeta_u |
---|
167 | & + ztmp1*(func_m*(1. + 27./9.*ztmp2/ztmp0)) |
---|
168 | |
---|
169 | !! First guess M-O stability dependent scaling params.(u*,t*,q*) to estimate z0 and z/L |
---|
170 | ztmp0 = vkarmn/(LOG(zu*z0t) - psi_h_ecmwf(func_h)) |
---|
171 | |
---|
172 | u_star = U_blk*vkarmn/(LOG(zu) - LOG(z0) - psi_m_ecmwf(func_h)) |
---|
173 | t_star = dt_zu*ztmp0 |
---|
174 | q_star = dq_zu*ztmp0 |
---|
175 | |
---|
176 | ! What's need to be done if zt /= zu: |
---|
177 | IF( .NOT. l_zt_equal_zu ) THEN |
---|
178 | ! |
---|
179 | !! First update of values at zu (or zt for wind) |
---|
180 | ztmp0 = psi_h_ecmwf(func_h) - psi_h_ecmwf(zt*func_h/zu) ! zt*func_h/zu == zeta_t |
---|
181 | ztmp1 = log(zt/zu) + ztmp0 |
---|
182 | t_zu = t_zt - t_star/vkarmn*ztmp1 |
---|
183 | q_zu = q_zt - q_star/vkarmn*ztmp1 |
---|
184 | q_zu = (0.5 + sign(0.5,q_zu))*q_zu !Makes it impossible to have negative humidity : |
---|
185 | |
---|
186 | dt_zu = t_zu - sst ; dt_zu = SIGN( MAX(ABS(dt_zu),1.E-6), dt_zu ) |
---|
187 | dq_zu = q_zu - ssq ; dq_zu = SIGN( MAX(ABS(dq_zu),1.E-9), dq_zu ) |
---|
188 | ! |
---|
189 | ENDIF |
---|
190 | |
---|
191 | |
---|
192 | !! => that was same first guess as in COARE... |
---|
193 | |
---|
194 | |
---|
195 | !! First guess of inverse of Monin-Obukov length (1/L) : |
---|
196 | ztmp0 = (1. + rctv0*q_zu) ! the factor to apply to temp. to get virt. temp... |
---|
197 | Linv = grav*vkarmn*(t_star*ztmp0 + rctv0*t_zu*q_star) / ( u_star*u_star * t_zu*ztmp0 ) |
---|
198 | |
---|
199 | !! Functions such as u* = U_blk*vkarmn/func_m |
---|
200 | ztmp1 = zu + z0 |
---|
201 | ztmp0 = ztmp1*Linv |
---|
202 | func_m = LOG(ztmp1) -LOG(z0) - psi_m_ecmwf(ztmp0) + psi_m_ecmwf(z0*Linv) |
---|
203 | func_h = LOG(ztmp1*z0t) - psi_h_ecmwf(ztmp0) + psi_h_ecmwf(1./z0t*Linv) |
---|
204 | |
---|
205 | |
---|
206 | !! ITERATION BLOCK |
---|
207 | !! *************** |
---|
208 | |
---|
209 | DO j_itt = 1, nb_itt |
---|
210 | |
---|
211 | !! Bulk Richardson Number at z=zu (Eq. 3.25) |
---|
212 | ztmp0 = Ri_bulk(zu, t_zu, dt_zu, q_zu, dq_zu, U_blk) |
---|
213 | |
---|
214 | !! New estimate of the inverse of the Monin-Obukhon length (Linv == zeta/zu) : |
---|
215 | Linv = ztmp0*func_m*func_m/func_h / zu ! From Eq. 3.23, Chap.3, p.33, IFS doc - Cy31r1 |
---|
216 | |
---|
217 | !! Update func_m with new Linv: |
---|
218 | ztmp1 = zu + z0 |
---|
219 | func_m = LOG(ztmp1) -LOG(z0) - psi_m_ecmwf(ztmp1*Linv) + psi_m_ecmwf(z0*Linv) |
---|
220 | |
---|
221 | !! Need to update roughness lengthes: |
---|
222 | u_star = U_blk*vkarmn/func_m |
---|
223 | ztmp2 = u_star*u_star |
---|
224 | ztmp1 = znu_a/u_star |
---|
225 | z0 = alpha_M*ztmp1 + charn0*ztmp2/grav |
---|
226 | z0t = alpha_H*ztmp1 ! eq.3.26, Chap.3, p.34, IFS doc - Cy31r1 |
---|
227 | z0q = alpha_Q*ztmp1 |
---|
228 | |
---|
229 | !! Update wind at 10m taking into acount convection-related wind gustiness: |
---|
230 | ! Only true when unstable (L<0) => when ztmp0 < 0 => - !!! |
---|
231 | ztmp2 = ztmp2 * (MAX(-zi0*Linv/vkarmn,0.))**(2./3.) ! => w*^2 (combining Eq. 3.8 and 3.18, hap.3, IFS doc - Cy31r1) |
---|
232 | !! => equivalent using Beta=1 (gustiness parameter, 1.25 for COARE, also zi0=600 in COARE..) |
---|
233 | U_blk = MAX(sqrt(U_zu*U_zu + ztmp2), 0.2) ! eq.3.17, Chap.3, p.32, IFS doc - Cy31r1 |
---|
234 | ! => 0.2 prevents U_blk to be 0 in stable case when U_zu=0. |
---|
235 | |
---|
236 | |
---|
237 | !! Need to update "theta" and "q" at zu in case they are given at different heights |
---|
238 | !! as well the air-sea differences: |
---|
239 | IF( .NOT. l_zt_equal_zu ) THEN |
---|
240 | |
---|
241 | !! Arrays func_m and func_h are free for a while so using them as temporary arrays... |
---|
242 | func_h = psi_h_ecmwf((zu+z0)*Linv) ! temporary array !!! |
---|
243 | func_m = psi_h_ecmwf((zt+z0)*Linv) ! temporary array !!! |
---|
244 | |
---|
245 | ztmp2 = psi_h_ecmwf(z0t*Linv) |
---|
246 | ztmp0 = func_h - ztmp2 |
---|
247 | ztmp1 = vkarmn/(LOG(zu+z0) - LOG(z0t) - ztmp0) |
---|
248 | t_star = dt_zu*ztmp1 |
---|
249 | ztmp2 = ztmp0 - func_m + ztmp2 |
---|
250 | ztmp1 = LOG(zt/zu) + ztmp2 |
---|
251 | t_zu = t_zt - t_star/vkarmn*ztmp1 |
---|
252 | |
---|
253 | ztmp2 = psi_h_ecmwf(z0q*Linv) |
---|
254 | ztmp0 = func_h - ztmp2 |
---|
255 | ztmp1 = vkarmn/(LOG(zu+z0) - LOG(z0q) - ztmp0) |
---|
256 | q_star = dq_zu*ztmp1 |
---|
257 | ztmp2 = ztmp0 - func_m + ztmp2 |
---|
258 | ztmp1 = log(zt/zu) + ztmp2 |
---|
259 | q_zu = q_zt - q_star/vkarmn*ztmp1 |
---|
260 | |
---|
261 | dt_zu = t_zu - sst ; dt_zu = SIGN( MAX(ABS(dt_zu),1.E-6), dt_zu ) |
---|
262 | dq_zu = q_zu - ssq ; dq_zu = SIGN( MAX(ABS(dq_zu),1.E-9), dq_zu ) |
---|
263 | |
---|
264 | END IF |
---|
265 | |
---|
266 | !! Updating because of updated z0 and z0t and new Linv... |
---|
267 | ztmp1 = zu + z0 |
---|
268 | ztmp0 = ztmp1*Linv |
---|
269 | func_m = log(ztmp1) - LOG(z0 ) - psi_m_ecmwf(ztmp0) + psi_m_ecmwf(z0 *Linv) |
---|
270 | func_h = log(ztmp1) - LOG(z0t) - psi_h_ecmwf(ztmp0) + psi_h_ecmwf(z0t*Linv) |
---|
271 | |
---|
272 | END DO |
---|
273 | |
---|
274 | Cd = vkarmn*vkarmn/(func_m*func_m) |
---|
275 | Ch = vkarmn*vkarmn/(func_m*func_h) |
---|
276 | ztmp1 = log((zu + z0)/z0q) - psi_h_ecmwf((zu + z0)*Linv) + psi_h_ecmwf(z0q*Linv) ! func_q |
---|
277 | Ce = vkarmn*vkarmn/(func_m*ztmp1) |
---|
278 | |
---|
279 | ztmp1 = zu + z0 |
---|
280 | Cdn = vkarmn*vkarmn / (log(ztmp1/z0 )*log(ztmp1/z0 )) |
---|
281 | Chn = vkarmn*vkarmn / (log(ztmp1/z0t)*log(ztmp1/z0t)) |
---|
282 | Cen = vkarmn*vkarmn / (log(ztmp1/z0q)*log(ztmp1/z0q)) |
---|
283 | |
---|
284 | END SUBROUTINE TURB_ECMWF |
---|
285 | |
---|
286 | |
---|
287 | FUNCTION psi_m_ecmwf( pzeta ) |
---|
288 | !!---------------------------------------------------------------------------------- |
---|
289 | !! Universal profile stability function for momentum |
---|
290 | !! ECMWF / as in IFS cy31r1 documentation, available online |
---|
291 | !! at ecmwf.int |
---|
292 | !! |
---|
293 | !! pzeta : stability paramenter, z/L where z is altitude measurement |
---|
294 | !! and L is M-O length |
---|
295 | !! |
---|
296 | !! ** Author: L. Brodeau, june 2016 / AeroBulk (https://sourceforge.net/p/aerobulk) |
---|
297 | !!---------------------------------------------------------------------------------- |
---|
298 | REAL(wp), DIMENSION(jpi,jpj) :: psi_m_ecmwf |
---|
299 | REAL(wp), DIMENSION(jpi,jpj), INTENT(in) :: pzeta |
---|
300 | ! |
---|
301 | INTEGER :: ji, jj ! dummy loop indices |
---|
302 | REAL(wp) :: zzeta, zx, ztmp, psi_unst, psi_stab, stab |
---|
303 | !!---------------------------------------------------------------------------------- |
---|
304 | ! |
---|
305 | DO jj = 1, jpj |
---|
306 | DO ji = 1, jpi |
---|
307 | ! |
---|
308 | zzeta = MIN( pzeta(ji,jj) , 5. ) !! Very stable conditions (L positif and big!): |
---|
309 | ! |
---|
310 | ! Unstable (Paulson 1970): |
---|
311 | ! eq.3.20, Chap.3, p.33, IFS doc - Cy31r1 |
---|
312 | zx = SQRT(ABS(1. - 16.*zzeta)) |
---|
313 | ztmp = 1. + SQRT(zx) |
---|
314 | ztmp = ztmp*ztmp |
---|
315 | psi_unst = LOG( 0.125*ztmp*(1. + zx) ) & |
---|
316 | & -2.*ATAN( SQRT(zx) ) + 0.5*rpi |
---|
317 | ! |
---|
318 | ! Unstable: |
---|
319 | ! eq.3.22, Chap.3, p.33, IFS doc - Cy31r1 |
---|
320 | psi_stab = -2./3.*(zzeta - 5./0.35)*EXP(-0.35*zzeta) & |
---|
321 | & - zzeta - 2./3.*5./0.35 |
---|
322 | ! |
---|
323 | ! Combining: |
---|
324 | stab = 0.5 + SIGN(0.5, zzeta) ! zzeta > 0 => stab = 1 |
---|
325 | ! |
---|
326 | psi_m_ecmwf(ji,jj) = (1. - stab) * psi_unst & ! (zzeta < 0) Unstable |
---|
327 | & + stab * psi_stab ! (zzeta > 0) Stable |
---|
328 | ! |
---|
329 | END DO |
---|
330 | END DO |
---|
331 | ! |
---|
332 | END FUNCTION psi_m_ecmwf |
---|
333 | |
---|
334 | |
---|
335 | FUNCTION psi_h_ecmwf( pzeta ) |
---|
336 | !!---------------------------------------------------------------------------------- |
---|
337 | !! Universal profile stability function for temperature and humidity |
---|
338 | !! ECMWF / as in IFS cy31r1 documentation, available online |
---|
339 | !! at ecmwf.int |
---|
340 | !! |
---|
341 | !! pzeta : stability paramenter, z/L where z is altitude measurement |
---|
342 | !! and L is M-O length |
---|
343 | !! |
---|
344 | !! ** Author: L. Brodeau, june 2016 / AeroBulk (https://sourceforge.net/p/aerobulk) |
---|
345 | !!---------------------------------------------------------------------------------- |
---|
346 | REAL(wp), DIMENSION(jpi,jpj) :: psi_h_ecmwf |
---|
347 | REAL(wp), DIMENSION(jpi,jpj), INTENT(in) :: pzeta |
---|
348 | ! |
---|
349 | INTEGER :: ji, jj ! dummy loop indices |
---|
350 | REAL(wp) :: zzeta, zx, psi_unst, psi_stab, stab |
---|
351 | !!---------------------------------------------------------------------------------- |
---|
352 | ! |
---|
353 | DO jj = 1, jpj |
---|
354 | DO ji = 1, jpi |
---|
355 | ! |
---|
356 | zzeta = MIN(pzeta(ji,jj) , 5.) ! Very stable conditions (L positif and big!): |
---|
357 | ! |
---|
358 | zx = ABS(1. - 16.*zzeta)**.25 ! this is actually (1/phi_m)**2 !!! |
---|
359 | ! ! eq.3.19, Chap.3, p.33, IFS doc - Cy31r1 |
---|
360 | ! Unstable (Paulson 1970) : |
---|
361 | psi_unst = 2.*LOG(0.5*(1. + zx*zx)) ! eq.3.20, Chap.3, p.33, IFS doc - Cy31r1 |
---|
362 | ! |
---|
363 | ! Stable: |
---|
364 | psi_stab = -2./3.*(zzeta - 5./0.35)*EXP(-0.35*zzeta) & ! eq.3.22, Chap.3, p.33, IFS doc - Cy31r1 |
---|
365 | & - ABS(1. + 2./3.*zzeta)**1.5 - 2./3.*5./0.35 + 1. |
---|
366 | ! LB: added ABS() to avoid NaN values when unstable, which contaminates the unstable solution... |
---|
367 | ! |
---|
368 | stab = 0.5 + SIGN(0.5, zzeta) ! zzeta > 0 => stab = 1 |
---|
369 | ! |
---|
370 | ! |
---|
371 | psi_h_ecmwf(ji,jj) = (1. - stab) * psi_unst & ! (zzeta < 0) Unstable |
---|
372 | & + stab * psi_stab ! (zzeta > 0) Stable |
---|
373 | ! |
---|
374 | END DO |
---|
375 | END DO |
---|
376 | ! |
---|
377 | END FUNCTION psi_h_ecmwf |
---|
378 | |
---|
379 | |
---|
380 | FUNCTION Ri_bulk( pz, ptz, pdt, pqz, pdq, pub ) |
---|
381 | !!---------------------------------------------------------------------------------- |
---|
382 | !! Bulk Richardson number (Eq. 3.25 IFS doc) |
---|
383 | !! |
---|
384 | !! ** Author: L. Brodeau, june 2016 / AeroBulk (https://sourceforge.net/p/aerobulk) |
---|
385 | !!---------------------------------------------------------------------------------- |
---|
386 | REAL(wp), DIMENSION(jpi,jpj) :: Ri_bulk ! |
---|
387 | ! |
---|
388 | REAL(wp) , INTENT(in) :: pz ! height above the sea [m] |
---|
389 | REAL(wp), DIMENSION(jpi,jpj), INTENT(in) :: ptz ! air temperature at pz m [K] |
---|
390 | REAL(wp), DIMENSION(jpi,jpj), INTENT(in) :: pdt ! ptz - sst [K] |
---|
391 | REAL(wp), DIMENSION(jpi,jpj), INTENT(in) :: pqz ! air temperature at pz m [kg/kg] |
---|
392 | REAL(wp), DIMENSION(jpi,jpj), INTENT(in) :: pdq ! pqz - ssq [kg/kg] |
---|
393 | REAL(wp), DIMENSION(jpi,jpj), INTENT(in) :: pub ! bulk wind speed [m/s] |
---|
394 | !!---------------------------------------------------------------------------------- |
---|
395 | ! |
---|
396 | Ri_bulk = grav*pz/(pub*pub) & |
---|
397 | & * ( pdt/(ptz - 0.5_wp*(pdt + grav*pz/(Cp_dry+Cp_vap*pqz))) & |
---|
398 | & + rctv0*pdq ) |
---|
399 | ! |
---|
400 | END FUNCTION Ri_bulk |
---|
401 | |
---|
402 | |
---|
403 | FUNCTION visc_air(ptak) |
---|
404 | !!---------------------------------------------------------------------------------- |
---|
405 | !! Air kinetic viscosity (m^2/s) given from temperature in degrees... |
---|
406 | !! |
---|
407 | !! ** Author: L. Brodeau, june 2016 / AeroBulk (https://sourceforge.net/p/aerobulk) |
---|
408 | !!---------------------------------------------------------------------------------- |
---|
409 | REAL(wp), DIMENSION(jpi,jpj) :: visc_air ! |
---|
410 | REAL(wp), DIMENSION(jpi,jpj), INTENT(in) :: ptak ! air temperature in (K) |
---|
411 | ! |
---|
412 | INTEGER :: ji, jj ! dummy loop indices |
---|
413 | REAL(wp) :: ztc, ztc2 ! local scalar |
---|
414 | !!---------------------------------------------------------------------------------- |
---|
415 | ! |
---|
416 | DO jj = 1, jpj |
---|
417 | DO ji = 1, jpi |
---|
418 | ztc = ptak(ji,jj) - rt0 ! air temp, in deg. C |
---|
419 | ztc2 = ztc*ztc |
---|
420 | visc_air(ji,jj) = 1.326e-5*(1. + 6.542E-3*ztc + 8.301e-6*ztc2 - 4.84e-9*ztc2*ztc) |
---|
421 | END DO |
---|
422 | END DO |
---|
423 | ! |
---|
424 | END FUNCTION visc_air |
---|
425 | |
---|
426 | !!====================================================================== |
---|
427 | END MODULE sbcblk_algo_ecmwf |
---|