New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
istate.F90 in NEMO/trunk/src/OCE/DOM – NEMO

source: NEMO/trunk/src/OCE/DOM/istate.F90 @ 15023

Last change on this file since 15023 was 15023, checked in by gsamson, 3 years ago

merge ticket2680_C1D_PAPA branch back into the trunk; see ticket #2680 for details
  • Property svn:keywords set to Id
File size: 7.9 KB
Line 
1MODULE istate
2   !!======================================================================
3   !!                     ***  MODULE  istate  ***
4   !! Ocean state   :  initial state setting
5   !!=====================================================================
6   !! History :  OPA  !  1989-12  (P. Andrich)  Original code
7   !!            5.0  !  1991-11  (G. Madec)  rewritting
8   !!            6.0  !  1996-01  (G. Madec)  terrain following coordinates
9   !!            8.0  !  2001-09  (M. Levy, M. Ben Jelloul)  istate_eel
10   !!            8.0  !  2001-09  (M. Levy, M. Ben Jelloul)  istate_uvg
11   !!   NEMO     1.0  !  2003-08  (G. Madec, C. Talandier)  F90: Free form, modules + EEL R5
12   !!             -   !  2004-05  (A. Koch-Larrouy)  istate_gyre
13   !!            2.0  !  2006-07  (S. Masson)  distributed restart using iom
14   !!            3.3  !  2010-10  (C. Ethe) merge TRC-TRA
15   !!            3.4  !  2011-04  (G. Madec) Merge of dtatem and dtasal & suppression of tb,tn/sb,sn
16   !!            3.7  !  2016-04  (S. Flavoni) introduce user defined initial state
17   !!----------------------------------------------------------------------
18
19   !!----------------------------------------------------------------------
20   !!   istate_init   : initial state setting
21   !!   istate_uvg    : initial velocity in geostropic balance
22   !!----------------------------------------------------------------------
23   USE oce            ! ocean dynamics and active tracers
24   USE dom_oce        ! ocean space and time domain
25   USE daymod         ! calendar
26   USE dtatsd         ! data temperature and salinity   (dta_tsd routine)
27   USE dtauvd         ! data: U & V current             (dta_uvd routine)
28   USE domvvl          ! varying vertical mesh
29   USE wet_dry         ! wetting and drying (needed for wad_istate)
30   USE usrdef_istate   ! User defined initial state
31   !
32   USE in_out_manager  ! I/O manager
33   USE iom             ! I/O library
34   USE lib_mpp         ! MPP library
35   USE restart         ! restart
36
37#if defined key_agrif
38   USE agrif_oce       ! initial state interpolation
39   USE agrif_oce_interp
40#endif   
41
42   IMPLICIT NONE
43   PRIVATE
44
45   PUBLIC   istate_init   ! routine called by nemogcm.F90
46
47   !! * Substitutions
48#  include "do_loop_substitute.h90"
49#  include "domzgr_substitute.h90"
50   !!----------------------------------------------------------------------
51   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
52   !! $Id$
53   !! Software governed by the CeCILL license (see ./LICENSE)
54   !!----------------------------------------------------------------------
55CONTAINS
56
57   SUBROUTINE istate_init( Kbb, Kmm, Kaa )
58      !!----------------------------------------------------------------------
59      !!                   ***  ROUTINE istate_init  ***
60      !!
61      !! ** Purpose :   Initialization of the dynamics and tracer fields.
62      !!
63      !! ** Method  :   
64      !!----------------------------------------------------------------------
65      INTEGER, INTENT( in )  ::  Kbb, Kmm, Kaa   ! ocean time level indices
66      !
67      INTEGER ::   ji, jj, jk   ! dummy loop indices
68      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zgdept     ! 3D table for qco substitute
69!!gm see comment further down
70      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:,:) ::   zuvd    ! U & V data workspace
71!!gm end
72      !!----------------------------------------------------------------------
73      !
74      IF(lwp) WRITE(numout,*)
75      IF(lwp) WRITE(numout,*) 'istate_init : Initialization of the dynamics and tracers'
76      IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
77
78      CALL dta_tsd_init                 ! Initialisation of T & S input data
79      IF( ln_c1d) CALL dta_uvd_init     ! Initialisation of U & V input data (c1d only)
80
81      rhd  (:,:,:      ) = 0._wp   ;   rhop (:,:,:  ) = 0._wp      ! set one for all to 0 at level jpk
82      rn2b (:,:,:      ) = 0._wp   ;   rn2  (:,:,:  ) = 0._wp      ! set one for all to 0 at levels 1 and jpk
83      ts   (:,:,:,:,Kaa) = 0._wp                                   ! set one for all to 0 at level jpk
84      rab_b(:,:,:,:    ) = 0._wp   ;   rab_n(:,:,:,:) = 0._wp      ! set one for all to 0 at level jpk
85#if defined key_agrif
86      uu   (:,:,:  ,Kaa) = 0._wp   ! used in agrif_oce_sponge at initialization
87      vv   (:,:,:  ,Kaa) = 0._wp   ! used in agrif_oce_sponge at initialization   
88#endif
89
90#if defined key_agrif
91      IF ( .NOT.Agrif_root() .AND. ln_init_chfrpar ) THEN
92         numror = 0                           ! define numror = 0 -> no restart file to read
93         ln_1st_euler = .true.                ! Set time-step indicator at nit000 (euler forward)
94         CALL day_init 
95         CALL agrif_istate_oce( Kbb, Kmm, Kaa )   ! Interp from parent
96         !
97         ts (:,:,:,:,Kmm) = ts (:,:,:,:,Kbb)
98         uu (:,:,:  ,Kmm) = uu (:,:,:  ,Kbb)
99         vv (:,:,:  ,Kmm) = vv (:,:,:  ,Kbb)
100      ELSE
101#endif
102         IF( ln_rstart ) THEN                    ! Restart from a file
103            !                                    ! -------------------
104            CALL rst_read( Kbb, Kmm )            ! Read the restart file
105            CALL day_init                        ! model calendar (using both namelist and restart infos)
106            !
107         ELSE                                    ! Start from rest
108            !                                    ! ---------------
109            numror = 0                           ! define numror = 0 -> no restart file to read
110            l_1st_euler = .true.                 ! Set time-step indicator at nit000 (euler forward)
111            CALL day_init                        ! model calendar (using both namelist and restart infos)
112            !                                    ! Initialization of ocean to zero
113            !
114            IF( ln_tsd_init ) THEN               
115               CALL dta_tsd( nit000, ts(:,:,:,:,Kbb) )                     ! read 3D T and S data at nit000
116            ENDIF
117            !
118            IF( ln_uvd_init .AND. ln_c1d ) THEN               
119               CALL dta_uvd( nit000, Kbb, uu(:,:,:,Kbb), vv(:,:,:,Kbb) )   ! read 3D U and V data at nit000
120            ELSE
121               uu  (:,:,:,Kbb) = 0._wp               ! set the ocean at rest
122               vv  (:,:,:,Kbb) = 0._wp 
123            ENDIF
124               !
125               !
126            IF( .NOT. ln_tsd_init .AND. .NOT. ln_uvd_init ) THEN
127               DO jk = 1, jpk
128                  zgdept(:,:,jk) = gdept(:,:,jk,Kbb)
129               END DO
130               CALL usr_def_istate( zgdept, tmask, ts(:,:,:,:,Kbb), uu(:,:,:,Kbb), vv(:,:,:,Kbb) )         
131            ENDIF
132            ts  (:,:,:,:,Kmm) = ts (:,:,:,:,Kbb)       ! set now values from to before ones
133            uu    (:,:,:,Kmm) = uu   (:,:,:,Kbb)
134            vv    (:,:,:,Kmm) = vv   (:,:,:,Kbb)
135
136         ENDIF 
137#if defined key_agrif
138      ENDIF
139#endif
140      !
141      ! Initialize "now" and "before" barotropic velocities:
142      ! Do it whatever the free surface method, these arrays being eventually used
143      !
144      uu_b(:,:,Kmm) = 0._wp   ;   vv_b(:,:,Kmm) = 0._wp
145      uu_b(:,:,Kbb) = 0._wp   ;   vv_b(:,:,Kbb) = 0._wp
146      !
147!!gm  the use of umsak & vmask is not necessary below as uu(:,:,:,Kmm), vv(:,:,:,Kmm), uu(:,:,:,Kbb), vv(:,:,:,Kbb) are always masked
148      DO_3D( nn_hls, nn_hls, nn_hls, nn_hls, 1, jpkm1 )
149         uu_b(ji,jj,Kmm) = uu_b(ji,jj,Kmm) + e3u(ji,jj,jk,Kmm) * uu(ji,jj,jk,Kmm) * umask(ji,jj,jk)
150         vv_b(ji,jj,Kmm) = vv_b(ji,jj,Kmm) + e3v(ji,jj,jk,Kmm) * vv(ji,jj,jk,Kmm) * vmask(ji,jj,jk)
151         !
152         uu_b(ji,jj,Kbb) = uu_b(ji,jj,Kbb) + e3u(ji,jj,jk,Kbb) * uu(ji,jj,jk,Kbb) * umask(ji,jj,jk)
153         vv_b(ji,jj,Kbb) = vv_b(ji,jj,Kbb) + e3v(ji,jj,jk,Kbb) * vv(ji,jj,jk,Kbb) * vmask(ji,jj,jk)
154      END_3D
155      !
156      uu_b(:,:,Kmm) = uu_b(:,:,Kmm) * r1_hu(:,:,Kmm)
157      vv_b(:,:,Kmm) = vv_b(:,:,Kmm) * r1_hv(:,:,Kmm)
158      !
159      uu_b(:,:,Kbb) = uu_b(:,:,Kbb) * r1_hu(:,:,Kbb)
160      vv_b(:,:,Kbb) = vv_b(:,:,Kbb) * r1_hv(:,:,Kbb)
161      !
162   END SUBROUTINE istate_init
163
164   !!======================================================================
165END MODULE istate
Note: See TracBrowser for help on using the repository browser.