[2148] | 1 | MODULE diahsb |
---|
| 2 | !!====================================================================== |
---|
| 3 | !! *** MODULE diahsb *** |
---|
[2334] | 4 | !! Ocean diagnostics: Heat, salt and volume budgets |
---|
[2148] | 5 | !!====================================================================== |
---|
[2334] | 6 | !! History : 3.3 ! 2010-09 (M. Leclair) Original code |
---|
[4161] | 7 | !! ! 2012-10 (C. Rousset) add iom_put |
---|
[2148] | 8 | !!---------------------------------------------------------------------- |
---|
[2334] | 9 | |
---|
| 10 | !!---------------------------------------------------------------------- |
---|
[4990] | 11 | !! dia_hsb : Diagnose the conservation of ocean heat and salt contents, and volume |
---|
| 12 | !! dia_hsb_rst : Read or write DIA file in restart file |
---|
| 13 | !! dia_hsb_init : Initialization of the conservation diagnostic |
---|
| 14 | !!---------------------------------------------------------------------- |
---|
[9168] | 15 | USE oce ! ocean dynamics and tracers |
---|
| 16 | USE dom_oce ! ocean space and time domain |
---|
| 17 | USE phycst ! physical constants |
---|
| 18 | USE sbc_oce ! surface thermohaline fluxes |
---|
[12377] | 19 | USE isf_oce ! ice shelf fluxes |
---|
[9168] | 20 | USE sbcrnf ! river runoff |
---|
| 21 | USE domvvl ! vertical scale factors |
---|
| 22 | USE traqsr ! penetrative solar radiation |
---|
| 23 | USE trabbc ! bottom boundary condition |
---|
| 24 | USE trabbc ! bottom boundary condition |
---|
| 25 | USE restart ! ocean restart |
---|
| 26 | USE bdy_oce , ONLY : ln_bdy |
---|
[4990] | 27 | ! |
---|
[9168] | 28 | USE iom ! I/O manager |
---|
| 29 | USE in_out_manager ! I/O manager |
---|
| 30 | USE lib_fortran ! glob_sum |
---|
| 31 | USE lib_mpp ! distributed memory computing library |
---|
| 32 | USE timing ! preformance summary |
---|
[2148] | 33 | |
---|
| 34 | IMPLICIT NONE |
---|
| 35 | PRIVATE |
---|
| 36 | |
---|
[2334] | 37 | PUBLIC dia_hsb ! routine called by step.F90 |
---|
[4161] | 38 | PUBLIC dia_hsb_init ! routine called by nemogcm.F90 |
---|
[2148] | 39 | |
---|
[4147] | 40 | LOGICAL, PUBLIC :: ln_diahsb !: check the heat and salt budgets |
---|
[2148] | 41 | |
---|
[4990] | 42 | REAL(wp) :: surf_tot ! ocean surface |
---|
| 43 | REAL(wp) :: frc_t, frc_s, frc_v ! global forcing trends |
---|
| 44 | REAL(wp) :: frc_wn_t, frc_wn_s ! global forcing trends |
---|
| 45 | ! |
---|
[6140] | 46 | REAL(wp), DIMENSION(:,:) , ALLOCATABLE :: surf |
---|
| 47 | REAL(wp), DIMENSION(:,:) , ALLOCATABLE :: surf_ini , ssh_ini ! |
---|
[4990] | 48 | REAL(wp), DIMENSION(:,:) , ALLOCATABLE :: ssh_hc_loc_ini, ssh_sc_loc_ini ! |
---|
| 49 | REAL(wp), DIMENSION(:,:,:), ALLOCATABLE :: hc_loc_ini, sc_loc_ini, e3t_ini ! |
---|
[12377] | 50 | REAL(wp), DIMENSION(:,:,:), ALLOCATABLE :: tmask_ini |
---|
[2148] | 51 | |
---|
[13237] | 52 | !! * Substitutions |
---|
| 53 | # include "domzgr_substitute.h90" |
---|
[2148] | 54 | !!---------------------------------------------------------------------- |
---|
[9598] | 55 | !! NEMO/OCE 4.0 , NEMO Consortium (2018) |
---|
[2281] | 56 | !! $Id$ |
---|
[10068] | 57 | !! Software governed by the CeCILL license (see ./LICENSE) |
---|
[2148] | 58 | !!---------------------------------------------------------------------- |
---|
| 59 | CONTAINS |
---|
| 60 | |
---|
[12377] | 61 | SUBROUTINE dia_hsb( kt, Kbb, Kmm ) |
---|
[2148] | 62 | !!--------------------------------------------------------------------------- |
---|
| 63 | !! *** ROUTINE dia_hsb *** |
---|
| 64 | !! |
---|
[2334] | 65 | !! ** Purpose: Compute the ocean global heat content, salt content and volume conservation |
---|
[2148] | 66 | !! |
---|
| 67 | !! ** Method : - Compute the deviation of heat content, salt content and volume |
---|
[2334] | 68 | !! at the current time step from their values at nit000 |
---|
| 69 | !! - Compute the contribution of forcing and remove it from these deviations |
---|
| 70 | !! |
---|
[2148] | 71 | !!--------------------------------------------------------------------------- |
---|
[12377] | 72 | INTEGER, INTENT(in) :: kt ! ocean time-step index |
---|
| 73 | INTEGER, INTENT(in) :: Kbb, Kmm ! ocean time level indices |
---|
[4990] | 74 | ! |
---|
| 75 | INTEGER :: ji, jj, jk ! dummy loop indice |
---|
| 76 | REAL(wp) :: zdiff_hc , zdiff_sc ! heat and salt content variations |
---|
| 77 | REAL(wp) :: zdiff_hc1 , zdiff_sc1 ! - - - - |
---|
| 78 | REAL(wp) :: zdiff_v1 , zdiff_v2 ! volume variation |
---|
| 79 | REAL(wp) :: zerr_hc1 , zerr_sc1 ! heat and salt content misfit |
---|
| 80 | REAL(wp) :: zvol_tot ! volume |
---|
| 81 | REAL(wp) :: z_frc_trd_t , z_frc_trd_s ! - - |
---|
| 82 | REAL(wp) :: z_frc_trd_v ! - - |
---|
| 83 | REAL(wp) :: z_wn_trd_t , z_wn_trd_s ! - - |
---|
| 84 | REAL(wp) :: z_ssh_hc , z_ssh_sc ! - - |
---|
[9227] | 85 | REAL(wp), DIMENSION(jpi,jpj) :: z2d0, z2d1 ! 2D workspace |
---|
| 86 | REAL(wp), DIMENSION(jpi,jpj,jpkm1) :: zwrk ! 3D workspace |
---|
[2148] | 87 | !!--------------------------------------------------------------------------- |
---|
[9124] | 88 | IF( ln_timing ) CALL timing_start('dia_hsb') |
---|
[7646] | 89 | ! |
---|
[12377] | 90 | ts(:,:,:,1,Kmm) = ts(:,:,:,1,Kmm) * tmask(:,:,:) ; ts(:,:,:,1,Kbb) = ts(:,:,:,1,Kbb) * tmask(:,:,:) ; |
---|
| 91 | ts(:,:,:,2,Kmm) = ts(:,:,:,2,Kmm) * tmask(:,:,:) ; ts(:,:,:,2,Kbb) = ts(:,:,:,2,Kbb) * tmask(:,:,:) ; |
---|
[2148] | 92 | ! ------------------------- ! |
---|
| 93 | ! 1 - Trends due to forcing ! |
---|
| 94 | ! ------------------------- ! |
---|
[12489] | 95 | z_frc_trd_v = r1_rho0 * glob_sum( 'diahsb', - ( emp(:,:) - rnf(:,:) + fwfisf_cav(:,:) + fwfisf_par(:,:) ) * surf(:,:) ) ! volume fluxes |
---|
[10425] | 96 | z_frc_trd_t = glob_sum( 'diahsb', sbc_tsc(:,:,jp_tem) * surf(:,:) ) ! heat fluxes |
---|
| 97 | z_frc_trd_s = glob_sum( 'diahsb', sbc_tsc(:,:,jp_sal) * surf(:,:) ) ! salt fluxes |
---|
[9227] | 98 | ! ! Add runoff heat & salt input |
---|
[10425] | 99 | IF( ln_rnf ) z_frc_trd_t = z_frc_trd_t + glob_sum( 'diahsb', rnf_tsc(:,:,jp_tem) * surf(:,:) ) |
---|
| 100 | IF( ln_rnf_sal) z_frc_trd_s = z_frc_trd_s + glob_sum( 'diahsb', rnf_tsc(:,:,jp_sal) * surf(:,:) ) |
---|
[9227] | 101 | ! ! Add ice shelf heat & salt input |
---|
[12377] | 102 | IF( ln_isf ) z_frc_trd_t = z_frc_trd_t & |
---|
| 103 | & + glob_sum( 'diahsb', ( risf_cav_tsc(:,:,jp_tem) + risf_par_tsc(:,:,jp_tem) ) * surf(:,:) ) |
---|
[9227] | 104 | ! ! Add penetrative solar radiation |
---|
[12489] | 105 | IF( ln_traqsr ) z_frc_trd_t = z_frc_trd_t + r1_rho0_rcp * glob_sum( 'diahsb', qsr (:,:) * surf(:,:) ) |
---|
[9227] | 106 | ! ! Add geothermal heat flux |
---|
[10425] | 107 | IF( ln_trabbc ) z_frc_trd_t = z_frc_trd_t + glob_sum( 'diahsb', qgh_trd0(:,:) * surf(:,:) ) |
---|
[4161] | 108 | ! |
---|
[6140] | 109 | IF( ln_linssh ) THEN |
---|
| 110 | IF( ln_isfcav ) THEN |
---|
[5120] | 111 | DO ji=1,jpi |
---|
| 112 | DO jj=1,jpj |
---|
[12377] | 113 | z2d0(ji,jj) = surf(ji,jj) * ww(ji,jj,mikt(ji,jj)) * ts(ji,jj,mikt(ji,jj),jp_tem,Kbb) |
---|
| 114 | z2d1(ji,jj) = surf(ji,jj) * ww(ji,jj,mikt(ji,jj)) * ts(ji,jj,mikt(ji,jj),jp_sal,Kbb) |
---|
[6140] | 115 | END DO |
---|
| 116 | END DO |
---|
[5120] | 117 | ELSE |
---|
[12377] | 118 | z2d0(:,:) = surf(:,:) * ww(:,:,1) * ts(:,:,1,jp_tem,Kbb) |
---|
| 119 | z2d1(:,:) = surf(:,:) * ww(:,:,1) * ts(:,:,1,jp_sal,Kbb) |
---|
[5120] | 120 | END IF |
---|
[10425] | 121 | z_wn_trd_t = - glob_sum( 'diahsb', z2d0 ) |
---|
| 122 | z_wn_trd_s = - glob_sum( 'diahsb', z2d1 ) |
---|
[4558] | 123 | ENDIF |
---|
| 124 | |
---|
[12489] | 125 | frc_v = frc_v + z_frc_trd_v * rn_Dt |
---|
| 126 | frc_t = frc_t + z_frc_trd_t * rn_Dt |
---|
| 127 | frc_s = frc_s + z_frc_trd_s * rn_Dt |
---|
[4558] | 128 | ! ! Advection flux through fixed surface (z=0) |
---|
[6140] | 129 | IF( ln_linssh ) THEN |
---|
[12489] | 130 | frc_wn_t = frc_wn_t + z_wn_trd_t * rn_Dt |
---|
| 131 | frc_wn_s = frc_wn_s + z_wn_trd_s * rn_Dt |
---|
[4558] | 132 | ENDIF |
---|
[2148] | 133 | |
---|
[4161] | 134 | ! ------------------------ ! |
---|
[9227] | 135 | ! 2 - Content variations ! |
---|
[4161] | 136 | ! ------------------------ ! |
---|
[6140] | 137 | ! glob_sum_full is needed because you keep the full interior domain to compute the sum (iscpl) |
---|
[4558] | 138 | |
---|
[9227] | 139 | ! ! volume variation (calculated with ssh) |
---|
[12377] | 140 | zdiff_v1 = glob_sum_full( 'diahsb', surf(:,:)*ssh(:,:,Kmm) - surf_ini(:,:)*ssh_ini(:,:) ) |
---|
[4558] | 141 | |
---|
[9227] | 142 | ! ! heat & salt content variation (associated with ssh) |
---|
| 143 | IF( ln_linssh ) THEN ! linear free surface case |
---|
| 144 | IF( ln_isfcav ) THEN ! ISF case |
---|
[5120] | 145 | DO ji = 1, jpi |
---|
| 146 | DO jj = 1, jpj |
---|
[12377] | 147 | z2d0(ji,jj) = surf(ji,jj) * ( ts(ji,jj,mikt(ji,jj),jp_tem,Kmm) * ssh(ji,jj,Kmm) - ssh_hc_loc_ini(ji,jj) ) |
---|
| 148 | z2d1(ji,jj) = surf(ji,jj) * ( ts(ji,jj,mikt(ji,jj),jp_sal,Kmm) * ssh(ji,jj,Kmm) - ssh_sc_loc_ini(ji,jj) ) |
---|
[5120] | 149 | END DO |
---|
[4990] | 150 | END DO |
---|
[9227] | 151 | ELSE ! no under ice-shelf seas |
---|
[12377] | 152 | z2d0(:,:) = surf(:,:) * ( ts(:,:,1,jp_tem,Kmm) * ssh(:,:,Kmm) - ssh_hc_loc_ini(:,:) ) |
---|
| 153 | z2d1(:,:) = surf(:,:) * ( ts(:,:,1,jp_sal,Kmm) * ssh(:,:,Kmm) - ssh_sc_loc_ini(:,:) ) |
---|
[5120] | 154 | END IF |
---|
[10425] | 155 | z_ssh_hc = glob_sum_full( 'diahsb', z2d0 ) |
---|
| 156 | z_ssh_sc = glob_sum_full( 'diahsb', z2d1 ) |
---|
[4558] | 157 | ENDIF |
---|
[9227] | 158 | ! |
---|
[10425] | 159 | DO jk = 1, jpkm1 ! volume variation (calculated with scale factors) |
---|
[13237] | 160 | zwrk(:,:,jk) = surf (:,:) * e3t (:,:,jk,Kmm)*tmask (:,:,jk) & |
---|
| 161 | & - surf_ini(:,:) * e3t_ini(:,:,jk )*tmask_ini(:,:,jk) |
---|
[9227] | 162 | END DO |
---|
[12377] | 163 | zdiff_v2 = glob_sum_full( 'diahsb', zwrk(:,:,:) ) ! glob_sum_full needed as tmask and tmask_ini could be different |
---|
[9227] | 164 | DO jk = 1, jpkm1 ! heat content variation |
---|
[13237] | 165 | zwrk(:,:,jk) = ( surf (:,:) * e3t(:,:,jk,Kmm)*ts(:,:,jk,jp_tem,Kmm) & |
---|
| 166 | & - surf_ini(:,:) * hc_loc_ini(:,:,jk) ) |
---|
[9227] | 167 | END DO |
---|
[10425] | 168 | zdiff_hc = glob_sum_full( 'diahsb', zwrk(:,:,:) ) |
---|
[9227] | 169 | DO jk = 1, jpkm1 ! salt content variation |
---|
[13237] | 170 | zwrk(:,:,jk) = ( surf (:,:) * e3t(:,:,jk,Kmm)*ts(:,:,jk,jp_sal,Kmm) & |
---|
| 171 | & - surf_ini(:,:) * sc_loc_ini(:,:,jk) ) |
---|
[9227] | 172 | END DO |
---|
[10425] | 173 | zdiff_sc = glob_sum_full( 'diahsb', zwrk(:,:,:) ) |
---|
[4558] | 174 | |
---|
[7646] | 175 | ! ------------------------ ! |
---|
| 176 | ! 3 - Drifts ! |
---|
| 177 | ! ------------------------ ! |
---|
[4558] | 178 | zdiff_v1 = zdiff_v1 - frc_v |
---|
[6140] | 179 | IF( .NOT.ln_linssh ) zdiff_v2 = zdiff_v2 - frc_v |
---|
[4558] | 180 | zdiff_hc = zdiff_hc - frc_t |
---|
| 181 | zdiff_sc = zdiff_sc - frc_s |
---|
[6140] | 182 | IF( ln_linssh ) THEN |
---|
[4558] | 183 | zdiff_hc1 = zdiff_hc + z_ssh_hc |
---|
| 184 | zdiff_sc1 = zdiff_sc + z_ssh_sc |
---|
| 185 | zerr_hc1 = z_ssh_hc - frc_wn_t |
---|
| 186 | zerr_sc1 = z_ssh_sc - frc_wn_s |
---|
[4162] | 187 | ENDIF |
---|
[4558] | 188 | |
---|
[2148] | 189 | ! ----------------------- ! |
---|
[7646] | 190 | ! 4 - Diagnostics writing ! |
---|
[4161] | 191 | ! ----------------------- ! |
---|
[9227] | 192 | DO jk = 1, jpkm1 ! total ocean volume (calculated with scale factors) |
---|
[12377] | 193 | zwrk(:,:,jk) = surf(:,:) * e3t(:,:,jk,Kmm) * tmask(:,:,jk) |
---|
[4558] | 194 | END DO |
---|
[12377] | 195 | zvol_tot = glob_sum( 'diahsb', zwrk(:,:,:) ) |
---|
[4558] | 196 | |
---|
[4990] | 197 | !!gm to be added ? |
---|
[6140] | 198 | ! IF( ln_linssh ) THEN ! fixed volume, add the ssh contribution |
---|
[12377] | 199 | ! zvol_tot = zvol_tot + glob_sum( 'diahsb', surf(:,:) * ssh(:,:,Kmm) ) |
---|
[4990] | 200 | ! ENDIF |
---|
| 201 | !!gm end |
---|
| 202 | |
---|
[7646] | 203 | CALL iom_put( 'bgfrcvol' , frc_v * 1.e-9 ) ! vol - surface forcing (km3) |
---|
[12489] | 204 | CALL iom_put( 'bgfrctem' , frc_t * rho0 * rcp * 1.e-20 ) ! hc - surface forcing (1.e20 J) |
---|
| 205 | CALL iom_put( 'bgfrchfx' , frc_t * rho0 * rcp / & ! hc - surface forcing (W/m2) |
---|
| 206 | & ( surf_tot * kt * rn_Dt ) ) |
---|
[7646] | 207 | CALL iom_put( 'bgfrcsal' , frc_s * 1.e-9 ) ! sc - surface forcing (psu*km3) |
---|
| 208 | |
---|
| 209 | IF( .NOT. ln_linssh ) THEN |
---|
[9227] | 210 | CALL iom_put( 'bgtemper' , zdiff_hc / zvol_tot ) ! Temperature drift (C) |
---|
| 211 | CALL iom_put( 'bgsaline' , zdiff_sc / zvol_tot ) ! Salinity drift (PSU) |
---|
[12489] | 212 | CALL iom_put( 'bgheatco' , zdiff_hc * 1.e-20 * rho0 * rcp ) ! Heat content drift (1.e20 J) |
---|
| 213 | CALL iom_put( 'bgheatfx' , zdiff_hc * rho0 * rcp / & ! Heat flux drift (W/m2) |
---|
| 214 | & ( surf_tot * kt * rn_Dt ) ) |
---|
[9227] | 215 | CALL iom_put( 'bgsaltco' , zdiff_sc * 1.e-9 ) ! Salt content drift (psu*km3) |
---|
| 216 | CALL iom_put( 'bgvolssh' , zdiff_v1 * 1.e-9 ) ! volume ssh drift (km3) |
---|
| 217 | CALL iom_put( 'bgvole3t' , zdiff_v2 * 1.e-9 ) ! volume e3t drift (km3) |
---|
| 218 | ! |
---|
| 219 | IF( kt == nitend .AND. lwp ) THEN |
---|
| 220 | WRITE(numout,*) |
---|
| 221 | WRITE(numout,*) 'dia_hsb : last time step hsb diagnostics: at it= ', kt,' date= ', ndastp |
---|
| 222 | WRITE(numout,*) '~~~~~~~' |
---|
| 223 | WRITE(numout,*) ' Temperature drift = ', zdiff_hc / zvol_tot, ' C' |
---|
| 224 | WRITE(numout,*) ' Salinity drift = ', zdiff_sc / zvol_tot, ' PSU' |
---|
| 225 | WRITE(numout,*) ' volume ssh drift = ', zdiff_v1 * 1.e-9 , ' km^3' |
---|
| 226 | WRITE(numout,*) ' volume e3t drift = ', zdiff_v2 * 1.e-9 , ' km^3' |
---|
| 227 | ENDIF |
---|
| 228 | ! |
---|
[7646] | 229 | ELSE |
---|
[9227] | 230 | CALL iom_put( 'bgtemper' , zdiff_hc1 / zvol_tot) ! Heat content drift (C) |
---|
| 231 | CALL iom_put( 'bgsaline' , zdiff_sc1 / zvol_tot) ! Salt content drift (PSU) |
---|
[12489] | 232 | CALL iom_put( 'bgheatco' , zdiff_hc1 * 1.e-20 * rho0 * rcp ) ! Heat content drift (1.e20 J) |
---|
| 233 | CALL iom_put( 'bgheatfx' , zdiff_hc1 * rho0 * rcp / & ! Heat flux drift (W/m2) |
---|
| 234 | & ( surf_tot * kt * rn_Dt ) ) |
---|
[9227] | 235 | CALL iom_put( 'bgsaltco' , zdiff_sc1 * 1.e-9 ) ! Salt content drift (psu*km3) |
---|
| 236 | CALL iom_put( 'bgvolssh' , zdiff_v1 * 1.e-9 ) ! volume ssh drift (km3) |
---|
| 237 | CALL iom_put( 'bgmistem' , zerr_hc1 / zvol_tot ) ! hc - error due to free surface (C) |
---|
| 238 | CALL iom_put( 'bgmissal' , zerr_sc1 / zvol_tot ) ! sc - error due to free surface (psu) |
---|
[4162] | 239 | ENDIF |
---|
[4558] | 240 | ! |
---|
[12377] | 241 | IF( lrst_oce ) CALL dia_hsb_rst( kt, Kmm, 'WRITE' ) |
---|
[6140] | 242 | ! |
---|
[9124] | 243 | IF( ln_timing ) CALL timing_stop('dia_hsb') |
---|
[6140] | 244 | ! |
---|
[2148] | 245 | END SUBROUTINE dia_hsb |
---|
| 246 | |
---|
[2334] | 247 | |
---|
[12377] | 248 | SUBROUTINE dia_hsb_rst( kt, Kmm, cdrw ) |
---|
[9169] | 249 | !!--------------------------------------------------------------------- |
---|
| 250 | !! *** ROUTINE dia_hsb_rst *** |
---|
| 251 | !! |
---|
| 252 | !! ** Purpose : Read or write DIA file in restart file |
---|
| 253 | !! |
---|
| 254 | !! ** Method : use of IOM library |
---|
| 255 | !!---------------------------------------------------------------------- |
---|
| 256 | INTEGER , INTENT(in) :: kt ! ocean time-step |
---|
[12377] | 257 | INTEGER , INTENT(in) :: Kmm ! ocean time level index |
---|
[9169] | 258 | CHARACTER(len=*), INTENT(in) :: cdrw ! "READ"/"WRITE" flag |
---|
| 259 | ! |
---|
| 260 | INTEGER :: ji, jj, jk ! dummy loop indices |
---|
| 261 | !!---------------------------------------------------------------------- |
---|
| 262 | ! |
---|
| 263 | IF( TRIM(cdrw) == 'READ' ) THEN ! Read/initialise |
---|
| 264 | IF( ln_rstart ) THEN !* Read the restart file |
---|
| 265 | ! |
---|
| 266 | IF(lwp) WRITE(numout,*) |
---|
| 267 | IF(lwp) WRITE(numout,*) ' dia_hsb_rst : read hsb restart at it= ', kt,' date= ', ndastp |
---|
| 268 | IF(lwp) WRITE(numout,*) |
---|
[9367] | 269 | CALL iom_get( numror, 'frc_v', frc_v, ldxios = lrxios ) |
---|
| 270 | CALL iom_get( numror, 'frc_t', frc_t, ldxios = lrxios ) |
---|
| 271 | CALL iom_get( numror, 'frc_s', frc_s, ldxios = lrxios ) |
---|
[9169] | 272 | IF( ln_linssh ) THEN |
---|
[9367] | 273 | CALL iom_get( numror, 'frc_wn_t', frc_wn_t, ldxios = lrxios ) |
---|
| 274 | CALL iom_get( numror, 'frc_wn_s', frc_wn_s, ldxios = lrxios ) |
---|
[9169] | 275 | ENDIF |
---|
[9367] | 276 | CALL iom_get( numror, jpdom_autoglo, 'surf_ini' , surf_ini , ldxios = lrxios ) ! ice sheet coupling |
---|
| 277 | CALL iom_get( numror, jpdom_autoglo, 'ssh_ini' , ssh_ini , ldxios = lrxios ) |
---|
| 278 | CALL iom_get( numror, jpdom_autoglo, 'e3t_ini' , e3t_ini , ldxios = lrxios ) |
---|
[12377] | 279 | CALL iom_get( numror, jpdom_autoglo, 'tmask_ini' , tmask_ini , ldxios = lrxios ) |
---|
[9367] | 280 | CALL iom_get( numror, jpdom_autoglo, 'hc_loc_ini', hc_loc_ini, ldxios = lrxios ) |
---|
| 281 | CALL iom_get( numror, jpdom_autoglo, 'sc_loc_ini', sc_loc_ini, ldxios = lrxios ) |
---|
[9169] | 282 | IF( ln_linssh ) THEN |
---|
[9367] | 283 | CALL iom_get( numror, jpdom_autoglo, 'ssh_hc_loc_ini', ssh_hc_loc_ini, ldxios = lrxios ) |
---|
| 284 | CALL iom_get( numror, jpdom_autoglo, 'ssh_sc_loc_ini', ssh_sc_loc_ini, ldxios = lrxios ) |
---|
[9169] | 285 | ENDIF |
---|
[9367] | 286 | ELSE |
---|
[9169] | 287 | IF(lwp) WRITE(numout,*) |
---|
| 288 | IF(lwp) WRITE(numout,*) ' dia_hsb_rst : initialise hsb at initial state ' |
---|
| 289 | IF(lwp) WRITE(numout,*) |
---|
| 290 | surf_ini(:,:) = e1e2t(:,:) * tmask_i(:,:) ! initial ocean surface |
---|
[12377] | 291 | ssh_ini(:,:) = ssh(:,:,Kmm) ! initial ssh |
---|
[9169] | 292 | DO jk = 1, jpk |
---|
| 293 | ! if ice sheet/oceqn coupling, need to mask ini variables here (mask could change at the next NEMO instance). |
---|
[12377] | 294 | e3t_ini (:,:,jk) = e3t(:,:,jk,Kmm) * tmask(:,:,jk) ! initial vertical scale factors |
---|
| 295 | tmask_ini (:,:,jk) = tmask(:,:,jk) ! initial mask |
---|
| 296 | hc_loc_ini(:,:,jk) = ts(:,:,jk,jp_tem,Kmm) * e3t(:,:,jk,Kmm) * tmask(:,:,jk) ! initial heat content |
---|
| 297 | sc_loc_ini(:,:,jk) = ts(:,:,jk,jp_sal,Kmm) * e3t(:,:,jk,Kmm) * tmask(:,:,jk) ! initial salt content |
---|
[9169] | 298 | END DO |
---|
| 299 | frc_v = 0._wp ! volume trend due to forcing |
---|
| 300 | frc_t = 0._wp ! heat content - - - - |
---|
| 301 | frc_s = 0._wp ! salt content - - - - |
---|
| 302 | IF( ln_linssh ) THEN |
---|
| 303 | IF( ln_isfcav ) THEN |
---|
| 304 | DO ji = 1, jpi |
---|
| 305 | DO jj = 1, jpj |
---|
[12377] | 306 | ssh_hc_loc_ini(ji,jj) = ts(ji,jj,mikt(ji,jj),jp_tem,Kmm) * ssh(ji,jj,Kmm) ! initial heat content in ssh |
---|
| 307 | ssh_sc_loc_ini(ji,jj) = ts(ji,jj,mikt(ji,jj),jp_sal,Kmm) * ssh(ji,jj,Kmm) ! initial salt content in ssh |
---|
[9169] | 308 | END DO |
---|
| 309 | END DO |
---|
| 310 | ELSE |
---|
[12377] | 311 | ssh_hc_loc_ini(:,:) = ts(:,:,1,jp_tem,Kmm) * ssh(:,:,Kmm) ! initial heat content in ssh |
---|
| 312 | ssh_sc_loc_ini(:,:) = ts(:,:,1,jp_sal,Kmm) * ssh(:,:,Kmm) ! initial salt content in ssh |
---|
[9169] | 313 | END IF |
---|
| 314 | frc_wn_t = 0._wp ! initial heat content misfit due to free surface |
---|
| 315 | frc_wn_s = 0._wp ! initial salt content misfit due to free surface |
---|
| 316 | ENDIF |
---|
| 317 | ENDIF |
---|
| 318 | ! |
---|
| 319 | ELSEIF( TRIM(cdrw) == 'WRITE' ) THEN ! Create restart file |
---|
| 320 | ! ! ------------------- |
---|
| 321 | IF(lwp) WRITE(numout,*) |
---|
| 322 | IF(lwp) WRITE(numout,*) ' dia_hsb_rst : write restart at it= ', kt,' date= ', ndastp |
---|
| 323 | IF(lwp) WRITE(numout,*) |
---|
| 324 | ! |
---|
[9367] | 325 | IF( lwxios ) CALL iom_swap( cwxios_context ) |
---|
| 326 | CALL iom_rstput( kt, nitrst, numrow, 'frc_v', frc_v, ldxios = lwxios ) |
---|
| 327 | CALL iom_rstput( kt, nitrst, numrow, 'frc_t', frc_t, ldxios = lwxios ) |
---|
| 328 | CALL iom_rstput( kt, nitrst, numrow, 'frc_s', frc_s, ldxios = lwxios ) |
---|
[9169] | 329 | IF( ln_linssh ) THEN |
---|
[9367] | 330 | CALL iom_rstput( kt, nitrst, numrow, 'frc_wn_t', frc_wn_t, ldxios = lwxios ) |
---|
| 331 | CALL iom_rstput( kt, nitrst, numrow, 'frc_wn_s', frc_wn_s, ldxios = lwxios ) |
---|
[9169] | 332 | ENDIF |
---|
[9367] | 333 | CALL iom_rstput( kt, nitrst, numrow, 'surf_ini' , surf_ini , ldxios = lwxios ) ! ice sheet coupling |
---|
| 334 | CALL iom_rstput( kt, nitrst, numrow, 'ssh_ini' , ssh_ini , ldxios = lwxios ) |
---|
| 335 | CALL iom_rstput( kt, nitrst, numrow, 'e3t_ini' , e3t_ini , ldxios = lwxios ) |
---|
[12377] | 336 | CALL iom_rstput( kt, nitrst, numrow, 'tmask_ini' , tmask_ini , ldxios = lwxios ) |
---|
[9367] | 337 | CALL iom_rstput( kt, nitrst, numrow, 'hc_loc_ini', hc_loc_ini, ldxios = lwxios ) |
---|
| 338 | CALL iom_rstput( kt, nitrst, numrow, 'sc_loc_ini', sc_loc_ini, ldxios = lwxios ) |
---|
[9169] | 339 | IF( ln_linssh ) THEN |
---|
[9367] | 340 | CALL iom_rstput( kt, nitrst, numrow, 'ssh_hc_loc_ini', ssh_hc_loc_ini, ldxios = lwxios ) |
---|
| 341 | CALL iom_rstput( kt, nitrst, numrow, 'ssh_sc_loc_ini', ssh_sc_loc_ini, ldxios = lwxios ) |
---|
[9169] | 342 | ENDIF |
---|
[9367] | 343 | IF( lwxios ) CALL iom_swap( cxios_context ) |
---|
[9169] | 344 | ! |
---|
| 345 | ENDIF |
---|
| 346 | ! |
---|
[4161] | 347 | END SUBROUTINE dia_hsb_rst |
---|
[2148] | 348 | |
---|
[4990] | 349 | |
---|
[12377] | 350 | SUBROUTINE dia_hsb_init( Kmm ) |
---|
[4990] | 351 | !!--------------------------------------------------------------------------- |
---|
| 352 | !! *** ROUTINE dia_hsb *** |
---|
| 353 | !! |
---|
| 354 | !! ** Purpose: Initialization for the heat salt volume budgets |
---|
| 355 | !! |
---|
| 356 | !! ** Method : Compute initial heat content, salt content and volume |
---|
| 357 | !! |
---|
| 358 | !! ** Action : - Compute initial heat content, salt content and volume |
---|
| 359 | !! - Initialize forcing trends |
---|
| 360 | !! - Compute coefficients for conversion |
---|
| 361 | !!--------------------------------------------------------------------------- |
---|
[12377] | 362 | INTEGER, INTENT(in) :: Kmm ! time level index |
---|
| 363 | ! |
---|
[9169] | 364 | INTEGER :: ierror, ios ! local integer |
---|
[7646] | 365 | !! |
---|
[4990] | 366 | NAMELIST/namhsb/ ln_diahsb |
---|
| 367 | !!---------------------------------------------------------------------- |
---|
[7646] | 368 | ! |
---|
[9169] | 369 | IF(lwp) THEN |
---|
| 370 | WRITE(numout,*) |
---|
| 371 | WRITE(numout,*) 'dia_hsb_init : heat and salt budgets diagnostics' |
---|
| 372 | WRITE(numout,*) '~~~~~~~~~~~~ ' |
---|
| 373 | ENDIF |
---|
[4990] | 374 | READ ( numnam_ref, namhsb, IOSTAT = ios, ERR = 901) |
---|
[11536] | 375 | 901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namhsb in reference namelist' ) |
---|
[4990] | 376 | READ ( numnam_cfg, namhsb, IOSTAT = ios, ERR = 902 ) |
---|
[11536] | 377 | 902 IF( ios > 0 ) CALL ctl_nam ( ios , 'namhsb in configuration namelist' ) |
---|
[9169] | 378 | IF(lwm) WRITE( numond, namhsb ) |
---|
[4990] | 379 | |
---|
[7646] | 380 | IF(lwp) THEN |
---|
[9168] | 381 | WRITE(numout,*) ' Namelist namhsb :' |
---|
| 382 | WRITE(numout,*) ' check the heat and salt budgets (T) or not (F) ln_diahsb = ', ln_diahsb |
---|
[4990] | 383 | ENDIF |
---|
[7646] | 384 | ! |
---|
[4990] | 385 | IF( .NOT. ln_diahsb ) RETURN |
---|
| 386 | |
---|
[9367] | 387 | IF(lwxios) THEN |
---|
| 388 | ! define variables in restart file when writing with XIOS |
---|
| 389 | CALL iom_set_rstw_var_active('frc_v') |
---|
| 390 | CALL iom_set_rstw_var_active('frc_t') |
---|
| 391 | CALL iom_set_rstw_var_active('frc_s') |
---|
| 392 | CALL iom_set_rstw_var_active('surf_ini') |
---|
| 393 | CALL iom_set_rstw_var_active('ssh_ini') |
---|
| 394 | CALL iom_set_rstw_var_active('e3t_ini') |
---|
| 395 | CALL iom_set_rstw_var_active('hc_loc_ini') |
---|
| 396 | CALL iom_set_rstw_var_active('sc_loc_ini') |
---|
| 397 | IF( ln_linssh ) THEN |
---|
| 398 | CALL iom_set_rstw_var_active('ssh_hc_loc_ini') |
---|
| 399 | CALL iom_set_rstw_var_active('ssh_sc_loc_ini') |
---|
| 400 | CALL iom_set_rstw_var_active('frc_wn_t') |
---|
| 401 | CALL iom_set_rstw_var_active('frc_wn_s') |
---|
| 402 | ENDIF |
---|
| 403 | ENDIF |
---|
[4990] | 404 | ! ------------------- ! |
---|
| 405 | ! 1 - Allocate memory ! |
---|
| 406 | ! ------------------- ! |
---|
[6140] | 407 | ALLOCATE( hc_loc_ini(jpi,jpj,jpk), sc_loc_ini(jpi,jpj,jpk), surf_ini(jpi,jpj), & |
---|
[12377] | 408 | & e3t_ini(jpi,jpj,jpk), surf(jpi,jpj), ssh_ini(jpi,jpj), tmask_ini(jpi,jpj,jpk),STAT=ierror ) |
---|
[4990] | 409 | IF( ierror > 0 ) THEN |
---|
[7646] | 410 | CALL ctl_stop( 'dia_hsb_init: unable to allocate hc_loc_ini' ) ; RETURN |
---|
[4990] | 411 | ENDIF |
---|
| 412 | |
---|
[6140] | 413 | IF( ln_linssh ) ALLOCATE( ssh_hc_loc_ini(jpi,jpj), ssh_sc_loc_ini(jpi,jpj),STAT=ierror ) |
---|
[4990] | 414 | IF( ierror > 0 ) THEN |
---|
[7646] | 415 | CALL ctl_stop( 'dia_hsb: unable to allocate ssh_hc_loc_ini' ) ; RETURN |
---|
[4990] | 416 | ENDIF |
---|
| 417 | |
---|
| 418 | ! ----------------------------------------------- ! |
---|
| 419 | ! 2 - Time independant variables and file opening ! |
---|
| 420 | ! ----------------------------------------------- ! |
---|
[10425] | 421 | surf(:,:) = e1e2t(:,:) * tmask_i(:,:) ! masked surface grid cell area |
---|
| 422 | surf_tot = glob_sum( 'diahsb', surf(:,:) ) ! total ocean surface area |
---|
[4990] | 423 | |
---|
[7646] | 424 | IF( ln_bdy ) CALL ctl_warn( 'dia_hsb_init: heat/salt budget does not consider open boundary fluxes' ) |
---|
[4990] | 425 | ! |
---|
| 426 | ! ---------------------------------- ! |
---|
| 427 | ! 4 - initial conservation variables ! |
---|
| 428 | ! ---------------------------------- ! |
---|
[12377] | 429 | CALL dia_hsb_rst( nit000, Kmm, 'READ' ) !* read or initialize all required files |
---|
[4990] | 430 | ! |
---|
| 431 | END SUBROUTINE dia_hsb_init |
---|
| 432 | |
---|
[2148] | 433 | !!====================================================================== |
---|
| 434 | END MODULE diahsb |
---|